Remove support for the --enable-hc-boot flag in configure
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.7], [glasgow-haskell-bugs@haskell.org], [ghc])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands, 
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42 FP_PROG_SORT
43
44 dnl ----------------------------------------------------------
45 FP_SETUP_PROJECT_VERSION
46
47 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
48 AC_SUBST([release], [1])
49
50 # First off, a distrib sanity check..
51 AC_CONFIG_SRCDIR([mk/config.mk.in])
52
53 dnl * We require autoconf version 2.60
54 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
55 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
56 dnl Using autoconf 2.59 started to give nonsense like this
57 dnl  #define SIZEOF_CHAR 0
58 dnl recently.
59 AC_PREREQ([2.60])
60
61 # -------------------------------------------------------------------------
62 # Prepare to generate the following header files
63 #
64 #
65 AC_CONFIG_HEADER(mk/config.h)
66
67 # No, semi-sadly, we don't do `--srcdir'...
68 if test x"$srcdir" != 'x.' ; then
69     echo "This configuration does not support the \`--srcdir' option.."
70     exit 1
71 fi
72
73 dnl --------------------------------------------------------------
74 dnl * Project specific configuration options
75 dnl --------------------------------------------------------------
76 dnl What follows is a bunch of options that can either be configured
77 dnl through command line options to the configure script or by
78 dnl supplying defns in the build tree's mk/build.mk. Having the option to
79 dnl use either is considered a Feature.
80
81 dnl ** What command to use to compile compiler sources ?
82 dnl --------------------------------------------------------------
83
84 AC_ARG_WITH([ghc],
85 [AC_HELP_STRING([--with-ghc=ARG],
86   [Use ARG as the path to GHC  [default=autodetect]])],
87   [WithGhc="$withval"],
88   [if test "$GHC" = ""; then
89     AC_PATH_PROG([GHC], [ghc])
90   fi
91   WithGhc="$GHC"])
92
93 dnl ** Tell the make system which OS we are using
94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something 
95 AC_SUBST(OSTYPE)
96
97 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
98 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
99                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
100         EnableBootstrapWithDevelSnaphost=YES,
101         EnableBootstrapWithDevelSnaphost=NO
102 )
103
104 if test "$WithGhc" != ""; then
105   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
106
107   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
108      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
109   fi
110
111   AC_SUBST(GhcVersion)dnl
112   AC_SUBST(GhcMajVersion)dnl
113   AC_SUBST(GhcMinVersion)dnl
114   AC_SUBST(GhcPatchLevel)dnl
115   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
116   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
117
118   BOOTSTRAPPING_GHC_INFO_FIELD([OS_STAGE0],[target os])
119   BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
120   if test "x$OS_STAGE0" != "xOSDarwin"; then
121     BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
122     BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
123     BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
124   else
125     AR_STAGE0='$(AR)'
126     AR_OPTS_STAGE0='$(AR_OPTS)'
127     ArSupportsAtFile_STAGE0='$(ArSupportsAtFile)'
128   fi
129 fi
130
131 dnl ** Must have GHC to build GHC
132   if test "$WithGhc" = ""; then
133      AC_MSG_ERROR([GHC is required.])
134   fi
135   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.4],
136     [AC_MSG_ERROR([GHC version 7.4 or later is required to compile GHC.])])dnl
137
138   if test `expr $GhcMinVersion % 2` = "1"; then
139      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
140         AC_MSG_ERROR([
141      $WithGhc is a development snapshot of GHC, version $GhcVersion.
142      Bootstrapping using this version of GHC is not supported, and may not
143      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
144      or --with-ghc to specify a different GHC to use.])
145      fi
146   fi
147
148   GHC_PACKAGE_DB_FLAG=package-db
149   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.5],GHC_PACKAGE_DB_FLAG=package-conf)
150   AC_SUBST(GHC_PACKAGE_DB_FLAG)
151
152 # GHC is passed to Cabal, so we need a native path
153 if test "${WithGhc}" != ""
154 then
155     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
156
157     if test "$ghc_host_os" = "mingw32"
158     then
159         if test "${OSTYPE}" = "msys"
160         then
161             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
162         else
163             # Canonicalise to <drive>:/path/to/ghc
164             WithGhc=`cygpath -m "${WithGhc}"`
165         fi
166         echo "GHC path canonicalised to: ${WithGhc}"
167     fi
168 fi
169 AC_SUBST([WithGhc])
170
171 dnl ** Without optimization some INLINE trickery fails for GHCi
172 SRC_CC_OPTS="-O"
173
174 dnl--------------------------------------------------------------------
175 dnl * Choose host(/target/build) platform
176 dnl--------------------------------------------------------------------
177 dnl If we aren't explicitly told what values to use with configure flags,
178 dnl we ask the bootstrapping compiler what platform it is for
179
180 if test "${WithGhc}" != ""
181 then
182         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
183         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
184         if test "$bootstrap_host" != "$bootstrap_target"
185         then
186                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
187         fi
188 fi
189
190 # We have to run these unconditionally, but we may discard their
191 # results in the following code
192 AC_CANONICAL_BUILD
193 AC_CANONICAL_HOST
194 AC_CANONICAL_TARGET
195
196 FPTOOLS_SET_PLATFORM_VARS
197
198 # Verify that the installed (bootstrap) GHC is capable of generating
199 # code for the requested build platform.
200     if test "$BuildPlatform" != "$bootstrap_target"
201     then
202         echo "This GHC (${WithGhc}) does not generate code for the build platform"
203         echo "   GHC target platform    : $bootstrap_target"
204         echo "   Desired build platform : $BuildPlatform"
205         exit 1
206     fi
207
208 # Testing if we shall enable shared libs support on Solaris.
209 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
210
211 SOLARIS_BROKEN_SHLD=NO
212
213 case $host in
214      i386-*-solaris2)
215      # here we go with the test
216      MINOR=`uname -r|cut -d '.' -f 2-`
217      if test "$MINOR" -lt "11"; then
218         SOLARIS_BROKEN_SHLD=YES
219      fi
220      ;;
221 esac
222
223 AC_SUBST(SOLARIS_BROKEN_SHLD)
224
225 dnl ** Do an unregisterised build?
226 dnl --------------------------------------------------------------
227 case "$HostArch" in
228     i386|x86_64|powerpc|arm)
229         UnregisterisedDefault=NO
230         ;;
231     *)
232         UnregisterisedDefault=YES
233         ;;
234 esac
235 AC_ARG_ENABLE(unregisterised,
236 [AC_HELP_STRING([--enable-unregisterised],
237 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
238 [ if test x"$enableval" = x"yes"; then
239         Unregisterised=YES
240   else
241         Unregisterised=NO
242   fi
243 ],
244 [Unregisterised="$UnregisterisedDefault"]
245 )
246 AC_SUBST(Unregisterised)
247
248 AC_ARG_WITH(hc,
249 [AC_HELP_STRING([--with-hc=ARG],
250         [Use ARG as the path to the compiler for compiling ordinary
251          Haskell code  (default= value of --with-ghc)])],
252 [WithHc="$withval"],
253 [WithHc=$WithGhc]
254 )
255 AC_SUBST(WithHc)
256
257 # This uses GHC, so put it after the "GHC is required" check above:
258 FP_INTREE_GHC_PWD
259 FP_FIND_ROOT
260
261 if test "$HostOS" = "mingw32"
262 then
263     test -d inplace || mkdir inplace
264
265     if test "$HostArch" = "i386"
266     then
267         # NB. If you update the tarballs to a new version of gcc, don't
268         # forget to tweak the paths in driver/gcc/gcc.c.
269         if ! test -d inplace/mingw ||
270              test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma  ||
271              test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma  ||
272              test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma   ||
273              test inplace/mingw -ot ghc-tarballs/mingw/libgcc*.tar.gz      ||
274              test inplace/mingw -ot ghc-tarballs/mingw/libgmp*.tar.gz      ||
275              test inplace/mingw -ot ghc-tarballs/mingw/libmpc*.tar.gz      ||
276              test inplace/mingw -ot ghc-tarballs/mingw/libmpfr*.tar.gz     ||
277              test inplace/mingw -ot ghc-tarballs/mingw/libstdc*.tar.lzma   ||
278              test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dev.tar.gz ||
279              test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dll.tar.gz ||
280              test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
281         then
282             AC_MSG_NOTICE([Making in-tree mingw tree])
283             rm -rf inplace/mingw
284             mkdir inplace/mingw
285             (
286                 cd inplace/mingw &&
287                 tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma  &&
288                 tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma  &&
289                 tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma   &&
290                 tar --lzma -xf ../../ghc-tarballs/mingw/libgcc*.tar.lzma    &&
291                 tar --lzma -xf ../../ghc-tarballs/mingw/libgmp*.tar.lzma    &&
292                 tar --lzma -xf ../../ghc-tarballs/mingw/libmpc*.tar.lzma    &&
293                 tar --lzma -xf ../../ghc-tarballs/mingw/libmpfr*.tar.lzma   &&
294                 tar --lzma -xf ../../ghc-tarballs/mingw/libstdc*.tar.lzma   &&
295                 tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dev.tar.gz &&
296                 tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dll.tar.gz &&
297                 tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma    &&
298                 mv bin/gcc.exe bin/realgcc.exe
299             )
300             PATH=`pwd`/inplace/mingw/bin:$PATH inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
301             AC_MSG_NOTICE([In-tree mingw tree created])
302         fi
303     else
304         # NB. If you update the tarballs to a new version of gcc, don't
305         # forget to tweak the paths in driver/gcc/gcc.c.
306         if ! test -d inplace/mingw ||
307              test inplace/mingw -ot ghc-tarballs/mingw64/*.tar.bz2
308         then
309             AC_MSG_NOTICE([Making in-tree mingw tree])
310             rm -rf inplace/mingw
311             mkdir inplace/mingw
312             (
313                 cd inplace/mingw &&
314                 tar -jxf ../../ghc-tarballs/mingw64/*.tar.bz2
315             )
316             AC_MSG_NOTICE([In-tree mingw tree created])
317         fi
318     fi
319
320     mingwbin="$hardtop/inplace/mingw/bin/"
321     CC="${mingwbin}gcc.exe"
322     LD="${mingwbin}ld.exe"
323     NM="${mingwbin}nm.exe"
324     OBJDUMP="${mingwbin}objdump.exe"
325     fp_prog_ar="${mingwbin}ar.exe"
326
327     if ! test -d inplace/perl ||
328          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
329     then
330         AC_MSG_NOTICE([Making in-tree perl tree])
331         rm -rf inplace/perl
332         mkdir inplace/perl
333         (
334             cd inplace/perl &&
335             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
336         )
337         AC_MSG_NOTICE([In-tree perl tree created])
338     fi
339 fi
340
341 # system libffi
342
343 AC_ARG_WITH([system-libffi],
344 [AC_HELP_STRING([--with-system-libffi],
345   [Use system provided libffi for RTS [default=no]])
346 ])
347
348 AS_IF([test "x$with_system_libffi" = "xyes"],
349   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
350 )
351
352
353 AC_SUBST(UseSystemLibFFI)
354
355 AC_ARG_WITH([ffi-includes],
356 [AC_HELP_STRING([--with-ffi-includes=ARG]
357   [Find includes for libffi in ARG [default=system default]])
358 ],
359 [
360  if test "x$UseSystemLibFFI" != "xYES"; then
361     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
362  else
363     FFIIncludeDir="$withval"
364     LIBFFI_CFLAGS="-I $withval" 
365  fi
366 ])
367
368 AC_SUBST(FFIIncludeDir)
369
370 AC_ARG_WITH([ffi-libraries],
371 [AC_HELP_STRING([--with-ffi-libraries=ARG]
372   [Find libffi in ARG [default=system default]])
373 ],
374 [
375  if test "x$UseSystemLibFFI" != "xYES"; then
376     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
377  else
378     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
379  fi
380 ])
381
382 AC_SUBST(FFILibDir)
383
384 AS_IF([test "$UseSystemLibFFI" = "YES"], [
385  CFLAGS2="$CFLAGS"
386  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
387  LDFLAGS2="$LDFLAGS"
388  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
389  AC_CHECK_LIB(ffi, ffi_call,
390   [AC_CHECK_HEADERS([ffi.h], [break], [])
391    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
392   [AC_MSG_ERROR([Cannot find system libffi])])
393  CFLAGS="$CFLAGS2"
394  LDFLAGS="$LDFLAGS2"
395 ])
396
397 FP_ICONV
398 FP_GMP
399
400 XCODE_VERSION()
401
402 SplitObjsBroken=NO
403 if test "$TargetOS_CPP" = "darwin"
404 then
405     # Split objects is broken (#4013) with XCode < 3.2
406     if test "$XCodeVersion1" -lt 3
407     then
408         SplitObjsBroken=YES
409     else
410         if test "$XCodeVersion1" -eq 3
411         then
412             if test "$XCodeVersion2" -lt 2
413             then
414                 SplitObjsBroken=YES
415             fi
416         fi
417     fi
418 fi
419 AC_SUBST([SplitObjsBroken])
420
421 dnl ** Building a cross compiler?
422 dnl --------------------------------------------------------------
423 CrossCompiling=NO
424 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
425 if test "$target" != "$host" ; then
426     CrossCompiling=YES
427     cross_compiling=yes   # This tells configure that it can accept just 'target',
428                           # otherwise you get
429                           #   configure: error: cannot run C compiled programs.
430                           #   If you meant to cross compile, use `--host'.
431 fi
432 if test "$build" != "$host" ; then
433    AC_MSG_ERROR([
434 You've selected:
435
436   BUILD:  $build   (the architecture we're building on)
437   HOST:   $host    (the architecture the compiler we're building will execute on)
438   TARGET: $target  (the architecture the compiler we're building will produce code for)
439
440 BUILD must equal HOST; that is, we do not support building GHC itself
441 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
442 1 will be a cross-compiler, and stage 2 will be the cross-compiled
443 GHC.
444 ])
445 fi
446 if test "$CrossCompiling" = "YES"
447 then
448   CrossCompilePrefix="${target}-"
449 else
450   CrossCompilePrefix=""
451 fi
452 TargetPlatformFull="${target}"
453 AC_SUBST(CrossCompiling)
454 AC_SUBST(CrossCompilePrefix)
455 AC_SUBST(TargetPlatformFull)
456
457 dnl ** Which gcc to use?
458 dnl --------------------------------------------------------------
459 FIND_GCC([WhatGccIsCalled], [gcc], [gcc])
460 CC="$WhatGccIsCalled"
461 export CC
462
463 dnl ** Which ld to use?
464 dnl --------------------------------------------------------------
465 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld], [ld])
466 LdCmd="$LD"
467 AC_SUBST([LdCmd])
468
469 dnl ** Which nm to use?
470 dnl --------------------------------------------------------------
471 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
472 NmCmd="$NM"
473 AC_SUBST([NmCmd])
474
475 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
476 case $HostOS_CPP in
477 cygwin32|mingw32)
478     dnl ** Which objdump to use?
479     dnl --------------------------------------------------------------
480     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
481     ObjdumpCmd="$OBJDUMP"
482     AC_SUBST([ObjdumpCmd])
483     ;;
484 esac
485
486 dnl ** Which LLVM llc to use?
487 dnl --------------------------------------------------------------
488 FIND_LLVM_PROG([LLC], [llc], [llc])
489 LlcCmd="$LLC"
490 AC_SUBST([LlcCmd])
491
492 dnl ** Which LLVM opt to use?
493 dnl --------------------------------------------------------------
494 FIND_LLVM_PROG([OPT], [opt], [opt])
495 OptCmd="$OPT"
496 AC_SUBST([OptCmd])
497
498 dnl ** Mac OS X: explicit deployment target
499 dnl --------------------------------------------------------------
500 AC_ARG_WITH([macosx-deployment-target],
501 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
502         [Build for Mac OS VERSION and higher  (default= version of build host)])],
503 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
504  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
505    # ignore everywhere, but on Mac OS
506    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
507    FP_MACOSX_DEPLOYMENT_TARGET=none
508  fi],
509 [FP_MACOSX_DEPLOYMENT_TARGET=none]
510 )
511 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
512 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
513 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
514
515 dnl --------------------------------------------------------------
516 dnl End of configure script option section
517 dnl --------------------------------------------------------------
518
519
520 dnl --------------------------------------------------------------
521 dnl * General configuration checks
522 dnl --------------------------------------------------------------
523
524 dnl ** Can the unix package be built?
525 dnl --------------------------------------------------------------
526
527 if test "$TargetOS" = "mingw32"
528 then
529     GhcLibsWithUnix=NO
530 else
531     GhcLibsWithUnix=YES
532 fi
533 AC_SUBST([GhcLibsWithUnix])
534
535 dnl ** does #! work?
536 AC_SYS_INTERPRETER()
537
538 dnl ** look for `perl'
539 case $HostOS_CPP in
540 cygwin32|mingw32)
541     PerlCmd=$hardtop/inplace/perl/perl
542     ;;
543 *)
544     AC_PATH_PROG(PerlCmd,perl)
545     if test -z "$PerlCmd"
546     then
547         echo "You must install perl before you can continue"
548         echo "Perhaps it is already installed, but not in your PATH?"
549         exit 1
550     else
551         FPTOOLS_CHECK_PERL_VERSION
552     fi
553     ;;
554 esac
555
556 dnl ** look for GCC and find out which version
557 dnl     Figure out which C compiler to use.  Gcc is preferred.
558 dnl     If gcc, make sure it's at least 3.0
559 dnl
560 FP_GCC_VERSION
561
562 dnl ** look to see if we have a C compiler using an llvm back end.
563 dnl
564 FP_CC_LLVM_BACKEND
565
566 FP_PROG_LD_HashSize31
567 FP_PROG_LD_ReduceMemoryOverheads
568 FP_PROG_LD_IS_GNU
569 FP_PROG_LD_BUILD_ID
570 FP_PROG_LD_NO_COMPACT_UNWIND
571
572
573 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
574 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
575 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
576 # Stage 3 won't be supported by cross-compilation
577 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
578
579 FP_GCC_EXTRA_FLAGS
580
581 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
582 AC_PROG_CPP
583
584 AC_SUBST(CONF_CC_OPTS_STAGE0)
585 AC_SUBST(CONF_CC_OPTS_STAGE1)
586 AC_SUBST(CONF_CC_OPTS_STAGE2)
587 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
588 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
589 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
590 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
591 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
592 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
593 AC_SUBST(CONF_CPP_OPTS_STAGE0)
594 AC_SUBST(CONF_CPP_OPTS_STAGE1)
595 AC_SUBST(CONF_CPP_OPTS_STAGE2)
596
597 dnl ** Set up the variables for the platform in the settings file.
598 dnl May need to use gcc to find platform details.
599 dnl --------------------------------------------------------------
600 FPTOOLS_SET_HASKELL_PLATFORM_VARS
601
602 dnl ** figure out how to do context diffs
603 FP_PROG_CONTEXT_DIFF
604
605 dnl Let's make sure install-sh is executable here.  If we got it from
606 dnl a darcs repo, it might not be (see bug #978).
607 chmod +x install-sh
608 dnl ** figure out how to do a BSD-ish install
609 AC_PROG_INSTALL
610
611 dnl If you can run configure, you certainly have /bin/sh
612 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
613
614 dnl ** how to invoke `ar' and `ranlib'
615 FP_PROG_AR_SUPPORTS_ATFILE
616 FP_PROG_AR_NEEDS_RANLIB
617
618 dnl ** Check to see whether ln -s works
619 AC_PROG_LN_S
620
621 FP_SETTINGS
622
623 dnl ** Find the path to sed
624 AC_PATH_PROGS(SedCmd,gsed sed,sed)
625
626
627 dnl ** check for time command
628 AC_PATH_PROG(TimeCmd,time)
629
630 dnl ** check for tar
631 dnl   if GNU tar is named gtar, look for it first.
632 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
633
634 dnl ** check for patch
635 dnl if GNU patch is named gpatch, look for it first
636 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
637
638 dnl ** check for dtrace (currently only implemented for Mac OS X)
639 HaveDtrace=NO
640 AC_PATH_PROG(DtraceCmd,dtrace)
641 if test -n "$DtraceCmd"; then
642   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
643     HaveDtrace=YES
644   fi
645 fi
646 AC_SUBST(HaveDtrace)
647
648 AC_PATH_PROG(HSCOLOUR,HsColour)
649 # HsColour is passed to Cabal, so we need a native path
650 if test "$HostOS"      = "mingw32" && \
651    test "${OSTYPE}"   != "msys"    && \
652    test "${HSCOLOUR}" != ""
653 then
654     # Canonicalise to <drive>:/path/to/gcc
655     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
656 fi
657
658 dnl ** check for DocBook toolchain
659 FP_CHECK_DOCBOOK_DTD
660 FP_DOCBOOK_XSL
661 FP_PROG_DBLATEX
662
663 dnl ** check for ghc-pkg command
664 FP_PROG_GHC_PKG
665
666 dnl ** check for installed happy binary + version
667 FPTOOLS_HAPPY
668
669 dnl ** check for installed alex binary + version
670 FPTOOLS_ALEX
671
672 dnl --------------------------------------------------
673 dnl ### program checking section ends here ###
674 dnl --------------------------------------------------
675
676 dnl --------------------------------------------------
677 dnl * Platform header file and syscall feature tests
678 dnl ### checking the state of the local header files and syscalls ###
679
680 dnl ** check for full ANSI header (.h) files
681 AC_HEADER_STDC
682
683 dnl ** Enable large file support.  NB. do this before testing the type of
684 dnl    off_t, because it will affect the result of that test.
685 AC_SYS_LARGEFILE
686
687 dnl ** check for specific header (.h) files that we are interested in
688 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/cpuset.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
689
690 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
691 AC_HEADER_TIME
692
693 dnl ** do we have long longs?
694 AC_CHECK_TYPES([long long])
695
696 dnl ** what are the sizes of various types
697 AC_CHECK_SIZEOF(char,               1)
698 AC_CHECK_SIZEOF(double,             8)
699 AC_CHECK_SIZEOF(float,              4)
700 AC_CHECK_SIZEOF(int,                4)
701 AC_CHECK_SIZEOF(long,               4)
702 if test "$ac_cv_type_long_long" = yes; then
703 AC_CHECK_SIZEOF(long long,          8)
704 fi
705 AC_CHECK_SIZEOF(short,              2)
706 AC_CHECK_SIZEOF(unsigned char,      1)
707 AC_CHECK_SIZEOF(unsigned int,       4)
708 AC_CHECK_SIZEOF(unsigned long,      4)
709 if test "$ac_cv_type_long_long" = yes; then
710 AC_CHECK_SIZEOF(unsigned long long, 8)
711 fi
712 AC_CHECK_SIZEOF(unsigned short,     2)
713 AC_CHECK_SIZEOF(void *,             4)
714
715 dnl for use in settings.in
716 WordSize=$ac_cv_sizeof_void_p
717 AC_SUBST(WordSize)
718
719 dnl ** what are alignment constraints on various types
720 FP_CHECK_ALIGNMENT(char)
721 FP_CHECK_ALIGNMENT(double)
722 FP_CHECK_ALIGNMENT(float)
723 FP_CHECK_ALIGNMENT(int)
724 FP_CHECK_ALIGNMENT(long)
725 if test "$ac_cv_type_long_long" = yes; then
726 FP_CHECK_ALIGNMENT(long long)
727 fi
728 FP_CHECK_ALIGNMENT(short)
729 FP_CHECK_ALIGNMENT(unsigned char)
730 FP_CHECK_ALIGNMENT(unsigned int)
731 FP_CHECK_ALIGNMENT(unsigned long)
732 if test "$ac_cv_type_long_long" = yes; then
733 FP_CHECK_ALIGNMENT(unsigned long long)
734 fi
735 FP_CHECK_ALIGNMENT(unsigned short)
736 FP_CHECK_ALIGNMENT(void *)
737
738 FP_CHECK_FUNC([WinExec],
739   [@%:@include <windows.h>], [WinExec("",0)])
740
741 FP_CHECK_FUNC([GetModuleFileName],
742   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
743
744 dnl ** check return type of signal handlers
745 dnl Foo: assumes we can use prototypes.
746 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
747 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
748 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
749 dnl #include <signal.h>
750 dnl #ifdef signal
751 dnl #undef signal
752 dnl #endif
753 dnl void (*signal (int, void (*)(int)))(int);
754 dnl ]],
755 dnl [[int i;]])],
756 dnl [ac_cv_type_signal_handler=void_int],
757 dnl [ac_cv_type_signal_handler=int_void])])
758 dnl if test "$ac_cv_type_signal_handler" = void_int; then
759 dnl AC_DEFINE(VOID_INT_SIGNALS)
760 dnl fi
761
762 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
763 AC_TYPE_SIGNAL
764 if test "$ac_cv_type_signal" = void; then
765   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
766 fi
767
768 dnl ** check for more functions
769 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
770 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
771
772 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
773 dnl ** _POSIX_C_SOURCE is defined
774 AC_CHECK_DECLS([ctime_r], , ,
775 [#define _POSIX_SOURCE 1
776 #define _POSIX_C_SOURCE 199506L
777 #include <time.h>])
778
779 dnl ** check for mingwex library
780 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
781 AC_SUBST(HaveLibMingwEx)
782
783 if test $HaveLibMingwEx = YES ; then
784   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
785 fi
786
787 dnl ** check for math library
788 dnl    Keep that check as early as possible.
789 dnl    as we need to know whether we need libm
790 dnl    for math functions or not
791 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
792 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
793 if test $HaveLibM = YES
794 then
795   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
796 fi
797
798 dnl ** check whether this machine has BFD and libiberty installed (used for debugging)
799 dnl    the order of these tests matters: bfd needs libiberty
800 AC_CHECK_LIB(iberty, xmalloc)
801 AC_CHECK_LIB(bfd,    bfd_uncompress_section_contents)
802
803 dnl ################################################################
804 dnl Check for libraries
805 dnl ################################################################
806
807 dnl ** check whether we need -ldl to get dlopen()
808
809 AC_CHECK_LIB(dl, dlopen,
810     [HaveLibDL=YES
811      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
812      LIBS="$LIBS -ldl"],
813     [HaveLibDL=NO])
814 AC_SUBST(HaveLibDL)
815
816 dnl --------------------------------------------------
817 dnl * Miscellaneous feature tests
818 dnl --------------------------------------------------
819
820 dnl ** can we get alloca?
821 AC_FUNC_ALLOCA
822
823 dnl ** working vfork?
824 AC_FUNC_FORK
825
826 dnl ** determine whether or not const works
827 AC_C_CONST
828
829 dnl ** are we big endian?
830 AC_C_BIGENDIAN
831 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
832
833 dnl ** check for leading underscores in symbol names
834 FP_LEADING_UNDERSCORE
835
836 FP_VISIBILITY_HIDDEN
837
838 dnl ** check for librt
839 AC_CHECK_LIB(rt, clock_gettime)
840 AC_CHECK_FUNCS(clock_gettime timer_settime)
841 FP_CHECK_TIMER_CREATE
842
843 dnl ** check for Apple's "interesting" long double compatibility scheme
844 AC_MSG_CHECKING(for printf\$LDBLStub)
845 AC_TRY_LINK_FUNC(printf\$LDBLStub,
846     [
847         AC_MSG_RESULT(yes)
848         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
849             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
850     ],
851     [
852         AC_MSG_RESULT(no)
853         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
854             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
855     ])
856
857 dnl ** check for eventfd which is needed by the I/O manager
858 AC_CHECK_HEADERS([sys/eventfd.h])
859 AC_CHECK_FUNCS([eventfd])
860
861 # test for GTK+
862 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
863 if test -n "$GTK_CONFIG"; then
864   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
865     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
866   else
867     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
868     GTK_CONFIG=
869   fi
870 fi
871 AC_SUBST([GTK_CONFIG])
872
873 # checking for PAPI
874 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
875 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
876 AC_SUBST(HavePapiLib)
877 AC_SUBST(HavePapiHeader)
878
879 AC_CHECK_FUNCS(__mingw_vfprintf)
880
881 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
882    HavePapi=YES
883 else
884    HavePapi=NO
885 fi
886 AC_SUBST(HavePapi)
887
888 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
889    test "$XsltprocCmd" = ""
890 then
891     BUILD_DOCBOOK_HTML=NO
892 else
893     BUILD_DOCBOOK_HTML=YES
894 fi
895 AC_SUBST(BUILD_DOCBOOK_HTML)
896
897 if test "$DblatexCmd" = ""
898 then
899     BUILD_DOCBOOK_PS=NO
900     BUILD_DOCBOOK_PDF=NO
901 else
902     BUILD_DOCBOOK_PS=YES
903     BUILD_DOCBOOK_PDF=YES
904 fi
905 AC_SUBST(BUILD_DOCBOOK_PS)
906 AC_SUBST(BUILD_DOCBOOK_PDF)
907
908 LIBRARY_VERSION(base)
909 LIBRARY_VERSION(Cabal, Cabal/Cabal)
910 LIBRARY_VERSION(ghc-prim)
911 LIBRARY_ghc_VERSION="$ProjectVersion"
912 AC_SUBST(LIBRARY_ghc_VERSION)
913
914 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
915    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
916 fi
917
918 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal ghc.spec settings docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/ghc.iss distrib/configure.ac])
919 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
920 AC_OUTPUT
921
922 # We got caught by
923 #     http://savannah.gnu.org/bugs/index.php?1516
924 #     $(eval ...) inside conditionals causes errors
925 # with make 3.80, so warn the user if it looks like they're about to
926 # try to use it.
927 # We would use "grep -q" here, but Solaris's grep doesn't support it.
928 checkMake380() {
929     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
930     then
931         echo
932         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
933         echo "This version cannot be used to build GHC."
934         echo "Please use GNU make >= 3.81."
935     fi
936 }
937
938 checkMake380 make
939 checkMake380 gmake
940
941 echo ["
942 ----------------------------------------------------------------------
943 Configure completed successfully.
944
945    Building GHC version  : $ProjectVersion
946
947    Build platform        : $BuildPlatform
948    Host platform         : $HostPlatform
949    Target platform       : $TargetPlatform
950 "]
951
952 echo ["\
953    Bootstrapping using   : $WithGhc
954       which is version   : $GhcVersion
955 "]
956
957 if test "x$CC_LLVM_BACKEND" = "x1"; then
958     if test "x$CC_CLANG_BACKEND" = "x1"; then
959         CompilerName="clang        "
960     else
961         CompilerName="llvm-gcc     "
962     fi
963 else
964     CompilerName="gcc          "
965 fi
966
967 echo ["\
968    Using $CompilerName       : $WhatGccIsCalled
969       which is version       : $GccVersion
970    Building a cross compiler : $CrossCompiling
971
972    ld       : $LdCmd
973    Happy    : $HappyCmd ($HappyVersion)
974    Alex     : $AlexCmd ($AlexVersion)
975    Perl     : $PerlCmd
976    dblatex  : $DblatexCmd
977    xsltproc : $XsltprocCmd
978
979    Using LLVM tools
980       llc   : $LlcCmd
981       opt   : $OptCmd"]
982
983 if test "$HSCOLOUR" = ""; then
984 echo ["
985    HsColour was not found; documentation will not contain source links
986 "]
987 else
988 echo ["\
989    HsColour : $HSCOLOUR
990 "]
991 fi
992
993 echo ["\
994    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
995    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
996    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
997
998 echo ["----------------------------------------------------------------------
999 "]
1000
1001 echo "\
1002 For a standard build of GHC (fully optimised with profiling), type (g)make.
1003
1004 To make changes to the default build configuration, copy the file
1005 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1006
1007 For more information on how to configure your GHC build, see
1008    http://hackage.haskell.org/trac/ghc/wiki/Building
1009 "