5da8b0afedb4919f9e057b2de7d4a4eb1544b90d
[ghc.git] / libraries / base / GHC / ST.lhs
1 \begin{code}
2 {-# LANGUAGE Unsafe #-}
3 {-# LANGUAGE NoImplicitPrelude, MagicHash, UnboxedTuples, RankNTypes #-}
4 {-# OPTIONS_HADDOCK hide #-}
5 -----------------------------------------------------------------------------
6 -- |
7 -- Module      :  GHC.ST
8 -- Copyright   :  (c) The University of Glasgow, 1992-2002
9 -- License     :  see libraries/base/LICENSE
10 -- 
11 -- Maintainer  :  cvs-ghc@haskell.org
12 -- Stability   :  internal
13 -- Portability :  non-portable (GHC Extensions)
14 --
15 -- The 'ST' Monad.
16 --
17 -----------------------------------------------------------------------------
18
19 module GHC.ST (
20         ST(..), STret(..), STRep,
21         fixST, runST, runSTRep,
22
23         -- * Unsafe functions
24         liftST, unsafeInterleaveST
25     ) where
26
27 import GHC.Base
28 import GHC.Show
29
30 default ()
31 \end{code}
32
33 %*********************************************************
34 %*                                                      *
35 \subsection{The @ST@ monad}
36 %*                                                      *
37 %*********************************************************
38
39 The state-transformer monad proper.  By default the monad is strict;
40 too many people got bitten by space leaks when it was lazy.
41
42 \begin{code}
43 -- | The strict state-transformer monad.
44 -- A computation of type @'ST' s a@ transforms an internal state indexed
45 -- by @s@, and returns a value of type @a@.
46 -- The @s@ parameter is either
47 --
48 -- * an uninstantiated type variable (inside invocations of 'runST'), or
49 --
50 -- * 'RealWorld' (inside invocations of 'Control.Monad.ST.stToIO').
51 --
52 -- It serves to keep the internal states of different invocations
53 -- of 'runST' separate from each other and from invocations of
54 -- 'Control.Monad.ST.stToIO'.
55 --
56 -- The '>>=' and '>>' operations are strict in the state (though not in
57 -- values stored in the state).  For example,
58 --
59 -- @'runST' (writeSTRef _|_ v >>= f) = _|_@
60 newtype ST s a = ST (STRep s a)
61 type STRep s a = State# s -> (# State# s, a #)
62
63 instance Functor (ST s) where
64     fmap f (ST m) = ST $ \ s ->
65       case (m s) of { (# new_s, r #) ->
66       (# new_s, f r #) }
67
68 instance Monad (ST s) where
69     {-# INLINE return #-}
70     {-# INLINE (>>)   #-}
71     {-# INLINE (>>=)  #-}
72     return x = ST (\ s -> (# s, x #))
73     m >> k   = m >>= \ _ -> k
74
75     (ST m) >>= k
76       = ST (\ s ->
77         case (m s) of { (# new_s, r #) ->
78         case (k r) of { ST k2 ->
79         (k2 new_s) }})
80
81 data STret s a = STret (State# s) a
82
83 -- liftST is useful when we want a lifted result from an ST computation.  See
84 -- fixST below.
85 liftST :: ST s a -> State# s -> STret s a
86 liftST (ST m) = \s -> case m s of (# s', r #) -> STret s' r
87
88 {-# NOINLINE unsafeInterleaveST #-}
89 unsafeInterleaveST :: ST s a -> ST s a
90 unsafeInterleaveST (ST m) = ST ( \ s ->
91     let
92         r = case m s of (# _, res #) -> res
93     in
94     (# s, r #)
95   )
96
97 -- | Allow the result of a state transformer computation to be used (lazily)
98 -- inside the computation.
99 -- Note that if @f@ is strict, @'fixST' f = _|_@.
100 fixST :: (a -> ST s a) -> ST s a
101 fixST k = ST $ \ s ->
102     let ans       = liftST (k r) s
103         STret _ r = ans
104     in
105     case ans of STret s' x -> (# s', x #)
106
107 instance  Show (ST s a)  where
108     showsPrec _ _  = showString "<<ST action>>"
109     showList       = showList__ (showsPrec 0)
110 \end{code}
111
112 Definition of runST
113 ~~~~~~~~~~~~~~~~~~~
114
115 SLPJ 95/04: Why @runST@ must not have an unfolding; consider:
116 \begin{verbatim}
117 f x =
118   runST ( \ s -> let
119                     (a, s')  = newArray# 100 [] s
120                     (_, s'') = fill_in_array_or_something a x s'
121                   in
122                   freezeArray# a s'' )
123 \end{verbatim}
124 If we inline @runST@, we'll get:
125 \begin{verbatim}
126 f x = let
127         (a, s')  = newArray# 100 [] realWorld#{-NB-}
128         (_, s'') = fill_in_array_or_something a x s'
129       in
130       freezeArray# a s''
131 \end{verbatim}
132 And now the @newArray#@ binding can be floated to become a CAF, which
133 is totally and utterly wrong:
134 \begin{verbatim}
135 f = let
136     (a, s')  = newArray# 100 [] realWorld#{-NB-} -- YIKES!!!
137     in
138     \ x ->
139         let (_, s'') = fill_in_array_or_something a x s' in
140         freezeArray# a s''
141 \end{verbatim}
142 All calls to @f@ will share a {\em single} array!  End SLPJ 95/04.
143
144 \begin{code}
145 {-# INLINE runST #-}
146 -- The INLINE prevents runSTRep getting inlined in *this* module
147 -- so that it is still visible when runST is inlined in an importing
148 -- module.  Regrettably delicate.  runST is behaving like a wrapper.
149
150 -- | Return the value computed by a state transformer computation.
151 -- The @forall@ ensures that the internal state used by the 'ST'
152 -- computation is inaccessible to the rest of the program.
153 runST :: (forall s. ST s a) -> a
154 runST st = runSTRep (case st of { ST st_rep -> st_rep })
155
156 -- I'm only letting runSTRep be inlined right at the end, in particular *after* full laziness
157 -- That's what the "INLINE [0]" says.
158 --              SLPJ Apr 99
159 -- {-# INLINE [0] runSTRep #-}
160
161 -- SDM: further to the above, inline phase 0 is run *before*
162 -- full-laziness at the moment, which means that the above comment is
163 -- invalid.  Inlining runSTRep doesn't make a huge amount of
164 -- difference, anyway.  Hence:
165
166 {-# NOINLINE runSTRep #-}
167 runSTRep :: (forall s. STRep s a) -> a
168 runSTRep st_rep = case st_rep realWorld# of
169                         (# _, r #) -> r
170 \end{code}