[project @ 2004-08-28 15:50:44 by panne]
[ghc.git] / aclocal.m4
1 # Extra autoconf macros for the Glasgow fptools
2 #
3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
4 # ensure we don't clash with any pre-supplied autoconf ones.
5
6
7 # FP_EVAL_STDERR(COMMAND)
8 # -----------------------
9 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
10 # into the file conftest.err and the exit status in the variable fp_status.
11 AC_DEFUN([FP_EVAL_STDERR],
12 [{ (eval $1) 2>conftest.er1
13   fp_status=$?
14   grep -v '^ *+' conftest.er1 >conftest.err
15   rm -f conftest.er1
16   (exit $fp_status); }[]dnl
17 ])# FP_EVAL_STDERR
18
19
20 # FP_CHECK_FLAG(FLAG, [ACTION-IF-SUPPORTED], [ACTION-IF-NOT-SUPPORTED])
21 # ---------------------------------------------------------------------
22 # Check to see whether the compiler for the current language supports a
23 # particular option.
24 #
25 # Implementation note: When given an unkown option, GCC issues an warning on
26 # stderr only, but returns an exit value of 0 nevertheless. Consequently we have
27 # to check stderr *and* the exit value.
28 #
29 # Used by ghc.
30 AC_DEFUN(FP_CHECK_FLAG,
31 [AC_LANG_COMPILER_REQUIRE()dnl
32 AC_LANG_CASE([C],          [fp_compiler="$CC"  m4_pushdef([fp_Flags], [CFLAGS])],
33              [C++],        [fp_compiler="$CXX" m4_pushdef([fp_Flags], [CXXFLAGS])],
34              [Fortran 77], [fp_compiler="$F77" m4_pushdef([fp_Flags], [FFLAGS])])
35 m4_pushdef([fp_Cache], [fp_cv_[]fp_Flags[]AS_TR_SH([$1])])[]dnl
36 AC_CACHE_CHECK([whether $fp_compiler accepts $1], [fp_Cache],
37 [AC_LANG_CONFTEST([AC_LANG_PROGRAM()])
38 fp_save_flags="$fp_Flags"
39 fp_Flags="$fp_Flags $1"
40 fp_Cache=no
41 if FP_EVAL_STDERR([$ac_compile conftest.$ac_ext]) >/dev/null; then
42   test -s conftest.err || fp_Cache=yes
43 fi
44 fp_Flags="$fp_save_flags"
45 rm -f conftest.err conftest.$ac_ext])
46 AS_IF([test $fp_Cache = yes], [$2], [$3])[]dnl
47 m4_popdef([fp_Cache])[]dnl
48 m4_popdef([fp_Flags])[]dnl
49 ])# FP_CHECK_FLAG
50
51
52 # FP_PROG_CONTEXT_DIFF
53 # --------------------
54 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
55 #
56 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
57 #
58 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
59 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
60 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
61 [echo foo > conftest1
62 echo foo > conftest2
63 fp_cv_context_diff=no
64 for fp_var in '-C 1' '-c1'
65 do
66   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
67     fp_cv_context_diff="diff $fp_var"
68     break
69   fi
70 done])
71 if test x"$fp_cv_context_diff" = xno; then
72    AC_MSG_ERROR([cannot figure out how to do context diffs])
73 fi
74 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
75 ])# FP_PROG_CONTEXT_DIFF
76
77
78 # FP_DECL_ALTZONE
79 # ---------------
80 # Defines HAVE_DECL_ALTZONE to 1 if declared, 0 otherwise.
81 #
82 # Used by base package.
83 AC_DEFUN([FP_DECL_ALTZONE],
84 [AC_REQUIRE([AC_HEADER_TIME])dnl
85 AC_CHECK_HEADERS([sys/time.h])
86 AC_CHECK_DECLS([altzone], [], [],[#if TIME_WITH_SYS_TIME
87 # include <sys/time.h>
88 # include <time.h>
89 #else
90 # if HAVE_SYS_TIME_H
91 #  include <sys/time.h>
92 # else
93 #  include <time.h>
94 # endif
95 #endif])
96 ])# FP_DECL_ALTZONE
97
98
99 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
100 # --------------------------------------------------------
101 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
102 # compilation. Execute IF-FAILS when unable to determine the value. Works for
103 # cross-compilation, too.
104 #
105 # Implementation note: We are lazy and use an internal autoconf macro, but it
106 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
107 # little risk.
108 AC_DEFUN([FP_COMPUTE_INT],
109 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
110 ])# FP_COMPUTE_INT
111
112
113 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
114 # ------------------------------------------------------------------
115 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
116 # given type. Defines ALIGNMENT_TYPE.
117 AC_DEFUN([FP_CHECK_ALIGNMENT],
118 [AS_LITERAL_IF([$1], [],
119                [AC_FATAL([$0: requires literal arguments])])[]dnl
120 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
121 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
122 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
123 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
124   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
125                  [fp_Cache],
126                  [AC_INCLUDES_DEFAULT([$3])],
127                  [AC_MSG_ERROR([cannot compute alignment ($1)
128 See `config.log' for more details.], [77])])
129 else
130   fp_Cache=0
131 fi])[]dnl
132 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
133 m4_popdef([fp_Cache])[]dnl
134 ])# FP_CHECK_ALIGNMENT
135
136
137 # FP_CHECK_CONST(EXPRESSION, [INCLUDES = DEFAULT-INCLUDES], [VALUE-IF-FAIL = -1])
138 # -------------------------------------------------------------------------------
139 # Defines CONST_EXPRESSION to the value of the compile-time EXPRESSION, using
140 # INCLUDES. If the value cannot be determined, use VALUE-IF-FAIL.
141 AC_DEFUN([FP_CHECK_CONST],
142 [AS_VAR_PUSHDEF([fp_Cache], [fp_cv_const_$1])[]dnl
143 AC_CACHE_CHECK([value of $1], fp_Cache,
144 [FP_COMPUTE_INT([$1], fp_check_const_result, [AC_INCLUDES_DEFAULT([$2])],
145                 [fp_check_const_result=m4_default([$3], ['-1'])])
146 AS_VAR_SET(fp_Cache, [$fp_check_const_result])])[]dnl
147 AC_DEFINE_UNQUOTED(AS_TR_CPP([CONST_$1]), AS_VAR_GET(fp_Cache), [The value of $1.])[]dnl
148 AS_VAR_POPDEF([fp_Cache])[]dnl
149 ])# FP_CHECK_CONST
150
151
152 # FP_CHECK_CONSTS_TEMPLATE(EXPRESSION...)
153 # ---------------------------------------
154 # autoheader helper for FP_CHECK_CONSTS
155 m4_define([FP_CHECK_CONSTS_TEMPLATE],
156 [AC_FOREACH([fp_Const], [$1],
157   [AH_TEMPLATE(AS_TR_CPP(CONST_[]fp_Const),
158                [The value of ]fp_Const[.])])[]dnl
159 ])# FP_CHECK_CONSTS_TEMPLATE
160
161
162 # FP_CHECK_CONSTS(EXPRESSION..., [INCLUDES = DEFAULT-INCLUDES], [VALUE-IF-FAIL = -1])
163 # -----------------------------------------------------------------------------------
164 # List version of FP_CHECK_CONST
165 AC_DEFUN(FP_CHECK_CONSTS,
166 [FP_CHECK_CONSTS_TEMPLATE([$1])dnl
167 for fp_const_name in $1
168 do
169 FP_CHECK_CONST([$fp_const_name], [$2], [$3])
170 done
171 ])# FP_CHECK_CONSTS
172
173
174 dnl ** check for leading underscores in symbol names
175 dnl 
176 dnl Test for determining whether symbol names have a leading
177 dnl underscore.
178 dnl 
179 dnl We assume that they _haven't_ if anything goes wrong.
180 dnl
181 dnl Some nlist implementations seem to try to be compatible by ignoring
182 dnl a leading underscore sometimes (eg. FreeBSD).  We therefore have
183 dnl to work around this by checking for *no* leading underscore first.
184 dnl Sigh.  --SDM
185 dnl
186 dnl Similarly on OpenBSD, but this test doesn't help. -- dons
187 dnl
188 AC_DEFUN(FPTOOLS_UNDERSCORE,
189 [AC_CHECK_LIB(elf, nlist, LIBS="-lelf $LIBS")dnl
190 AC_CACHE_CHECK([leading underscore in symbol names], fptools_cv_lead_uscore,
191
192 dnl
193 dnl Hack!: nlist() under Digital UNIX insist on there being an _,
194 dnl but symbol table listings shows none. What is going on here?!?
195 dnl
196 dnl Another hack: cygwin doesn't come with nlist.h , so we hardwire
197 dnl the underscoredness of that "platform"
198 changequote(<<, >>)dnl
199 <<
200 case $HostPlatform in
201 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
202     case $build in
203         i386-*2\.[[0-9]] | i386-*3\.[[0-3]] ) fptools_cv_lead_uscore='yes' ;;
204         *)      fptools_cv_lead_uscore='no' ;;
205     esac ;;
206 alpha-dec-osf*) fptools_cv_lead_uscore='no';;
207 *cygwin32) fptools_cv_lead_uscore='yes';;
208 *mingw32) fptools_cv_lead_uscore='yes';;
209 *) >>
210 changequote([, ])dnl
211 AC_TRY_RUN([#ifdef HAVE_NLIST_H
212 #include <nlist.h>
213 changequote(<<, >>)dnl
214 <<
215 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
216 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
217 #endif
218
219 main(argc, argv)
220 int argc;
221 char **argv;
222 {
223 #ifdef HAVE_NLIST_H
224     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
225         exit(1);
226     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
227         exit(0);>>
228 changequote([, ])dnl
229 #endif
230     exit(1);
231 }], fptools_cv_lead_uscore=yes, fptools_cv_lead_uscore=no, fptools_cv_lead_uscore=NO)
232 ;;
233 esac);
234 LeadingUnderscore=`echo $fptools_cv_lead_uscore | sed 'y/yesno/YESNO/'`
235 AC_SUBST(LeadingUnderscore)
236 case $LeadingUnderscore in
237 YES) AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.]);;
238 esac
239 ])
240
241
242 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
243 # ----------------------------------------------------------------------------------
244 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
245 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
246 AC_DEFUN([FP_COMPARE_VERSIONS],
247 [fp_version1=$1; fp_version2=$3
248 fp_save_IFS=$IFS; IFS='.'
249 while test x"$fp_version1" != x || test x"$fp_version2" != x
250 do
251
252   set dummy $fp_version1; shift
253   fp_num1=""
254   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
255   test x"$fp_num1" = x && fp_num1="0"
256   fp_version1="[$]*"
257
258   set dummy $fp_version2; shift
259   fp_num2=""
260   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
261   test x"$fp_num2" = x && fp_num2="0"
262   fp_version2="[$]*"
263
264   test "$fp_num1" = "$fp_num2" || break;
265 done
266 IFS=$fp_save_IFS
267 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
268 ])# FP_COMPARE_VERSIONS
269
270
271 dnl
272 dnl Check for GreenCard and version.
273 dnl
274 AC_DEFUN(FPTOOLS_GREENCARD,
275 [
276 AC_PATH_PROG(GreenCardCmd,greencard)
277 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
278 changequote(, )dnl
279 [if test x"$GreenCardCmd" != x; then
280    fptools_cv_greencard_version="`$GreenCardCmd --version |
281                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
282 else
283    fptools_cv_greencard_version=""
284 fi
285 changequote([, ])dnl
286 ])
287 FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
288   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
289 GreenCardVersion=$fptools_cv_greencard_version
290 AC_SUBST(GreenCardVersion)
291 ])
292
293 dnl
294 dnl Check for Happy and version.  If we're building GHC, then we need
295 dnl at least Happy version 1.14.  If there's no installed Happy, we look
296 dnl for a happy source tree and point the build system at that instead.
297 dnl
298 AC_DEFUN(FPTOOLS_HAPPY,
299 [
300 if test -d $srcdir/happy; then
301    SrcTreeHappyCmd=$hardtop/happy/src/happy-inplace
302 fi
303 if test x"$UseSrcTreeHappy" = xYES; then
304   HappyCmd=$SrcTreeHappyCmd
305 else
306   AC_PATH_PROG(HappyCmd,happy,$SrcTreeHappyCmd)
307 fi
308 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
309 changequote(, )dnl
310 [if test x"$HappyCmd" = x"$SrcTreeHappyCmd" -a -e $srcdir/happy/mk/version.mk; then
311    fptools_cv_happy_version=`grep '^ProjectVersion[     ]*=' $srcdir/happy/mk/version.mk | sed 's/.*\([0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`;
312 elif test x"$HappyCmd" != x; then
313    fptools_cv_happy_version="`$HappyCmd -v |
314                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'`" ;
315 else
316    fptools_cv_happy_version="";
317 fi;
318 changequote([, ])dnl
319 ])
320 if test -d $srcdir/ghc -a ! -f $srcdir/ghc/compiler/parser/Parser.hs; then
321   FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.14],
322   [AC_MSG_ERROR([Happy version 1.14 or later is required to compile GHC.])])[]dnl
323 fi
324 HappyVersion=$fptools_cv_happy_version;
325 AC_SUBST(HappyVersion)
326 ])
327
328 dnl
329 dnl Check for Haddock and version.  If there's no installed Haddock, we look
330 dnl for a haddock source tree and point the build system at that instead.
331 dnl
332 AC_DEFUN(FPTOOLS_HADDOCK,
333 [
334 if test -d $srcdir/haddock; then
335    SrcTreeHaddockCmd=$hardtop/haddock/src/haddock-inplace
336 fi
337 if test x"$UseSrcTreeHaddock" = xYES; then
338   HaddockCmd=$SrcTreeHaddockCmd
339 else
340   AC_PATH_PROG(HaddockCmd,haddock,$SrcTreeHaddockCmd)
341 fi
342 dnl Darn, I forgot to make Haddock print out its version number when
343 dnl invoked with -v.  We could try generating some HTML and grepping
344 dnl through that to find the version number, but I think we'll make
345 dnl do without it for now.
346 ])
347
348 dnl
349 dnl Check for Alex and version.  If we're building GHC, then we need
350 dnl at least Alex version 2.0.  If there's no installed Alex, we look
351 dnl for a alex source tree and point the build system at that instead.
352 dnl
353 AC_DEFUN(FPTOOLS_ALEX,
354 [
355 if test -d $srcdir/alex; then
356    SrcTreeAlexCmd=$hardtop/alex/src/alex-inplace
357 fi
358 if test x"$UseSrcTreeAlex" = xYES; then
359   AlexCmd=$SrcTreeAlexCmd
360 else
361   AC_PATH_PROG(AlexCmd,alex,$SrcTreeAlexCmd)
362 fi
363 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
364 changequote(, )dnl
365 [if test x"$AlexCmd" = x"$SrcTreeAlexCmd"; then
366    fptools_cv_alex_version=`grep '^ProjectVersion[      ]*=' $srcdir/alex/mk/version.mk | sed 's/.*\([0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`;
367 elif test x"$AlexCmd" != x; then
368    fptools_cv_alex_version="`$AlexCmd -v |
369                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'`" ;
370 else
371    fptools_cv_alex_version="";
372 fi;
373 changequote([, ])dnl
374 ])
375 if test -d $srcdir/ghc -a ! -f $srcdir/ghc/compiler/parser/Lexer.hs; then
376   FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.0],
377   [AC_MSG_ERROR([Alex version 2.0 or later is required to compile GHC.])])[]dnl
378 fi
379 AlexVersion=$fptools_cv_alex_version;
380 AC_SUBST(AlexVersion)
381 ])
382
383
384 dnl
385 dnl Check whether ld supports -x
386 dnl
387 AC_DEFUN(FPTOOLS_LD_X,
388 [AC_CACHE_CHECK([whether ld understands -x], fptools_cv_ld_x,
389 [
390 echo 'foo() {}' > conftest.c
391 ${CC-cc} -c conftest.c
392 if ${LdCmd} -r -x -o foo.o conftest.o; then
393    fptools_cv_ld_x=yes
394 else
395    fptools_cv_ld_x=no
396 fi
397 rm -rf conftest.c conftest.o foo.o
398 ])
399 if test "$fptools_cv_ld_x" = yes; then
400         LdXFlag=-x
401 else
402         LdXFlag=
403 fi
404 AC_SUBST(LdXFlag)
405 ])
406
407
408 # FP_PROG_AR
409 # ----------
410 # Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
411 # version of it. Exits if no ar can be found
412 AC_DEFUN([FP_PROG_AR],
413 [AC_PATH_PROG([fp_prog_ar_raw], [ar])
414 if test -z "$fp_prog_ar_raw"; then
415   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
416 fi
417 fp_prog_ar=$fp_prog_ar_raw
418 case $HostPlatform in
419   *mingw32) if test x${OSTYPE} != xmsys; then
420               fp_prog_ar="`cygpath -w ${fp_prog_ar_raw} | sed -e 's@\\\\@/@g'`"
421               AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
422             fi
423             ;;
424 esac
425 ])# FP_PROG_AR
426
427
428 # FP_PROG_AR_IS_GNU
429 # -----------------
430 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
431 AC_DEFUN([FP_PROG_AR_IS_GNU],
432 [AC_REQUIRE([FP_PROG_AR])
433 AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
434 [if $fp_prog_ar_raw --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
435   fp_cv_prog_ar_is_gnu=yes
436 else
437   fp_cv_prog_ar_is_gnu=no
438 fi])
439 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
440 ])# FP_PROG_AR_IS_GNU
441
442
443 # FP_PROG_AR_ARGS
444 # ---------------
445 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
446 # to a non-Cygwin invocation of ar including these arguments.
447 AC_DEFUN([FP_PROG_AR_ARGS],
448 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
449 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
450 [
451 # GNU ar needs special treatment: it appears to have problems with
452 # object files with the same name if you use the 's' modifier, but
453 # simple 'ar q' works fine, and doesn't need a separate ranlib.
454 if test $fp_prog_ar_is_gnu = yes; then
455   fp_cv_prog_ar_args="q"
456 else
457   touch conftest.dummy
458   for fp_var in clqsZ clqs cqs clq cq ; do
459      rm -f conftest.a
460      if $fp_prog_ar_raw $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
461         fp_cv_prog_ar_args=$fp_var
462         break
463      fi
464   done
465   rm -f conftest*
466   if test -z "$fp_cv_prog_ar_args"; then
467     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
468   fi
469 fi])
470 fp_prog_ar_args=$fp_cv_prog_ar_args
471 AC_SUBST([ArCmd], ["$fp_prog_ar $fp_prog_ar_args"])
472
473 ])# FP_PROG_AR_ARGS
474
475
476 # FP_PROG_AR_NEEDS_RANLIB
477 # -----------------------
478 # Sets the output variable RANLIB to "ranlib" if it is needed and found,
479 # to ":" otherwise.
480 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
481 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
482 AC_REQUIRE([FP_PROG_AR_ARGS])
483 AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
484 [if test $fp_prog_ar_is_gnu = yes; then
485   fp_cv_prog_ar_needs_ranlib=no
486 elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
487   fp_cv_prog_ar_needs_ranlib=no
488 else
489   fp_cv_prog_ar_needs_ranlib=yes
490 fi])
491 if test $fp_cv_prog_ar_needs_ranlib = yes; then
492    AC_PROG_RANLIB
493 else
494   RANLIB=":"
495   AC_SUBST([RANLIB])
496 fi
497 ])# FP_PROG_AR_NEEDS_RANLIB
498
499
500 # FP_PROG_AR_SUPPORTS_INPUT
501 # -------------------------
502 # Sets the output variable ArSupportsInput to "-input" or "", depending on
503 # whether ar supports -input flag is supported or not.
504 AC_DEFUN([FP_PROG_AR_SUPPORTS_INPUT],
505 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
506 AC_REQUIRE([FP_PROG_AR_ARGS])
507 AC_CACHE_CHECK([whether $fp_prog_ar_raw supports -input], [fp_cv_prog_ar_supports_input],
508 [fp_cv_prog_ar_supports_input=no
509 if test $fp_prog_ar_is_gnu = no; then
510   rm -f conftest*
511   touch conftest.lst
512   if $fp_prog_ar_raw $fp_prog_ar_args conftest.a -input conftest.lst > /dev/null 2> /dev/null; then
513     fp_cv_prog_ar_supports_input=yes
514   fi
515   rm -f conftest*
516 fi])
517 if test $fp_cv_prog_ar_supports_input = yes; then
518     ArSupportsInput="-input"
519 else
520     ArSupportsInput=""
521 fi
522 AC_SUBST([ArSupportsInput])
523 ])# FP_PROG_AR_SUPPORTS_INPUT
524
525
526 dnl
527 dnl AC_SHEBANG_PERL - can we she-bang perl?
528 dnl
529 AC_DEFUN(FPTOOLS_SHEBANG_PERL,
530 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
531 [echo "#!$PerlCmd"'
532 exit $1;
533 ' > conftest
534 chmod u+x conftest
535 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
536 if test $? -ne 69; then
537    fptools_cv_shebang_perl=yes
538 else
539    fptools_cv_shebang_perl=no
540 fi
541 rm -f conftest
542 ])])
543
544 dnl
545 dnl Extra testing of the result AC_PROG_CC, testing the gcc version no.
546 dnl *Must* be called after AC_PROG_CC
547 dnl
548 AC_DEFUN(FPTOOLS_HAVE_GCC,
549 [AC_CACHE_CHECK([whether you have an ok gcc], fptools_cv_have_gcc,
550 [if test -z "$GCC"; then
551     echo ''
552     echo "You would be better off with gcc"
553     echo "Perhaps it is already installed, but not in your PATH?"
554     fptools_cv_have_gcc='no'
555 else
556 changequote(, )dnl
557     gcc_version_str="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [^0-9]*\([0-9][0-9]*\)\.\([0-9][0-9]*\).*/\1\.\2/g' `"
558 changequote([, ])dnl
559     fptools_cv_have_gcc='yes'
560     FP_COMPARE_VERSIONS([$gcc_version_str], [-lt], [2.0],
561         [fptools_cv_have_gcc='no'
562         echo ""
563         echo "your gcc version appears to be ..."
564         $CC --version
565         echo "gcc prior to 2.0 and have never worked with ghc."
566         echo "we recommend 2.95.3, although versions back to 2.7.2 should be ok."
567         AC_MSG_ERROR([gcc 1.X has never been supported])])
568 fi
569 ])
570 HaveGcc=`echo $fptools_cv_have_gcc | sed 'y/yesno/YESNO/'`
571 AC_SUBST(HaveGcc)
572 GccVersion=`gcc --version | grep mingw | cut -f 3 -d ' '`
573 AC_SUBST(GccVersion)
574 ])
575
576 dnl
577 dnl Some OSs (Mandrake Linux, in particular) configure GCC with
578 dnl -momit-leaf-frame-pointer on by default.  If this is the case, we
579 dnl need to turn it off for mangling to work.  The test is currently a bit
580 dnl crude, using only the version number of gcc.
581 dnl
582 AC_DEFUN([FPTOOLS_GCC_NEEDS_NO_OMIT_LFPTR],
583 [AC_CACHE_CHECK([whether gcc needs -mno-omit-leaf-frame-pointer], [fptools_cv_gcc_needs_no_omit_lfptr],
584 [FP_COMPARE_VERSIONS([$gcc_version_str], [-ge], [3.2],
585   [fptools_cv_gcc_needs_no_omit_lfptr=yes],
586   [fptools_cv_gcc_needs_no_omit_lfptr=no])])
587 if test "$fptools_cv_gcc_needs_no_omit_lfptr" = "yes"; then
588    AC_DEFINE([HAVE_GCC_MNO_OMIT_LFPTR], [1], [Define to 1 if gcc supports -mno-omit-leaf-frame-pointer.])
589 fi])# FPTOOLS_GCC_NEEDS_NO_OMIT_LFPTR
590
591
592 dnl Small feature test for perl version. Assumes PerlCmd
593 dnl contains path to perl binary
594 dnl
595 AC_DEFUN(FPTOOLS_CHECK_PERL_VERSION,
596 [$PerlCmd -v >conftest.out 2>&1
597 if grep "version 5" conftest.out >/dev/null 2>&1; then
598    :
599 else
600    if grep "v5.6" conftest.out >/dev/null 2>&1; then
601       :
602    else
603       if grep "v5.8" conftest.out >/dev/null 2>&1; then
604          :
605       else
606          if grep "version 6" conftest.out >/dev/null 2>&1; then
607             :
608          else
609             echo "Your version of perl probably won't work."
610          fi  
611       fi
612    fi
613 fi
614 rm -fr conftest*
615 ])
616
617
618 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
619 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
620 # -----------------------------------------------------
621 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
622 # of PROG-TO-CHECK-FOR when found.
623 AC_DEFUN([FP_CHECK_PROG],
624 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
625 )# FP_CHECK_PROC
626
627
628 # FP_PROG_FIND
629 # ------------
630 # Find a non-WinDoze version of the "find" utility.
631 AC_DEFUN([FP_PROG_FIND],
632 [AC_PATH_PROG([fp_prog_find], [find])
633 echo foo > conftest.txt
634 $fp_prog_find conftest.txt -print > conftest.out 2>&1
635 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
636   # OK, looks like a real "find".
637   FindCmd="$fp_prog_find"
638 else
639   # Found a poor WinDoze version of "find", ignore it.
640   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
641   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
642 fi
643 rm -f conftest.txt conftest.out
644 AC_SUBST([FindCmd])[]dnl
645 ])# FP_PROG_FIND
646
647
648 dnl
649 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
650 dnl values of the second argument to the result of running
651 dnl the commands given by the third. It does not cache its
652 dnl result, so it is suitable for checks which should be
653 dnl run every time.
654 dnl
655 AC_DEFUN(FPTOOLS_NOCACHE_CHECK,
656 [AC_MSG_CHECKING([$1])
657  $3
658  AC_MSG_RESULT([$][$2])
659 ])
660
661 dnl
662 dnl FPTOOLS_GHC_VERSION(version)
663 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
664 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
665 dnl
666 dnl Test for version of installed ghc.  Uses $GHC.
667 dnl [original version pinched from c2hs]
668 dnl
669 AC_DEFUN(FPTOOLS_GHC_VERSION,
670 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
671 ["${WithGhc-ghc}" --version > conftestghc 2>&1
672   cat conftestghc >&AC_FD_CC
673 #Useless Use Of cat award...
674   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
675   rm -fr conftest*
676   if test "[$]fptools_version_of_ghc" = ""
677   then
678     fptools_version_of_ghc='unknown'
679   fi
680 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
681 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
682 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
683 #
684 if test "[$]fptools_version_of_ghc[_pl]" = ""
685 then
686   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
687   fptools_version_of_ghc[_pl]="0"
688 else
689   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
690 fi
691 #
692 ifelse($#, [1], [dnl
693 [$1]="[$]fptools_version_of_ghc[_all]"
694 ], $#, [2], [dnl
695 [$1]="[$]fptools_version_of_ghc[_major]"
696 [$2]="[$]fptools_version_of_ghc[_minor]"
697 ], $#, [3], [dnl
698 [$1]="[$]fptools_version_of_ghc[_major]"
699 [$2]="[$]fptools_version_of_ghc[_minor]"
700 [$3]="[$]fptools_version_of_ghc[_pl]"
701 ], $#, [4], [dnl
702 [$1]="[$]fptools_version_of_ghc[_all]"
703 [$2]="[$]fptools_version_of_ghc[_major]"
704 [$3]="[$]fptools_version_of_ghc[_minor]"
705 [$4]="[$]fptools_version_of_ghc[_pl]"
706 ])
707 ])
708 ])dnl
709
710
711 dnl ** Map an arithmetic C type to a Haskell type.
712 dnl    Based on autconf's AC_CHECK_SIZEOF.
713
714 dnl FPTOOLS_CHECK_HTYPE(TYPE [, DEFAULT_VALUE, [, VALUE-FOR-CROSS-COMPILATION])
715 AC_DEFUN(FPTOOLS_CHECK_HTYPE,
716 [changequote(<<, >>)dnl
717 dnl The name to #define.
718 define(<<AC_TYPE_NAME>>, translit(htype_$1, [a-z *], [A-Z_P]))dnl
719 dnl The cache variable name.
720 define(<<AC_CV_NAME>>, translit(fptools_cv_htype_$1, [ *], [_p]))dnl
721 define(<<AC_CV_NAME_supported>>, translit(fptools_cv_htype_sup_$1, [ *], [_p]))dnl
722 changequote([, ])dnl
723 AC_MSG_CHECKING(Haskell type for $1)
724 AC_CACHE_VAL(AC_CV_NAME,
725 [AC_CV_NAME_supported=yes
726 fp_check_htype_save_cppflags="$CPPFLAGS"
727 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
728 AC_TRY_RUN([#include <stdio.h>
729 #include <stddef.h>
730
731 #if HAVE_SYS_TYPES_H
732 # include <sys/types.h>
733 #endif
734
735 #if HAVE_UNISTD_H
736 # include <unistd.h>
737 #endif
738
739 #if HAVE_SYS_STAT_H
740 # include <sys/stat.h>
741 #endif
742
743 #if HAVE_FCNTL_H
744 # include <fcntl.h>
745 #endif
746
747 #if HAVE_SIGNAL_H
748 # include <signal.h>
749 #endif
750
751 #if HAVE_TIME_H
752 # include <time.h>
753 #endif
754
755 #if HAVE_TERMIOS_H
756 # include <termios.h>
757 #endif
758
759 #if HAVE_STRING_H
760 # include <string.h>
761 #endif
762
763 #if HAVE_CTYPE_H
764 # include <ctype.h>
765 #endif
766
767 #if defined(HAVE_GL_GL_H)
768 # include <GL/gl.h>
769 #elif defined(HAVE_OPENGL_GL_H)
770 # include <OpenGL/gl.h>
771 #endif
772
773 #if defined(HAVE_AL_ALC_H)
774 # include <AL/alc.h>
775 #elif defined(HAVE_OPENAL_ALC_H)
776 # include <OpenAL/alc.h>
777 #endif
778
779 #if HAVE_SYS_RESOURCE_H
780 # include <sys/resource.h>
781 #endif
782
783 typedef $1 testing;
784
785 main() {
786   FILE *f=fopen("conftestval", "w");
787   if (!f) exit(1);
788   if (((testing)((int)((testing)1.4))) == ((testing)1.4)) {
789     fprintf(f, "%s%d\n",
790            ((testing)(-1) < (testing)0) ? "Int" : "Word",
791            sizeof(testing)*8);
792   } else {
793     fprintf(f,"%s\n",
794            (sizeof(testing) >  sizeof(double)) ? "LDouble" :
795            (sizeof(testing) == sizeof(double)) ? "Double"  : "Float");
796   }
797   fclose(f);
798   exit(0);
799 }],AC_CV_NAME=`cat conftestval`,
800 ifelse([$2], , [AC_CV_NAME=NotReallyAType; AC_CV_NAME_supported=no], AC_CV_NAME=$2),
801 ifelse([$3], , [AC_CV_NAME=NotReallyATypeCross; AC_CV_NAME_supported=no], AC_CV_NAME=$3))]) dnl
802 CPPFLAGS="$fp_check_htype_save_cppflags"
803 if test "$AC_CV_NAME_supported" = yes; then
804   AC_MSG_RESULT($AC_CV_NAME)
805   AC_DEFINE_UNQUOTED(AC_TYPE_NAME, $AC_CV_NAME, [Define to Haskell type for $1])
806 else
807   AC_MSG_RESULT([not supported])
808 fi
809 undefine([AC_TYPE_NAME])dnl
810 undefine([AC_CV_NAME])dnl
811 undefine([AC_CV_NAME_supported])dnl
812 ])
813
814
815 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
816 # ---------------------------------------------------------------------------------
817 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
818 # additional flexibility of specifying the PROLOGUE and BODY.
819 AC_DEFUN([FP_CHECK_FUNC],
820 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
821 AC_CACHE_CHECK([for $1], fp_func,
822 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
823                 [AS_VAR_SET(fp_func, yes)],
824                 [AS_VAR_SET(fp_func, no)])])
825 AS_IF([test AS_VAR_GET(fp_func) = yes],
826       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
827                 [Define to 1 if you have the `]$1[' function.]) $4],
828       [$5])dnl
829 AS_VAR_POPDEF([fp_func])dnl
830 ])# FP_CHECK_FUNC
831
832
833 # FP_GEN_DOCBOOK_XML
834 # ------------------
835 # Generates a DocBook XML V4.2 document in conftest.xml.
836 AC_DEFUN([FP_GEN_DOCBOOK_XML],
837 [rm -f conftest.xml
838 cat > conftest.xml << EOF
839 <?xml version="1.0" encoding="iso-8859-1"?>
840 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.2//EN"
841    "http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd">
842 <book id="test">
843   <title>A DocBook Test Document</title>
844   <chapter id="id-one">
845     <title>A Chapter Title</title>
846     <para>This is a paragraph, referencing <xref linkend="id-two"/>.</para>
847   </chapter>
848   <chapter id="id-two">
849     <title>Another Chapter Title</title>
850     <para>This is another paragraph, referencing <xref linkend="id-one"/>.</para>
851   </chapter>
852 </book>
853 EOF
854 ]) # FP_GEN_DOCBOOK_XML
855
856
857 # FP_PROG_XSLTPROC
858 # ----------------
859 # Sets the output variable XsltprocCmd to the full path of the XSLT processor
860 # xsltproc. XsltprocCmd is empty if xsltproc could not be found.
861 AC_DEFUN([FP_PROG_XSLTPROC],
862 [AC_PATH_PROG([XsltprocCmd], [xsltproc])
863 if test -z "$XsltprocCmd"; then
864   AC_MSG_WARN([cannot find xsltproc in your PATH, you will not be able to build the documentation])
865 fi
866 ])# FP_PROG_XSLTPROC
867
868
869 # FP_DIR_DOCBOOK_XSL(XSL-DIRS)
870 # ----------------------------
871 # Check which of the directories XSL-DIRS contains DocBook XSL stylesheets. The
872 # output variable DIR_DOCBOOK_XSL will contain the first usable directory or
873 # will be empty if none could be found.
874 AC_DEFUN([FP_DIR_DOCBOOK_XSL],
875 [AC_REQUIRE([FP_PROG_XSLTPROC])dnl
876 if test -n "$XsltprocCmd"; then
877   AC_CACHE_CHECK([for DocBook XSL stylesheet directory], fp_cv_dir_docbook_xsl,
878   [FP_GEN_DOCBOOK_XML
879   fp_cv_dir_docbook_xsl=no
880   for fp_var in $1; do
881      if $XsltprocCmd ${fp_var}/html/docbook.xsl conftest.xml > /dev/null 2>&1; then
882         fp_cv_dir_docbook_xsl=$fp_var
883         break
884      fi
885   done
886   rm -rf conftest*])
887 fi
888 if test x"$fp_cv_dir_docbook_xsl" = xno; then
889   AC_MSG_WARN([cannot find DocBook XSL stylesheets, you will not be able to build the documentation])
890   DIR_DOCBOOK_XSL=
891 else
892   DIR_DOCBOOK_XSL=$fp_cv_dir_docbook_xsl
893 fi
894 AC_SUBST([DIR_DOCBOOK_XSL])
895 ])# FP_DIR_DOCBOOK_XSL
896
897
898 # FP_PROG_XMLLINT
899 # ----------------
900 # Sets the output variable XmllintCmd to the full path of the XSLT processor
901 # xmllint. XmllintCmd is empty if xmllint could not be found.
902 AC_DEFUN([FP_PROG_XMLLINT],
903 [AC_PATH_PROG([XmllintCmd], [xmllint])
904 if test -z "$XmllintCmd"; then
905   AC_MSG_WARN([cannot find xmllint in your PATH, you will not be able to validate your documentation])
906 fi
907 ])# FP_PROG_XMLLINT
908
909
910 # FP_CHECK_DOCBOOK_DTD
911 # --------------------
912 AC_DEFUN([FP_CHECK_DOCBOOK_DTD],
913 [AC_REQUIRE([FP_PROG_XMLLINT])dnl
914 if test -n "$XmllintCmd"; then
915   AC_MSG_CHECKING([for DocBook DTD])
916   FP_GEN_DOCBOOK_XML
917   if $XmllintCmd --valid --noout conftest.xml > /dev/null 2>&1; then
918     AC_MSG_RESULT([ok])
919   else
920     AC_MSG_RESULT([failed])
921     AC_MSG_WARN([cannot find a DTD for DocBook XML V4.2, you will not be able to validate your documentation])
922     AC_MSG_WARN([check your XML_CATALOG_FILES environment variable and/or /etc/xml/catalog])
923   fi
924   rm -rf conftest*
925 fi
926 ])# FP_CHECK_DOCBOOK_DTD
927
928
929 # FP_PROG_FO_PROCESSOR
930 # --------------------
931 # Try to find an FO processor. PassiveTeX output is sometimes a bit strange, so
932 # try FOP first.  Furthermore, /usr/bin/fop is broken in SuSE 9.1, so try the
933 # "real" fop.sh first. Sets the output variables FopCmd, XmltexCmd, DvipsCmd,
934 # and PdfxmltexCmd.
935 AC_DEFUN([FP_PROG_FO_PROCESSOR],
936 [AC_PATH_PROGS([FopCmd], [fop.sh fop], [], [$PATH:/usr/share/fop])
937 AC_PATH_PROG([XmltexCmd], [xmltex])
938 AC_PATH_PROG([DvipsCmd], [dvips])
939 if test -z "$FopCmd"; then
940   if test -z "$XmltexCmd"; then
941     AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI or PostScript documentation])
942   else
943     if test -z "$DvipsCmd"; then
944       AC_MSG_WARN([cannot find a DVI  => PS converter, you will not be able to build PostScript documentation])
945     fi
946   fi
947   AC_PATH_PROG([PdfxmltexCmd], [pdfxmltex])
948   if test -z "$PdfxmltexCmd"; then
949     AC_MSG_WARN([cannot find an FO => PDF converter, you will not be able to build PDF documentation])
950   fi
951 elif test -z "$XmltexCmd"; then
952   AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI documentation])
953 fi
954 ])# FP_PROG_FO_PROCESSOR
955
956
957 # FP_CHECK_WIN32
958 # --------------
959 # If Windows is the target platform (e.g. MinGW/MSYS or Cygwin with
960 # -mno-cygwin), the variable "is_win32" is set to "yes", otherwise (e.g. *nix
961 # systems or plain Cygwin) it is set to "no".
962 AC_DEFUN([FP_CHECK_WIN32],
963 [AC_CACHE_CHECK([for Windows environment], [fp_cv_is_win32],
964   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
965 #if !_WIN32
966    syntax error;
967 #endif
968 ])], [fp_cv_is_win32=yes], [fp_cv_is_win32=no])])
969 is_win32="$fp_cv_is_win32"[]dnl
970 ])# FP_CHECK_WIN32
971
972
973 # FP_PATH_X
974 # ---------
975 # Same as AC_PATH_X, but works even for broken Cygwins which try to include the
976 # non-existant <gl/mesa_wgl.h> header when -mno-cygwin is used.
977 AC_DEFUN([FP_PATH_X],
978 [AC_REQUIRE([FP_CHECK_WIN32])
979 if test x"$is_win32" = xyes; then
980   no_x=yes
981 else
982   AC_PATH_X
983 fi
984 ])# FP_PATH_X
985
986
987 # FP_PATH_XTRA
988 # ------------
989 # Same as AC_PATH_XTRA, but works even for broken Cygwins which try to include
990 # the non-existant <gl/mesa_wgl.h> header when -mno-cygwin is used.
991 AC_DEFUN([FP_PATH_XTRA],
992 [AC_REQUIRE([FP_CHECK_WIN32])
993 if test x"$is_win32" = xyes; then
994   no_x=yes
995 else
996   AC_PATH_XTRA
997 fi
998 ])# FP_PATH_XTRA
999
1000
1001 # FP_CHECK_GL_HELPER(LIBNAME, LIBS, INCLUDES, FUNCTION-BODY)
1002 # ----------------------------------------------------------
1003 # Try each library in LIBS to successfully link INCLUDES plus FUNCTION-BODY,
1004 # setting LIBNAME_CFLAGS and LIBNAME_LIBS to the corresponding values. Sets
1005 # no_LIBNAME to "yes" if no suitable library was found. (LIBNAME_CFLAGS0
1006 # contains the value of LIBNAME_CFLAGS without CPPFLAGS, and LIBNAME_LIBS0
1007 # contains the value of LIBNAME_LIBS without LDFLAGS, but these are only
1008 # used internally.)
1009 AC_DEFUN([FP_CHECK_GL_HELPER],
1010 [AC_CACHE_CHECK([for $1 library], [fp_cv_check_$1_lib],
1011   [fp_cv_check_$1_lib="no"
1012   fp_save_CPPFLAGS="$CPPFLAGS"
1013   CPPFLAGS="$CPPFLAGS ${$1_CFLAGS}"
1014   fp_save_LIBS="$LIBS"
1015   for fp_try_lib in $2; do
1016     # transform "-lfoo" to "foo.lib" when using cl
1017     if test x"$CC" = xcl; then
1018       fp_try_lib=`echo $fp_try_lib | sed -e 's/^-l//' -e 's/$/.lib/'`
1019     fi
1020     LIBS="$fp_try_lib ${$1_LIBS} $fp_save_LIBS"
1021     AC_TRY_LINK([$3], [$4], [fp_cv_check_$1_lib="$fp_try_lib ${$1_LIBS}"; break])
1022   done
1023   LIBS="$fp_save_LIBS"
1024   CPPFLAGS="$fp_save_CPPFLAGS"])
1025
1026   if test x"$fp_cv_check_$1_lib" = xno; then
1027     no_$1=yes
1028     $1_CFLAGS=
1029     $1_LIBS=
1030   else
1031     $1_CFLAGS0="${$1_CFLAGS}"
1032     $1_CFLAGS="$CPPFLAGS ${$1_CFLAGS0}"
1033     $1_LIBS0="$fp_cv_check_$1_lib"
1034     $1_LIBS="$LDFLAGS ${$1_LIBS0}"
1035   fi
1036 ])# FP_CHECK_GL_HELPER
1037
1038
1039 # FP_CHECK_GL
1040 # -----------
1041 AC_DEFUN([FP_CHECK_GL],
1042 [AC_REQUIRE([FP_PATH_X])
1043 AC_REQUIRE([AC_CANONICAL_SYSTEM])
1044
1045 AC_ARG_ENABLE([hopengl],
1046   [AC_HELP_STRING([--enable-hopengl],
1047     [build a Haskell binding for OpenGL (GL/GLU). On Mac OS X, use
1048      --enable-hopengl=x11 to use X11 instead of the "native" libraries.
1049      (default=no)])],
1050   [enable_opengl=$enableval], [enable_opengl=no])
1051
1052 if test x"$enable_opengl" = xno; then
1053    no_GL=yes
1054 else
1055   use_quartz_opengl=no
1056   case $target_os in
1057   darwin*)
1058     if test x"$enable_opengl" != xx11; then
1059       AC_DEFINE([USE_QUARTZ_OPENGL], [1],
1060                 [Define to 1 if native OpenGL should be used on Mac OS X])
1061       use_quartz_opengl=yes
1062     fi
1063     ;;
1064   esac
1065
1066   if test x"$use_quartz_opengl" != xyes; then
1067     AC_CHECK_LIB([m], [atan], [GL_LIBS="-lm $GL_LIBS"])
1068
1069     if test x"$no_x" != xyes; then
1070       test -n "$x_includes" && GL_CFLAGS="-I$x_includes $GL_CFLAGS"
1071       test -n "$x_libraries" && GL_LIBS="-L$x_libraries -lX11 $GL_LIBS"
1072     fi
1073
1074     FP_CHECK_GL_HELPER([GL], [-lGL -lopengl32], [@%:@include <GL/gl.h>], [glEnd()])
1075
1076     if test x"$no_GL" != xyes; then
1077       # Ugly: To get wglGetProcAddress on Windows, we have to link with
1078       # opengl32.dll, too, even when we are using Cygwin with X11.
1079       case "$GL_LIBS" in
1080         *-lopengl32*|*opengl32.lib*) ;;
1081         *) fp_save_LIBS="$LIBS"
1082            LIBS="$LIBS -lopengl32"
1083            AC_TRY_LINK([@%:@include <GL/gl.h>], [glEnd()],
1084              [GL_LIBS="$GL_LIBS -lopengl32"; GL_LIBS0="$GL_LIBS0 -lopengl32"])
1085            LIBS="$fp_save_LIBS"
1086            ;;
1087       esac
1088     fi
1089   fi
1090 fi
1091
1092 AC_SUBST([GL_CFLAGS])
1093 AC_SUBST([GL_LIBS])
1094 ])# FP_CHECK_GL
1095
1096
1097 # FP_CHECK_GLU
1098 # ------------
1099 AC_DEFUN([FP_CHECK_GLU],
1100 [AC_REQUIRE([FP_CHECK_GL])dnl
1101 GLU_CFLAGS="$GL_CFLAGS0"
1102 GLU_LIBS="$GL_LIBS0"
1103
1104 if test x"$enable_opengl" = xno; then
1105    no_GLU=yes
1106 elif test x"$use_quartz_opengl" != xyes; then
1107   FP_CHECK_GL_HELPER([GLU], [-lglu32 -lGLU], [@%:@include <GL/glu.h>], [gluNewQuadric()])
1108 fi
1109
1110 AC_SUBST([GLU_CFLAGS])
1111 AC_SUBST([GLU_LIBS])
1112 ])# FP_CHECK_GLU
1113
1114
1115 # FP_CHECK_GLUT
1116 # -------------
1117 AC_DEFUN([FP_CHECK_GLUT],
1118 [AC_REQUIRE([FP_CHECK_GLU])
1119 FP_PATH_XTRA
1120
1121 if test x"$enable_opengl" = xno; then
1122    no_GLUT=yes
1123 elif test x"$use_quartz_opengl" != xyes; then
1124   GLUT_CFLAGS="$GLU_CFLAGS0"
1125   GLUT_LIBS="$GLU_LIBS0"
1126
1127   if test x"$no_x" != xyes; then
1128     GLUT_LIBS="$X_PRE_LIBS -lXmu -lXi $X_EXTRA_LIBS $GLUT_LIBS"
1129   fi
1130
1131   AC_CHECK_HEADERS([windows.h GL/glut.h])
1132   # Note 1: On Cygwin with X11, GL/GLU functions use the "normal" calling
1133   # convention, but GLUT functions use stdcall. To get this right, it is
1134   # necessary to include <windows.h> first.
1135   # Note 2: MinGW/MSYS comes without a GLUT header, so we use Cygwin's one in
1136   # that case.
1137   FP_CHECK_GL_HELPER([GLUT], [-lglut32 -lglut], [
1138 #if HAVE_WINDOWS_H
1139 #include <windows.h>
1140 #endif
1141 #if HAVE_GL_GLUT_H
1142 #include <GL/glut.h>
1143 #else
1144 #include "glut_local.h"
1145 #endif
1146     ], [glutMainLoop()])
1147 fi
1148
1149 AC_SUBST([GLUT_CFLAGS])
1150 AC_SUBST([GLUT_LIBS])
1151 ])# FP_CHECK_GLUT
1152
1153
1154 dnl @synopsis FP_EMPTY_STRUCTS
1155 dnl 
1156 dnl Check whether empty structs is accepted by CC.
1157 dnl
1158 AC_DEFUN(FP_EMPTY_STRUCTS,
1159 [AC_CACHE_CHECK(empty struct support, fptools_cv_empty_structs,
1160 [AC_TRY_COMPILE([
1161 typedef struct { /*empty*/ } StgFoo;
1162 ],
1163 [int i;], 
1164 fptools_cv_empty_structs=yes,
1165 fptools_cv_empty_structs=no)])
1166 if test "$fptools_cv_empty_structs" = yes; then
1167 AC_DEFINE([SUPPORTS_EMPTY_STRUCTS], [1], [Define to 1 if C compiler supports declaration of empty structure types.])
1168 fi
1169 ])
1170
1171
1172 dnl @synopsis FP_READDIR_EOF_ERRNO
1173 dnl
1174 dnl Check what readdir() sets 'errno' to upon reaching 
1175 dnl end of directory; not setting it is the correct thing to do,
1176 dnl but mingw based versions have set it to ENOENT until recently
1177 dnl (summer 2004).
1178 dnl
1179 dnl
1180 AC_DEFUN(FP_READDIR_EOF_ERRNO,
1181 [AC_CACHE_CHECK([what readdir sets errno to upon EOF], fptools_cv_readdir_eof_errno,
1182 [AC_TRY_RUN([#include <dirent.h>
1183 #include <stdio.h>
1184 #include <errno.h>
1185 int
1186 main(argc, argv)
1187 int argc;
1188 char **argv;
1189 {
1190   FILE *f=fopen("conftestval", "w");
1191 #if defined(__MINGW32__)
1192   int fd = mkdir("testdir");
1193 #else
1194   int fd = mkdir("testdir", 0666);
1195 #endif
1196   DIR* dp;
1197   struct dirent* de;
1198   int err = 0;
1199
1200   if (!f) return 1;
1201   if (fd == -1) { 
1202      fprintf(stderr,"unable to create directory; quitting.\n");
1203      return 1;
1204   }
1205   close(fd);
1206   dp = opendir("testdir");
1207   if (!dp) { 
1208      fprintf(stderr,"unable to browse directory; quitting.\n");
1209      rmdir("testdir");
1210      return 1;
1211   }
1212
1213   /* the assumption here is that readdir() will only return NULL
1214    * due to reaching the end of the directory.
1215    */
1216   while (de = readdir(dp)) {
1217         ;
1218   }
1219   err = errno;
1220   fprintf(f,"%d", err);
1221   fclose(f);
1222   closedir(de);
1223   rmdir("testdir");
1224   return 0;
1225 }],fptools_cv_readdir_eof_errno=`cat conftestval`, fptools_cv_readdir_eof_errno=bogus, fptools_cv_readdir_eof_errno=0)])
1226 dnl the cross value is somewhat bogus.
1227 AC_DEFINE_UNQUOTED([READDIR_ERRNO_EOF], [$fptools_cv_readdir_eof_errno], [readdir() sets errno to this upon EOF])
1228 ])
1229
1230 dnl @synopsis FP_DIRENT_FLAT_LAYOUT
1231 dnl
1232 dnl Check whether 'struct dirent' (in dirent.h) has d_name defined
1233 dnl as being the final field in a struct, or a pointer to somewhere
1234 dnl else. The former is the standardly thing to do, but mingw defns
1235 dnl have for the longest time gone for the latter. They no longer do,
1236 dnl hence the need to configure test for this.
1237 dnl
1238 dnl
1239 AC_DEFUN(FP_DIRENT_FLAT_LAYOUT,
1240 [AC_CACHE_CHECK([if struct dirent layout is flat], fptools_cv_dirent_flat_layout,
1241 [AC_TRY_RUN([#include <dirent.h>
1242 #include <stdio.h>
1243 #include <string.h>
1244 int
1245 main(argc, argv)
1246 int argc;
1247 char **argv;
1248 {
1249   struct dirent de;
1250   /*
1251    * Check whether d_name is defined as
1252    *    struct dirent { .... ; char d_name[..]; } 
1253    * or
1254    *    struct dirent { .... ; char* d_name; } 
1255    * 
1256    * Returns 0 if the former.
1257    */
1258   memset(&de,0,sizeof(struct dirent));
1259   return ((int)de.d_name == 0);
1260 }],fptools_cv_dirent_flat_layout=yes, fptools_cv_dirent_flat_layout=no, fptools_cv_dirent_flat_layout=yes)])
1261 dnl the cross value is somewhat bogus.
1262 if test "$fptools_cv_dirent_flat_layout" = yes; then
1263 AC_DEFINE([STRUCT_DIRENT_FLAT_LAYOUT], [1], [Define to 1 if struct dirent is a flat structure])
1264 fi
1265 ])
1266
1267
1268 # LocalWords:  fi