Fix and improve deriving for indexed data types
[ghc.git] / compiler / types / Type.lhs
1 %
2 % (c) The University of Glasgow 2006
3 % (c) The GRASP/AQUA Project, Glasgow University, 1998
4 %
5
6 Type - public interface
7
8 \begin{code}
9 module Type (
10         -- re-exports from TypeRep
11         TyThing(..), Type, PredType(..), ThetaType, 
12         funTyCon,
13
14         -- Kinds
15         Kind, SimpleKind, KindVar,
16         kindFunResult, splitKindFunTys, splitKindFunTysN,
17
18         liftedTypeKindTyCon, openTypeKindTyCon, unliftedTypeKindTyCon,
19         argTypeKindTyCon, ubxTupleKindTyCon,
20
21         liftedTypeKind, unliftedTypeKind, openTypeKind,
22         argTypeKind, ubxTupleKind,
23
24         tySuperKind, coSuperKind, 
25
26         isLiftedTypeKind, isUnliftedTypeKind, isOpenTypeKind,
27         isUbxTupleKind, isArgTypeKind, isKind, isTySuperKind, 
28         isCoSuperKind, isSuperKind, isCoercionKind, isEqPred,
29         mkArrowKind, mkArrowKinds,
30
31         isSubArgTypeKind, isSubOpenTypeKind, isSubKind, defaultKind, eqKind,
32         isSubKindCon,
33
34         -- Re-exports from TyCon
35         PrimRep(..),
36
37         mkTyVarTy, mkTyVarTys, getTyVar, getTyVar_maybe, isTyVarTy,
38
39         mkAppTy, mkAppTys, splitAppTy, splitAppTys, 
40         splitAppTy_maybe, repSplitAppTy_maybe,
41
42         mkFunTy, mkFunTys, splitFunTy, splitFunTy_maybe, 
43         splitFunTys, splitFunTysN,
44         funResultTy, funArgTy, zipFunTys, isFunTy,
45
46         mkTyConApp, mkTyConTy, 
47         tyConAppTyCon, tyConAppArgs, 
48         splitTyConApp_maybe, splitTyConApp, 
49         splitNewTyConApp_maybe, splitNewTyConApp,
50
51         repType, repType', typePrimRep, coreView, tcView, kindView,
52
53         mkForAllTy, mkForAllTys, splitForAllTy_maybe, splitForAllTys, 
54         applyTy, applyTys, isForAllTy, dropForAlls,
55
56         -- Source types
57         predTypeRep, mkPredTy, mkPredTys,
58         tyConOrigHead, pprSourceTyCon,
59
60         -- Newtypes
61         splitRecNewType_maybe, newTyConInstRhs,
62
63         -- Lifting and boxity
64         isUnLiftedType, isUnboxedTupleType, isAlgType, isPrimitiveType,
65         isStrictType, isStrictPred, 
66
67         -- Free variables
68         tyVarsOfType, tyVarsOfTypes, tyVarsOfPred, tyVarsOfTheta,
69         typeKind, addFreeTyVars,
70
71         -- Tidying up for printing
72         tidyType,      tidyTypes,
73         tidyOpenType,  tidyOpenTypes,
74         tidyTyVarBndr, tidyFreeTyVars,
75         tidyOpenTyVar, tidyOpenTyVars,
76         tidyTopType,   tidyPred,
77         tidyKind,
78
79         -- Comparison
80         coreEqType, tcEqType, tcEqTypes, tcCmpType, tcCmpTypes, 
81         tcEqPred, tcCmpPred, tcEqTypeX, 
82
83         -- Seq
84         seqType, seqTypes,
85
86         -- Type substitutions
87         TvSubstEnv, emptyTvSubstEnv,    -- Representation widely visible
88         TvSubst(..), emptyTvSubst,      -- Representation visible to a few friends
89         mkTvSubst, mkOpenTvSubst, zipOpenTvSubst, zipTopTvSubst, mkTopTvSubst, notElemTvSubst,
90         getTvSubstEnv, setTvSubstEnv, getTvInScope, extendTvInScope,
91         extendTvSubst, extendTvSubstList, isInScope, composeTvSubst, zipTyEnv,
92
93         -- Performing substitution on types
94         substTy, substTys, substTyWith, substTheta, 
95         substPred, substTyVar, substTyVars, substTyVarBndr, deShadowTy, lookupTyVar,
96
97         -- Pretty-printing
98         pprType, pprParendType, pprTyThingCategory, pprForAll,
99         pprPred, pprTheta, pprThetaArrow, pprClassPred, pprKind, pprParendKind
100     ) where
101
102 #include "HsVersions.h"
103
104 -- We import the representation and primitive functions from TypeRep.
105 -- Many things are reexported, but not the representation!
106
107 import TypeRep
108
109 -- friends:
110 import Var
111 import VarEnv
112 import VarSet
113
114 import Name
115 import Class
116 import PrelNames
117 import TyCon
118
119 -- others
120 import StaticFlags
121 import Util
122 import Outputable
123 import UniqSet
124
125 import Data.Maybe       ( isJust )
126 \end{code}
127
128
129 %************************************************************************
130 %*                                                                      *
131                 Type representation
132 %*                                                                      *
133 %************************************************************************
134
135 In Core, we "look through" non-recursive newtypes and PredTypes.
136
137 \begin{code}
138 {-# INLINE coreView #-}
139 coreView :: Type -> Maybe Type
140 -- Strips off the *top layer only* of a type to give 
141 -- its underlying representation type. 
142 -- Returns Nothing if there is nothing to look through.
143 --
144 -- In the case of newtypes, it returns
145 --      *either* a vanilla TyConApp (recursive newtype, or non-saturated)
146 --      *or*     the newtype representation (otherwise), meaning the
147 --                      type written in the RHS of the newtype decl,
148 --                      which may itself be a newtype
149 --
150 -- Example: newtype R = MkR S
151 --          newtype S = MkS T
152 --          newtype T = MkT (T -> T)
153 --   expandNewTcApp on R gives Just S
154 --                  on S gives Just T
155 --                  on T gives Nothing   (no expansion)
156
157 -- By being non-recursive and inlined, this case analysis gets efficiently
158 -- joined onto the case analysis that the caller is already doing
159 coreView (NoteTy _ ty)     = Just ty
160 coreView (PredTy p)
161   | isEqPred p             = Nothing
162   | otherwise              = Just (predTypeRep p)
163 coreView (TyConApp tc tys) | Just (tenv, rhs, tys') <- coreExpandTyCon_maybe tc tys 
164                            = Just (mkAppTys (substTy (mkTopTvSubst tenv) rhs) tys')
165                                 -- Its important to use mkAppTys, rather than (foldl AppTy),
166                                 -- because the function part might well return a 
167                                 -- partially-applied type constructor; indeed, usually will!
168 coreView ty                = Nothing
169
170
171
172 -----------------------------------------------
173 {-# INLINE tcView #-}
174 tcView :: Type -> Maybe Type
175 -- Same, but for the type checker, which just looks through synonyms
176 tcView (NoteTy _ ty)     = Just ty
177 tcView (TyConApp tc tys) | Just (tenv, rhs, tys') <- tcExpandTyCon_maybe tc tys 
178                          = Just (mkAppTys (substTy (mkTopTvSubst tenv) rhs) tys')
179 tcView ty                = Nothing
180
181 -----------------------------------------------
182 {-# INLINE kindView #-}
183 kindView :: Kind -> Maybe Kind
184 -- C.f. coreView, tcView
185 -- For the moment, we don't even handle synonyms in kinds
186 kindView (NoteTy _ k) = Just k
187 kindView other        = Nothing
188 \end{code}
189
190
191 %************************************************************************
192 %*                                                                      *
193 \subsection{Constructor-specific functions}
194 %*                                                                      *
195 %************************************************************************
196
197
198 ---------------------------------------------------------------------
199                                 TyVarTy
200                                 ~~~~~~~
201 \begin{code}
202 mkTyVarTy  :: TyVar   -> Type
203 mkTyVarTy  = TyVarTy
204
205 mkTyVarTys :: [TyVar] -> [Type]
206 mkTyVarTys = map mkTyVarTy -- a common use of mkTyVarTy
207
208 getTyVar :: String -> Type -> TyVar
209 getTyVar msg ty = case getTyVar_maybe ty of
210                     Just tv -> tv
211                     Nothing -> panic ("getTyVar: " ++ msg)
212
213 isTyVarTy :: Type -> Bool
214 isTyVarTy ty = isJust (getTyVar_maybe ty)
215
216 getTyVar_maybe :: Type -> Maybe TyVar
217 getTyVar_maybe ty | Just ty' <- coreView ty = getTyVar_maybe ty'
218 getTyVar_maybe (TyVarTy tv)                 = Just tv  
219 getTyVar_maybe other                        = Nothing
220
221 \end{code}
222
223
224 ---------------------------------------------------------------------
225                                 AppTy
226                                 ~~~~~
227 We need to be pretty careful with AppTy to make sure we obey the 
228 invariant that a TyConApp is always visibly so.  mkAppTy maintains the
229 invariant: use it.
230
231 \begin{code}
232 mkAppTy orig_ty1 orig_ty2
233   = mk_app orig_ty1
234   where
235     mk_app (NoteTy _ ty1)    = mk_app ty1
236     mk_app (TyConApp tc tys) = mkTyConApp tc (tys ++ [orig_ty2])
237     mk_app ty1               = AppTy orig_ty1 orig_ty2
238         -- Note that the TyConApp could be an 
239         -- under-saturated type synonym.  GHC allows that; e.g.
240         --      type Foo k = k a -> k a
241         --      type Id x = x
242         --      foo :: Foo Id -> Foo Id
243         --
244         -- Here Id is partially applied in the type sig for Foo,
245         -- but once the type synonyms are expanded all is well
246
247 mkAppTys :: Type -> [Type] -> Type
248 mkAppTys orig_ty1 []        = orig_ty1
249         -- This check for an empty list of type arguments
250         -- avoids the needless loss of a type synonym constructor.
251         -- For example: mkAppTys Rational []
252         --   returns to (Ratio Integer), which has needlessly lost
253         --   the Rational part.
254 mkAppTys orig_ty1 orig_tys2
255   = mk_app orig_ty1
256   where
257     mk_app (NoteTy _ ty1)    = mk_app ty1
258     mk_app (TyConApp tc tys) = mkTyConApp tc (tys ++ orig_tys2)
259                                 -- mkTyConApp: see notes with mkAppTy
260     mk_app ty1               = foldl AppTy orig_ty1 orig_tys2
261
262 -------------
263 splitAppTy_maybe :: Type -> Maybe (Type, Type)
264 splitAppTy_maybe ty | Just ty' <- coreView ty
265                     = splitAppTy_maybe ty'
266 splitAppTy_maybe ty = repSplitAppTy_maybe ty
267
268 -------------
269 repSplitAppTy_maybe :: Type -> Maybe (Type,Type)
270 -- Does the AppTy split, but assumes that any view stuff is already done
271 repSplitAppTy_maybe (FunTy ty1 ty2)   = Just (TyConApp funTyCon [ty1], ty2)
272 repSplitAppTy_maybe (AppTy ty1 ty2)   = Just (ty1, ty2)
273 repSplitAppTy_maybe (TyConApp tc tys) = case snocView tys of
274                                                 Just (tys', ty') -> Just (TyConApp tc tys', ty')
275                                                 Nothing          -> Nothing
276 repSplitAppTy_maybe other = Nothing
277 -------------
278 splitAppTy :: Type -> (Type, Type)
279 splitAppTy ty = case splitAppTy_maybe ty of
280                         Just pr -> pr
281                         Nothing -> panic "splitAppTy"
282
283 -------------
284 splitAppTys :: Type -> (Type, [Type])
285 splitAppTys ty = split ty ty []
286   where
287     split orig_ty ty args | Just ty' <- coreView ty = split orig_ty ty' args
288     split orig_ty (AppTy ty arg)        args = split ty ty (arg:args)
289     split orig_ty (TyConApp tc tc_args) args = (TyConApp tc [], tc_args ++ args)
290     split orig_ty (FunTy ty1 ty2)       args = ASSERT( null args )
291                                                (TyConApp funTyCon [], [ty1,ty2])
292     split orig_ty ty                    args = (orig_ty, args)
293
294 \end{code}
295
296
297 ---------------------------------------------------------------------
298                                 FunTy
299                                 ~~~~~
300
301 \begin{code}
302 mkFunTy :: Type -> Type -> Type
303 mkFunTy (PredTy (EqPred ty1 ty2)) res = mkForAllTy (mkWildCoVar (PredTy (EqPred ty1 ty2))) res
304 mkFunTy arg res = FunTy arg res
305
306 mkFunTys :: [Type] -> Type -> Type
307 mkFunTys tys ty = foldr mkFunTy ty tys
308
309 isFunTy :: Type -> Bool 
310 isFunTy ty = isJust (splitFunTy_maybe ty)
311
312 splitFunTy :: Type -> (Type, Type)
313 splitFunTy ty | Just ty' <- coreView ty = splitFunTy ty'
314 splitFunTy (FunTy arg res)   = (arg, res)
315 splitFunTy other             = pprPanic "splitFunTy" (ppr other)
316
317 splitFunTy_maybe :: Type -> Maybe (Type, Type)
318 splitFunTy_maybe ty | Just ty' <- coreView ty = splitFunTy_maybe ty'
319 splitFunTy_maybe (FunTy arg res)   = Just (arg, res)
320 splitFunTy_maybe other             = Nothing
321
322 splitFunTys :: Type -> ([Type], Type)
323 splitFunTys ty = split [] ty ty
324   where
325     split args orig_ty ty | Just ty' <- coreView ty = split args orig_ty ty'
326     split args orig_ty (FunTy arg res)   = split (arg:args) res res
327     split args orig_ty ty                = (reverse args, orig_ty)
328
329 splitFunTysN :: Int -> Type -> ([Type], Type)
330 -- Split off exactly n arg tys
331 splitFunTysN 0 ty = ([], ty)
332 splitFunTysN n ty = case splitFunTy ty of { (arg, res) ->
333                     case splitFunTysN (n-1) res of { (args, res) ->
334                     (arg:args, res) }}
335
336 zipFunTys :: Outputable a => [a] -> Type -> ([(a,Type)], Type)
337 zipFunTys orig_xs orig_ty = split [] orig_xs orig_ty orig_ty
338   where
339     split acc []     nty ty                = (reverse acc, nty)
340     split acc xs     nty ty 
341           | Just ty' <- coreView ty        = split acc xs nty ty'
342     split acc (x:xs) nty (FunTy arg res)   = split ((x,arg):acc) xs res res
343     split acc (x:xs) nty ty                = pprPanic "zipFunTys" (ppr orig_xs <+> ppr orig_ty)
344     
345 funResultTy :: Type -> Type
346 funResultTy ty | Just ty' <- coreView ty = funResultTy ty'
347 funResultTy (FunTy arg res)   = res
348 funResultTy ty                = pprPanic "funResultTy" (ppr ty)
349
350 funArgTy :: Type -> Type
351 funArgTy ty | Just ty' <- coreView ty = funArgTy ty'
352 funArgTy (FunTy arg res)   = arg
353 funArgTy ty                = pprPanic "funArgTy" (ppr ty)
354 \end{code}
355
356
357 ---------------------------------------------------------------------
358                                 TyConApp
359                                 ~~~~~~~~
360 @mkTyConApp@ is a key function, because it builds a TyConApp, FunTy or PredTy,
361 as apppropriate.
362
363 \begin{code}
364 mkTyConApp :: TyCon -> [Type] -> Type
365 mkTyConApp tycon tys
366   | isFunTyCon tycon, [ty1,ty2] <- tys
367   = FunTy ty1 ty2
368
369   | otherwise
370   = TyConApp tycon tys
371
372 mkTyConTy :: TyCon -> Type
373 mkTyConTy tycon = mkTyConApp tycon []
374
375 -- splitTyConApp "looks through" synonyms, because they don't
376 -- mean a distinct type, but all other type-constructor applications
377 -- including functions are returned as Just ..
378
379 tyConAppTyCon :: Type -> TyCon
380 tyConAppTyCon ty = fst (splitTyConApp ty)
381
382 tyConAppArgs :: Type -> [Type]
383 tyConAppArgs ty = snd (splitTyConApp ty)
384
385 splitTyConApp :: Type -> (TyCon, [Type])
386 splitTyConApp ty = case splitTyConApp_maybe ty of
387                         Just stuff -> stuff
388                         Nothing    -> pprPanic "splitTyConApp" (ppr ty)
389
390 splitTyConApp_maybe :: Type -> Maybe (TyCon, [Type])
391 splitTyConApp_maybe ty | Just ty' <- coreView ty = splitTyConApp_maybe ty'
392 splitTyConApp_maybe (TyConApp tc tys) = Just (tc, tys)
393 splitTyConApp_maybe (FunTy arg res)   = Just (funTyCon, [arg,res])
394 splitTyConApp_maybe other             = Nothing
395
396 -- Sometimes we do NOT want to look throught a newtype.  When case matching
397 -- on a newtype we want a convenient way to access the arguments of a newty
398 -- constructor so as to properly form a coercion.
399 splitNewTyConApp :: Type -> (TyCon, [Type])
400 splitNewTyConApp ty = case splitNewTyConApp_maybe ty of
401                         Just stuff -> stuff
402                         Nothing    -> pprPanic "splitNewTyConApp" (ppr ty)
403 splitNewTyConApp_maybe :: Type -> Maybe (TyCon, [Type])
404 splitNewTyConApp_maybe ty | Just ty' <- tcView ty = splitNewTyConApp_maybe ty'
405 splitNewTyConApp_maybe (TyConApp tc tys) = Just (tc, tys)
406 splitNewTyConApp_maybe (FunTy arg res)   = Just (funTyCon, [arg,res])
407 splitNewTyConApp_maybe other          = Nothing
408
409 -- get instantiated newtype rhs, the arguments had better saturate 
410 -- the constructor
411 newTyConInstRhs :: TyCon -> [Type] -> Type
412 newTyConInstRhs tycon tys =
413     let (tvs, ty) = newTyConRhs tycon in substTyWith tvs tys ty
414 \end{code}
415
416
417 ---------------------------------------------------------------------
418                                 SynTy
419                                 ~~~~~
420
421 Notes on type synonyms
422 ~~~~~~~~~~~~~~~~~~~~~~
423 The various "split" functions (splitFunTy, splitRhoTy, splitForAllTy) try
424 to return type synonyms whereever possible. Thus
425
426         type Foo a = a -> a
427
428 we want 
429         splitFunTys (a -> Foo a) = ([a], Foo a)
430 not                                ([a], a -> a)
431
432 The reason is that we then get better (shorter) type signatures in 
433 interfaces.  Notably this plays a role in tcTySigs in TcBinds.lhs.
434
435
436                 Representation types
437                 ~~~~~~~~~~~~~~~~~~~~
438 repType looks through 
439         (a) for-alls, and
440         (b) synonyms
441         (c) predicates
442         (d) usage annotations
443         (e) all newtypes, including recursive ones, but not newtype families
444 It's useful in the back end.
445
446 \begin{code}
447 repType :: Type -> Type
448 -- Only applied to types of kind *; hence tycons are saturated
449 repType ty | Just ty' <- coreView ty = repType ty'
450 repType (ForAllTy _ ty)  = repType ty
451 repType (TyConApp tc tys)
452   | isClosedNewTyCon tc  = -- Recursive newtypes are opaque to coreView
453                            -- but we must expand them here.  Sure to
454                            -- be saturated because repType is only applied
455                            -- to types of kind *
456                            ASSERT( {- isRecursiveTyCon tc && -} tys `lengthIs` tyConArity tc )
457                            repType (new_type_rep tc tys)
458 repType ty = ty
459
460 -- repType' aims to be a more thorough version of repType
461 -- For now it simply looks through the TyConApp args too
462 repType' ty -- | pprTrace "repType'" (ppr ty $$ ppr (go1 ty)) False = undefined
463             | otherwise = go1 ty 
464  where 
465         go1 = go . repType
466         go (TyConApp tc tys) = mkTyConApp tc (map repType' tys)
467         go ty = ty
468
469
470 -- new_type_rep doesn't ask any questions: 
471 -- it just expands newtype, whether recursive or not
472 new_type_rep new_tycon tys = ASSERT( tys `lengthIs` tyConArity new_tycon )
473                              case newTyConRep new_tycon of
474                                  (tvs, rep_ty) -> substTyWith tvs tys rep_ty
475
476 -- ToDo: this could be moved to the code generator, using splitTyConApp instead
477 -- of inspecting the type directly.
478 typePrimRep :: Type -> PrimRep
479 typePrimRep ty = case repType ty of
480                    TyConApp tc _ -> tyConPrimRep tc
481                    FunTy _ _     -> PtrRep
482                    AppTy _ _     -> PtrRep      -- See note below
483                    TyVarTy _     -> PtrRep
484                    other         -> pprPanic "typePrimRep" (ppr ty)
485         -- Types of the form 'f a' must be of kind *, not *#, so
486         -- we are guaranteed that they are represented by pointers.
487         -- The reason is that f must have kind *->*, not *->*#, because
488         -- (we claim) there is no way to constrain f's kind any other
489         -- way.
490
491 \end{code}
492
493
494 ---------------------------------------------------------------------
495                                 ForAllTy
496                                 ~~~~~~~~
497
498 \begin{code}
499 mkForAllTy :: TyVar -> Type -> Type
500 mkForAllTy tyvar ty
501   = mkForAllTys [tyvar] ty
502
503 mkForAllTys :: [TyVar] -> Type -> Type
504 mkForAllTys tyvars ty = foldr ForAllTy ty tyvars
505
506 isForAllTy :: Type -> Bool
507 isForAllTy (NoteTy _ ty)  = isForAllTy ty
508 isForAllTy (ForAllTy _ _) = True
509 isForAllTy other_ty       = False
510
511 splitForAllTy_maybe :: Type -> Maybe (TyVar, Type)
512 splitForAllTy_maybe ty = splitFAT_m ty
513   where
514     splitFAT_m ty | Just ty' <- coreView ty = splitFAT_m ty'
515     splitFAT_m (ForAllTy tyvar ty)          = Just(tyvar, ty)
516     splitFAT_m _                            = Nothing
517
518 splitForAllTys :: Type -> ([TyVar], Type)
519 splitForAllTys ty = split ty ty []
520    where
521      split orig_ty ty tvs | Just ty' <- coreView ty = split orig_ty ty' tvs
522      split orig_ty (ForAllTy tv ty)  tvs = split ty ty (tv:tvs)
523      split orig_ty t                 tvs = (reverse tvs, orig_ty)
524
525 dropForAlls :: Type -> Type
526 dropForAlls ty = snd (splitForAllTys ty)
527 \end{code}
528
529 -- (mkPiType now in CoreUtils)
530
531 applyTy, applyTys
532 ~~~~~~~~~~~~~~~~~
533 Instantiate a for-all type with one or more type arguments.
534 Used when we have a polymorphic function applied to type args:
535         f t1 t2
536 Then we use (applyTys type-of-f [t1,t2]) to compute the type of
537 the expression. 
538
539 \begin{code}
540 applyTy :: Type -> Type -> Type
541 applyTy ty arg | Just ty' <- coreView ty = applyTy ty' arg
542 applyTy (ForAllTy tv ty) arg = substTyWith [tv] [arg] ty
543 applyTy other            arg = panic "applyTy"
544
545 applyTys :: Type -> [Type] -> Type
546 -- This function is interesting because 
547 --      a) the function may have more for-alls than there are args
548 --      b) less obviously, it may have fewer for-alls
549 -- For case (b) think of 
550 --      applyTys (forall a.a) [forall b.b, Int]
551 -- This really can happen, via dressing up polymorphic types with newtype
552 -- clothing.  Here's an example:
553 --      newtype R = R (forall a. a->a)
554 --      foo = case undefined :: R of
555 --              R f -> f ()
556
557 applyTys orig_fun_ty []      = orig_fun_ty
558 applyTys orig_fun_ty arg_tys 
559   | n_tvs == n_args     -- The vastly common case
560   = substTyWith tvs arg_tys rho_ty
561   | n_tvs > n_args      -- Too many for-alls
562   = substTyWith (take n_args tvs) arg_tys 
563                 (mkForAllTys (drop n_args tvs) rho_ty)
564   | otherwise           -- Too many type args
565   = ASSERT2( n_tvs > 0, ppr orig_fun_ty )       -- Zero case gives infnite loop!
566     applyTys (substTyWith tvs (take n_tvs arg_tys) rho_ty)
567              (drop n_tvs arg_tys)
568   where
569     (tvs, rho_ty) = splitForAllTys orig_fun_ty 
570     n_tvs = length tvs
571     n_args = length arg_tys     
572 \end{code}
573
574
575 %************************************************************************
576 %*                                                                      *
577 \subsection{Source types}
578 %*                                                                      *
579 %************************************************************************
580
581 A "source type" is a type that is a separate type as far as the type checker is
582 concerned, but which has low-level representation as far as the back end is concerned.
583
584 Source types are always lifted.
585
586 The key function is predTypeRep which gives the representation of a source type:
587
588 \begin{code}
589 mkPredTy :: PredType -> Type
590 mkPredTy pred = PredTy pred
591
592 mkPredTys :: ThetaType -> [Type]
593 mkPredTys preds = map PredTy preds
594
595 predTypeRep :: PredType -> Type
596 -- Convert a PredType to its "representation type";
597 -- the post-type-checking type used by all the Core passes of GHC.
598 -- Unwraps only the outermost level; for example, the result might
599 -- be a newtype application
600 predTypeRep (IParam _ ty)     = ty
601 predTypeRep (ClassP clas tys) = mkTyConApp (classTyCon clas) tys
602         -- Result might be a newtype application, but the consumer will
603         -- look through that too if necessary
604 predTypeRep (EqPred ty1 ty2) = pprPanic "predTypeRep" (ppr (EqPred ty1 ty2))
605
606 -- The original head is the tycon and its variables for a vanilla tycon and it
607 -- is the family tycon and its type indexes for a family instance.
608 tyConOrigHead :: TyCon -> (TyCon, [Type])
609 tyConOrigHead tycon = case tyConFamInst_maybe tycon of
610                         Nothing      -> (tycon, mkTyVarTys (tyConTyVars tycon))
611                         Just famInst -> famInst
612
613 -- Pretty prints a tycon, using the family instance in case of a
614 -- representation tycon.
615 pprSourceTyCon tycon | Just (repTyCon, tys) <- tyConFamInst_maybe tycon =
616   ppr $ repTyCon `TyConApp` tys        -- can't be FunTyCon
617                      | otherwise                                        =
618   ppr tycon
619 \end{code}
620
621
622 %************************************************************************
623 %*                                                                      *
624                 NewTypes
625 %*                                                                      *
626 %************************************************************************
627
628 \begin{code}
629 splitRecNewType_maybe :: Type -> Maybe Type
630 -- Sometimes we want to look through a recursive newtype, and that's what happens here
631 -- It only strips *one layer* off, so the caller will usually call itself recursively
632 -- Only applied to types of kind *, hence the newtype is always saturated
633 splitRecNewType_maybe ty | Just ty' <- coreView ty = splitRecNewType_maybe ty'
634 splitRecNewType_maybe (TyConApp tc tys)
635   | isClosedNewTyCon tc
636   = ASSERT( tys `lengthIs` tyConArity tc )      -- splitRecNewType_maybe only be applied 
637                                                 --      to *types* (of kind *)
638     ASSERT( isRecursiveTyCon tc )               -- Guaranteed by coreView
639     case newTyConRhs tc of
640         (tvs, rep_ty) -> ASSERT( length tvs == length tys )
641                          Just (substTyWith tvs tys rep_ty)
642         
643 splitRecNewType_maybe other = Nothing
644
645
646
647 \end{code}
648
649
650 %************************************************************************
651 %*                                                                      *
652 \subsection{Kinds and free variables}
653 %*                                                                      *
654 %************************************************************************
655
656 ---------------------------------------------------------------------
657                 Finding the kind of a type
658                 ~~~~~~~~~~~~~~~~~~~~~~~~~~
659 \begin{code}
660 typeKind :: Type -> Kind
661 typeKind (TyConApp tycon tys) = ASSERT( not (isCoercionTyCon tycon) )
662                                    -- We should be looking for the coercion kind,
663                                    -- not the type kind
664                                 foldr (\_ k -> kindFunResult k) (tyConKind tycon) tys
665 typeKind (NoteTy _ ty)        = typeKind ty
666 typeKind (PredTy pred)        = predKind pred
667 typeKind (AppTy fun arg)      = kindFunResult (typeKind fun)
668 typeKind (ForAllTy tv ty)     = typeKind ty
669 typeKind (TyVarTy tyvar)      = tyVarKind tyvar
670 typeKind (FunTy arg res)
671     -- Hack alert.  The kind of (Int -> Int#) is liftedTypeKind (*), 
672     --              not unliftedTypKind (#)
673     -- The only things that can be after a function arrow are
674     --   (a) types (of kind openTypeKind or its sub-kinds)
675     --   (b) kinds (of super-kind TY) (e.g. * -> (* -> *))
676     | isTySuperKind k         = k
677     | otherwise               = ASSERT( isSubOpenTypeKind k) liftedTypeKind 
678     where
679       k = typeKind res
680
681 predKind :: PredType -> Kind
682 predKind (EqPred {}) = coSuperKind      -- A coercion kind!
683 predKind (ClassP {}) = liftedTypeKind   -- Class and implicitPredicates are
684 predKind (IParam {}) = liftedTypeKind   -- always represented by lifted types
685 \end{code}
686
687
688 ---------------------------------------------------------------------
689                 Free variables of a type
690                 ~~~~~~~~~~~~~~~~~~~~~~~~
691 \begin{code}
692 tyVarsOfType :: Type -> TyVarSet
693 -- NB: for type synonyms tyVarsOfType does *not* expand the synonym
694 tyVarsOfType (TyVarTy tv)               = unitVarSet tv
695 tyVarsOfType (TyConApp tycon tys)       = tyVarsOfTypes tys
696 tyVarsOfType (NoteTy (FTVNote tvs) ty2) = tvs
697 tyVarsOfType (PredTy sty)               = tyVarsOfPred sty
698 tyVarsOfType (FunTy arg res)            = tyVarsOfType arg `unionVarSet` tyVarsOfType res
699 tyVarsOfType (AppTy fun arg)            = tyVarsOfType fun `unionVarSet` tyVarsOfType arg
700 tyVarsOfType (ForAllTy tyvar ty)        = delVarSet (tyVarsOfType ty) tyvar
701
702 tyVarsOfTypes :: [Type] -> TyVarSet
703 tyVarsOfTypes tys = foldr (unionVarSet.tyVarsOfType) emptyVarSet tys
704
705 tyVarsOfPred :: PredType -> TyVarSet
706 tyVarsOfPred (IParam _ ty)    = tyVarsOfType ty
707 tyVarsOfPred (ClassP _ tys)   = tyVarsOfTypes tys
708 tyVarsOfPred (EqPred ty1 ty2) = tyVarsOfType ty1 `unionVarSet` tyVarsOfType ty2
709
710 tyVarsOfTheta :: ThetaType -> TyVarSet
711 tyVarsOfTheta = foldr (unionVarSet . tyVarsOfPred) emptyVarSet
712
713 -- Add a Note with the free tyvars to the top of the type
714 addFreeTyVars :: Type -> Type
715 addFreeTyVars ty@(NoteTy (FTVNote _) _)      = ty
716 addFreeTyVars ty                             = NoteTy (FTVNote (tyVarsOfType ty)) ty
717 \end{code}
718
719
720 %************************************************************************
721 %*                                                                      *
722 \subsection{TidyType}
723 %*                                                                      *
724 %************************************************************************
725
726 tidyTy tidies up a type for printing in an error message, or in
727 an interface file.
728
729 It doesn't change the uniques at all, just the print names.
730
731 \begin{code}
732 tidyTyVarBndr :: TidyEnv -> TyVar -> (TidyEnv, TyVar)
733 tidyTyVarBndr (tidy_env, subst) tyvar
734   = case tidyOccName tidy_env (getOccName name) of
735       (tidy', occ') ->  ((tidy', subst'), tyvar')
736                     where
737                         subst' = extendVarEnv subst tyvar tyvar'
738                         tyvar' = setTyVarName tyvar name'
739                         name'  = tidyNameOcc name occ'
740   where
741     name = tyVarName tyvar
742
743 tidyFreeTyVars :: TidyEnv -> TyVarSet -> TidyEnv
744 -- Add the free tyvars to the env in tidy form,
745 -- so that we can tidy the type they are free in
746 tidyFreeTyVars env tyvars = fst (tidyOpenTyVars env (varSetElems tyvars))
747
748 tidyOpenTyVars :: TidyEnv -> [TyVar] -> (TidyEnv, [TyVar])
749 tidyOpenTyVars env tyvars = mapAccumL tidyOpenTyVar env tyvars
750
751 tidyOpenTyVar :: TidyEnv -> TyVar -> (TidyEnv, TyVar)
752 -- Treat a new tyvar as a binder, and give it a fresh tidy name
753 tidyOpenTyVar env@(tidy_env, subst) tyvar
754   = case lookupVarEnv subst tyvar of
755         Just tyvar' -> (env, tyvar')            -- Already substituted
756         Nothing     -> tidyTyVarBndr env tyvar  -- Treat it as a binder
757
758 tidyType :: TidyEnv -> Type -> Type
759 tidyType env@(tidy_env, subst) ty
760   = go ty
761   where
762     go (TyVarTy tv)         = case lookupVarEnv subst tv of
763                                 Nothing  -> TyVarTy tv
764                                 Just tv' -> TyVarTy tv'
765     go (TyConApp tycon tys) = let args = map go tys
766                               in args `seqList` TyConApp tycon args
767     go (NoteTy note ty)     = (NoteTy $! (go_note note)) $! (go ty)
768     go (PredTy sty)         = PredTy (tidyPred env sty)
769     go (AppTy fun arg)      = (AppTy $! (go fun)) $! (go arg)
770     go (FunTy fun arg)      = (FunTy $! (go fun)) $! (go arg)
771     go (ForAllTy tv ty)     = ForAllTy tvp $! (tidyType envp ty)
772                               where
773                                 (envp, tvp) = tidyTyVarBndr env tv
774
775     go_note note@(FTVNote ftvs) = note  -- No need to tidy the free tyvars
776
777 tidyTypes env tys = map (tidyType env) tys
778
779 tidyPred :: TidyEnv -> PredType -> PredType
780 tidyPred env (IParam n ty)     = IParam n (tidyType env ty)
781 tidyPred env (ClassP clas tys) = ClassP clas (tidyTypes env tys)
782 tidyPred env (EqPred ty1 ty2)  = EqPred (tidyType env ty1) (tidyType env ty2)
783 \end{code}
784
785
786 @tidyOpenType@ grabs the free type variables, tidies them
787 and then uses @tidyType@ to work over the type itself
788
789 \begin{code}
790 tidyOpenType :: TidyEnv -> Type -> (TidyEnv, Type)
791 tidyOpenType env ty
792   = (env', tidyType env' ty)
793   where
794     env' = tidyFreeTyVars env (tyVarsOfType ty)
795
796 tidyOpenTypes :: TidyEnv -> [Type] -> (TidyEnv, [Type])
797 tidyOpenTypes env tys = mapAccumL tidyOpenType env tys
798
799 tidyTopType :: Type -> Type
800 tidyTopType ty = tidyType emptyTidyEnv ty
801 \end{code}
802
803 \begin{code}
804
805 tidyKind :: TidyEnv -> Kind -> (TidyEnv, Kind)
806 tidyKind env k = tidyOpenType env k
807
808 \end{code}
809
810
811 %************************************************************************
812 %*                                                                      *
813 \subsection{Liftedness}
814 %*                                                                      *
815 %************************************************************************
816
817 \begin{code}
818 isUnLiftedType :: Type -> Bool
819         -- isUnLiftedType returns True for forall'd unlifted types:
820         --      x :: forall a. Int#
821         -- I found bindings like these were getting floated to the top level.
822         -- They are pretty bogus types, mind you.  It would be better never to
823         -- construct them
824
825 isUnLiftedType ty | Just ty' <- coreView ty = isUnLiftedType ty'
826 isUnLiftedType (ForAllTy tv ty)  = isUnLiftedType ty
827 isUnLiftedType (TyConApp tc _)   = isUnLiftedTyCon tc
828 isUnLiftedType other             = False        
829
830 isUnboxedTupleType :: Type -> Bool
831 isUnboxedTupleType ty = case splitTyConApp_maybe ty of
832                            Just (tc, ty_args) -> isUnboxedTupleTyCon tc
833                            other              -> False
834
835 -- Should only be applied to *types*; hence the assert
836 isAlgType :: Type -> Bool
837 isAlgType ty = case splitTyConApp_maybe ty of
838                         Just (tc, ty_args) -> ASSERT( ty_args `lengthIs` tyConArity tc )
839                                               isAlgTyCon tc
840                         other              -> False
841 \end{code}
842
843 @isStrictType@ computes whether an argument (or let RHS) should
844 be computed strictly or lazily, based only on its type.
845 Works just like isUnLiftedType, except that it has a special case 
846 for dictionaries.  Since it takes account of ClassP, you might think
847 this function should be in TcType, but isStrictType is used by DataCon,
848 which is below TcType in the hierarchy, so it's convenient to put it here.
849
850 \begin{code}
851 isStrictType (PredTy pred)     = isStrictPred pred
852 isStrictType ty | Just ty' <- coreView ty = isStrictType ty'
853 isStrictType (ForAllTy tv ty)  = isStrictType ty
854 isStrictType (TyConApp tc _)   = isUnLiftedTyCon tc
855 isStrictType other             = False  
856
857 isStrictPred (ClassP clas _) = opt_DictsStrict && not (isNewTyCon (classTyCon clas))
858 isStrictPred other           = False
859         -- We may be strict in dictionary types, but only if it 
860         -- has more than one component.
861         -- [Being strict in a single-component dictionary risks
862         --  poking the dictionary component, which is wrong.]
863 \end{code}
864
865 \begin{code}
866 isPrimitiveType :: Type -> Bool
867 -- Returns types that are opaque to Haskell.
868 -- Most of these are unlifted, but now that we interact with .NET, we
869 -- may have primtive (foreign-imported) types that are lifted
870 isPrimitiveType ty = case splitTyConApp_maybe ty of
871                         Just (tc, ty_args) -> ASSERT( ty_args `lengthIs` tyConArity tc )
872                                               isPrimTyCon tc
873                         other              -> False
874 \end{code}
875
876
877 %************************************************************************
878 %*                                                                      *
879 \subsection{Sequencing on types
880 %*                                                                      *
881 %************************************************************************
882
883 \begin{code}
884 seqType :: Type -> ()
885 seqType (TyVarTy tv)      = tv `seq` ()
886 seqType (AppTy t1 t2)     = seqType t1 `seq` seqType t2
887 seqType (FunTy t1 t2)     = seqType t1 `seq` seqType t2
888 seqType (NoteTy note t2)  = seqNote note `seq` seqType t2
889 seqType (PredTy p)        = seqPred p
890 seqType (TyConApp tc tys) = tc `seq` seqTypes tys
891 seqType (ForAllTy tv ty)  = tv `seq` seqType ty
892
893 seqTypes :: [Type] -> ()
894 seqTypes []       = ()
895 seqTypes (ty:tys) = seqType ty `seq` seqTypes tys
896
897 seqNote :: TyNote -> ()
898 seqNote (FTVNote set) = sizeUniqSet set `seq` ()
899
900 seqPred :: PredType -> ()
901 seqPred (ClassP c tys)   = c `seq` seqTypes tys
902 seqPred (IParam n ty)    = n `seq` seqType ty
903 seqPred (EqPred ty1 ty2) = seqType ty1 `seq` seqType ty2
904 \end{code}
905
906
907 %************************************************************************
908 %*                                                                      *
909                 Equality for Core types 
910         (We don't use instances so that we know where it happens)
911 %*                                                                      *
912 %************************************************************************
913
914 Note that eqType works right even for partial applications of newtypes.
915 See Note [Newtype eta] in TyCon.lhs
916
917 \begin{code}
918 coreEqType :: Type -> Type -> Bool
919 coreEqType t1 t2
920   = eq rn_env t1 t2
921   where
922     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfType t1 `unionVarSet` tyVarsOfType t2))
923
924     eq env (TyVarTy tv1)       (TyVarTy tv2)     = rnOccL env tv1 == rnOccR env tv2
925     eq env (ForAllTy tv1 t1)   (ForAllTy tv2 t2) = eq (rnBndr2 env tv1 tv2) t1 t2
926     eq env (AppTy s1 t1)       (AppTy s2 t2)     = eq env s1 s2 && eq env t1 t2
927     eq env (FunTy s1 t1)       (FunTy s2 t2)     = eq env s1 s2 && eq env t1 t2
928     eq env (TyConApp tc1 tys1) (TyConApp tc2 tys2) 
929         | tc1 == tc2, all2 (eq env) tys1 tys2 = True
930                         -- The lengths should be equal because
931                         -- the two types have the same kind
932         -- NB: if the type constructors differ that does not 
933         --     necessarily mean that the types aren't equal
934         --     (synonyms, newtypes)
935         -- Even if the type constructors are the same, but the arguments
936         -- differ, the two types could be the same (e.g. if the arg is just
937         -- ignored in the RHS).  In both these cases we fall through to an 
938         -- attempt to expand one side or the other.
939
940         -- Now deal with newtypes, synonyms, pred-tys
941     eq env t1 t2 | Just t1' <- coreView t1 = eq env t1' t2 
942                  | Just t2' <- coreView t2 = eq env t1 t2' 
943
944         -- Fall through case; not equal!
945     eq env t1 t2 = False
946 \end{code}
947
948
949 %************************************************************************
950 %*                                                                      *
951                 Comparision for source types 
952         (We don't use instances so that we know where it happens)
953 %*                                                                      *
954 %************************************************************************
955
956 Note that 
957         tcEqType, tcCmpType 
958 do *not* look through newtypes, PredTypes
959
960 \begin{code}
961 tcEqType :: Type -> Type -> Bool
962 tcEqType t1 t2 = isEqual $ cmpType t1 t2
963
964 tcEqTypes :: [Type] -> [Type] -> Bool
965 tcEqTypes tys1 tys2 = isEqual $ cmpTypes tys1 tys2
966
967 tcCmpType :: Type -> Type -> Ordering
968 tcCmpType t1 t2 = cmpType t1 t2
969
970 tcCmpTypes :: [Type] -> [Type] -> Ordering
971 tcCmpTypes tys1 tys2 = cmpTypes tys1 tys2
972
973 tcEqPred :: PredType -> PredType -> Bool
974 tcEqPred p1 p2 = isEqual $ cmpPred p1 p2
975
976 tcCmpPred :: PredType -> PredType -> Ordering
977 tcCmpPred p1 p2 = cmpPred p1 p2
978
979 tcEqTypeX :: RnEnv2 -> Type -> Type -> Bool
980 tcEqTypeX env t1 t2 = isEqual $ cmpTypeX env t1 t2
981 \end{code}
982
983 Now here comes the real worker
984
985 \begin{code}
986 cmpType :: Type -> Type -> Ordering
987 cmpType t1 t2 = cmpTypeX rn_env t1 t2
988   where
989     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfType t1 `unionVarSet` tyVarsOfType t2))
990
991 cmpTypes :: [Type] -> [Type] -> Ordering
992 cmpTypes ts1 ts2 = cmpTypesX rn_env ts1 ts2
993   where
994     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfTypes ts1 `unionVarSet` tyVarsOfTypes ts2))
995
996 cmpPred :: PredType -> PredType -> Ordering
997 cmpPred p1 p2 = cmpPredX rn_env p1 p2
998   where
999     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfPred p1 `unionVarSet` tyVarsOfPred p2))
1000
1001 cmpTypeX :: RnEnv2 -> Type -> Type -> Ordering  -- Main workhorse
1002 cmpTypeX env t1 t2 | Just t1' <- tcView t1 = cmpTypeX env t1' t2
1003                    | Just t2' <- tcView t2 = cmpTypeX env t1 t2'
1004
1005 cmpTypeX env (TyVarTy tv1)       (TyVarTy tv2)       = rnOccL env tv1 `compare` rnOccR env tv2
1006 cmpTypeX env (ForAllTy tv1 t1)   (ForAllTy tv2 t2)   = cmpTypeX (rnBndr2 env tv1 tv2) t1 t2
1007 cmpTypeX env (AppTy s1 t1)       (AppTy s2 t2)       = cmpTypeX env s1 s2 `thenCmp` cmpTypeX env t1 t2
1008 cmpTypeX env (FunTy s1 t1)       (FunTy s2 t2)       = cmpTypeX env s1 s2 `thenCmp` cmpTypeX env t1 t2
1009 cmpTypeX env (PredTy p1)         (PredTy p2)         = cmpPredX env p1 p2
1010 cmpTypeX env (TyConApp tc1 tys1) (TyConApp tc2 tys2) = (tc1 `compare` tc2) `thenCmp` cmpTypesX env tys1 tys2
1011 cmpTypeX env t1                 (NoteTy _ t2)        = cmpTypeX env t1 t2
1012
1013     -- Deal with the rest: TyVarTy < AppTy < FunTy < TyConApp < ForAllTy < PredTy
1014 cmpTypeX env (AppTy _ _) (TyVarTy _) = GT
1015     
1016 cmpTypeX env (FunTy _ _) (TyVarTy _) = GT
1017 cmpTypeX env (FunTy _ _) (AppTy _ _) = GT
1018     
1019 cmpTypeX env (TyConApp _ _) (TyVarTy _) = GT
1020 cmpTypeX env (TyConApp _ _) (AppTy _ _) = GT
1021 cmpTypeX env (TyConApp _ _) (FunTy _ _) = GT
1022     
1023 cmpTypeX env (ForAllTy _ _) (TyVarTy _)    = GT
1024 cmpTypeX env (ForAllTy _ _) (AppTy _ _)    = GT
1025 cmpTypeX env (ForAllTy _ _) (FunTy _ _)    = GT
1026 cmpTypeX env (ForAllTy _ _) (TyConApp _ _) = GT
1027
1028 cmpTypeX env (PredTy _)   t2            = GT
1029
1030 cmpTypeX env _ _ = LT
1031
1032 -------------
1033 cmpTypesX :: RnEnv2 -> [Type] -> [Type] -> Ordering
1034 cmpTypesX env []        []        = EQ
1035 cmpTypesX env (t1:tys1) (t2:tys2) = cmpTypeX env t1 t2 `thenCmp` cmpTypesX env tys1 tys2
1036 cmpTypesX env []        tys       = LT
1037 cmpTypesX env ty        []        = GT
1038
1039 -------------
1040 cmpPredX :: RnEnv2 -> PredType -> PredType -> Ordering
1041 cmpPredX env (IParam n1 ty1) (IParam n2 ty2) = (n1 `compare` n2) `thenCmp` cmpTypeX env ty1 ty2
1042         -- Compare names only for implicit parameters
1043         -- This comparison is used exclusively (I believe) 
1044         -- for the Avails finite map built in TcSimplify
1045         -- If the types differ we keep them distinct so that we see 
1046         -- a distinct pair to run improvement on 
1047 cmpPredX env (ClassP c1 tys1) (ClassP c2 tys2) = (c1 `compare` c2) `thenCmp` (cmpTypesX env tys1 tys2)
1048 cmpPredX env (EqPred ty1 ty2) (EqPred ty1' ty2') = (cmpTypeX env ty1 ty1') `thenCmp` (cmpTypeX env ty2 ty2')
1049
1050 -- Constructor order: IParam < ClassP < EqPred
1051 cmpPredX env (IParam {})     _              = LT
1052 cmpPredX env (ClassP {})    (IParam {})     = GT
1053 cmpPredX env (ClassP {})    (EqPred {})     = LT
1054 cmpPredX env (EqPred {})    _               = GT
1055 \end{code}
1056
1057 PredTypes are used as a FM key in TcSimplify, 
1058 so we take the easy path and make them an instance of Ord
1059
1060 \begin{code}
1061 instance Eq  PredType where { (==)    = tcEqPred }
1062 instance Ord PredType where { compare = tcCmpPred }
1063 \end{code}
1064
1065
1066 %************************************************************************
1067 %*                                                                      *
1068                 Type substitutions
1069 %*                                                                      *
1070 %************************************************************************
1071
1072 \begin{code}
1073 data TvSubst            
1074   = TvSubst InScopeSet  -- The in-scope type variables
1075             TvSubstEnv  -- The substitution itself
1076         -- See Note [Apply Once]
1077         -- and Note [Extending the TvSubstEnv]
1078
1079 {- ----------------------------------------------------------
1080
1081 Note [Apply Once]
1082 ~~~~~~~~~~~~~~~~~
1083 We use TvSubsts to instantiate things, and we might instantiate
1084         forall a b. ty
1085 \with the types
1086         [a, b], or [b, a].
1087 So the substition might go [a->b, b->a].  A similar situation arises in Core
1088 when we find a beta redex like
1089         (/\ a /\ b -> e) b a
1090 Then we also end up with a substition that permutes type variables. Other
1091 variations happen to; for example [a -> (a, b)].  
1092
1093         ***************************************************
1094         *** So a TvSubst must be applied precisely once ***
1095         ***************************************************
1096
1097 A TvSubst is not idempotent, but, unlike the non-idempotent substitution
1098 we use during unifications, it must not be repeatedly applied.
1099
1100 Note [Extending the TvSubst]
1101 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1102 The following invariant should hold of a TvSubst
1103
1104         The in-scope set is needed *only* to
1105         guide the generation of fresh uniques
1106
1107         In particular, the *kind* of the type variables in 
1108         the in-scope set is not relevant
1109
1110 This invariant allows a short-cut when the TvSubstEnv is empty:
1111 if the TvSubstEnv is empty --- i.e. (isEmptyTvSubt subst) holds ---
1112 then (substTy subst ty) does nothing.
1113
1114 For example, consider:
1115         (/\a. /\b:(a~Int). ...b..) Int
1116 We substitute Int for 'a'.  The Unique of 'b' does not change, but
1117 nevertheless we add 'b' to the TvSubstEnv, because b's type does change
1118
1119 This invariant has several crucial consequences:
1120
1121 * In substTyVarBndr, we need extend the TvSubstEnv 
1122         - if the unique has changed
1123         - or if the kind has changed
1124
1125 * In substTyVar, we do not need to consult the in-scope set;
1126   the TvSubstEnv is enough
1127
1128 * In substTy, substTheta, we can short-circuit when the TvSubstEnv is empty
1129   
1130
1131 -------------------------------------------------------------- -}
1132
1133
1134 type TvSubstEnv = TyVarEnv Type
1135         -- A TvSubstEnv is used both inside a TvSubst (with the apply-once
1136         -- invariant discussed in Note [Apply Once]), and also independently
1137         -- in the middle of matching, and unification (see Types.Unify)
1138         -- So you have to look at the context to know if it's idempotent or
1139         -- apply-once or whatever
1140 emptyTvSubstEnv :: TvSubstEnv
1141 emptyTvSubstEnv = emptyVarEnv
1142
1143 composeTvSubst :: InScopeSet -> TvSubstEnv -> TvSubstEnv -> TvSubstEnv
1144 -- (compose env1 env2)(x) is env1(env2(x)); i.e. apply env2 then env1
1145 -- It assumes that both are idempotent
1146 -- Typically, env1 is the refinement to a base substitution env2
1147 composeTvSubst in_scope env1 env2
1148   = env1 `plusVarEnv` mapVarEnv (substTy subst1) env2
1149         -- First apply env1 to the range of env2
1150         -- Then combine the two, making sure that env1 loses if
1151         -- both bind the same variable; that's why env1 is the
1152         --  *left* argument to plusVarEnv, because the right arg wins
1153   where
1154     subst1 = TvSubst in_scope env1
1155
1156 emptyTvSubst = TvSubst emptyInScopeSet emptyVarEnv
1157
1158 isEmptyTvSubst :: TvSubst -> Bool
1159          -- See Note [Extending the TvSubstEnv]
1160 isEmptyTvSubst (TvSubst _ env) = isEmptyVarEnv env
1161
1162 mkTvSubst :: InScopeSet -> TvSubstEnv -> TvSubst
1163 mkTvSubst = TvSubst
1164
1165 getTvSubstEnv :: TvSubst -> TvSubstEnv
1166 getTvSubstEnv (TvSubst _ env) = env
1167
1168 getTvInScope :: TvSubst -> InScopeSet
1169 getTvInScope (TvSubst in_scope _) = in_scope
1170
1171 isInScope :: Var -> TvSubst -> Bool
1172 isInScope v (TvSubst in_scope _) = v `elemInScopeSet` in_scope
1173
1174 notElemTvSubst :: TyVar -> TvSubst -> Bool
1175 notElemTvSubst tv (TvSubst _ env) = not (tv `elemVarEnv` env)
1176
1177 setTvSubstEnv :: TvSubst -> TvSubstEnv -> TvSubst
1178 setTvSubstEnv (TvSubst in_scope _) env = TvSubst in_scope env
1179
1180 extendTvInScope :: TvSubst -> [Var] -> TvSubst
1181 extendTvInScope (TvSubst in_scope env) vars = TvSubst (extendInScopeSetList in_scope vars) env
1182
1183 extendTvSubst :: TvSubst -> TyVar -> Type -> TvSubst
1184 extendTvSubst (TvSubst in_scope env) tv ty = TvSubst in_scope (extendVarEnv env tv ty)
1185
1186 extendTvSubstList :: TvSubst -> [TyVar] -> [Type] -> TvSubst
1187 extendTvSubstList (TvSubst in_scope env) tvs tys 
1188   = TvSubst in_scope (extendVarEnvList env (tvs `zip` tys))
1189
1190 -- mkOpenTvSubst and zipOpenTvSubst generate the in-scope set from
1191 -- the types given; but it's just a thunk so with a bit of luck
1192 -- it'll never be evaluated
1193
1194 mkOpenTvSubst :: TvSubstEnv -> TvSubst
1195 mkOpenTvSubst env = TvSubst (mkInScopeSet (tyVarsOfTypes (varEnvElts env))) env
1196
1197 zipOpenTvSubst :: [TyVar] -> [Type] -> TvSubst
1198 zipOpenTvSubst tyvars tys 
1199 #ifdef DEBUG
1200   | length tyvars /= length tys
1201   = pprTrace "zipOpenTvSubst" (ppr tyvars $$ ppr tys) emptyTvSubst
1202   | otherwise
1203 #endif
1204   = TvSubst (mkInScopeSet (tyVarsOfTypes tys)) (zipTyEnv tyvars tys)
1205
1206 -- mkTopTvSubst is called when doing top-level substitutions.
1207 -- Here we expect that the free vars of the range of the
1208 -- substitution will be empty.
1209 mkTopTvSubst :: [(TyVar, Type)] -> TvSubst
1210 mkTopTvSubst prs = TvSubst emptyInScopeSet (mkVarEnv prs)
1211
1212 zipTopTvSubst :: [TyVar] -> [Type] -> TvSubst
1213 zipTopTvSubst tyvars tys 
1214 #ifdef DEBUG
1215   | length tyvars /= length tys
1216   = pprTrace "zipOpenTvSubst" (ppr tyvars $$ ppr tys) emptyTvSubst
1217   | otherwise
1218 #endif
1219   = TvSubst emptyInScopeSet (zipTyEnv tyvars tys)
1220
1221 zipTyEnv :: [TyVar] -> [Type] -> TvSubstEnv
1222 zipTyEnv tyvars tys
1223 #ifdef DEBUG
1224   | length tyvars /= length tys
1225   = pprTrace "mkTopTvSubst" (ppr tyvars $$ ppr tys) emptyVarEnv
1226   | otherwise
1227 #endif
1228   = zip_ty_env tyvars tys emptyVarEnv
1229
1230 -- Later substitutions in the list over-ride earlier ones, 
1231 -- but there should be no loops
1232 zip_ty_env []       []       env = env
1233 zip_ty_env (tv:tvs) (ty:tys) env = zip_ty_env tvs tys (extendVarEnv env tv ty)
1234         -- There used to be a special case for when 
1235         --      ty == TyVarTy tv
1236         -- (a not-uncommon case) in which case the substitution was dropped.
1237         -- But the type-tidier changes the print-name of a type variable without
1238         -- changing the unique, and that led to a bug.   Why?  Pre-tidying, we had 
1239         -- a type {Foo t}, where Foo is a one-method class.  So Foo is really a newtype.
1240         -- And it happened that t was the type variable of the class.  Post-tiding, 
1241         -- it got turned into {Foo t2}.  The ext-core printer expanded this using
1242         -- sourceTypeRep, but that said "Oh, t == t2" because they have the same unique,
1243         -- and so generated a rep type mentioning t not t2.  
1244         --
1245         -- Simplest fix is to nuke the "optimisation"
1246 zip_ty_env tvs      tys      env   = pprTrace "Var/Type length mismatch: " (ppr tvs $$ ppr tys) env
1247 -- zip_ty_env _ _ env = env
1248
1249 instance Outputable TvSubst where
1250   ppr (TvSubst ins env) 
1251     = brackets $ sep[ ptext SLIT("TvSubst"),
1252                       nest 2 (ptext SLIT("In scope:") <+> ppr ins), 
1253                       nest 2 (ptext SLIT("Env:") <+> ppr env) ]
1254 \end{code}
1255
1256 %************************************************************************
1257 %*                                                                      *
1258                 Performing type substitutions
1259 %*                                                                      *
1260 %************************************************************************
1261
1262 \begin{code}
1263 substTyWith :: [TyVar] -> [Type] -> Type -> Type
1264 substTyWith tvs tys = ASSERT( length tvs == length tys )
1265                       substTy (zipOpenTvSubst tvs tys)
1266
1267 substTy :: TvSubst -> Type  -> Type
1268 substTy subst ty | isEmptyTvSubst subst = ty
1269                  | otherwise            = subst_ty subst ty
1270
1271 substTys :: TvSubst -> [Type] -> [Type]
1272 substTys subst tys | isEmptyTvSubst subst = tys
1273                    | otherwise            = map (subst_ty subst) tys
1274
1275 substTheta :: TvSubst -> ThetaType -> ThetaType
1276 substTheta subst theta
1277   | isEmptyTvSubst subst = theta
1278   | otherwise            = map (substPred subst) theta
1279
1280 substPred :: TvSubst -> PredType -> PredType
1281 substPred subst (IParam n ty)     = IParam n (subst_ty subst ty)
1282 substPred subst (ClassP clas tys) = ClassP clas (map (subst_ty subst) tys)
1283 substPred subst (EqPred ty1 ty2)  = EqPred (subst_ty subst ty1) (subst_ty subst ty2)
1284
1285 deShadowTy :: TyVarSet -> Type -> Type  -- Remove any nested binders mentioning tvs
1286 deShadowTy tvs ty 
1287   = subst_ty (mkTvSubst in_scope emptyTvSubstEnv) ty
1288   where
1289     in_scope = mkInScopeSet tvs
1290
1291 subst_ty :: TvSubst -> Type -> Type
1292 -- subst_ty is the main workhorse for type substitution
1293 --
1294 -- Note that the in_scope set is poked only if we hit a forall
1295 -- so it may often never be fully computed 
1296 subst_ty subst ty
1297    = go ty
1298   where
1299     go (TyVarTy tv)                = substTyVar subst tv
1300     go (TyConApp tc tys)           = let args = map go tys
1301                                      in  args `seqList` TyConApp tc args
1302
1303     go (PredTy p)                  = PredTy $! (substPred subst p)
1304
1305     go (NoteTy (FTVNote _) ty2)    = go ty2             -- Discard the free tyvar note
1306
1307     go (FunTy arg res)             = (FunTy $! (go arg)) $! (go res)
1308     go (AppTy fun arg)             = mkAppTy (go fun) $! (go arg)
1309                 -- The mkAppTy smart constructor is important
1310                 -- we might be replacing (a Int), represented with App
1311                 -- by [Int], represented with TyConApp
1312     go (ForAllTy tv ty)            = case substTyVarBndr subst tv of
1313                                         (subst', tv') -> ForAllTy tv' $! (subst_ty subst' ty)
1314
1315 substTyVar :: TvSubst -> TyVar  -> Type
1316 substTyVar subst@(TvSubst in_scope env) tv
1317   = case lookupTyVar subst tv of {
1318         Nothing -> TyVarTy tv;
1319         Just ty -> ty   -- See Note [Apply Once]
1320     } 
1321
1322 substTyVars :: TvSubst -> [TyVar] -> [Type]
1323 substTyVars subst tvs = map (substTyVar subst) tvs
1324
1325 lookupTyVar :: TvSubst -> TyVar  -> Maybe Type
1326         -- See Note [Extending the TvSubst]
1327 lookupTyVar (TvSubst in_scope env) tv = lookupVarEnv env tv
1328
1329 substTyVarBndr :: TvSubst -> TyVar -> (TvSubst, TyVar)  
1330 substTyVarBndr subst@(TvSubst in_scope env) old_var
1331   = (TvSubst (in_scope `extendInScopeSet` new_var) new_env, new_var)
1332   where
1333     is_co_var = isCoVar old_var
1334
1335     new_env | no_change = delVarEnv env old_var
1336             | otherwise = extendVarEnv env old_var (TyVarTy new_var)
1337
1338     no_change = new_var == old_var && not is_co_var
1339         -- no_change means that the new_var is identical in
1340         -- all respects to the old_var (same unique, same kind)
1341         -- See Note [Extending the TvSubst]
1342         --
1343         -- In that case we don't need to extend the substitution
1344         -- to map old to new.  But instead we must zap any 
1345         -- current substitution for the variable. For example:
1346         --      (\x.e) with id_subst = [x |-> e']
1347         -- Here we must simply zap the substitution for x
1348
1349     new_var = uniqAway in_scope subst_old_var
1350         -- The uniqAway part makes sure the new variable is not already in scope
1351
1352     subst_old_var -- subst_old_var is old_var with the substitution applied to its kind
1353                   -- It's only worth doing the substitution for coercions,
1354                   -- becuase only they can have free type variables
1355         | is_co_var = setTyVarKind old_var (substTy subst (tyVarKind old_var))
1356         | otherwise = old_var
1357 \end{code}
1358
1359 ----------------------------------------------------
1360 -- Kind Stuff
1361
1362 Kinds
1363 ~~~~~
1364 There's a little subtyping at the kind level:  
1365
1366                  ?
1367                 / \
1368                /   \
1369               ??   (#)
1370              /  \
1371             *   #
1372
1373 where   *    [LiftedTypeKind]   means boxed type
1374         #    [UnliftedTypeKind] means unboxed type
1375         (#)  [UbxTupleKind]     means unboxed tuple
1376         ??   [ArgTypeKind]      is the lub of *,#
1377         ?    [OpenTypeKind]     means any type at all
1378
1379 In particular:
1380
1381         error :: forall a:?. String -> a
1382         (->)  :: ?? -> ? -> *
1383         (\(x::t) -> ...)        Here t::?? (i.e. not unboxed tuple)
1384
1385 \begin{code}
1386 type KindVar = TyVar  -- invariant: KindVar will always be a 
1387                       -- TcTyVar with details MetaTv TauTv ...
1388 -- kind var constructors and functions are in TcType
1389
1390 type SimpleKind = Kind
1391 \end{code}
1392
1393 Kind inference
1394 ~~~~~~~~~~~~~~
1395 During kind inference, a kind variable unifies only with 
1396 a "simple kind", sk
1397         sk ::= * | sk1 -> sk2
1398 For example 
1399         data T a = MkT a (T Int#)
1400 fails.  We give T the kind (k -> *), and the kind variable k won't unify
1401 with # (the kind of Int#).
1402
1403 Type inference
1404 ~~~~~~~~~~~~~~
1405 When creating a fresh internal type variable, we give it a kind to express 
1406 constraints on it.  E.g. in (\x->e) we make up a fresh type variable for x, 
1407 with kind ??.  
1408
1409 During unification we only bind an internal type variable to a type
1410 whose kind is lower in the sub-kind hierarchy than the kind of the tyvar.
1411
1412 When unifying two internal type variables, we collect their kind constraints by
1413 finding the GLB of the two.  Since the partial order is a tree, they only
1414 have a glb if one is a sub-kind of the other.  In that case, we bind the
1415 less-informative one to the more informative one.  Neat, eh?
1416
1417
1418 \begin{code}
1419
1420 \end{code}
1421
1422 %************************************************************************
1423 %*                                                                      *
1424         Functions over Kinds            
1425 %*                                                                      *
1426 %************************************************************************
1427
1428 \begin{code}
1429 kindFunResult :: Kind -> Kind
1430 kindFunResult k = funResultTy k
1431
1432 splitKindFunTys :: Kind -> ([Kind],Kind)
1433 splitKindFunTys k = splitFunTys k
1434
1435 splitKindFunTysN :: Int -> Kind -> ([Kind],Kind)
1436 splitKindFunTysN k = splitFunTysN k
1437
1438 isUbxTupleKind, isOpenTypeKind, isArgTypeKind, isUnliftedTypeKind :: Kind -> Bool
1439
1440 isOpenTypeKindCon tc    = tyConUnique tc == openTypeKindTyConKey
1441
1442 isOpenTypeKind (TyConApp tc _) = isOpenTypeKindCon tc
1443 isOpenTypeKind other           = False
1444
1445 isUbxTupleKindCon tc = tyConUnique tc == ubxTupleKindTyConKey
1446
1447 isUbxTupleKind (TyConApp tc _) = isUbxTupleKindCon tc
1448 isUbxTupleKind other           = False
1449
1450 isArgTypeKindCon tc = tyConUnique tc == argTypeKindTyConKey
1451
1452 isArgTypeKind (TyConApp tc _) = isArgTypeKindCon tc
1453 isArgTypeKind other = False
1454
1455 isUnliftedTypeKindCon tc = tyConUnique tc == unliftedTypeKindTyConKey
1456
1457 isUnliftedTypeKind (TyConApp tc _) = isUnliftedTypeKindCon tc
1458 isUnliftedTypeKind other           = False
1459
1460 isSubOpenTypeKind :: Kind -> Bool
1461 -- True of any sub-kind of OpenTypeKind (i.e. anything except arrow)
1462 isSubOpenTypeKind (FunTy k1 k2)    = ASSERT2 ( isKind k1, text "isSubOpenTypeKind" <+> ppr k1 <+> text "::" <+> ppr (typeKind k1) ) 
1463                                      ASSERT2 ( isKind k2, text "isSubOpenTypeKind" <+> ppr k2 <+> text "::" <+> ppr (typeKind k2) ) 
1464                                      False
1465 isSubOpenTypeKind (TyConApp kc []) = ASSERT( isKind (TyConApp kc []) ) True
1466 isSubOpenTypeKind other            = ASSERT( isKind other ) False
1467          -- This is a conservative answer
1468          -- It matters in the call to isSubKind in
1469          -- checkExpectedKind.
1470
1471 isSubArgTypeKindCon kc
1472   | isUnliftedTypeKindCon kc = True
1473   | isLiftedTypeKindCon kc   = True
1474   | isArgTypeKindCon kc      = True
1475   | otherwise                = False
1476
1477 isSubArgTypeKind :: Kind -> Bool
1478 -- True of any sub-kind of ArgTypeKind 
1479 isSubArgTypeKind (TyConApp kc []) = isSubArgTypeKindCon kc
1480 isSubArgTypeKind other            = False
1481
1482 isSuperKind :: Type -> Bool
1483 isSuperKind (TyConApp (skc) []) = isSuperKindTyCon skc
1484 isSuperKind other = False
1485
1486 isKind :: Kind -> Bool
1487 isKind k = isSuperKind (typeKind k)
1488
1489
1490
1491 isSubKind :: Kind -> Kind -> Bool
1492 -- (k1 `isSubKind` k2) checks that k1 <: k2
1493 isSubKind (TyConApp kc1 []) (TyConApp kc2 []) = kc1 `isSubKindCon` kc2
1494 isSubKind (FunTy a1 r1) (FunTy a2 r2)         = (a2 `isSubKind` a1) && (r1 `isSubKind` r2)
1495 isSubKind (PredTy (EqPred ty1 ty2)) (PredTy (EqPred ty1' ty2')) 
1496   = ty1 `tcEqType` ty1' && ty2 `tcEqType` ty2'
1497 isSubKind k1            k2                    = False
1498
1499 eqKind :: Kind -> Kind -> Bool
1500 eqKind = tcEqType
1501
1502 isSubKindCon :: TyCon -> TyCon -> Bool
1503 -- (kc1 `isSubKindCon` kc2) checks that kc1 <: kc2
1504 isSubKindCon kc1 kc2
1505   | isLiftedTypeKindCon kc1   && isLiftedTypeKindCon kc2   = True
1506   | isUnliftedTypeKindCon kc1 && isUnliftedTypeKindCon kc2 = True
1507   | isUbxTupleKindCon kc1     && isUbxTupleKindCon kc2     = True
1508   | isOpenTypeKindCon kc2                                  = True 
1509                            -- we already know kc1 is not a fun, its a TyCon
1510   | isArgTypeKindCon kc2      && isSubArgTypeKindCon kc1   = True
1511   | otherwise                                              = False
1512
1513 defaultKind :: Kind -> Kind
1514 -- Used when generalising: default kind '?' and '??' to '*'
1515 -- 
1516 -- When we generalise, we make generic type variables whose kind is
1517 -- simple (* or *->* etc).  So generic type variables (other than
1518 -- built-in constants like 'error') always have simple kinds.  This is important;
1519 -- consider
1520 --      f x = True
1521 -- We want f to get type
1522 --      f :: forall (a::*). a -> Bool
1523 -- Not 
1524 --      f :: forall (a::??). a -> Bool
1525 -- because that would allow a call like (f 3#) as well as (f True),
1526 --and the calling conventions differ.  This defaulting is done in TcMType.zonkTcTyVarBndr.
1527 defaultKind k 
1528   | isSubOpenTypeKind k = liftedTypeKind
1529   | isSubArgTypeKind k  = liftedTypeKind
1530   | otherwise        = k
1531
1532 isEqPred :: PredType -> Bool
1533 isEqPred (EqPred _ _) = True
1534 isEqPred other        = False
1535 \end{code}