Update Trac ticket URLs to point to GitLab
[ghc.git] / compiler / typecheck / Inst.hs
1 {-
2 (c) The University of Glasgow 2006
3 (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
4
5
6 The @Inst@ type: dictionaries or method instances
7 -}
8
9 {-# LANGUAGE CPP, MultiWayIf, TupleSections #-}
10 {-# LANGUAGE FlexibleContexts #-}
11
12 module Inst (
13 deeplySkolemise,
14 topInstantiate, topInstantiateInferred, deeplyInstantiate,
15 instCall, instDFunType, instStupidTheta, instTyVarsWith,
16 newWanted, newWanteds,
17
18 tcInstInvisibleTyBinders, tcInstInvisibleTyBinder,
19
20 newOverloadedLit, mkOverLit,
21
22 newClsInst,
23 tcGetInsts, tcGetInstEnvs, getOverlapFlag,
24 tcExtendLocalInstEnv,
25 instCallConstraints, newMethodFromName,
26 tcSyntaxName,
27
28 -- Simple functions over evidence variables
29 tyCoVarsOfWC,
30 tyCoVarsOfCt, tyCoVarsOfCts,
31 ) where
32
33 #include "HsVersions.h"
34
35 import GhcPrelude
36
37 import {-# SOURCE #-} TcExpr( tcPolyExpr, tcSyntaxOp )
38 import {-# SOURCE #-} TcUnify( unifyType, unifyKind )
39
40 import BasicTypes ( IntegralLit(..), SourceText(..) )
41 import FastString
42 import HsSyn
43 import TcHsSyn
44 import TcRnMonad
45 import TcEnv
46 import TcEvidence
47 import InstEnv
48 import TysWiredIn ( heqDataCon, eqDataCon )
49 import CoreSyn ( isOrphan )
50 import FunDeps
51 import TcMType
52 import Type
53 import TyCoRep
54 import TcType
55 import HscTypes
56 import Class( Class )
57 import MkId( mkDictFunId )
58 import CoreSyn( Expr(..) ) -- For the Coercion constructor
59 import Id
60 import Name
61 import Var ( EvVar, tyVarName, VarBndr(..) )
62 import DataCon
63 import VarEnv
64 import PrelNames
65 import SrcLoc
66 import DynFlags
67 import Util
68 import Outputable
69 import qualified GHC.LanguageExtensions as LangExt
70
71 import Control.Monad( unless )
72
73 {-
74 ************************************************************************
75 * *
76 Creating and emittind constraints
77 * *
78 ************************************************************************
79 -}
80
81 newMethodFromName :: CtOrigin -> Name -> TcRhoType -> TcM (HsExpr GhcTcId)
82 -- Used when Name is the wired-in name for a wired-in class method,
83 -- so the caller knows its type for sure, which should be of form
84 -- forall a. C a => <blah>
85 -- newMethodFromName is supposed to instantiate just the outer
86 -- type variable and constraint
87
88 newMethodFromName origin name inst_ty
89 = do { id <- tcLookupId name
90 -- Use tcLookupId not tcLookupGlobalId; the method is almost
91 -- always a class op, but with -XRebindableSyntax GHC is
92 -- meant to find whatever thing is in scope, and that may
93 -- be an ordinary function.
94
95 ; let ty = piResultTy (idType id) inst_ty
96 (theta, _caller_knows_this) = tcSplitPhiTy ty
97 ; wrap <- ASSERT( not (isForAllTy ty) && isSingleton theta )
98 instCall origin [inst_ty] theta
99
100 ; return (mkHsWrap wrap (HsVar noExt (noLoc id))) }
101
102 {-
103 ************************************************************************
104 * *
105 Deep instantiation and skolemisation
106 * *
107 ************************************************************************
108
109 Note [Deep skolemisation]
110 ~~~~~~~~~~~~~~~~~~~~~~~~~
111 deeplySkolemise decomposes and skolemises a type, returning a type
112 with all its arrows visible (ie not buried under foralls)
113
114 Examples:
115
116 deeplySkolemise (Int -> forall a. Ord a => blah)
117 = ( wp, [a], [d:Ord a], Int -> blah )
118 where wp = \x:Int. /\a. \(d:Ord a). <hole> x
119
120 deeplySkolemise (forall a. Ord a => Maybe a -> forall b. Eq b => blah)
121 = ( wp, [a,b], [d1:Ord a,d2:Eq b], Maybe a -> blah )
122 where wp = /\a.\(d1:Ord a).\(x:Maybe a)./\b.\(d2:Ord b). <hole> x
123
124 In general,
125 if deeplySkolemise ty = (wrap, tvs, evs, rho)
126 and e :: rho
127 then wrap e :: ty
128 and 'wrap' binds tvs, evs
129
130 ToDo: this eta-abstraction plays fast and loose with termination,
131 because it can introduce extra lambdas. Maybe add a `seq` to
132 fix this
133 -}
134
135 deeplySkolemise :: TcSigmaType
136 -> TcM ( HsWrapper
137 , [(Name,TyVar)] -- All skolemised variables
138 , [EvVar] -- All "given"s
139 , TcRhoType )
140
141 deeplySkolemise ty
142 = go init_subst ty
143 where
144 init_subst = mkEmptyTCvSubst (mkInScopeSet (tyCoVarsOfType ty))
145
146 go subst ty
147 | Just (arg_tys, tvs, theta, ty') <- tcDeepSplitSigmaTy_maybe ty
148 = do { let arg_tys' = substTys subst arg_tys
149 ; ids1 <- newSysLocalIds (fsLit "dk") arg_tys'
150 ; (subst', tvs1) <- tcInstSkolTyVarsX subst tvs
151 ; ev_vars1 <- newEvVars (substTheta subst' theta)
152 ; (wrap, tvs_prs2, ev_vars2, rho) <- go subst' ty'
153 ; let tv_prs1 = map tyVarName tvs `zip` tvs1
154 ; return ( mkWpLams ids1
155 <.> mkWpTyLams tvs1
156 <.> mkWpLams ev_vars1
157 <.> wrap
158 <.> mkWpEvVarApps ids1
159 , tv_prs1 ++ tvs_prs2
160 , ev_vars1 ++ ev_vars2
161 , mkVisFunTys arg_tys' rho ) }
162
163 | otherwise
164 = return (idHsWrapper, [], [], substTy subst ty)
165 -- substTy is a quick no-op on an empty substitution
166
167 -- | Instantiate all outer type variables
168 -- and any context. Never looks through arrows.
169 topInstantiate :: CtOrigin -> TcSigmaType -> TcM (HsWrapper, TcRhoType)
170 -- if topInstantiate ty = (wrap, rho)
171 -- and e :: ty
172 -- then wrap e :: rho (that is, wrap :: ty "->" rho)
173 topInstantiate = top_instantiate True
174
175 -- | Instantiate all outer 'Inferred' binders
176 -- and any context. Never looks through arrows or specified type variables.
177 -- Used for visible type application.
178 topInstantiateInferred :: CtOrigin -> TcSigmaType
179 -> TcM (HsWrapper, TcSigmaType)
180 -- if topInstantiate ty = (wrap, rho)
181 -- and e :: ty
182 -- then wrap e :: rho
183 topInstantiateInferred = top_instantiate False
184
185 top_instantiate :: Bool -- True <=> instantiate *all* variables
186 -- False <=> instantiate only the inferred ones
187 -> CtOrigin -> TcSigmaType -> TcM (HsWrapper, TcRhoType)
188 top_instantiate inst_all orig ty
189 | not (null binders && null theta)
190 = do { let (inst_bndrs, leave_bndrs) = span should_inst binders
191 (inst_theta, leave_theta)
192 | null leave_bndrs = (theta, [])
193 | otherwise = ([], theta)
194 in_scope = mkInScopeSet (tyCoVarsOfType ty)
195 empty_subst = mkEmptyTCvSubst in_scope
196 inst_tvs = binderVars inst_bndrs
197 ; (subst, inst_tvs') <- mapAccumLM newMetaTyVarX empty_subst inst_tvs
198 ; let inst_theta' = substTheta subst inst_theta
199 sigma' = substTy subst (mkForAllTys leave_bndrs $
200 mkPhiTy leave_theta rho)
201 inst_tv_tys' = mkTyVarTys inst_tvs'
202
203 ; wrap1 <- instCall orig inst_tv_tys' inst_theta'
204 ; traceTc "Instantiating"
205 (vcat [ text "all tyvars?" <+> ppr inst_all
206 , text "origin" <+> pprCtOrigin orig
207 , text "type" <+> debugPprType ty
208 , text "theta" <+> ppr theta
209 , text "leave_bndrs" <+> ppr leave_bndrs
210 , text "with" <+> vcat (map debugPprType inst_tv_tys')
211 , text "theta:" <+> ppr inst_theta' ])
212
213 ; (wrap2, rho2) <-
214 if null leave_bndrs
215
216 -- account for types like forall a. Num a => forall b. Ord b => ...
217 then top_instantiate inst_all orig sigma'
218
219 -- but don't loop if there were any un-inst'able tyvars
220 else return (idHsWrapper, sigma')
221
222 ; return (wrap2 <.> wrap1, rho2) }
223
224 | otherwise = return (idHsWrapper, ty)
225 where
226 (binders, phi) = tcSplitForAllVarBndrs ty
227 (theta, rho) = tcSplitPhiTy phi
228
229 should_inst bndr
230 | inst_all = True
231 | otherwise = binderArgFlag bndr == Inferred
232
233 deeplyInstantiate :: CtOrigin -> TcSigmaType -> TcM (HsWrapper, TcRhoType)
234 -- Int -> forall a. a -> a ==> (\x:Int. [] x alpha) :: Int -> alpha
235 -- In general if
236 -- if deeplyInstantiate ty = (wrap, rho)
237 -- and e :: ty
238 -- then wrap e :: rho
239 -- That is, wrap :: ty ~> rho
240 --
241 -- If you don't need the HsWrapper returned from this function, consider
242 -- using tcSplitNestedSigmaTys in TcType, which is a pure alternative that
243 -- only computes the returned TcRhoType.
244
245 deeplyInstantiate orig ty =
246 deeply_instantiate orig
247 (mkEmptyTCvSubst (mkInScopeSet (tyCoVarsOfType ty)))
248 ty
249
250 deeply_instantiate :: CtOrigin
251 -> TCvSubst
252 -> TcSigmaType -> TcM (HsWrapper, TcRhoType)
253 -- Internal function to deeply instantiate that builds on an existing subst.
254 -- It extends the input substitution and applies the final subtitution to
255 -- the types on return. See #12549.
256
257 deeply_instantiate orig subst ty
258 | Just (arg_tys, tvs, theta, rho) <- tcDeepSplitSigmaTy_maybe ty
259 = do { (subst', tvs') <- newMetaTyVarsX subst tvs
260 ; let arg_tys' = substTys subst' arg_tys
261 theta' = substTheta subst' theta
262 ; ids1 <- newSysLocalIds (fsLit "di") arg_tys'
263 ; wrap1 <- instCall orig (mkTyVarTys tvs') theta'
264 ; traceTc "Instantiating (deeply)" (vcat [ text "origin" <+> pprCtOrigin orig
265 , text "type" <+> ppr ty
266 , text "with" <+> ppr tvs'
267 , text "args:" <+> ppr ids1
268 , text "theta:" <+> ppr theta'
269 , text "subst:" <+> ppr subst'])
270 ; (wrap2, rho2) <- deeply_instantiate orig subst' rho
271 ; return (mkWpLams ids1
272 <.> wrap2
273 <.> wrap1
274 <.> mkWpEvVarApps ids1,
275 mkVisFunTys arg_tys' rho2) }
276
277 | otherwise
278 = do { let ty' = substTy subst ty
279 ; traceTc "deeply_instantiate final subst"
280 (vcat [ text "origin:" <+> pprCtOrigin orig
281 , text "type:" <+> ppr ty
282 , text "new type:" <+> ppr ty'
283 , text "subst:" <+> ppr subst ])
284 ; return (idHsWrapper, ty') }
285
286
287 instTyVarsWith :: CtOrigin -> [TyVar] -> [TcType] -> TcM TCvSubst
288 -- Use this when you want to instantiate (forall a b c. ty) with
289 -- types [ta, tb, tc], but when the kinds of 'a' and 'ta' might
290 -- not yet match (perhaps because there are unsolved constraints; #14154)
291 -- If they don't match, emit a kind-equality to promise that they will
292 -- eventually do so, and thus make a kind-homongeneous substitution.
293 instTyVarsWith orig tvs tys
294 = go empty_subst tvs tys
295 where
296 empty_subst = mkEmptyTCvSubst (mkInScopeSet (tyCoVarsOfTypes tys))
297
298 go subst [] []
299 = return subst
300 go subst (tv:tvs) (ty:tys)
301 | tv_kind `tcEqType` ty_kind
302 = go (extendTCvSubst subst tv ty) tvs tys
303 | otherwise
304 = do { co <- emitWantedEq orig KindLevel Nominal ty_kind tv_kind
305 ; go (extendTCvSubst subst tv (ty `mkCastTy` co)) tvs tys }
306 where
307 tv_kind = substTy subst (tyVarKind tv)
308 ty_kind = tcTypeKind ty
309
310 go _ _ _ = pprPanic "instTysWith" (ppr tvs $$ ppr tys)
311
312 {-
313 ************************************************************************
314 * *
315 Instantiating a call
316 * *
317 ************************************************************************
318
319 Note [Handling boxed equality]
320 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
321 The solver deals entirely in terms of unboxed (primitive) equality.
322 There should never be a boxed Wanted equality. Ever. But, what if
323 we are calling `foo :: forall a. (F a ~ Bool) => ...`? That equality
324 is boxed, so naive treatment here would emit a boxed Wanted equality.
325
326 So we simply check for this case and make the right boxing of evidence.
327
328 -}
329
330 ----------------
331 instCall :: CtOrigin -> [TcType] -> TcThetaType -> TcM HsWrapper
332 -- Instantiate the constraints of a call
333 -- (instCall o tys theta)
334 -- (a) Makes fresh dictionaries as necessary for the constraints (theta)
335 -- (b) Throws these dictionaries into the LIE
336 -- (c) Returns an HsWrapper ([.] tys dicts)
337
338 instCall orig tys theta
339 = do { dict_app <- instCallConstraints orig theta
340 ; return (dict_app <.> mkWpTyApps tys) }
341
342 ----------------
343 instCallConstraints :: CtOrigin -> TcThetaType -> TcM HsWrapper
344 -- Instantiates the TcTheta, puts all constraints thereby generated
345 -- into the LIE, and returns a HsWrapper to enclose the call site.
346
347 instCallConstraints orig preds
348 | null preds
349 = return idHsWrapper
350 | otherwise
351 = do { evs <- mapM go preds
352 ; traceTc "instCallConstraints" (ppr evs)
353 ; return (mkWpEvApps evs) }
354 where
355 go :: TcPredType -> TcM EvTerm
356 go pred
357 | Just (Nominal, ty1, ty2) <- getEqPredTys_maybe pred -- Try short-cut #1
358 = do { co <- unifyType Nothing ty1 ty2
359 ; return (evCoercion co) }
360
361 -- Try short-cut #2
362 | Just (tc, args@[_, _, ty1, ty2]) <- splitTyConApp_maybe pred
363 , tc `hasKey` heqTyConKey
364 = do { co <- unifyType Nothing ty1 ty2
365 ; return (evDFunApp (dataConWrapId heqDataCon) args [Coercion co]) }
366
367 | otherwise
368 = emitWanted orig pred
369
370 instDFunType :: DFunId -> [DFunInstType]
371 -> TcM ( [TcType] -- instantiated argument types
372 , TcThetaType ) -- instantiated constraint
373 -- See Note [DFunInstType: instantiating types] in InstEnv
374 instDFunType dfun_id dfun_inst_tys
375 = do { (subst, inst_tys) <- go empty_subst dfun_tvs dfun_inst_tys
376 ; return (inst_tys, substTheta subst dfun_theta) }
377 where
378 dfun_ty = idType dfun_id
379 (dfun_tvs, dfun_theta, _) = tcSplitSigmaTy dfun_ty
380 empty_subst = mkEmptyTCvSubst (mkInScopeSet (tyCoVarsOfType dfun_ty))
381 -- With quantified constraints, the
382 -- type of a dfun may not be closed
383
384 go :: TCvSubst -> [TyVar] -> [DFunInstType] -> TcM (TCvSubst, [TcType])
385 go subst [] [] = return (subst, [])
386 go subst (tv:tvs) (Just ty : mb_tys)
387 = do { (subst', tys) <- go (extendTvSubstAndInScope subst tv ty)
388 tvs
389 mb_tys
390 ; return (subst', ty : tys) }
391 go subst (tv:tvs) (Nothing : mb_tys)
392 = do { (subst', tv') <- newMetaTyVarX subst tv
393 ; (subst'', tys) <- go subst' tvs mb_tys
394 ; return (subst'', mkTyVarTy tv' : tys) }
395 go _ _ _ = pprPanic "instDFunTypes" (ppr dfun_id $$ ppr dfun_inst_tys)
396
397 ----------------
398 instStupidTheta :: CtOrigin -> TcThetaType -> TcM ()
399 -- Similar to instCall, but only emit the constraints in the LIE
400 -- Used exclusively for the 'stupid theta' of a data constructor
401 instStupidTheta orig theta
402 = do { _co <- instCallConstraints orig theta -- Discard the coercion
403 ; return () }
404
405
406 {- *********************************************************************
407 * *
408 Instantiating Kinds
409 * *
410 ********************************************************************* -}
411
412 -- | Instantiates up to n invisible binders
413 -- Returns the instantiating types, and body kind
414 tcInstInvisibleTyBinders :: Int -> TcKind -> TcM ([TcType], TcKind)
415
416 tcInstInvisibleTyBinders 0 kind
417 = return ([], kind)
418 tcInstInvisibleTyBinders n ty
419 = go n empty_subst ty
420 where
421 empty_subst = mkEmptyTCvSubst (mkInScopeSet (tyCoVarsOfType ty))
422
423 go n subst kind
424 | n > 0
425 , Just (bndr, body) <- tcSplitPiTy_maybe kind
426 , isInvisibleBinder bndr
427 = do { (subst', arg) <- tcInstInvisibleTyBinder subst bndr
428 ; (args, inner_ty) <- go (n-1) subst' body
429 ; return (arg:args, inner_ty) }
430 | otherwise
431 = return ([], substTy subst kind)
432
433 -- | Used only in *types*
434 tcInstInvisibleTyBinder :: TCvSubst -> TyBinder -> TcM (TCvSubst, TcType)
435 tcInstInvisibleTyBinder subst (Named (Bndr tv _))
436 = do { (subst', tv') <- newMetaTyVarX subst tv
437 ; return (subst', mkTyVarTy tv') }
438
439 tcInstInvisibleTyBinder subst (Anon af ty)
440 | Just (mk, k1, k2) <- get_eq_tys_maybe (substTy subst ty)
441 -- Equality is the *only* constraint currently handled in types.
442 -- See Note [Constraints in kinds] in TyCoRep
443 = ASSERT( af == InvisArg )
444 do { co <- unifyKind Nothing k1 k2
445 ; arg' <- mk co
446 ; return (subst, arg') }
447
448 | otherwise -- This should never happen
449 -- See TyCoRep Note [Constraints in kinds]
450 = pprPanic "tcInvisibleTyBinder" (ppr ty)
451
452 -------------------------------
453 get_eq_tys_maybe :: Type
454 -> Maybe ( Coercion -> TcM Type
455 -- given a coercion proving t1 ~# t2, produce the
456 -- right instantiation for the TyBinder at hand
457 , Type -- t1
458 , Type -- t2
459 )
460 -- See Note [Constraints in kinds] in TyCoRep
461 get_eq_tys_maybe ty
462 -- Lifted heterogeneous equality (~~)
463 | Just (tc, [_, _, k1, k2]) <- splitTyConApp_maybe ty
464 , tc `hasKey` heqTyConKey
465 = Just (\co -> mkHEqBoxTy co k1 k2, k1, k2)
466
467 -- Lifted homogeneous equality (~)
468 | Just (tc, [_, k1, k2]) <- splitTyConApp_maybe ty
469 , tc `hasKey` eqTyConKey
470 = Just (\co -> mkEqBoxTy co k1 k2, k1, k2)
471
472 | otherwise
473 = Nothing
474
475 -- | This takes @a ~# b@ and returns @a ~~ b@.
476 mkHEqBoxTy :: TcCoercion -> Type -> Type -> TcM Type
477 -- monadic just for convenience with mkEqBoxTy
478 mkHEqBoxTy co ty1 ty2
479 = return $
480 mkTyConApp (promoteDataCon heqDataCon) [k1, k2, ty1, ty2, mkCoercionTy co]
481 where k1 = tcTypeKind ty1
482 k2 = tcTypeKind ty2
483
484 -- | This takes @a ~# b@ and returns @a ~ b@.
485 mkEqBoxTy :: TcCoercion -> Type -> Type -> TcM Type
486 mkEqBoxTy co ty1 ty2
487 = return $
488 mkTyConApp (promoteDataCon eqDataCon) [k, ty1, ty2, mkCoercionTy co]
489 where k = tcTypeKind ty1
490
491 {-
492 ************************************************************************
493 * *
494 Literals
495 * *
496 ************************************************************************
497
498 -}
499
500 {-
501 In newOverloadedLit we convert directly to an Int or Integer if we
502 know that's what we want. This may save some time, by not
503 temporarily generating overloaded literals, but it won't catch all
504 cases (the rest are caught in lookupInst).
505
506 -}
507
508 newOverloadedLit :: HsOverLit GhcRn
509 -> ExpRhoType
510 -> TcM (HsOverLit GhcTcId)
511 newOverloadedLit
512 lit@(OverLit { ol_val = val, ol_ext = rebindable }) res_ty
513 | not rebindable
514 -- all built-in overloaded lits are tau-types, so we can just
515 -- tauify the ExpType
516 = do { res_ty <- expTypeToType res_ty
517 ; dflags <- getDynFlags
518 ; case shortCutLit dflags val res_ty of
519 -- Do not generate a LitInst for rebindable syntax.
520 -- Reason: If we do, tcSimplify will call lookupInst, which
521 -- will call tcSyntaxName, which does unification,
522 -- which tcSimplify doesn't like
523 Just expr -> return (lit { ol_witness = expr
524 , ol_ext = OverLitTc False res_ty })
525 Nothing -> newNonTrivialOverloadedLit orig lit
526 (mkCheckExpType res_ty) }
527
528 | otherwise
529 = newNonTrivialOverloadedLit orig lit res_ty
530 where
531 orig = LiteralOrigin lit
532 newOverloadedLit XOverLit{} _ = panic "newOverloadedLit"
533
534 -- Does not handle things that 'shortCutLit' can handle. See also
535 -- newOverloadedLit in TcUnify
536 newNonTrivialOverloadedLit :: CtOrigin
537 -> HsOverLit GhcRn
538 -> ExpRhoType
539 -> TcM (HsOverLit GhcTcId)
540 newNonTrivialOverloadedLit orig
541 lit@(OverLit { ol_val = val, ol_witness = HsVar _ (L _ meth_name)
542 , ol_ext = rebindable }) res_ty
543 = do { hs_lit <- mkOverLit val
544 ; let lit_ty = hsLitType hs_lit
545 ; (_, fi') <- tcSyntaxOp orig (mkRnSyntaxExpr meth_name)
546 [synKnownType lit_ty] res_ty $
547 \_ -> return ()
548 ; let L _ witness = nlHsSyntaxApps fi' [nlHsLit hs_lit]
549 ; res_ty <- readExpType res_ty
550 ; return (lit { ol_witness = witness
551 , ol_ext = OverLitTc rebindable res_ty }) }
552 newNonTrivialOverloadedLit _ lit _
553 = pprPanic "newNonTrivialOverloadedLit" (ppr lit)
554
555 ------------
556 mkOverLit ::OverLitVal -> TcM (HsLit GhcTc)
557 mkOverLit (HsIntegral i)
558 = do { integer_ty <- tcMetaTy integerTyConName
559 ; return (HsInteger (il_text i)
560 (il_value i) integer_ty) }
561
562 mkOverLit (HsFractional r)
563 = do { rat_ty <- tcMetaTy rationalTyConName
564 ; return (HsRat noExt r rat_ty) }
565
566 mkOverLit (HsIsString src s) = return (HsString src s)
567
568 {-
569 ************************************************************************
570 * *
571 Re-mappable syntax
572
573 Used only for arrow syntax -- find a way to nuke this
574 * *
575 ************************************************************************
576
577 Suppose we are doing the -XRebindableSyntax thing, and we encounter
578 a do-expression. We have to find (>>) in the current environment, which is
579 done by the rename. Then we have to check that it has the same type as
580 Control.Monad.(>>). Or, more precisely, a compatible type. One 'customer' had
581 this:
582
583 (>>) :: HB m n mn => m a -> n b -> mn b
584
585 So the idea is to generate a local binding for (>>), thus:
586
587 let then72 :: forall a b. m a -> m b -> m b
588 then72 = ...something involving the user's (>>)...
589 in
590 ...the do-expression...
591
592 Now the do-expression can proceed using then72, which has exactly
593 the expected type.
594
595 In fact tcSyntaxName just generates the RHS for then72, because we only
596 want an actual binding in the do-expression case. For literals, we can
597 just use the expression inline.
598 -}
599
600 tcSyntaxName :: CtOrigin
601 -> TcType -- ^ Type to instantiate it at
602 -> (Name, HsExpr GhcRn) -- ^ (Standard name, user name)
603 -> TcM (Name, HsExpr GhcTcId)
604 -- ^ (Standard name, suitable expression)
605 -- USED ONLY FOR CmdTop (sigh) ***
606 -- See Note [CmdSyntaxTable] in HsExpr
607
608 tcSyntaxName orig ty (std_nm, HsVar _ (L _ user_nm))
609 | std_nm == user_nm
610 = do rhs <- newMethodFromName orig std_nm ty
611 return (std_nm, rhs)
612
613 tcSyntaxName orig ty (std_nm, user_nm_expr) = do
614 std_id <- tcLookupId std_nm
615 let
616 -- C.f. newMethodAtLoc
617 ([tv], _, tau) = tcSplitSigmaTy (idType std_id)
618 sigma1 = substTyWith [tv] [ty] tau
619 -- Actually, the "tau-type" might be a sigma-type in the
620 -- case of locally-polymorphic methods.
621
622 addErrCtxtM (syntaxNameCtxt user_nm_expr orig sigma1) $ do
623
624 -- Check that the user-supplied thing has the
625 -- same type as the standard one.
626 -- Tiresome jiggling because tcCheckSigma takes a located expression
627 span <- getSrcSpanM
628 expr <- tcPolyExpr (L span user_nm_expr) sigma1
629 return (std_nm, unLoc expr)
630
631 syntaxNameCtxt :: HsExpr GhcRn -> CtOrigin -> Type -> TidyEnv
632 -> TcRn (TidyEnv, SDoc)
633 syntaxNameCtxt name orig ty tidy_env
634 = do { inst_loc <- getCtLocM orig (Just TypeLevel)
635 ; let msg = vcat [ text "When checking that" <+> quotes (ppr name)
636 <+> text "(needed by a syntactic construct)"
637 , nest 2 (text "has the required type:"
638 <+> ppr (tidyType tidy_env ty))
639 , nest 2 (pprCtLoc inst_loc) ]
640 ; return (tidy_env, msg) }
641
642 {-
643 ************************************************************************
644 * *
645 Instances
646 * *
647 ************************************************************************
648 -}
649
650 getOverlapFlag :: Maybe OverlapMode -> TcM OverlapFlag
651 -- Construct the OverlapFlag from the global module flags,
652 -- but if the overlap_mode argument is (Just m),
653 -- set the OverlapMode to 'm'
654 getOverlapFlag overlap_mode
655 = do { dflags <- getDynFlags
656 ; let overlap_ok = xopt LangExt.OverlappingInstances dflags
657 incoherent_ok = xopt LangExt.IncoherentInstances dflags
658 use x = OverlapFlag { isSafeOverlap = safeLanguageOn dflags
659 , overlapMode = x }
660 default_oflag | incoherent_ok = use (Incoherent NoSourceText)
661 | overlap_ok = use (Overlaps NoSourceText)
662 | otherwise = use (NoOverlap NoSourceText)
663
664 final_oflag = setOverlapModeMaybe default_oflag overlap_mode
665 ; return final_oflag }
666
667 tcGetInsts :: TcM [ClsInst]
668 -- Gets the local class instances.
669 tcGetInsts = fmap tcg_insts getGblEnv
670
671 newClsInst :: Maybe OverlapMode -> Name -> [TyVar] -> ThetaType
672 -> Class -> [Type] -> TcM ClsInst
673 newClsInst overlap_mode dfun_name tvs theta clas tys
674 = do { (subst, tvs') <- freshenTyVarBndrs tvs
675 -- Be sure to freshen those type variables,
676 -- so they are sure not to appear in any lookup
677 ; let tys' = substTys subst tys
678
679 dfun = mkDictFunId dfun_name tvs theta clas tys
680 -- The dfun uses the original 'tvs' because
681 -- (a) they don't need to be fresh
682 -- (b) they may be mentioned in the ib_binds field of
683 -- an InstInfo, and in TcEnv.pprInstInfoDetails it's
684 -- helpful to use the same names
685
686 ; oflag <- getOverlapFlag overlap_mode
687 ; let inst = mkLocalInstance dfun oflag tvs' clas tys'
688 ; warnIfFlag Opt_WarnOrphans
689 (isOrphan (is_orphan inst))
690 (instOrphWarn inst)
691 ; return inst }
692
693 instOrphWarn :: ClsInst -> SDoc
694 instOrphWarn inst
695 = hang (text "Orphan instance:") 2 (pprInstanceHdr inst)
696 $$ text "To avoid this"
697 $$ nest 4 (vcat possibilities)
698 where
699 possibilities =
700 text "move the instance declaration to the module of the class or of the type, or" :
701 text "wrap the type with a newtype and declare the instance on the new type." :
702 []
703
704 tcExtendLocalInstEnv :: [ClsInst] -> TcM a -> TcM a
705 -- Add new locally-defined instances
706 tcExtendLocalInstEnv dfuns thing_inside
707 = do { traceDFuns dfuns
708 ; env <- getGblEnv
709 ; (inst_env', cls_insts') <- foldlM addLocalInst
710 (tcg_inst_env env, tcg_insts env)
711 dfuns
712 ; let env' = env { tcg_insts = cls_insts'
713 , tcg_inst_env = inst_env' }
714 ; setGblEnv env' thing_inside }
715
716 addLocalInst :: (InstEnv, [ClsInst]) -> ClsInst -> TcM (InstEnv, [ClsInst])
717 -- Check that the proposed new instance is OK,
718 -- and then add it to the home inst env
719 -- If overwrite_inst, then we can overwrite a direct match
720 addLocalInst (home_ie, my_insts) ispec
721 = do {
722 -- Load imported instances, so that we report
723 -- duplicates correctly
724
725 -- 'matches' are existing instance declarations that are less
726 -- specific than the new one
727 -- 'dups' are those 'matches' that are equal to the new one
728 ; isGHCi <- getIsGHCi
729 ; eps <- getEps
730 ; tcg_env <- getGblEnv
731
732 -- In GHCi, we *override* any identical instances
733 -- that are also defined in the interactive context
734 -- See Note [Override identical instances in GHCi]
735 ; let home_ie'
736 | isGHCi = deleteFromInstEnv home_ie ispec
737 | otherwise = home_ie
738
739 global_ie = eps_inst_env eps
740 inst_envs = InstEnvs { ie_global = global_ie
741 , ie_local = home_ie'
742 , ie_visible = tcVisibleOrphanMods tcg_env }
743
744 -- Check for inconsistent functional dependencies
745 ; let inconsistent_ispecs = checkFunDeps inst_envs ispec
746 ; unless (null inconsistent_ispecs) $
747 funDepErr ispec inconsistent_ispecs
748
749 -- Check for duplicate instance decls.
750 ; let (_tvs, cls, tys) = instanceHead ispec
751 (matches, _, _) = lookupInstEnv False inst_envs cls tys
752 dups = filter (identicalClsInstHead ispec) (map fst matches)
753 ; unless (null dups) $
754 dupInstErr ispec (head dups)
755
756 ; return (extendInstEnv home_ie' ispec, ispec : my_insts) }
757
758 {-
759 Note [Signature files and type class instances]
760 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
761 Instances in signature files do not have an effect when compiling:
762 when you compile a signature against an implementation, you will
763 see the instances WHETHER OR NOT the instance is declared in
764 the file (this is because the signatures go in the EPS and we
765 can't filter them out easily.) This is also why we cannot
766 place the instance in the hi file: it would show up as a duplicate,
767 and we don't have instance reexports anyway.
768
769 However, you might find them useful when typechecking against
770 a signature: the instance is a way of indicating to GHC that
771 some instance exists, in case downstream code uses it.
772
773 Implementing this is a little tricky. Consider the following
774 situation (sigof03):
775
776 module A where
777 instance C T where ...
778
779 module ASig where
780 instance C T
781
782 When compiling ASig, A.hi is loaded, which brings its instances
783 into the EPS. When we process the instance declaration in ASig,
784 we should ignore it for the purpose of doing a duplicate check,
785 since it's not actually a duplicate. But don't skip the check
786 entirely, we still want this to fail (tcfail221):
787
788 module ASig where
789 instance C T
790 instance C T
791
792 Note that in some situations, the interface containing the type
793 class instances may not have been loaded yet at all. The usual
794 situation when A imports another module which provides the
795 instances (sigof02m):
796
797 module A(module B) where
798 import B
799
800 See also Note [Signature lazy interface loading]. We can't
801 rely on this, however, since sometimes we'll have spurious
802 type class instances in the EPS, see #9422 (sigof02dm)
803
804 ************************************************************************
805 * *
806 Errors and tracing
807 * *
808 ************************************************************************
809 -}
810
811 traceDFuns :: [ClsInst] -> TcRn ()
812 traceDFuns ispecs
813 = traceTc "Adding instances:" (vcat (map pp ispecs))
814 where
815 pp ispec = hang (ppr (instanceDFunId ispec) <+> colon)
816 2 (ppr ispec)
817 -- Print the dfun name itself too
818
819 funDepErr :: ClsInst -> [ClsInst] -> TcRn ()
820 funDepErr ispec ispecs
821 = addClsInstsErr (text "Functional dependencies conflict between instance declarations:")
822 (ispec : ispecs)
823
824 dupInstErr :: ClsInst -> ClsInst -> TcRn ()
825 dupInstErr ispec dup_ispec
826 = addClsInstsErr (text "Duplicate instance declarations:")
827 [ispec, dup_ispec]
828
829 addClsInstsErr :: SDoc -> [ClsInst] -> TcRn ()
830 addClsInstsErr herald ispecs
831 = setSrcSpan (getSrcSpan (head sorted)) $
832 addErr (hang herald 2 (pprInstances sorted))
833 where
834 sorted = sortWith getSrcLoc ispecs
835 -- The sortWith just arranges that instances are dislayed in order
836 -- of source location, which reduced wobbling in error messages,
837 -- and is better for users