Eliminate orphan rules and instances in the array package
[ghc.git] / libraries / base / Data / Traversable.hs
1 -----------------------------------------------------------------------------
2 -- |
3 -- Module : Data.Traversable
4 -- Copyright : Conor McBride and Ross Paterson 2005
5 -- License : BSD-style (see the LICENSE file in the distribution)
6 --
7 -- Maintainer : libraries@haskell.org
8 -- Stability : experimental
9 -- Portability : portable
10 --
11 -- Class of data structures that can be traversed from left to right,
12 -- performing an action on each element.
13 --
14 -- See also
15 --
16 -- * /Applicative Programming with Effects/,
17 -- by Conor McBride and Ross Paterson, online at
18 -- <http://www.soi.city.ac.uk/~ross/papers/Applicative.html>.
19 --
20 -- * /The Essence of the Iterator Pattern/,
21 -- by Jeremy Gibbons and Bruno Oliveira,
22 -- in /Mathematically-Structured Functional Programming/, 2006, and online at
23 -- <http://web.comlab.ox.ac.uk/oucl/work/jeremy.gibbons/publications/#iterator>.
24 --
25 -- Note that the functions 'mapM' and 'sequence' generalize "Prelude"
26 -- functions of the same names from lists to any 'Traversable' functor.
27 -- To avoid ambiguity, either import the "Prelude" hiding these names
28 -- or qualify uses of these function names with an alias for this module.
29
30 module Data.Traversable (
31 Traversable(..),
32 for,
33 forM,
34 mapAccumL,
35 mapAccumR,
36 fmapDefault,
37 foldMapDefault,
38 ) where
39
40 import Prelude hiding (mapM, sequence, foldr)
41 import qualified Prelude (mapM, foldr)
42 import Control.Applicative
43 import Data.Foldable (Foldable())
44 import Data.Monoid (Monoid)
45
46 #if defined(__GLASGOW_HASKELL__)
47 import GHC.Arr
48 #elif defined(__HUGS__)
49 import Hugs.Array
50 #endif
51
52 -- | Functors representing data structures that can be traversed from
53 -- left to right.
54 --
55 -- Minimal complete definition: 'traverse' or 'sequenceA'.
56 --
57 -- Instances are similar to 'Functor', e.g. given a data type
58 --
59 -- > data Tree a = Empty | Leaf a | Node (Tree a) a (Tree a)
60 --
61 -- a suitable instance would be
62 --
63 -- > instance Traversable Tree
64 -- > traverse f Empty = pure Empty
65 -- > traverse f (Leaf x) = Leaf <$> f x
66 -- > traverse f (Node l k r) = Node <$> traverse f l <*> f k <*> traverse f r
67 --
68 -- This is suitable even for abstract types, as the laws for '<*>'
69 -- imply a form of associativity.
70 --
71 -- The superclass instances should satisfy the following:
72 --
73 -- * In the 'Functor' instance, 'fmap' should be equivalent to traversal
74 -- with the identity applicative functor ('fmapDefault').
75 --
76 -- * In the 'Foldable' instance, 'Data.Foldable.foldMap' should be
77 -- equivalent to traversal with a constant applicative functor
78 -- ('foldMapDefault').
79 --
80 class (Functor t, Foldable t) => Traversable t where
81 -- | Map each element of a structure to an action, evaluate
82 -- these actions from left to right, and collect the results.
83 traverse :: Applicative f => (a -> f b) -> t a -> f (t b)
84 traverse f = sequenceA . fmap f
85
86 -- | Evaluate each action in the structure from left to right,
87 -- and collect the results.
88 sequenceA :: Applicative f => t (f a) -> f (t a)
89 sequenceA = traverse id
90
91 -- | Map each element of a structure to a monadic action, evaluate
92 -- these actions from left to right, and collect the results.
93 mapM :: Monad m => (a -> m b) -> t a -> m (t b)
94 mapM f = unwrapMonad . traverse (WrapMonad . f)
95
96 -- | Evaluate each monadic action in the structure from left to right,
97 -- and collect the results.
98 sequence :: Monad m => t (m a) -> m (t a)
99 sequence = mapM id
100
101 -- instances for Prelude types
102
103 instance Traversable Maybe where
104 traverse f Nothing = pure Nothing
105 traverse f (Just x) = Just <$> f x
106
107 instance Traversable [] where
108 traverse f = Prelude.foldr cons_f (pure [])
109 where cons_f x ys = (:) <$> f x <*> ys
110
111 mapM = Prelude.mapM
112
113 #ifndef __NHC__
114 instance Ix i => Traversable (Array i) where
115 traverse f arr = listArray (bounds arr) `fmap` traverse f (elems arr)
116 #endif
117
118 -- general functions
119
120 -- | 'for' is 'traverse' with its arguments flipped.
121 for :: (Traversable t, Applicative f) => t a -> (a -> f b) -> f (t b)
122 {-# INLINE for #-}
123 for = flip traverse
124
125 -- | 'forM' is 'mapM' with its arguments flipped.
126 forM :: (Traversable t, Monad m) => t a -> (a -> m b) -> m (t b)
127 {-# INLINE forM #-}
128 forM = flip mapM
129
130 -- left-to-right state transformer
131 newtype StateL s a = StateL { runStateL :: s -> (s, a) }
132
133 instance Functor (StateL s) where
134 fmap f (StateL k) = StateL $ \ s ->
135 let (s', v) = k s in (s', f v)
136
137 instance Applicative (StateL s) where
138 pure x = StateL (\ s -> (s, x))
139 StateL kf <*> StateL kv = StateL $ \ s ->
140 let (s', f) = kf s
141 (s'', v) = kv s'
142 in (s'', f v)
143
144 -- |The 'mapAccumL' function behaves like a combination of 'fmap'
145 -- and 'foldl'; it applies a function to each element of a structure,
146 -- passing an accumulating parameter from left to right, and returning
147 -- a final value of this accumulator together with the new structure.
148 mapAccumL :: Traversable t => (a -> b -> (a, c)) -> a -> t b -> (a, t c)
149 mapAccumL f s t = runStateL (traverse (StateL . flip f) t) s
150
151 -- right-to-left state transformer
152 newtype StateR s a = StateR { runStateR :: s -> (s, a) }
153
154 instance Functor (StateR s) where
155 fmap f (StateR k) = StateR $ \ s ->
156 let (s', v) = k s in (s', f v)
157
158 instance Applicative (StateR s) where
159 pure x = StateR (\ s -> (s, x))
160 StateR kf <*> StateR kv = StateR $ \ s ->
161 let (s', v) = kv s
162 (s'', f) = kf s'
163 in (s'', f v)
164
165 -- |The 'mapAccumR' function behaves like a combination of 'fmap'
166 -- and 'foldr'; it applies a function to each element of a structure,
167 -- passing an accumulating parameter from right to left, and returning
168 -- a final value of this accumulator together with the new structure.
169 mapAccumR :: Traversable t => (a -> b -> (a, c)) -> a -> t b -> (a, t c)
170 mapAccumR f s t = runStateR (traverse (StateR . flip f) t) s
171
172 -- | This function may be used as a value for `fmap` in a `Functor` instance.
173 fmapDefault :: Traversable t => (a -> b) -> t a -> t b
174 fmapDefault f = getId . traverse (Id . f)
175
176 -- | This function may be used as a value for `Data.Foldable.foldMap`
177 -- in a `Foldable` instance.
178 foldMapDefault :: (Traversable t, Monoid m) => (a -> m) -> t a -> m
179 foldMapDefault f = getConst . traverse (Const . f)
180
181 -- local instances
182
183 newtype Id a = Id { getId :: a }
184
185 instance Functor Id where
186 fmap f (Id x) = Id (f x)
187
188 instance Applicative Id where
189 pure = Id
190 Id f <*> Id x = Id (f x)