add a comment about LD_STAGE0
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.7], [glasgow-haskell-bugs@haskell.org], [ghc])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands, 
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42 FP_PROG_SORT
43
44 dnl ----------------------------------------------------------
45 FP_SETUP_PROJECT_VERSION
46
47 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
48 AC_SUBST([release], [1])
49
50 # First off, a distrib sanity check..
51 AC_CONFIG_SRCDIR([mk/config.mk.in])
52
53 dnl * We require autoconf version 2.60
54 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
55 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
56 dnl Using autoconf 2.59 started to give nonsense like this
57 dnl  #define SIZEOF_CHAR 0
58 dnl recently.
59 AC_PREREQ([2.60])
60
61 # -------------------------------------------------------------------------
62 # Prepare to generate the following header files
63 #
64 #
65 AC_CONFIG_HEADER(mk/config.h)
66
67 # No, semi-sadly, we don't do `--srcdir'...
68 if test x"$srcdir" != 'x.' ; then
69     echo "This configuration does not support the \`--srcdir' option.."
70     exit 1
71 fi
72
73 dnl --------------------------------------------------------------
74 dnl * Project specific configuration options
75 dnl --------------------------------------------------------------
76 dnl What follows is a bunch of options that can either be configured
77 dnl through command line options to the configure script or by
78 dnl supplying defns in the build tree's mk/build.mk. Having the option to
79 dnl use either is considered a Feature.
80
81 dnl ** What command to use to compile compiler sources ?
82 dnl --------------------------------------------------------------
83
84 AC_ARG_WITH([ghc],
85 [AC_HELP_STRING([--with-ghc=ARG],
86   [Use ARG as the path to GHC  [default=autodetect]])],
87   [WithGhc="$withval"],
88   [if test "$GHC" = ""; then
89     AC_PATH_PROG([GHC], [ghc])
90   fi
91   WithGhc="$GHC"])
92
93 dnl ** Tell the make system which OS we are using
94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something 
95 AC_SUBST(OSTYPE)
96
97 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
98 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
99                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
100         EnableBootstrapWithDevelSnaphost=YES,
101         EnableBootstrapWithDevelSnaphost=NO
102 )
103
104 if test "$WithGhc" != ""; then
105   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
106
107   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
108      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
109   fi
110
111   AC_SUBST(GhcVersion)dnl
112   AC_SUBST(GhcMajVersion)dnl
113   AC_SUBST(GhcMinVersion)dnl
114   AC_SUBST(GhcPatchLevel)dnl
115   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
116   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
117
118   BOOTSTRAPPING_GHC_INFO_FIELD([OS_STAGE0],[target os])
119   BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
120   dnl ToDo, once "ld command" is reliably available.
121   dnl Then, we can remove the LD_STAGE0 hack in mk/build-package-date.mk
122   dnl BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
123   if test "x$OS_STAGE0" != "xOSDarwin"; then
124     BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
125     BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
126     BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
127   else
128     AR_STAGE0='$(AR)'
129     AR_OPTS_STAGE0='$(AR_OPTS)'
130     ArSupportsAtFile_STAGE0='$(ArSupportsAtFile)'
131   fi
132 fi
133
134 dnl ** Must have GHC to build GHC
135 if test "$WithGhc" = ""
136 then
137     AC_MSG_ERROR([GHC is required.])
138 fi
139 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.4],
140     [AC_MSG_ERROR([GHC version 7.4 or later is required to compile GHC.])])dnl
141
142 if test `expr $GhcMinVersion % 2` = "1"
143 then
144     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
145     then
146         AC_MSG_ERROR([
147      $WithGhc is a development snapshot of GHC, version $GhcVersion.
148      Bootstrapping using this version of GHC is not supported, and may not
149      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
150      or --with-ghc to specify a different GHC to use.])
151     fi
152 fi
153
154 GHC_PACKAGE_DB_FLAG=package-db
155 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.5],GHC_PACKAGE_DB_FLAG=package-conf)
156 AC_SUBST(GHC_PACKAGE_DB_FLAG)
157
158 # GHC is passed to Cabal, so we need a native path
159 if test "${WithGhc}" != ""
160 then
161     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
162
163     if test "$ghc_host_os" = "mingw32"
164     then
165         if test "${OSTYPE}" = "msys"
166         then
167             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
168         else
169             # Canonicalise to <drive>:/path/to/ghc
170             WithGhc=`cygpath -m "${WithGhc}"`
171         fi
172         echo "GHC path canonicalised to: ${WithGhc}"
173     fi
174 fi
175 AC_SUBST([WithGhc])
176
177 dnl ** Without optimization some INLINE trickery fails for GHCi
178 SRC_CC_OPTS="-O"
179
180 dnl--------------------------------------------------------------------
181 dnl * Choose host(/target/build) platform
182 dnl--------------------------------------------------------------------
183 dnl If we aren't explicitly told what values to use with configure flags,
184 dnl we ask the bootstrapping compiler what platform it is for
185
186 if test "${WithGhc}" != ""
187 then
188         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
189         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
190         if test "$bootstrap_host" != "$bootstrap_target"
191         then
192                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
193         fi
194 fi
195
196 # We have to run these unconditionally, but we may discard their
197 # results in the following code
198 AC_CANONICAL_BUILD
199 AC_CANONICAL_HOST
200 AC_CANONICAL_TARGET
201
202 FPTOOLS_SET_PLATFORM_VARS
203
204 # Verify that the installed (bootstrap) GHC is capable of generating
205 # code for the requested build platform.
206 if test "$BuildPlatform" != "$bootstrap_target"
207 then
208     echo "This GHC (${WithGhc}) does not generate code for the build platform"
209     echo "   GHC target platform    : $bootstrap_target"
210     echo "   Desired build platform : $BuildPlatform"
211     exit 1
212 fi
213
214 # Testing if we shall enable shared libs support on Solaris.
215 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
216
217 SOLARIS_BROKEN_SHLD=NO
218
219 case $host in
220      i386-*-solaris2)
221      # here we go with the test
222      MINOR=`uname -r|cut -d '.' -f 2-`
223      if test "$MINOR" -lt "11"; then
224         SOLARIS_BROKEN_SHLD=YES
225      fi
226      ;;
227 esac
228
229 AC_SUBST(SOLARIS_BROKEN_SHLD)
230
231 dnl ** Do an unregisterised build?
232 dnl --------------------------------------------------------------
233 case "$HostArch" in
234     i386|x86_64|powerpc|arm)
235         UnregisterisedDefault=NO
236         ;;
237     *)
238         UnregisterisedDefault=YES
239         ;;
240 esac
241 AC_ARG_ENABLE(unregisterised,
242 [AC_HELP_STRING([--enable-unregisterised],
243 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
244 [ if test x"$enableval" = x"yes"; then
245         Unregisterised=YES
246   else
247         Unregisterised=NO
248   fi
249 ],
250 [Unregisterised="$UnregisterisedDefault"]
251 )
252 AC_SUBST(Unregisterised)
253
254 AC_ARG_WITH(hc,
255 [AC_HELP_STRING([--with-hc=ARG],
256         [Use ARG as the path to the compiler for compiling ordinary
257          Haskell code  (default= value of --with-ghc)])],
258 [WithHc="$withval"],
259 [WithHc=$WithGhc]
260 )
261 AC_SUBST(WithHc)
262
263 # This uses GHC, so put it after the "GHC is required" check above:
264 FP_INTREE_GHC_PWD
265 FP_FIND_ROOT
266
267 if test "$HostOS" = "mingw32"
268 then
269     test -d inplace || mkdir inplace
270
271     if test "$HostArch" = "i386"
272     then
273         # NB. If you update the tarballs to a new version of gcc, don't
274         # forget to tweak the paths in driver/gcc/gcc.c.
275         if ! test -d inplace/mingw ||
276              test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma  ||
277              test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma  ||
278              test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma   ||
279              test inplace/mingw -ot ghc-tarballs/mingw/libgcc*.tar.gz      ||
280              test inplace/mingw -ot ghc-tarballs/mingw/libgmp*.tar.gz      ||
281              test inplace/mingw -ot ghc-tarballs/mingw/libmpc*.tar.gz      ||
282              test inplace/mingw -ot ghc-tarballs/mingw/libmpfr*.tar.gz     ||
283              test inplace/mingw -ot ghc-tarballs/mingw/libstdc*.tar.lzma   ||
284              test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dev.tar.gz ||
285              test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dll.tar.gz ||
286              test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
287         then
288             AC_MSG_NOTICE([Making in-tree mingw tree])
289             rm -rf inplace/mingw
290             mkdir inplace/mingw
291             (
292                 cd inplace/mingw &&
293                 tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma  &&
294                 tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma  &&
295                 tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma   &&
296                 tar --lzma -xf ../../ghc-tarballs/mingw/libgcc*.tar.lzma    &&
297                 tar --lzma -xf ../../ghc-tarballs/mingw/libgmp*.tar.lzma    &&
298                 tar --lzma -xf ../../ghc-tarballs/mingw/libmpc*.tar.lzma    &&
299                 tar --lzma -xf ../../ghc-tarballs/mingw/libmpfr*.tar.lzma   &&
300                 tar --lzma -xf ../../ghc-tarballs/mingw/libstdc*.tar.lzma   &&
301                 tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dev.tar.gz &&
302                 tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dll.tar.gz &&
303                 tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma    &&
304                 mv bin/gcc.exe bin/realgcc.exe
305             )
306             PATH=`pwd`/inplace/mingw/bin:$PATH inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
307             AC_MSG_NOTICE([In-tree mingw tree created])
308         fi
309     else
310         # NB. If you update the tarballs to a new version of gcc, don't
311         # forget to tweak the paths in driver/gcc/gcc.c.
312         if ! test -d inplace/mingw ||
313              test inplace/mingw -ot ghc-tarballs/mingw64/*.tar.bz2
314         then
315             AC_MSG_NOTICE([Making in-tree mingw tree])
316             rm -rf inplace/mingw
317             mkdir inplace/mingw
318             (
319                 cd inplace/mingw &&
320                 tar -jxf ../../ghc-tarballs/mingw64/*.tar.bz2
321             )
322             AC_MSG_NOTICE([In-tree mingw tree created])
323         fi
324     fi
325
326     mingwbin="$hardtop/inplace/mingw/bin/"
327     CC="${mingwbin}gcc.exe"
328     LD="${mingwbin}ld.exe"
329     NM="${mingwbin}nm.exe"
330     OBJDUMP="${mingwbin}objdump.exe"
331     fp_prog_ar="${mingwbin}ar.exe"
332
333     if ! test -d inplace/perl ||
334          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
335     then
336         AC_MSG_NOTICE([Making in-tree perl tree])
337         rm -rf inplace/perl
338         mkdir inplace/perl
339         (
340             cd inplace/perl &&
341             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
342         )
343         AC_MSG_NOTICE([In-tree perl tree created])
344     fi
345 fi
346
347 # system libffi
348
349 AC_ARG_WITH([system-libffi],
350 [AC_HELP_STRING([--with-system-libffi],
351   [Use system provided libffi for RTS [default=no]])
352 ])
353
354 AS_IF([test "x$with_system_libffi" = "xyes"],
355   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
356 )
357
358
359 AC_SUBST(UseSystemLibFFI)
360
361 AC_ARG_WITH([ffi-includes],
362 [AC_HELP_STRING([--with-ffi-includes=ARG]
363   [Find includes for libffi in ARG [default=system default]])
364 ],
365 [
366  if test "x$UseSystemLibFFI" != "xYES"; then
367     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
368  else
369     FFIIncludeDir="$withval"
370     LIBFFI_CFLAGS="-I $withval" 
371  fi
372 ])
373
374 AC_SUBST(FFIIncludeDir)
375
376 AC_ARG_WITH([ffi-libraries],
377 [AC_HELP_STRING([--with-ffi-libraries=ARG]
378   [Find libffi in ARG [default=system default]])
379 ],
380 [
381  if test "x$UseSystemLibFFI" != "xYES"; then
382     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
383  else
384     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
385  fi
386 ])
387
388 AC_SUBST(FFILibDir)
389
390 AS_IF([test "$UseSystemLibFFI" = "YES"], [
391  CFLAGS2="$CFLAGS"
392  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
393  LDFLAGS2="$LDFLAGS"
394  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
395  AC_CHECK_LIB(ffi, ffi_call,
396   [AC_CHECK_HEADERS([ffi.h], [break], [])
397    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
398   [AC_MSG_ERROR([Cannot find system libffi])])
399  CFLAGS="$CFLAGS2"
400  LDFLAGS="$LDFLAGS2"
401 ])
402
403 FP_ICONV
404 FP_GMP
405
406 XCODE_VERSION()
407
408 SplitObjsBroken=NO
409 if test "$TargetOS_CPP" = "darwin"
410 then
411     # Split objects is broken (#4013) with XCode < 3.2
412     if test "$XCodeVersion1" -lt 3
413     then
414         SplitObjsBroken=YES
415     else
416         if test "$XCodeVersion1" -eq 3
417         then
418             if test "$XCodeVersion2" -lt 2
419             then
420                 SplitObjsBroken=YES
421             fi
422         fi
423     fi
424 fi
425 AC_SUBST([SplitObjsBroken])
426
427 dnl ** Building a cross compiler?
428 dnl --------------------------------------------------------------
429 CrossCompiling=NO
430 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
431 if test "$target" != "$host" ; then
432     CrossCompiling=YES
433     cross_compiling=yes   # This tells configure that it can accept just 'target',
434                           # otherwise you get
435                           #   configure: error: cannot run C compiled programs.
436                           #   If you meant to cross compile, use `--host'.
437 fi
438 if test "$build" != "$host" ; then
439    AC_MSG_ERROR([
440 You've selected:
441
442   BUILD:  $build   (the architecture we're building on)
443   HOST:   $host    (the architecture the compiler we're building will execute on)
444   TARGET: $target  (the architecture the compiler we're building will produce code for)
445
446 BUILD must equal HOST; that is, we do not support building GHC itself
447 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
448 1 will be a cross-compiler, and stage 2 will be the cross-compiled
449 GHC.
450 ])
451 fi
452 if test "$CrossCompiling" = "YES"
453 then
454   CrossCompilePrefix="${target}-"
455 else
456   CrossCompilePrefix=""
457 fi
458 TargetPlatformFull="${target}"
459 AC_SUBST(CrossCompiling)
460 AC_SUBST(CrossCompilePrefix)
461 AC_SUBST(TargetPlatformFull)
462
463 dnl ** Which gcc to use?
464 dnl --------------------------------------------------------------
465 FIND_GCC([WhatGccIsCalled], [gcc], [gcc])
466 CC="$WhatGccIsCalled"
467 export CC
468
469 dnl ** Which ld to use?
470 dnl --------------------------------------------------------------
471 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld], [ld])
472 LdCmd="$LD"
473 AC_SUBST([LdCmd])
474
475 dnl ** Which nm to use?
476 dnl --------------------------------------------------------------
477 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
478 NmCmd="$NM"
479 AC_SUBST([NmCmd])
480
481 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
482 case $HostOS_CPP in
483 cygwin32|mingw32)
484     dnl ** Which objdump to use?
485     dnl --------------------------------------------------------------
486     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
487     ObjdumpCmd="$OBJDUMP"
488     AC_SUBST([ObjdumpCmd])
489     ;;
490 esac
491
492 dnl ** Which LLVM llc to use?
493 dnl --------------------------------------------------------------
494 FIND_LLVM_PROG([LLC], [llc], [llc])
495 LlcCmd="$LLC"
496 AC_SUBST([LlcCmd])
497
498 dnl ** Which LLVM opt to use?
499 dnl --------------------------------------------------------------
500 FIND_LLVM_PROG([OPT], [opt], [opt])
501 OptCmd="$OPT"
502 AC_SUBST([OptCmd])
503
504 dnl --------------------------------------------------------------
505 dnl End of configure script option section
506 dnl --------------------------------------------------------------
507
508
509 dnl --------------------------------------------------------------
510 dnl * General configuration checks
511 dnl --------------------------------------------------------------
512
513 dnl ** Can the unix package be built?
514 dnl --------------------------------------------------------------
515
516 if test "$TargetOS" = "mingw32"
517 then
518     GhcLibsWithUnix=NO
519 else
520     GhcLibsWithUnix=YES
521 fi
522 AC_SUBST([GhcLibsWithUnix])
523
524 dnl ** does #! work?
525 AC_SYS_INTERPRETER()
526
527 dnl ** look for `perl'
528 case $HostOS_CPP in
529 cygwin32|mingw32)
530     PerlCmd=$hardtop/inplace/perl/perl
531     ;;
532 *)
533     AC_PATH_PROG(PerlCmd,perl)
534     if test -z "$PerlCmd"
535     then
536         echo "You must install perl before you can continue"
537         echo "Perhaps it is already installed, but not in your PATH?"
538         exit 1
539     else
540         FPTOOLS_CHECK_PERL_VERSION
541     fi
542     ;;
543 esac
544
545 dnl ** look for GCC and find out which version
546 dnl     Figure out which C compiler to use.  Gcc is preferred.
547 dnl     If gcc, make sure it's at least 3.0
548 dnl
549 FP_GCC_VERSION
550
551 dnl ** look to see if we have a C compiler using an llvm back end.
552 dnl
553 FP_CC_LLVM_BACKEND
554
555 FP_PROG_LD_HashSize31
556 FP_PROG_LD_ReduceMemoryOverheads
557 FP_PROG_LD_IS_GNU
558 FP_PROG_LD_BUILD_ID
559 FP_PROG_LD_NO_COMPACT_UNWIND
560
561
562 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
563 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
564 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
565 # Stage 3 won't be supported by cross-compilation
566 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
567
568 FP_GCC_EXTRA_FLAGS
569
570 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
571 AC_PROG_CPP
572
573 AC_SUBST(CONF_CC_OPTS_STAGE0)
574 AC_SUBST(CONF_CC_OPTS_STAGE1)
575 AC_SUBST(CONF_CC_OPTS_STAGE2)
576 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
577 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
578 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
579 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
580 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
581 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
582 AC_SUBST(CONF_CPP_OPTS_STAGE0)
583 AC_SUBST(CONF_CPP_OPTS_STAGE1)
584 AC_SUBST(CONF_CPP_OPTS_STAGE2)
585
586 dnl ** Set up the variables for the platform in the settings file.
587 dnl May need to use gcc to find platform details.
588 dnl --------------------------------------------------------------
589 FPTOOLS_SET_HASKELL_PLATFORM_VARS
590
591 dnl ** figure out how to do context diffs
592 FP_PROG_CONTEXT_DIFF
593
594 dnl Let's make sure install-sh is executable here.  If we got it from
595 dnl a darcs repo, it might not be (see bug #978).
596 chmod +x install-sh
597 dnl ** figure out how to do a BSD-ish install
598 AC_PROG_INSTALL
599
600 dnl If you can run configure, you certainly have /bin/sh
601 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
602
603 dnl ** how to invoke `ar' and `ranlib'
604 FP_PROG_AR_SUPPORTS_ATFILE
605 FP_PROG_AR_NEEDS_RANLIB
606
607 dnl ** Check to see whether ln -s works
608 AC_PROG_LN_S
609
610 FP_SETTINGS
611
612 dnl ** Find the path to sed
613 AC_PATH_PROGS(SedCmd,gsed sed,sed)
614
615
616 dnl ** check for time command
617 AC_PATH_PROG(TimeCmd,time)
618
619 dnl ** check for tar
620 dnl   if GNU tar is named gtar, look for it first.
621 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
622
623 dnl ** check for patch
624 dnl if GNU patch is named gpatch, look for it first
625 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
626
627 dnl ** check for dtrace (currently only implemented for Mac OS X)
628 HaveDtrace=NO
629 AC_PATH_PROG(DtraceCmd,dtrace)
630 if test -n "$DtraceCmd"; then
631   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
632     HaveDtrace=YES
633   fi
634 fi
635 AC_SUBST(HaveDtrace)
636
637 AC_PATH_PROG(HSCOLOUR,HsColour)
638 # HsColour is passed to Cabal, so we need a native path
639 if test "$HostOS"      = "mingw32" && \
640    test "${OSTYPE}"   != "msys"    && \
641    test "${HSCOLOUR}" != ""
642 then
643     # Canonicalise to <drive>:/path/to/gcc
644     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
645 fi
646
647 dnl ** check for DocBook toolchain
648 FP_CHECK_DOCBOOK_DTD
649 FP_DOCBOOK_XSL
650 FP_PROG_DBLATEX
651
652 dnl ** check for ghc-pkg command
653 FP_PROG_GHC_PKG
654
655 dnl ** check for installed happy binary + version
656 FPTOOLS_HAPPY
657
658 dnl ** check for installed alex binary + version
659 FPTOOLS_ALEX
660
661 dnl --------------------------------------------------
662 dnl ### program checking section ends here ###
663 dnl --------------------------------------------------
664
665 dnl --------------------------------------------------
666 dnl * Platform header file and syscall feature tests
667 dnl ### checking the state of the local header files and syscalls ###
668
669 dnl ** check for full ANSI header (.h) files
670 AC_HEADER_STDC
671
672 dnl ** Enable large file support.  NB. do this before testing the type of
673 dnl    off_t, because it will affect the result of that test.
674 AC_SYS_LARGEFILE
675
676 dnl ** check for specific header (.h) files that we are interested in
677 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
678
679 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
680 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
681 [[#if HAVE_SYS_PARAM_H
682 # include <sys/param.h>
683 #endif
684 ]])
685
686 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
687 AC_HEADER_TIME
688
689 dnl ** do we have long longs?
690 AC_CHECK_TYPES([long long])
691
692 dnl ** what are the sizes of various types
693 AC_CHECK_SIZEOF(char,               1)
694 AC_CHECK_SIZEOF(double,             8)
695 AC_CHECK_SIZEOF(float,              4)
696 AC_CHECK_SIZEOF(int,                4)
697 AC_CHECK_SIZEOF(long,               4)
698 if test "$ac_cv_type_long_long" = yes; then
699 AC_CHECK_SIZEOF(long long,          8)
700 fi
701 AC_CHECK_SIZEOF(short,              2)
702 AC_CHECK_SIZEOF(unsigned char,      1)
703 AC_CHECK_SIZEOF(unsigned int,       4)
704 AC_CHECK_SIZEOF(unsigned long,      4)
705 if test "$ac_cv_type_long_long" = yes; then
706 AC_CHECK_SIZEOF(unsigned long long, 8)
707 fi
708 AC_CHECK_SIZEOF(unsigned short,     2)
709 AC_CHECK_SIZEOF(void *,             4)
710
711 dnl for use in settings.in
712 WordSize=$ac_cv_sizeof_void_p
713 AC_SUBST(WordSize)
714
715 dnl ** what are alignment constraints on various types
716 FP_CHECK_ALIGNMENT(char)
717 FP_CHECK_ALIGNMENT(double)
718 FP_CHECK_ALIGNMENT(float)
719 FP_CHECK_ALIGNMENT(int)
720 FP_CHECK_ALIGNMENT(long)
721 if test "$ac_cv_type_long_long" = yes; then
722 FP_CHECK_ALIGNMENT(long long)
723 fi
724 FP_CHECK_ALIGNMENT(short)
725 FP_CHECK_ALIGNMENT(unsigned char)
726 FP_CHECK_ALIGNMENT(unsigned int)
727 FP_CHECK_ALIGNMENT(unsigned long)
728 if test "$ac_cv_type_long_long" = yes; then
729 FP_CHECK_ALIGNMENT(unsigned long long)
730 fi
731 FP_CHECK_ALIGNMENT(unsigned short)
732 FP_CHECK_ALIGNMENT(void *)
733
734 FP_CHECK_FUNC([WinExec],
735   [@%:@include <windows.h>], [WinExec("",0)])
736
737 FP_CHECK_FUNC([GetModuleFileName],
738   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
739
740 dnl ** check return type of signal handlers
741 dnl Foo: assumes we can use prototypes.
742 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
743 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
744 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
745 dnl #include <signal.h>
746 dnl #ifdef signal
747 dnl #undef signal
748 dnl #endif
749 dnl void (*signal (int, void (*)(int)))(int);
750 dnl ]],
751 dnl [[int i;]])],
752 dnl [ac_cv_type_signal_handler=void_int],
753 dnl [ac_cv_type_signal_handler=int_void])])
754 dnl if test "$ac_cv_type_signal_handler" = void_int; then
755 dnl AC_DEFINE(VOID_INT_SIGNALS)
756 dnl fi
757
758 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
759 AC_TYPE_SIGNAL
760 if test "$ac_cv_type_signal" = void; then
761   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
762 fi
763
764 dnl ** check for more functions
765 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
766 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
767
768 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
769 dnl ** _POSIX_C_SOURCE is defined
770 AC_CHECK_DECLS([ctime_r], , ,
771 [#define _POSIX_SOURCE 1
772 #define _POSIX_C_SOURCE 199506L
773 #include <time.h>])
774
775 dnl ** check for mingwex library
776 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
777 AC_SUBST(HaveLibMingwEx)
778
779 if test $HaveLibMingwEx = YES ; then
780   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
781 fi
782
783 dnl ** check for math library
784 dnl    Keep that check as early as possible.
785 dnl    as we need to know whether we need libm
786 dnl    for math functions or not
787 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
788 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
789 if test $HaveLibM = YES
790 then
791   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
792 fi
793
794 dnl ** check whether this machine has BFD and libiberty installed (used for debugging)
795 dnl    the order of these tests matters: bfd needs libiberty
796 AC_CHECK_LIB(iberty, xmalloc)
797 AC_CHECK_LIB(bfd,    bfd_uncompress_section_contents)
798
799 dnl ################################################################
800 dnl Check for libraries
801 dnl ################################################################
802
803 dnl ** check whether we need -ldl to get dlopen()
804
805 AC_CHECK_LIB(dl, dlopen,
806     [HaveLibDL=YES
807      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
808      LIBS="$LIBS -ldl"],
809     [HaveLibDL=NO])
810 AC_SUBST(HaveLibDL)
811
812 dnl --------------------------------------------------
813 dnl * Miscellaneous feature tests
814 dnl --------------------------------------------------
815
816 dnl ** can we get alloca?
817 AC_FUNC_ALLOCA
818
819 dnl ** working vfork?
820 AC_FUNC_FORK
821
822 dnl ** determine whether or not const works
823 AC_C_CONST
824
825 dnl ** are we big endian?
826 AC_C_BIGENDIAN
827 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
828
829 dnl ** check for leading underscores in symbol names
830 FP_LEADING_UNDERSCORE
831
832 FP_VISIBILITY_HIDDEN
833
834 dnl ** check for librt
835 AC_CHECK_LIB(rt, clock_gettime)
836 AC_CHECK_FUNCS(clock_gettime timer_settime)
837 FP_CHECK_TIMER_CREATE
838
839 dnl ** check for Apple's "interesting" long double compatibility scheme
840 AC_MSG_CHECKING(for printf\$LDBLStub)
841 AC_TRY_LINK_FUNC(printf\$LDBLStub,
842     [
843         AC_MSG_RESULT(yes)
844         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
845             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
846     ],
847     [
848         AC_MSG_RESULT(no)
849         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
850             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
851     ])
852
853 dnl ** check for eventfd which is needed by the I/O manager
854 AC_CHECK_HEADERS([sys/eventfd.h])
855 AC_CHECK_FUNCS([eventfd])
856
857 # checking for PAPI
858 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
859 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
860 AC_SUBST(HavePapiLib)
861 AC_SUBST(HavePapiHeader)
862
863 AC_CHECK_FUNCS(__mingw_vfprintf)
864
865 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
866    HavePapi=YES
867 else
868    HavePapi=NO
869 fi
870 AC_SUBST(HavePapi)
871
872 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
873    test "$XsltprocCmd" = ""
874 then
875     BUILD_DOCBOOK_HTML=NO
876 else
877     BUILD_DOCBOOK_HTML=YES
878 fi
879 AC_SUBST(BUILD_DOCBOOK_HTML)
880
881 if test "$DblatexCmd" = ""
882 then
883     BUILD_DOCBOOK_PS=NO
884     BUILD_DOCBOOK_PDF=NO
885 else
886     BUILD_DOCBOOK_PS=YES
887     BUILD_DOCBOOK_PDF=YES
888 fi
889 AC_SUBST(BUILD_DOCBOOK_PS)
890 AC_SUBST(BUILD_DOCBOOK_PDF)
891
892 LIBRARY_VERSION(base)
893 LIBRARY_VERSION(Cabal, Cabal/Cabal)
894 LIBRARY_VERSION(ghc-prim)
895 LIBRARY_ghc_VERSION="$ProjectVersion"
896 AC_SUBST(LIBRARY_ghc_VERSION)
897
898 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
899    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
900 fi
901
902 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal ghc.spec settings docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/ghc.iss distrib/configure.ac])
903 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
904 AC_OUTPUT
905
906 # We got caught by
907 #     http://savannah.gnu.org/bugs/index.php?1516
908 #     $(eval ...) inside conditionals causes errors
909 # with make 3.80, so warn the user if it looks like they're about to
910 # try to use it.
911 # We would use "grep -q" here, but Solaris's grep doesn't support it.
912 checkMake380() {
913     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
914     then
915         echo
916         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
917         echo "This version cannot be used to build GHC."
918         echo "Please use GNU make >= 3.81."
919     fi
920 }
921
922 checkMake380 make
923 checkMake380 gmake
924
925 echo ["
926 ----------------------------------------------------------------------
927 Configure completed successfully.
928
929    Building GHC version  : $ProjectVersion
930
931    Build platform        : $BuildPlatform
932    Host platform         : $HostPlatform
933    Target platform       : $TargetPlatform
934 "]
935
936 echo ["\
937    Bootstrapping using   : $WithGhc
938       which is version   : $GhcVersion
939 "]
940
941 if test "x$CC_LLVM_BACKEND" = "x1"; then
942     if test "x$CC_CLANG_BACKEND" = "x1"; then
943         CompilerName="clang        "
944     else
945         CompilerName="llvm-gcc     "
946     fi
947 else
948     CompilerName="gcc          "
949 fi
950
951 echo ["\
952    Using $CompilerName       : $WhatGccIsCalled
953       which is version       : $GccVersion
954    Building a cross compiler : $CrossCompiling
955
956    ld       : $LdCmd
957    Happy    : $HappyCmd ($HappyVersion)
958    Alex     : $AlexCmd ($AlexVersion)
959    Perl     : $PerlCmd
960    dblatex  : $DblatexCmd
961    xsltproc : $XsltprocCmd
962
963    Using LLVM tools
964       llc   : $LlcCmd
965       opt   : $OptCmd"]
966
967 if test "$HSCOLOUR" = ""; then
968 echo ["
969    HsColour was not found; documentation will not contain source links
970 "]
971 else
972 echo ["\
973    HsColour : $HSCOLOUR
974 "]
975 fi
976
977 echo ["\
978    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
979    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
980    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
981
982 echo ["----------------------------------------------------------------------
983 "]
984
985 echo "\
986 For a standard build of GHC (fully optimised with profiling), type (g)make.
987
988 To make changes to the default build configuration, copy the file
989 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
990
991 For more information on how to configure your GHC build, see
992    http://hackage.haskell.org/trac/ghc/wiki/Building
993 "