Revert "Remove ArchUnknown"
[ghc.git] / compiler / nativeGen / AsmCodeGen.lhs
1 -- -----------------------------------------------------------------------------
2 --
3 -- (c) The University of Glasgow 1993-2004
4 -- 
5 -- This is the top-level module in the native code generator.
6 --
7 -- -----------------------------------------------------------------------------
8
9 \begin{code}
10 module AsmCodeGen ( nativeCodeGen ) where
11
12 #include "HsVersions.h"
13 #include "nativeGen/NCG.h"
14
15
16 import qualified X86.CodeGen
17 import qualified X86.Regs
18 import qualified X86.Instr
19 import qualified X86.Ppr
20
21 import qualified SPARC.CodeGen
22 import qualified SPARC.Regs
23 import qualified SPARC.Instr
24 import qualified SPARC.Ppr
25 import qualified SPARC.ShortcutJump
26 import qualified SPARC.CodeGen.Expand
27
28 import qualified PPC.CodeGen
29 import qualified PPC.Cond
30 import qualified PPC.Regs
31 import qualified PPC.RegInfo
32 import qualified PPC.Instr
33 import qualified PPC.Ppr
34
35 import RegAlloc.Liveness
36 import qualified RegAlloc.Linear.Main           as Linear
37
38 import qualified GraphColor                     as Color
39 import qualified RegAlloc.Graph.Main            as Color
40 import qualified RegAlloc.Graph.Stats           as Color
41 import qualified RegAlloc.Graph.TrivColorable   as Color
42
43 import TargetReg
44 import Platform
45 import Config
46 import Instruction
47 import PIC
48 import Reg
49 import NCGMonad
50
51 import BlockId
52 import CgUtils          ( fixStgRegisters )
53 import OldCmm
54 import CmmOpt           ( cmmEliminateDeadBlocks, cmmMiniInline, cmmMachOpFold )
55 import OldPprCmm
56 import CLabel
57
58 import UniqFM
59 import Unique           ( Unique, getUnique )
60 import UniqSupply
61 import DynFlags
62 import StaticFlags
63 import Util
64
65 import BasicTypes       ( Alignment )
66 import Digraph
67 import Pretty (Doc)
68 import qualified Pretty
69 import BufWrite
70 import Outputable
71 import FastString
72 import UniqSet
73 import ErrUtils
74 import Module
75
76 -- DEBUGGING ONLY
77 --import OrdList
78
79 import Data.List
80 import Data.Maybe
81 import Control.Monad
82 import System.IO
83
84 {-
85 The native-code generator has machine-independent and
86 machine-dependent modules.
87
88 This module ("AsmCodeGen") is the top-level machine-independent
89 module.  Before entering machine-dependent land, we do some
90 machine-independent optimisations (defined below) on the
91 'CmmStmts's.
92
93 We convert to the machine-specific 'Instr' datatype with
94 'cmmCodeGen', assuming an infinite supply of registers.  We then use
95 a machine-independent register allocator ('regAlloc') to rejoin
96 reality.  Obviously, 'regAlloc' has machine-specific helper
97 functions (see about "RegAllocInfo" below).
98
99 Finally, we order the basic blocks of the function so as to minimise
100 the number of jumps between blocks, by utilising fallthrough wherever
101 possible.
102
103 The machine-dependent bits break down as follows:
104
105   * ["MachRegs"]  Everything about the target platform's machine
106     registers (and immediate operands, and addresses, which tend to
107     intermingle/interact with registers).
108
109   * ["MachInstrs"]  Includes the 'Instr' datatype (possibly should
110     have a module of its own), plus a miscellany of other things
111     (e.g., 'targetDoubleSize', 'smStablePtrTable', ...)
112
113   * ["MachCodeGen"]  is where 'Cmm' stuff turns into
114     machine instructions.
115
116   * ["PprMach"] 'pprInstr' turns an 'Instr' into text (well, really
117     a 'Doc').
118
119   * ["RegAllocInfo"] In the register allocator, we manipulate
120     'MRegsState's, which are 'BitSet's, one bit per machine register.
121     When we want to say something about a specific machine register
122     (e.g., ``it gets clobbered by this instruction''), we set/unset
123     its bit.  Obviously, we do this 'BitSet' thing for efficiency
124     reasons.
125
126     The 'RegAllocInfo' module collects together the machine-specific
127     info needed to do register allocation.
128
129    * ["RegisterAlloc"] The (machine-independent) register allocator.
130 -}
131
132 -- -----------------------------------------------------------------------------
133 -- Top-level of the native codegen
134
135 data NcgImpl statics instr jumpDest = NcgImpl {
136     cmmTopCodeGen             :: RawCmmDecl -> NatM [NatCmmDecl statics instr],
137     generateJumpTableForInstr :: instr -> Maybe (NatCmmDecl statics instr),
138     getJumpDestBlockId        :: jumpDest -> Maybe BlockId,
139     canShortcut               :: instr -> Maybe jumpDest,
140     shortcutStatics           :: (BlockId -> Maybe jumpDest) -> statics -> statics,
141     shortcutJump              :: (BlockId -> Maybe jumpDest) -> instr -> instr,
142     pprNatCmmDecl              :: Platform -> NatCmmDecl statics instr -> Doc,
143     maxSpillSlots             :: Int,
144     allocatableRegs           :: [RealReg],
145     ncg_x86fp_kludge          :: [NatCmmDecl statics instr] -> [NatCmmDecl statics instr],
146     ncgExpandTop              :: [NatCmmDecl statics instr] -> [NatCmmDecl statics instr],
147     ncgMakeFarBranches        :: [NatBasicBlock instr] -> [NatBasicBlock instr]
148     }
149
150 --------------------
151 nativeCodeGen :: DynFlags -> Handle -> UniqSupply -> [RawCmmGroup] -> IO ()
152 nativeCodeGen dflags h us cmms
153  = let nCG' :: (PlatformOutputable statics, PlatformOutputable instr, Instruction instr) => NcgImpl statics instr jumpDest -> IO ()
154        nCG' ncgImpl = nativeCodeGen' dflags ncgImpl h us cmms
155        x86NcgImpl = NcgImpl {
156                          cmmTopCodeGen             = X86.CodeGen.cmmTopCodeGen
157                         ,generateJumpTableForInstr = X86.CodeGen.generateJumpTableForInstr
158                         ,getJumpDestBlockId        = X86.Instr.getJumpDestBlockId
159                         ,canShortcut               = X86.Instr.canShortcut
160                         ,shortcutStatics           = X86.Instr.shortcutStatics
161                         ,shortcutJump              = X86.Instr.shortcutJump
162                         ,pprNatCmmDecl              = X86.Ppr.pprNatCmmDecl
163                         ,maxSpillSlots             = X86.Instr.maxSpillSlots
164                         ,allocatableRegs           = X86.Regs.allocatableRegs
165                         ,ncg_x86fp_kludge          = id
166                         ,ncgExpandTop              = id
167                         ,ncgMakeFarBranches        = id
168                     }
169    in case platformArch $ targetPlatform dflags of
170                  ArchX86    -> nCG' (x86NcgImpl { ncg_x86fp_kludge = map x86fp_kludge })
171                  ArchX86_64 -> nCG' x86NcgImpl
172                  ArchPPC ->
173                      nCG' $ NcgImpl {
174                           cmmTopCodeGen             = PPC.CodeGen.cmmTopCodeGen
175                          ,generateJumpTableForInstr = PPC.CodeGen.generateJumpTableForInstr
176                          ,getJumpDestBlockId        = PPC.RegInfo.getJumpDestBlockId
177                          ,canShortcut               = PPC.RegInfo.canShortcut
178                          ,shortcutStatics           = PPC.RegInfo.shortcutStatics
179                          ,shortcutJump              = PPC.RegInfo.shortcutJump
180                          ,pprNatCmmDecl              = PPC.Ppr.pprNatCmmDecl
181                          ,maxSpillSlots             = PPC.Instr.maxSpillSlots
182                          ,allocatableRegs           = PPC.Regs.allocatableRegs
183                          ,ncg_x86fp_kludge          = id
184                          ,ncgExpandTop              = id
185                          ,ncgMakeFarBranches        = makeFarBranches
186                      }
187                  ArchSPARC ->
188                      nCG' $ NcgImpl {
189                           cmmTopCodeGen             = SPARC.CodeGen.cmmTopCodeGen
190                          ,generateJumpTableForInstr = SPARC.CodeGen.generateJumpTableForInstr
191                          ,getJumpDestBlockId        = SPARC.ShortcutJump.getJumpDestBlockId
192                          ,canShortcut               = SPARC.ShortcutJump.canShortcut
193                          ,shortcutStatics           = SPARC.ShortcutJump.shortcutStatics
194                          ,shortcutJump              = SPARC.ShortcutJump.shortcutJump
195                          ,pprNatCmmDecl              = SPARC.Ppr.pprNatCmmDecl
196                          ,maxSpillSlots             = SPARC.Instr.maxSpillSlots
197                          ,allocatableRegs           = SPARC.Regs.allocatableRegs
198                          ,ncg_x86fp_kludge          = id
199                          ,ncgExpandTop              = map SPARC.CodeGen.Expand.expandTop
200                          ,ncgMakeFarBranches        = id
201                      }
202                  ArchARM _ _ ->
203                      panic "nativeCodeGen: No NCG for ARM"
204                  ArchPPC_64 ->
205                      panic "nativeCodeGen: No NCG for PPC 64"
206                  ArchUnknown ->
207                      panic "nativeCodeGen: No NCG for unknown arch"
208
209 nativeCodeGen' :: (PlatformOutputable statics, PlatformOutputable instr, Instruction instr)
210                => DynFlags
211                -> NcgImpl statics instr jumpDest
212                -> Handle -> UniqSupply -> [RawCmmGroup] -> IO ()
213 nativeCodeGen' dflags ncgImpl h us cmms
214  = do
215         let platform = targetPlatform dflags
216             split_cmms  = concat $ map add_split cmms
217         -- BufHandle is a performance hack.  We could hide it inside
218         -- Pretty if it weren't for the fact that we do lots of little
219         -- printDocs here (in order to do codegen in constant space).
220         bufh <- newBufHandle h
221         (imports, prof) <- cmmNativeGens dflags ncgImpl bufh us split_cmms [] [] 0
222         bFlush bufh
223
224         let (native, colorStats, linearStats)
225                 = unzip3 prof
226
227         -- dump native code
228         dumpIfSet_dyn dflags
229                 Opt_D_dump_asm "Asm code"
230                 (vcat $ map (docToSDoc . pprNatCmmDecl ncgImpl platform) $ concat native)
231
232         -- dump global NCG stats for graph coloring allocator
233         (case concat $ catMaybes colorStats of
234           []    -> return ()
235           stats -> do   
236                 -- build the global register conflict graph
237                 let graphGlobal 
238                         = foldl Color.union Color.initGraph
239                         $ [ Color.raGraph stat
240                                 | stat@Color.RegAllocStatsStart{} <- stats]
241            
242                 dumpSDoc dflags Opt_D_dump_asm_stats "NCG stats"
243                         $ Color.pprStats stats graphGlobal
244
245                 dumpIfSet_dyn dflags
246                         Opt_D_dump_asm_conflicts "Register conflict graph"
247                         $ Color.dotGraph 
248                                 (targetRegDotColor platform)
249                                 (Color.trivColorable platform
250                                         (targetVirtualRegSqueeze platform)
251                                         (targetRealRegSqueeze platform))
252                         $ graphGlobal)
253
254
255         -- dump global NCG stats for linear allocator
256         (case concat $ catMaybes linearStats of
257                 []      -> return ()
258                 stats   -> dumpSDoc dflags Opt_D_dump_asm_stats "NCG stats"
259                                 $ Linear.pprStats (concat native) stats)
260
261         -- write out the imports
262         Pretty.printDoc Pretty.LeftMode h
263                 $ makeImportsDoc dflags (concat imports)
264
265         return  ()
266
267  where  add_split tops
268                 | dopt Opt_SplitObjs dflags = split_marker : tops
269                 | otherwise                 = tops
270
271         split_marker = CmmProc Nothing mkSplitMarkerLabel (ListGraph [])
272
273
274 -- | Do native code generation on all these cmms.
275 --
276 cmmNativeGens :: (PlatformOutputable statics, PlatformOutputable instr, Instruction instr)
277               => DynFlags
278               -> NcgImpl statics instr jumpDest
279               -> BufHandle
280               -> UniqSupply
281               -> [RawCmmDecl]
282               -> [[CLabel]]
283               -> [ ([NatCmmDecl statics instr],
284                    Maybe [Color.RegAllocStats statics instr],
285                    Maybe [Linear.RegAllocStats]) ]
286               -> Int
287               -> IO ( [[CLabel]],
288                       [([NatCmmDecl statics instr],
289                       Maybe [Color.RegAllocStats statics instr],
290                       Maybe [Linear.RegAllocStats])] )
291
292 cmmNativeGens _ _ _ _ [] impAcc profAcc _
293         = return (reverse impAcc, reverse profAcc)
294
295 cmmNativeGens dflags ncgImpl h us (cmm : cmms) impAcc profAcc count
296  = do
297         let platform = targetPlatform dflags
298
299         (us', native, imports, colorStats, linearStats)
300                 <- cmmNativeGen dflags ncgImpl us cmm count
301
302         Pretty.bufLeftRender h
303                 $ {-# SCC "pprNativeCode" #-} Pretty.vcat $ map (pprNatCmmDecl ncgImpl platform) native
304
305            -- carefully evaluate this strictly.  Binding it with 'let'
306            -- and then using 'seq' doesn't work, because the let
307            -- apparently gets inlined first.
308         lsPprNative <- return $!
309                 if  dopt Opt_D_dump_asm       dflags
310                  || dopt Opt_D_dump_asm_stats dflags
311                         then native
312                         else []
313
314         count' <- return $! count + 1;
315
316         -- force evaulation all this stuff to avoid space leaks
317         seqString (showSDoc $ vcat $ map (pprPlatform platform) imports) `seq` return ()
318
319         cmmNativeGens dflags ncgImpl
320             h us' cmms
321                         (imports : impAcc)
322                         ((lsPprNative, colorStats, linearStats) : profAcc)
323                         count'
324
325  where  seqString []            = ()
326         seqString (x:xs)        = x `seq` seqString xs `seq` ()
327
328
329 -- | Complete native code generation phase for a single top-level chunk of Cmm.
330 --      Dumping the output of each stage along the way.
331 --      Global conflict graph and NGC stats
332 cmmNativeGen
333         :: (PlatformOutputable statics, PlatformOutputable instr, Instruction instr)
334     => DynFlags
335     -> NcgImpl statics instr jumpDest
336         -> UniqSupply
337         -> RawCmmDecl                                   -- ^ the cmm to generate code for
338         -> Int                                          -- ^ sequence number of this top thing
339         -> IO   ( UniqSupply
340                 , [NatCmmDecl statics instr]                -- native code
341                 , [CLabel]                                  -- things imported by this cmm
342                 , Maybe [Color.RegAllocStats statics instr] -- stats for the coloring register allocator
343                 , Maybe [Linear.RegAllocStats])             -- stats for the linear register allocators
344
345 cmmNativeGen dflags ncgImpl us cmm count
346  = do
347         let platform = targetPlatform dflags
348
349         -- rewrite assignments to global regs
350         let fixed_cmm =
351                 {-# SCC "fixStgRegisters" #-}
352                 fixStgRegisters cmm
353
354         -- cmm to cmm optimisations
355         let (opt_cmm, imports) =
356                 {-# SCC "cmmToCmm" #-}
357                 cmmToCmm dflags fixed_cmm
358
359         dumpIfSet_dyn dflags
360                 Opt_D_dump_opt_cmm "Optimised Cmm"
361                 (pprCmmGroup platform [opt_cmm])
362
363         -- generate native code from cmm
364         let ((native, lastMinuteImports), usGen) =
365                 {-# SCC "genMachCode" #-}
366                 initUs us $ genMachCode dflags (cmmTopCodeGen ncgImpl) opt_cmm
367
368         dumpIfSet_dyn dflags
369                 Opt_D_dump_asm_native "Native code"
370                 (vcat $ map (docToSDoc . pprNatCmmDecl ncgImpl platform) native)
371
372         -- tag instructions with register liveness information
373         let (withLiveness, usLive) =
374                 {-# SCC "regLiveness" #-}
375                 initUs usGen 
376                         $ mapUs (regLiveness platform)
377                         $ map natCmmTopToLive native
378
379         dumpIfSet_dyn dflags
380                 Opt_D_dump_asm_liveness "Liveness annotations added"
381                 (vcat $ map (pprPlatform platform) withLiveness)
382                 
383         -- allocate registers
384         (alloced, usAlloc, ppr_raStatsColor, ppr_raStatsLinear) <-
385          if ( dopt Opt_RegsGraph dflags
386            || dopt Opt_RegsIterative dflags)
387           then do
388                 -- the regs usable for allocation
389                 let (alloc_regs :: UniqFM (UniqSet RealReg))
390                         = foldr (\r -> plusUFM_C unionUniqSets
391                                         $ unitUFM (targetClassOfRealReg platform r) (unitUniqSet r))
392                                 emptyUFM
393                         $ allocatableRegs ncgImpl
394
395                 -- do the graph coloring register allocation
396                 let ((alloced, regAllocStats), usAlloc)
397                         = {-# SCC "RegAlloc" #-}
398                           initUs usLive
399                           $ Color.regAlloc
400                                 dflags
401                                 alloc_regs
402                                 (mkUniqSet [0 .. maxSpillSlots ncgImpl])
403                                 withLiveness
404
405                 -- dump out what happened during register allocation
406                 dumpIfSet_dyn dflags
407                         Opt_D_dump_asm_regalloc "Registers allocated"
408                         (vcat $ map (docToSDoc . pprNatCmmDecl ncgImpl platform) alloced)
409
410                 dumpIfSet_dyn dflags
411                         Opt_D_dump_asm_regalloc_stages "Build/spill stages"
412                         (vcat   $ map (\(stage, stats)
413                                         -> text "# --------------------------"
414                                         $$ text "#  cmm " <> int count <> text " Stage " <> int stage
415                                         $$ pprPlatform platform stats)
416                                 $ zip [0..] regAllocStats)
417
418                 let mPprStats =
419                         if dopt Opt_D_dump_asm_stats dflags
420                          then Just regAllocStats else Nothing
421
422                 -- force evaluation of the Maybe to avoid space leak
423                 mPprStats `seq` return ()
424
425                 return  ( alloced, usAlloc
426                         , mPprStats
427                         , Nothing)
428
429           else do
430                 -- do linear register allocation
431                 let ((alloced, regAllocStats), usAlloc) 
432                         = {-# SCC "RegAlloc" #-}
433                           initUs usLive
434                           $ liftM unzip
435                           $ mapUs (Linear.regAlloc dflags) withLiveness
436
437                 dumpIfSet_dyn dflags
438                         Opt_D_dump_asm_regalloc "Registers allocated"
439                         (vcat $ map (docToSDoc . pprNatCmmDecl ncgImpl platform) alloced)
440
441                 let mPprStats =
442                         if dopt Opt_D_dump_asm_stats dflags
443                          then Just (catMaybes regAllocStats) else Nothing
444
445                 -- force evaluation of the Maybe to avoid space leak
446                 mPprStats `seq` return ()
447
448                 return  ( alloced, usAlloc
449                         , Nothing
450                         , mPprStats)
451
452         ---- x86fp_kludge.  This pass inserts ffree instructions to clear
453         ---- the FPU stack on x86.  The x86 ABI requires that the FPU stack
454         ---- is clear, and library functions can return odd results if it
455         ---- isn't.
456         ----
457         ---- NB. must happen before shortcutBranches, because that
458         ---- generates JXX_GBLs which we can't fix up in x86fp_kludge.
459         let kludged = {-# SCC "x86fp_kludge" #-} ncg_x86fp_kludge ncgImpl alloced
460
461         ---- generate jump tables
462         let tabled      =
463                 {-# SCC "generateJumpTables" #-}
464                 generateJumpTables ncgImpl kludged
465
466         ---- shortcut branches
467         let shorted     =
468                 {-# SCC "shortcutBranches" #-}
469                 shortcutBranches dflags ncgImpl tabled
470
471         ---- sequence blocks
472         let sequenced   =
473                 {-# SCC "sequenceBlocks" #-}
474                 map (sequenceTop ncgImpl) shorted
475
476         ---- expansion of SPARC synthetic instrs
477         let expanded = 
478                 {-# SCC "sparc_expand" #-}
479                 ncgExpandTop ncgImpl sequenced
480
481         dumpIfSet_dyn dflags
482                 Opt_D_dump_asm_expanded "Synthetic instructions expanded"
483                 (vcat $ map (docToSDoc . pprNatCmmDecl ncgImpl platform) expanded)
484
485         return  ( usAlloc
486                 , expanded
487                 , lastMinuteImports ++ imports
488                 , ppr_raStatsColor
489                 , ppr_raStatsLinear)
490
491
492 x86fp_kludge :: NatCmmDecl (Alignment, CmmStatics) X86.Instr.Instr -> NatCmmDecl (Alignment, CmmStatics) X86.Instr.Instr
493 x86fp_kludge top@(CmmData _ _) = top
494 x86fp_kludge (CmmProc info lbl (ListGraph code)) = 
495         CmmProc info lbl (ListGraph $ X86.Instr.i386_insert_ffrees code)
496
497
498 -- | Build a doc for all the imports.
499 --
500 makeImportsDoc :: DynFlags -> [CLabel] -> Pretty.Doc
501 makeImportsDoc dflags imports
502  = dyld_stubs imports
503
504 #if HAVE_SUBSECTIONS_VIA_SYMBOLS
505                 -- On recent versions of Darwin, the linker supports
506                 -- dead-stripping of code and data on a per-symbol basis.
507                 -- There's a hack to make this work in PprMach.pprNatCmmDecl.
508             Pretty.$$ Pretty.text ".subsections_via_symbols"
509 #endif
510 #if HAVE_GNU_NONEXEC_STACK
511                 -- On recent GNU ELF systems one can mark an object file
512                 -- as not requiring an executable stack. If all objects
513                 -- linked into a program have this note then the program
514                 -- will not use an executable stack, which is good for
515                 -- security. GHC generated code does not need an executable
516                 -- stack so add the note in:
517             Pretty.$$ Pretty.text ".section .note.GNU-stack,\"\",@progbits"
518 #endif
519                 -- And just because every other compiler does, lets stick in
520                 -- an identifier directive: .ident "GHC x.y.z"
521             Pretty.$$ let compilerIdent = Pretty.text "GHC" Pretty.<+>
522                                           Pretty.text cProjectVersion
523                        in Pretty.text ".ident" Pretty.<+>
524                           Pretty.doubleQuotes compilerIdent
525
526  where
527         -- Generate "symbol stubs" for all external symbols that might
528         -- come from a dynamic library.
529         dyld_stubs :: [CLabel] -> Pretty.Doc
530 {-      dyld_stubs imps = Pretty.vcat $ map pprDyldSymbolStub $
531                                     map head $ group $ sort imps-}
532
533         platform = targetPlatform dflags
534         arch = platformArch platform
535         os   = platformOS   platform
536         
537         -- (Hack) sometimes two Labels pretty-print the same, but have
538         -- different uniques; so we compare their text versions...
539         dyld_stubs imps
540                 | needImportedSymbols arch os
541                 = Pretty.vcat $
542                         (pprGotDeclaration arch os :) $
543                         map ( pprImportedSymbol platform . fst . head) $
544                         groupBy (\(_,a) (_,b) -> a == b) $
545                         sortBy (\(_,a) (_,b) -> compare a b) $
546                         map doPpr $
547                         imps
548                 | otherwise
549                 = Pretty.empty
550
551         doPpr lbl = (lbl, renderWithStyle (pprCLabel platform lbl) astyle)
552         astyle = mkCodeStyle AsmStyle
553
554
555 -- -----------------------------------------------------------------------------
556 -- Sequencing the basic blocks
557
558 -- Cmm BasicBlocks are self-contained entities: they always end in a
559 -- jump, either non-local or to another basic block in the same proc.
560 -- In this phase, we attempt to place the basic blocks in a sequence
561 -- such that as many of the local jumps as possible turn into
562 -- fallthroughs.
563
564 sequenceTop 
565         :: Instruction instr
566     => NcgImpl statics instr jumpDest -> NatCmmDecl statics instr -> NatCmmDecl statics instr
567
568 sequenceTop _       top@(CmmData _ _) = top
569 sequenceTop ncgImpl (CmmProc info lbl (ListGraph blocks)) = 
570   CmmProc info lbl (ListGraph $ ncgMakeFarBranches ncgImpl $ sequenceBlocks blocks)
571
572 -- The algorithm is very simple (and stupid): we make a graph out of
573 -- the blocks where there is an edge from one block to another iff the
574 -- first block ends by jumping to the second.  Then we topologically
575 -- sort this graph.  Then traverse the list: for each block, we first
576 -- output the block, then if it has an out edge, we move the
577 -- destination of the out edge to the front of the list, and continue.
578
579 -- FYI, the classic layout for basic blocks uses postorder DFS; this
580 -- algorithm is implemented in Hoopl.
581
582 sequenceBlocks 
583         :: Instruction instr
584         => [NatBasicBlock instr] 
585         -> [NatBasicBlock instr]
586
587 sequenceBlocks [] = []
588 sequenceBlocks (entry:blocks) = 
589   seqBlocks (mkNode entry : reverse (flattenSCCs (sccBlocks blocks)))
590   -- the first block is the entry point ==> it must remain at the start.
591
592
593 sccBlocks 
594         :: Instruction instr
595         => [NatBasicBlock instr] 
596         -> [SCC ( NatBasicBlock instr
597                 , Unique
598                 , [Unique])]
599
600 sccBlocks blocks = stronglyConnCompFromEdgedVerticesR (map mkNode blocks)
601
602 -- we're only interested in the last instruction of
603 -- the block, and only if it has a single destination.
604 getOutEdges 
605         :: Instruction instr
606         => [instr] -> [Unique]
607
608 getOutEdges instrs 
609         = case jumpDestsOfInstr (last instrs) of
610                 [one] -> [getUnique one]
611                 _many -> []
612
613 mkNode :: (Instruction t)
614        => GenBasicBlock t
615        -> (GenBasicBlock t, Unique, [Unique])
616 mkNode block@(BasicBlock id instrs) = (block, getUnique id, getOutEdges instrs)
617
618 seqBlocks :: (Eq t) => [(GenBasicBlock t1, t, [t])] -> [GenBasicBlock t1]
619 seqBlocks [] = []
620 seqBlocks ((block,_,[]) : rest)
621   = block : seqBlocks rest
622 seqBlocks ((block@(BasicBlock id instrs),_,[next]) : rest)
623   | can_fallthrough = BasicBlock id (init instrs) : seqBlocks rest'
624   | otherwise       = block : seqBlocks rest'
625   where
626         (can_fallthrough, rest') = reorder next [] rest
627           -- TODO: we should do a better job for cycles; try to maximise the
628           -- fallthroughs within a loop.
629 seqBlocks _ = panic "AsmCodegen:seqBlocks"
630
631 reorder :: (Eq a) => a -> [(t, a, t1)] -> [(t, a, t1)] -> (Bool, [(t, a, t1)])
632 reorder  _ accum [] = (False, reverse accum)
633 reorder id accum (b@(block,id',out) : rest)
634   | id == id'  = (True, (block,id,out) : reverse accum ++ rest)
635   | otherwise  = reorder id (b:accum) rest
636
637
638 -- -----------------------------------------------------------------------------
639 -- Making far branches
640
641 -- Conditional branches on PowerPC are limited to +-32KB; if our Procs get too
642 -- big, we have to work around this limitation.
643
644 makeFarBranches
645         :: [NatBasicBlock PPC.Instr.Instr] 
646         -> [NatBasicBlock PPC.Instr.Instr]
647 makeFarBranches blocks
648     | last blockAddresses < nearLimit = blocks
649     | otherwise = zipWith handleBlock blockAddresses blocks
650     where
651         blockAddresses = scanl (+) 0 $ map blockLen blocks
652         blockLen (BasicBlock _ instrs) = length instrs
653         
654         handleBlock addr (BasicBlock id instrs)
655                 = BasicBlock id (zipWith makeFar [addr..] instrs)
656         
657         makeFar _ (PPC.Instr.BCC PPC.Cond.ALWAYS tgt) = PPC.Instr.BCC PPC.Cond.ALWAYS tgt
658         makeFar addr (PPC.Instr.BCC cond tgt)
659             | abs (addr - targetAddr) >= nearLimit
660             = PPC.Instr.BCCFAR cond tgt
661             | otherwise
662             = PPC.Instr.BCC cond tgt
663             where Just targetAddr = lookupUFM blockAddressMap tgt
664         makeFar _ other            = other
665         
666         nearLimit = 7000 -- 8192 instructions are allowed; let's keep some
667                          -- distance, as we have a few pseudo-insns that are
668                          -- pretty-printed as multiple instructions,
669                          -- and it's just not worth the effort to calculate
670                          -- things exactly
671         
672         blockAddressMap = listToUFM $ zip (map blockId blocks) blockAddresses
673
674 -- -----------------------------------------------------------------------------
675 -- Generate jump tables
676
677 -- Analyzes all native code and generates data sections for all jump
678 -- table instructions.
679 generateJumpTables
680         :: NcgImpl statics instr jumpDest
681     -> [NatCmmDecl statics instr] -> [NatCmmDecl statics instr]
682 generateJumpTables ncgImpl xs = concatMap f xs
683     where f p@(CmmProc _ _ (ListGraph xs)) = p : concatMap g xs
684           f p = [p]
685           g (BasicBlock _ xs) = catMaybes (map (generateJumpTableForInstr ncgImpl) xs)
686
687 -- -----------------------------------------------------------------------------
688 -- Shortcut branches
689
690 shortcutBranches
691         :: DynFlags
692     -> NcgImpl statics instr jumpDest
693         -> [NatCmmDecl statics instr] 
694         -> [NatCmmDecl statics instr]
695
696 shortcutBranches dflags ncgImpl tops
697   | optLevel dflags < 1 = tops    -- only with -O or higher
698   | otherwise           = map (apply_mapping ncgImpl mapping) tops'
699   where
700     (tops', mappings) = mapAndUnzip (build_mapping ncgImpl) tops
701     mapping = foldr plusUFM emptyUFM mappings
702
703 build_mapping :: NcgImpl statics instr jumpDest
704               -> GenCmmDecl d t (ListGraph instr)
705               -> (GenCmmDecl d t (ListGraph instr), UniqFM jumpDest)
706 build_mapping _ top@(CmmData _ _) = (top, emptyUFM)
707 build_mapping _ (CmmProc info lbl (ListGraph []))
708   = (CmmProc info lbl (ListGraph []), emptyUFM)
709 build_mapping ncgImpl (CmmProc info lbl (ListGraph (head:blocks)))
710   = (CmmProc info lbl (ListGraph (head:others)), mapping)
711         -- drop the shorted blocks, but don't ever drop the first one,
712         -- because it is pointed to by a global label.
713   where
714     -- find all the blocks that just consist of a jump that can be
715     -- shorted.
716     -- Don't completely eliminate loops here -- that can leave a dangling jump!
717     (_, shortcut_blocks, others) = foldl split (emptyBlockSet, [], []) blocks
718     split (s, shortcut_blocks, others) b@(BasicBlock id [insn])
719         | Just jd <- canShortcut ncgImpl insn,
720           Just dest <- getJumpDestBlockId ncgImpl jd,
721           (setMember dest s) || dest == id -- loop checks
722         = (s, shortcut_blocks, b : others)
723     split (s, shortcut_blocks, others) (BasicBlock id [insn])
724         | Just dest <- canShortcut ncgImpl insn
725         = (setInsert id s, (id,dest) : shortcut_blocks, others)
726     split (s, shortcut_blocks, others) other = (s, shortcut_blocks, other : others)
727
728
729     -- build a mapping from BlockId to JumpDest for shorting branches
730     mapping = foldl add emptyUFM shortcut_blocks
731     add ufm (id,dest) = addToUFM ufm id dest
732     
733 apply_mapping :: NcgImpl statics instr jumpDest
734               -> UniqFM jumpDest
735               -> GenCmmDecl statics h (ListGraph instr)
736               -> GenCmmDecl statics h (ListGraph instr)
737 apply_mapping ncgImpl ufm (CmmData sec statics)
738   = CmmData sec (shortcutStatics ncgImpl (lookupUFM ufm) statics)
739 apply_mapping ncgImpl ufm (CmmProc info lbl (ListGraph blocks))
740   = CmmProc info lbl (ListGraph $ map short_bb blocks)
741   where
742     short_bb (BasicBlock id insns) = BasicBlock id $! map short_insn insns
743     short_insn i = shortcutJump ncgImpl (lookupUFM ufm) i
744                  -- shortcutJump should apply the mapping repeatedly,
745                  -- just in case we can short multiple branches.
746
747 -- -----------------------------------------------------------------------------
748 -- Instruction selection
749
750 -- Native code instruction selection for a chunk of stix code.  For
751 -- this part of the computation, we switch from the UniqSM monad to
752 -- the NatM monad.  The latter carries not only a Unique, but also an
753 -- Int denoting the current C stack pointer offset in the generated
754 -- code; this is needed for creating correct spill offsets on
755 -- architectures which don't offer, or for which it would be
756 -- prohibitively expensive to employ, a frame pointer register.  Viz,
757 -- x86.
758
759 -- The offset is measured in bytes, and indicates the difference
760 -- between the current (simulated) C stack-ptr and the value it was at
761 -- the beginning of the block.  For stacks which grow down, this value
762 -- should be either zero or negative.
763
764 -- Switching between the two monads whilst carrying along the same
765 -- Unique supply breaks abstraction.  Is that bad?
766
767 genMachCode 
768         :: DynFlags 
769         -> (RawCmmDecl -> NatM [NatCmmDecl statics instr])
770         -> RawCmmDecl 
771         -> UniqSM 
772                 ( [NatCmmDecl statics instr]
773                 , [CLabel])
774
775 genMachCode dflags cmmTopCodeGen cmm_top
776   = do  { initial_us <- getUs
777         ; let initial_st           = mkNatM_State initial_us 0 dflags
778               (new_tops, final_st) = initNat initial_st (cmmTopCodeGen cmm_top)
779               final_delta          = natm_delta final_st
780               final_imports        = natm_imports final_st
781         ; if   final_delta == 0
782           then return (new_tops, final_imports)
783           else pprPanic "genMachCode: nonzero final delta" (int final_delta)
784     }
785
786 -- -----------------------------------------------------------------------------
787 -- Generic Cmm optimiser
788
789 {-
790 Here we do:
791
792   (a) Constant folding
793   (b) Simple inlining: a temporary which is assigned to and then
794       used, once, can be shorted.
795   (c) Position independent code and dynamic linking
796         (i)  introduce the appropriate indirections
797              and position independent refs
798         (ii) compile a list of imported symbols
799   (d) Some arch-specific optimizations
800
801 (a) and (b) will be moving to the new Hoopl pipeline, however, (c) and
802 (d) are only needed by the native backend and will continue to live
803 here.
804
805 Ideas for other things we could do (put these in Hoopl please!):
806
807   - shortcut jumps-to-jumps
808   - simple CSE: if an expr is assigned to a temp, then replace later occs of
809     that expr with the temp, until the expr is no longer valid (can push through
810     temp assignments, and certain assigns to mem...)
811 -}
812
813 cmmToCmm :: DynFlags -> RawCmmDecl -> (RawCmmDecl, [CLabel])
814 cmmToCmm _ top@(CmmData _ _) = (top, [])
815 cmmToCmm dflags (CmmProc info lbl (ListGraph blocks)) = runCmmOpt dflags $ do
816   blocks' <- mapM cmmBlockConFold (cmmMiniInline (cmmEliminateDeadBlocks blocks))
817   return $ CmmProc info lbl (ListGraph blocks')
818
819 newtype CmmOptM a = CmmOptM (([CLabel], DynFlags) -> (# a, [CLabel] #))
820
821 instance Monad CmmOptM where
822   return x = CmmOptM $ \(imports, _) -> (# x,imports #)
823   (CmmOptM f) >>= g =
824     CmmOptM $ \(imports, dflags) ->
825                 case f (imports, dflags) of
826                   (# x, imports' #) ->
827                     case g x of
828                       CmmOptM g' -> g' (imports', dflags)
829
830 addImportCmmOpt :: CLabel -> CmmOptM ()
831 addImportCmmOpt lbl = CmmOptM $ \(imports, _dflags) -> (# (), lbl:imports #)
832
833 getDynFlagsCmmOpt :: CmmOptM DynFlags
834 getDynFlagsCmmOpt = CmmOptM $ \(imports, dflags) -> (# dflags, imports #)
835
836 runCmmOpt :: DynFlags -> CmmOptM a -> (a, [CLabel])
837 runCmmOpt dflags (CmmOptM f) = case f ([], dflags) of
838                         (# result, imports #) -> (result, imports)
839
840 cmmBlockConFold :: CmmBasicBlock -> CmmOptM CmmBasicBlock
841 cmmBlockConFold (BasicBlock id stmts) = do
842   stmts' <- mapM cmmStmtConFold stmts
843   return $ BasicBlock id stmts'
844
845 -- This does three optimizations, but they're very quick to check, so we don't
846 -- bother turning them off even when the Hoopl code is active.  Since
847 -- this is on the old Cmm representation, we can't reuse the code either:
848 --  * reg = reg      --> nop
849 --  * if 0 then jump --> nop
850 --  * if 1 then jump --> jump
851 -- We might be tempted to skip this step entirely of not opt_PIC, but
852 -- there is some PowerPC code for the non-PIC case, which would also
853 -- have to be separated.
854 cmmStmtConFold :: CmmStmt -> CmmOptM CmmStmt
855 cmmStmtConFold stmt
856    = case stmt of
857         CmmAssign reg src
858            -> do src' <- cmmExprConFold DataReference src
859                  return $ case src' of
860                    CmmReg reg' | reg == reg' -> CmmNop
861                    new_src -> CmmAssign reg new_src
862
863         CmmStore addr src
864            -> do addr' <- cmmExprConFold DataReference addr
865                  src'  <- cmmExprConFold DataReference src
866                  return $ CmmStore addr' src'
867
868         CmmJump addr regs
869            -> do addr' <- cmmExprConFold JumpReference addr
870                  return $ CmmJump addr' regs
871
872         CmmCall target regs args srt returns
873            -> do target' <- case target of
874                               CmmCallee e conv -> do
875                                 e' <- cmmExprConFold CallReference e
876                                 return $ CmmCallee e' conv
877                               other -> return other
878                  args' <- mapM (\(CmmHinted arg hint) -> do
879                                   arg' <- cmmExprConFold DataReference arg
880                                   return (CmmHinted arg' hint)) args
881                  return $ CmmCall target' regs args' srt returns
882
883         CmmCondBranch test dest
884            -> do test' <- cmmExprConFold DataReference test
885                  dflags <- getDynFlagsCmmOpt
886                  let platform = targetPlatform dflags
887                  return $ case test' of
888                    CmmLit (CmmInt 0 _) -> 
889                      CmmComment (mkFastString ("deleted: " ++ 
890                                         showSDoc (pprStmt platform stmt)))
891
892                    CmmLit (CmmInt _ _) -> CmmBranch dest
893                    _other -> CmmCondBranch test' dest
894
895         CmmSwitch expr ids
896            -> do expr' <- cmmExprConFold DataReference expr
897                  return $ CmmSwitch expr' ids
898
899         other
900            -> return other
901
902 cmmExprConFold :: ReferenceKind -> CmmExpr -> CmmOptM CmmExpr
903 cmmExprConFold referenceKind expr = do
904     dflags <- getDynFlagsCmmOpt
905     -- Skip constant folding if new code generator is running
906     -- (this optimization is done in Hoopl)
907     let expr' = if dopt Opt_TryNewCodeGen dflags
908                     then expr
909                     else cmmExprCon expr
910     cmmExprNative referenceKind expr'
911
912 cmmExprCon :: CmmExpr -> CmmExpr
913 cmmExprCon (CmmLoad addr rep) = CmmLoad (cmmExprCon addr) rep
914 cmmExprCon (CmmMachOp mop args) = cmmMachOpFold mop (map cmmExprCon args)
915 cmmExprCon other = other
916
917 -- handles both PIC and non-PIC cases... a very strange mixture
918 -- of things to do.
919 cmmExprNative :: ReferenceKind -> CmmExpr -> CmmOptM CmmExpr
920 cmmExprNative referenceKind expr = do
921      dflags <- getDynFlagsCmmOpt
922      let arch = platformArch (targetPlatform dflags)
923      case expr of
924         CmmLoad addr rep
925            -> do addr' <- cmmExprNative DataReference addr
926                  return $ CmmLoad addr' rep
927
928         CmmMachOp mop args
929            -> do args' <- mapM (cmmExprNative DataReference) args
930                  return $ CmmMachOp mop args'
931
932         CmmLit (CmmLabel lbl)
933            -> do
934                 cmmMakeDynamicReference dflags addImportCmmOpt referenceKind lbl
935         CmmLit (CmmLabelOff lbl off)
936            -> do
937                  dynRef <- cmmMakeDynamicReference dflags addImportCmmOpt referenceKind lbl
938                  -- need to optimize here, since it's late
939                  return $ cmmMachOpFold (MO_Add wordWidth) [
940                      dynRef,
941                      (CmmLit $ CmmInt (fromIntegral off) wordWidth)
942                    ]
943
944         -- On powerpc (non-PIC), it's easier to jump directly to a label than
945         -- to use the register table, so we replace these registers
946         -- with the corresponding labels:
947         CmmReg (CmmGlobal EagerBlackholeInfo)
948           | arch == ArchPPC && not opt_PIC
949           -> cmmExprNative referenceKind $
950              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_EAGER_BLACKHOLE_info")))
951         CmmReg (CmmGlobal GCEnter1)
952           | arch == ArchPPC && not opt_PIC
953           -> cmmExprNative referenceKind $
954              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_gc_enter_1"))) 
955         CmmReg (CmmGlobal GCFun)
956           | arch == ArchPPC && not opt_PIC
957           -> cmmExprNative referenceKind $
958              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_gc_fun")))
959
960         other
961            -> return other
962
963 \end{code}
964