Vectoriser gets all DPH library identifiers from Data.Array.Parallel.Prim
[ghc.git] / compiler / main / TidyPgm.lhs
1
2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
3 %
4 \section{Tidying up Core}
5
6 \begin{code}
7 module TidyPgm (
8        mkBootModDetailsTc, tidyProgram, globaliseAndTidyId
9    ) where
10
11 #include "HsVersions.h"
12
13 import TcRnTypes
14 import DynFlags
15 import CoreSyn
16 import CoreUnfold
17 import CoreFVs
18 import CoreTidy
19 import CoreMonad
20 import CoreUtils
21 import Literal
22 import Rules
23 import CoreArity        ( exprArity, exprBotStrictness_maybe )
24 import VarEnv
25 import VarSet
26 import Var
27 import Id
28 import IdInfo
29 import InstEnv
30 import FamInstEnv
31 import Demand
32 import BasicTypes
33 import Name hiding (varName)
34 import NameSet
35 import NameEnv
36 import Avail
37 import IfaceEnv
38 import TcType
39 import DataCon
40 import TyCon
41 import Class
42 import Module
43 import Packages( isDllName )
44 import HscTypes
45 import Maybes
46 import UniqSupply
47 import Outputable
48 import FastBool hiding ( fastOr )
49 import Util
50 import FastString
51
52 import Control.Monad    ( when )
53 import Data.List        ( sortBy )
54 import Data.IORef       ( IORef, readIORef, writeIORef )
55 \end{code}
56
57
58 Constructing the TypeEnv, Instances, Rules, VectInfo from which the
59 ModIface is constructed, and which goes on to subsequent modules in
60 --make mode.
61
62 Most of the interface file is obtained simply by serialising the
63 TypeEnv.  One important consequence is that if the *interface file*
64 has pragma info if and only if the final TypeEnv does. This is not so
65 important for *this* module, but it's essential for ghc --make:
66 subsequent compilations must not see (e.g.) the arity if the interface
67 file does not contain arity If they do, they'll exploit the arity;
68 then the arity might change, but the iface file doesn't change =>
69 recompilation does not happen => disaster. 
70
71 For data types, the final TypeEnv will have a TyThing for the TyCon,
72 plus one for each DataCon; the interface file will contain just one
73 data type declaration, but it is de-serialised back into a collection
74 of TyThings.
75
76 %************************************************************************
77 %*                                                                      *
78                 Plan A: simpleTidyPgm
79 %*                                                                      * 
80 %************************************************************************
81
82
83 Plan A: mkBootModDetails: omit pragmas, make interfaces small
84 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
85 * Ignore the bindings
86
87 * Drop all WiredIn things from the TypeEnv 
88         (we never want them in interface files)
89
90 * Retain all TyCons and Classes in the TypeEnv, to avoid
91         having to find which ones are mentioned in the
92         types of exported Ids
93
94 * Trim off the constructors of non-exported TyCons, both
95         from the TyCon and from the TypeEnv
96
97 * Drop non-exported Ids from the TypeEnv
98
99 * Tidy the types of the DFunIds of Instances, 
100   make them into GlobalIds, (they already have External Names)
101   and add them to the TypeEnv
102
103 * Tidy the types of the (exported) Ids in the TypeEnv,
104   make them into GlobalIds (they already have External Names)
105
106 * Drop rules altogether
107
108 * Tidy the bindings, to ensure that the Caf and Arity
109   information is correct for each top-level binder; the 
110   code generator needs it. And to ensure that local names have
111   distinct OccNames in case of object-file splitting
112
113 \begin{code}
114 -- This is Plan A: make a small type env when typechecking only,
115 -- or when compiling a hs-boot file, or simply when not using -O
116 --
117 -- We don't look at the bindings at all -- there aren't any
118 -- for hs-boot files
119
120 mkBootModDetailsTc :: HscEnv -> TcGblEnv -> IO ModDetails
121 mkBootModDetailsTc hsc_env 
122         TcGblEnv{ tcg_exports   = exports,
123                   tcg_type_env  = type_env, -- just for the Ids
124                   tcg_tcs       = tcs,
125                   tcg_clss      = clss,
126                   tcg_insts     = insts,
127                   tcg_fam_insts = fam_insts
128                 }
129   = do  { let dflags = hsc_dflags hsc_env
130         ; showPass dflags CoreTidy
131
132         ; let { insts'     = tidyInstances globaliseAndTidyId insts
133               ; dfun_ids   = map instanceDFunId insts'
134               ; type_env1  = mkBootTypeEnv (availsToNameSet exports)
135                                 (typeEnvIds type_env) tcs clss fam_insts
136               ; type_env'  = extendTypeEnvWithIds type_env1 dfun_ids
137               }
138         ; return (ModDetails { md_types     = type_env'
139                              , md_insts     = insts'
140                              , md_fam_insts = fam_insts
141                              , md_rules     = []
142                              , md_anns      = []
143                              , md_exports   = exports
144                              , md_vect_info = noVectInfo
145                              })
146         }
147   where
148
149 mkBootTypeEnv :: NameSet -> [Id] -> [TyCon] -> [Class] -> [FamInst] -> TypeEnv
150 mkBootTypeEnv exports ids tcs clss fam_insts
151   = tidyTypeEnv True False exports $
152        typeEnvFromEntities final_ids tcs clss fam_insts
153   where
154         -- Find the LocalIds in the type env that are exported
155         -- Make them into GlobalIds, and tidy their types
156         --
157         -- It's very important to remove the non-exported ones
158         -- because we don't tidy the OccNames, and if we don't remove
159         -- the non-exported ones we'll get many things with the
160         -- same name in the interface file, giving chaos.
161         --
162         -- Do make sure that we keep Ids that are already Global.
163         -- When typechecking an .hs-boot file, the Ids come through as
164         -- GlobalIds.
165     final_ids = [ if isLocalId id then globaliseAndTidyId id
166                                   else id
167                 | id <- ids
168                 , keep_it id ]
169
170         -- default methods have their export flag set, but everything
171         -- else doesn't (yet), because this is pre-desugaring, so we
172         -- must test both.
173     keep_it id = isExportedId id || idName id `elemNameSet` exports
174
175
176
177 globaliseAndTidyId :: Id -> Id
178 -- Takes an LocalId with an External Name, 
179 -- makes it into a GlobalId 
180 --     * unchanged Name (might be Internal or External)
181 --     * unchanged details
182 --     * VanillaIdInfo (makes a conservative assumption about Caf-hood)
183 globaliseAndTidyId id   
184   = Id.setIdType (globaliseId id) tidy_type
185   where
186     tidy_type = tidyTopType (idType id)
187 \end{code}
188
189
190 %************************************************************************
191 %*                                                                      *
192         Plan B: tidy bindings, make TypeEnv full of IdInfo
193 %*                                                                      * 
194 %************************************************************************
195
196 Plan B: include pragmas, make interfaces 
197 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
198 * Figure out which Ids are externally visible
199
200 * Tidy the bindings, externalising appropriate Ids
201
202 * Drop all Ids from the TypeEnv, and add all the External Ids from 
203   the bindings.  (This adds their IdInfo to the TypeEnv; and adds
204   floated-out Ids that weren't even in the TypeEnv before.)
205
206 Step 1: Figure out external Ids
207 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
208 Note [choosing external names]
209
210 See also the section "Interface stability" in the
211 RecompilationAvoidance commentary:
212   http://hackage.haskell.org/trac/ghc/wiki/Commentary/Compiler/RecompilationAvoidance
213
214 First we figure out which Ids are "external" Ids.  An
215 "external" Id is one that is visible from outside the compilation
216 unit.  These are
217   a) the user exported ones
218   b) ones mentioned in the unfoldings, workers, 
219      rules of externally-visible ones ,
220      or vectorised versions of externally-visible ones
221
222 While figuring out which Ids are external, we pick a "tidy" OccName
223 for each one.  That is, we make its OccName distinct from the other
224 external OccNames in this module, so that in interface files and
225 object code we can refer to it unambiguously by its OccName.  The
226 OccName for each binder is prefixed by the name of the exported Id
227 that references it; e.g. if "f" references "x" in its unfolding, then
228 "x" is renamed to "f_x".  This helps distinguish the different "x"s
229 from each other, and means that if "f" is later removed, things that
230 depend on the other "x"s will not need to be recompiled.  Of course,
231 if there are multiple "f_x"s, then we have to disambiguate somehow; we
232 use "f_x0", "f_x1" etc.
233
234 As far as possible we should assign names in a deterministic fashion.
235 Each time this module is compiled with the same options, we should end
236 up with the same set of external names with the same types.  That is,
237 the ABI hash in the interface should not change.  This turns out to be
238 quite tricky, since the order of the bindings going into the tidy
239 phase is already non-deterministic, as it is based on the ordering of
240 Uniques, which are assigned unpredictably.
241
242 To name things in a stable way, we do a depth-first-search of the
243 bindings, starting from the exports sorted by name.  This way, as long
244 as the bindings themselves are deterministic (they sometimes aren't!),
245 the order in which they are presented to the tidying phase does not
246 affect the names we assign.
247
248 Step 2: Tidy the program
249 ~~~~~~~~~~~~~~~~~~~~~~~~
250 Next we traverse the bindings top to bottom.  For each *top-level*
251 binder
252
253  1. Make it into a GlobalId; its IdDetails becomes VanillaGlobal, 
254     reflecting the fact that from now on we regard it as a global, 
255     not local, Id
256
257  2. Give it a system-wide Unique.
258     [Even non-exported things need system-wide Uniques because the
259     byte-code generator builds a single Name->BCO symbol table.]
260
261     We use the NameCache kept in the HscEnv as the
262     source of such system-wide uniques.
263
264     For external Ids, use the original-name cache in the NameCache
265     to ensure that the unique assigned is the same as the Id had 
266     in any previous compilation run.
267
268  3. Rename top-level Ids according to the names we chose in step 1.
269     If it's an external Id, make it have a External Name, otherwise
270     make it have an Internal Name.  This is used by the code generator
271     to decide whether to make the label externally visible
272
273  4. Give it its UTTERLY FINAL IdInfo; in ptic, 
274         * its unfolding, if it should have one
275         
276         * its arity, computed from the number of visible lambdas
277
278         * its CAF info, computed from what is free in its RHS
279
280                 
281 Finally, substitute these new top-level binders consistently
282 throughout, including in unfoldings.  We also tidy binders in
283 RHSs, so that they print nicely in interfaces.
284
285 \begin{code}
286 tidyProgram :: HscEnv -> ModGuts -> IO (CgGuts, ModDetails)
287 tidyProgram hsc_env  (ModGuts { mg_module    = mod
288                               , mg_exports   = exports
289                               , mg_tcs       = tcs
290                               , mg_clss      = clss
291                               , mg_insts     = insts
292                               , mg_fam_insts = fam_insts
293                               , mg_binds     = binds
294                               , mg_rules     = imp_rules
295                               , mg_vect_info = vect_info
296                               , mg_anns      = anns
297                               , mg_deps      = deps 
298                               , mg_foreign   = foreign_stubs
299                               , mg_hpc_info  = hpc_info
300                               , mg_modBreaks = modBreaks 
301                               })
302
303   = do  { let { dflags     = hsc_dflags hsc_env
304               ; omit_prags = dopt Opt_OmitInterfacePragmas dflags
305               ; expose_all = dopt Opt_ExposeAllUnfoldings  dflags
306               ; th         = xopt Opt_TemplateHaskell      dflags
307               }
308         ; showPass dflags CoreTidy
309
310         ; let { type_env = typeEnvFromEntities [] tcs clss fam_insts
311
312               ; implicit_binds
313                   = concatMap getClassImplicitBinds (typeEnvClasses type_env) ++
314                     concatMap getTyConImplicitBinds (typeEnvTyCons type_env)
315               }
316
317         ; (unfold_env, tidy_occ_env)
318               <- chooseExternalIds hsc_env mod omit_prags expose_all 
319                                    binds implicit_binds imp_rules (vectInfoVar vect_info)
320         ; let { ext_rules = findExternalRules omit_prags binds imp_rules unfold_env }
321                 -- Glom together imp_rules and rules currently attached to binders
322                 -- Then pick just the ones we need to expose
323                 -- See Note [Which rules to expose]
324
325         ; let { (tidy_env, tidy_binds)
326                  = tidyTopBinds hsc_env unfold_env tidy_occ_env binds }
327
328         ; let { export_set = availsToNameSet exports
329               ; final_ids  = [ id | id <- bindersOfBinds tidy_binds, 
330                                     isExternalName (idName id)]
331
332               ; tidy_type_env = tidyTypeEnv omit_prags th export_set
333                                       (extendTypeEnvWithIds type_env final_ids)
334
335               ; tidy_insts    = tidyInstances (lookup_dfun tidy_type_env) insts
336                 -- A DFunId will have a binding in tidy_binds, and so
337                 -- will now be in final_env, replete with IdInfo
338                 -- Its name will be unchanged since it was born, but
339                 -- we want Global, IdInfo-rich (or not) DFunId in the
340                 -- tidy_insts
341
342               ; tidy_rules = tidyRules tidy_env ext_rules
343                 -- You might worry that the tidy_env contains IdInfo-rich stuff
344                 -- and indeed it does, but if omit_prags is on, ext_rules is
345                 -- empty
346
347               ; tidy_vect_info = tidyVectInfo tidy_env vect_info
348
349               -- See Note [Injecting implicit bindings]
350               ; all_tidy_binds = implicit_binds ++ tidy_binds
351
352               -- get the TyCons to generate code for.  Careful!  We must use
353               -- the untidied TypeEnv here, because we need
354               --  (a) implicit TyCons arising from types and classes defined
355               --      in this module
356               --  (b) wired-in TyCons, which are normally removed from the
357               --      TypeEnv we put in the ModDetails
358               --  (c) Constructors even if they are not exported (the
359               --      tidied TypeEnv has trimmed these away)
360               ; alg_tycons = filter isAlgTyCon (typeEnvTyCons type_env)
361               }
362
363         ; endPass dflags CoreTidy all_tidy_binds tidy_rules
364
365           -- If the endPass didn't print the rules, but ddump-rules is
366           -- on, print now
367         ; dumpIfSet (dopt Opt_D_dump_rules dflags 
368                      && (not (dopt Opt_D_dump_simpl dflags))) 
369                     CoreTidy
370                     (ptext (sLit "rules"))
371                     (pprRulesForUser tidy_rules)
372
373           -- Print one-line size info
374         ; let cs = coreBindsStats tidy_binds
375         ; when (dopt Opt_D_dump_core_stats dflags)
376                (printDump (ptext (sLit "Tidy size (terms,types,coercions)") 
377                            <+> ppr (moduleName mod) <> colon 
378                            <+> int (cs_tm cs) 
379                            <+> int (cs_ty cs) 
380                            <+> int (cs_co cs) ))
381
382         ; return (CgGuts { cg_module   = mod,
383                            cg_tycons   = alg_tycons,
384                            cg_binds    = all_tidy_binds,
385                            cg_foreign  = foreign_stubs,
386                            cg_dep_pkgs = map fst $ dep_pkgs deps,
387                            cg_hpc_info = hpc_info,
388                            cg_modBreaks = modBreaks }, 
389
390                    ModDetails { md_types     = tidy_type_env,
391                                 md_rules     = tidy_rules,
392                                 md_insts     = tidy_insts,
393                                 md_vect_info = tidy_vect_info,
394                                 md_fam_insts = fam_insts,
395                                 md_exports   = exports,
396                                 md_anns      = anns      -- are already tidy
397                               })
398         }
399
400 lookup_dfun :: TypeEnv -> Var -> Id
401 lookup_dfun type_env dfun_id
402   = case lookupTypeEnv type_env (idName dfun_id) of
403         Just (AnId dfun_id') -> dfun_id'
404         _other -> pprPanic "lookup_dfun" (ppr dfun_id)
405
406 --------------------------
407 tidyTypeEnv :: Bool       -- Compiling without -O, so omit prags
408             -> Bool       -- Template Haskell is on
409             -> NameSet -> TypeEnv -> TypeEnv
410
411 -- The competed type environment is gotten from
412 --      a) the types and classes defined here (plus implicit things)
413 --      b) adding Ids with correct IdInfo, including unfoldings,
414 --              gotten from the bindings
415 -- From (b) we keep only those Ids with External names;
416 --          the CoreTidy pass makes sure these are all and only
417 --          the externally-accessible ones
418 -- This truncates the type environment to include only the 
419 -- exported Ids and things needed from them, which saves space
420
421 tidyTypeEnv omit_prags th exports type_env
422  = let
423         type_env1 = filterNameEnv (not . isWiredInName . getName) type_env
424           -- (1) remove wired-in things
425         type_env2 | omit_prags = mapNameEnv (trimThing th exports) type_env1
426                   | otherwise  = type_env1
427           -- (2) trimmed if necessary
428     in
429     type_env2
430
431 --------------------------
432 trimThing :: Bool -> NameSet -> TyThing -> TyThing
433 -- Trim off inessentials, for boot files and no -O
434 trimThing th exports (ATyCon tc)
435    | not th && not (mustExposeTyCon exports tc)
436    = ATyCon (makeTyConAbstract tc)      -- Note [Trimming and Template Haskell]
437
438 trimThing _th _exports (AnId id)
439    | not (isImplicitId id) 
440    = AnId (id `setIdInfo` vanillaIdInfo)
441
442 trimThing _th _exports other_thing 
443   = other_thing
444
445
446 {- Note [Trimming and Template Haskell]
447    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
448 Consider (Trac #2386) this
449         module M(T, makeOne) where
450           data T = Yay String
451           makeOne = [| Yay "Yep" |]
452 Notice that T is exported abstractly, but makeOne effectively exports it too!
453 A module that splices in $(makeOne) will then look for a declartion of Yay,
454 so it'd better be there.  Hence, brutally but simply, we switch off type
455 constructor trimming if TH is enabled in this module. -}
456
457
458 mustExposeTyCon :: NameSet      -- Exports
459                 -> TyCon        -- The tycon
460                 -> Bool         -- Can its rep be hidden?
461 -- We are compiling without -O, and thus trying to write as little as 
462 -- possible into the interface file.  But we must expose the details of
463 -- any data types whose constructors or fields are exported
464 mustExposeTyCon exports tc
465   | not (isAlgTyCon tc)         -- Synonyms
466   = True
467   | isEnumerationTyCon tc       -- For an enumeration, exposing the constructors
468   = True                        -- won't lead to the need for further exposure
469                                 -- (This includes data types with no constructors.)
470   | isFamilyTyCon tc            -- Open type family
471   = True
472
473   | otherwise                   -- Newtype, datatype
474   = any exported_con (tyConDataCons tc)
475         -- Expose rep if any datacon or field is exported
476
477   || (isNewTyCon tc && isFFITy (snd (newTyConRhs tc)))
478         -- Expose the rep for newtypes if the rep is an FFI type.  
479         -- For a very annoying reason.  'Foreign import' is meant to
480         -- be able to look through newtypes transparently, but it
481         -- can only do that if it can "see" the newtype representation
482   where
483     exported_con con = any (`elemNameSet` exports) 
484                            (dataConName con : dataConFieldLabels con)
485
486 tidyInstances :: (DFunId -> DFunId) -> [Instance] -> [Instance]
487 tidyInstances tidy_dfun ispecs
488   = map tidy ispecs
489   where
490     tidy ispec = setInstanceDFunId ispec $
491                  tidy_dfun (instanceDFunId ispec)
492 \end{code}
493
494 \begin{code}
495 tidyVectInfo :: TidyEnv -> VectInfo -> VectInfo
496 tidyVectInfo (_, var_env) info@(VectInfo { vectInfoVar          = vars
497                                          , vectInfoScalarVars   = scalarVars
498                                          })
499   = info { vectInfoVar          = tidy_vars
500          , vectInfoScalarVars   = tidy_scalarVars
501          }
502   where
503       -- we only export mappings whose co-domain is exported (otherwise, the iface is inconsistent)
504     tidy_vars = mkVarEnv [ (tidy_var, (tidy_var, tidy_var_v))
505                          | (var, var_v) <- varEnvElts vars
506                          , let tidy_var   = lookup_var var
507                                tidy_var_v = lookup_var var_v
508                          , isExportedId tidy_var_v
509                          ]
510
511     tidy_scalarVars = mkVarSet [ lookup_var var 
512                                | var <- varSetElems scalarVars
513                                , isGlobalId var || isExportedId var]
514       
515     lookup_var var = lookupWithDefaultVarEnv var_env var var
516 \end{code}
517
518
519 %************************************************************************
520 %*                                                                      *
521         Implicit bindings
522 %*                                                                      *
523 %************************************************************************
524
525 Note [Injecting implicit bindings]
526 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
527 We inject the implict bindings right at the end, in CoreTidy.
528 Some of these bindings, notably record selectors, are not
529 constructed in an optimised form.  E.g. record selector for
530         data T = MkT { x :: {-# UNPACK #-} !Int }
531 Then the unfolding looks like
532         x = \t. case t of MkT x1 -> let x = I# x1 in x
533 This generates bad code unless it's first simplified a bit.  That is
534 why CoreUnfold.mkImplicitUnfolding uses simleExprOpt to do a bit of
535 optimisation first.  (Only matters when the selector is used curried;
536 eg map x ys.)  See Trac #2070.
537
538 [Oct 09: in fact, record selectors are no longer implicit Ids at all,
539 because we really do want to optimise them properly. They are treated
540 much like any other Id.  But doing "light" optimisation on an implicit
541 Id still makes sense.]
542
543 At one time I tried injecting the implicit bindings *early*, at the
544 beginning of SimplCore.  But that gave rise to real difficulty,
545 becuase GlobalIds are supposed to have *fixed* IdInfo, but the
546 simplifier and other core-to-core passes mess with IdInfo all the
547 time.  The straw that broke the camels back was when a class selector
548 got the wrong arity -- ie the simplifier gave it arity 2, whereas
549 importing modules were expecting it to have arity 1 (Trac #2844).
550 It's much safer just to inject them right at the end, after tidying.
551
552 Oh: two other reasons for injecting them late:
553
554   - If implicit Ids are already in the bindings when we start TidyPgm,
555     we'd have to be careful not to treat them as external Ids (in
556     the sense of findExternalIds); else the Ids mentioned in *their*
557     RHSs will be treated as external and you get an interface file 
558     saying      a18 = <blah>
559     but nothing refererring to a18 (because the implicit Id is the 
560     one that does, and implicit Ids don't appear in interface files).
561
562   - More seriously, the tidied type-envt will include the implicit
563     Id replete with a18 in its unfolding; but we won't take account
564     of a18 when computing a fingerprint for the class; result chaos.
565     
566 There is one sort of implicit binding that is injected still later,
567 namely those for data constructor workers. Reason (I think): it's
568 really just a code generation trick.... binding itself makes no sense.
569 See CorePrep Note [Data constructor workers].
570
571 \begin{code}
572 getTyConImplicitBinds :: TyCon -> [CoreBind]
573 getTyConImplicitBinds tc = map get_defn (mapCatMaybes dataConWrapId_maybe (tyConDataCons tc))
574
575 getClassImplicitBinds :: Class -> [CoreBind]
576 getClassImplicitBinds cls = map get_defn (classAllSelIds cls)
577
578 get_defn :: Id -> CoreBind
579 get_defn id = NonRec id (unfoldingTemplate (realIdUnfolding id))
580 \end{code}
581
582
583 %************************************************************************
584 %*                                                                      *
585 \subsection{Step 1: finding externals}
586 %*                                                                      * 
587 %************************************************************************
588
589 See Note [Choosing external names].
590
591 \begin{code}
592 type UnfoldEnv  = IdEnv (Name{-new name-}, Bool {-show unfolding-})
593   -- Maps each top-level Id to its new Name (the Id is tidied in step 2)
594   -- The Unique is unchanged.  If the new Name is external, it will be
595   -- visible in the interface file.  
596   --
597   -- Bool => expose unfolding or not.
598
599 chooseExternalIds :: HscEnv
600                   -> Module
601                   -> Bool -> Bool
602                   -> [CoreBind]
603                   -> [CoreBind]
604                   -> [CoreRule]
605                   -> VarEnv (Var, Var)
606                   -> IO (UnfoldEnv, TidyOccEnv)
607                   -- Step 1 from the notes above
608
609 chooseExternalIds hsc_env mod omit_prags expose_all binds implicit_binds imp_id_rules vect_vars
610   = do { (unfold_env1,occ_env1) <- search init_work_list emptyVarEnv init_occ_env
611        ; let internal_ids = filter (not . (`elemVarEnv` unfold_env1)) binders
612        ; tidy_internal internal_ids unfold_env1 occ_env1 }
613  where
614   nc_var = hsc_NC hsc_env 
615
616   -- init_ext_ids is the intial list of Ids that should be
617   -- externalised.  It serves as the starting point for finding a
618   -- deterministic, tidy, renaming for all external Ids in this
619   -- module.
620   -- 
621   -- It is sorted, so that it has adeterministic order (i.e. it's the
622   -- same list every time this module is compiled), in contrast to the
623   -- bindings, which are ordered non-deterministically.
624   init_work_list = zip init_ext_ids init_ext_ids
625   init_ext_ids   = sortBy (compare `on` getOccName) $
626                    filter is_external binders
627
628   -- An Id should be external if either (a) it is exported,
629   -- (b) it appears in the RHS of a local rule for an imported Id, or
630   -- (c) it is the vectorised version of an imported Id
631   -- See Note [Which rules to expose]
632   is_external id = isExportedId id || id `elemVarSet` rule_rhs_vars || id `elemVarSet` vect_var_vs
633   rule_rhs_vars  = foldr (unionVarSet . ruleRhsFreeVars) emptyVarSet imp_id_rules
634   vect_var_vs    = mkVarSet [var_v | (var, var_v) <- nameEnvElts vect_vars, isGlobalId var]
635
636   binders          = bindersOfBinds binds
637   implicit_binders = bindersOfBinds implicit_binds
638   binder_set       = mkVarSet binders
639
640   avoids   = [getOccName name | bndr <- binders ++ implicit_binders,
641                                 let name = idName bndr,
642                                 isExternalName name ]
643                 -- In computing our "avoids" list, we must include
644                 --      all implicit Ids
645                 --      all things with global names (assigned once and for
646                 --                                      all by the renamer)
647                 -- since their names are "taken".
648                 -- The type environment is a convenient source of such things.
649                 -- In particular, the set of binders doesn't include
650                 -- implicit Ids at this stage.
651
652         -- We also make sure to avoid any exported binders.  Consider
653         --      f{-u1-} = 1     -- Local decl
654         --      ...
655         --      f{-u2-} = 2     -- Exported decl
656         --
657         -- The second exported decl must 'get' the name 'f', so we
658         -- have to put 'f' in the avoids list before we get to the first
659         -- decl.  tidyTopId then does a no-op on exported binders.
660   init_occ_env = initTidyOccEnv avoids
661
662
663   search :: [(Id,Id)]    -- The work-list: (external id, referrring id)
664                          -- Make a tidy, external Name for the external id,
665                          --   add it to the UnfoldEnv, and do the same for the
666                          --   transitive closure of Ids it refers to
667                          -- The referring id is used to generate a tidy
668                          ---  name for the external id
669          -> UnfoldEnv    -- id -> (new Name, show_unfold)
670          -> TidyOccEnv   -- occ env for choosing new Names
671          -> IO (UnfoldEnv, TidyOccEnv)
672
673   search [] unfold_env occ_env = return (unfold_env, occ_env)
674
675   search ((idocc,referrer) : rest) unfold_env occ_env
676     | idocc `elemVarEnv` unfold_env = search rest unfold_env occ_env
677     | otherwise = do
678       (occ_env', name') <- tidyTopName mod nc_var (Just referrer) occ_env idocc
679       let 
680           (new_ids, show_unfold)
681                 | omit_prags = ([], False)
682                 | otherwise  = addExternal expose_all refined_id
683
684                 -- 'idocc' is an *occurrence*, but we need to see the
685                 -- unfolding in the *definition*; so look up in binder_set
686           refined_id = case lookupVarSet binder_set idocc of
687                          Just id -> id
688                          Nothing -> WARN( True, ppr idocc ) idocc
689
690           unfold_env' = extendVarEnv unfold_env idocc (name',show_unfold)
691           referrer' | isExportedId refined_id = refined_id
692                     | otherwise               = referrer
693       --
694       search (zip new_ids (repeat referrer') ++ rest) unfold_env' occ_env'
695
696   tidy_internal :: [Id] -> UnfoldEnv -> TidyOccEnv
697                 -> IO (UnfoldEnv, TidyOccEnv)
698   tidy_internal []       unfold_env occ_env = return (unfold_env,occ_env)
699   tidy_internal (id:ids) unfold_env occ_env = do
700       (occ_env', name') <- tidyTopName mod nc_var Nothing occ_env id
701       let unfold_env' = extendVarEnv unfold_env id (name',False)
702       tidy_internal ids unfold_env' occ_env'
703
704 addExternal :: Bool -> Id -> ([Id], Bool)
705 addExternal expose_all id = (new_needed_ids, show_unfold)
706   where
707     new_needed_ids = bndrFvsInOrder show_unfold id
708     idinfo         = idInfo id
709     show_unfold    = show_unfolding (unfoldingInfo idinfo)
710     never_active   = isNeverActive (inlinePragmaActivation (inlinePragInfo idinfo))
711     loop_breaker   = isStrongLoopBreaker (occInfo idinfo)
712     bottoming_fn   = isBottomingSig (strictnessInfo idinfo `orElse` topSig)
713
714         -- Stuff to do with the Id's unfolding
715         -- We leave the unfolding there even if there is a worker
716         -- In GHCi the unfolding is used by importers
717
718     show_unfolding (CoreUnfolding { uf_src = src, uf_guidance = guidance })
719        =  expose_all         -- 'expose_all' says to expose all 
720                              -- unfoldings willy-nilly
721
722        || isStableSource src     -- Always expose things whose 
723                                  -- source is an inline rule
724
725        || not (bottoming_fn      -- No need to inline bottom functions
726            || never_active       -- Or ones that say not to
727            || loop_breaker       -- Or that are loop breakers
728            || neverUnfoldGuidance guidance)
729     show_unfolding (DFunUnfolding {}) = True
730     show_unfolding _                  = False
731 \end{code}
732
733 %************************************************************************
734 %*                                                                      *
735                Deterministic free variables
736 %*                                                                      *
737 %************************************************************************
738
739 We want a deterministic free-variable list.  exprFreeVars gives us
740 a VarSet, which is in a non-deterministic order when converted to a
741 list.  Hence, here we define a free-variable finder that returns
742 the free variables in the order that they are encountered.
743
744 See Note [Choosing external names]
745
746 \begin{code}
747 bndrFvsInOrder :: Bool -> Id -> [Id]
748 bndrFvsInOrder show_unfold id
749   = run (dffvLetBndr show_unfold id)
750
751 run :: DFFV () -> [Id]
752 run (DFFV m) = case m emptyVarSet (emptyVarSet, []) of
753                  ((_,ids),_) -> ids
754
755 newtype DFFV a 
756   = DFFV (VarSet              -- Envt: non-top-level things that are in scope
757                               -- we don't want to record these as free vars
758       -> (VarSet, [Var])      -- Input State: (set, list) of free vars so far 
759       -> ((VarSet,[Var]),a))  -- Output state
760
761 instance Monad DFFV where
762   return a = DFFV $ \_ st -> (st, a)
763   (DFFV m) >>= k = DFFV $ \env st ->
764     case m env st of
765        (st',a) -> case k a of
766                      DFFV f -> f env st'
767
768 extendScope :: Var -> DFFV a -> DFFV a
769 extendScope v (DFFV f) = DFFV (\env st -> f (extendVarSet env v) st)
770
771 extendScopeList :: [Var] -> DFFV a -> DFFV a
772 extendScopeList vs (DFFV f) = DFFV (\env st -> f (extendVarSetList env vs) st)
773
774 insert :: Var -> DFFV ()
775 insert v = DFFV $ \ env (set, ids) -> 
776            let keep_me = isLocalId v && 
777                          not (v `elemVarSet` env) &&
778                            not (v `elemVarSet` set)
779            in if keep_me 
780               then ((extendVarSet set v, v:ids), ())
781               else ((set,                ids),   ())
782
783
784 dffvExpr :: CoreExpr -> DFFV ()
785 dffvExpr (Var v)              = insert v
786 dffvExpr (App e1 e2)          = dffvExpr e1 >> dffvExpr e2
787 dffvExpr (Lam v e)            = extendScope v (dffvExpr e)
788 dffvExpr (Note _ e)           = dffvExpr e
789 dffvExpr (Cast e _)           = dffvExpr e
790 dffvExpr (Let (NonRec x r) e) = dffvBind (x,r) >> extendScope x (dffvExpr e)
791 dffvExpr (Let (Rec prs) e)    = extendScopeList (map fst prs) $
792                                 (mapM_ dffvBind prs >> dffvExpr e)
793 dffvExpr (Case e b _ as)      = dffvExpr e >> extendScope b (mapM_ dffvAlt as)
794 dffvExpr _other               = return ()
795
796 dffvAlt :: (t, [Var], CoreExpr) -> DFFV ()
797 dffvAlt (_,xs,r) = extendScopeList xs (dffvExpr r)
798
799 dffvBind :: (Id, CoreExpr) -> DFFV ()
800 dffvBind(x,r) 
801   | not (isId x) = dffvExpr r
802   | otherwise    = dffvLetBndr False x >> dffvExpr r
803                 -- Pass False because we are doing the RHS right here
804                 -- If you say True you'll get *exponential* behaviour!
805
806 dffvLetBndr :: Bool -> Id -> DFFV ()
807 -- Gather the free vars of the RULES and unfolding of a binder
808 -- We always get the free vars of a *stable* unfolding, but
809 -- for a *vanilla* one (InlineRhs), the flag controls what happens:
810 --   True <=> get fvs of even a *vanilla* unfolding
811 --   False <=> ignore an InlineRhs
812 -- For nested bindings (call from dffvBind) we always say "False" because
813 --       we are taking the fvs of the RHS anyway
814 -- For top-level bindings (call from addExternal, via bndrFvsInOrder)
815 --       we say "True" if we are exposing that unfolding
816 dffvLetBndr vanilla_unfold id
817   = do { go_unf (unfoldingInfo idinfo)
818        ; mapM_ go_rule (specInfoRules (specInfo idinfo)) }
819   where
820     idinfo = idInfo id
821
822     go_unf (CoreUnfolding { uf_tmpl = rhs, uf_src = src })
823        = case src of
824            InlineRhs | vanilla_unfold -> dffvExpr rhs
825                      | otherwise      -> return ()
826            InlineWrapper v            -> insert v    
827            _                          -> dffvExpr rhs
828             -- For a wrapper, externalise the wrapper id rather than the
829             -- fvs of the rhs.  The two usually come down to the same thing
830             -- but I've seen cases where we had a wrapper id $w but a
831             -- rhs where $w had been inlined; see Trac #3922
832
833     go_unf (DFunUnfolding _ _ args) = mapM_ dffvExpr args
834     go_unf _ = return ()
835
836     go_rule (BuiltinRule {}) = return ()
837     go_rule (Rule { ru_bndrs = bndrs, ru_rhs = rhs })
838       = extendScopeList bndrs (dffvExpr rhs)
839 \end{code}
840
841
842 %************************************************************************
843 %*                                                                      *
844                tidyTopName
845 %*                                                                      *
846 %************************************************************************
847
848 This is where we set names to local/global based on whether they really are 
849 externally visible (see comment at the top of this module).  If the name
850 was previously local, we have to give it a unique occurrence name if
851 we intend to externalise it.
852
853 \begin{code}
854 tidyTopName :: Module -> IORef NameCache -> Maybe Id -> TidyOccEnv
855             -> Id -> IO (TidyOccEnv, Name)
856 tidyTopName mod nc_var maybe_ref occ_env id
857   | global && internal = return (occ_env, localiseName name)
858
859   | global && external = return (occ_env, name)
860         -- Global names are assumed to have been allocated by the renamer,
861         -- so they already have the "right" unique
862         -- And it's a system-wide unique too
863
864   -- Now we get to the real reason that all this is in the IO Monad:
865   -- we have to update the name cache in a nice atomic fashion
866
867   | local  && internal = do { nc <- readIORef nc_var
868                             ; let (nc', new_local_name) = mk_new_local nc
869                             ; writeIORef nc_var nc'
870                             ; return (occ_env', new_local_name) }
871         -- Even local, internal names must get a unique occurrence, because
872         -- if we do -split-objs we externalise the name later, in the code generator
873         --
874         -- Similarly, we must make sure it has a system-wide Unique, because
875         -- the byte-code generator builds a system-wide Name->BCO symbol table
876
877   | local  && external = do { nc <- readIORef nc_var
878                             ; let (nc', new_external_name) = mk_new_external nc
879                             ; writeIORef nc_var nc'
880                             ; return (occ_env', new_external_name) }
881
882   | otherwise = panic "tidyTopName"
883   where
884     name        = idName id
885     external    = isJust maybe_ref
886     global      = isExternalName name
887     local       = not global
888     internal    = not external
889     loc         = nameSrcSpan name
890
891     old_occ     = nameOccName name
892     new_occ
893       | Just ref <- maybe_ref, ref /= id = 
894           mkOccName (occNameSpace old_occ) $
895              let
896                  ref_str = occNameString (getOccName ref)
897                  occ_str = occNameString old_occ
898              in
899              case occ_str of
900                '$':'w':_ -> occ_str
901                   -- workers: the worker for a function already
902                   -- includes the occname for its parent, so there's
903                   -- no need to prepend the referrer.
904                _other | isSystemName name -> ref_str
905                       | otherwise         -> ref_str ++ '_' : occ_str
906                   -- If this name was system-generated, then don't bother
907                   -- to retain its OccName, just use the referrer.  These
908                   -- system-generated names will become "f1", "f2", etc. for
909                   -- a referrer "f".
910       | otherwise = old_occ
911
912     (occ_env', occ') = tidyOccName occ_env new_occ
913
914     mk_new_local nc = (nc { nsUniqs = us }, mkInternalName uniq occ' loc)
915                     where
916                       (uniq, us) = takeUniqFromSupply (nsUniqs nc)
917
918     mk_new_external nc = allocateGlobalBinder nc mod occ' loc
919         -- If we want to externalise a currently-local name, check
920         -- whether we have already assigned a unique for it.
921         -- If so, use it; if not, extend the table.
922         -- All this is done by allcoateGlobalBinder.
923         -- This is needed when *re*-compiling a module in GHCi; we must
924         -- use the same name for externally-visible things as we did before.
925 \end{code}
926
927 \begin{code}
928 findExternalRules :: Bool       -- Omit pragmas
929                   -> [CoreBind]
930                   -> [CoreRule] -- Local rules for imported fns
931                   -> UnfoldEnv  -- Ids that are exported, so we need their rules
932                   -> [CoreRule]
933   -- The complete rules are gotten by combining
934   --    a) local rules for imported Ids
935   --    b) rules embedded in the top-level Ids
936 findExternalRules omit_prags binds imp_id_rules unfold_env
937   | omit_prags = []
938   | otherwise  = filterOut internal_rule (imp_id_rules ++ local_rules)
939   where
940     local_rules  = [ rule
941                    | id <- bindersOfBinds binds,
942                      external_id id,
943                      rule <- idCoreRules id
944                    ]
945
946     internal_rule rule
947         =  any (not . external_id) (varSetElems (ruleLhsFreeIds rule))
948                 -- Don't export a rule whose LHS mentions a locally-defined
949                 --  Id that is completely internal (i.e. not visible to an
950                 -- importing module)
951
952     external_id id
953       | Just (name,_) <- lookupVarEnv unfold_env id = isExternalName name
954       | otherwise = False
955 \end{code}
956
957 Note [Which rules to expose]
958 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
959 findExternalRules filters imp_rules to avoid binders that 
960 aren't externally visible; but the externally-visible binders 
961 are computed (by findExternalIds) assuming that all orphan
962 rules are externalised (see init_ext_ids in function 
963 'search'). So in fact we may export more than we need. 
964 (It's a sort of mutual recursion.)
965
966 %************************************************************************
967 %*                                                                      *
968 \subsection{Step 2: top-level tidying}
969 %*                                                                      *
970 %************************************************************************
971
972
973 \begin{code}
974 -- TopTidyEnv: when tidying we need to know
975 --   * nc_var: The NameCache, containing a unique supply and any pre-ordained Names.  
976 --        These may have arisen because the
977 --        renamer read in an interface file mentioning M.$wf, say,
978 --        and assigned it unique r77.  If, on this compilation, we've
979 --        invented an Id whose name is $wf (but with a different unique)
980 --        we want to rename it to have unique r77, so that we can do easy
981 --        comparisons with stuff from the interface file
982 --
983 --   * occ_env: The TidyOccEnv, which tells us which local occurrences 
984 --     are 'used'
985 --
986 --   * subst_env: A Var->Var mapping that substitutes the new Var for the old
987
988 tidyTopBinds :: HscEnv
989              -> UnfoldEnv
990              -> TidyOccEnv
991              -> CoreProgram
992              -> (TidyEnv, CoreProgram)
993
994 tidyTopBinds hsc_env unfold_env init_occ_env binds
995   = tidy init_env binds
996   where
997     init_env = (init_occ_env, emptyVarEnv)
998
999     this_pkg = thisPackage (hsc_dflags hsc_env)
1000
1001     tidy env []     = (env, [])
1002     tidy env (b:bs) = let (env1, b')  = tidyTopBind this_pkg unfold_env env b
1003                           (env2, bs') = tidy env1 bs
1004                       in
1005                           (env2, b':bs')
1006
1007 ------------------------
1008 tidyTopBind  :: PackageId
1009              -> UnfoldEnv
1010              -> TidyEnv
1011              -> CoreBind
1012              -> (TidyEnv, CoreBind)
1013
1014 tidyTopBind this_pkg unfold_env (occ_env,subst1) (NonRec bndr rhs)
1015   = (tidy_env2,  NonRec bndr' rhs')
1016   where
1017     Just (name',show_unfold) = lookupVarEnv unfold_env bndr
1018     caf_info      = hasCafRefs this_pkg subst1 (idArity bndr) rhs
1019     (bndr', rhs') = tidyTopPair show_unfold tidy_env2 caf_info name' (bndr, rhs)
1020     subst2        = extendVarEnv subst1 bndr bndr'
1021     tidy_env2     = (occ_env, subst2)
1022
1023 tidyTopBind this_pkg unfold_env (occ_env,subst1) (Rec prs)
1024   = (tidy_env2, Rec prs')
1025   where
1026     prs' = [ tidyTopPair show_unfold tidy_env2 caf_info name' (id,rhs)
1027            | (id,rhs) <- prs,
1028              let (name',show_unfold) = 
1029                     expectJust "tidyTopBind" $ lookupVarEnv unfold_env id
1030            ]
1031
1032     subst2    = extendVarEnvList subst1 (bndrs `zip` map fst prs')
1033     tidy_env2 = (occ_env, subst2)
1034
1035     bndrs = map fst prs
1036
1037         -- the CafInfo for a recursive group says whether *any* rhs in
1038         -- the group may refer indirectly to a CAF (because then, they all do).
1039     caf_info 
1040         | or [ mayHaveCafRefs (hasCafRefs this_pkg subst1 (idArity bndr) rhs)
1041              | (bndr,rhs) <- prs ] = MayHaveCafRefs
1042         | otherwise                = NoCafRefs
1043
1044 -----------------------------------------------------------
1045 tidyTopPair :: Bool  -- show unfolding
1046             -> TidyEnv  -- The TidyEnv is used to tidy the IdInfo
1047                         -- It is knot-tied: don't look at it!
1048             -> CafInfo
1049             -> Name             -- New name
1050             -> (Id, CoreExpr)   -- Binder and RHS before tidying
1051             -> (Id, CoreExpr)
1052         -- This function is the heart of Step 2
1053         -- The rec_tidy_env is the one to use for the IdInfo
1054         -- It's necessary because when we are dealing with a recursive
1055         -- group, a variable late in the group might be mentioned
1056         -- in the IdInfo of one early in the group
1057
1058 tidyTopPair show_unfold rhs_tidy_env caf_info name' (bndr, rhs)
1059   = (bndr1, rhs1)
1060   where
1061     bndr1    = mkGlobalId details name' ty' idinfo'
1062     details  = idDetails bndr   -- Preserve the IdDetails
1063     ty'      = tidyTopType (idType bndr)
1064     rhs1     = tidyExpr rhs_tidy_env rhs
1065     idinfo'  = tidyTopIdInfo rhs_tidy_env name' rhs rhs1 (idInfo bndr) 
1066                              show_unfold caf_info
1067
1068 -- tidyTopIdInfo creates the final IdInfo for top-level
1069 -- binders.  There are two delicate pieces:
1070 --
1071 --  * Arity.  After CoreTidy, this arity must not change any more.
1072 --      Indeed, CorePrep must eta expand where necessary to make
1073 --      the manifest arity equal to the claimed arity.
1074 --
1075 --  * CAF info.  This must also remain valid through to code generation.
1076 --      We add the info here so that it propagates to all
1077 --      occurrences of the binders in RHSs, and hence to occurrences in
1078 --      unfoldings, which are inside Ids imported by GHCi. Ditto RULES.
1079 --      CoreToStg makes use of this when constructing SRTs.
1080 tidyTopIdInfo :: TidyEnv -> Name -> CoreExpr -> CoreExpr 
1081               -> IdInfo -> Bool -> CafInfo -> IdInfo
1082 tidyTopIdInfo rhs_tidy_env name orig_rhs tidy_rhs idinfo show_unfold caf_info
1083   | not is_external     -- For internal Ids (not externally visible)
1084   = vanillaIdInfo       -- we only need enough info for code generation
1085                         -- Arity and strictness info are enough;
1086                         --      c.f. CoreTidy.tidyLetBndr
1087         `setCafInfo`        caf_info
1088         `setArityInfo`      arity
1089         `setStrictnessInfo` final_sig
1090
1091   | otherwise           -- Externally-visible Ids get the whole lot
1092   = vanillaIdInfo
1093         `setCafInfo`           caf_info
1094         `setArityInfo`         arity
1095         `setStrictnessInfo`    final_sig
1096         `setOccInfo`           robust_occ_info
1097         `setInlinePragInfo`    (inlinePragInfo idinfo)
1098         `setUnfoldingInfo`     unfold_info
1099                 -- NB: we throw away the Rules
1100                 -- They have already been extracted by findExternalRules
1101   where
1102     is_external = isExternalName name
1103
1104     --------- OccInfo ------------
1105     robust_occ_info = zapFragileOcc (occInfo idinfo)
1106     -- It's important to keep loop-breaker information
1107     -- when we are doing -fexpose-all-unfoldings
1108
1109     --------- Strictness ------------
1110     final_sig | Just sig <- strictnessInfo idinfo
1111               = WARN( _bottom_hidden sig, ppr name ) Just sig
1112               | Just (_, sig) <- mb_bot_str = Just sig
1113               | otherwise                   = Nothing
1114
1115     -- If the cheap-and-cheerful bottom analyser can see that
1116     -- the RHS is bottom, it should jolly well be exposed
1117     _bottom_hidden id_sig = case mb_bot_str of
1118                                Nothing         -> False
1119                                Just (arity, _) -> not (appIsBottom id_sig arity)
1120
1121     mb_bot_str = exprBotStrictness_maybe orig_rhs
1122
1123     --------- Unfolding ------------
1124     unf_info = unfoldingInfo idinfo
1125     unfold_info | show_unfold = tidyUnfolding rhs_tidy_env unf_info unf_from_rhs
1126                 | otherwise   = noUnfolding
1127     unf_from_rhs = mkTopUnfolding is_bot tidy_rhs
1128     is_bot = case final_sig of 
1129                 Just sig -> isBottomingSig sig
1130                 Nothing  -> False
1131     -- NB: do *not* expose the worker if show_unfold is off,
1132     --     because that means this thing is a loop breaker or
1133     --     marked NOINLINE or something like that
1134     -- This is important: if you expose the worker for a loop-breaker
1135     -- then you can make the simplifier go into an infinite loop, because
1136     -- in effect the unfolding is exposed.  See Trac #1709
1137     -- 
1138     -- You might think that if show_unfold is False, then the thing should
1139     -- not be w/w'd in the first place.  But a legitimate reason is this:
1140     --    the function returns bottom
1141     -- In this case, show_unfold will be false (we don't expose unfoldings
1142     -- for bottoming functions), but we might still have a worker/wrapper
1143     -- split (see Note [Worker-wrapper for bottoming functions] in WorkWrap.lhs
1144
1145     --------- Arity ------------
1146     -- Usually the Id will have an accurate arity on it, because
1147     -- the simplifier has just run, but not always. 
1148     -- One case I found was when the last thing the simplifier
1149     -- did was to let-bind a non-atomic argument and then float
1150     -- it to the top level. So it seems more robust just to
1151     -- fix it here.
1152     arity = exprArity orig_rhs
1153 \end{code}
1154
1155 %************************************************************************
1156 %*                                                                      *
1157 \subsection{Figuring out CafInfo for an expression}
1158 %*                                                                      *
1159 %************************************************************************
1160
1161 hasCafRefs decides whether a top-level closure can point into the dynamic heap.
1162 We mark such things as `MayHaveCafRefs' because this information is
1163 used to decide whether a particular closure needs to be referenced
1164 in an SRT or not.
1165
1166 There are two reasons for setting MayHaveCafRefs:
1167         a) The RHS is a CAF: a top-level updatable thunk.
1168         b) The RHS refers to something that MayHaveCafRefs
1169
1170 Possible improvement: In an effort to keep the number of CAFs (and 
1171 hence the size of the SRTs) down, we could also look at the expression and 
1172 decide whether it requires a small bounded amount of heap, so we can ignore 
1173 it as a CAF.  In these cases however, we would need to use an additional
1174 CAF list to keep track of non-collectable CAFs.  
1175
1176 \begin{code}
1177 hasCafRefs  :: PackageId -> VarEnv Var -> Arity -> CoreExpr -> CafInfo
1178 hasCafRefs this_pkg p arity expr 
1179   | is_caf || mentions_cafs = MayHaveCafRefs
1180   | otherwise               = NoCafRefs
1181  where
1182   mentions_cafs = isFastTrue (cafRefsE p expr)
1183   is_dynamic_name = isDllName this_pkg 
1184   is_caf = not (arity > 0 || rhsIsStatic is_dynamic_name expr)
1185
1186   -- NB. we pass in the arity of the expression, which is expected
1187   -- to be calculated by exprArity.  This is because exprArity
1188   -- knows how much eta expansion is going to be done by 
1189   -- CorePrep later on, and we don't want to duplicate that
1190   -- knowledge in rhsIsStatic below.
1191
1192 cafRefsE :: VarEnv Id -> Expr a -> FastBool
1193 cafRefsE p (Var id)            = cafRefsV p id
1194 cafRefsE p (Lit lit)           = cafRefsL p lit
1195 cafRefsE p (App f a)           = fastOr (cafRefsE p f) (cafRefsE p) a
1196 cafRefsE p (Lam _ e)           = cafRefsE p e
1197 cafRefsE p (Let b e)           = fastOr (cafRefsEs p (rhssOfBind b)) (cafRefsE p) e
1198 cafRefsE p (Case e _bndr _ alts) = fastOr (cafRefsE p e) (cafRefsEs p) (rhssOfAlts alts)
1199 cafRefsE p (Note _n e)         = cafRefsE p e
1200 cafRefsE p (Cast e _co)         = cafRefsE p e
1201 cafRefsE _ (Type _)            = fastBool False
1202 cafRefsE _ (Coercion _)         = fastBool False
1203
1204 cafRefsEs :: VarEnv Id -> [Expr a] -> FastBool
1205 cafRefsEs _ []    = fastBool False
1206 cafRefsEs p (e:es) = fastOr (cafRefsE p e) (cafRefsEs p) es
1207
1208 cafRefsL :: VarEnv Id -> Literal -> FastBool
1209 -- Don't forget that the embeded mk_integer id might have Caf refs!
1210 -- See Note [Integer literals] in Literal
1211 cafRefsL p (LitInteger _ mk_integer) = cafRefsV p mk_integer
1212 cafRefsL _ _                         = fastBool False
1213
1214 cafRefsV :: VarEnv Id -> Id -> FastBool
1215 cafRefsV p id 
1216   | not (isLocalId id)            = fastBool (mayHaveCafRefs (idCafInfo id))
1217   | Just id' <- lookupVarEnv p id = fastBool (mayHaveCafRefs (idCafInfo id'))
1218   | otherwise                     = fastBool False
1219
1220 fastOr :: FastBool -> (a -> FastBool) -> a -> FastBool
1221 -- hack for lazy-or over FastBool.
1222 fastOr a f x = fastBool (isFastTrue a || isFastTrue (f x))
1223 \end{code}