Remove redundant `#if`s
[ghc.git] / libraries / base / Text / ParserCombinators / ReadPrec.hs
1 {-# LANGUAGE Trustworthy #-}
2 {-# LANGUAGE NoImplicitPrelude #-}
3
4 -----------------------------------------------------------------------------
5 -- |
6 -- Module : Text.ParserCombinators.ReadPrec
7 -- Copyright : (c) The University of Glasgow 2002
8 -- License : BSD-style (see the file libraries/base/LICENSE)
9 --
10 -- Maintainer : libraries@haskell.org
11 -- Stability : provisional
12 -- Portability : non-portable (uses Text.ParserCombinators.ReadP)
13 --
14 -- This library defines parser combinators for precedence parsing.
15
16 -----------------------------------------------------------------------------
17
18 module Text.ParserCombinators.ReadPrec
19 (
20 ReadPrec,
21
22 -- * Precedences
23 Prec,
24 minPrec,
25
26 -- * Precedence operations
27 lift,
28 prec,
29 step,
30 reset,
31
32 -- * Other operations
33 -- | All are based directly on their similarly-named 'ReadP' counterparts.
34 get,
35 look,
36 (+++),
37 (<++),
38 pfail,
39 choice,
40
41 -- * Converters
42 readPrec_to_P,
43 readP_to_Prec,
44 readPrec_to_S,
45 readS_to_Prec,
46 )
47 where
48
49
50 import Text.ParserCombinators.ReadP
51 ( ReadP
52 , ReadS
53 , readP_to_S
54 , readS_to_P
55 )
56
57 import qualified Text.ParserCombinators.ReadP as ReadP
58 ( get
59 , look
60 , (+++), (<++)
61 , pfail
62 )
63
64 import GHC.Num( Num(..) )
65 import GHC.Base
66
67 import qualified Control.Monad.Fail as MonadFail
68
69 -- ---------------------------------------------------------------------------
70 -- The readPrec type
71
72 newtype ReadPrec a = P (Prec -> ReadP a)
73
74 -- Functor, Monad, MonadPlus
75
76 instance Functor ReadPrec where
77 fmap h (P f) = P (\n -> fmap h (f n))
78
79 instance Applicative ReadPrec where
80 pure x = P (\_ -> pure x)
81 (<*>) = ap
82
83 instance Monad ReadPrec where
84 fail s = P (\_ -> fail s)
85 P f >>= k = P (\n -> do a <- f n; let P f' = k a in f' n)
86
87 instance MonadFail.MonadFail ReadPrec where
88 fail s = P (\_ -> fail s)
89
90 instance MonadPlus ReadPrec where
91 mzero = pfail
92 mplus = (+++)
93
94 instance Alternative ReadPrec where
95 empty = mzero
96 (<|>) = mplus
97
98 -- precedences
99 type Prec = Int
100
101 minPrec :: Prec
102 minPrec = 0
103
104 -- ---------------------------------------------------------------------------
105 -- Operations over ReadPrec
106
107 lift :: ReadP a -> ReadPrec a
108 -- ^ Lift a precedence-insensitive 'ReadP' to a 'ReadPrec'.
109 lift m = P (\_ -> m)
110
111 step :: ReadPrec a -> ReadPrec a
112 -- ^ Increases the precedence context by one.
113 step (P f) = P (\n -> f (n+1))
114
115 reset :: ReadPrec a -> ReadPrec a
116 -- ^ Resets the precedence context to zero.
117 reset (P f) = P (\_ -> f minPrec)
118
119 prec :: Prec -> ReadPrec a -> ReadPrec a
120 -- ^ @(prec n p)@ checks whether the precedence context is
121 -- less than or equal to @n@, and
122 --
123 -- * if not, fails
124 --
125 -- * if so, parses @p@ in context @n@.
126 prec n (P f) = P (\c -> if c <= n then f n else ReadP.pfail)
127
128 -- ---------------------------------------------------------------------------
129 -- Derived operations
130
131 get :: ReadPrec Char
132 -- ^ Consumes and returns the next character.
133 -- Fails if there is no input left.
134 get = lift ReadP.get
135
136 look :: ReadPrec String
137 -- ^ Look-ahead: returns the part of the input that is left, without
138 -- consuming it.
139 look = lift ReadP.look
140
141 (+++) :: ReadPrec a -> ReadPrec a -> ReadPrec a
142 -- ^ Symmetric choice.
143 P f1 +++ P f2 = P (\n -> f1 n ReadP.+++ f2 n)
144
145 (<++) :: ReadPrec a -> ReadPrec a -> ReadPrec a
146 -- ^ Local, exclusive, left-biased choice: If left parser
147 -- locally produces any result at all, then right parser is
148 -- not used.
149 P f1 <++ P f2 = P (\n -> f1 n ReadP.<++ f2 n)
150
151 pfail :: ReadPrec a
152 -- ^ Always fails.
153 pfail = lift ReadP.pfail
154
155 choice :: [ReadPrec a] -> ReadPrec a
156 -- ^ Combines all parsers in the specified list.
157 choice ps = foldr (+++) pfail ps
158
159 -- ---------------------------------------------------------------------------
160 -- Converting between ReadPrec and Read
161
162 readPrec_to_P :: ReadPrec a -> (Int -> ReadP a)
163 readPrec_to_P (P f) = f
164
165 readP_to_Prec :: (Int -> ReadP a) -> ReadPrec a
166 readP_to_Prec f = P f
167
168 readPrec_to_S :: ReadPrec a -> (Int -> ReadS a)
169 readPrec_to_S (P f) n = readP_to_S (f n)
170
171 readS_to_Prec :: (Int -> ReadS a) -> ReadPrec a
172 readS_to_Prec f = P (\n -> readS_to_P (f n))
173