Do version specific detection of LLVM tools (#10170).
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.11], [glasgow-haskell-bugs@haskell.org], [ghc])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands,
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42 FP_PROG_SORT
43
44 dnl ----------------------------------------------------------
45 FP_SETUP_PROJECT_VERSION
46
47 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
48 AC_SUBST([release], [1])
49
50 # First off, a distrib sanity check..
51 AC_CONFIG_SRCDIR([mk/config.mk.in])
52
53 dnl * We require autoconf version 2.60
54 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
55 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
56 dnl Using autoconf 2.59 started to give nonsense like this
57 dnl  #define SIZEOF_CHAR 0
58 dnl recently.
59 AC_PREREQ([2.60])
60
61 # -------------------------------------------------------------------------
62 # Prepare to generate the following header files
63 #
64 #
65 AC_CONFIG_HEADER(mk/config.h)
66
67 # No, semi-sadly, we don't do `--srcdir'...
68 if test x"$srcdir" != 'x.' ; then
69     echo "This configuration does not support the \`--srcdir' option.."
70     exit 1
71 fi
72
73 dnl --------------------------------------------------------------
74 dnl * Project specific configuration options
75 dnl --------------------------------------------------------------
76 dnl What follows is a bunch of options that can either be configured
77 dnl through command line options to the configure script or by
78 dnl supplying defns in the build tree's mk/build.mk. Having the option to
79 dnl use either is considered a Feature.
80
81 dnl ** What command to use to compile compiler sources ?
82 dnl --------------------------------------------------------------
83
84 AC_ARG_WITH([ghc],
85 [AC_HELP_STRING([--with-ghc=ARG],
86   [Use ARG as the path to GHC  [default=autodetect]])],
87   [WithGhc="$withval"],
88   [if test "$GHC" = ""; then
89     AC_PATH_PROG([GHC], [ghc])
90   fi
91   WithGhc="$GHC"])
92
93 dnl ** Tell the make system which OS we are using
94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
95 AC_SUBST(OSTYPE)
96
97 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
98 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
99                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
100         EnableBootstrapWithDevelSnaphost=YES,
101         EnableBootstrapWithDevelSnaphost=NO
102 )
103
104 if test "$WithGhc" != ""; then
105   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
106
107   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
108      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
109   fi
110
111   AC_SUBST(GhcVersion)dnl
112   AC_SUBST(GhcMajVersion)dnl
113   AC_SUBST(GhcMinVersion)dnl
114   AC_SUBST(GhcPatchLevel)dnl
115   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
116   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
117
118   BOOTSTRAPPING_GHC_INFO_FIELD([OS_STAGE0],[target os])
119   BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
120   dnl ToDo, once "ld command" is reliably available.
121   dnl Then, we can remove the LD_STAGE0 hack in mk/build-package-date.mk
122   dnl BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
123   if test "x$OS_STAGE0" != "xOSDarwin"; then
124     BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
125     BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
126     BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
127   else
128     AR_STAGE0='$(AR)'
129     AR_OPTS_STAGE0='$(AR_OPTS)'
130     ArSupportsAtFile_STAGE0='$(ArSupportsAtFile)'
131   fi
132 fi
133
134 dnl ** Must have GHC to build GHC
135 if test "$WithGhc" = ""
136 then
137     AC_MSG_ERROR([GHC is required.])
138 fi
139 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.6],
140     [AC_MSG_ERROR([GHC version 7.6 or later is required to compile GHC.])])
141
142 if test `expr $GhcMinVersion % 2` = "1"
143 then
144     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
145     then
146         AC_MSG_ERROR([
147      $WithGhc is a development snapshot of GHC, version $GhcVersion.
148      Bootstrapping using this version of GHC is not supported, and may not
149      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
150      or --with-ghc to specify a different GHC to use.])
151     fi
152 fi
153
154 GHC_PACKAGE_DB_FLAG=package-db
155 AC_SUBST(GHC_PACKAGE_DB_FLAG)
156
157 # GHC 7.7+ needs -fcmm-sink when compiling Parser.hs. See #8182
158 FP_COMPARE_VERSIONS([$GhcVersion],[-gt],[7.7],
159                     CMM_SINK_BOOTSTRAP_IS_NEEDED=YES,
160                     CMM_SINK_BOOTSTRAP_IS_NEEDED=NO)
161 AC_SUBST(CMM_SINK_BOOTSTRAP_IS_NEEDED)
162
163 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.9],
164                     SUPPORTS_PACKAGE_KEY=NO,
165                     SUPPORTS_PACKAGE_KEY=YES)
166 AC_SUBST(SUPPORTS_PACKAGE_KEY)
167
168 # GHC is passed to Cabal, so we need a native path
169 if test "${WithGhc}" != ""
170 then
171     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
172
173     if test "$ghc_host_os" = "mingw32"
174     then
175         if test "${OSTYPE}" = "msys"
176         then
177             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
178         else
179             # Canonicalise to <drive>:/path/to/ghc
180             WithGhc=`cygpath -m "${WithGhc}"`
181         fi
182         echo "GHC path canonicalised to: ${WithGhc}"
183     fi
184 fi
185 AC_SUBST([WithGhc])
186
187 dnl ** Without optimization some INLINE trickery fails for GHCi
188 SRC_CC_OPTS="-O"
189
190 dnl--------------------------------------------------------------------
191 dnl * Choose host(/target/build) platform
192 dnl--------------------------------------------------------------------
193 dnl If we aren't explicitly told what values to use with configure flags,
194 dnl we ask the bootstrapping compiler what platform it is for
195
196 if test "${WithGhc}" != ""
197 then
198         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
199         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
200         if test "$bootstrap_host" != "$bootstrap_target"
201         then
202                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
203         fi
204 fi
205
206 # We have to run these unconditionally, but we may discard their
207 # results in the following code
208 AC_CANONICAL_BUILD
209 AC_CANONICAL_HOST
210 AC_CANONICAL_TARGET
211
212 FPTOOLS_SET_PLATFORM_VARS
213
214 # Verify that the installed (bootstrap) GHC is capable of generating
215 # code for the requested build platform.
216 if test "$BuildPlatform" != "$bootstrap_target"
217 then
218     echo "This GHC (${WithGhc}) does not generate code for the build platform"
219     echo "   GHC target platform    : $bootstrap_target"
220     echo "   Desired build platform : $BuildPlatform"
221     exit 1
222 fi
223
224 # Testing if we shall enable shared libs support on Solaris.
225 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
226
227 SOLARIS_BROKEN_SHLD=NO
228
229 case $host in
230      i386-*-solaris2)
231      # here we go with the test
232      MINOR=`uname -r|cut -d '.' -f 2-`
233      if test "$MINOR" -lt "11"; then
234          SOLARIS_BROKEN_SHLD=YES
235      fi
236      ;;
237 esac
238
239 AC_SUBST(SOLARIS_BROKEN_SHLD)
240
241 dnl ** Do an unregisterised build?
242 dnl --------------------------------------------------------------
243 case "$HostArch" in
244     i386|x86_64|powerpc|arm)
245         UnregisterisedDefault=NO
246         ;;
247     *)
248         UnregisterisedDefault=YES
249         ;;
250 esac
251 AC_ARG_ENABLE(unregisterised,
252 [AC_HELP_STRING([--enable-unregisterised],
253 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
254 [ if test x"$enableval" = x"yes"; then
255         Unregisterised=YES
256   else
257         Unregisterised=NO
258   fi
259 ],
260 [Unregisterised="$UnregisterisedDefault"]
261 )
262 AC_SUBST(Unregisterised)
263
264 AC_ARG_WITH(hc,
265 [AC_HELP_STRING([--with-hc=ARG],
266         [Use ARG as the path to the compiler for compiling ordinary
267          Haskell code  (default= value of --with-ghc)])],
268 [WithHc="$withval"],
269 [WithHc=$WithGhc]
270 )
271 AC_SUBST(WithHc)
272
273 # This uses GHC, so put it after the "GHC is required" check above:
274 FP_INTREE_GHC_PWD
275 FP_FIND_ROOT
276
277 if test "$HostOS" = "mingw32"
278 then
279     test -d inplace || mkdir inplace
280
281     if test "$HostArch" = "i386"
282     then
283         # NB. If you update the tarballs to a new version of gcc, don't
284         # forget to tweak the paths in driver/gcc/gcc.c.
285         if ! test -d inplace/mingw ||
286              test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma  ||
287              test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma  ||
288              test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma   ||
289              test inplace/mingw -ot ghc-tarballs/mingw/libgcc*.tar.gz      ||
290              test inplace/mingw -ot ghc-tarballs/mingw/libgmp*.tar.gz      ||
291              test inplace/mingw -ot ghc-tarballs/mingw/libmpc*.tar.gz      ||
292              test inplace/mingw -ot ghc-tarballs/mingw/libmpfr*.tar.gz     ||
293              test inplace/mingw -ot ghc-tarballs/mingw/libstdc*.tar.lzma   ||
294              test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dev.tar.gz ||
295              test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dll.tar.gz ||
296              test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
297         then
298             AC_MSG_NOTICE([Making in-tree mingw tree])
299             rm -rf inplace/mingw
300             mkdir inplace/mingw
301             (
302                 cd inplace/mingw &&
303                 tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma  &&
304                 tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma  &&
305                 tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma   &&
306                 tar --lzma -xf ../../ghc-tarballs/mingw/libgcc*.tar.lzma    &&
307                 tar --lzma -xf ../../ghc-tarballs/mingw/libgmp*.tar.lzma    &&
308                 tar --lzma -xf ../../ghc-tarballs/mingw/libmpc*.tar.lzma    &&
309                 tar --lzma -xf ../../ghc-tarballs/mingw/libmpfr*.tar.lzma   &&
310                 tar --lzma -xf ../../ghc-tarballs/mingw/libstdc*.tar.lzma   &&
311                 tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dev.tar.gz &&
312                 tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dll.tar.gz &&
313                 tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma    &&
314                 mv bin/gcc.exe bin/realgcc.exe
315             )
316             PATH=`pwd`/inplace/mingw/bin:$PATH inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
317             AC_MSG_NOTICE([In-tree mingw tree created])
318         fi
319     else
320         # NB. If you update the tarballs to a new version of gcc, don't
321         # forget to tweak the paths in driver/gcc/gcc.c.
322         if ! test -d inplace/mingw ||
323              test inplace/mingw -ot ghc-tarballs/mingw64/*.tar.bz2
324         then
325             AC_MSG_NOTICE([Making in-tree mingw tree])
326             rm -rf inplace/mingw
327             mkdir inplace/mingw
328             (
329                 cd inplace/mingw &&
330                 tar -jxf ../../ghc-tarballs/mingw64/*.tar.bz2
331             )
332             AC_MSG_NOTICE([In-tree mingw tree created])
333         fi
334     fi
335
336     mingwbin="$hardtop/inplace/mingw/bin/"
337     CC="${mingwbin}gcc.exe"
338     LD="${mingwbin}ld.exe"
339     NM="${mingwbin}nm.exe"
340     RANLIB="${mingwbin}ranlib.exe"
341     OBJDUMP="${mingwbin}objdump.exe"
342     fp_prog_ar="${mingwbin}ar.exe"
343
344     if ! test -d inplace/perl ||
345          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
346     then
347         AC_MSG_NOTICE([Making in-tree perl tree])
348         rm -rf inplace/perl
349         mkdir inplace/perl
350         (
351             cd inplace/perl &&
352             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
353         )
354         AC_MSG_NOTICE([In-tree perl tree created])
355     fi
356 fi
357
358 FP_ICONV
359 FP_GMP
360 FP_CURSES
361
362 XCODE_VERSION()
363
364 SplitObjsBroken=NO
365 if test "$TargetOS_CPP" = "darwin"
366 then
367     # Split objects is broken (#4013) with XCode < 3.2
368     if test "$XCodeVersion1" -lt 3
369     then
370         SplitObjsBroken=YES
371     else
372         if test "$XCodeVersion1" -eq 3
373         then
374             if test "$XCodeVersion2" -lt 2
375             then
376                 SplitObjsBroken=YES
377             fi
378         fi
379     fi
380 fi
381 AC_SUBST([SplitObjsBroken])
382
383 dnl ** Building a cross compiler?
384 dnl --------------------------------------------------------------
385 CrossCompiling=NO
386 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
387 if test "$target" != "$host" ; then
388     CrossCompiling=YES
389     cross_compiling=yes   # This tells configure that it can accept just 'target',
390                           # otherwise you get
391                           #   configure: error: cannot run C compiled programs.
392                           #   If you meant to cross compile, use `--host'.
393 fi
394 if test "$build" != "$host" ; then
395    AC_MSG_ERROR([
396 You've selected:
397
398   BUILD:  $build   (the architecture we're building on)
399   HOST:   $host    (the architecture the compiler we're building will execute on)
400   TARGET: $target  (the architecture the compiler we're building will produce code for)
401
402 BUILD must equal HOST; that is, we do not support building GHC itself
403 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
404 1 will be a cross-compiler, and stage 2 will be the cross-compiled
405 GHC.
406 ])
407 fi
408 if test "$CrossCompiling" = "YES"
409 then
410   CrossCompilePrefix="${target}-"
411 else
412   CrossCompilePrefix=""
413 fi
414 TargetPlatformFull="${target}"
415 AC_SUBST(CrossCompiling)
416 AC_SUBST(CrossCompilePrefix)
417 AC_SUBST(TargetPlatformFull)
418
419 dnl ** Which gcc to use?
420 dnl --------------------------------------------------------------
421 FIND_GCC([WhatGccIsCalled], [gcc], [gcc])
422 CC="$WhatGccIsCalled"
423 export CC
424
425 # If --with-gcc was used, and we're not cross-compiling, then it also
426 # applies to the stage0 compiler.
427 MAYBE_OVERRIDE_STAGE0([gcc],[CC_STAGE0])
428 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
429
430 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
431 AC_PROG_CPP
432
433 # --with-hs-cpp/--with-hs-cpp-flags
434 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
435 AC_SUBST([HaskellCPPCmd])
436 AC_SUBST([HaskellCPPArgs])
437
438 dnl ** Which ld to use?
439 dnl --------------------------------------------------------------
440 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld], [ld])
441 case $target in
442 arm*linux*)
443         # Arm requires use of the binutils ld.gold linker.
444         # This case should catch at least arm-unknown-linux-gnueabihf and
445         # arm-linux-androideabi.
446         FP_ARG_WITH_PATH_GNU_PROG([LD_GOLD], [ld.gold], [ld.gold])
447         LdCmd="$LD_GOLD"
448         ;;
449 *)
450         LdCmd="$LD"
451         ;;
452 esac
453 AC_SUBST([LdCmd])
454
455 dnl ** Which nm to use?
456 dnl --------------------------------------------------------------
457 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
458 NmCmd="$NM"
459 AC_SUBST([NmCmd])
460
461 dnl ** Which ar to use?
462 dnl --------------------------------------------------------------
463 FP_ARG_WITH_PATH_GNU_PROG([AR], [ar], [ar])
464 ArCmd="$AR"
465 fp_prog_ar="$AR"
466 AC_SUBST([ArCmd])
467
468 dnl ** Which ranlib to use?
469 dnl --------------------------------------------------------------
470 FP_ARG_WITH_PATH_GNU_PROG([RANLIB], [ranlib], [ranlib])
471 RanlibCmd="$RANLIB"
472 RANLIB="$RanlibCmd"
473
474
475 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
476 case $HostOS_CPP in
477 cygwin32|mingw32)
478     dnl ** Which objdump to use?
479     dnl --------------------------------------------------------------
480     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
481     ObjdumpCmd="$OBJDUMP"
482     AC_SUBST([ObjdumpCmd])
483     ;;
484 esac
485
486 # Here is where we re-target which specific version of the LLVM
487 # tools we are looking for. In the past, GHC supported a number of
488 # versions of LLVM simultaneously, but that stopped working around
489 # 3.5/3.6 release of LLVM.
490 llvm_version=3.6
491
492 dnl ** Which LLVM llc to use?
493 dnl --------------------------------------------------------------
494 FIND_LLVM_PROG([LLC], [llc], [llc], [$llvm_version])
495 LlcCmd="$LLC"
496 AC_SUBST([LlcCmd])
497
498 dnl ** Which LLVM opt to use?
499 dnl --------------------------------------------------------------
500 FIND_LLVM_PROG([OPT], [opt], [opt], [$llvm_version])
501 OptCmd="$OPT"
502 AC_SUBST([OptCmd])
503
504 dnl --------------------------------------------------------------
505 dnl End of configure script option section
506 dnl --------------------------------------------------------------
507
508
509 dnl --------------------------------------------------------------
510 dnl * General configuration checks
511 dnl --------------------------------------------------------------
512
513 dnl ** Bug 9439: Some GHC 7.8 releases had broken LLVM code generator.
514 dnl Unfortunately we don't know whether the user is going to request a
515 dnl build with the LLVM backend as this is only given in build.mk.
516 dnl
517 dnl Instead, we try to do as much work as possible here, checking
518 dnl whether -fllvm is the stage 0 compiler's default. If so we
519 dnl fail. If not, we check whether -fllvm is affected explicitly and
520 dnl if so set a flag. The build system will later check this flag
521 dnl after the desired build flags are known.
522
523 dnl This problem is further complicated by the fact that the llvm
524 dnl version used by the bootstrap compiler may be different from the
525 dnl version we arre trying to compile GHC against. Therefore, we need
526 dnl to find the boostrap compiler's `settings` file then check to see
527 dnl if the `opt` and `llc` command strings are non-empty and if these
528 dnl programs exist. Only if they exist to we test for bug #9439.
529
530 FIND_GHC_BOOTSTRAP_PROG([BootstrapLlcCmd], [${WithGhc}], "LLVM llc command")
531 FIND_GHC_BOOTSTRAP_PROG([BootstrapOptCmd], [${WithGhc}], "LLVM opt command")
532
533 if test -n "$BootstrapLlcCmd" && test -n "$BootstrapOptCmd"
534 then
535     AC_MSG_CHECKING(whether bootstrap compiler is affected by bug 9439)
536     echo "main = putStrLn \"%function\"" > conftestghc.hs
537
538     # Check whether LLVM backend is default for this platform
539     "${WithGhc}" -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" conftestghc.hs 2>&1 >/dev/null
540     res=`./conftestghc`
541     if test "x$res" = "x%object"
542     then
543         AC_MSG_RESULT(yes)
544         echo "Buggy bootstrap compiler"
545         echo ""
546         echo "The stage 0 compiler $WithGhc is affected by GHC Bug \#9439"
547         echo "and therefore will miscompile the LLVM backend if -fllvm is"
548         echo "used."
549         echo
550         echo "Please use another bootstrap compiler"
551         exit 1
552     fi
553
554     # -fllvm is not the default, but set a flag so the Makefile can check
555     # -for it in the build flags later on
556     "${WithGhc}" -fforce-recomp -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" -fllvm conftestghc.hs 2>&1 >/dev/null
557     if test $? = 0
558     then
559         res=`./conftestghc`
560         if test "x$res" = "x%object"
561         then
562             AC_MSG_RESULT(yes)
563             GHC_LLVM_AFFECTED_BY_9439=1
564         elif test "x$res" = "x%function"
565         then
566             AC_MSG_RESULT(no)
567             GHC_LLVM_AFFECTED_BY_9439=0
568         else
569             AC_MSG_WARN(unexpected output $res)
570         fi
571     else
572         AC_MSG_RESULT(failed to compile, assuming no)
573     fi
574 fi
575 AC_SUBST([GHC_LLVM_AFFECTED_BY_9439])
576
577 dnl ** Can the unix package be built?
578 dnl --------------------------------------------------------------
579
580 if test "$TargetOS" = "mingw32"
581 then
582     GhcLibsWithUnix=NO
583 else
584     GhcLibsWithUnix=YES
585 fi
586 AC_SUBST([GhcLibsWithUnix])
587
588 dnl ** does #! work?
589 AC_SYS_INTERPRETER()
590
591 dnl ** look for `perl'
592 case $HostOS_CPP in
593 cygwin32|mingw32)
594     PerlCmd=$hardtop/inplace/perl/perl
595     ;;
596 *)
597     AC_PATH_PROG(PerlCmd,perl)
598     if test -z "$PerlCmd"
599     then
600         echo "You must install perl before you can continue"
601         echo "Perhaps it is already installed, but not in your PATH?"
602         exit 1
603     else
604         FPTOOLS_CHECK_PERL_VERSION
605     fi
606     ;;
607 esac
608
609 dnl ** look for GCC and find out which version
610 dnl     Figure out which C compiler to use.  Gcc is preferred.
611 dnl     If gcc, make sure it's at least 3.0
612 dnl
613 FP_GCC_VERSION
614
615 dnl ** look to see if we have a C compiler using an llvm back end.
616 dnl
617 FP_CC_LLVM_BACKEND
618
619 FP_PROG_LD_IS_GNU
620 FP_PROG_LD_BUILD_ID
621 FP_PROG_LD_NO_COMPACT_UNWIND
622 FP_PROG_LD_FILELIST
623
624
625 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
626 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
627 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
628 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
629 # Stage 3 won't be supported by cross-compilation
630
631 FP_GCC_EXTRA_FLAGS
632
633 AC_SUBST(CONF_CC_OPTS_STAGE0)
634 AC_SUBST(CONF_CC_OPTS_STAGE1)
635 AC_SUBST(CONF_CC_OPTS_STAGE2)
636 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
637 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
638 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
639 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
640 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
641 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
642 AC_SUBST(CONF_CPP_OPTS_STAGE0)
643 AC_SUBST(CONF_CPP_OPTS_STAGE1)
644 AC_SUBST(CONF_CPP_OPTS_STAGE2)
645
646 dnl ** Set up the variables for the platform in the settings file.
647 dnl May need to use gcc to find platform details.
648 dnl --------------------------------------------------------------
649 FPTOOLS_SET_HASKELL_PLATFORM_VARS
650
651 dnl ** figure out how to do context diffs
652 FP_PROG_CONTEXT_DIFF
653
654 dnl Let's make sure install-sh is executable here.  If we got it from
655 dnl a darcs repo, it might not be (see bug #978).
656 chmod +x install-sh
657 dnl ** figure out how to do a BSD-ish install
658 AC_PROG_INSTALL
659
660 dnl ** how to invoke `ar' and `ranlib'
661 FP_PROG_AR_SUPPORTS_ATFILE
662 FP_PROG_AR_NEEDS_RANLIB
663
664 dnl ** Check to see whether ln -s works
665 AC_PROG_LN_S
666
667 FP_SETTINGS
668
669 dnl ** Find the path to sed
670 AC_PATH_PROGS(SedCmd,gsed sed,sed)
671
672
673 dnl ** check for time command
674 AC_PATH_PROG(TimeCmd,time)
675
676 dnl ** check for tar
677 dnl   if GNU tar is named gtar, look for it first.
678 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
679
680 dnl ** check for patch
681 dnl if GNU patch is named gpatch, look for it first
682 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
683
684 dnl ** check for dtrace (currently only implemented for Mac OS X)
685 HaveDtrace=NO
686 AC_PATH_PROG(DtraceCmd,dtrace)
687 if test -n "$DtraceCmd"; then
688   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
689     HaveDtrace=YES
690   fi
691 fi
692 AC_SUBST(HaveDtrace)
693
694 AC_PATH_PROG(HSCOLOUR,HsColour)
695 # HsColour is passed to Cabal, so we need a native path
696 if test "$HostOS"      = "mingw32" && \
697    test "${OSTYPE}"   != "msys"    && \
698    test "${HSCOLOUR}" != ""
699 then
700     # Canonicalise to <drive>:/path/to/gcc
701     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
702 fi
703
704 dnl ** check for DocBook toolchain
705 FP_CHECK_DOCBOOK_DTD
706 FP_DOCBOOK_XSL
707 FP_PROG_DBLATEX
708
709 dnl ** check for ghc-pkg command
710 FP_PROG_GHC_PKG
711
712 dnl ** check for installed happy binary + version
713 FPTOOLS_HAPPY
714
715 dnl ** check for installed alex binary + version
716 FPTOOLS_ALEX
717
718 dnl --------------------------------------------------
719 dnl ### program checking section ends here ###
720 dnl --------------------------------------------------
721
722 dnl --------------------------------------------------
723 dnl * Platform header file and syscall feature tests
724 dnl ### checking the state of the local header files and syscalls ###
725
726 dnl ** check for full ANSI header (.h) files
727 AC_HEADER_STDC
728
729 dnl ** Enable large file support.  NB. do this before testing the type of
730 dnl    off_t, because it will affect the result of that test.
731 AC_SYS_LARGEFILE
732
733 dnl ** check for specific header (.h) files that we are interested in
734 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
735
736 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
737 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
738 [[#if HAVE_SYS_PARAM_H
739 # include <sys/param.h>
740 #endif
741 ]])
742
743 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
744 AC_HEADER_TIME
745
746 dnl ** do we have long longs?
747 AC_CHECK_TYPES([long long])
748
749 dnl ** what are the sizes of various types
750 AC_CHECK_SIZEOF(char,               1)
751 AC_CHECK_SIZEOF(double,             8)
752 AC_CHECK_SIZEOF(float,              4)
753 AC_CHECK_SIZEOF(int,                4)
754 AC_CHECK_SIZEOF(long,               4)
755 if test "$ac_cv_type_long_long" = yes; then
756 AC_CHECK_SIZEOF(long long,          8)
757 fi
758 AC_CHECK_SIZEOF(short,              2)
759 AC_CHECK_SIZEOF(unsigned char,      1)
760 AC_CHECK_SIZEOF(unsigned int,       4)
761 AC_CHECK_SIZEOF(unsigned long,      4)
762 if test "$ac_cv_type_long_long" = yes; then
763 AC_CHECK_SIZEOF(unsigned long long, 8)
764 fi
765 AC_CHECK_SIZEOF(unsigned short,     2)
766 AC_CHECK_SIZEOF(void *,             4)
767
768 dnl for use in settings.in
769 WordSize=$ac_cv_sizeof_void_p
770 AC_SUBST(WordSize)
771
772 dnl ** what are alignment constraints on various types
773 FP_CHECK_ALIGNMENT(char)
774 FP_CHECK_ALIGNMENT(double)
775 FP_CHECK_ALIGNMENT(float)
776 FP_CHECK_ALIGNMENT(int)
777 FP_CHECK_ALIGNMENT(long)
778 if test "$ac_cv_type_long_long" = yes; then
779 FP_CHECK_ALIGNMENT(long long)
780 fi
781 FP_CHECK_ALIGNMENT(short)
782 FP_CHECK_ALIGNMENT(unsigned char)
783 FP_CHECK_ALIGNMENT(unsigned int)
784 FP_CHECK_ALIGNMENT(unsigned long)
785 if test "$ac_cv_type_long_long" = yes; then
786 FP_CHECK_ALIGNMENT(unsigned long long)
787 fi
788 FP_CHECK_ALIGNMENT(unsigned short)
789 FP_CHECK_ALIGNMENT(void *)
790
791 FP_CHECK_FUNC([WinExec],
792   [@%:@include <windows.h>], [WinExec("",0)])
793
794 FP_CHECK_FUNC([GetModuleFileName],
795   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
796
797 dnl ** check for more functions
798 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
799 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
800
801 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
802 dnl ** _POSIX_C_SOURCE is defined
803 AC_CHECK_DECLS([ctime_r], , ,
804 [#define _POSIX_SOURCE 1
805 #define _POSIX_C_SOURCE 199506L
806 #include <time.h>])
807
808 dnl ** check for mingwex library
809 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
810 AC_SUBST(HaveLibMingwEx)
811
812 if test $HaveLibMingwEx = YES ; then
813   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
814 fi
815
816 dnl ** check for math library
817 dnl    Keep that check as early as possible.
818 dnl    as we need to know whether we need libm
819 dnl    for math functions or not
820 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
821 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
822 if test $HaveLibM = YES
823 then
824   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
825 fi
826
827 FP_BFD_SUPPORT
828
829 dnl ################################################################
830 dnl Check for libraries
831 dnl ################################################################
832
833 # system libffi
834
835 AC_ARG_WITH([system-libffi],
836 [AC_HELP_STRING([--with-system-libffi],
837   [Use system provided libffi for RTS [default=no]])
838 ])
839
840 AS_IF([test "x$with_system_libffi" = "xyes"],
841   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
842 )
843
844
845 AC_SUBST(UseSystemLibFFI)
846
847 AC_ARG_WITH([ffi-includes],
848 [AC_HELP_STRING([--with-ffi-includes=ARG],
849   [Find includes for libffi in ARG [default=system default]])
850 ],
851 [
852  if test "x$UseSystemLibFFI" != "xYES"; then
853     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
854  else
855     FFIIncludeDir="$withval"
856     LIBFFI_CFLAGS="-I$withval"
857  fi
858 ])
859
860 AC_SUBST(FFIIncludeDir)
861
862 AC_ARG_WITH([ffi-libraries],
863 [AC_HELP_STRING([--with-ffi-libraries=ARG],
864   [Find libffi in ARG [default=system default]])
865 ],
866 [
867  if test "x$UseSystemLibFFI" != "xYES"; then
868     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
869  else
870     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
871  fi
872 ])
873
874 AC_SUBST(FFILibDir)
875
876 AS_IF([test "$UseSystemLibFFI" = "YES"], [
877  CFLAGS2="$CFLAGS"
878  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
879  LDFLAGS2="$LDFLAGS"
880  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
881  AC_CHECK_LIB(ffi, ffi_call,
882   [AC_CHECK_HEADERS([ffi.h], [break], [])
883    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
884   [AC_MSG_ERROR([Cannot find system libffi])])
885  CFLAGS="$CFLAGS2"
886  LDFLAGS="$LDFLAGS2"
887 ])
888
889 dnl ** check whether we need -ldl to get dlopen()
890 AC_CHECK_LIB(dl, dlopen)
891
892 dnl --------------------------------------------------
893 dnl * Miscellaneous feature tests
894 dnl --------------------------------------------------
895
896 dnl ** can we get alloca?
897 AC_FUNC_ALLOCA
898
899 dnl ** working vfork?
900 AC_FUNC_FORK
901
902 dnl ** determine whether or not const works
903 AC_C_CONST
904
905 dnl ** are we big endian?
906 AC_C_BIGENDIAN
907 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
908
909 dnl ** check for leading underscores in symbol names
910 FP_LEADING_UNDERSCORE
911
912 FP_VISIBILITY_HIDDEN
913
914 dnl ** check for librt
915 AC_CHECK_LIB(rt, clock_gettime)
916 AC_CHECK_FUNCS(clock_gettime timer_settime)
917 FP_CHECK_TIMER_CREATE
918
919 dnl ** check for Apple's "interesting" long double compatibility scheme
920 AC_MSG_CHECKING(for printf\$LDBLStub)
921 AC_TRY_LINK_FUNC(printf\$LDBLStub,
922     [
923         AC_MSG_RESULT(yes)
924         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
925             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
926     ],
927     [
928         AC_MSG_RESULT(no)
929         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
930             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
931     ])
932
933 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
934 dnl    a different single-argument version.
935 AC_CHECK_LIB(pthread, pthread_setname_np)
936 AC_MSG_CHECKING(for pthread_setname_np)
937 AC_TRY_LINK(
938 [
939 #define _GNU_SOURCE
940 #include <pthread.h>
941 ],
942 [pthread_setname_np(pthread_self(), "name");],
943     AC_MSG_RESULT(yes)
944     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
945       [Define to 1 if you have the glibc version of pthread_setname_np]),
946     AC_MSG_RESULT(no)
947 )
948
949 dnl ** check for eventfd which is needed by the I/O manager
950 AC_CHECK_HEADERS([sys/eventfd.h])
951 AC_CHECK_FUNCS([eventfd])
952
953 dnl ** Check for __thread support in the compiler
954 AC_MSG_CHECKING(for __thread support)
955 AC_COMPILE_IFELSE(
956   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
957   [
958    AC_MSG_RESULT(yes)
959    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
960   ],
961   [
962    AC_MSG_RESULT(no)
963    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
964   ])
965
966
967 dnl ** checking for PAPI
968 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
969 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
970 AC_SUBST(HavePapiLib)
971 AC_SUBST(HavePapiHeader)
972
973 AC_CHECK_FUNCS(__mingw_vfprintf)
974
975 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
976    HavePapi=YES
977 else
978    HavePapi=NO
979 fi
980 AC_SUBST(HavePapi)
981
982 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
983    test "$XsltprocCmd" = ""
984 then
985     BUILD_DOCBOOK_HTML=NO
986 else
987     BUILD_DOCBOOK_HTML=YES
988 fi
989 AC_SUBST(BUILD_DOCBOOK_HTML)
990
991 if test "$DblatexCmd" = ""
992 then
993     BUILD_DOCBOOK_PS=NO
994     BUILD_DOCBOOK_PDF=NO
995 else
996     BUILD_DOCBOOK_PS=YES
997     BUILD_DOCBOOK_PDF=YES
998 fi
999 AC_SUBST(BUILD_DOCBOOK_PS)
1000 AC_SUBST(BUILD_DOCBOOK_PDF)
1001
1002 LIBRARY_VERSION(base)
1003 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1004 LIBRARY_VERSION(ghc-prim)
1005 LIBRARY_ghc_VERSION="$ProjectVersion"
1006 AC_SUBST(LIBRARY_ghc_VERSION)
1007
1008 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1009    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1010 fi
1011
1012 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal settings docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/configure.ac])
1013 AC_OUTPUT
1014
1015 # We got caught by
1016 #     http://savannah.gnu.org/bugs/index.php?1516
1017 #     $(eval ...) inside conditionals causes errors
1018 # with make 3.80, so warn the user if it looks like they're about to
1019 # try to use it.
1020 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1021 checkMake380() {
1022     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
1023     then
1024         echo
1025         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
1026         echo "This version cannot be used to build GHC."
1027         echo "Please use GNU make >= 3.81."
1028     fi
1029 }
1030
1031 checkMake380 make
1032 checkMake380 gmake
1033
1034 echo ["
1035 ----------------------------------------------------------------------
1036 Configure completed successfully.
1037
1038    Building GHC version  : $ProjectVersion
1039           Git commit id  : $ProjectGitCommitId
1040
1041    Build platform        : $BuildPlatform
1042    Host platform         : $HostPlatform
1043    Target platform       : $TargetPlatform
1044 "]
1045
1046 echo ["\
1047    Bootstrapping using   : $WithGhc
1048       which is version   : $GhcVersion
1049 "]
1050
1051 if test "x$CC_LLVM_BACKEND" = "x1"; then
1052     if test "x$CC_CLANG_BACKEND" = "x1"; then
1053         CompilerName="clang        "
1054     else
1055         CompilerName="llvm-gcc     "
1056     fi
1057 else
1058     CompilerName="gcc          "
1059 fi
1060
1061 echo ["\
1062    Using $CompilerName       : $WhatGccIsCalled
1063       which is version       : $GccVersion
1064    Building a cross compiler : $CrossCompiling
1065    hs-cpp       : $HaskellCPPCmd
1066    hs-cpp-flags : $HaskellCPPArgs
1067    ld           : $LdCmd
1068    Happy        : $HappyCmd ($HappyVersion)
1069    Alex         : $AlexCmd ($AlexVersion)
1070    Perl         : $PerlCmd
1071    dblatex      : $DblatexCmd
1072    xsltproc     : $XsltprocCmd
1073
1074    Using LLVM tools
1075       llc   : $LlcCmd
1076       opt   : $OptCmd"]
1077
1078 if test "$HSCOLOUR" = ""; then
1079 echo ["
1080    HsColour was not found; documentation will not contain source links
1081 "]
1082 else
1083 echo ["\
1084    HsColour : $HSCOLOUR
1085 "]
1086 fi
1087
1088 echo ["\
1089    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
1090    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
1091    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
1092
1093 echo ["----------------------------------------------------------------------
1094 "]
1095
1096 echo "\
1097 For a standard build of GHC (fully optimised with profiling), type (g)make.
1098
1099 To make changes to the default build configuration, copy the file
1100 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1101
1102 For more information on how to configure your GHC build, see
1103    http://ghc.haskell.org/trac/ghc/wiki/Building
1104 "