Merge branch 'master' of http://darcs.haskell.org/ghc
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2004
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.1], [glasgow-haskell-bugs@haskell.org], [ghc])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 6.7.20070204).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # darcs repository.  If this is a source distribution (not a darcs
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands, 
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42
43 dnl ** Find sort command (for the benefit of Win32 environs)
44 FP_PROG_SORT
45
46 dnl ----------------------------------------------------------
47 FP_SETUP_PROJECT_VERSION
48
49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
50 AC_SUBST([release], [1])
51
52 # First off, a distrib sanity check..
53 AC_CONFIG_SRCDIR([mk/config.mk.in])
54
55 dnl * We require autoconf version 2.52
56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
58 AC_PREREQ([2.52])
59
60 # -------------------------------------------------------------------------
61 # Prepare to generate the following header files
62 #
63 #
64 AC_CONFIG_HEADER(mk/config.h)
65
66 # No, semi-sadly, we don't do `--srcdir'...
67 if test x"$srcdir" != 'x.' ; then
68     echo "This configuration does not support the \`--srcdir' option.."
69     exit 1
70 fi
71
72 dnl --------------------------------------------------------------
73 dnl * Project specific configuration options
74 dnl --------------------------------------------------------------
75 dnl What follows is a bunch of options that can either be configured
76 dnl through command line options to the configure script or by
77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
78 dnl use either is considered a Feature.
79
80 dnl ** What command to use to compile compiler sources ?
81 dnl --------------------------------------------------------------
82
83 AC_ARG_WITH([ghc],
84 [AC_HELP_STRING([--with-ghc=ARG],
85   [Use ARG as the path to GHC  [default=autodetect]])],
86   [WithGhc="$withval"],
87   [if test "$GHC" = ""; then
88     AC_PATH_PROG([GHC], [ghc])
89   fi
90   WithGhc="$GHC"])
91
92
93 dnl ** Tell the make system which OS we are using
94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something 
95 AC_SUBST(OSTYPE)
96
97 dnl ** Booting from .hc files?
98 dnl --------------------------------------------------------------
99 AC_ARG_ENABLE(hc-boot,
100 [AC_HELP_STRING([--enable-hc-boot],
101 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
102  (This option is mostly of interest to porters.) [default=no]])],
103 [ if test x"$enableval" = x"yes"; then
104         BootingFromHc=YES
105   else
106         BootingFromHc=NO
107   fi
108 ],
109 [BootingFromHc=NO]
110 )
111 AC_SUBST(BootingFromHc)
112
113 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
114 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
115                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
116         EnableBootstrapWithDevelSnaphost=YES,
117         EnableBootstrapWithDevelSnaphost=NO
118 )
119
120 if test "$WithGhc" != ""; then
121   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
122
123   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
124      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
125   fi
126
127   AC_SUBST(GhcVersion)dnl
128   AC_SUBST(GhcMajVersion)dnl
129   AC_SUBST(GhcMinVersion)dnl
130   AC_SUBST(GhcPatchLevel)dnl
131   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
132   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
133   if test $GhcCanonVersion -ge 613; then ghc_ge_613=YES; else ghc_ge_613=NO; fi
134   AC_SUBST(ghc_ge_613)dnl
135
136   BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command],['$(CC)'])
137   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command],['$(AR)'])
138   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags],['$(AR_OPTS)'])
139   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file],['$(ArSupportsAtFile)'])
140 fi
141
142 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
143 if test "$BootingFromHc" = "NO"; then
144   if test "$WithGhc" = ""; then
145      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
146   fi
147   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.12],
148     [AC_MSG_ERROR([GHC version 6.12 or later is required to compile GHC.])])dnl
149
150   if test `expr $GhcMinVersion % 2` = "1"; then
151      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
152         AC_MSG_ERROR([
153      $WithGhc is a development snapshot of GHC, version $GhcVersion.
154      Bootstrapping using this version of GHC is not supported, and may not
155      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
156      or --with-ghc to specify a different GHC to use.])
157      fi
158   fi
159 fi;
160
161 # GHC is passed to Cabal, so we need a native path
162 if test "${WithGhc}" != ""
163 then
164     ghc_host=`"${WithGhc}" +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
165
166     if test "$ghc_host" = "i386-unknown-mingw32"
167     then
168         if test "${OSTYPE}" = "msys"
169         then
170             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
171         else
172             # Canonicalise to <drive>:/path/to/ghc
173             WithGhc=`cygpath -m "${WithGhc}"`
174         fi
175         echo "GHC path canonicalised to: ${WithGhc}"
176     fi
177 fi
178 AC_SUBST([WithGhc])
179
180 dnl ** Without optimization some INLINE trickery fails for GHCi
181 SRC_CC_OPTS="-O"
182
183 FP_ICONV
184 FP_GMP
185
186 dnl--------------------------------------------------------------------
187 dnl * Choose host(/target/build) platform
188 dnl--------------------------------------------------------------------
189 dnl If we aren't explicitly told what values to use with configure flags,
190 dnl we ask the bootstrapping compiler what platform it is for
191
192 if test "${WithGhc}" != ""
193 then
194         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
195         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
196         if test "$bootstrap_host" != "$bootstrap_target"
197         then
198                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
199         fi
200 fi
201
202 # We have to run these unconditionally, but we may discard their
203 # results in the following code
204 AC_CANONICAL_BUILD
205 AC_CANONICAL_HOST
206 AC_CANONICAL_TARGET
207
208 FPTOOLS_SET_PLATFORM_VARS
209
210 # Testing if we shall enable shared libs support on Solaris.
211 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
212
213 SOLARIS_BROKEN_SHLD=NO
214
215 case $host in
216      i386-*-solaris2)
217      # here we go with the test
218      MINOR=`uname -r|cut -d '.' -f 2-`
219      if test "$MINOR" -lt "11"; then
220         SOLARIS_BROKEN_SHLD=YES
221      fi
222      ;;
223 esac
224
225 checkArch() {
226     case $1 in
227     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
228         ;;
229     *)
230         echo "Unknown arch $1"
231         exit 1
232         ;;
233     esac
234 }
235
236 checkVendor() {
237     case $1 in
238     dec|unknown|hp|apple|next|sun|sgi|ibm)
239         ;;
240     *)
241         echo "Unknown vendor $1"
242         exit 1
243         ;;
244     esac
245 }
246
247 checkOS() {
248     case $1 in
249     linux|freebsd|netbsd|openbsd|dragonfly|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix|haiku)
250         ;;
251     *)
252         echo "Unknown OS '$1'"
253         exit 1
254         ;;
255     esac
256 }
257
258 BuildPlatform="$BuildArch-$BuildVendor-$BuildOS"
259 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
260 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
261 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
262 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
263
264 checkArch "$BuildArch"
265 checkVendor "$BuildVendor"
266 checkOS "$BuildOS"
267
268 HostPlatform="$HostArch-$HostVendor-$HostOS"
269 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
270 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
271 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
272 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
273
274 checkArch "$HostArch"
275 checkVendor "$HostVendor"
276 checkOS "$HostOS"
277
278 TargetPlatform="$TargetArch-$TargetVendor-$TargetOS"
279 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
280 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
281 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
282 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
283
284 checkArch "$TargetArch"
285 checkVendor "$TargetVendor"
286 checkOS "$TargetOS"
287
288 # Verify that the installed (bootstrap) GHC is capable of generating
289 # code for the requested build platform.
290 if test "$BootingFromHc" = "NO"
291 then
292     if test "$BuildPlatform" != "$bootstrap_target"
293     then
294         echo "This GHC (${WithGhc}) does not generate code for the build platform"
295         echo "   GHC target platform    : $bootstrap_target"
296         echo "   Desired build platform : $BuildPlatform"
297         exit 1
298     fi
299 fi
300
301 echo "GHC build  : $BuildPlatform"
302 echo "GHC host   : $HostPlatform"
303 echo "GHC target : $TargetPlatform"
304
305 AC_SUBST(BuildPlatform)
306 AC_SUBST(HostPlatform)
307 AC_SUBST(TargetPlatform)
308 AC_SUBST(HostPlatform_CPP)
309 AC_SUBST(BuildPlatform_CPP)
310 AC_SUBST(TargetPlatform_CPP)
311
312 AC_SUBST(HostArch_CPP)
313 AC_SUBST(BuildArch_CPP)
314 AC_SUBST(TargetArch_CPP)
315
316 AC_SUBST(HostOS_CPP)
317 AC_SUBST(BuildOS_CPP)
318 AC_SUBST(TargetOS_CPP)
319
320 AC_SUBST(HostVendor_CPP)
321 AC_SUBST(BuildVendor_CPP)
322 AC_SUBST(TargetVendor_CPP)
323
324 AC_SUBST(exeext)
325 AC_SUBST(soext)
326
327 AC_SUBST(SOLARIS_BROKEN_SHLD)
328
329 AC_ARG_WITH(hc,
330 [AC_HELP_STRING([--with-hc=ARG],
331         [Use ARG as the path to the compiler for compiling ordinary
332          Haskell code  (default= value of --with-ghc)])],
333 [WithHc="$withval"],
334 [WithHc=$WithGhc]
335 )
336 AC_SUBST(WithHc)
337
338 # This uses GHC, so put it after the "GHC is required" check above:
339 FP_INTREE_GHC_PWD
340 FP_FIND_ROOT
341
342 if test "$HostOS" = "mingw32"
343 then
344     test -d inplace || mkdir inplace
345
346     CC="$hardtop/inplace/mingw/bin/gcc.exe"
347     LD="$hardtop/inplace/mingw/bin/ld.exe"
348     NM="$hardtop/inplace/mingw/bin/nm.exe"
349     fp_prog_ar_raw="$hardtop/inplace/mingw/bin/ar.exe"
350
351     # NB. If you update the tarbballs to a new version of gcc, don't
352     # forget to tweak the paths in driver/gcc/gcc.c.
353     if ! test -d inplace/mingw ||
354          test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma  ||
355          test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma  ||
356          test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma   ||
357          test inplace/mingw -ot ghc-tarballs/mingw/libgcc*.tar.gz      ||
358          test inplace/mingw -ot ghc-tarballs/mingw/libgmp*.tar.gz      ||
359          test inplace/mingw -ot ghc-tarballs/mingw/libmpc*.tar.gz      ||
360          test inplace/mingw -ot ghc-tarballs/mingw/libmpfr*.tar.gz     ||
361          test inplace/mingw -ot ghc-tarballs/mingw/libstdc*.tar.lzma   ||
362          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dev.tar.gz ||
363          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dll.tar.gz ||
364          test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
365     then
366         AC_MSG_NOTICE([Making in-tree mingw tree])
367         rm -rf inplace/mingw
368         mkdir inplace/mingw
369         (
370             cd inplace/mingw &&
371             tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma  &&
372             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma  &&
373             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma   &&
374             tar --lzma -xf ../../ghc-tarballs/mingw/libgcc*.tar.lzma    &&
375             tar --lzma -xf ../../ghc-tarballs/mingw/libgmp*.tar.lzma    &&
376             tar --lzma -xf ../../ghc-tarballs/mingw/libmpc*.tar.lzma    &&
377             tar --lzma -xf ../../ghc-tarballs/mingw/libmpfr*.tar.lzma   &&
378             tar --lzma -xf ../../ghc-tarballs/mingw/libstdc*.tar.lzma   &&
379             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dev.tar.gz &&
380             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dll.tar.gz &&
381             tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma    &&
382             mv bin/gcc.exe bin/realgcc.exe
383         )
384         PATH=`pwd`/inplace/mingw/bin:$PATH inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
385         if ! test -e inplace/mingw/bin/gcc.exe
386         then
387             AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
388         fi
389         AC_MSG_NOTICE([In-tree mingw tree created])
390     fi
391     if ! test -d inplace/perl ||
392          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
393     then
394         AC_MSG_NOTICE([Making in-tree perl tree])
395         rm -rf inplace/perl
396         mkdir inplace
397         mkdir inplace/perl
398         (
399             cd inplace/perl &&
400             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
401         )
402         AC_MSG_NOTICE([In-tree perl tree created])
403     fi
404 fi
405
406 dnl ** Which gcc to use?
407 dnl --------------------------------------------------------------
408 FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc])
409 export CC
410 WhatGccIsCalled="$CC"
411 AC_SUBST(WhatGccIsCalled)
412
413 dnl ** Which ld to use?
414 dnl --------------------------------------------------------------
415 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld])
416 LdCmd="$LD"
417 AC_SUBST([LdCmd])
418
419 dnl ** Which nm to use?
420 dnl --------------------------------------------------------------
421 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm])
422 NmCmd="$NM"
423 AC_SUBST([NmCmd])
424
425 SplitObjsBroken=NO
426 if test "$TargetOS_CPP" = "darwin"
427 then
428     AC_MSG_CHECKING(XCode version)
429     XCodeVersion=`xcodebuild -version | grep Xcode | sed "s/Xcode //"`
430     # Old XCode versions don't actually give the XCode version
431     if test "$XCodeVersion" = ""
432     then
433         AC_MSG_RESULT(not found (too old?))
434         SplitObjsBroken=YES
435     else
436         AC_MSG_RESULT($XCodeVersion)
437         XCodeVersion1=`echo "$XCodeVersion" | sed 's/\..*//'`
438 changequote(, )dnl
439         XCodeVersion2=`echo "$XCodeVersion" | sed 's/[^.]*\.\([^.]*\).*/\1/'`
440 changequote([, ])dnl
441         AC_MSG_NOTICE(XCode version component 1: $XCodeVersion1)
442         AC_MSG_NOTICE(XCode version component 2: $XCodeVersion2)
443         # Split objects is broken (#4013) with XCode < 3.2
444         if test "$XCodeVersion1" -lt 3
445         then
446             SplitObjsBroken=YES
447         else
448             if test "$XCodeVersion1" -eq 3
449             then
450                 if test "$XCodeVersion2" -lt 2
451                 then
452                     SplitObjsBroken=YES
453                 fi
454             fi
455         fi
456     fi
457 fi
458 AC_SUBST([SplitObjsBroken])
459
460 dnl ** Mac OS X: explicit deployment target
461 dnl --------------------------------------------------------------
462 AC_ARG_WITH([macosx-deployment-target],
463 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
464         [Build for Mac OS VERSION and higher  (default= version of build host)])],
465 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
466  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
467    # ignore everywhere, but on Mac OS
468    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
469    FP_MACOSX_DEPLOYMENT_TARGET=none
470  fi],
471 [FP_MACOSX_DEPLOYMENT_TARGET=none]
472 )
473 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
474 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
475 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
476
477 dnl --------------------------------------------------------------
478 dnl End of configure script option section
479 dnl --------------------------------------------------------------
480
481
482 dnl --------------------------------------------------------------
483 dnl * General configuration checks
484 dnl --------------------------------------------------------------
485
486 dnl ** Can the unix package be built?
487 dnl --------------------------------------------------------------
488
489 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
490    GhcLibsWithUnix=NO
491 else
492    GhcLibsWithUnix=YES
493 fi
494 AC_SUBST([GhcLibsWithUnix])
495
496 dnl ** does #! work?
497 AC_SYS_INTERPRETER()
498
499 dnl ** look for `perl'
500 case $HostOS_CPP in
501 cygwin32|mingw32)
502     PerlCmd=$hardtop/inplace/perl/perl
503     ;;
504 *)
505     AC_PATH_PROG(PerlCmd,perl)
506     if test -z "$PerlCmd"
507     then
508         echo "You must install perl before you can continue"
509         echo "Perhaps it is already installed, but not in your PATH?"
510         exit 1
511     else
512         FPTOOLS_CHECK_PERL_VERSION
513     fi
514     ;;
515 esac
516
517 dnl ** does #! path/to/perl work? (sometimes it's too long...)
518 FPTOOLS_SHEBANG_PERL
519
520 dnl ** check for Python
521 AC_PATH_PROG(PythonCmd,python)
522
523 dnl ** look for GCC and find out which version
524 dnl     Figure out which C compiler to use.  Gcc is preferred.
525 dnl     If gcc, make sure it's at least 2.1
526 dnl
527 FP_GCC_VERSION
528
529 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
530 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
531 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
532 # Stage 3 won't be supported by cross-compilation
533 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
534
535 FP_GCC_EXTRA_FLAGS
536
537 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
538 AC_PROG_CPP
539
540 AC_SUBST(CONF_CC_OPTS_STAGE0)
541 AC_SUBST(CONF_CC_OPTS_STAGE1)
542 AC_SUBST(CONF_CC_OPTS_STAGE2)
543 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
544 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
545 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
546 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
547 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
548 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
549 AC_SUBST(CONF_CPP_OPTS_STAGE0)
550 AC_SUBST(CONF_CPP_OPTS_STAGE1)
551 AC_SUBST(CONF_CPP_OPTS_STAGE2)
552
553 FP_SETTINGS
554
555 dnl ** figure out how to do context diffs
556 FP_PROG_CONTEXT_DIFF
557
558 dnl Let's make sure install-sh is executable here.  If we got it from
559 dnl a darcs repo, it might not be (see bug #978).
560 chmod +x install-sh
561 dnl ** figure out how to do a BSD-ish install
562 AC_PROG_INSTALL
563
564 dnl If you can run configure, you certainly have /bin/sh
565 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
566
567 dnl ** how to invoke `ar' and `ranlib'
568 FP_PROG_AR_SUPPORTS_ATFILE
569 FP_PROG_AR_NEEDS_RANLIB
570
571 dnl ** Check to see whether ln -s works
572 AC_PROG_LN_S
573
574
575 dnl ** Find the path to sed
576 AC_PATH_PROGS(SedCmd,gsed sed,sed)
577
578
579 dnl ** check for time command
580 AC_PATH_PROG(TimeCmd,time)
581
582 dnl ** check for tar
583 dnl   if GNU tar is named gtar, look for it first.
584 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
585
586 dnl ** check for patch
587 dnl if GNU patch is named gpatch, look for it first
588 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
589
590 dnl ** check for dtrace (currently only implemented for Mac OS X)
591 HaveDtrace=NO
592 AC_PATH_PROG(DtraceCmd,dtrace)
593 if test -n "$DtraceCmd"; then
594   if test "x$TargetOS_CPP-$TargetVendor_CPP" == "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" == "xsolaris2-unknown"; then
595     HaveDtrace=YES
596   fi
597 fi
598 AC_SUBST(HaveDtrace)
599
600 AC_PATH_PROG(HSCOLOUR,HsColour)
601 # HsColour is passed to Cabal, so we need a native path
602 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
603    test "${OSTYPE}"      != "msys"                  && \
604    test "${HSCOLOUR}"    != ""
605 then
606     # Canonicalise to <drive>:/path/to/gcc
607     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
608 fi
609
610 dnl ** check for DocBook toolchain
611 FP_CHECK_DOCBOOK_DTD
612 FP_DOCBOOK_XSL
613 FP_PROG_DBLATEX
614
615 dnl ** check for ghc-pkg command
616 FP_PROG_GHC_PKG
617
618 dnl ** check for installed happy binary + version
619 dnl    (don't do it if we're booting from .hc files though.)
620 if test "$BootingFromHc" = "NO"; then
621 FPTOOLS_HAPPY
622 fi;
623
624 dnl ** check for installed alex binary + version
625 dnl    (don't do it if we're booting from .hc files though.)
626 if test "$BootingFromHc" = "NO"; then
627 FPTOOLS_ALEX
628 fi;
629
630 dnl --------------------------------------------------
631 dnl ### program checking section ends here ###
632 dnl --------------------------------------------------
633
634 dnl --------------------------------------------------
635 dnl * Platform header file and syscall feature tests
636 dnl ### checking the state of the local header files and syscalls ###
637
638 dnl ** check for full ANSI header (.h) files
639 AC_HEADER_STDC
640
641 dnl ** Enable large file support.  NB. do this before testing the type of
642 dnl    off_t, because it will affect the result of that test.
643 AC_SYS_LARGEFILE
644
645 dnl ** check for specific header (.h) files that we are interested in
646 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/cpuset.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
647
648 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
649 AC_HEADER_TIME
650
651 dnl ** do we have long longs?
652 AC_CHECK_TYPES([long long])
653
654 dnl ** what are the sizes of various types
655 AC_CHECK_SIZEOF(char,               1)
656 AC_CHECK_SIZEOF(double,             8)
657 AC_CHECK_SIZEOF(float,              4)
658 AC_CHECK_SIZEOF(int,                4)
659 AC_CHECK_SIZEOF(long,               4)
660 if test "$ac_cv_type_long_long" = yes; then
661 AC_CHECK_SIZEOF(long long,          8)
662 fi
663 AC_CHECK_SIZEOF(short,              2)
664 AC_CHECK_SIZEOF(unsigned char,      1)
665 AC_CHECK_SIZEOF(unsigned int,       4)
666 AC_CHECK_SIZEOF(unsigned long,      4)
667 if test "$ac_cv_type_long_long" = yes; then
668 AC_CHECK_SIZEOF(unsigned long long, 8)
669 fi
670 AC_CHECK_SIZEOF(unsigned short,     2)
671 AC_CHECK_SIZEOF(void *,             4)
672
673 dnl ** what are alignment constraints on various types
674 FP_CHECK_ALIGNMENT(char)
675 FP_CHECK_ALIGNMENT(double)
676 FP_CHECK_ALIGNMENT(float)
677 FP_CHECK_ALIGNMENT(int)
678 FP_CHECK_ALIGNMENT(long)
679 if test "$ac_cv_type_long_long" = yes; then
680 FP_CHECK_ALIGNMENT(long long)
681 fi
682 FP_CHECK_ALIGNMENT(short)
683 FP_CHECK_ALIGNMENT(unsigned char)
684 FP_CHECK_ALIGNMENT(unsigned int)
685 FP_CHECK_ALIGNMENT(unsigned long)
686 if test "$ac_cv_type_long_long" = yes; then
687 FP_CHECK_ALIGNMENT(unsigned long long)
688 fi
689 FP_CHECK_ALIGNMENT(unsigned short)
690 FP_CHECK_ALIGNMENT(void *)
691
692 FP_CHECK_FUNC([WinExec],
693   [@%:@include <windows.h>], [WinExec("",0)])
694
695 FP_CHECK_FUNC([GetModuleFileName],
696   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
697
698 dnl ** check return type of signal handlers
699 dnl Foo: assumes we can use prototypes.
700 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
701 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
702 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
703 dnl #include <signal.h>
704 dnl #ifdef signal
705 dnl #undef signal
706 dnl #endif
707 dnl void (*signal (int, void (*)(int)))(int);
708 dnl ]],
709 dnl [[int i;]])],
710 dnl [ac_cv_type_signal_handler=void_int],
711 dnl [ac_cv_type_signal_handler=int_void])])
712 dnl if test "$ac_cv_type_signal_handler" = void_int; then
713 dnl AC_DEFINE(VOID_INT_SIGNALS)
714 dnl fi
715
716 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
717 AC_TYPE_SIGNAL
718 if test "$ac_cv_type_signal" = void; then
719   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
720 fi
721
722 dnl ** check for more functions
723 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
724 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
725
726 AC_TRY_RUN([
727 #include <sys/types.h>
728 #include <sys/time.h>
729 int main(void) {
730   struct itimerval tval;
731   tval.it_value.tv_sec = 1;
732   tval.it_value.tv_usec = 0;
733   tval.it_interval = tval.it_value;
734   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
735 }
736 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
737
738 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
739 dnl ** _POSIX_C_SOURCE is defined
740 AC_CHECK_DECLS([ctime_r], , ,
741 [#define _POSIX_SOURCE 1
742 #define _POSIX_C_SOURCE 199506L
743 #include <time.h>])
744
745 dnl ** check for mingwex library
746 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
747 AC_SUBST(HaveLibMingwEx)
748
749 if test $HaveLibMingwEx = YES ; then
750   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
751 fi
752
753 dnl ** check for math library
754 dnl    Keep that check as early as possible.
755 dnl    as we need to know whether we need libm
756 dnl    for math functions or not
757 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
758 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
759 if test $HaveLibM = YES
760 then
761   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
762 fi
763
764 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
765 dnl    the order of these tests matters: bfd needs liberty
766 AC_CHECK_LIB(iberty, xmalloc)
767 AC_CHECK_LIB(bfd,    bfd_uncompress_section_contents)
768
769 dnl ################################################################
770 dnl Check for libraries
771 dnl ################################################################
772
773 dnl ** check whether we need -ldl to get dlopen()
774
775 AC_CHECK_LIB(dl, dlopen,
776     [HaveLibDL=YES
777      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
778      LIBS="$LIBS -ldl"],
779     [HaveLibDL=NO])
780 AC_SUBST(HaveLibDL)
781
782 dnl --------------------------------------------------
783 dnl * Miscellaneous feature tests
784 dnl --------------------------------------------------
785
786 dnl ** can we get alloca?
787 AC_FUNC_ALLOCA
788
789 dnl ** Working vfork?
790 AC_FUNC_FORK
791
792 dnl ** determine whether or not const works
793 AC_C_CONST
794
795 dnl ** are we big endian?
796 AC_C_BIGENDIAN
797 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
798
799 dnl ** check for leading underscores in symbol names
800 FP_LEADING_UNDERSCORE
801
802 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
803 FP_PROG_LD_X
804 FP_PROG_LD_IS_GNU
805 FP_PROG_LD_BUILD_ID
806
807 dnl ** check for Apple-style dead-stripping support
808 dnl    (.subsections-via-symbols assembler directive)
809
810
811 AC_MSG_CHECKING(for .subsections_via_symbols)
812 AC_COMPILE_IFELSE(
813     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
814     [AC_MSG_RESULT(yes)
815      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
816                [Define to 1 if Apple-style dead-stripping is supported.])
817     ],
818     [AC_MSG_RESULT(no)])
819
820 dnl *** check for GNU non-executable stack note support (ELF only)
821 dnl     (.section .note.GNU-stack,"",@progbits)
822
823 dnl This test doesn't work with "gcc -g" in gcc 4.4 (GHC trac #3889:
824 dnl     Error: can't resolve `.note.GNU-stack' {.note.GNU-stack section} - `.Ltext0' {.text section}
825 dnl so we empty CFLAGS while running this test
826 CFLAGS2="$CFLAGS"
827 CFLAGS=
828 AC_MSG_CHECKING(for GNU non-executable stack support)
829 AC_COMPILE_IFELSE(
830     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
831     [AC_MSG_RESULT(yes)
832      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
833                [Define to 1 if GNU non-executable stack notes are supported.])
834     ],
835     [AC_MSG_RESULT(no)])
836 CFLAGS="$CFLAGS2"
837
838 FP_VISIBILITY_HIDDEN
839
840 dnl ** check for librt
841 AC_CHECK_LIB(rt, clock_gettime)
842 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
843 FP_CHECK_TIMER_CREATE
844
845 dnl ** check for Apple's "interesting" long double compatibility scheme
846 AC_MSG_CHECKING(for printf\$LDBLStub)
847 AC_TRY_LINK_FUNC(printf\$LDBLStub,
848     [
849         AC_MSG_RESULT(yes)
850         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
851             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
852     ],
853     [
854         AC_MSG_RESULT(no)
855         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
856             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
857     ])
858
859 dnl ** check for eventfd which is needed by the I/O manager
860 AC_CHECK_HEADERS([sys/eventfd.h])
861 AC_CHECK_FUNCS([eventfd])
862
863 # test for GTK+
864 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
865 if test -n "$GTK_CONFIG"; then
866   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
867     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
868   else
869     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
870     GTK_CONFIG=
871   fi
872 fi
873 AC_SUBST([GTK_CONFIG])
874
875 #Checking for PAPI
876 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
877 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
878 AC_SUBST(HavePapiLib)
879 AC_SUBST(HavePapiHeader)
880
881 AC_CHECK_FUNCS(__mingw_vfprintf)
882
883 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
884    HavePapi=YES
885 else
886    HavePapi=NO
887 fi
888 AC_SUBST(HavePapi)
889
890 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
891    test "$XsltprocCmd" = ""
892 then
893     BUILD_DOCBOOK_HTML=NO
894 else
895     BUILD_DOCBOOK_HTML=YES
896 fi
897 AC_SUBST(BUILD_DOCBOOK_HTML)
898
899 if test "$DblatexCmd" = ""
900 then
901     BUILD_DOCBOOK_PS=NO
902     BUILD_DOCBOOK_PDF=NO
903 else
904     BUILD_DOCBOOK_PS=YES
905     BUILD_DOCBOOK_PDF=YES
906 fi
907 AC_SUBST(BUILD_DOCBOOK_PS)
908 AC_SUBST(BUILD_DOCBOOK_PDF)
909
910 LIBRARY_VERSION(base)
911 LIBRARY_VERSION(Cabal)
912 LIBRARY_VERSION(ghc-prim)
913 LIBRARY_ghc_VERSION="$ProjectVersion"
914 AC_SUBST(LIBRARY_ghc_VERSION)
915
916 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
917    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
918 fi
919
920 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal ghc.spec settings docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/ghc.iss distrib/configure.ac])
921 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
922 AC_OUTPUT
923
924 # We get caught by
925 #     http://savannah.gnu.org/bugs/index.php?1516
926 #     $(eval ...) inside conditionals causes errors
927 # with make 3.80, so warn the user if it looks like they're about to
928 # try to use it.
929 # We would use "grep -q" here, but Solaris's grep doesn't support it.
930 checkMake380() {
931     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
932     then
933         echo
934         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
935         echo "This version cannot be used to build GHC."
936         echo "Please use GNU make >= 3.81."
937     fi
938 }
939
940 checkMake380 make
941 checkMake380 gmake
942
943 echo ["
944 ----------------------------------------------------------------------
945 Configure completed successfully.
946
947    Building GHC version  : $ProjectVersion
948
949    Build platform        : $BuildPlatform
950    Host platform         : $HostPlatform
951    Target platform       : $TargetPlatform
952 "]
953
954 if test "$BootingFromHc" = "YES"; then
955 echo ["\
956    Bootstrapping from HC files.
957 "]
958 else
959 echo ["\
960    Bootstrapping using   : $WithGhc
961       which is version   : $GhcVersion
962 "]
963 fi
964
965 echo ["\
966    Using GCC             : $WhatGccIsCalled
967       which is version   : $GccVersion
968
969    ld       : $LdCmd
970    Happy    : $HappyCmd ($HappyVersion)
971    Alex     : $AlexCmd ($AlexVersion)
972    Python   : $PythonCmd
973    Perl     : $PerlCmd
974    dblatex  : $DblatexCmd
975    xsltproc : $XsltprocCmd"]
976
977 if test "$HSCOLOUR" = ""; then
978 echo ["
979    HsColour was not found; documentation will not contain source links
980 "]
981 else
982 echo ["\
983    HsColour : $HSCOLOUR
984 "]
985 fi
986
987 echo ["\
988    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
989    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
990    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
991
992 echo ["----------------------------------------------------------------------
993 "]
994
995 echo "\
996 For a standard build of GHC (fully optimised with profiling), type (g)make.
997
998 To make changes to the default build configuration, copy the file
999 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1000
1001 For more information on how to configure your GHC build, see
1002    http://hackage.haskell.org/trac/ghc/wiki/Building
1003 "