Make `derivedConstants` more crosscompile-friendly
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.11], [glasgow-haskell-bugs@haskell.org], [ghc])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands,
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42 FP_PROG_SORT
43
44 dnl ----------------------------------------------------------
45 FP_SETUP_PROJECT_VERSION
46
47 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
48 AC_SUBST([release], [1])
49
50 # First off, a distrib sanity check..
51 AC_CONFIG_SRCDIR([mk/config.mk.in])
52
53 dnl * We require autoconf version 2.60
54 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
55 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
56 dnl Using autoconf 2.59 started to give nonsense like this
57 dnl  #define SIZEOF_CHAR 0
58 dnl recently.
59 AC_PREREQ([2.60])
60
61 # -------------------------------------------------------------------------
62 # Prepare to generate the following header files
63 #
64 #
65 AC_CONFIG_HEADER(mk/config.h)
66
67 # No, semi-sadly, we don't do `--srcdir'...
68 if test x"$srcdir" != 'x.' ; then
69     echo "This configuration does not support the \`--srcdir' option.."
70     exit 1
71 fi
72
73 dnl --------------------------------------------------------------
74 dnl * Project specific configuration options
75 dnl --------------------------------------------------------------
76 dnl What follows is a bunch of options that can either be configured
77 dnl through command line options to the configure script or by
78 dnl supplying defns in the build tree's mk/build.mk. Having the option to
79 dnl use either is considered a Feature.
80
81 dnl ** What command to use to compile compiler sources ?
82 dnl --------------------------------------------------------------
83
84 AC_ARG_WITH([ghc],
85 [AC_HELP_STRING([--with-ghc=ARG],
86   [Use ARG as the path to GHC  [default=autodetect]])],
87   [WithGhc="$withval"],
88   [if test "$GHC" = ""; then
89     AC_PATH_PROG([GHC], [ghc])
90   fi
91   WithGhc="$GHC"])
92
93 dnl ** Tell the make system which OS we are using
94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
95 AC_SUBST(OSTYPE)
96
97 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
98 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
99                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
100         EnableBootstrapWithDevelSnaphost=YES,
101         EnableBootstrapWithDevelSnaphost=NO
102 )
103
104 AC_ARG_ENABLE(tarballs-autodownload,
105 [AC_HELP_STRING([--enable-tarballs-autodownload],
106                 [Automatically download Windows distribution binaries if needed.])],
107         TarballsAutodownload=YES,
108         TarballsAutodownload=NO
109 )
110 if test "$WithGhc" != ""; then
111   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
112
113   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
114      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
115   fi
116
117   AC_SUBST(GhcVersion)dnl
118   AC_SUBST(GhcMajVersion)dnl
119   AC_SUBST(GhcMinVersion)dnl
120   AC_SUBST(GhcPatchLevel)dnl
121   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
122   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
123
124   BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
125   dnl ToDo, once "ld command" is reliably available.
126   dnl Then, we can remove the LD_STAGE0 hack in mk/build-package-date.mk
127   dnl BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
128   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
129   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
130   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
131 fi
132
133 dnl ** Must have GHC to build GHC
134 if test "$WithGhc" = ""
135 then
136     AC_MSG_ERROR([GHC is required.])
137 fi
138 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.8],
139     [AC_MSG_ERROR([GHC version 7.8 or later is required to compile GHC.])])
140
141 if test `expr $GhcMinVersion % 2` = "1"
142 then
143     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
144     then
145         AC_MSG_ERROR([
146      $WithGhc is a development snapshot of GHC, version $GhcVersion.
147      Bootstrapping using this version of GHC is not supported, and may not
148      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
149      or --with-ghc to specify a different GHC to use.])
150     fi
151 fi
152
153 GHC_PACKAGE_DB_FLAG=package-db
154 AC_SUBST(GHC_PACKAGE_DB_FLAG)
155
156 # GHC 7.7+ needs -fcmm-sink when compiling Parser.hs. See #8182
157 FP_COMPARE_VERSIONS([$GhcVersion],[-gt],[7.7],
158                     CMM_SINK_BOOTSTRAP_IS_NEEDED=YES,
159                     CMM_SINK_BOOTSTRAP_IS_NEEDED=NO)
160 AC_SUBST(CMM_SINK_BOOTSTRAP_IS_NEEDED)
161
162 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.9],
163                     SUPPORTS_COMPONENT_ID=NO,
164                     SUPPORTS_COMPONENT_ID=YES)
165 AC_SUBST(SUPPORTS_COMPONENT_ID)
166
167 # GHC is passed to Cabal, so we need a native path
168 if test "${WithGhc}" != ""
169 then
170     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
171
172     if test "$ghc_host_os" = "mingw32"
173     then
174         if test "${OSTYPE}" = "msys"
175         then
176             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
177         else
178             # Canonicalise to <drive>:/path/to/ghc
179             WithGhc=`cygpath -m "${WithGhc}"`
180         fi
181         echo "GHC path canonicalised to: ${WithGhc}"
182     fi
183 fi
184 AC_SUBST([WithGhc])
185
186 dnl ** Without optimization some INLINE trickery fails for GHCi
187 SRC_CC_OPTS="-O"
188
189 dnl--------------------------------------------------------------------
190 dnl * Choose host(/target/build) platform
191 dnl--------------------------------------------------------------------
192 dnl If we aren't explicitly told what values to use with configure flags,
193 dnl we ask the bootstrapping compiler what platform it is for
194
195 if test "${WithGhc}" != ""
196 then
197         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
198         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
199         if test "$bootstrap_host" != "$bootstrap_target"
200         then
201                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
202         fi
203 fi
204
205 # We have to run these unconditionally, but we may discard their
206 # results in the following code
207 AC_CANONICAL_BUILD
208 AC_CANONICAL_HOST
209 AC_CANONICAL_TARGET
210
211 FPTOOLS_SET_PLATFORM_VARS
212
213 # Verify that the installed (bootstrap) GHC is capable of generating
214 # code for the requested build platform.
215 if test "$BuildPlatform" != "$bootstrap_target"
216 then
217     echo "This GHC (${WithGhc}) does not generate code for the build platform"
218     echo "   GHC target platform    : $bootstrap_target"
219     echo "   Desired build platform : $BuildPlatform"
220     exit 1
221 fi
222
223 # Testing if we shall enable shared libs support on Solaris.
224 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
225
226 SOLARIS_BROKEN_SHLD=NO
227
228 case $host in
229      i386-*-solaris2)
230      # here we go with the test
231      MINOR=`uname -r|cut -d '.' -f 2-`
232      if test "$MINOR" -lt "11"; then
233          SOLARIS_BROKEN_SHLD=YES
234      fi
235      ;;
236 esac
237
238 AC_SUBST(SOLARIS_BROKEN_SHLD)
239
240 dnl ** Do an unregisterised build?
241 dnl --------------------------------------------------------------
242 case "$HostArch" in
243     i386|x86_64|powerpc|powerpc64|powerpc64le|arm)
244         UnregisterisedDefault=NO
245         ;;
246     *)
247         UnregisterisedDefault=YES
248         ;;
249 esac
250 AC_ARG_ENABLE(unregisterised,
251 [AC_HELP_STRING([--enable-unregisterised],
252 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
253 [ if test x"$enableval" = x"yes"; then
254         Unregisterised=YES
255   else
256         Unregisterised=NO
257   fi
258 ],
259 [Unregisterised="$UnregisterisedDefault"]
260 )
261 AC_SUBST(Unregisterised)
262
263 AC_ARG_WITH(hc,
264 [AC_HELP_STRING([--with-hc=ARG],
265         [Use ARG as the path to the compiler for compiling ordinary
266          Haskell code  (default= value of --with-ghc)])],
267 [WithHc="$withval"],
268 [WithHc=$WithGhc]
269 )
270 AC_SUBST(WithHc)
271
272 # This uses GHC, so put it after the "GHC is required" check above:
273 FP_INTREE_GHC_PWD
274 FP_FIND_ROOT
275
276 fail() {
277     echo >&2
278     echo "$1" >&2
279     exit 1
280 }
281
282
283 if test "$HostOS" = "mingw32"
284 then
285     # Find the mingw-w64 7z file to extract.
286     # NB. If you update the tarballs to a new version of gcc, don't
287     # forget to tweak the paths in driver/gcc/gcc.c.
288     if test "$HostArch" = "i386"
289     then
290         mingw_arch="i686"
291         tarball_dest_dir="mingw-w64/x86"
292         tarball_mingw_dir="mingw32"
293     else
294         mingw_arch="x86_64"
295         tarball_dest_dir="mingw-w64/x86_64"
296         tarball_mingw_dir="mingw64"
297     fi
298 fi
299
300 set_up_tarballs() {
301     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
302     local action
303     if test "$TarballsAutodownload" = "NO"
304     then
305         action="verify"
306     else
307         action="download"
308     fi
309     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
310     case $? in
311         0)
312            rm missing-win32-tarballs
313            ;;
314         2)
315            echo
316            echo "Error:"
317            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
318            echo
319            echo "  * run configure with the --enable-tarballs-autodownload option"
320            echo
321            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
322            echo
323            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
324            echo "    them in the ghc-tarballs directory."
325            echo
326            exit 1
327            ;;
328         *)
329            echo
330            echo "Error fetching msys2 tarballs; see errors above."
331            exit 1
332            ;;
333     esac
334
335     # Extract all the tarballs in one go
336     if ! test -d inplace/mingw
337     then
338         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
339         rm -rf inplace/mingw
340         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
341         ( cd inplace &&
342         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
343         rm ".MTREE" &&
344         rm ".PKGINFO" &&
345         cd .. ) || fail "Error: Could not extract Windows toolchains."
346
347         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
348         touch inplace/mingw
349
350         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
351         # make a wrapper around it to give it the proper paths
352         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
353         PATH=`pwd`/inplace/mingw/bin:$PATH
354         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
355
356         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
357     fi
358 }
359
360 if test "$HostOS" = "mingw32"
361 then
362     test -d inplace || mkdir inplace
363
364     # NB. Download and extract the MingW-w64 distribution if required
365     set_up_tarballs
366
367     mingwbin="$hardtop/inplace/mingw/bin/"
368     CC="${mingwbin}gcc.exe"
369     LD="${mingwbin}ld.exe"
370     NM="${mingwbin}nm.exe"
371     RANLIB="${mingwbin}ranlib.exe"
372     OBJDUMP="${mingwbin}objdump.exe"
373     fp_prog_ar="${mingwbin}ar.exe"
374
375     # NB. Download the perl binaries if required
376     if ! test -d inplace/perl ||
377          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
378     then
379         AC_MSG_NOTICE([Making in-tree perl tree])
380         rm -rf inplace/perl
381         mkdir inplace/perl
382         (
383             cd inplace/perl &&
384             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
385         )
386         AC_MSG_NOTICE([In-tree perl tree created])
387     fi
388 fi
389
390 FP_ICONV
391 FP_GMP
392 FP_CURSES
393
394 XCODE_VERSION()
395
396 SplitObjsBroken=NO
397 if test "$TargetOS_CPP" = "darwin"
398 then
399     # Split objects is broken (#4013) with XCode < 3.2
400     if test "$XCodeVersion1" -lt 3
401     then
402         SplitObjsBroken=YES
403     else
404         if test "$XCodeVersion1" -eq 3
405         then
406             if test "$XCodeVersion2" -lt 2
407             then
408                 SplitObjsBroken=YES
409             fi
410         fi
411     fi
412 fi
413 AC_SUBST([SplitObjsBroken])
414
415 dnl ** Building a cross compiler?
416 dnl --------------------------------------------------------------
417 CrossCompiling=NO
418 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
419 if test "$target" != "$host" ; then
420     CrossCompiling=YES
421     cross_compiling=yes   # This tells configure that it can accept just 'target',
422                           # otherwise you get
423                           #   configure: error: cannot run C compiled programs.
424                           #   If you meant to cross compile, use `--host'.
425 fi
426 if test "$build" != "$host" ; then
427    AC_MSG_ERROR([
428 You've selected:
429
430   BUILD:  $build   (the architecture we're building on)
431   HOST:   $host    (the architecture the compiler we're building will execute on)
432   TARGET: $target  (the architecture the compiler we're building will produce code for)
433
434 BUILD must equal HOST; that is, we do not support building GHC itself
435 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
436 1 will be a cross-compiler, and stage 2 will be the cross-compiled
437 GHC.
438 ])
439 fi
440 if test "$CrossCompiling" = "YES"
441 then
442   CrossCompilePrefix="${target}-"
443 else
444   CrossCompilePrefix=""
445 fi
446 TargetPlatformFull="${target}"
447 AC_SUBST(CrossCompiling)
448 AC_SUBST(CrossCompilePrefix)
449 AC_SUBST(TargetPlatformFull)
450
451 dnl ** Which gcc to use?
452 dnl --------------------------------------------------------------
453 FIND_GCC([WhatGccIsCalled], [gcc], [gcc])
454 CC="$WhatGccIsCalled"
455 export CC
456
457 # If --with-gcc was used, and we're not cross-compiling, then it also
458 # applies to the stage0 compiler.
459 MAYBE_OVERRIDE_STAGE0([gcc],[CC_STAGE0])
460 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
461
462 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
463 AC_PROG_CPP
464
465 # --with-hs-cpp/--with-hs-cpp-flags
466 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
467 AC_SUBST([HaskellCPPCmd])
468 AC_SUBST([HaskellCPPArgs])
469
470 dnl ** Which ld to use?
471 dnl --------------------------------------------------------------
472 FIND_LD([LdCmd])
473 AC_SUBST([LdCmd])
474
475 dnl ** Which nm to use?
476 dnl --------------------------------------------------------------
477 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
478 NmCmd="$NM"
479 AC_SUBST([NmCmd])
480
481 dnl ** Which objdump to use?
482 dnl --------------------------------------------------------------
483 FP_ARG_WITH_PATH_GNU_PROG_OPTIONAL([OBJDUMP], [objdump], [objdump])
484 ObjdumpCmd="$OBJDUMP"
485 AC_SUBST([ObjdumpCmd])
486
487 dnl ** Which ar to use?
488 dnl --------------------------------------------------------------
489 FP_ARG_WITH_PATH_GNU_PROG([AR], [ar], [ar])
490 ArCmd="$AR"
491 fp_prog_ar="$AR"
492 AC_SUBST([ArCmd])
493
494 dnl ** Which ranlib to use?
495 dnl --------------------------------------------------------------
496 FP_ARG_WITH_PATH_GNU_PROG([RANLIB], [ranlib], [ranlib])
497 RanlibCmd="$RANLIB"
498 RANLIB="$RanlibCmd"
499
500
501 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
502 case $HostOS_CPP in
503 cygwin32|mingw32)
504     dnl ** Which objdump to use?
505     dnl --------------------------------------------------------------
506     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
507     ObjdumpCmd="$OBJDUMP"
508     AC_SUBST([ObjdumpCmd])
509     ;;
510 esac
511
512 # Here is where we re-target which specific version of the LLVM
513 # tools we are looking for. In the past, GHC supported a number of
514 # versions of LLVM simultaneously, but that stopped working around
515 # 3.5/3.6 release of LLVM.
516 LlvmVersion=3.7
517 AC_SUBST([LlvmVersion])
518 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
519 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
520
521 dnl ** Which LLVM llc to use?
522 dnl --------------------------------------------------------------
523 FIND_LLVM_PROG([LLC], [llc], [llc], [$LlvmVersion])
524 LlcCmd="$LLC"
525 AC_SUBST([LlcCmd])
526
527 dnl ** Which LLVM opt to use?
528 dnl --------------------------------------------------------------
529 FIND_LLVM_PROG([OPT], [opt], [opt], [$LlvmVersion])
530 OptCmd="$OPT"
531 AC_SUBST([OptCmd])
532
533 dnl --------------------------------------------------------------
534 dnl End of configure script option section
535 dnl --------------------------------------------------------------
536
537
538 dnl --------------------------------------------------------------
539 dnl * General configuration checks
540 dnl --------------------------------------------------------------
541
542 dnl ** Bug 9439: Some GHC 7.8 releases had broken LLVM code generator.
543 dnl Unfortunately we don't know whether the user is going to request a
544 dnl build with the LLVM backend as this is only given in build.mk.
545 dnl
546 dnl Instead, we try to do as much work as possible here, checking
547 dnl whether -fllvm is the stage 0 compiler's default. If so we
548 dnl fail. If not, we check whether -fllvm is affected explicitly and
549 dnl if so set a flag. The build system will later check this flag
550 dnl after the desired build flags are known.
551
552 dnl This problem is further complicated by the fact that the llvm
553 dnl version used by the bootstrap compiler may be different from the
554 dnl version we arre trying to compile GHC against. Therefore, we need
555 dnl to find the boostrap compiler's `settings` file then check to see
556 dnl if the `opt` and `llc` command strings are non-empty and if these
557 dnl programs exist. Only if they exist to we test for bug #9439.
558
559 FIND_GHC_BOOTSTRAP_PROG([BootstrapLlcCmd], [${WithGhc}], "LLVM llc command")
560 FIND_GHC_BOOTSTRAP_PROG([BootstrapOptCmd], [${WithGhc}], "LLVM opt command")
561
562 if test -n "$BootstrapLlcCmd" && test -n "$BootstrapOptCmd"
563 then
564     AC_MSG_CHECKING(whether bootstrap compiler is affected by bug 9439)
565     echo "main = putStrLn \"%function\"" > conftestghc.hs
566
567     # Check whether LLVM backend is default for this platform
568     "${WithGhc}" -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" conftestghc.hs 2>&1 >/dev/null
569     res=`./conftestghc`
570     if test "x$res" = "x%object"
571     then
572         AC_MSG_RESULT(yes)
573         echo "Buggy bootstrap compiler"
574         echo ""
575         echo "The stage 0 compiler $WithGhc is affected by GHC Bug \#9439"
576         echo "and therefore will miscompile the LLVM backend if -fllvm is"
577         echo "used."
578         echo
579         echo "Please use another bootstrap compiler"
580         exit 1
581     fi
582
583     # -fllvm is not the default, but set a flag so the Makefile can check
584     # -for it in the build flags later on
585     "${WithGhc}" -fforce-recomp -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" -fllvm conftestghc.hs 2>&1 >/dev/null
586     if test $? = 0
587     then
588         res=`./conftestghc`
589         if test "x$res" = "x%object"
590         then
591             AC_MSG_RESULT(yes)
592             GHC_LLVM_AFFECTED_BY_9439=1
593         elif test "x$res" = "x%function"
594         then
595             AC_MSG_RESULT(no)
596             GHC_LLVM_AFFECTED_BY_9439=0
597         else
598             AC_MSG_WARN(unexpected output $res)
599         fi
600     else
601         AC_MSG_RESULT(failed to compile, assuming no)
602     fi
603 fi
604 AC_SUBST([GHC_LLVM_AFFECTED_BY_9439])
605
606 dnl ** Can the unix package be built?
607 dnl --------------------------------------------------------------
608
609 if test "$TargetOS" = "mingw32"
610 then
611     GhcLibsWithUnix=NO
612 else
613     GhcLibsWithUnix=YES
614 fi
615 AC_SUBST([GhcLibsWithUnix])
616
617 dnl ** does #! work?
618 AC_SYS_INTERPRETER()
619
620 dnl ** look for `perl'
621 case $HostOS_CPP in
622 cygwin32|mingw32)
623     PerlCmd=$hardtop/inplace/perl/perl
624     ;;
625 *)
626     AC_PATH_PROG(PerlCmd,perl)
627     if test -z "$PerlCmd"
628     then
629         echo "You must install perl before you can continue"
630         echo "Perhaps it is already installed, but not in your PATH?"
631         exit 1
632     else
633         FPTOOLS_CHECK_PERL_VERSION
634     fi
635     ;;
636 esac
637
638 dnl ** look for GCC and find out which version
639 dnl     Figure out which C compiler to use.  Gcc is preferred.
640 dnl     If gcc, make sure it's at least 3.0
641 dnl
642 FP_GCC_VERSION
643
644 dnl ** look to see if we have a C compiler using an llvm back end.
645 dnl
646 FP_CC_LLVM_BACKEND
647
648 FP_PROG_LD_IS_GNU
649 FP_PROG_LD_BUILD_ID
650 FP_PROG_LD_NO_COMPACT_UNWIND
651 FP_PROG_LD_FILELIST
652
653
654 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
655 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
656 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
657 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
658 # Stage 3 won't be supported by cross-compilation
659
660 FP_GCC_EXTRA_FLAGS
661
662 AC_SUBST(CONF_CC_OPTS_STAGE0)
663 AC_SUBST(CONF_CC_OPTS_STAGE1)
664 AC_SUBST(CONF_CC_OPTS_STAGE2)
665 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
666 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
667 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
668 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
669 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
670 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
671 AC_SUBST(CONF_CPP_OPTS_STAGE0)
672 AC_SUBST(CONF_CPP_OPTS_STAGE1)
673 AC_SUBST(CONF_CPP_OPTS_STAGE2)
674
675 dnl ** Set up the variables for the platform in the settings file.
676 dnl May need to use gcc to find platform details.
677 dnl --------------------------------------------------------------
678 FPTOOLS_SET_HASKELL_PLATFORM_VARS
679
680 dnl ** figure out how to do context diffs
681 FP_PROG_CONTEXT_DIFF
682
683 dnl Let's make sure install-sh is executable here.  If we got it from
684 dnl a darcs repo, it might not be (see bug #978).
685 chmod +x install-sh
686 dnl ** figure out how to do a BSD-ish install
687 AC_PROG_INSTALL
688
689 dnl ** how to invoke `ar' and `ranlib'
690 FP_PROG_AR_SUPPORTS_ATFILE
691 FP_PROG_AR_NEEDS_RANLIB
692
693 dnl ** Check to see whether ln -s works
694 AC_PROG_LN_S
695
696 FP_SETTINGS
697
698 dnl ** Find the path to sed
699 AC_PATH_PROGS(SedCmd,gsed sed,sed)
700
701
702 dnl ** check for time command
703 AC_PATH_PROG(TimeCmd,time)
704
705 dnl ** check for tar
706 dnl   if GNU tar is named gtar, look for it first.
707 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
708
709 dnl ** check for patch
710 dnl if GNU patch is named gpatch, look for it first
711 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
712
713 dnl ** check for dtrace (currently only implemented for Mac OS X)
714 HaveDtrace=NO
715 AC_PATH_PROG(DtraceCmd,dtrace)
716 if test -n "$DtraceCmd"; then
717   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
718     HaveDtrace=YES
719   fi
720 fi
721 AC_SUBST(HaveDtrace)
722
723 AC_PATH_PROG(HSCOLOUR,HsColour)
724 # HsColour is passed to Cabal, so we need a native path
725 if test "$HostOS"      = "mingw32" && \
726    test "${OSTYPE}"   != "msys"    && \
727    test "${HSCOLOUR}" != ""
728 then
729     # Canonicalise to <drive>:/path/to/gcc
730     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
731 fi
732
733 dnl ** check for Sphinx toolchain
734 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
735 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
736 changequote(, )dnl
737 [if test -n "$SPHINXBUILD"; then
738   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
739 fi;
740 changequote([, ])dnl
741 ])
742 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
743     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
744
745 dnl ** check for xelatex
746 AC_PATH_PROG(XELATEX,xelatex)
747
748 dnl ** check for ghc-pkg command
749 FP_PROG_GHC_PKG
750
751 dnl ** check for installed happy binary + version
752 FPTOOLS_HAPPY
753
754 dnl ** check for installed alex binary + version
755 FPTOOLS_ALEX
756
757 dnl --------------------------------------------------
758 dnl ### program checking section ends here ###
759 dnl --------------------------------------------------
760
761 dnl --------------------------------------------------
762 dnl * Platform header file and syscall feature tests
763 dnl ### checking the state of the local header files and syscalls ###
764
765 dnl ** check for full ANSI header (.h) files
766 AC_HEADER_STDC
767
768 dnl ** Enable large file support.  NB. do this before testing the type of
769 dnl    off_t, because it will affect the result of that test.
770 AC_SYS_LARGEFILE
771
772 dnl ** check for specific header (.h) files that we are interested in
773 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
774
775 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
776 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
777 [[#if HAVE_SYS_PARAM_H
778 # include <sys/param.h>
779 #endif
780 ]])
781
782 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
783 AC_HEADER_TIME
784
785 dnl ** do we have long longs?
786 AC_CHECK_TYPES([long long])
787
788 dnl ** what are the sizes of various types
789 AC_CHECK_SIZEOF(char,               1)
790 AC_CHECK_SIZEOF(double,             8)
791 AC_CHECK_SIZEOF(float,              4)
792 AC_CHECK_SIZEOF(int,                4)
793 AC_CHECK_SIZEOF(long,               4)
794 if test "$ac_cv_type_long_long" = yes; then
795 AC_CHECK_SIZEOF(long long,          8)
796 fi
797 AC_CHECK_SIZEOF(short,              2)
798 AC_CHECK_SIZEOF(unsigned char,      1)
799 AC_CHECK_SIZEOF(unsigned int,       4)
800 AC_CHECK_SIZEOF(unsigned long,      4)
801 if test "$ac_cv_type_long_long" = yes; then
802 AC_CHECK_SIZEOF(unsigned long long, 8)
803 fi
804 AC_CHECK_SIZEOF(unsigned short,     2)
805 AC_CHECK_SIZEOF(void *,             4)
806
807 dnl for use in settings.in
808 WordSize=$ac_cv_sizeof_void_p
809 AC_SUBST(WordSize)
810
811 dnl ** what are alignment constraints on various types
812 FP_CHECK_ALIGNMENT(char)
813 FP_CHECK_ALIGNMENT(double)
814 FP_CHECK_ALIGNMENT(float)
815 FP_CHECK_ALIGNMENT(int)
816 FP_CHECK_ALIGNMENT(long)
817 if test "$ac_cv_type_long_long" = yes; then
818 FP_CHECK_ALIGNMENT(long long)
819 fi
820 FP_CHECK_ALIGNMENT(short)
821 FP_CHECK_ALIGNMENT(unsigned char)
822 FP_CHECK_ALIGNMENT(unsigned int)
823 FP_CHECK_ALIGNMENT(unsigned long)
824 if test "$ac_cv_type_long_long" = yes; then
825 FP_CHECK_ALIGNMENT(unsigned long long)
826 fi
827 FP_CHECK_ALIGNMENT(unsigned short)
828 FP_CHECK_ALIGNMENT(void *)
829
830 FP_CHECK_FUNC([WinExec],
831   [@%:@include <windows.h>], [WinExec("",0)])
832
833 FP_CHECK_FUNC([GetModuleFileName],
834   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
835
836 dnl ** check for more functions
837 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
838 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
839
840 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
841 dnl ** _POSIX_C_SOURCE is defined
842 AC_CHECK_DECLS([ctime_r], , ,
843 [#define _POSIX_SOURCE 1
844 #define _POSIX_C_SOURCE 199506L
845 #include <time.h>])
846
847 dnl ** check for mingwex library
848 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
849 AC_SUBST(HaveLibMingwEx)
850
851 if test $HaveLibMingwEx = YES ; then
852   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
853 fi
854
855 dnl ** check for math library
856 dnl    Keep that check as early as possible.
857 dnl    as we need to know whether we need libm
858 dnl    for math functions or not
859 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
860 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
861 if test $HaveLibM = YES
862 then
863   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
864 fi
865
866 FP_BFD_SUPPORT
867
868 dnl ################################################################
869 dnl Check for libraries
870 dnl ################################################################
871
872 # system libffi
873
874 AC_ARG_WITH([system-libffi],
875 [AC_HELP_STRING([--with-system-libffi],
876   [Use system provided libffi for RTS [default=no]])
877 ])
878
879 AS_IF([test "x$with_system_libffi" = "xyes"],
880   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
881 )
882
883
884 AC_SUBST(UseSystemLibFFI)
885
886 AC_ARG_WITH([ffi-includes],
887 [AC_HELP_STRING([--with-ffi-includes=ARG],
888   [Find includes for libffi in ARG [default=system default]])
889 ],
890 [
891  if test "x$UseSystemLibFFI" != "xYES"; then
892     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
893  else
894     FFIIncludeDir="$withval"
895     LIBFFI_CFLAGS="-I$withval"
896  fi
897 ])
898
899 AC_SUBST(FFIIncludeDir)
900
901 AC_ARG_WITH([ffi-libraries],
902 [AC_HELP_STRING([--with-ffi-libraries=ARG],
903   [Find libffi in ARG [default=system default]])
904 ],
905 [
906  if test "x$UseSystemLibFFI" != "xYES"; then
907     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
908  else
909     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
910  fi
911 ])
912
913 AC_SUBST(FFILibDir)
914
915 AS_IF([test "$UseSystemLibFFI" = "YES"], [
916  CFLAGS2="$CFLAGS"
917  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
918  LDFLAGS2="$LDFLAGS"
919  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
920  if test "$HostOS" = "openbsd";
921  then
922    # OpenBSD's libffi is not directly linked to the libpthread but
923    # still requires pthread functionality. This means that any client
924    # binary which links with libffi also needs to link with
925    # libpthread. If it does not, then linking fails with unresolved
926    # symbols.
927    LDFLAGS="$LDFLAGS -lpthread"
928  fi
929  AC_CHECK_LIB(ffi, ffi_call,
930   [AC_CHECK_HEADERS([ffi.h], [break], [])
931    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
932   [AC_MSG_ERROR([Cannot find system libffi])])
933  CFLAGS="$CFLAGS2"
934  LDFLAGS="$LDFLAGS2"
935 ])
936
937 dnl ** check whether we need -ldl to get dlopen()
938 AC_CHECK_LIB(dl, dlopen)
939
940 dnl --------------------------------------------------
941 dnl * Miscellaneous feature tests
942 dnl --------------------------------------------------
943
944 dnl ** can we get alloca?
945 AC_FUNC_ALLOCA
946
947 dnl ** working vfork?
948 AC_FUNC_FORK
949
950 dnl ** determine whether or not const works
951 AC_C_CONST
952
953 dnl ** are we big endian?
954 AC_C_BIGENDIAN
955 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
956
957 dnl ** check for leading underscores in symbol names
958 FP_LEADING_UNDERSCORE
959
960 FP_VISIBILITY_HIDDEN
961
962 dnl ** check for librt
963 AC_CHECK_LIB(rt, clock_gettime)
964 AC_CHECK_FUNCS(clock_gettime timer_settime)
965 FP_CHECK_TIMER_CREATE
966
967 dnl ** check for Apple's "interesting" long double compatibility scheme
968 AC_MSG_CHECKING(for printf\$LDBLStub)
969 AC_TRY_LINK_FUNC(printf\$LDBLStub,
970     [
971         AC_MSG_RESULT(yes)
972         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
973             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
974     ],
975     [
976         AC_MSG_RESULT(no)
977         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
978             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
979     ])
980
981 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
982 dnl    a different single-argument version.
983 AC_CHECK_LIB(pthread, pthread_setname_np)
984 AC_MSG_CHECKING(for pthread_setname_np)
985 AC_TRY_LINK(
986 [
987 #define _GNU_SOURCE
988 #include <pthread.h>
989 ],
990 [pthread_setname_np(pthread_self(), "name");],
991     AC_MSG_RESULT(yes)
992     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
993       [Define to 1 if you have the glibc version of pthread_setname_np]),
994     AC_MSG_RESULT(no)
995 )
996
997 dnl ** check for eventfd which is needed by the I/O manager
998 AC_CHECK_HEADERS([sys/eventfd.h])
999 AC_CHECK_FUNCS([eventfd])
1000
1001 dnl ** Check for __thread support in the compiler
1002 AC_MSG_CHECKING(for __thread support)
1003 AC_COMPILE_IFELSE(
1004   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
1005   [
1006    AC_MSG_RESULT(yes)
1007    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1008   ],
1009   [
1010    AC_MSG_RESULT(no)
1011    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1012   ])
1013
1014
1015 AC_CHECK_FUNCS(__mingw_vfprintf)
1016
1017 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
1018    HavePapi=YES
1019 else
1020    HavePapi=NO
1021 fi
1022 AC_SUBST(HavePapi)
1023
1024 dnl large address space support (see includes/rts/storage/MBlock.h)
1025 dnl
1026 dnl Darwin has vm_allocate/vm_protect
1027 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1028 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1029 dnl (They also have MADV_DONTNEED, but it means something else!)
1030 dnl
1031 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1032 dnl it counts page-table space as committed memory, and so quickly
1033 dnl runs out of paging file when we have multiple processes reserving
1034 dnl 1TB of address space, we get the following error:
1035 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1036 dnl
1037
1038 AC_ARG_ENABLE(large-address-space,
1039     [AC_HELP_STRING([--enable-large-address-space],
1040         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1041     EnableLargeAddressSpace=$enableval,
1042     EnableLargeAddressSpace=yes
1043 )
1044
1045 use_large_address_space=no
1046 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1047     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1048         if test "$ghc_host_os" = "darwin" ; then
1049             use_large_address_space=yes
1050         elif test "$ghc_host_os" = "openbsd" ; then
1051             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1052             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1053             # but is completely ignored by OS mmap
1054             use_large_address_space=no
1055         else
1056             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1057                 [
1058                 #include <unistd.h>
1059                 #include <sys/types.h>
1060                 #include <sys/mman.h>
1061                 #include <fcntl.h>
1062             ])
1063             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1064                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1065                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1066                     use_large_address_space=yes
1067             fi
1068         fi
1069     fi
1070 fi
1071 if test "$use_large_address_space" = "yes" ; then
1072    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1073 fi
1074
1075 AC_CHECK_LIB(dw, dwfl_begin, [HaveLibdw=YES], [HaveLibdw=NO])
1076 AC_SUBST(HaveLibdw)
1077
1078 if test -n "$SPHINXBUILD"; then
1079     BUILD_MAN=YES
1080     BUILD_SPHINX_HTML=YES
1081     if test -n "$XELATEX"; then
1082         BUILD_SPHINX_PDF=YES
1083     else
1084         BUILD_SPHINX_PDF=NO
1085     fi
1086 else
1087     BUILD_MAN=NO
1088     BUILD_SPHINX_HTML=NO
1089     BUILD_SPHINX_PDF=NO
1090 fi
1091 AC_SUBST(BUILD_MAN)
1092 AC_SUBST(BUILD_SPHINX_HTML)
1093 AC_SUBST(BUILD_SPHINX_PDF)
1094
1095 LIBRARY_VERSION(base)
1096 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1097 LIBRARY_VERSION(ghc-prim)
1098 LIBRARY_ghc_VERSION="$ProjectVersion"
1099 AC_SUBST(LIBRARY_ghc_VERSION)
1100
1101 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1102    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1103 fi
1104
1105 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt distrib/configure.ac])
1106 AC_OUTPUT
1107
1108 # We got caught by
1109 #     http://savannah.gnu.org/bugs/index.php?1516
1110 #     $(eval ...) inside conditionals causes errors
1111 # with make 3.80, so warn the user if it looks like they're about to
1112 # try to use it.
1113 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1114 checkMake380() {
1115     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
1116     then
1117         echo
1118         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
1119         echo "This version cannot be used to build GHC."
1120         echo "Please use GNU make >= 3.81."
1121     fi
1122 }
1123
1124 checkMake380 make
1125 checkMake380 gmake
1126
1127 echo ["
1128 ----------------------------------------------------------------------
1129 Configure completed successfully.
1130
1131    Building GHC version  : $ProjectVersion
1132           Git commit id  : $ProjectGitCommitId
1133
1134    Build platform        : $BuildPlatform
1135    Host platform         : $HostPlatform
1136    Target platform       : $TargetPlatform
1137 "]
1138
1139 echo ["\
1140    Bootstrapping using   : $WithGhc
1141       which is version   : $GhcVersion
1142 "]
1143
1144 if test "x$CC_LLVM_BACKEND" = "x1"; then
1145     if test "x$CC_CLANG_BACKEND" = "x1"; then
1146         CompilerName="clang        "
1147     else
1148         CompilerName="llvm-gcc     "
1149     fi
1150 else
1151     CompilerName="gcc          "
1152 fi
1153
1154 echo ["\
1155    Using $CompilerName       : $WhatGccIsCalled
1156       which is version       : $GccVersion
1157    Building a cross compiler : $CrossCompiling
1158    hs-cpp       : $HaskellCPPCmd
1159    hs-cpp-flags : $HaskellCPPArgs
1160    ld           : $LdCmd
1161    nm           : $NmCmd
1162    objdump      : $ObjdumpCmd
1163    Happy        : $HappyCmd ($HappyVersion)
1164    Alex         : $AlexCmd ($AlexVersion)
1165    Perl         : $PerlCmd
1166    sphinx-build : $SPHINXBUILD
1167    xelatex      : $XELATEX
1168
1169    Using LLVM tools
1170       llc   : $LlcCmd
1171       opt   : $OptCmd"]
1172
1173 if test "$HSCOLOUR" = ""; then
1174 echo ["
1175    HsColour was not found; documentation will not contain source links
1176 "]
1177 else
1178 echo ["\
1179    HsColour : $HSCOLOUR
1180 "]
1181 fi
1182
1183 echo ["\
1184    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1185    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"]
1186
1187 echo ["----------------------------------------------------------------------
1188 "]
1189
1190 echo "\
1191 For a standard build of GHC (fully optimised with profiling), type (g)make.
1192
1193 To make changes to the default build configuration, copy the file
1194 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1195
1196 For more information on how to configure your GHC build, see
1197    http://ghc.haskell.org/trac/ghc/wiki/Building
1198 "