Revert "Remove the Windows GCC driver."
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.3], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl this makes sure `./configure --target=<cross-compile-target>`
37 dnl works as expected, since we're slightly modifying how Autoconf
38 dnl interprets build/host/target and how this interacts with $CC tests
39 test -n "$target_alias" && ac_tool_prefix=$target_alias-
40
41 dnl ----------------------------------------------------------
42 dnl ** Find unixy sort and find commands,
43 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
44
45 dnl ** Find find command (for Win32's benefit)
46 FP_PROG_FIND
47 FP_PROG_SORT
48
49 dnl ----------------------------------------------------------
50 FP_SETUP_PROJECT_VERSION
51
52 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
53 AC_SUBST([release], [1])
54
55 # First off, a distrib sanity check..
56 AC_CONFIG_SRCDIR([mk/config.mk.in])
57
58 dnl * We require autoconf version 2.60
59 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
60 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
61 dnl Using autoconf 2.59 started to give nonsense like this
62 dnl  #define SIZEOF_CHAR 0
63 dnl recently.
64 AC_PREREQ([2.60])
65
66 # -------------------------------------------------------------------------
67 # Prepare to generate the following header files
68 #
69 #
70 AC_CONFIG_HEADER(mk/config.h)
71
72 # No, semi-sadly, we don't do `--srcdir'...
73 if test x"$srcdir" != 'x.' ; then
74     echo "This configuration does not support the \`--srcdir' option.."
75     exit 1
76 fi
77
78 dnl --------------------------------------------------------------
79 dnl * Project specific configuration options
80 dnl --------------------------------------------------------------
81 dnl What follows is a bunch of options that can either be configured
82 dnl through command line options to the configure script or by
83 dnl supplying defns in the build tree's mk/build.mk. Having the option to
84 dnl use either is considered a Feature.
85
86 dnl ** What command to use to compile compiler sources ?
87 dnl --------------------------------------------------------------
88
89 AC_ARG_WITH([ghc],
90 [AC_HELP_STRING([--with-ghc=ARG],
91   [Use ARG as the path to GHC  [default=autodetect]])],
92   [WithGhc="$withval"],
93   [if test "$GHC" = ""; then
94     AC_PATH_PROG([GHC], [ghc])
95   fi
96   WithGhc="$GHC"])
97
98 dnl ** Tell the make system which OS we are using
99 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
100 AC_SUBST(OSTYPE)
101
102 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
103 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
104                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
105         EnableBootstrapWithDevelSnaphost=YES,
106         EnableBootstrapWithDevelSnaphost=NO
107 )
108
109 AC_ARG_ENABLE(tarballs-autodownload,
110 [AC_HELP_STRING([--enable-tarballs-autodownload],
111                 [Automatically download Windows distribution binaries if needed.])],
112         TarballsAutodownload=YES,
113         TarballsAutodownload=NO
114 )
115
116 AC_ARG_ENABLE(distro-toolchain,
117 [AC_HELP_STRING([--enable-distro-toolchain],
118                 [Do not use bundled Windows toolchain binaries.])],
119         EnableDistroToolchain=YES,
120         EnableDistroToolchain=NO
121 )
122
123 if test "$EnableDistroToolchain" = "YES"; then
124   TarballsAutodownload=NO
125 fi
126
127 dnl CC_STAGE0 is like the "previous" variable CC (inherited by CC_STAGE[123])
128 dnl but instead used by stage0 for bootstrapping stage1
129 AC_ARG_VAR(CC_STAGE0, [C compiler command (bootstrap)])
130
131 if test "$WithGhc" != ""; then
132   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
133
134   if test "$GhcMajVersion" = "unknown" || test "$GhcMinVersion" = "unknown"; then
135      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
136   fi
137
138   AC_SUBST(GhcVersion)dnl
139   AC_SUBST(GhcMajVersion)dnl
140   AC_SUBST(GhcMinVersion)dnl
141   AC_SUBST(GhcPatchLevel)dnl
142   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
143   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
144
145   dnl infer CC_STAGE0 from `ghc --info` unless explicitly set by user
146   if test -z "$CC_STAGE0"; then
147     BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
148   fi
149
150   BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
151   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
152   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
153   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
154 fi
155
156 dnl ** Must have GHC to build GHC
157 if test "$WithGhc" = ""
158 then
159     AC_MSG_ERROR([GHC is required.])
160 fi
161 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.10],
162     [AC_MSG_ERROR([GHC version 7.10 or later is required to compile GHC.])])
163
164 if test `expr $GhcMinVersion % 2` = "1"
165 then
166     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
167     then
168         AC_MSG_ERROR([
169      $WithGhc is a development snapshot of GHC, version $GhcVersion.
170      Bootstrapping using this version of GHC is not supported, and may not
171      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
172      or --with-ghc to specify a different GHC to use.])
173     fi
174 fi
175
176 GHC_PACKAGE_DB_FLAG=package-db
177 AC_SUBST(GHC_PACKAGE_DB_FLAG)
178
179 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.11],
180                     SUPPORTS_THIS_UNIT_ID=NO,
181                     SUPPORTS_THIS_UNIT_ID=YES)
182 AC_SUBST(SUPPORTS_THIS_UNIT_ID)
183
184 # GHC is passed to Cabal, so we need a native path
185 if test "${WithGhc}" != ""
186 then
187     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
188
189     if test "$ghc_host_os" = "mingw32"
190     then
191         if test "${OSTYPE}" = "msys"
192         then
193             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
194         else
195             # Canonicalise to <drive>:/path/to/ghc
196             WithGhc=`cygpath -m "${WithGhc}"`
197         fi
198         echo "GHC path canonicalised to: ${WithGhc}"
199     fi
200 fi
201 AC_SUBST([WithGhc])
202
203 dnl ** Without optimization some INLINE trickery fails for GHCi
204 SRC_CC_OPTS="-O"
205
206 dnl--------------------------------------------------------------------
207 dnl * Choose host(/target/build) platform
208 dnl--------------------------------------------------------------------
209 dnl If we aren't explicitly told what values to use with configure flags,
210 dnl we ask the bootstrapping compiler what platform it is for
211
212 if test "${WithGhc}" != ""
213 then
214         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
215         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
216         if test "$bootstrap_host" != "$bootstrap_target"
217         then
218                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
219         fi
220 fi
221
222 # We have to run these unconditionally, but we may discard their
223 # results in the following code
224 AC_CANONICAL_BUILD
225 AC_CANONICAL_HOST
226 AC_CANONICAL_TARGET
227
228 FPTOOLS_SET_PLATFORM_VARS
229
230 # Verify that the installed (bootstrap) GHC is capable of generating
231 # code for the requested build platform.
232 if test "$BuildPlatform" != "$bootstrap_target"
233 then
234     echo "This GHC (${WithGhc}) does not generate code for the build platform"
235     echo "   GHC target platform    : $bootstrap_target"
236     echo "   Desired build platform : $BuildPlatform"
237     exit 1
238 fi
239
240 # Testing if we shall enable shared libs support on Solaris.
241 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
242
243 SOLARIS_BROKEN_SHLD=NO
244
245 case $host in
246      i386-*-solaris2)
247      # here we go with the test
248      MINOR=`uname -r|cut -d '.' -f 2-`
249      if test "$MINOR" -lt "11"; then
250          SOLARIS_BROKEN_SHLD=YES
251      fi
252      ;;
253 esac
254
255 AC_SUBST(SOLARIS_BROKEN_SHLD)
256
257 dnl ** Do an unregisterised build?
258 dnl --------------------------------------------------------------
259 case "$TargetArch" in
260     i386|x86_64|powerpc|powerpc64|powerpc64le|arm|aarch64)
261         UnregisterisedDefault=NO
262         ;;
263     *)
264         UnregisterisedDefault=YES
265         ;;
266 esac
267 AC_ARG_ENABLE(unregisterised,
268 [AC_HELP_STRING([--enable-unregisterised],
269 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
270 [ if test x"$enableval" = x"yes"; then
271         Unregisterised=YES
272   else
273         Unregisterised=NO
274   fi
275 ],
276 [Unregisterised="$UnregisterisedDefault"]
277 )
278 AC_SUBST(Unregisterised)
279
280 dnl ** Does target have runtime linker support?
281 dnl --------------------------------------------------------------
282 case "$target" in
283     powerpc64-*|powerpc64le-*|powerpc-ibm-aix*)
284         HaskellHaveRTSLinker=NO
285         ;;
286     *)
287         HaskellHaveRTSLinker=YES
288         ;;
289 esac
290 AC_SUBST(HaskellHaveRTSLinker)
291
292 # Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
293 FP_FIND_ROOT
294
295 fail() {
296     echo >&2
297     echo "$1" >&2
298     exit 1
299 }
300
301
302 if test "$HostOS" = "mingw32"
303 then
304     # Find the mingw-w64 7z file to extract.
305     # NB. If you update the tarballs to a new version of gcc, don't
306     # forget to tweak the paths in driver/gcc/gcc.c.
307     if test "$HostArch" = "i386"
308     then
309         mingw_arch="i686"
310         tarball_dest_dir="mingw-w64/x86"
311         tarball_mingw_dir="mingw32"
312     else
313         mingw_arch="x86_64"
314         tarball_dest_dir="mingw-w64/x86_64"
315         tarball_mingw_dir="mingw64"
316     fi
317 fi
318
319 set_up_tarballs() {
320     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
321     local action
322     if test "$TarballsAutodownload" = "NO"
323     then
324         action="verify"
325     else
326         action="download"
327     fi
328     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
329     case $? in
330         0)
331            rm missing-win32-tarballs
332            ;;
333         2)
334            echo
335            echo "Error:"
336            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
337            echo
338            echo "  * run configure with the --enable-tarballs-autodownload option"
339            echo
340            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
341            echo
342            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
343            echo "    them in the ghc-tarballs directory."
344            echo
345            exit 1
346            ;;
347         *)
348            echo
349            echo "Error fetching msys2 tarballs; see errors above."
350            exit 1
351            ;;
352     esac
353
354     # Extract all the tarballs in one go
355     if ! test -d inplace/mingw
356     then
357         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
358         rm -rf inplace/mingw
359         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
360         ( cd inplace &&
361         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
362         rm ".MTREE" &&
363         rm ".PKGINFO" &&
364         cd .. ) || fail "Error: Could not extract Windows toolchains."
365
366         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
367         touch inplace/mingw
368
369         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
370         # make a wrapper around it to give it the proper paths
371         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
372         PATH=`pwd`/inplace/mingw/bin:$PATH
373         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
374
375         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
376     fi
377 }
378
379 if test "$HostOS" = "mingw32" -a "$EnableDistroToolchain" = "NO"
380 then
381     test -d inplace || mkdir inplace
382
383     # NB. Download and extract the MingW-w64 distribution if required
384     set_up_tarballs
385
386     mingwbin="$hardtop/inplace/mingw/bin/"
387     CC="${mingwbin}gcc.exe"
388     LD="${mingwbin}ld.exe"
389     NM="${mingwbin}nm.exe"
390     RANLIB="${mingwbin}ranlib.exe"
391     OBJDUMP="${mingwbin}objdump.exe"
392     fp_prog_ar="${mingwbin}ar.exe"
393
394     # NB. Download the perl binaries if required
395     if ! test -d inplace/perl ||
396          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
397     then
398         AC_MSG_NOTICE([Making in-tree perl tree])
399         rm -rf inplace/perl
400         mkdir inplace/perl
401         (
402             cd inplace/perl &&
403             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
404         )
405         AC_MSG_NOTICE([In-tree perl tree created])
406     fi
407 fi
408
409 # We don't want to bundle a MinGW-w64 toolchain
410 # So we have to find these individual tools.
411 if test "$EnableDistroToolchain" = "YES"
412 then
413     # Ideally should use AC_CHECK_TARGET_TOOL but our triples
414     # are screwed up. Configure doesn't think they're ever equal and
415     # so never tried without the prefix.
416     AC_PATH_PROG([CC],[gcc], [clang])
417     AC_PATH_PROG([LD],[ld], [lld])
418     AC_PATH_PROG([NM],[nm])
419     AC_PATH_PROG([AR],[ar])
420     AC_PATH_PROG([RANLIB],[ranlib])
421     AC_PATH_PROG([OBJDUMP],[objdump])
422     AC_PATH_PROG([DllWrap],[dllwrap])
423     AC_PATH_PROG([Windres],[windres])
424
425     DllWrapCmd="$DllWrap"
426     WindresCmd="$Windres"
427
428     AC_SUBST([DllWrapCmd])
429     AC_SUBST([WindresCmd])
430 fi
431
432 FP_ICONV
433 FP_GMP
434 FP_CURSES
435
436 XCODE_VERSION()
437
438
439 dnl ** Building a cross compiler?
440 dnl --------------------------------------------------------------
441 CrossCompiling=NO
442 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
443 if test "$TargetPlatform" != "$HostPlatform" ; then
444     CrossCompiling=YES
445     cross_compiling=yes   # This tells configure that it can accept just 'target',
446                           # otherwise you get
447                           #   configure: error: cannot run C compiled programs.
448                           #   If you meant to cross compile, use `--host'.
449 fi
450 if test "$BuildPlatform" != "$HostPlatform" ; then
451    AC_MSG_ERROR([
452 You've selected:
453
454   BUILD:  $BuildPlatform   (the architecture we're building on)
455   HOST:   $HostPlatform    (the architecture the compiler we're building will execute on)
456   TARGET: $TargetPlatform  (the architecture the compiler we're building will produce code for)
457
458 BUILD must equal HOST; that is, we do not support building GHC itself
459 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
460 1 will be a cross-compiler, and stage 2 will be the cross-compiled
461 GHC.
462 ])
463 fi
464 # Despite its similarity in name to TargetPlatform, TargetPlatformFull is used
465 # in calls to subproject configure scripts and thus must be set to the autoconf
466 # triple, not the normalized GHC triple that TargetPlatform is set to.
467 #
468 # We use the non-canonicalized triple, target_alias, here since the subproject
469 # configure scripts will use this triple to construct the names of the toolchain
470 # executables. If we instead passed down the triple produced by
471 # AC_CANONICAL_TARGET then it may look for the target toolchain under the wrong
472 # name (this is a known problem in the case of the Android NDK, which has
473 # slightly odd triples).
474 #
475 # It may be better to just do away with the GHC triples altogether. This would
476 # all be taken care of for us if we configured the subprojects using
477 # AC_CONFIG_DIR, but unfortunately Cabal needs to be the one to do the
478 # configuration.
479 #
480 # We also use non-canonicalized triple when install stage1 crosscompiler
481 if test -z "${target_alias}"
482 then
483   # --target wasn't given; use result from AC_CANONICAL_TARGET
484   TargetPlatformFull="${target}"
485 else
486   TargetPlatformFull="${target_alias}"
487 fi
488 if test "$CrossCompiling" = "YES"
489 then
490   # Use value passed by user from --target=
491   CrossCompilePrefix="${TargetPlatformFull}-"
492 else
493   CrossCompilePrefix=""
494 fi
495 AC_SUBST(CrossCompiling)
496 AC_SUBST(CrossCompilePrefix)
497 AC_SUBST(TargetPlatformFull)
498 AC_SUBST(EnableDistroToolchain)
499
500 dnl ** Which gcc to use?
501 dnl --------------------------------------------------------------
502
503 AC_ARG_WITH([gcc],
504         AS_HELP_STRING([--with-gcc=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
505         AC_MSG_ERROR([--with-gcc=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
506
507 AC_ARG_WITH([clang],
508         AS_HELP_STRING([--with-clang=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
509         AC_MSG_ERROR([--with-clang=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
510
511 dnl detect compiler (prefer gcc over clang) and set $CC (unless CC already set),
512 dnl later CC is copied to CC_STAGE{1,2,3}
513 AC_PROG_CC([gcc clang])
514
515 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
516
517 dnl make extensions visible to allow feature-tests to detect them lateron
518 AC_USE_SYSTEM_EXTENSIONS
519
520 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
521 AC_PROG_CPP
522
523 # --with-hs-cpp/--with-hs-cpp-flags
524 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
525 AC_SUBST([HaskellCPPCmd])
526 AC_SUBST([HaskellCPPArgs])
527
528 FP_SET_CFLAGS_C99([CC],[CFLAGS],[CPPFLAGS])
529 FP_SET_CFLAGS_C99([CC_STAGE0],[CONF_CC_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
530 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
531 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
532
533 dnl ** Which ld to use?
534 dnl --------------------------------------------------------------
535 FIND_LD([$target],[LdCmd])
536 AC_SUBST([LdCmd])
537
538 dnl ** Which nm to use?
539 dnl --------------------------------------------------------------
540 if test "$HostOS" != "mingw32"; then
541     AC_CHECK_TARGET_TOOL([NM], [nm])
542     if test "$NM" = ":"; then
543         AC_MSG_ERROR([cannot find nm in your PATH])
544     fi
545 fi
546 NmCmd="$NM"
547 AC_SUBST([NmCmd])
548
549 if test "$TargetOS_CPP" = "darwin"
550 then
551     AC_MSG_CHECKING(whether nm program is broken)
552     # Some versions of XCode ship a broken version of `nm`. Detect and work
553     # around this issue. See : https://ghc.haskell.org/trac/ghc/ticket/11744
554     nmver=$(${NM} --version | grep version | sed 's/ //g')
555     case "$nmver" in
556         LLVMversion7.3.0|LLVMversion7.3.1)
557             AC_MSG_RESULT(yes)
558             echo "The detected nm program is broken."
559             echo
560             echo "See: https://ghc.haskell.org/trac/ghc/ticket/11744"
561             echo
562             echo "Try re-running configure with:"
563             echo
564             echo '   NM=$(xcrun --find nm-classic) ./configure'
565             echo
566             exit 1
567             ;;
568         *)
569             AC_MSG_RESULT(no)
570             ;;
571         esac
572 fi
573
574 dnl ** Which objdump to use?
575 dnl --------------------------------------------------------------
576 dnl Note: we may not have objdump on OS X, and we only need it on
577 dnl Windows (for DLL checks), OpenBSD, and AIX
578 case $HostOS_CPP in
579   cygwin32|mingw32|openbsd|aix)
580     AC_CHECK_TARGET_TOOL([OBJDUMP], [objdump])
581     ;;
582 esac
583
584 ObjdumpCmd="$OBJDUMP"
585 AC_SUBST([ObjdumpCmd])
586
587 dnl ** Which ar to use?
588 dnl --------------------------------------------------------------
589 if test "$HostOS" != "mingw32"; then
590     AC_CHECK_TARGET_TOOL([AR], [ar])
591     if test "$AR" = ":"; then
592         AC_MSG_ERROR([cannot find ar in your PATH])
593     fi
594 fi
595 ArCmd="$AR"
596 fp_prog_ar="$AR"
597 AC_SUBST([ArCmd])
598
599 dnl ** Which ranlib to use?
600 dnl --------------------------------------------------------------
601 AC_PROG_RANLIB
602 if test "$RANLIB" = ":"; then
603     AC_MSG_ERROR([cannot find ranlib in your PATH])
604 fi
605 RanlibCmd="$RANLIB"
606 RANLIB="$RanlibCmd"
607
608 dnl ** which libtool to use?
609 dnl --------------------------------------------------------------
610 AC_CHECK_TARGET_TOOL([LIBTOOL], [libtool])
611 LibtoolCmd="$LIBTOOL"
612 LIBTOOL="$LibtoolCmd"
613
614 # Here is where we re-target which specific version of the LLVM
615 # tools we are looking for. In the past, GHC supported a number of
616 # versions of LLVM simultaneously, but that stopped working around
617 # 3.5/3.6 release of LLVM.
618 LlvmVersion=4.0
619 AC_SUBST([LlvmVersion])
620 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
621 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
622
623 dnl ** Which LLVM llc to use?
624 dnl --------------------------------------------------------------
625 FIND_LLVM_PROG([LLC], [llc], [$LlvmVersion])
626 LlcCmd="$LLC"
627 AC_SUBST([LlcCmd])
628
629 dnl ** Which LLVM opt to use?
630 dnl --------------------------------------------------------------
631 FIND_LLVM_PROG([OPT], [opt], [$LlvmVersion])
632 OptCmd="$OPT"
633 AC_SUBST([OptCmd])
634
635 dnl --------------------------------------------------------------
636 dnl End of configure script option section
637 dnl --------------------------------------------------------------
638
639
640 dnl --------------------------------------------------------------
641 dnl ** Can the unix package be built?
642 dnl --------------------------------------------------------------
643
644 if test "$TargetOS" = "mingw32"
645 then
646     GhcLibsWithUnix=NO
647 else
648     GhcLibsWithUnix=YES
649 fi
650 AC_SUBST([GhcLibsWithUnix])
651
652 dnl ** does #! work?
653 AC_SYS_INTERPRETER()
654
655 # Check for split-objs
656 SplitObjsBroken=NO
657 dnl ** look for `perl'
658 case $HostOS_CPP in
659 cygwin32|mingw32)
660   if test "$EnableDistroToolchain" = "NO"; then
661     PerlCmd=$hardtop/inplace/perl/perl
662   else
663     AC_PATH_PROG([PerlCmd],[perl])
664   fi
665   ;;
666 *)
667     AC_PATH_PROG([PerlCmd],[perl])
668     if test -z "$PerlCmd"
669     then
670         AC_MSG_WARN([No Perl on PATH, disabling split object support])
671         SplitObjsBroken=YES
672     else
673         FPTOOLS_CHECK_PERL_VERSION
674     fi
675     ;;
676 esac
677 AC_SUBST([SplitObjsBroken])
678
679 dnl ** look for GCC and find out which version
680 dnl     Figure out which C compiler to use.  Gcc is preferred.
681 dnl     If gcc, make sure it's at least 3.0
682 dnl
683 FP_GCC_VERSION
684
685 dnl ** See whether gcc supports -no-pie
686 FP_GCC_SUPPORTS_NO_PIE
687
688 dnl ** look to see if we have a C compiler using an llvm back end.
689 dnl
690 FP_CC_LLVM_BACKEND
691
692 FP_PROG_LD_IS_GNU
693 FP_PROG_LD_BUILD_ID
694 FP_PROG_LD_NO_COMPACT_UNWIND
695 FP_PROG_LD_FILELIST
696
697
698 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
699 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
700 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
701 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
702 # Stage 3 won't be supported by cross-compilation
703
704 FP_GCC_EXTRA_FLAGS
705
706 # See rules/distdir-way-opts.mk for details.
707 # Flags passed to the C compiler
708 AC_SUBST(CONF_CC_OPTS_STAGE0)
709 AC_SUBST(CONF_CC_OPTS_STAGE1)
710 AC_SUBST(CONF_CC_OPTS_STAGE2)
711 # Flags passed to the C compiler when we ask it to link
712 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
713 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
714 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
715 # Flags passed to the linker when we ask it to link
716 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
717 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
718 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
719 # Flags passed to the C preprocessor
720 AC_SUBST(CONF_CPP_OPTS_STAGE0)
721 AC_SUBST(CONF_CPP_OPTS_STAGE1)
722 AC_SUBST(CONF_CPP_OPTS_STAGE2)
723 # Flags passed to the Haskell compiler
724 AC_SUBST(CONF_HC_OPTS_STAGE0)
725 AC_SUBST(CONF_HC_OPTS_STAGE1)
726 AC_SUBST(CONF_HC_OPTS_STAGE2)
727
728 dnl ** Set up the variables for the platform in the settings file.
729 dnl May need to use gcc to find platform details.
730 dnl --------------------------------------------------------------
731 FPTOOLS_SET_HASKELL_PLATFORM_VARS
732
733 dnl ** figure out how to do context diffs
734 FP_PROG_CONTEXT_DIFF
735
736 dnl Let's make sure install-sh is executable here.  If we got it from
737 dnl a darcs repo, it might not be (see bug #978).
738 chmod +x install-sh
739 dnl ** figure out how to do a BSD-ish install
740 AC_PROG_INSTALL
741
742 dnl ** how to invoke `ar' and `ranlib'
743 FP_PROG_AR_SUPPORTS_ATFILE
744 FP_PROG_AR_NEEDS_RANLIB
745
746 dnl ** Check to see whether ln -s works
747 AC_PROG_LN_S
748
749 FP_SETTINGS
750
751 dnl ** Find the path to sed
752 AC_PATH_PROGS(SedCmd,gsed sed,sed)
753
754
755 dnl ** check for time command
756 AC_PATH_PROG(TimeCmd,time)
757
758 dnl ** check for tar
759 dnl   if GNU tar is named gtar, look for it first.
760 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
761
762 dnl ** check for compressors
763 AC_PATH_PROGS(Bzip2Cmd,bzip2, bzip2)
764 AC_PATH_PROGS(GzipCmd,gzip, gzip)
765 AC_PATH_PROGS(XzCmd,pxz xz, xz)
766
767 dnl ** check for patch
768 dnl if GNU patch is named gpatch, look for it first
769 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
770
771 dnl ** check for dtrace (currently only implemented for Mac OS X)
772 HaveDtrace=NO
773 AC_PATH_PROG(DtraceCmd,dtrace)
774 if test -n "$DtraceCmd"; then
775   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
776     HaveDtrace=YES
777   fi
778 fi
779 AC_SUBST(HaveDtrace)
780
781 AC_PATH_PROG(HSCOLOUR,HsColour)
782 # HsColour is passed to Cabal, so we need a native path
783 if test "$HostOS"      = "mingw32" && \
784    test "${OSTYPE}"   != "msys"    && \
785    test "${HSCOLOUR}" != ""
786 then
787     # Canonicalise to <drive>:/path/to/gcc
788     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
789 fi
790
791 dnl ** check for Sphinx toolchain
792 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
793 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
794 changequote(, )dnl
795 [if test -n "$SPHINXBUILD"; then
796   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
797 fi;
798 changequote([, ])dnl
799 ])
800 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
801     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
802
803 dnl ** check for xelatex
804 AC_PATH_PROG(XELATEX,xelatex)
805
806 dnl ** check for ghc-pkg command
807 FP_PROG_GHC_PKG
808
809 dnl ** check for installed happy binary + version
810 FPTOOLS_HAPPY
811
812 dnl ** check for installed alex binary + version
813 FPTOOLS_ALEX
814
815 dnl --------------------------------------------------
816 dnl ### program checking section ends here ###
817 dnl --------------------------------------------------
818
819 dnl --------------------------------------------------
820 dnl * Platform header file and syscall feature tests
821 dnl ### checking the state of the local header files and syscalls ###
822
823 dnl ** check for full ANSI header (.h) files
824 AC_HEADER_STDC
825
826 dnl ** Enable large file support.  NB. do this before testing the type of
827 dnl    off_t, because it will affect the result of that test.
828 AC_SYS_LARGEFILE
829
830 dnl ** check for specific header (.h) files that we are interested in
831 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
832
833 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
834 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
835 [[#if HAVE_SYS_PARAM_H
836 # include <sys/param.h>
837 #endif
838 ]])
839
840 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
841 AC_HEADER_TIME
842
843 dnl ** do we have long longs?
844 AC_CHECK_TYPES([long long])
845
846 dnl ** what are the sizes of various types
847 FP_CHECK_SIZEOF_AND_ALIGNMENT(char)
848 FP_CHECK_SIZEOF_AND_ALIGNMENT(double)
849 FP_CHECK_SIZEOF_AND_ALIGNMENT(float)
850 FP_CHECK_SIZEOF_AND_ALIGNMENT(int)
851 FP_CHECK_SIZEOF_AND_ALIGNMENT(long)
852 if test "$ac_cv_type_long_long" = yes; then
853 FP_CHECK_SIZEOF_AND_ALIGNMENT(long long)
854 fi
855 FP_CHECK_SIZEOF_AND_ALIGNMENT(short)
856 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned char)
857 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned int)
858 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long)
859 if test "$ac_cv_type_long_long" = yes; then
860 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long long)
861 fi
862 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned short)
863 FP_CHECK_SIZEOF_AND_ALIGNMENT(void *)
864
865 FP_CHECK_SIZEOF_AND_ALIGNMENT(int8_t)
866 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint8_t)
867 FP_CHECK_SIZEOF_AND_ALIGNMENT(int16_t)
868 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint16_t)
869 FP_CHECK_SIZEOF_AND_ALIGNMENT(int32_t)
870 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint32_t)
871 FP_CHECK_SIZEOF_AND_ALIGNMENT(int64_t)
872 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint64_t)
873
874
875 dnl for use in settings.in
876 WordSize=$ac_cv_sizeof_void_p
877 AC_SUBST(WordSize)
878 FP_CHECK_FUNC([WinExec],
879   [@%:@include <windows.h>], [WinExec("",0)])
880
881 FP_CHECK_FUNC([GetModuleFileName],
882   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
883
884 dnl ** check for more functions
885 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
886 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
887
888 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
889 dnl ** _POSIX_C_SOURCE is defined
890 AC_CHECK_DECLS([ctime_r], , ,
891 [#define _POSIX_SOURCE 1
892 #define _POSIX_C_SOURCE 199506L
893 #include <time.h>])
894
895 dnl ** check for mingwex library
896 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
897 AC_SUBST(HaveLibMingwEx)
898
899 if test $HaveLibMingwEx = YES ; then
900   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
901 fi
902
903 dnl ** check for math library
904 dnl    Keep that check as early as possible.
905 dnl    as we need to know whether we need libm
906 dnl    for math functions or not
907 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
908 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
909 if test $HaveLibM = YES
910 then
911   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
912 fi
913
914 FP_BFD_SUPPORT
915
916 dnl ################################################################
917 dnl Check for libraries
918 dnl ################################################################
919
920 # system libffi
921
922 AC_ARG_WITH([system-libffi],
923 [AC_HELP_STRING([--with-system-libffi],
924   [Use system provided libffi for RTS [default=no]])
925 ])
926
927 AS_IF([test "x$with_system_libffi" = "xyes"],
928   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
929 )
930
931
932 AC_SUBST(UseSystemLibFFI)
933
934 AC_ARG_WITH([ffi-includes],
935 [AC_HELP_STRING([--with-ffi-includes=ARG],
936   [Find includes for libffi in ARG [default=system default]])
937 ],
938 [
939  if test "x$UseSystemLibFFI" != "xYES"; then
940     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
941  else
942     FFIIncludeDir="$withval"
943     LIBFFI_CFLAGS="-I$withval"
944  fi
945 ])
946
947 AC_SUBST(FFIIncludeDir)
948
949 AC_ARG_WITH([ffi-libraries],
950 [AC_HELP_STRING([--with-ffi-libraries=ARG],
951   [Find libffi in ARG [default=system default]])
952 ],
953 [
954  if test "x$UseSystemLibFFI" != "xYES"; then
955     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
956  else
957     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
958  fi
959 ])
960
961 AC_SUBST(FFILibDir)
962
963 AS_IF([test "$UseSystemLibFFI" = "YES"], [
964  CFLAGS2="$CFLAGS"
965  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
966  LDFLAGS2="$LDFLAGS"
967  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
968  if test "$HostOS" = "openbsd";
969  then
970    # OpenBSD's libffi is not directly linked to the libpthread but
971    # still requires pthread functionality. This means that any client
972    # binary which links with libffi also needs to link with
973    # libpthread. If it does not, then linking fails with unresolved
974    # symbols.
975    LDFLAGS="$LDFLAGS -lpthread"
976  fi
977  AC_CHECK_LIB(ffi, ffi_call,
978   [AC_CHECK_HEADERS([ffi.h], [break], [])
979    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
980   [AC_MSG_ERROR([Cannot find system libffi])])
981  CFLAGS="$CFLAGS2"
982  LDFLAGS="$LDFLAGS2"
983 ])
984
985 dnl ** check whether we need -ldl to get dlopen()
986 AC_CHECK_LIB(dl, dlopen)
987
988 dnl --------------------------------------------------
989 dnl * Miscellaneous feature tests
990 dnl --------------------------------------------------
991
992 dnl ** can we get alloca?
993 AC_FUNC_ALLOCA
994
995 dnl ** working vfork?
996 AC_FUNC_FORK
997
998 dnl ** determine whether or not const works
999 AC_C_CONST
1000
1001 dnl ** are we big endian?
1002 AC_C_BIGENDIAN
1003 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
1004
1005 dnl ** check for leading underscores in symbol names
1006 FP_LEADING_UNDERSCORE
1007
1008 FP_VISIBILITY_HIDDEN
1009
1010 dnl ** check for librt
1011 AC_CHECK_LIB(rt, clock_gettime)
1012 AC_CHECK_FUNCS(clock_gettime timer_settime)
1013 FP_CHECK_TIMER_CREATE
1014
1015 dnl ** check for Apple's "interesting" long double compatibility scheme
1016 AC_MSG_CHECKING(for printf\$LDBLStub)
1017 AC_TRY_LINK_FUNC(printf\$LDBLStub,
1018     [
1019         AC_MSG_RESULT(yes)
1020         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
1021             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
1022     ],
1023     [
1024         AC_MSG_RESULT(no)
1025         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
1026             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
1027     ])
1028
1029 dnl Some platforms (e.g. Android's Bionic) have pthreads support available
1030 dnl without linking against libpthread. Check whether -lpthread is necessary
1031 dnl to use pthreads.
1032 dnl
1033 dnl Note that it is important that this happens before we AC_CHECK_LIB(thread)
1034 AC_MSG_CHECKING(whether -lpthread is needed for pthreads)
1035 AC_CHECK_FUNC(pthread_create,
1036     [
1037         AC_MSG_RESULT(no)
1038         need_lpthread=0
1039     ],
1040     [
1041         AC_CHECK_LIB(pthread, pthread_create,
1042             [
1043                 AC_MSG_RESULT(yes)
1044                 need_lpthread=1
1045             ],
1046             [
1047                 AC_MSG_RESULT([no pthreads support found.])
1048                 need_lpthread=0
1049             ])
1050     ])
1051 AC_DEFINE_UNQUOTED([NEED_PTHREAD_LIB], [$need_lpthread],
1052     [Define 1 if we need to link code using pthreads with -lpthread])
1053
1054 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
1055 dnl    a different single-argument version.
1056 AC_CHECK_LIB(pthread, pthread_setname_np)
1057 AC_MSG_CHECKING(for pthread_setname_np)
1058 AC_TRY_LINK(
1059 [
1060 #define _GNU_SOURCE
1061 #include <pthread.h>
1062 ],
1063 [pthread_setname_np(pthread_self(), "name");],
1064     AC_MSG_RESULT(yes)
1065     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
1066       [Define to 1 if you have the glibc version of pthread_setname_np]),
1067     AC_MSG_RESULT(no)
1068 )
1069
1070 dnl ** check for eventfd which is needed by the I/O manager
1071 AC_CHECK_HEADERS([sys/eventfd.h])
1072 AC_CHECK_FUNCS([eventfd])
1073
1074 dnl ** Check for __thread support in the compiler
1075 AC_MSG_CHECKING(for __thread support)
1076 AC_COMPILE_IFELSE(
1077   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
1078   [
1079    AC_MSG_RESULT(yes)
1080    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1081   ],
1082   [
1083    AC_MSG_RESULT(no)
1084    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1085   ])
1086
1087 dnl large address space support (see includes/rts/storage/MBlock.h)
1088 dnl
1089 dnl Darwin has vm_allocate/vm_protect
1090 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1091 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1092 dnl (They also have MADV_DONTNEED, but it means something else!)
1093 dnl
1094 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1095 dnl it counts page-table space as committed memory, and so quickly
1096 dnl runs out of paging file when we have multiple processes reserving
1097 dnl 1TB of address space, we get the following error:
1098 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1099 dnl
1100
1101 AC_ARG_ENABLE(large-address-space,
1102     [AC_HELP_STRING([--enable-large-address-space],
1103         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1104     EnableLargeAddressSpace=$enableval,
1105     EnableLargeAddressSpace=yes
1106 )
1107
1108 use_large_address_space=no
1109 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1110     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1111         if test "$ghc_host_os" = "darwin" ; then
1112             use_large_address_space=yes
1113         elif test "$ghc_host_os" = "openbsd" ; then
1114             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1115             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1116             # but is completely ignored by OS mmap
1117             use_large_address_space=no
1118         else
1119             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1120                 [
1121                 #include <unistd.h>
1122                 #include <sys/types.h>
1123                 #include <sys/mman.h>
1124                 #include <fcntl.h>
1125             ])
1126             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1127                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1128                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1129                     use_large_address_space=yes
1130             fi
1131         fi
1132     fi
1133 fi
1134 if test "$use_large_address_space" = "yes" ; then
1135    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1136 fi
1137
1138 dnl ** Use MMAP in the runtime linker?
1139 dnl --------------------------------------------------------------
1140
1141 case ${TargetOS} in
1142     linux|linux-android|freebsd|dragonfly|netbsd|openbsd|kfreebsdgnu|gnu|solaris2)
1143         RtsLinkerUseMmap=1
1144         ;;
1145     darwin|ios)
1146         # Don't use mmap on powerpc/darwin as the mmap there doesn't support
1147         # reallocating. Reallocating is needed to allocate jump islands just
1148         # after each object image. Jumps to these jump islands use relative
1149         # branches which are limited to offsets that can be represented in
1150         # 24-bits.
1151         if test "$TargetArch" != "powerpc" ; then
1152             RtsLinkerUseMmap=1
1153         else
1154             RtsLinkerUseMmap=0
1155         fi
1156         ;;
1157     *)
1158         # Windows (which doesn't have mmap) and everything else.
1159         RtsLinkerUseMmap=0
1160         ;;
1161     esac
1162
1163 AC_DEFINE_UNQUOTED([RTS_LINKER_USE_MMAP], [$RtsLinkerUseMmap],
1164                    [Use mmap in the runtime linker])
1165
1166 dnl ** Have libdw?
1167 dnl --------------------------------------------------------------
1168 UseLibdw=NO
1169 USE_LIBDW=0
1170 AC_ARG_ENABLE(dwarf-unwind,
1171     [AC_HELP_STRING([--enable-dwarf-unwind],
1172         [Enable DWARF unwinding support in the runtime system via elfutils' libdw [default=no]])],
1173     [AC_CHECK_LIB(dw, dwfl_attach_state, [UseLibdw=YES], [UseLibdw=NO])],
1174     [UseLibdw=NO]
1175 )
1176 AC_SUBST(UseLibdw)
1177 if test $UseLibdw = "YES" ; then
1178         USE_LIBDW=1
1179 fi
1180 AC_DEFINE_UNQUOTED([USE_LIBDW], [$USE_LIBDW], [Set to 1 to use libdw])
1181
1182 dnl ** Have libnuma?
1183 dnl --------------------------------------------------------------
1184 HaveLibNuma=0
1185 AC_CHECK_HEADERS([numa.h numaif.h])
1186
1187 if test "$ac_cv_header_numa_h$ac_cv_header_numaif_h" = "yesyes" ; then
1188     AC_CHECK_LIB(numa, numa_available,HaveLibNuma=1)
1189 fi
1190 AC_DEFINE_UNQUOTED([HAVE_LIBNUMA], [$HaveLibNuma], [Define to 1 if you have libnuma])
1191
1192 dnl ** Documentation
1193 dnl --------------------------------------------------------------
1194 if test -n "$SPHINXBUILD"; then
1195     BUILD_MAN=YES
1196     BUILD_SPHINX_HTML=YES
1197     if test -n "$XELATEX"; then
1198         BUILD_SPHINX_PDF=YES
1199     else
1200         BUILD_SPHINX_PDF=NO
1201     fi
1202 else
1203     BUILD_MAN=NO
1204     BUILD_SPHINX_HTML=NO
1205     BUILD_SPHINX_PDF=NO
1206 fi
1207 AC_SUBST(BUILD_MAN)
1208 AC_SUBST(BUILD_SPHINX_HTML)
1209 AC_SUBST(BUILD_SPHINX_PDF)
1210
1211 LIBRARY_VERSION(base)
1212 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1213 LIBRARY_VERSION(ghc-prim)
1214 LIBRARY_VERSION(ghc-compact)
1215 LIBRARY_ghc_VERSION="$ProjectVersion"
1216 AC_SUBST(LIBRARY_ghc_VERSION)
1217
1218 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1219    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1220 fi
1221
1222 # Create the configuration for the Hadrian build system if it is present
1223 if test -e hadrian/cfg/system.config.in; then
1224     AC_CONFIG_FILES([hadrian/cfg/system.config])
1225 fi
1226
1227 # We got caught by
1228 #     http://savannah.gnu.org/bugs/index.php?1516
1229 #     $(eval ...) inside conditionals causes errors
1230 # with make 3.80, so warn the user if it looks like they're about to
1231 # try to use it.
1232 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1233 print_make_warning=""
1234 checkMake380() {
1235     make_ver=`$1 --version 2>&1 | head -1`
1236     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1237     then
1238         print_make_warning="true"
1239     fi
1240     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1241     then
1242         MakeCmd=$1
1243         AC_SUBST(MakeCmd)
1244     fi
1245 }
1246
1247 checkMake380 make
1248 checkMake380 gmake
1249
1250 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghc-boot-th/ghc-boot-th.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt utils/mkUserGuidePart/mkUserGuidePart.cabal distrib/configure.ac])
1251 AC_OUTPUT
1252 [
1253 if test "$print_make_warning" = "true"; then
1254    echo
1255    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1256    echo "This version cannot be used to build GHC."
1257    echo "Please use GNU make >= 3.81."
1258 fi
1259
1260 echo "
1261 ----------------------------------------------------------------------
1262 Configure completed successfully.
1263
1264    Building GHC version  : $ProjectVersion
1265           Git commit id  : $ProjectGitCommitId
1266
1267    Build platform        : $BuildPlatform
1268    Host platform         : $HostPlatform
1269    Target platform       : $TargetPlatform
1270 "
1271
1272 echo "\
1273    Bootstrapping using   : $WithGhc
1274       which is version   : $GhcVersion
1275 "
1276
1277 if test "x$CC_LLVM_BACKEND" = "x1"; then
1278     if test "x$CC_CLANG_BACKEND" = "x1"; then
1279         CompilerName="clang        "
1280     else
1281         CompilerName="llvm-gcc     "
1282     fi
1283 else
1284     CompilerName="gcc          "
1285 fi
1286
1287 echo "\
1288    Using (for bootstrapping) : $CC_STAGE0
1289    Using $CompilerName       : $CC
1290       which is version       : $GccVersion
1291    Building a cross compiler : $CrossCompiling
1292    Unregisterised            : $Unregisterised
1293    hs-cpp       : $HaskellCPPCmd
1294    hs-cpp-flags : $HaskellCPPArgs
1295    ar           : $ArCmd
1296    ld           : $LdCmd
1297    nm           : $NmCmd
1298    libtool      : $LibtoolCmd
1299    objdump      : $ObjdumpCmd
1300    ranlib       : $RanlibCmd
1301    windres      : $WindresCmd
1302    dllwrap      : $DllWrapCmd
1303    Happy        : $HappyCmd ($HappyVersion)
1304    Alex         : $AlexCmd ($AlexVersion)
1305    Perl         : $PerlCmd
1306    sphinx-build : $SPHINXBUILD
1307    xelatex      : $XELATEX
1308
1309    Using LLVM tools
1310       llc   : $LlcCmd
1311       opt   : $OptCmd"
1312
1313 if test "$HSCOLOUR" = ""; then
1314 echo "
1315    HsColour was not found; documentation will not contain source links
1316 "
1317 else
1318 echo "\
1319    HsColour : $HSCOLOUR
1320 "
1321 fi
1322
1323 echo "\
1324    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1325    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"
1326
1327 echo "----------------------------------------------------------------------
1328 "
1329
1330 echo "\
1331 For a standard build of GHC (fully optimised with profiling), type (g)make.
1332
1333 To make changes to the default build configuration, copy the file
1334 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1335
1336 For more information on how to configure your GHC build, see
1337    http://ghc.haskell.org/trac/ghc/wiki/Building
1338 "]