42988feeeb76f5cb92b541e9dac277e073bcb3ef
[ghc.git] / compiler / parser / Parser.y.pp
1 --                                                              -*-haskell-*-
2 -- ---------------------------------------------------------------------------
3 -- (c) The University of Glasgow 1997-2003
4 ---
5 -- The GHC grammar.
6 --
7 -- Author(s): Simon Marlow, Sven Panne 1997, 1998, 1999
8 -- ---------------------------------------------------------------------------
9
10 {
11 {-# LANGUAGE BangPatterns #-} -- required for versions of Happy before 1.18.6
12 {-# OPTIONS -Wwarn -w #-}
13 -- The above warning supression flag is a temporary kludge.
14 -- While working on this module you are encouraged to remove it and fix
15 -- any warnings in the module. See
16 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
17 -- for details
18
19 {-# OPTIONS_GHC -O0 -fno-ignore-interface-pragmas #-}
20 {-
21 Careful optimisation of the parser: we don't want to throw everything
22 at it, because that takes too long and doesn't buy much, but we do want
23 to inline certain key external functions, so we instruct GHC not to
24 throw away inlinings as it would normally do in -O0 mode.
25 -}
26
27 module Parser ( parseModule, parseStmt, parseIdentifier, parseType,
28                 parseHeader ) where
29
30 import HsSyn
31 import RdrHsSyn
32 import HscTypes         ( IsBootInterface, WarningTxt(..) )
33 import Lexer
34 import RdrName
35 import TysWiredIn       ( unitTyCon, unitDataCon, tupleTyCon, tupleCon, nilDataCon,
36                           unboxedSingletonTyCon, unboxedSingletonDataCon,
37                           listTyCon_RDR, parrTyCon_RDR, consDataCon_RDR )
38 import Type             ( funTyCon )
39 import ForeignCall      ( Safety(..), CExportSpec(..), CLabelString,
40                           CCallConv(..), CCallTarget(..), defaultCCallConv
41                         )
42 import OccName          ( varName, dataName, tcClsName, tvName )
43 import DataCon          ( DataCon, dataConName )
44 import SrcLoc
45 import Module
46 import StaticFlags      ( opt_SccProfilingOn, opt_Hpc )
47 import Type             ( Kind, liftedTypeKind, unliftedTypeKind )
48 import Coercion         ( mkArrowKind )
49 import Class            ( FunDep )
50 import BasicTypes
51 import DynFlags
52 import OrdList
53 import HaddockUtils
54
55 import FastString
56 import Maybes           ( orElse )
57 import Outputable
58
59 import Control.Monad    ( unless )
60 import GHC.Exts
61 import Data.Char
62 import Control.Monad    ( mplus )
63 }
64
65 {-
66 -----------------------------------------------------------------------------
67 24 Februar 2006
68
69 Conflicts: 33 shift/reduce
70            1 reduce/reduce
71
72 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
73 would think the two should never occur in the same context.
74
75   -=chak
76
77 -----------------------------------------------------------------------------
78 31 December 2006
79
80 Conflicts: 34 shift/reduce
81            1 reduce/reduce
82
83 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
84 would think the two should never occur in the same context.
85
86   -=chak
87
88 -----------------------------------------------------------------------------
89 6 December 2006
90
91 Conflicts: 32 shift/reduce
92            1 reduce/reduce
93
94 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
95 would think the two should never occur in the same context.
96
97   -=chak
98
99 -----------------------------------------------------------------------------
100 26 July 2006
101
102 Conflicts: 37 shift/reduce
103            1 reduce/reduce
104
105 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
106 would think the two should never occur in the same context.
107
108   -=chak
109
110 -----------------------------------------------------------------------------
111 Conflicts: 38 shift/reduce (1.25)
112
113 10 for abiguity in 'if x then y else z + 1'             [State 178]
114         (shift parses as 'if x then y else (z + 1)', as per longest-parse rule)
115         10 because op might be: : - ! * . `x` VARSYM CONSYM QVARSYM QCONSYM
116
117 1 for ambiguity in 'if x then y else z :: T'            [State 178]
118         (shift parses as 'if x then y else (z :: T)', as per longest-parse rule)
119
120 4 for ambiguity in 'if x then y else z -< e'            [State 178]
121         (shift parses as 'if x then y else (z -< T)', as per longest-parse rule)
122         There are four such operators: -<, >-, -<<, >>-
123
124
125 2 for ambiguity in 'case v of { x :: T -> T ... } '     [States 11, 253]
126         Which of these two is intended?
127           case v of
128             (x::T) -> T         -- Rhs is T
129     or
130           case v of
131             (x::T -> T) -> ..   -- Rhs is ...
132
133 10 for ambiguity in 'e :: a `b` c'.  Does this mean     [States 11, 253]
134         (e::a) `b` c, or 
135         (e :: (a `b` c))
136     As well as `b` we can have !, VARSYM, QCONSYM, and CONSYM, hence 5 cases
137     Same duplication between states 11 and 253 as the previous case
138
139 1 for ambiguity in 'let ?x ...'                         [State 329]
140         the parser can't tell whether the ?x is the lhs of a normal binding or
141         an implicit binding.  Fortunately resolving as shift gives it the only
142         sensible meaning, namely the lhs of an implicit binding.
143
144 1 for ambiguity in '{-# RULES "name" [ ... #-}          [State 382]
145         we don't know whether the '[' starts the activation or not: it
146         might be the start of the declaration with the activation being
147         empty.  --SDM 1/4/2002
148
149 1 for ambiguity in '{-# RULES "name" forall = ... #-}'  [State 474]
150         since 'forall' is a valid variable name, we don't know whether
151         to treat a forall on the input as the beginning of a quantifier
152         or the beginning of the rule itself.  Resolving to shift means
153         it's always treated as a quantifier, hence the above is disallowed.
154         This saves explicitly defining a grammar for the rule lhs that
155         doesn't include 'forall'.
156
157 1 for ambiguity when the source file starts with "-- | doc". We need another
158   token of lookahead to determine if a top declaration or the 'module' keyword
159   follows. Shift parses as if the 'module' keyword follows.   
160
161 -- ---------------------------------------------------------------------------
162 -- Adding location info
163
164 This is done in a stylised way using the three macros below, L0, L1
165 and LL.  Each of these macros can be thought of as having type
166
167    L0, L1, LL :: a -> Located a
168
169 They each add a SrcSpan to their argument.
170
171    L0   adds 'noSrcSpan', used for empty productions
172      -- This doesn't seem to work anymore -=chak
173
174    L1   for a production with a single token on the lhs.  Grabs the SrcSpan
175         from that token.
176
177    LL   for a production with >1 token on the lhs.  Makes up a SrcSpan from
178         the first and last tokens.
179
180 These suffice for the majority of cases.  However, we must be
181 especially careful with empty productions: LL won't work if the first
182 or last token on the lhs can represent an empty span.  In these cases,
183 we have to calculate the span using more of the tokens from the lhs, eg.
184
185         | 'newtype' tycl_hdr '=' newconstr deriving
186                 { L (comb3 $1 $4 $5)
187                     (mkTyData NewType (unLoc $2) [$4] (unLoc $5)) }
188
189 We provide comb3 and comb4 functions which are useful in such cases.
190
191 Be careful: there's no checking that you actually got this right, the
192 only symptom will be that the SrcSpans of your syntax will be
193 incorrect.
194
195 /*
196  * We must expand these macros *before* running Happy, which is why this file is
197  * Parser.y.pp rather than just Parser.y - we run the C pre-processor first.
198  */
199 #define L0   L noSrcSpan
200 #define L1   sL (getLoc $1)
201 #define LL   sL (comb2 $1 $>)
202
203 -- -----------------------------------------------------------------------------
204
205 -}
206
207 %token
208  '_'            { L _ ITunderscore }            -- Haskell keywords
209  'as'           { L _ ITas }
210  'case'         { L _ ITcase }          
211  'class'        { L _ ITclass } 
212  'data'         { L _ ITdata } 
213  'default'      { L _ ITdefault }
214  'deriving'     { L _ ITderiving }
215  'do'           { L _ ITdo }
216  'else'         { L _ ITelse }
217  'hiding'       { L _ IThiding }
218  'if'           { L _ ITif }
219  'import'       { L _ ITimport }
220  'in'           { L _ ITin }
221  'infix'        { L _ ITinfix }
222  'infixl'       { L _ ITinfixl }
223  'infixr'       { L _ ITinfixr }
224  'instance'     { L _ ITinstance }
225  'let'          { L _ ITlet }
226  'module'       { L _ ITmodule }
227  'newtype'      { L _ ITnewtype }
228  'of'           { L _ ITof }
229  'qualified'    { L _ ITqualified }
230  'then'         { L _ ITthen }
231  'type'         { L _ ITtype }
232  'where'        { L _ ITwhere }
233  '_scc_'        { L _ ITscc }         -- ToDo: remove
234
235  'forall'       { L _ ITforall }                -- GHC extension keywords
236  'foreign'      { L _ ITforeign }
237  'export'       { L _ ITexport }
238  'label'        { L _ ITlabel } 
239  'dynamic'      { L _ ITdynamic }
240  'safe'         { L _ ITsafe }
241  'interruptible' { L _ ITinterruptible }
242  'unsafe'       { L _ ITunsafe }
243  'mdo'          { L _ ITmdo }
244  'family'       { L _ ITfamily }
245  'stdcall'      { L _ ITstdcallconv }
246  'ccall'        { L _ ITccallconv }
247  'prim'         { L _ ITprimcallconv }
248  'proc'         { L _ ITproc }          -- for arrow notation extension
249  'rec'          { L _ ITrec }           -- for arrow notation extension
250  'group'    { L _ ITgroup }     -- for list transform extension
251  'by'       { L _ ITby }        -- for list transform extension
252  'using'    { L _ ITusing }     -- for list transform extension
253
254  '{-# INLINE'             { L _ (ITinline_prag _ _) }
255  '{-# SPECIALISE'         { L _ ITspec_prag }
256  '{-# SPECIALISE_INLINE'  { L _ (ITspec_inline_prag _) }
257  '{-# SOURCE'                                   { L _ ITsource_prag }
258  '{-# RULES'                                    { L _ ITrules_prag }
259  '{-# CORE'                                     { L _ ITcore_prag }              -- hdaume: annotated core
260  '{-# SCC'                { L _ ITscc_prag }
261  '{-# GENERATED'          { L _ ITgenerated_prag }
262  '{-# DEPRECATED'         { L _ ITdeprecated_prag }
263  '{-# WARNING'            { L _ ITwarning_prag }
264  '{-# UNPACK'             { L _ ITunpack_prag }
265  '{-# ANN'                { L _ ITann_prag }
266  '{-# VECTORISE'          { L _ ITvect_prag }
267  '{-# VECTORISE_SCALAR'   { L _ ITvect_scalar_prag }
268  '{-# NOVECTORISE'        { L _ ITnovect_prag }
269  '#-}'                                          { L _ ITclose_prag }
270
271  '..'           { L _ ITdotdot }                        -- reserved symbols
272  ':'            { L _ ITcolon }
273  '::'           { L _ ITdcolon }
274  '='            { L _ ITequal }
275  '\\'           { L _ ITlam }
276  '|'            { L _ ITvbar }
277  '<-'           { L _ ITlarrow }
278  '->'           { L _ ITrarrow }
279  '@'            { L _ ITat }
280  '~'            { L _ ITtilde }
281  '=>'           { L _ ITdarrow }
282  '-'            { L _ ITminus }
283  '!'            { L _ ITbang }
284  '*'            { L _ ITstar }
285  '-<'           { L _ ITlarrowtail }            -- for arrow notation
286  '>-'           { L _ ITrarrowtail }            -- for arrow notation
287  '-<<'          { L _ ITLarrowtail }            -- for arrow notation
288  '>>-'          { L _ ITRarrowtail }            -- for arrow notation
289  '.'            { L _ ITdot }
290
291  '{'            { L _ ITocurly }                        -- special symbols
292  '}'            { L _ ITccurly }
293  '{|'           { L _ ITocurlybar }
294  '|}'           { L _ ITccurlybar }
295  vocurly        { L _ ITvocurly } -- virtual open curly (from layout)
296  vccurly        { L _ ITvccurly } -- virtual close curly (from layout)
297  '['            { L _ ITobrack }
298  ']'            { L _ ITcbrack }
299  '[:'           { L _ ITopabrack }
300  ':]'           { L _ ITcpabrack }
301  '('            { L _ IToparen }
302  ')'            { L _ ITcparen }
303  '(#'           { L _ IToubxparen }
304  '#)'           { L _ ITcubxparen }
305  '(|'           { L _ IToparenbar }
306  '|)'           { L _ ITcparenbar }
307  ';'            { L _ ITsemi }
308  ','            { L _ ITcomma }
309  '`'            { L _ ITbackquote }
310
311  VARID          { L _ (ITvarid    _) }          -- identifiers
312  CONID          { L _ (ITconid    _) }
313  VARSYM         { L _ (ITvarsym   _) }
314  CONSYM         { L _ (ITconsym   _) }
315  QVARID         { L _ (ITqvarid   _) }
316  QCONID         { L _ (ITqconid   _) }
317  QVARSYM        { L _ (ITqvarsym  _) }
318  QCONSYM        { L _ (ITqconsym  _) }
319  PREFIXQVARSYM  { L _ (ITprefixqvarsym  _) }
320  PREFIXQCONSYM  { L _ (ITprefixqconsym  _) }
321
322  IPDUPVARID     { L _ (ITdupipvarid   _) }              -- GHC extension
323
324  CHAR           { L _ (ITchar     _) }
325  STRING         { L _ (ITstring   _) }
326  INTEGER        { L _ (ITinteger  _) }
327  RATIONAL       { L _ (ITrational _) }
328                     
329  PRIMCHAR       { L _ (ITprimchar   _) }
330  PRIMSTRING     { L _ (ITprimstring _) }
331  PRIMINTEGER    { L _ (ITprimint    _) }
332  PRIMWORD       { L _ (ITprimword  _) }
333  PRIMFLOAT      { L _ (ITprimfloat  _) }
334  PRIMDOUBLE     { L _ (ITprimdouble _) }
335
336  DOCNEXT        { L _ (ITdocCommentNext _) }
337  DOCPREV        { L _ (ITdocCommentPrev _) }
338  DOCNAMED       { L _ (ITdocCommentNamed _) }
339  DOCSECTION     { L _ (ITdocSection _ _) }
340
341 -- Template Haskell 
342 '[|'            { L _ ITopenExpQuote  }       
343 '[p|'           { L _ ITopenPatQuote  }      
344 '[t|'           { L _ ITopenTypQuote  }      
345 '[d|'           { L _ ITopenDecQuote  }      
346 '|]'            { L _ ITcloseQuote    }
347 TH_ID_SPLICE    { L _ (ITidEscape _)  }     -- $x
348 '$('            { L _ ITparenEscape   }     -- $( exp )
349 TH_VAR_QUOTE    { L _ ITvarQuote      }     -- 'x
350 TH_TY_QUOTE     { L _ ITtyQuote       }      -- ''T
351 TH_QUASIQUOTE   { L _ (ITquasiQuote _) }
352
353 %monad { P } { >>= } { return }
354 %lexer { lexer } { L _ ITeof }
355 %name parseModule module
356 %name parseStmt   maybe_stmt
357 %name parseIdentifier  identifier
358 %name parseType ctype
359 %partial parseHeader header
360 %tokentype { (Located Token) }
361 %%
362
363 -----------------------------------------------------------------------------
364 -- Identifiers; one of the entry points
365 identifier :: { Located RdrName }
366         : qvar                          { $1 }
367         | qcon                          { $1 }
368         | qvarop                        { $1 }
369         | qconop                        { $1 }
370     | '(' '->' ')'      { LL $ getRdrName funTyCon }
371
372 -----------------------------------------------------------------------------
373 -- Module Header
374
375 -- The place for module deprecation is really too restrictive, but if it
376 -- was allowed at its natural place just before 'module', we get an ugly
377 -- s/r conflict with the second alternative. Another solution would be the
378 -- introduction of a new pragma DEPRECATED_MODULE, but this is not very nice,
379 -- either, and DEPRECATED is only expected to be used by people who really
380 -- know what they are doing. :-)
381
382 module  :: { Located (HsModule RdrName) }
383         : maybedocheader 'module' modid maybemodwarning maybeexports 'where' body
384                 {% fileSrcSpan >>= \ loc ->
385                    return (L loc (HsModule (Just $3) $5 (fst $7) (snd $7) $4 $1
386                           ) )}
387         | body2
388                 {% fileSrcSpan >>= \ loc ->
389                    return (L loc (HsModule Nothing Nothing
390                           (fst $1) (snd $1) Nothing Nothing
391                           )) }
392
393 maybedocheader :: { Maybe LHsDocString }
394         : moduleheader            { $1 }
395         | {- empty -}             { Nothing }
396
397 missing_module_keyword :: { () }
398         : {- empty -}                           {% pushCurrentContext }
399
400 maybemodwarning :: { Maybe WarningTxt }
401     : '{-# DEPRECATED' strings '#-}' { Just (DeprecatedTxt $ unLoc $2) }
402     | '{-# WARNING' strings '#-}'    { Just (WarningTxt $ unLoc $2) }
403     |  {- empty -}                  { Nothing }
404
405 body    :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
406         :  '{'            top '}'               { $2 }
407         |      vocurly    top close             { $2 }
408
409 body2   :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
410         :  '{' top '}'                          { $2 }
411         |  missing_module_keyword top close     { $2 }
412
413 top     :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
414         : importdecls                           { (reverse $1,[]) }
415         | importdecls ';' cvtopdecls            { (reverse $1,$3) }
416         | cvtopdecls                            { ([],$1) }
417
418 cvtopdecls :: { [LHsDecl RdrName] }
419         : topdecls                              { cvTopDecls $1 }
420
421 -----------------------------------------------------------------------------
422 -- Module declaration & imports only
423
424 header  :: { Located (HsModule RdrName) }
425         : maybedocheader 'module' modid maybemodwarning maybeexports 'where' header_body
426                 {% fileSrcSpan >>= \ loc ->
427                    return (L loc (HsModule (Just $3) $5 $7 [] $4 $1
428                           ))}
429         | header_body2
430                 {% fileSrcSpan >>= \ loc ->
431                    return (L loc (HsModule Nothing Nothing $1 [] Nothing
432                           Nothing)) }
433
434 header_body :: { [LImportDecl RdrName] }
435         :  '{'            importdecls           { $2 }
436         |      vocurly    importdecls           { $2 }
437
438 header_body2 :: { [LImportDecl RdrName] }
439         :  '{' importdecls                      { $2 }
440         |  missing_module_keyword importdecls   { $2 }
441
442 -----------------------------------------------------------------------------
443 -- The Export List
444
445 maybeexports :: { Maybe [LIE RdrName] }
446         :  '(' exportlist ')'                   { Just $2 }
447         |  {- empty -}                          { Nothing }
448
449 exportlist :: { [LIE RdrName] }
450         : expdoclist ',' expdoclist             { $1 ++ $3 }
451         | exportlist1                           { $1 }
452
453 exportlist1 :: { [LIE RdrName] }
454         : expdoclist export expdoclist ',' exportlist  { $1 ++ ($2 : $3) ++ $5 }
455         | expdoclist export expdoclist                 { $1 ++ ($2 : $3) }
456         | expdoclist                                   { $1 }
457
458 expdoclist :: { [LIE RdrName] }
459         : exp_doc expdoclist                           { $1 : $2 }
460         | {- empty -}                                  { [] }
461
462 exp_doc :: { LIE RdrName }                                                   
463         : docsection    { L1 (case (unLoc $1) of (n, doc) -> IEGroup n doc) }
464         | docnamed      { L1 (IEDocNamed ((fst . unLoc) $1)) } 
465         | docnext       { L1 (IEDoc (unLoc $1)) }       
466                        
467    -- No longer allow things like [] and (,,,) to be exported
468    -- They are built in syntax, always available
469 export  :: { LIE RdrName }
470         :  qvar                         { L1 (IEVar (unLoc $1)) }
471         |  oqtycon                      { L1 (IEThingAbs (unLoc $1)) }
472         |  oqtycon '(' '..' ')'         { LL (IEThingAll (unLoc $1)) }
473         |  oqtycon '(' ')'              { LL (IEThingWith (unLoc $1) []) }
474         |  oqtycon '(' qcnames ')'      { LL (IEThingWith (unLoc $1) (reverse $3)) }
475         |  'module' modid               { LL (IEModuleContents (unLoc $2)) }
476
477 qcnames :: { [RdrName] }
478         :  qcnames ',' qcname_ext       { unLoc $3 : $1 }
479         |  qcname_ext                   { [unLoc $1]  }
480
481 qcname_ext :: { Located RdrName }       -- Variable or data constructor
482                                         -- or tagged type constructor
483         :  qcname                       { $1 }
484         |  'type' qcon                  { sL (comb2 $1 $2) 
485                                              (setRdrNameSpace (unLoc $2) 
486                                                               tcClsName)  }
487
488 -- Cannot pull into qcname_ext, as qcname is also used in expression.
489 qcname  :: { Located RdrName }  -- Variable or data constructor
490         :  qvar                         { $1 }
491         |  qcon                         { $1 }
492
493 -----------------------------------------------------------------------------
494 -- Import Declarations
495
496 -- import decls can be *empty*, or even just a string of semicolons
497 -- whereas topdecls must contain at least one topdecl.
498
499 importdecls :: { [LImportDecl RdrName] }
500         : importdecls ';' importdecl            { $3 : $1 }
501         | importdecls ';'                       { $1 }
502         | importdecl                            { [ $1 ] }
503         | {- empty -}                           { [] }
504
505 importdecl :: { LImportDecl RdrName }
506         : 'import' maybe_src maybe_safe optqualified maybe_pkg modid maybeas maybeimpspec 
507                 { L (comb4 $1 $6 $7 $8) $
508                   ImportDecl { ideclName = $6, ideclPkgQual = $5
509                              , ideclSource = $2, ideclSafe = $3
510                              , ideclQualified = $4, ideclImplicit = False
511                              , ideclAs = unLoc $7, ideclHiding = unLoc $8 } }
512
513 maybe_src :: { IsBootInterface }
514         : '{-# SOURCE' '#-}'                    { True }
515         | {- empty -}                           { False }
516
517 maybe_safe :: { Bool }
518         : 'safe'                                { True }
519         | {- empty -}                           { False }
520
521 maybe_pkg :: { Maybe FastString }
522         : STRING                                { Just (getSTRING $1) }
523         | {- empty -}                           { Nothing }
524
525 optqualified :: { Bool }
526         : 'qualified'                           { True  }
527         | {- empty -}                           { False }
528
529 maybeas :: { Located (Maybe ModuleName) }
530         : 'as' modid                            { LL (Just (unLoc $2)) }
531         | {- empty -}                           { noLoc Nothing }
532
533 maybeimpspec :: { Located (Maybe (Bool, [LIE RdrName])) }
534         : impspec                               { L1 (Just (unLoc $1)) }
535         | {- empty -}                           { noLoc Nothing }
536
537 impspec :: { Located (Bool, [LIE RdrName]) }
538         :  '(' exportlist ')'                   { LL (False, $2) }
539         |  'hiding' '(' exportlist ')'          { LL (True,  $3) }
540
541 -----------------------------------------------------------------------------
542 -- Fixity Declarations
543
544 prec    :: { Int }
545         : {- empty -}           { 9 }
546         | INTEGER               {% checkPrecP (L1 (fromInteger (getINTEGER $1))) }
547
548 infix   :: { Located FixityDirection }
549         : 'infix'                               { L1 InfixN  }
550         | 'infixl'                              { L1 InfixL  }
551         | 'infixr'                              { L1 InfixR }
552
553 ops     :: { Located [Located RdrName] }
554         : ops ',' op                            { LL ($3 : unLoc $1) }
555         | op                                    { L1 [$1] }
556
557 -----------------------------------------------------------------------------
558 -- Top-Level Declarations
559
560 topdecls :: { OrdList (LHsDecl RdrName) }
561         : topdecls ';' topdecl                  { $1 `appOL` $3 }
562         | topdecls ';'                          { $1 }
563         | topdecl                               { $1 }
564
565 topdecl :: { OrdList (LHsDecl RdrName) }
566         : cl_decl                       { unitOL (L1 (TyClD (unLoc $1))) }
567         | ty_decl                       { unitOL (L1 (TyClD (unLoc $1))) }
568         | 'instance' inst_type where_inst
569             { let (binds, sigs, ats, _) = cvBindsAndSigs (unLoc $3)
570               in 
571               unitOL (L (comb3 $1 $2 $3) (InstD (InstDecl $2 binds sigs ats)))}
572         | stand_alone_deriving                  { unitOL (LL (DerivD (unLoc $1))) }
573         | 'default' '(' comma_types0 ')'        { unitOL (LL $ DefD (DefaultDecl $3)) }
574         | 'foreign' fdecl                       { unitOL (LL (unLoc $2)) }
575         | '{-# DEPRECATED' deprecations '#-}'   { $2 }
576         | '{-# WARNING' warnings '#-}'          { $2 }
577         | '{-# RULES' rules '#-}'               { $2 }
578         | '{-# VECTORISE_SCALAR' qvar '#-}'     { unitOL $ LL $ VectD (HsVect   $2 Nothing) }
579         | '{-# VECTORISE' qvar '=' exp '#-}'    { unitOL $ LL $ VectD (HsVect   $2 (Just $4)) }
580         | '{-# NOVECTORISE' qvar '#-}'                          { unitOL $ LL $ VectD (HsNoVect $2) }
581         | annotation { unitOL $1 }
582         | decl                                  { unLoc $1 }
583
584         -- Template Haskell Extension
585         -- The $(..) form is one possible form of infixexp
586         -- but we treat an arbitrary expression just as if 
587         -- it had a $(..) wrapped around it
588         | infixexp                              { unitOL (LL $ mkTopSpliceDecl $1) } 
589
590 -- Type classes
591 --
592 cl_decl :: { LTyClDecl RdrName }
593         : 'class' tycl_hdr fds where_cls        {% mkClassDecl (comb4 $1 $2 $3 $4) $2 $3 $4 }
594
595 -- Type declarations (toplevel)
596 --
597 ty_decl :: { LTyClDecl RdrName }
598            -- ordinary type synonyms
599         : 'type' type '=' ctypedoc
600                 -- Note ctype, not sigtype, on the right of '='
601                 -- We allow an explicit for-all but we don't insert one
602                 -- in   type Foo a = (b,b)
603                 -- Instead we just say b is out of scope
604                 --
605                 -- Note the use of type for the head; this allows
606                 -- infix type constructors to be declared 
607                 {% mkTySynonym (comb2 $1 $4) False $2 $4 }
608
609            -- type family declarations
610         | 'type' 'family' type opt_kind_sig 
611                 -- Note the use of type for the head; this allows
612                 -- infix type constructors to be declared
613                 {% mkTyFamily (comb3 $1 $3 $4) TypeFamily $3 (unLoc $4) }
614
615            -- type instance declarations
616         | 'type' 'instance' type '=' ctype
617                 -- Note the use of type for the head; this allows
618                 -- infix type constructors and type patterns
619                 {% mkTySynonym (comb2 $1 $5) True $3 $5 }
620
621           -- ordinary data type or newtype declaration
622         | data_or_newtype tycl_hdr constrs deriving
623                 {% mkTyData (comb4 $1 $2 $3 $4) (unLoc $1) False $2 
624                             Nothing (reverse (unLoc $3)) (unLoc $4) }
625                                    -- We need the location on tycl_hdr in case 
626                                    -- constrs and deriving are both empty
627
628           -- ordinary GADT declaration
629         | data_or_newtype tycl_hdr opt_kind_sig 
630                  gadt_constrlist
631                  deriving
632                 {% mkTyData (comb4 $1 $2 $4 $5) (unLoc $1) False $2 
633                             (unLoc $3) (unLoc $4) (unLoc $5) }
634                                    -- We need the location on tycl_hdr in case 
635                                    -- constrs and deriving are both empty
636
637           -- data/newtype family
638         | 'data' 'family' type opt_kind_sig
639                 {% mkTyFamily (comb3 $1 $2 $4) DataFamily $3 (unLoc $4) }
640
641           -- data/newtype instance declaration
642         | data_or_newtype 'instance' tycl_hdr constrs deriving
643                 {% mkTyData (comb4 $1 $3 $4 $5) (unLoc $1) True $3
644                             Nothing (reverse (unLoc $4)) (unLoc $5) }
645
646           -- GADT instance declaration
647         | data_or_newtype 'instance' tycl_hdr opt_kind_sig 
648                  gadt_constrlist
649                  deriving
650                 {% mkTyData (comb4 $1 $3 $5 $6) (unLoc $1) True $3
651                             (unLoc $4) (unLoc $5) (unLoc $6) }
652
653 -- Associated type family declarations
654 --
655 -- * They have a different syntax than on the toplevel (no family special
656 --   identifier).
657 --
658 -- * They also need to be separate from instances; otherwise, data family
659 --   declarations without a kind signature cause parsing conflicts with empty
660 --   data declarations. 
661 --
662 at_decl_cls :: { LTyClDecl RdrName }
663            -- type family declarations
664         : 'type' type opt_kind_sig
665                 -- Note the use of type for the head; this allows
666                 -- infix type constructors to be declared
667                 {% mkTyFamily (comb3 $1 $2 $3) TypeFamily $2 (unLoc $3) }
668
669            -- default type instance
670         | 'type' type '=' ctype
671                 -- Note the use of type for the head; this allows
672                 -- infix type constructors and type patterns
673                 {% mkTySynonym (comb2 $1 $4) True $2 $4 }
674
675           -- data/newtype family declaration
676         | 'data' type opt_kind_sig
677                 {% mkTyFamily (comb3 $1 $2 $3) DataFamily $2 (unLoc $3) }
678
679 -- Associated type instances
680 --
681 at_decl_inst :: { LTyClDecl RdrName }
682            -- type instance declarations
683         : 'type' type '=' ctype
684                 -- Note the use of type for the head; this allows
685                 -- infix type constructors and type patterns
686                 {% mkTySynonym (comb2 $1 $4) True $2 $4 }
687
688         -- data/newtype instance declaration
689         | data_or_newtype tycl_hdr constrs deriving
690                 {% mkTyData (comb4 $1 $2 $3 $4) (unLoc $1) True $2 
691                             Nothing (reverse (unLoc $3)) (unLoc $4) }
692
693         -- GADT instance declaration
694         | data_or_newtype tycl_hdr opt_kind_sig 
695                  gadt_constrlist
696                  deriving
697                 {% mkTyData (comb4 $1 $2 $4 $5) (unLoc $1) True $2 
698                             (unLoc $3) (unLoc $4) (unLoc $5) }
699
700 data_or_newtype :: { Located NewOrData }
701         : 'data'        { L1 DataType }
702         | 'newtype'     { L1 NewType }
703
704 opt_kind_sig :: { Located (Maybe Kind) }
705         :                               { noLoc Nothing }
706         | '::' kind                     { LL (Just (unLoc $2)) }
707
708 -- tycl_hdr parses the header of a class or data type decl,
709 -- which takes the form
710 --      T a b
711 --      Eq a => T a
712 --      (Eq a, Ord b) => T a b
713 --      T Int [a]                       -- for associated types
714 -- Rather a lot of inlining here, else we get reduce/reduce errors
715 tycl_hdr :: { Located (Maybe (LHsContext RdrName), LHsType RdrName) }
716         : context '=>' type             { LL (Just $1, $3) }
717         | type                          { L1 (Nothing, $1) }
718
719 -----------------------------------------------------------------------------
720 -- Stand-alone deriving
721
722 -- Glasgow extension: stand-alone deriving declarations
723 stand_alone_deriving :: { LDerivDecl RdrName }
724         : 'deriving' 'instance' inst_type { LL (DerivDecl $3) }
725
726 -----------------------------------------------------------------------------
727 -- Nested declarations
728
729 -- Declaration in class bodies
730 --
731 decl_cls  :: { Located (OrdList (LHsDecl RdrName)) }
732 decl_cls  : at_decl_cls                 { LL (unitOL (L1 (TyClD (unLoc $1)))) }
733           | decl                        { $1 }
734
735           -- A 'default' signature used with the generic-programming extension
736           | 'default' infixexp '::' sigtypedoc
737                     {% do { (TypeSig l ty) <- checkValSig $2 $4
738                           ; return (LL $ unitOL (LL $ SigD (GenericSig l ty))) } }
739
740 decls_cls :: { Located (OrdList (LHsDecl RdrName)) }    -- Reversed
741           : decls_cls ';' decl_cls      { LL (unLoc $1 `appOL` unLoc $3) }
742           | decls_cls ';'               { LL (unLoc $1) }
743           | decl_cls                    { $1 }
744           | {- empty -}                 { noLoc nilOL }
745
746
747 decllist_cls
748         :: { Located (OrdList (LHsDecl RdrName)) }      -- Reversed
749         : '{'         decls_cls '}'     { LL (unLoc $2) }
750         |     vocurly decls_cls close   { $2 }
751
752 -- Class body
753 --
754 where_cls :: { Located (OrdList (LHsDecl RdrName)) }    -- Reversed
755                                 -- No implicit parameters
756                                 -- May have type declarations
757         : 'where' decllist_cls          { LL (unLoc $2) }
758         | {- empty -}                   { noLoc nilOL }
759
760 -- Declarations in instance bodies
761 --
762 decl_inst  :: { Located (OrdList (LHsDecl RdrName)) }
763 decl_inst  : at_decl_inst               { LL (unitOL (L1 (TyClD (unLoc $1)))) }
764            | decl                       { $1 }
765
766 decls_inst :: { Located (OrdList (LHsDecl RdrName)) }   -- Reversed
767            : decls_inst ';' decl_inst   { LL (unLoc $1 `appOL` unLoc $3) }
768            | decls_inst ';'             { LL (unLoc $1) }
769            | decl_inst                  { $1 }
770            | {- empty -}                { noLoc nilOL }
771
772 decllist_inst 
773         :: { Located (OrdList (LHsDecl RdrName)) }      -- Reversed
774         : '{'         decls_inst '}'    { LL (unLoc $2) }
775         |     vocurly decls_inst close  { $2 }
776
777 -- Instance body
778 --
779 where_inst :: { Located (OrdList (LHsDecl RdrName)) }   -- Reversed
780                                 -- No implicit parameters
781                                 -- May have type declarations
782         : 'where' decllist_inst         { LL (unLoc $2) }
783         | {- empty -}                   { noLoc nilOL }
784
785 -- Declarations in binding groups other than classes and instances
786 --
787 decls   :: { Located (OrdList (LHsDecl RdrName)) }      
788         : decls ';' decl                { let { this = unLoc $3;
789                                     rest = unLoc $1;
790                                     these = rest `appOL` this }
791                               in rest `seq` this `seq` these `seq`
792                                     LL these }
793         | decls ';'                     { LL (unLoc $1) }
794         | decl                          { $1 }
795         | {- empty -}                   { noLoc nilOL }
796
797 decllist :: { Located (OrdList (LHsDecl RdrName)) }
798         : '{'            decls '}'      { LL (unLoc $2) }
799         |     vocurly    decls close    { $2 }
800
801 -- Binding groups other than those of class and instance declarations
802 --
803 binds   ::  { Located (HsLocalBinds RdrName) }          -- May have implicit parameters
804                                                 -- No type declarations
805         : decllist                      { L1 (HsValBinds (cvBindGroup (unLoc $1))) }
806         | '{'            dbinds '}'     { LL (HsIPBinds (IPBinds (unLoc $2) emptyTcEvBinds)) }
807         |     vocurly    dbinds close   { L (getLoc $2) (HsIPBinds (IPBinds (unLoc $2) emptyTcEvBinds)) }
808
809 wherebinds :: { Located (HsLocalBinds RdrName) }        -- May have implicit parameters
810                                                 -- No type declarations
811         : 'where' binds                 { LL (unLoc $2) }
812         | {- empty -}                   { noLoc emptyLocalBinds }
813
814
815 -----------------------------------------------------------------------------
816 -- Transformation Rules
817
818 rules   :: { OrdList (LHsDecl RdrName) }
819         :  rules ';' rule                       { $1 `snocOL` $3 }
820         |  rules ';'                            { $1 }
821         |  rule                                 { unitOL $1 }
822         |  {- empty -}                          { nilOL }
823
824 rule    :: { LHsDecl RdrName }
825         : STRING activation rule_forall infixexp '=' exp
826              { LL $ RuleD (HsRule (getSTRING $1) 
827                                   ($2 `orElse` AlwaysActive) 
828                                   $3 $4 placeHolderNames $6 placeHolderNames) }
829
830 activation :: { Maybe Activation } 
831         : {- empty -}                           { Nothing }
832         | explicit_activation                   { Just $1 }
833
834 explicit_activation :: { Activation }  -- In brackets
835         : '[' INTEGER ']'               { ActiveAfter  (fromInteger (getINTEGER $2)) }
836         | '[' '~' INTEGER ']'           { ActiveBefore (fromInteger (getINTEGER $3)) }
837
838 rule_forall :: { [RuleBndr RdrName] }
839         : 'forall' rule_var_list '.'            { $2 }
840         | {- empty -}                           { [] }
841
842 rule_var_list :: { [RuleBndr RdrName] }
843         : rule_var                              { [$1] }
844         | rule_var rule_var_list                { $1 : $2 }
845
846 rule_var :: { RuleBndr RdrName }
847         : varid                                 { RuleBndr $1 }
848         | '(' varid '::' ctype ')'              { RuleBndrSig $2 $4 }
849
850 -----------------------------------------------------------------------------
851 -- Warnings and deprecations (c.f. rules)
852
853 warnings :: { OrdList (LHsDecl RdrName) }
854         : warnings ';' warning          { $1 `appOL` $3 }
855         | warnings ';'                  { $1 }
856         | warning                               { $1 }
857         | {- empty -}                           { nilOL }
858
859 -- SUP: TEMPORARY HACK, not checking for `module Foo'
860 warning :: { OrdList (LHsDecl RdrName) }
861         : namelist strings
862                 { toOL [ LL $ WarningD (Warning n (WarningTxt $ unLoc $2))
863                        | n <- unLoc $1 ] }
864
865 deprecations :: { OrdList (LHsDecl RdrName) }
866         : deprecations ';' deprecation          { $1 `appOL` $3 }
867         | deprecations ';'                      { $1 }
868         | deprecation                           { $1 }
869         | {- empty -}                           { nilOL }
870
871 -- SUP: TEMPORARY HACK, not checking for `module Foo'
872 deprecation :: { OrdList (LHsDecl RdrName) }
873         : namelist strings
874                 { toOL [ LL $ WarningD (Warning n (DeprecatedTxt $ unLoc $2))
875                        | n <- unLoc $1 ] }
876
877 strings :: { Located [FastString] }
878     : STRING { L1 [getSTRING $1] }
879     | '[' stringlist ']' { LL $ fromOL (unLoc $2) }
880
881 stringlist :: { Located (OrdList FastString) }
882     : stringlist ',' STRING { LL (unLoc $1 `snocOL` getSTRING $3) }
883     | STRING                { LL (unitOL (getSTRING $1)) }
884
885 -----------------------------------------------------------------------------
886 -- Annotations
887 annotation :: { LHsDecl RdrName }
888     : '{-# ANN' name_var aexp '#-}'      { LL (AnnD $ HsAnnotation (ValueAnnProvenance (unLoc $2)) $3) }
889     | '{-# ANN' 'type' tycon aexp '#-}'  { LL (AnnD $ HsAnnotation (TypeAnnProvenance (unLoc $3)) $4) }
890     | '{-# ANN' 'module' aexp '#-}'      { LL (AnnD $ HsAnnotation ModuleAnnProvenance $3) }
891
892
893 -----------------------------------------------------------------------------
894 -- Foreign import and export declarations
895
896 fdecl :: { LHsDecl RdrName }
897 fdecl : 'import' callconv safety fspec
898                 {% mkImport $2 $3 (unLoc $4) >>= return.LL }
899       | 'import' callconv        fspec          
900                 {% do { d <- mkImport $2 PlaySafe (unLoc $3);
901                         return (LL d) } }
902       | 'export' callconv fspec
903                 {% mkExport $2 (unLoc $3) >>= return.LL }
904
905 callconv :: { CCallConv }
906           : 'stdcall'                   { StdCallConv }
907           | 'ccall'                     { CCallConv   }
908           | 'prim'                      { PrimCallConv}
909
910 safety :: { Safety }
911         : 'unsafe'                      { PlayRisky }
912         | 'safe'                        { PlaySafe }
913         | 'interruptible'               { PlayInterruptible }
914
915 fspec :: { Located (Located FastString, Located RdrName, LHsType RdrName) }
916        : STRING var '::' sigtypedoc     { LL (L (getLoc $1) (getSTRING $1), $2, $4) }
917        |        var '::' sigtypedoc     { LL (noLoc nilFS, $1, $3) }
918          -- if the entity string is missing, it defaults to the empty string;
919          -- the meaning of an empty entity string depends on the calling
920          -- convention
921
922 -----------------------------------------------------------------------------
923 -- Type signatures
924
925 opt_sig :: { Maybe (LHsType RdrName) }
926         : {- empty -}                   { Nothing }
927         | '::' sigtype                  { Just $2 }
928
929 opt_asig :: { Maybe (LHsType RdrName) }
930         : {- empty -}                   { Nothing }
931         | '::' atype                    { Just $2 }
932
933 sigtype :: { LHsType RdrName }          -- Always a HsForAllTy,
934                                         -- to tell the renamer where to generalise
935         : ctype                         { L1 (mkImplicitHsForAllTy (noLoc []) $1) }
936         -- Wrap an Implicit forall if there isn't one there already
937
938 sigtypedoc :: { LHsType RdrName }       -- Always a HsForAllTy
939         : ctypedoc                      { L1 (mkImplicitHsForAllTy (noLoc []) $1) }
940         -- Wrap an Implicit forall if there isn't one there already
941
942 sig_vars :: { Located [Located RdrName] }
943          : sig_vars ',' var             { LL ($3 : unLoc $1) }
944          | var                          { L1 [$1] }
945
946 sigtypes1 :: { [LHsType RdrName] }      -- Always HsForAllTys
947         : sigtype                       { [ $1 ] }
948         | sigtype ',' sigtypes1         { $1 : $3 }
949
950 -----------------------------------------------------------------------------
951 -- Types
952
953 infixtype :: { LHsType RdrName }
954         : btype qtyconop type         { LL $ HsOpTy $1 $2 $3 }
955         | btype tyvarop  type    { LL $ HsOpTy $1 $2 $3 }
956
957 strict_mark :: { Located HsBang }
958         : '!'                           { L1 HsStrict }
959         | '{-# UNPACK' '#-}' '!'        { LL HsUnpack }
960
961 -- A ctype is a for-all type
962 ctype   :: { LHsType RdrName }
963         : 'forall' tv_bndrs '.' ctype   { LL $ mkExplicitHsForAllTy $2 (noLoc []) $4 }
964         | context '=>' ctype            { LL $ mkImplicitHsForAllTy   $1 $3 }
965         -- A type of form (context => type) is an *implicit* HsForAllTy
966         | ipvar '::' type               { LL (HsPredTy (HsIParam (unLoc $1) $3)) }
967         | type                          { $1 }
968
969 ----------------------
970 -- Notes for 'ctypedoc'
971 -- It would have been nice to simplify the grammar by unifying `ctype` and 
972 -- ctypedoc` into one production, allowing comments on types everywhere (and
973 -- rejecting them after parsing, where necessary).  This is however not possible
974 -- since it leads to ambiguity. The reason is the support for comments on record
975 -- fields: 
976 --         data R = R { field :: Int -- ^ comment on the field }
977 -- If we allow comments on types here, it's not clear if the comment applies
978 -- to 'field' or to 'Int'. So we must use `ctype` to describe the type.
979
980 ctypedoc :: { LHsType RdrName }
981         : 'forall' tv_bndrs '.' ctypedoc        { LL $ mkExplicitHsForAllTy $2 (noLoc []) $4 }
982         | context '=>' ctypedoc         { LL $ mkImplicitHsForAllTy   $1 $3 }
983         -- A type of form (context => type) is an *implicit* HsForAllTy
984         | ipvar '::' type               { LL (HsPredTy (HsIParam (unLoc $1) $3)) }
985         | typedoc                       { $1 }
986
987 ----------------------
988 -- Notes for 'context'
989 -- We parse a context as a btype so that we don't get reduce/reduce
990 -- errors in ctype.  The basic problem is that
991 --      (Eq a, Ord a)
992 -- looks so much like a tuple type.  We can't tell until we find the =>
993
994 -- We have the t1 ~ t2 form both in 'context' and in type, 
995 -- to permit an individual equational constraint without parenthesis.
996 -- Thus for some reason we allow    f :: a~b => blah
997 -- but not                          f :: ?x::Int => blah
998 context :: { LHsContext RdrName }
999         : btype '~'      btype          {% checkContext
1000                                              (LL $ HsPredTy (HsEqualP $1 $3)) }
1001         | btype                         {% checkContext $1 }
1002
1003 type :: { LHsType RdrName }
1004         : btype                         { $1 }
1005         | btype qtyconop type           { LL $ HsOpTy $1 $2 $3 }
1006         | btype tyvarop  type           { LL $ HsOpTy $1 $2 $3 }
1007         | btype '->'     ctype          { LL $ HsFunTy $1 $3 }
1008         | btype '~'      btype          { LL $ HsPredTy (HsEqualP $1 $3) }
1009
1010 typedoc :: { LHsType RdrName }
1011         : btype                          { $1 }
1012         | btype docprev                  { LL $ HsDocTy $1 $2 }
1013         | btype qtyconop type            { LL $ HsOpTy $1 $2 $3 }
1014         | btype qtyconop type docprev    { LL $ HsDocTy (L (comb3 $1 $2 $3) (HsOpTy $1 $2 $3)) $4 }
1015         | btype tyvarop  type            { LL $ HsOpTy $1 $2 $3 }
1016         | btype tyvarop  type docprev    { LL $ HsDocTy (L (comb3 $1 $2 $3) (HsOpTy $1 $2 $3)) $4 }
1017         | btype '->'     ctypedoc        { LL $ HsFunTy $1 $3 }
1018         | btype docprev '->' ctypedoc    { LL $ HsFunTy (L (comb2 $1 $2) (HsDocTy $1 $2)) $4 }
1019         | btype '~'      btype           { LL $ HsPredTy (HsEqualP $1 $3) }
1020
1021 btype :: { LHsType RdrName }
1022         : btype atype                   { LL $ HsAppTy $1 $2 }
1023         | atype                         { $1 }
1024
1025 atype :: { LHsType RdrName }
1026         : gtycon                        { L1 (HsTyVar (unLoc $1)) }
1027         | tyvar                         { L1 (HsTyVar (unLoc $1)) }
1028         | strict_mark atype             { LL (HsBangTy (unLoc $1) $2) }  -- Constructor sigs only
1029         | '{' fielddecls '}'            { LL $ HsRecTy $2 }              -- Constructor sigs only
1030         | '(' ctype ',' comma_types1 ')'  { LL $ HsTupleTy Boxed  ($2:$4) }
1031         | '(#' comma_types1 '#)'        { LL $ HsTupleTy Unboxed $2     }
1032         | '[' ctype ']'                 { LL $ HsListTy  $2 }
1033         | '[:' ctype ':]'               { LL $ HsPArrTy  $2 }
1034         | '(' ctype ')'                 { LL $ HsParTy   $2 }
1035         | '(' ctype '::' kind ')'       { LL $ HsKindSig $2 (unLoc $4) }
1036         | quasiquote                    { L1 (HsQuasiQuoteTy (unLoc $1)) }
1037         | '$(' exp ')'                  { LL $ mkHsSpliceTy $2 }
1038         | TH_ID_SPLICE                  { LL $ mkHsSpliceTy $ L1 $ HsVar $ 
1039                                           mkUnqual varName (getTH_ID_SPLICE $1) }
1040
1041 -- An inst_type is what occurs in the head of an instance decl
1042 --      e.g.  (Foo a, Gaz b) => Wibble a b
1043 -- It's kept as a single type, with a MonoDictTy at the right
1044 -- hand corner, for convenience.
1045 inst_type :: { LHsType RdrName }
1046         : sigtype                       {% checkInstType $1 }
1047
1048 inst_types1 :: { [LHsType RdrName] }
1049         : inst_type                     { [$1] }
1050         | inst_type ',' inst_types1     { $1 : $3 }
1051
1052 comma_types0  :: { [LHsType RdrName] }
1053         : comma_types1                  { $1 }
1054         | {- empty -}                   { [] }
1055
1056 comma_types1    :: { [LHsType RdrName] }
1057         : ctype                         { [$1] }
1058         | ctype  ',' comma_types1       { $1 : $3 }
1059
1060 tv_bndrs :: { [LHsTyVarBndr RdrName] }
1061          : tv_bndr tv_bndrs             { $1 : $2 }
1062          | {- empty -}                  { [] }
1063
1064 tv_bndr :: { LHsTyVarBndr RdrName }
1065         : tyvar                         { L1 (UserTyVar (unLoc $1) placeHolderKind) }
1066         | '(' tyvar '::' kind ')'       { LL (KindedTyVar (unLoc $2) 
1067                                                           (unLoc $4)) }
1068
1069 fds :: { Located [Located (FunDep RdrName)] }
1070         : {- empty -}                   { noLoc [] }
1071         | '|' fds1                      { LL (reverse (unLoc $2)) }
1072
1073 fds1 :: { Located [Located (FunDep RdrName)] }
1074         : fds1 ',' fd                   { LL ($3 : unLoc $1) }
1075         | fd                            { L1 [$1] }
1076
1077 fd :: { Located (FunDep RdrName) }
1078         : varids0 '->' varids0          { L (comb3 $1 $2 $3)
1079                                            (reverse (unLoc $1), reverse (unLoc $3)) }
1080
1081 varids0 :: { Located [RdrName] }
1082         : {- empty -}                   { noLoc [] }
1083         | varids0 tyvar                 { LL (unLoc $2 : unLoc $1) }
1084
1085 -----------------------------------------------------------------------------
1086 -- Kinds
1087
1088 kind    :: { Located Kind }
1089         : akind                 { $1 }
1090         | akind '->' kind       { LL (mkArrowKind (unLoc $1) (unLoc $3)) }
1091
1092 akind   :: { Located Kind }
1093         : '*'                   { L1 liftedTypeKind }
1094         | '!'                   { L1 unliftedTypeKind }
1095         | '(' kind ')'          { LL (unLoc $2) }
1096
1097
1098 -----------------------------------------------------------------------------
1099 -- Datatype declarations
1100
1101 gadt_constrlist :: { Located [LConDecl RdrName] }       -- Returned in order
1102         : 'where' '{'        gadt_constrs '}'      { L (comb2 $1 $3) (unLoc $3) }
1103         | 'where' vocurly    gadt_constrs close    { L (comb2 $1 $3) (unLoc $3) }
1104         | {- empty -}                              { noLoc [] }
1105
1106 gadt_constrs :: { Located [LConDecl RdrName] }
1107         : gadt_constr ';' gadt_constrs  { L (comb2 (head $1) $3) ($1 ++ unLoc $3) }
1108         | gadt_constr                   { L (getLoc (head $1)) $1 }
1109         | {- empty -}                   { noLoc [] }
1110
1111 -- We allow the following forms:
1112 --      C :: Eq a => a -> T a
1113 --      C :: forall a. Eq a => !a -> T a
1114 --      D { x,y :: a } :: T a
1115 --      forall a. Eq a => D { x,y :: a } :: T a
1116
1117 gadt_constr :: { [LConDecl RdrName] }   -- Returns a list because of:   C,D :: ty
1118         : con_list '::' sigtype
1119                 { map (sL (comb2 $1 $3)) (mkGadtDecl (unLoc $1) $3) } 
1120
1121                 -- Deprecated syntax for GADT record declarations
1122         | oqtycon '{' fielddecls '}' '::' sigtype
1123                 {% do { cd <- mkDeprecatedGadtRecordDecl (comb2 $1 $6) $1 $3 $6
1124                       ; return [cd] } }
1125
1126 constrs :: { Located [LConDecl RdrName] }
1127         : maybe_docnext '=' constrs1    { L (comb2 $2 $3) (addConDocs (unLoc $3) $1) }
1128
1129 constrs1 :: { Located [LConDecl RdrName] }
1130         : constrs1 maybe_docnext '|' maybe_docprev constr { LL (addConDoc $5 $2 : addConDocFirst (unLoc $1) $4) }
1131         | constr                                          { L1 [$1] }
1132
1133 constr :: { LConDecl RdrName }
1134         : maybe_docnext forall context '=>' constr_stuff maybe_docprev  
1135                 { let (con,details) = unLoc $5 in 
1136                   addConDoc (L (comb4 $2 $3 $4 $5) (mkSimpleConDecl con (unLoc $2) $3 details))
1137                             ($1 `mplus` $6) }
1138         | maybe_docnext forall constr_stuff maybe_docprev
1139                 { let (con,details) = unLoc $3 in 
1140                   addConDoc (L (comb2 $2 $3) (mkSimpleConDecl con (unLoc $2) (noLoc []) details))
1141                             ($1 `mplus` $4) }
1142
1143 forall :: { Located [LHsTyVarBndr RdrName] }
1144         : 'forall' tv_bndrs '.'         { LL $2 }
1145         | {- empty -}                   { noLoc [] }
1146
1147 constr_stuff :: { Located (Located RdrName, HsConDeclDetails RdrName) }
1148 -- We parse the constructor declaration 
1149 --      C t1 t2
1150 -- as a btype (treating C as a type constructor) and then convert C to be
1151 -- a data constructor.  Reason: it might continue like this:
1152 --      C t1 t2 %: D Int
1153 -- in which case C really would be a type constructor.  We can't resolve this
1154 -- ambiguity till we come across the constructor oprerator :% (or not, more usually)
1155         : btype                         {% splitCon $1 >>= return.LL }
1156         | btype conop btype             {  LL ($2, InfixCon $1 $3) }
1157
1158 fielddecls :: { [ConDeclField RdrName] }
1159         : {- empty -}     { [] }
1160         | fielddecls1     { $1 }
1161
1162 fielddecls1 :: { [ConDeclField RdrName] }
1163         : fielddecl maybe_docnext ',' maybe_docprev fielddecls1
1164                       { [ addFieldDoc f $4 | f <- $1 ] ++ addFieldDocs $5 $2 }
1165                              -- This adds the doc $4 to each field separately
1166         | fielddecl   { $1 }
1167
1168 fielddecl :: { [ConDeclField RdrName] }    -- A list because of   f,g :: Int
1169         : maybe_docnext sig_vars '::' ctype maybe_docprev      { [ ConDeclField fld $4 ($1 `mplus` $5) 
1170                                                                  | fld <- reverse (unLoc $2) ] }
1171
1172 -- We allow the odd-looking 'inst_type' in a deriving clause, so that
1173 -- we can do deriving( forall a. C [a] ) in a newtype (GHC extension).
1174 -- The 'C [a]' part is converted to an HsPredTy by checkInstType
1175 -- We don't allow a context, but that's sorted out by the type checker.
1176 deriving :: { Located (Maybe [LHsType RdrName]) }
1177         : {- empty -}                           { noLoc Nothing }
1178         | 'deriving' qtycon     {% do { let { L loc tv = $2 }
1179                                       ; p <- checkInstType (L loc (HsTyVar tv))
1180                                       ; return (LL (Just [p])) } }
1181         | 'deriving' '(' ')'                    { LL (Just []) }
1182         | 'deriving' '(' inst_types1 ')'        { LL (Just $3) }
1183              -- Glasgow extension: allow partial 
1184              -- applications in derivings
1185
1186 -----------------------------------------------------------------------------
1187 -- Value definitions
1188
1189 {- Note [Declaration/signature overlap]
1190 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1191 There's an awkward overlap with a type signature.  Consider
1192         f :: Int -> Int = ...rhs...
1193    Then we can't tell whether it's a type signature or a value
1194    definition with a result signature until we see the '='.
1195    So we have to inline enough to postpone reductions until we know.
1196 -}
1197
1198 {-
1199   ATTENTION: Dirty Hackery Ahead! If the second alternative of vars is var
1200   instead of qvar, we get another shift/reduce-conflict. Consider the
1201   following programs:
1202   
1203      { (^^) :: Int->Int ; }          Type signature; only var allowed
1204
1205      { (^^) :: Int->Int = ... ; }    Value defn with result signature;
1206                                      qvar allowed (because of instance decls)
1207   
1208   We can't tell whether to reduce var to qvar until after we've read the signatures.
1209 -}
1210
1211 docdecl :: { LHsDecl RdrName }
1212         : docdecld { L1 (DocD (unLoc $1)) }
1213
1214 docdecld :: { LDocDecl }
1215         : docnext                               { L1 (DocCommentNext (unLoc $1)) }
1216         | docprev                               { L1 (DocCommentPrev (unLoc $1)) }
1217         | docnamed                              { L1 (case (unLoc $1) of (n, doc) -> DocCommentNamed n doc) }
1218         | docsection                            { L1 (case (unLoc $1) of (n, doc) -> DocGroup n doc) }
1219
1220 decl    :: { Located (OrdList (LHsDecl RdrName)) }
1221         : sigdecl               { $1 }
1222
1223         | '!' aexp rhs          {% do { let { e = LL (SectionR (LL (HsVar bang_RDR)) $2) };
1224                                         pat <- checkPattern e;
1225                                         return $ LL $ unitOL $ LL $ ValD $
1226                                                PatBind pat (unLoc $3)
1227                                                        placeHolderType placeHolderNames } }
1228                                 -- Turn it all into an expression so that
1229                                 -- checkPattern can check that bangs are enabled
1230
1231         | infixexp opt_sig rhs  {% do { r <- checkValDef $1 $2 $3;
1232                                         let { l = comb2 $1 $> };
1233                                         return $! (sL l (unitOL $! (sL l $ ValD r))) } }
1234         | docdecl               { LL $ unitOL $1 }
1235
1236 rhs     :: { Located (GRHSs RdrName) }
1237         : '=' exp wherebinds    { sL (comb3 $1 $2 $3) $ GRHSs (unguardedRHS $2) (unLoc $3) }
1238         | gdrhs wherebinds      { LL $ GRHSs (reverse (unLoc $1)) (unLoc $2) }
1239
1240 gdrhs :: { Located [LGRHS RdrName] }
1241         : gdrhs gdrh            { LL ($2 : unLoc $1) }
1242         | gdrh                  { L1 [$1] }
1243
1244 gdrh :: { LGRHS RdrName }
1245         : '|' guardquals '=' exp        { sL (comb2 $1 $>) $ GRHS (unLoc $2) $4 }
1246
1247 sigdecl :: { Located (OrdList (LHsDecl RdrName)) }
1248         : 
1249         -- See Note [Declaration/signature overlap] for why we need infixexp here
1250           infixexp '::' sigtypedoc
1251                         {% do s <- checkValSig $1 $3 
1252                         ; return (LL $ unitOL (LL $ SigD s)) }
1253         | var ',' sig_vars '::' sigtypedoc
1254                                 { LL $ toOL [ LL $ SigD (TypeSig ($1 : unLoc $3) $5) ] }
1255         | infix prec ops        { LL $ toOL [ LL $ SigD (FixSig (FixitySig n (Fixity $2 (unLoc $1))))
1256                                              | n <- unLoc $3 ] }
1257         | '{-# INLINE'   activation qvar '#-}'        
1258                 { LL $ unitOL (LL $ SigD (InlineSig $3 (mkInlinePragma (getINLINE $1) $2))) }
1259         | '{-# SPECIALISE' qvar '::' sigtypes1 '#-}'
1260                 { LL $ toOL [ LL $ SigD (SpecSig $2 t defaultInlinePragma) 
1261                                             | t <- $4] }
1262         | '{-# SPECIALISE_INLINE' activation qvar '::' sigtypes1 '#-}'
1263                 { LL $ toOL [ LL $ SigD (SpecSig $3 t (mkInlinePragma (getSPEC_INLINE $1) $2))
1264                                             | t <- $5] }
1265         | '{-# SPECIALISE' 'instance' inst_type '#-}'
1266                 { LL $ unitOL (LL $ SigD (SpecInstSig $3)) }
1267
1268 -----------------------------------------------------------------------------
1269 -- Expressions
1270
1271 quasiquote :: { Located (HsQuasiQuote RdrName) }
1272         : TH_QUASIQUOTE   { let { loc = getLoc $1
1273                                 ; ITquasiQuote (quoter, quote, quoteSpan) = unLoc $1
1274                                 ; quoterId = mkUnqual varName quoter }
1275                             in L1 (mkHsQuasiQuote quoterId (RealSrcSpan quoteSpan) quote) }
1276
1277 exp   :: { LHsExpr RdrName }
1278         : infixexp '::' sigtype         { LL $ ExprWithTySig $1 $3 }
1279         | infixexp '-<' exp             { LL $ HsArrApp $1 $3 placeHolderType HsFirstOrderApp True }
1280         | infixexp '>-' exp             { LL $ HsArrApp $3 $1 placeHolderType HsFirstOrderApp False }
1281         | infixexp '-<<' exp            { LL $ HsArrApp $1 $3 placeHolderType HsHigherOrderApp True }
1282         | infixexp '>>-' exp            { LL $ HsArrApp $3 $1 placeHolderType HsHigherOrderApp False}
1283         | infixexp                      { $1 }
1284
1285 infixexp :: { LHsExpr RdrName }
1286         : exp10                         { $1 }
1287         | infixexp qop exp10            { LL (OpApp $1 $2 (panic "fixity") $3) }
1288
1289 exp10 :: { LHsExpr RdrName }
1290         : '\\' apat apats opt_asig '->' exp     
1291                         { LL $ HsLam (mkMatchGroup [LL $ Match ($2:$3) $4
1292                                                                 (unguardedGRHSs $6)
1293                                                             ]) }
1294         | 'let' binds 'in' exp                  { LL $ HsLet (unLoc $2) $4 }
1295         | 'if' exp optSemi 'then' exp optSemi 'else' exp
1296                                         {% checkDoAndIfThenElse $2 $3 $5 $6 $8 >>
1297                                            return (LL $ mkHsIf $2 $5 $8) }
1298         | 'case' exp 'of' altslist              { LL $ HsCase $2 (mkMatchGroup (unLoc $4)) }
1299         | '-' fexp                              { LL $ NegApp $2 noSyntaxExpr }
1300
1301         | 'do' stmtlist                 { L (comb2 $1 $2) (mkHsDo DoExpr  (unLoc $2)) }
1302         | 'mdo' stmtlist                { L (comb2 $1 $2) (mkHsDo MDoExpr (unLoc $2)) }
1303
1304         | scc_annot exp                         { LL $ if opt_SccProfilingOn
1305                                                         then HsSCC (unLoc $1) $2
1306                                                         else HsPar $2 }
1307         | hpc_annot exp                         { LL $ if opt_Hpc
1308                                                         then HsTickPragma (unLoc $1) $2
1309                                                         else HsPar $2 }
1310
1311         | 'proc' aexp '->' exp  
1312                         {% checkPattern $2 >>= \ p -> 
1313                            return (LL $ HsProc p (LL $ HsCmdTop $4 [] 
1314                                                    placeHolderType undefined)) }
1315                                                 -- TODO: is LL right here?
1316
1317         | '{-# CORE' STRING '#-}' exp           { LL $ HsCoreAnn (getSTRING $2) $4 }
1318                                                     -- hdaume: core annotation
1319         | fexp                                  { $1 }
1320
1321 optSemi :: { Bool }
1322         : ';'         { True }
1323         | {- empty -} { False }
1324
1325 scc_annot :: { Located FastString }
1326         : '_scc_' STRING                        {% (addWarning Opt_WarnWarningsDeprecations (getLoc $1) (text "_scc_ is deprecated; use an SCC pragma instead")) >>= \_ ->
1327                                    ( do scc <- getSCC $2; return $ LL scc ) }
1328         | '{-# SCC' STRING '#-}'                {% do scc <- getSCC $2; return $ LL scc }
1329
1330 hpc_annot :: { Located (FastString,(Int,Int),(Int,Int)) }
1331         : '{-# GENERATED' STRING INTEGER ':' INTEGER '-' INTEGER ':' INTEGER '#-}'
1332                                                 { LL $ (getSTRING $2
1333                                                        ,( fromInteger $ getINTEGER $3
1334                                                         , fromInteger $ getINTEGER $5
1335                                                         )
1336                                                        ,( fromInteger $ getINTEGER $7
1337                                                         , fromInteger $ getINTEGER $9
1338                                                         )
1339                                                        )
1340                                                  }
1341
1342 fexp    :: { LHsExpr RdrName }
1343         : fexp aexp                             { LL $ HsApp $1 $2 }
1344         | aexp                                  { $1 }
1345
1346 aexp    :: { LHsExpr RdrName }
1347         : qvar '@' aexp                 { LL $ EAsPat $1 $3 }
1348         | '~' aexp                      { LL $ ELazyPat $2 }
1349         | aexp1                 { $1 }
1350
1351 aexp1   :: { LHsExpr RdrName }
1352         : aexp1 '{' fbinds '}'  {% do { r <- mkRecConstrOrUpdate $1 (comb2 $2 $4) $3
1353                                       ; return (LL r) }}
1354         | aexp2                 { $1 }
1355
1356 -- Here was the syntax for type applications that I was planning
1357 -- but there are difficulties (e.g. what order for type args)
1358 -- so it's not enabled yet.
1359 -- But this case *is* used for the left hand side of a generic definition,
1360 -- which is parsed as an expression before being munged into a pattern
1361         | qcname '{|' type '|}'         { LL $ HsApp (sL (getLoc $1) (HsVar (unLoc $1)))
1362                                                      (sL (getLoc $3) (HsType $3)) }
1363
1364 aexp2   :: { LHsExpr RdrName }
1365         : ipvar                         { L1 (HsIPVar $! unLoc $1) }
1366         | qcname                        { L1 (HsVar   $! unLoc $1) }
1367         | literal                       { L1 (HsLit   $! unLoc $1) }
1368 -- This will enable overloaded strings permanently.  Normally the renamer turns HsString
1369 -- into HsOverLit when -foverloaded-strings is on.
1370 --      | STRING                        { sL (getLoc $1) (HsOverLit $! mkHsIsString (getSTRING $1) placeHolderType) }
1371         | INTEGER                       { sL (getLoc $1) (HsOverLit $! mkHsIntegral (getINTEGER $1) placeHolderType) }
1372         | RATIONAL                      { sL (getLoc $1) (HsOverLit $! mkHsFractional (getRATIONAL $1) placeHolderType) }
1373
1374         -- N.B.: sections get parsed by these next two productions.
1375         -- This allows you to write, e.g., '(+ 3, 4 -)', which isn't
1376         -- correct Haskell (you'd have to write '((+ 3), (4 -))')
1377         -- but the less cluttered version fell out of having texps.
1378         | '(' texp ')'                  { LL (HsPar $2) }
1379         | '(' tup_exprs ')'             { LL (ExplicitTuple $2 Boxed) }
1380
1381         | '(#' texp '#)'                { LL (ExplicitTuple [Present $2] Unboxed) }
1382         | '(#' tup_exprs '#)'           { LL (ExplicitTuple $2 Unboxed) }
1383
1384         | '[' list ']'                  { LL (unLoc $2) }
1385         | '[:' parr ':]'                { LL (unLoc $2) }
1386         | '_'                           { L1 EWildPat }
1387         
1388         -- Template Haskell Extension
1389         | TH_ID_SPLICE          { L1 $ HsSpliceE (mkHsSplice 
1390                                         (L1 $ HsVar (mkUnqual varName 
1391                                                         (getTH_ID_SPLICE $1)))) } 
1392         | '$(' exp ')'          { LL $ HsSpliceE (mkHsSplice $2) }               
1393
1394
1395         | TH_VAR_QUOTE qvar     { LL $ HsBracket (VarBr (unLoc $2)) }
1396         | TH_VAR_QUOTE qcon     { LL $ HsBracket (VarBr (unLoc $2)) }
1397         | TH_TY_QUOTE tyvar     { LL $ HsBracket (VarBr (unLoc $2)) }
1398         | TH_TY_QUOTE gtycon    { LL $ HsBracket (VarBr (unLoc $2)) }
1399         | '[|' exp '|]'         { LL $ HsBracket (ExpBr $2) }                       
1400         | '[t|' ctype '|]'      { LL $ HsBracket (TypBr $2) }                       
1401         | '[p|' infixexp '|]'   {% checkPattern $2 >>= \p ->
1402                                         return (LL $ HsBracket (PatBr p)) }
1403         | '[d|' cvtopbody '|]'  { LL $ HsBracket (DecBrL $2) }
1404         | quasiquote            { L1 (HsQuasiQuoteE (unLoc $1)) }
1405
1406         -- arrow notation extension
1407         | '(|' aexp2 cmdargs '|)'       { LL $ HsArrForm $2 Nothing (reverse $3) }
1408
1409 cmdargs :: { [LHsCmdTop RdrName] }
1410         : cmdargs acmd                  { $2 : $1 }
1411         | {- empty -}                   { [] }
1412
1413 acmd    :: { LHsCmdTop RdrName }
1414         : aexp2                 { L1 $ HsCmdTop $1 [] placeHolderType undefined }
1415
1416 cvtopbody :: { [LHsDecl RdrName] }
1417         :  '{'            cvtopdecls0 '}'               { $2 }
1418         |      vocurly    cvtopdecls0 close             { $2 }
1419
1420 cvtopdecls0 :: { [LHsDecl RdrName] }
1421         : {- empty -}           { [] }
1422         | cvtopdecls            { $1 }
1423
1424 -----------------------------------------------------------------------------
1425 -- Tuple expressions
1426
1427 -- "texp" is short for tuple expressions: 
1428 -- things that can appear unparenthesized as long as they're
1429 -- inside parens or delimitted by commas
1430 texp :: { LHsExpr RdrName }
1431         : exp                           { $1 }
1432
1433         -- Note [Parsing sections]
1434         -- ~~~~~~~~~~~~~~~~~~~~~~~
1435         -- We include left and right sections here, which isn't
1436         -- technically right according to the Haskell standard.
1437         -- For example (3 +, True) isn't legal.
1438         -- However, we want to parse bang patterns like
1439         --      (!x, !y)
1440         -- and it's convenient to do so here as a section
1441         -- Then when converting expr to pattern we unravel it again
1442         -- Meanwhile, the renamer checks that real sections appear
1443         -- inside parens.
1444         | infixexp qop        { LL $ SectionL $1 $2 }
1445         | qopm infixexp       { LL $ SectionR $1 $2 }
1446
1447        -- View patterns get parenthesized above
1448         | exp '->' texp   { LL $ EViewPat $1 $3 }
1449
1450 -- Always at least one comma
1451 tup_exprs :: { [HsTupArg RdrName] }
1452            : texp commas_tup_tail  { Present $1 : $2 }
1453            | commas tup_tail       { replicate $1 missingTupArg ++ $2 }
1454
1455 -- Always starts with commas; always follows an expr
1456 commas_tup_tail :: { [HsTupArg RdrName] }
1457 commas_tup_tail : commas tup_tail  { replicate ($1-1) missingTupArg ++ $2 }
1458
1459 -- Always follows a comma
1460 tup_tail :: { [HsTupArg RdrName] }
1461           : texp commas_tup_tail        { Present $1 : $2 }
1462           | texp                        { [Present $1] }
1463           | {- empty -}                 { [missingTupArg] }
1464
1465 -----------------------------------------------------------------------------
1466 -- List expressions
1467
1468 -- The rules below are little bit contorted to keep lexps left-recursive while
1469 -- avoiding another shift/reduce-conflict.
1470
1471 list :: { LHsExpr RdrName }
1472         : texp                  { L1 $ ExplicitList placeHolderType [$1] }
1473         | lexps                 { L1 $ ExplicitList placeHolderType (reverse (unLoc $1)) }
1474         | texp '..'             { LL $ ArithSeq noPostTcExpr (From $1) }
1475         | texp ',' exp '..'     { LL $ ArithSeq noPostTcExpr (FromThen $1 $3) }
1476         | texp '..' exp         { LL $ ArithSeq noPostTcExpr (FromTo $1 $3) }
1477         | texp ',' exp '..' exp { LL $ ArithSeq noPostTcExpr (FromThenTo $1 $3 $5) }
1478         | texp '|' flattenedpquals      
1479              {% checkMonadComp >>= \ ctxt ->
1480                 return (sL (comb2 $1 $>) $ 
1481                         mkHsComp ctxt (unLoc $3) $1) }
1482
1483 lexps :: { Located [LHsExpr RdrName] }
1484         : lexps ',' texp                { LL (((:) $! $3) $! unLoc $1) }
1485         | texp ',' texp                 { LL [$3,$1] }
1486
1487 -----------------------------------------------------------------------------
1488 -- List Comprehensions
1489
1490 flattenedpquals :: { Located [LStmt RdrName] }
1491     : pquals   { case (unLoc $1) of
1492                     [qs] -> L1 qs
1493                     -- We just had one thing in our "parallel" list so 
1494                     -- we simply return that thing directly
1495                     
1496                     qss -> L1 [L1 $ ParStmt [(qs, undefined) | qs <- qss] noSyntaxExpr noSyntaxExpr noSyntaxExpr]
1497                     -- We actually found some actual parallel lists so
1498                     -- we wrap them into as a ParStmt
1499                 }
1500
1501 pquals :: { Located [[LStmt RdrName]] }
1502     : squals '|' pquals     { L (getLoc $2) (reverse (unLoc $1) : unLoc $3) }
1503     | squals                { L (getLoc $1) [reverse (unLoc $1)] }
1504
1505 squals :: { Located [LStmt RdrName] }   -- In reverse order, because the last 
1506                                         -- one can "grab" the earlier ones
1507     : squals ',' transformqual               { LL [L (getLoc $3) ((unLoc $3) (reverse (unLoc $1)))] }
1508     | squals ',' qual                        { LL ($3 : unLoc $1) }
1509     | transformqual                          { LL [L (getLoc $1) ((unLoc $1) [])] }
1510     | qual                                   { L1 [$1] }
1511 --  | transformquals1 ',' '{|' pquals '|}'   { LL ($4 : unLoc $1) }
1512 --  | '{|' pquals '|}'                       { L1 [$2] }
1513
1514
1515 -- It is possible to enable bracketing (associating) qualifier lists by uncommenting the lines with {| |}
1516 -- above. Due to a lack of consensus on the syntax, this feature is not being used until we get user
1517 -- demand.
1518
1519 transformqual :: { Located ([LStmt RdrName] -> Stmt RdrName) }
1520                         -- Function is applied to a list of stmts *in order*
1521     : 'then' exp                { LL $ \leftStmts -> (mkTransformStmt leftStmts $2) }
1522     -- >>>
1523     | 'then' exp 'by' exp       { LL $ \leftStmts -> (mkTransformByStmt leftStmts $2 $4) }
1524     | 'then' 'group' 'by' exp   { LL $ \leftStmts -> (mkGroupByStmt leftStmts $4) }
1525     -- <<<
1526     -- These two productions deliberately have a shift-reduce conflict. I have made 'group' into a special_id,
1527     -- which means you can enable TransformListComp while still using Data.List.group. However, this makes the two
1528     -- productions ambiguous. I've set things up so that Happy chooses to resolve the conflict in that case by
1529     -- choosing the "group by" variant, which is what we want.
1530     --
1531     -- This is rather dubious: the user might be confused as to how to parse this statement. However, it is a good
1532     -- practical choice. NB: Data.List.group :: [a] -> [[a]], so using the first production would not even type check
1533     -- if /that/ is the group function we conflict with.
1534     | 'then' 'group' 'using' exp           { LL $ \leftStmts -> (mkGroupUsingStmt leftStmts $4) }
1535     | 'then' 'group' 'by' exp 'using' exp  { LL $ \leftStmts -> (mkGroupByUsingStmt leftStmts $4 $6) }
1536
1537 -----------------------------------------------------------------------------
1538 -- Parallel array expressions
1539
1540 -- The rules below are little bit contorted; see the list case for details.
1541 -- Note that, in contrast to lists, we only have finite arithmetic sequences.
1542 -- Moreover, we allow explicit arrays with no element (represented by the nil
1543 -- constructor in the list case).
1544
1545 parr :: { LHsExpr RdrName }
1546         :                               { noLoc (ExplicitPArr placeHolderType []) }
1547         | texp                          { L1 $ ExplicitPArr placeHolderType [$1] }
1548         | lexps                         { L1 $ ExplicitPArr placeHolderType 
1549                                                        (reverse (unLoc $1)) }
1550         | texp '..' exp                 { LL $ PArrSeq noPostTcExpr (FromTo $1 $3) }
1551         | texp ',' exp '..' exp         { LL $ PArrSeq noPostTcExpr (FromThenTo $1 $3 $5) }
1552         | texp '|' flattenedpquals      { LL $ mkHsComp PArrComp (unLoc $3) $1 }
1553
1554 -- We are reusing `lexps' and `flattenedpquals' from the list case.
1555
1556 -----------------------------------------------------------------------------
1557 -- Guards
1558
1559 guardquals :: { Located [LStmt RdrName] }
1560     : guardquals1           { L (getLoc $1) (reverse (unLoc $1)) }
1561
1562 guardquals1 :: { Located [LStmt RdrName] }
1563     : guardquals1 ',' qual  { LL ($3 : unLoc $1) }
1564     | qual                  { L1 [$1] }
1565
1566 -----------------------------------------------------------------------------
1567 -- Case alternatives
1568
1569 altslist :: { Located [LMatch RdrName] }
1570         : '{'            alts '}'       { LL (reverse (unLoc $2)) }
1571         |     vocurly    alts  close    { L (getLoc $2) (reverse (unLoc $2)) }
1572
1573 alts    :: { Located [LMatch RdrName] }
1574         : alts1                         { L1 (unLoc $1) }
1575         | ';' alts                      { LL (unLoc $2) }
1576
1577 alts1   :: { Located [LMatch RdrName] }
1578         : alts1 ';' alt                 { LL ($3 : unLoc $1) }
1579         | alts1 ';'                     { LL (unLoc $1) }
1580         | alt                           { L1 [$1] }
1581
1582 alt     :: { LMatch RdrName }
1583         : pat opt_sig alt_rhs           { LL (Match [$1] $2 (unLoc $3)) }
1584
1585 alt_rhs :: { Located (GRHSs RdrName) }
1586         : ralt wherebinds               { LL (GRHSs (unLoc $1) (unLoc $2)) }
1587
1588 ralt :: { Located [LGRHS RdrName] }
1589         : '->' exp                      { LL (unguardedRHS $2) }
1590         | gdpats                        { L1 (reverse (unLoc $1)) }
1591
1592 gdpats :: { Located [LGRHS RdrName] }
1593         : gdpats gdpat                  { LL ($2 : unLoc $1) }
1594         | gdpat                         { L1 [$1] }
1595
1596 gdpat   :: { LGRHS RdrName }
1597         : '|' guardquals '->' exp               { sL (comb2 $1 $>) $ GRHS (unLoc $2) $4 }
1598
1599 -- 'pat' recognises a pattern, including one with a bang at the top
1600 --      e.g.  "!x" or "!(x,y)" or "C a b" etc
1601 -- Bangs inside are parsed as infix operator applications, so that
1602 -- we parse them right when bang-patterns are off
1603 pat     :: { LPat RdrName }
1604 pat     :  exp                  {% checkPattern $1 }
1605         | '!' aexp              {% checkPattern (LL (SectionR (L1 (HsVar bang_RDR)) $2)) }
1606
1607 apat   :: { LPat RdrName }      
1608 apat    : aexp                  {% checkPattern $1 }
1609         | '!' aexp              {% checkPattern (LL (SectionR (L1 (HsVar bang_RDR)) $2)) }
1610
1611 apats  :: { [LPat RdrName] }
1612         : apat apats            { $1 : $2 }
1613         | {- empty -}           { [] }
1614
1615 -----------------------------------------------------------------------------
1616 -- Statement sequences
1617
1618 stmtlist :: { Located [LStmt RdrName] }
1619         : '{'           stmts '}'       { LL (unLoc $2) }
1620         |     vocurly   stmts close     { $2 }
1621
1622 --      do { ;; s ; s ; ; s ;; }
1623 -- The last Stmt should be an expression, but that's hard to enforce
1624 -- here, because we need too much lookahead if we see do { e ; }
1625 -- So we use ExprStmts throughout, and switch the last one over
1626 -- in ParseUtils.checkDo instead
1627 stmts :: { Located [LStmt RdrName] }
1628         : stmt stmts_help               { LL ($1 : unLoc $2) }
1629         | ';' stmts                     { LL (unLoc $2) }
1630         | {- empty -}                   { noLoc [] }
1631
1632 stmts_help :: { Located [LStmt RdrName] } -- might be empty
1633         : ';' stmts                     { LL (unLoc $2) }
1634         | {- empty -}                   { noLoc [] }
1635
1636 -- For typing stmts at the GHCi prompt, where 
1637 -- the input may consist of just comments.
1638 maybe_stmt :: { Maybe (LStmt RdrName) }
1639         : stmt                          { Just $1 }
1640         | {- nothing -}                 { Nothing }
1641
1642 stmt  :: { LStmt RdrName }
1643         : qual                              { $1 }
1644         | 'rec' stmtlist                { LL $ mkRecStmt (unLoc $2) }
1645
1646 qual  :: { LStmt RdrName }
1647     : pat '<-' exp                      { LL $ mkBindStmt $1 $3 }
1648     | exp                                   { L1 $ mkExprStmt $1 }
1649     | 'let' binds                       { LL $ LetStmt (unLoc $2) }
1650
1651 -----------------------------------------------------------------------------
1652 -- Record Field Update/Construction
1653
1654 fbinds  :: { ([HsRecField RdrName (LHsExpr RdrName)], Bool) }
1655         : fbinds1                       { $1 }
1656         | {- empty -}                   { ([], False) }
1657
1658 fbinds1 :: { ([HsRecField RdrName (LHsExpr RdrName)], Bool) }
1659         : fbind ',' fbinds1             { case $3 of (flds, dd) -> ($1 : flds, dd) } 
1660         | fbind                         { ([$1], False) }
1661         | '..'                          { ([],   True) }
1662   
1663 fbind   :: { HsRecField RdrName (LHsExpr RdrName) }
1664         : qvar '=' exp  { HsRecField $1 $3                False }
1665         | qvar          { HsRecField $1 placeHolderPunRhs True }
1666                         -- In the punning case, use a place-holder
1667                         -- The renamer fills in the final value
1668
1669 -----------------------------------------------------------------------------
1670 -- Implicit Parameter Bindings
1671
1672 dbinds  :: { Located [LIPBind RdrName] }
1673         : dbinds ';' dbind              { let { this = $3; rest = unLoc $1 }
1674                               in rest `seq` this `seq` LL (this : rest) }
1675         | dbinds ';'                    { LL (unLoc $1) }
1676         | dbind                         { let this = $1 in this `seq` L1 [this] }
1677 --      | {- empty -}                   { [] }
1678
1679 dbind   :: { LIPBind RdrName }
1680 dbind   : ipvar '=' exp                 { LL (IPBind (unLoc $1) $3) }
1681
1682 ipvar   :: { Located (IPName RdrName) }
1683         : IPDUPVARID            { L1 (IPName (mkUnqual varName (getIPDUPVARID $1))) }
1684
1685 -----------------------------------------------------------------------------
1686 -- Warnings and deprecations
1687
1688 namelist :: { Located [RdrName] }
1689 namelist : name_var              { L1 [unLoc $1] }
1690          | name_var ',' namelist { LL (unLoc $1 : unLoc $3) }
1691
1692 name_var :: { Located RdrName }
1693 name_var : var { $1 }
1694          | con { $1 }
1695
1696 -----------------------------------------
1697 -- Data constructors
1698 qcon    :: { Located RdrName }
1699         : qconid                { $1 }
1700         | '(' qconsym ')'       { LL (unLoc $2) }
1701         | sysdcon               { L1 $ nameRdrName (dataConName (unLoc $1)) }
1702 -- The case of '[:' ':]' is part of the production `parr'
1703
1704 con     :: { Located RdrName }
1705         : conid                 { $1 }
1706         | '(' consym ')'        { LL (unLoc $2) }
1707         | sysdcon               { L1 $ nameRdrName (dataConName (unLoc $1)) }
1708
1709 con_list :: { Located [Located RdrName] }
1710 con_list : con                  { L1 [$1] }
1711          | con ',' con_list     { LL ($1 : unLoc $3) }
1712
1713 sysdcon :: { Located DataCon }  -- Wired in data constructors
1714         : '(' ')'               { LL unitDataCon }
1715         | '(' commas ')'        { LL $ tupleCon Boxed ($2 + 1) }
1716         | '(#' '#)'             { LL $ unboxedSingletonDataCon }
1717         | '(#' commas '#)'      { LL $ tupleCon Unboxed ($2 + 1) }
1718         | '[' ']'               { LL nilDataCon }
1719
1720 conop :: { Located RdrName }
1721         : consym                { $1 }  
1722         | '`' conid '`'         { LL (unLoc $2) }
1723
1724 qconop :: { Located RdrName }
1725         : qconsym               { $1 }
1726         | '`' qconid '`'        { LL (unLoc $2) }
1727
1728 -----------------------------------------------------------------------------
1729 -- Type constructors
1730
1731 gtycon  :: { Located RdrName }  -- A "general" qualified tycon
1732         : oqtycon                       { $1 }
1733         | '(' ')'                       { LL $ getRdrName unitTyCon }
1734         | '(' commas ')'                { LL $ getRdrName (tupleTyCon Boxed ($2 + 1)) }
1735         | '(#' '#)'                     { LL $ getRdrName unboxedSingletonTyCon }
1736         | '(#' commas '#)'              { LL $ getRdrName (tupleTyCon Unboxed ($2 + 1)) }
1737         | '(' '->' ')'                  { LL $ getRdrName funTyCon }
1738         | '[' ']'                       { LL $ listTyCon_RDR }
1739         | '[:' ':]'                     { LL $ parrTyCon_RDR }
1740
1741 oqtycon :: { Located RdrName }  -- An "ordinary" qualified tycon
1742         : qtycon                        { $1 }
1743         | '(' qtyconsym ')'             { LL (unLoc $2) }
1744
1745 qtyconop :: { Located RdrName } -- Qualified or unqualified
1746         : qtyconsym                     { $1 }
1747         | '`' qtycon '`'                { LL (unLoc $2) }
1748
1749 qtycon :: { Located RdrName }   -- Qualified or unqualified
1750         : QCONID                        { L1 $! mkQual tcClsName (getQCONID $1) }
1751         | PREFIXQCONSYM                 { L1 $! mkQual tcClsName (getPREFIXQCONSYM $1) }
1752         | tycon                         { $1 }
1753
1754 tycon   :: { Located RdrName }  -- Unqualified
1755         : CONID                         { L1 $! mkUnqual tcClsName (getCONID $1) }
1756
1757 qtyconsym :: { Located RdrName }
1758         : QCONSYM                       { L1 $! mkQual tcClsName (getQCONSYM $1) }
1759         | tyconsym                      { $1 }
1760
1761 tyconsym :: { Located RdrName }
1762         : CONSYM                        { L1 $! mkUnqual tcClsName (getCONSYM $1) }
1763
1764 -----------------------------------------------------------------------------
1765 -- Operators
1766
1767 op      :: { Located RdrName }   -- used in infix decls
1768         : varop                 { $1 }
1769         | conop                 { $1 }
1770
1771 varop   :: { Located RdrName }
1772         : varsym                { $1 }
1773         | '`' varid '`'         { LL (unLoc $2) }
1774
1775 qop     :: { LHsExpr RdrName }   -- used in sections
1776         : qvarop                { L1 $ HsVar (unLoc $1) }
1777         | qconop                { L1 $ HsVar (unLoc $1) }
1778
1779 qopm    :: { LHsExpr RdrName }   -- used in sections
1780         : qvaropm               { L1 $ HsVar (unLoc $1) }
1781         | qconop                { L1 $ HsVar (unLoc $1) }
1782
1783 qvarop :: { Located RdrName }
1784         : qvarsym               { $1 }
1785         | '`' qvarid '`'        { LL (unLoc $2) }
1786
1787 qvaropm :: { Located RdrName }
1788         : qvarsym_no_minus      { $1 }
1789         | '`' qvarid '`'        { LL (unLoc $2) }
1790
1791 -----------------------------------------------------------------------------
1792 -- Type variables
1793
1794 tyvar   :: { Located RdrName }
1795 tyvar   : tyvarid               { $1 }
1796         | '(' tyvarsym ')'      { LL (unLoc $2) }
1797
1798 tyvarop :: { Located RdrName }
1799 tyvarop : '`' tyvarid '`'       { LL (unLoc $2) }
1800         | tyvarsym              { $1 }
1801         | '.'                   {% parseErrorSDoc (getLoc $1) 
1802                                       (vcat [ptext (sLit "Illegal symbol '.' in type"), 
1803                                              ptext (sLit "Perhaps you intended -XRankNTypes or similar flag"),
1804                                              ptext (sLit "to enable explicit-forall syntax: forall <tvs>. <type>")])
1805                                 }
1806
1807 tyvarid :: { Located RdrName }
1808         : VARID                 { L1 $! mkUnqual tvName (getVARID $1) }
1809         | special_id            { L1 $! mkUnqual tvName (unLoc $1) }
1810         | 'unsafe'              { L1 $! mkUnqual tvName (fsLit "unsafe") }
1811         | 'safe'                { L1 $! mkUnqual tvName (fsLit "safe") }
1812         | 'interruptible'       { L1 $! mkUnqual tvName (fsLit "interruptible") }
1813
1814 tyvarsym :: { Located RdrName }
1815 -- Does not include "!", because that is used for strictness marks
1816 --               or ".", because that separates the quantified type vars from the rest
1817 --               or "*", because that's used for kinds
1818 tyvarsym : VARSYM               { L1 $! mkUnqual tvName (getVARSYM $1) }
1819
1820 -----------------------------------------------------------------------------
1821 -- Variables 
1822
1823 var     :: { Located RdrName }
1824         : varid                 { $1 }
1825         | '(' varsym ')'        { LL (unLoc $2) }
1826
1827 qvar    :: { Located RdrName }
1828         : qvarid                { $1 }
1829         | '(' varsym ')'        { LL (unLoc $2) }
1830         | '(' qvarsym1 ')'      { LL (unLoc $2) }
1831 -- We've inlined qvarsym here so that the decision about
1832 -- whether it's a qvar or a var can be postponed until
1833 -- *after* we see the close paren.
1834
1835 qvarid :: { Located RdrName }
1836         : varid                 { $1 }
1837         | QVARID                { L1 $! mkQual varName (getQVARID $1) }
1838         | PREFIXQVARSYM         { L1 $! mkQual varName (getPREFIXQVARSYM $1) }
1839
1840 varid :: { Located RdrName }
1841         : VARID                 { L1 $! mkUnqual varName (getVARID $1) }
1842         | special_id            { L1 $! mkUnqual varName (unLoc $1) }
1843         | 'unsafe'              { L1 $! mkUnqual varName (fsLit "unsafe") }
1844         | 'safe'                { L1 $! mkUnqual varName (fsLit "safe") }
1845         | 'interruptible'       { L1 $! mkUnqual varName (fsLit "interruptible") }
1846         | 'forall'              { L1 $! mkUnqual varName (fsLit "forall") }
1847         | 'family'              { L1 $! mkUnqual varName (fsLit "family") }
1848
1849 qvarsym :: { Located RdrName }
1850         : varsym                { $1 }
1851         | qvarsym1              { $1 }
1852
1853 qvarsym_no_minus :: { Located RdrName }
1854         : varsym_no_minus       { $1 }
1855         | qvarsym1              { $1 }
1856
1857 qvarsym1 :: { Located RdrName }
1858 qvarsym1 : QVARSYM              { L1 $ mkQual varName (getQVARSYM $1) }
1859
1860 varsym :: { Located RdrName }
1861         : varsym_no_minus       { $1 }
1862         | '-'                   { L1 $ mkUnqual varName (fsLit "-") }
1863
1864 varsym_no_minus :: { Located RdrName } -- varsym not including '-'
1865         : VARSYM                { L1 $ mkUnqual varName (getVARSYM $1) }
1866         | special_sym           { L1 $ mkUnqual varName (unLoc $1) }
1867
1868
1869 -- These special_ids are treated as keywords in various places, 
1870 -- but as ordinary ids elsewhere.   'special_id' collects all these
1871 -- except 'unsafe', 'interruptible', 'forall', and 'family' whose treatment differs
1872 -- depending on context 
1873 special_id :: { Located FastString }
1874 special_id
1875         : 'as'                  { L1 (fsLit "as") }
1876         | 'qualified'           { L1 (fsLit "qualified") }
1877         | 'hiding'              { L1 (fsLit "hiding") }
1878         | 'export'              { L1 (fsLit "export") }
1879         | 'label'               { L1 (fsLit "label")  }
1880         | 'dynamic'             { L1 (fsLit "dynamic") }
1881         | 'stdcall'             { L1 (fsLit "stdcall") }
1882         | 'ccall'               { L1 (fsLit "ccall") }
1883         | 'prim'                { L1 (fsLit "prim") }
1884         | 'group'               { L1 (fsLit "group") }
1885
1886 special_sym :: { Located FastString }
1887 special_sym : '!'       { L1 (fsLit "!") }
1888             | '.'       { L1 (fsLit ".") }
1889             | '*'       { L1 (fsLit "*") }
1890
1891 -----------------------------------------------------------------------------
1892 -- Data constructors
1893
1894 qconid :: { Located RdrName }   -- Qualified or unqualified
1895         : conid                 { $1 }
1896         | QCONID                { L1 $! mkQual dataName (getQCONID $1) }
1897         | PREFIXQCONSYM         { L1 $! mkQual dataName (getPREFIXQCONSYM $1) }
1898
1899 conid   :: { Located RdrName }
1900         : CONID                 { L1 $ mkUnqual dataName (getCONID $1) }
1901
1902 qconsym :: { Located RdrName }  -- Qualified or unqualified
1903         : consym                { $1 }
1904         | QCONSYM               { L1 $ mkQual dataName (getQCONSYM $1) }
1905
1906 consym :: { Located RdrName }
1907         : CONSYM                { L1 $ mkUnqual dataName (getCONSYM $1) }
1908
1909         -- ':' means only list cons
1910         | ':'                   { L1 $ consDataCon_RDR }
1911
1912
1913 -----------------------------------------------------------------------------
1914 -- Literals
1915
1916 literal :: { Located HsLit }
1917         : CHAR                  { L1 $ HsChar       $ getCHAR $1 }
1918         | STRING                { L1 $ HsString     $ getSTRING $1 }
1919         | PRIMINTEGER           { L1 $ HsIntPrim    $ getPRIMINTEGER $1 }
1920         | PRIMWORD              { L1 $ HsWordPrim    $ getPRIMWORD $1 }
1921         | PRIMCHAR              { L1 $ HsCharPrim   $ getPRIMCHAR $1 }
1922         | PRIMSTRING            { L1 $ HsStringPrim $ getPRIMSTRING $1 }
1923         | PRIMFLOAT             { L1 $ HsFloatPrim  $ getPRIMFLOAT $1 }
1924         | PRIMDOUBLE            { L1 $ HsDoublePrim $ getPRIMDOUBLE $1 }
1925
1926 -----------------------------------------------------------------------------
1927 -- Layout
1928
1929 close :: { () }
1930         : vccurly               { () } -- context popped in lexer.
1931         | error                 {% popContext }
1932
1933 -----------------------------------------------------------------------------
1934 -- Miscellaneous (mostly renamings)
1935
1936 modid   :: { Located ModuleName }
1937         : CONID                 { L1 $ mkModuleNameFS (getCONID $1) }
1938         | QCONID                { L1 $ let (mod,c) = getQCONID $1 in
1939                                   mkModuleNameFS
1940                                    (mkFastString
1941                                      (unpackFS mod ++ '.':unpackFS c))
1942                                 }
1943
1944 commas :: { Int }
1945         : commas ','                    { $1 + 1 }
1946         | ','                           { 1 }
1947
1948 -----------------------------------------------------------------------------
1949 -- Documentation comments
1950
1951 docnext :: { LHsDocString }
1952   : DOCNEXT {% return (L1 (HsDocString (mkFastString (getDOCNEXT $1)))) }
1953
1954 docprev :: { LHsDocString }
1955   : DOCPREV {% return (L1 (HsDocString (mkFastString (getDOCPREV $1)))) }
1956
1957 docnamed :: { Located (String, HsDocString) }
1958   : DOCNAMED {%
1959       let string = getDOCNAMED $1 
1960           (name, rest) = break isSpace string
1961       in return (L1 (name, HsDocString (mkFastString rest))) }
1962
1963 docsection :: { Located (Int, HsDocString) }
1964   : DOCSECTION {% let (n, doc) = getDOCSECTION $1 in
1965         return (L1 (n, HsDocString (mkFastString doc))) }
1966
1967 moduleheader :: { Maybe LHsDocString }
1968         : DOCNEXT {% let string = getDOCNEXT $1 in
1969                      return (Just (L1 (HsDocString (mkFastString string)))) }
1970
1971 maybe_docprev :: { Maybe LHsDocString }
1972         : docprev                       { Just $1 }
1973         | {- empty -}                   { Nothing }
1974
1975 maybe_docnext :: { Maybe LHsDocString }
1976         : docnext                       { Just $1 }
1977         | {- empty -}                   { Nothing }
1978
1979 {
1980 happyError :: P a
1981 happyError = srcParseFail
1982
1983 getVARID        (L _ (ITvarid    x)) = x
1984 getCONID        (L _ (ITconid    x)) = x
1985 getVARSYM       (L _ (ITvarsym   x)) = x
1986 getCONSYM       (L _ (ITconsym   x)) = x
1987 getQVARID       (L _ (ITqvarid   x)) = x
1988 getQCONID       (L _ (ITqconid   x)) = x
1989 getQVARSYM      (L _ (ITqvarsym  x)) = x
1990 getQCONSYM      (L _ (ITqconsym  x)) = x
1991 getPREFIXQVARSYM (L _ (ITprefixqvarsym  x)) = x
1992 getPREFIXQCONSYM (L _ (ITprefixqconsym  x)) = x
1993 getIPDUPVARID   (L _ (ITdupipvarid   x)) = x
1994 getCHAR         (L _ (ITchar     x)) = x
1995 getSTRING       (L _ (ITstring   x)) = x
1996 getINTEGER      (L _ (ITinteger  x)) = x
1997 getRATIONAL     (L _ (ITrational x)) = x
1998 getPRIMCHAR     (L _ (ITprimchar   x)) = x
1999 getPRIMSTRING   (L _ (ITprimstring x)) = x
2000 getPRIMINTEGER  (L _ (ITprimint    x)) = x
2001 getPRIMWORD     (L _ (ITprimword x)) = x
2002 getPRIMFLOAT    (L _ (ITprimfloat  x)) = x
2003 getPRIMDOUBLE   (L _ (ITprimdouble x)) = x
2004 getTH_ID_SPLICE (L _ (ITidEscape x)) = x
2005 getINLINE       (L _ (ITinline_prag inl conl)) = (inl,conl)
2006 getSPEC_INLINE  (L _ (ITspec_inline_prag True))  = (Inline,  FunLike)
2007 getSPEC_INLINE  (L _ (ITspec_inline_prag False)) = (NoInline,FunLike)
2008
2009 getDOCNEXT (L _ (ITdocCommentNext x)) = x
2010 getDOCPREV (L _ (ITdocCommentPrev x)) = x
2011 getDOCNAMED (L _ (ITdocCommentNamed x)) = x
2012 getDOCSECTION (L _ (ITdocSection n x)) = (n, x)
2013
2014 getSCC :: Located Token -> P FastString
2015 getSCC lt = do let s = getSTRING lt
2016                    err = "Spaces are not allowed in SCCs"
2017                -- We probably actually want to be more restrictive than this
2018                if ' ' `elem` unpackFS s
2019                    then failSpanMsgP (getLoc lt) (text err)
2020                    else return s
2021
2022 -- Utilities for combining source spans
2023 comb2 :: Located a -> Located b -> SrcSpan
2024 comb2 a b = a `seq` b `seq` combineLocs a b
2025
2026 comb3 :: Located a -> Located b -> Located c -> SrcSpan
2027 comb3 a b c = a `seq` b `seq` c `seq`
2028     combineSrcSpans (getLoc a) (combineSrcSpans (getLoc b) (getLoc c))
2029
2030 comb4 :: Located a -> Located b -> Located c -> Located d -> SrcSpan
2031 comb4 a b c d = a `seq` b `seq` c `seq` d `seq`
2032     (combineSrcSpans (getLoc a) $ combineSrcSpans (getLoc b) $
2033                 combineSrcSpans (getLoc c) (getLoc d))
2034
2035 -- strict constructor version:
2036 {-# INLINE sL #-}
2037 sL :: SrcSpan -> a -> Located a
2038 sL span a = span `seq` a `seq` L span a
2039
2040 -- Make a source location for the file.  We're a bit lazy here and just
2041 -- make a point SrcSpan at line 1, column 0.  Strictly speaking we should
2042 -- try to find the span of the whole file (ToDo).
2043 fileSrcSpan :: P SrcSpan
2044 fileSrcSpan = do 
2045   l <- getSrcLoc; 
2046   let loc = mkSrcLoc (srcLocFile l) 1 1;
2047   return (mkSrcSpan loc loc)
2048 }