Don't import FastString in HsVersions.h
[ghc.git] / compiler / simplCore / SimplUtils.lhs
1 %
2 % (c) The AQUA Project, Glasgow University, 1993-1998
3 %
4 \section[SimplUtils]{The simplifier utilities}
5
6 \begin{code}
7 {-# OPTIONS -w #-}
8 -- The above warning supression flag is a temporary kludge.
9 -- While working on this module you are encouraged to remove it and fix
10 -- any warnings in the module. See
11 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
12 -- for details
13
14 module SimplUtils (
15         -- Rebuilding
16         mkLam, mkCase, prepareAlts, bindCaseBndr,
17
18         -- Inlining,
19         preInlineUnconditionally, postInlineUnconditionally, 
20         activeInline, activeRule, inlineMode,
21
22         -- The continuation type
23         SimplCont(..), DupFlag(..), ArgInfo(..),
24         contIsDupable, contResultType, contIsTrivial, contArgs, dropArgs, 
25         countValArgs, countArgs, splitInlineCont,
26         mkBoringStop, mkLazyArgStop, mkRhsStop, contIsRhsOrArg,
27         interestingCallContext, interestingArgContext,
28
29         interestingArg, mkArgInfo,
30         
31         abstractFloats
32     ) where
33
34 #include "HsVersions.h"
35
36 import SimplEnv
37 import DynFlags
38 import StaticFlags
39 import CoreSyn
40 import qualified CoreSubst
41 import PprCore
42 import CoreFVs
43 import CoreUtils
44 import Literal  
45 import CoreUnfold
46 import MkId
47 import Name
48 import Id
49 import Var      ( isCoVar )
50 import NewDemand
51 import SimplMonad
52 import Type     hiding( substTy )
53 import TyCon
54 import DataCon
55 import Unify    ( dataConCannotMatch )
56 import VarSet
57 import BasicTypes
58 import Util
59 import MonadUtils
60 import Outputable
61 import FastString
62
63 import List( nub )
64 \end{code}
65
66
67 %************************************************************************
68 %*                                                                      *
69                 The SimplCont type
70 %*                                                                      *
71 %************************************************************************
72
73 A SimplCont allows the simplifier to traverse the expression in a 
74 zipper-like fashion.  The SimplCont represents the rest of the expression,
75 "above" the point of interest.
76
77 You can also think of a SimplCont as an "evaluation context", using
78 that term in the way it is used for operational semantics. This is the
79 way I usually think of it, For example you'll often see a syntax for
80 evaluation context looking like
81         C ::= []  |  C e   |  case C of alts  |  C `cast` co
82 That's the kind of thing we are doing here, and I use that syntax in
83 the comments.
84
85
86 Key points:
87   * A SimplCont describes a *strict* context (just like 
88     evaluation contexts do).  E.g. Just [] is not a SimplCont
89
90   * A SimplCont describes a context that *does not* bind
91     any variables.  E.g. \x. [] is not a SimplCont
92
93 \begin{code}
94 data SimplCont  
95   = Stop                -- An empty context, or hole, []     
96         OutType         -- Type of the result
97         CallCtxt        -- True <=> There is something interesting about
98                         --          the context, and hence the inliner
99                         --          should be a bit keener (see interestingCallContext)
100                         -- Specifically:
101                         --     This is an argument of a function that has RULES
102                         --     Inlining the call might allow the rule to fire
103
104   | CoerceIt            -- C `cast` co
105         OutCoercion             -- The coercion simplified
106         SimplCont
107
108   | ApplyTo             -- C arg
109         DupFlag 
110         InExpr SimplEnv         -- The argument and its static env
111         SimplCont
112
113   | Select              -- case C of alts
114         DupFlag 
115         InId [InAlt] SimplEnv   -- The case binder, alts, and subst-env
116         SimplCont
117
118   -- The two strict forms have no DupFlag, because we never duplicate them
119   | StrictBind          -- (\x* \xs. e) C
120         InId [InBndr]           -- let x* = [] in e     
121         InExpr SimplEnv         --      is a special case 
122         SimplCont       
123
124   | StrictArg           -- e C
125         OutExpr OutType         -- e and its type
126         CallCtxt                -- Whether *this* argument position is interesting
127         ArgInfo                 -- Whether the function at the head of e has rules, etc
128         SimplCont               --     plus strictness flags for *further* args
129
130 data ArgInfo 
131   = ArgInfo {
132         ai_rules :: Bool,       -- Function has rules (recursively)
133                                 --      => be keener to inline in all args
134         ai_strs :: [Bool],      -- Strictness of arguments
135                                 --   Usually infinite, but if it is finite it guarantees
136                                 --   that the function diverges after being given
137                                 --   that number of args
138         ai_discs :: [Int]       -- Discounts for arguments; non-zero => be keener to inline
139                                 --   Always infinite
140     }
141
142 instance Outputable SimplCont where
143   ppr (Stop ty _)                    = ptext SLIT("Stop") <+> ppr ty
144   ppr (ApplyTo dup arg se cont)      = ((ptext SLIT("ApplyTo") <+> ppr dup <+> pprParendExpr arg)
145                                           {-  $$ nest 2 (pprSimplEnv se) -}) $$ ppr cont
146   ppr (StrictBind b _ _ _ cont)      = (ptext SLIT("StrictBind") <+> ppr b) $$ ppr cont
147   ppr (StrictArg f _ _ _ cont)       = (ptext SLIT("StrictArg") <+> ppr f) $$ ppr cont
148   ppr (Select dup bndr alts se cont) = (ptext SLIT("Select") <+> ppr dup <+> ppr bndr) $$ 
149                                        (nest 4 (ppr alts)) $$ ppr cont 
150   ppr (CoerceIt co cont)             = (ptext SLIT("CoerceIt") <+> ppr co) $$ ppr cont
151
152 data DupFlag = OkToDup | NoDup
153
154 instance Outputable DupFlag where
155   ppr OkToDup = ptext SLIT("ok")
156   ppr NoDup   = ptext SLIT("nodup")
157
158
159
160 -------------------
161 mkBoringStop :: OutType -> SimplCont
162 mkBoringStop ty = Stop ty BoringCtxt
163
164 mkLazyArgStop :: OutType -> CallCtxt -> SimplCont
165 mkLazyArgStop ty cci = Stop ty cci
166
167 mkRhsStop :: OutType -> SimplCont
168 mkRhsStop ty = Stop ty BoringCtxt
169
170 -------------------
171 contIsRhsOrArg (Stop {})         = True
172 contIsRhsOrArg (StrictBind {})   = True
173 contIsRhsOrArg (StrictArg {})    = True
174 contIsRhsOrArg other             = False
175
176 -------------------
177 contIsDupable :: SimplCont -> Bool
178 contIsDupable (Stop {})                  = True
179 contIsDupable (ApplyTo  OkToDup _ _ _)   = True
180 contIsDupable (Select   OkToDup _ _ _ _) = True
181 contIsDupable (CoerceIt _ cont)          = contIsDupable cont
182 contIsDupable other                      = False
183
184 -------------------
185 contIsTrivial :: SimplCont -> Bool
186 contIsTrivial (Stop {})                   = True
187 contIsTrivial (ApplyTo _ (Type _) _ cont) = contIsTrivial cont
188 contIsTrivial (CoerceIt _ cont)           = contIsTrivial cont
189 contIsTrivial other                       = False
190
191 -------------------
192 contResultType :: SimplCont -> OutType
193 contResultType (Stop to_ty _)            = to_ty
194 contResultType (StrictArg _ _ _ _ cont)  = contResultType cont
195 contResultType (StrictBind _ _ _ _ cont) = contResultType cont
196 contResultType (ApplyTo _ _ _ cont)      = contResultType cont
197 contResultType (CoerceIt _ cont)         = contResultType cont
198 contResultType (Select _ _ _ _ cont)     = contResultType cont
199
200 -------------------
201 countValArgs :: SimplCont -> Int
202 countValArgs (ApplyTo _ (Type ty) se cont) = countValArgs cont
203 countValArgs (ApplyTo _ val_arg   se cont) = 1 + countValArgs cont
204 countValArgs other                         = 0
205
206 countArgs :: SimplCont -> Int
207 countArgs (ApplyTo _ arg se cont) = 1 + countArgs cont
208 countArgs other                   = 0
209
210 contArgs :: SimplCont -> ([OutExpr], SimplCont)
211 -- Uses substitution to turn each arg into an OutExpr
212 contArgs cont = go [] cont
213   where
214     go args (ApplyTo _ arg se cont) = go (substExpr se arg : args) cont
215     go args cont                    = (reverse args, cont)
216
217 dropArgs :: Int -> SimplCont -> SimplCont
218 dropArgs 0 cont = cont
219 dropArgs n (ApplyTo _ _ _ cont) = dropArgs (n-1) cont
220 dropArgs n other                = pprPanic "dropArgs" (ppr n <+> ppr other)
221
222 --------------------
223 splitInlineCont :: SimplCont -> Maybe (SimplCont, SimplCont)
224 -- Returns Nothing if the continuation should dissolve an InlineMe Note
225 -- Return Just (c1,c2) otherwise, 
226 --      where c1 is the continuation to put inside the InlineMe 
227 --      and   c2 outside
228
229 -- Example: (__inline_me__ (/\a. e)) ty
230 --      Here we want to do the beta-redex without dissolving the InlineMe
231 -- See test simpl017 (and Trac #1627) for a good example of why this is important
232
233 splitInlineCont (ApplyTo dup (Type ty) se c)
234   | Just (c1, c2) <- splitInlineCont c          = Just (ApplyTo dup (Type ty) se c1, c2)
235 splitInlineCont cont@(Stop ty _)                = Just (mkBoringStop ty, cont)
236 splitInlineCont cont@(StrictBind bndr _ _ se _) = Just (mkBoringStop (substTy se (idType bndr)), cont)
237 splitInlineCont cont@(StrictArg _ fun_ty _ _ _) = Just (mkBoringStop (funArgTy fun_ty), cont)
238 splitInlineCont other                           = Nothing
239         -- NB: the calculation of the type for mkBoringStop is an annoying
240         --     duplication of the same calucation in mkDupableCont
241 \end{code}
242
243
244 \begin{code}
245 interestingArg :: OutExpr -> Bool
246         -- An argument is interesting if it has *some* structure
247         -- We are here trying to avoid unfolding a function that
248         -- is applied only to variables that have no unfolding
249         -- (i.e. they are probably lambda bound): f x y z
250         -- There is little point in inlining f here.
251 interestingArg (Var v)           = hasSomeUnfolding (idUnfolding v)
252                                         -- Was: isValueUnfolding (idUnfolding v')
253                                         -- But that seems over-pessimistic
254                                  || isDataConWorkId v
255                                         -- This accounts for an argument like
256                                         -- () or [], which is definitely interesting
257 interestingArg (Type _)          = False
258 interestingArg (App fn (Type _)) = interestingArg fn
259 interestingArg (Note _ a)        = interestingArg a
260
261 -- Idea (from Sam B); I'm not sure if it's a good idea, so commented out for now
262 -- interestingArg expr | isUnLiftedType (exprType expr)
263 --        -- Unlifted args are only ever interesting if we know what they are
264 --  =                  case expr of
265 --                        Lit lit -> True
266 --                        _       -> False
267
268 interestingArg other             = True
269         -- Consider     let x = 3 in f x
270         -- The substitution will contain (x -> ContEx 3), and we want to
271         -- to say that x is an interesting argument.
272         -- But consider also (\x. f x y) y
273         -- The substitution will contain (x -> ContEx y), and we want to say
274         -- that x is not interesting (assuming y has no unfolding)
275 \end{code}
276
277
278 Comment about interestingCallContext
279 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
280 We want to avoid inlining an expression where there can't possibly be
281 any gain, such as in an argument position.  Hence, if the continuation
282 is interesting (eg. a case scrutinee, application etc.) then we
283 inline, otherwise we don't.  
284
285 Previously some_benefit used to return True only if the variable was
286 applied to some value arguments.  This didn't work:
287
288         let x = _coerce_ (T Int) Int (I# 3) in
289         case _coerce_ Int (T Int) x of
290                 I# y -> ....
291
292 we want to inline x, but can't see that it's a constructor in a case
293 scrutinee position, and some_benefit is False.
294
295 Another example:
296
297 dMonadST = _/\_ t -> :Monad (g1 _@_ t, g2 _@_ t, g3 _@_ t)
298
299 ....  case dMonadST _@_ x0 of (a,b,c) -> ....
300
301 we'd really like to inline dMonadST here, but we *don't* want to
302 inline if the case expression is just
303
304         case x of y { DEFAULT -> ... }
305
306 since we can just eliminate this case instead (x is in WHNF).  Similar
307 applies when x is bound to a lambda expression.  Hence
308 contIsInteresting looks for case expressions with just a single
309 default case.
310
311
312 \begin{code}
313 interestingCallContext :: SimplCont -> CallCtxt
314 interestingCallContext cont
315   = interesting cont
316   where
317     interestingCtxt = ArgCtxt False 2   -- Give *some* incentive!
318
319     interesting (Select _ bndr _ _ _)
320         | isDeadBinder bndr       = CaseCtxt
321         | otherwise               = interestingCtxt
322                 
323     interesting (ApplyTo {})      = interestingCtxt
324                                 -- Can happen if we have (coerce t (f x)) y
325                                 -- Perhaps interestingCtxt is a bit over-keen, but I've
326                                 -- seen (coerce f) x, where f has an INLINE prag,
327                                 -- So we have to give some motivation for inlining it
328
329     interesting (StrictArg _ _ cci _ _) = cci
330     interesting (StrictBind {})         = BoringCtxt
331     interesting (Stop ty cci)           = cci
332     interesting (CoerceIt _ cont)       = interesting cont
333         -- If this call is the arg of a strict function, the context
334         -- is a bit interesting.  If we inline here, we may get useful
335         -- evaluation information to avoid repeated evals: e.g.
336         --      x + (y * z)
337         -- Here the contIsInteresting makes the '*' keener to inline,
338         -- which in turn exposes a constructor which makes the '+' inline.
339         -- Assuming that +,* aren't small enough to inline regardless.
340         --
341         -- It's also very important to inline in a strict context for things
342         -- like
343         --              foldr k z (f x)
344         -- Here, the context of (f x) is strict, and if f's unfolding is
345         -- a build it's *great* to inline it here.  So we must ensure that
346         -- the context for (f x) is not totally uninteresting.
347
348
349 -------------------
350 mkArgInfo :: Id
351           -> Int        -- Number of value args
352           -> SimplCont  -- Context of the cal
353           -> ArgInfo
354
355 mkArgInfo fun n_val_args call_cont
356   = ArgInfo { ai_rules = interestingArgContext fun call_cont
357             , ai_strs  = arg_stricts
358             , ai_discs = arg_discounts }
359   where
360     vanilla_discounts, arg_discounts :: [Int]
361     vanilla_discounts = repeat 0
362     arg_discounts = case idUnfolding fun of
363                         CoreUnfolding _ _ _ _ (UnfoldIfGoodArgs _ discounts _ _)
364                               -> discounts ++ vanilla_discounts
365                         other -> vanilla_discounts
366
367     vanilla_stricts, arg_stricts :: [Bool]
368     vanilla_stricts  = repeat False
369
370     arg_stricts
371       = case splitStrictSig (idNewStrictness fun) of
372           (demands, result_info)
373                 | not (demands `lengthExceeds` n_val_args)
374                 ->      -- Enough args, use the strictness given.
375                         -- For bottoming functions we used to pretend that the arg
376                         -- is lazy, so that we don't treat the arg as an
377                         -- interesting context.  This avoids substituting
378                         -- top-level bindings for (say) strings into 
379                         -- calls to error.  But now we are more careful about
380                         -- inlining lone variables, so its ok (see SimplUtils.analyseCont)
381                    if isBotRes result_info then
382                         map isStrictDmd demands         -- Finite => result is bottom
383                    else
384                         map isStrictDmd demands ++ vanilla_stricts
385
386           other -> vanilla_stricts      -- Not enough args, or no strictness
387
388 interestingArgContext :: Id -> SimplCont -> Bool
389 -- If the argument has form (f x y), where x,y are boring,
390 -- and f is marked INLINE, then we don't want to inline f.
391 -- But if the context of the argument is
392 --      g (f x y) 
393 -- where g has rules, then we *do* want to inline f, in case it
394 -- exposes a rule that might fire.  Similarly, if the context is
395 --      h (g (f x x))
396 -- where h has rules, then we do want to inline f; hence the
397 -- call_cont argument to interestingArgContext
398 --
399 -- The interesting_arg_ctxt flag makes this happen; if it's
400 -- set, the inliner gets just enough keener to inline f 
401 -- regardless of how boring f's arguments are, if it's marked INLINE
402 --
403 -- The alternative would be to *always* inline an INLINE function,
404 -- regardless of how boring its context is; but that seems overkill
405 -- For example, it'd mean that wrapper functions were always inlined
406 interestingArgContext fn call_cont
407   = idHasRules fn || go call_cont
408   where
409     go (Select {})             = False
410     go (ApplyTo {})            = False
411     go (StrictArg _ _ cci _ _) = interesting cci
412     go (StrictBind {})         = False  -- ??
413     go (CoerceIt _ c)          = go c
414     go (Stop _ cci)            = interesting cci
415
416     interesting (ArgCtxt rules _) = rules
417     interesting other             = False
418 \end{code}
419
420
421
422 %************************************************************************
423 %*                                                                      *
424 \subsection{Decisions about inlining}
425 %*                                                                      *
426 %************************************************************************
427
428 Inlining is controlled partly by the SimplifierMode switch.  This has two
429 settings:
430
431         SimplGently     (a) Simplifying before specialiser/full laziness
432                         (b) Simplifiying inside INLINE pragma
433                         (c) Simplifying the LHS of a rule
434                         (d) Simplifying a GHCi expression or Template 
435                                 Haskell splice
436
437         SimplPhase n _   Used at all other times
438
439 The key thing about SimplGently is that it does no call-site inlining.
440 Before full laziness we must be careful not to inline wrappers,
441 because doing so inhibits floating
442     e.g. ...(case f x of ...)...
443     ==> ...(case (case x of I# x# -> fw x#) of ...)...
444     ==> ...(case x of I# x# -> case fw x# of ...)...
445 and now the redex (f x) isn't floatable any more.
446
447 The no-inlining thing is also important for Template Haskell.  You might be 
448 compiling in one-shot mode with -O2; but when TH compiles a splice before
449 running it, we don't want to use -O2.  Indeed, we don't want to inline
450 anything, because the byte-code interpreter might get confused about 
451 unboxed tuples and suchlike.
452
453 INLINE pragmas
454 ~~~~~~~~~~~~~~
455 SimplGently is also used as the mode to simplify inside an InlineMe note.
456
457 \begin{code}
458 inlineMode :: SimplifierMode
459 inlineMode = SimplGently
460 \end{code}
461
462 It really is important to switch off inlinings inside such
463 expressions.  Consider the following example 
464
465         let f = \pq -> BIG
466         in
467         let g = \y -> f y y
468             {-# INLINE g #-}
469         in ...g...g...g...g...g...
470
471 Now, if that's the ONLY occurrence of f, it will be inlined inside g,
472 and thence copied multiple times when g is inlined.
473
474
475 This function may be inlinined in other modules, so we
476 don't want to remove (by inlining) calls to functions that have
477 specialisations, or that may have transformation rules in an importing
478 scope.
479
480 E.g.    {-# INLINE f #-}
481                 f x = ...g...
482
483 and suppose that g is strict *and* has specialisations.  If we inline
484 g's wrapper, we deny f the chance of getting the specialised version
485 of g when f is inlined at some call site (perhaps in some other
486 module).
487
488 It's also important not to inline a worker back into a wrapper.
489 A wrapper looks like
490         wraper = inline_me (\x -> ...worker... )
491 Normally, the inline_me prevents the worker getting inlined into
492 the wrapper (initially, the worker's only call site!).  But,
493 if the wrapper is sure to be called, the strictness analyser will
494 mark it 'demanded', so when the RHS is simplified, it'll get an ArgOf
495 continuation.  That's why the keep_inline predicate returns True for
496 ArgOf continuations.  It shouldn't do any harm not to dissolve the
497 inline-me note under these circumstances.
498
499 Note that the result is that we do very little simplification
500 inside an InlineMe.  
501
502         all xs = foldr (&&) True xs
503         any p = all . map p  {-# INLINE any #-}
504
505 Problem: any won't get deforested, and so if it's exported and the
506 importer doesn't use the inlining, (eg passes it as an arg) then we
507 won't get deforestation at all.  We havn't solved this problem yet!
508
509
510 preInlineUnconditionally
511 ~~~~~~~~~~~~~~~~~~~~~~~~
512 @preInlineUnconditionally@ examines a bndr to see if it is used just
513 once in a completely safe way, so that it is safe to discard the
514 binding inline its RHS at the (unique) usage site, REGARDLESS of how
515 big the RHS might be.  If this is the case we don't simplify the RHS
516 first, but just inline it un-simplified.
517
518 This is much better than first simplifying a perhaps-huge RHS and then
519 inlining and re-simplifying it.  Indeed, it can be at least quadratically
520 better.  Consider
521
522         x1 = e1
523         x2 = e2[x1]
524         x3 = e3[x2]
525         ...etc...
526         xN = eN[xN-1]
527
528 We may end up simplifying e1 N times, e2 N-1 times, e3 N-3 times etc.
529 This can happen with cascades of functions too:
530
531         f1 = \x1.e1
532         f2 = \xs.e2[f1]
533         f3 = \xs.e3[f3]
534         ...etc...
535
536 THE MAIN INVARIANT is this:
537
538         ----  preInlineUnconditionally invariant -----
539    IF preInlineUnconditionally chooses to inline x = <rhs>
540    THEN doing the inlining should not change the occurrence
541         info for the free vars of <rhs>
542         ----------------------------------------------
543
544 For example, it's tempting to look at trivial binding like
545         x = y
546 and inline it unconditionally.  But suppose x is used many times,
547 but this is the unique occurrence of y.  Then inlining x would change
548 y's occurrence info, which breaks the invariant.  It matters: y
549 might have a BIG rhs, which will now be dup'd at every occurrenc of x.
550
551
552 Even RHSs labelled InlineMe aren't caught here, because there might be
553 no benefit from inlining at the call site.
554
555 [Sept 01] Don't unconditionally inline a top-level thing, because that
556 can simply make a static thing into something built dynamically.  E.g.
557         x = (a,b)
558         main = \s -> h x
559
560 [Remember that we treat \s as a one-shot lambda.]  No point in
561 inlining x unless there is something interesting about the call site.
562
563 But watch out: if you aren't careful, some useful foldr/build fusion
564 can be lost (most notably in spectral/hartel/parstof) because the
565 foldr didn't see the build.  Doing the dynamic allocation isn't a big
566 deal, in fact, but losing the fusion can be.  But the right thing here
567 seems to be to do a callSiteInline based on the fact that there is
568 something interesting about the call site (it's strict).  Hmm.  That
569 seems a bit fragile.
570
571 Conclusion: inline top level things gaily until Phase 0 (the last
572 phase), at which point don't.
573
574 \begin{code}
575 preInlineUnconditionally :: SimplEnv -> TopLevelFlag -> InId -> InExpr -> Bool
576 preInlineUnconditionally env top_lvl bndr rhs
577   | not active             = False
578   | opt_SimplNoPreInlining = False
579   | otherwise = case idOccInfo bndr of
580                   IAmDead                    -> True    -- Happens in ((\x.1) v)
581                   OneOcc in_lam True int_cxt -> try_once in_lam int_cxt
582                   other                      -> False
583   where
584     phase = getMode env
585     active = case phase of
586                    SimplGently    -> isAlwaysActive prag
587                    SimplPhase n _ -> isActive n prag
588     prag = idInlinePragma bndr
589
590     try_once in_lam int_cxt     -- There's one textual occurrence
591         | not in_lam = isNotTopLevel top_lvl || early_phase
592         | otherwise  = int_cxt && canInlineInLam rhs
593
594 -- Be very careful before inlining inside a lambda, becuase (a) we must not 
595 -- invalidate occurrence information, and (b) we want to avoid pushing a
596 -- single allocation (here) into multiple allocations (inside lambda).  
597 -- Inlining a *function* with a single *saturated* call would be ok, mind you.
598 --      || (if is_cheap && not (canInlineInLam rhs) then pprTrace "preinline" (ppr bndr <+> ppr rhs) ok else ok)
599 --      where 
600 --              is_cheap = exprIsCheap rhs
601 --              ok = is_cheap && int_cxt
602
603         --      int_cxt         The context isn't totally boring
604         -- E.g. let f = \ab.BIG in \y. map f xs
605         --      Don't want to substitute for f, because then we allocate
606         --      its closure every time the \y is called
607         -- But: let f = \ab.BIG in \y. map (f y) xs
608         --      Now we do want to substitute for f, even though it's not 
609         --      saturated, because we're going to allocate a closure for 
610         --      (f y) every time round the loop anyhow.
611
612         -- canInlineInLam => free vars of rhs are (Once in_lam) or Many,
613         -- so substituting rhs inside a lambda doesn't change the occ info.
614         -- Sadly, not quite the same as exprIsHNF.
615     canInlineInLam (Lit l)              = True
616     canInlineInLam (Lam b e)            = isRuntimeVar b || canInlineInLam e
617     canInlineInLam (Note _ e)           = canInlineInLam e
618     canInlineInLam _                    = False
619
620     early_phase = case phase of
621                         SimplPhase 0 _ -> False
622                         other          -> True
623 -- If we don't have this early_phase test, consider
624 --      x = length [1,2,3]
625 -- The full laziness pass carefully floats all the cons cells to
626 -- top level, and preInlineUnconditionally floats them all back in.
627 -- Result is (a) static allocation replaced by dynamic allocation
628 --           (b) many simplifier iterations because this tickles
629 --               a related problem; only one inlining per pass
630 -- 
631 -- On the other hand, I have seen cases where top-level fusion is
632 -- lost if we don't inline top level thing (e.g. string constants)
633 -- Hence the test for phase zero (which is the phase for all the final
634 -- simplifications).  Until phase zero we take no special notice of
635 -- top level things, but then we become more leery about inlining
636 -- them.  
637
638 \end{code}
639
640 postInlineUnconditionally
641 ~~~~~~~~~~~~~~~~~~~~~~~~~
642 @postInlineUnconditionally@ decides whether to unconditionally inline
643 a thing based on the form of its RHS; in particular if it has a
644 trivial RHS.  If so, we can inline and discard the binding altogether.
645
646 NB: a loop breaker has must_keep_binding = True and non-loop-breakers
647 only have *forward* references Hence, it's safe to discard the binding
648         
649 NOTE: This isn't our last opportunity to inline.  We're at the binding
650 site right now, and we'll get another opportunity when we get to the
651 ocurrence(s)
652
653 Note that we do this unconditional inlining only for trival RHSs.
654 Don't inline even WHNFs inside lambdas; doing so may simply increase
655 allocation when the function is called. This isn't the last chance; see
656 NOTE above.
657
658 NB: Even inline pragmas (e.g. IMustBeINLINEd) are ignored here Why?
659 Because we don't even want to inline them into the RHS of constructor
660 arguments. See NOTE above
661
662 NB: At one time even NOINLINE was ignored here: if the rhs is trivial
663 it's best to inline it anyway.  We often get a=E; b=a from desugaring,
664 with both a and b marked NOINLINE.  But that seems incompatible with
665 our new view that inlining is like a RULE, so I'm sticking to the 'active'
666 story for now.
667
668 \begin{code}
669 postInlineUnconditionally 
670     :: SimplEnv -> TopLevelFlag
671     -> InId             -- The binder (an OutId would be fine too)
672     -> OccInfo          -- From the InId
673     -> OutExpr
674     -> Unfolding
675     -> Bool
676 postInlineUnconditionally env top_lvl bndr occ_info rhs unfolding
677   | not active             = False
678   | isLoopBreaker occ_info = False      -- If it's a loop-breaker of any kind, dont' inline
679                                         -- because it might be referred to "earlier"
680   | isExportedId bndr      = False
681   | exprIsTrivial rhs      = True
682   | otherwise
683   = case occ_info of
684         -- The point of examining occ_info here is that for *non-values* 
685         -- that occur outside a lambda, the call-site inliner won't have
686         -- a chance (becuase it doesn't know that the thing
687         -- only occurs once).   The pre-inliner won't have gotten
688         -- it either, if the thing occurs in more than one branch
689         -- So the main target is things like
690         --      let x = f y in
691         --      case v of
692         --         True  -> case x of ...
693         --         False -> case x of ...
694         -- I'm not sure how important this is in practice
695       OneOcc in_lam one_br int_cxt      -- OneOcc => no code-duplication issue
696         ->     smallEnoughToInline unfolding    -- Small enough to dup
697                         -- ToDo: consider discount on smallEnoughToInline if int_cxt is true
698                         --
699                         -- NB: Do NOT inline arbitrarily big things, even if one_br is True
700                         -- Reason: doing so risks exponential behaviour.  We simplify a big
701                         --         expression, inline it, and simplify it again.  But if the
702                         --         very same thing happens in the big expression, we get 
703                         --         exponential cost!
704                         -- PRINCIPLE: when we've already simplified an expression once, 
705                         -- make sure that we only inline it if it's reasonably small.
706
707            &&  ((isNotTopLevel top_lvl && not in_lam) || 
708                         -- But outside a lambda, we want to be reasonably aggressive
709                         -- about inlining into multiple branches of case
710                         -- e.g. let x = <non-value> 
711                         --      in case y of { C1 -> ..x..; C2 -> ..x..; C3 -> ... } 
712                         -- Inlining can be a big win if C3 is the hot-spot, even if
713                         -- the uses in C1, C2 are not 'interesting'
714                         -- An example that gets worse if you add int_cxt here is 'clausify'
715
716                 (isCheapUnfolding unfolding && int_cxt))
717                         -- isCheap => acceptable work duplication; in_lam may be true
718                         -- int_cxt to prevent us inlining inside a lambda without some 
719                         -- good reason.  See the notes on int_cxt in preInlineUnconditionally
720
721       IAmDead -> True   -- This happens; for example, the case_bndr during case of
722                         -- known constructor:  case (a,b) of x { (p,q) -> ... }
723                         -- Here x isn't mentioned in the RHS, so we don't want to
724                         -- create the (dead) let-binding  let x = (a,b) in ...
725
726       other -> False
727
728 -- Here's an example that we don't handle well:
729 --      let f = if b then Left (\x.BIG) else Right (\y.BIG)
730 --      in \y. ....case f of {...} ....
731 -- Here f is used just once, and duplicating the case work is fine (exprIsCheap).
732 -- But
733 -- * We can't preInlineUnconditionally because that woud invalidate
734 --   the occ info for b.  
735 -- * We can't postInlineUnconditionally because the RHS is big, and
736 --   that risks exponential behaviour
737 -- * We can't call-site inline, because the rhs is big
738 -- Alas!
739
740   where
741     active = case getMode env of
742                    SimplGently    -> isAlwaysActive prag
743                    SimplPhase n _ -> isActive n prag
744     prag = idInlinePragma bndr
745
746 activeInline :: SimplEnv -> OutId -> Bool
747 activeInline env id
748   = case getMode env of
749       SimplGently -> False
750         -- No inlining at all when doing gentle stuff,
751         -- except for local things that occur once
752         -- The reason is that too little clean-up happens if you 
753         -- don't inline use-once things.   Also a bit of inlining is *good* for
754         -- full laziness; it can expose constant sub-expressions.
755         -- Example in spectral/mandel/Mandel.hs, where the mandelset 
756         -- function gets a useful let-float if you inline windowToViewport
757
758         -- NB: we used to have a second exception, for data con wrappers.
759         -- On the grounds that we use gentle mode for rule LHSs, and 
760         -- they match better when data con wrappers are inlined.
761         -- But that only really applies to the trivial wrappers (like (:)),
762         -- and they are now constructed as Compulsory unfoldings (in MkId)
763         -- so they'll happen anyway.
764
765       SimplPhase n _ -> isActive n prag
766   where
767     prag = idInlinePragma id
768
769 activeRule :: DynFlags -> SimplEnv -> Maybe (Activation -> Bool)
770 -- Nothing => No rules at all
771 activeRule dflags env
772   | not (dopt Opt_RewriteRules dflags)
773   = Nothing     -- Rewriting is off
774   | otherwise
775   = case getMode env of
776         SimplGently    -> Just isAlwaysActive
777                         -- Used to be Nothing (no rules in gentle mode)
778                         -- Main motivation for changing is that I wanted
779                         --      lift String ===> ...
780                         -- to work in Template Haskell when simplifying
781                         -- splices, so we get simpler code for literal strings
782         SimplPhase n _ -> Just (isActive n)
783 \end{code}
784
785
786 %************************************************************************
787 %*                                                                      *
788         Rebuilding a lambda
789 %*                                                                      *
790 %************************************************************************
791
792 \begin{code}
793 mkLam :: [OutBndr] -> OutExpr -> SimplM OutExpr
794 -- mkLam tries three things
795 --      a) eta reduction, if that gives a trivial expression
796 --      b) eta expansion [only if there are some value lambdas]
797
798 mkLam [] body 
799   = return body
800 mkLam bndrs body
801   = do  { dflags <- getDOptsSmpl
802         ; mkLam' dflags bndrs body }
803   where
804     mkLam' :: DynFlags -> [OutBndr] -> OutExpr -> SimplM OutExpr
805     mkLam' dflags bndrs (Cast body co)
806       | not (any bad bndrs)
807         -- Note [Casts and lambdas]
808       = do { lam <- mkLam' dflags bndrs body
809            ; return (mkCoerce (mkPiTypes bndrs co) lam) }
810       where
811         co_vars  = tyVarsOfType co
812         bad bndr = isCoVar bndr && bndr `elemVarSet` co_vars      
813
814     mkLam' dflags bndrs body
815       | dopt Opt_DoEtaReduction dflags,
816         Just etad_lam <- tryEtaReduce bndrs body
817       = do { tick (EtaReduction (head bndrs))
818            ; return etad_lam }
819
820       | dopt Opt_DoLambdaEtaExpansion dflags,
821         any isRuntimeVar bndrs
822       = do { body' <- tryEtaExpansion dflags body
823            ; return (mkLams bndrs body') }
824    
825       | otherwise 
826       = return (mkLams bndrs body)
827 \end{code}
828
829 Note [Casts and lambdas]
830 ~~~~~~~~~~~~~~~~~~~~~~~~
831 Consider 
832         (\x. (\y. e) `cast` g1) `cast` g2
833 There is a danger here that the two lambdas look separated, and the 
834 full laziness pass might float an expression to between the two.
835
836 So this equation in mkLam' floats the g1 out, thus:
837         (\x. e `cast` g1)  -->  (\x.e) `cast` (tx -> g1)
838 where x:tx.
839
840 In general, this floats casts outside lambdas, where (I hope) they
841 might meet and cancel with some other cast:
842         \x. e `cast` co   ===>   (\x. e) `cast` (tx -> co)
843         /\a. e `cast` co  ===>   (/\a. e) `cast` (/\a. co)
844         /\g. e `cast` co  ===>   (/\g. e) `cast` (/\g. co)
845                           (if not (g `in` co))
846
847 Notice that it works regardless of 'e'.  Originally it worked only
848 if 'e' was itself a lambda, but in some cases that resulted in 
849 fruitless iteration in the simplifier.  A good example was when
850 compiling Text.ParserCombinators.ReadPrec, where we had a definition 
851 like    (\x. Get `cast` g)
852 where Get is a constructor with nonzero arity.  Then mkLam eta-expanded
853 the Get, and the next iteration eta-reduced it, and then eta-expanded 
854 it again.
855
856 Note also the side condition for the case of coercion binders.
857 It does not make sense to transform
858         /\g. e `cast` g  ==>  (/\g.e) `cast` (/\g.g)
859 because the latter is not well-kinded.
860
861 --      c) floating lets out through big lambdas 
862 --              [only if all tyvar lambdas, and only if this lambda
863 --               is the RHS of a let]
864
865 {-      Sept 01: I'm experimenting with getting the
866         full laziness pass to float out past big lambdsa
867  | all isTyVar bndrs,   -- Only for big lambdas
868    contIsRhs cont       -- Only try the rhs type-lambda floating
869                         -- if this is indeed a right-hand side; otherwise
870                         -- we end up floating the thing out, only for float-in
871                         -- to float it right back in again!
872  = do (floats, body') <- tryRhsTyLam env bndrs body
873       return (floats, mkLams bndrs body')
874 -}
875
876
877 %************************************************************************
878 %*                                                                      *
879                 Eta reduction
880 %*                                                                      *
881 %************************************************************************
882
883 Note [Eta reduction conditions]
884 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
885 We try for eta reduction here, but *only* if we get all the way to an
886 trivial expression.  We don't want to remove extra lambdas unless we
887 are going to avoid allocating this thing altogether.
888
889 There are some particularly delicate points here:
890
891 * Eta reduction is not valid in general:  
892         \x. bot  /=  bot
893   This matters, partly for old-fashioned correctness reasons but,
894   worse, getting it wrong can yield a seg fault. Consider
895         f = \x.f x
896         h y = case (case y of { True -> f `seq` True; False -> False }) of
897                 True -> ...; False -> ...
898
899   If we (unsoundly) eta-reduce f to get f=f, the strictness analyser
900   says f=bottom, and replaces the (f `seq` True) with just
901   (f `cast` unsafe-co).  BUT, as thing stand, 'f' got arity 1, and it
902   *keeps* arity 1 (perhaps also wrongly).  So CorePrep eta-expands 
903   the definition again, so that it does not termninate after all.
904   Result: seg-fault because the boolean case actually gets a function value.
905   See Trac #1947.
906
907   So it's important to to the right thing.
908
909 * We need to be careful if we just look at f's arity. Currently (Dec07),
910   f's arity is visible in its own RHS (see Note [Arity robustness] in 
911   SimplEnv) so we must *not* trust the arity when checking that 'f' is
912   a value.  Instead, look at the unfolding. 
913
914   However for GlobalIds we can look at the arity; and for primops we
915   must, since they have no unfolding.  
916
917 * Regardless of whether 'f' is a vlaue, we always want to 
918   reduce (/\a -> f a) to f
919   This came up in a RULE: foldr (build (/\a -> g a))
920   did not match            foldr (build (/\b -> ...something complex...))
921   The type checker can insert these eta-expanded versions,
922   with both type and dictionary lambdas; hence the slightly 
923   ad-hoc isDictId
924
925 These delicacies are why we don't use exprIsTrivial and exprIsHNF here.
926 Alas.
927
928 \begin{code}
929 tryEtaReduce :: [OutBndr] -> OutExpr -> Maybe OutExpr
930 tryEtaReduce bndrs body 
931   = go (reverse bndrs) body
932   where
933     go (b : bs) (App fun arg) | ok_arg b arg = go bs fun        -- Loop round
934     go []       fun           | ok_fun fun   = Just fun         -- Success!
935     go _        _                            = Nothing          -- Failure!
936
937         -- Note [Eta reduction conditions]
938     ok_fun (App fun (Type ty)) 
939         | not (any (`elemVarSet` tyVarsOfType ty) bndrs)
940         =  ok_fun fun
941     ok_fun (Var fun_id)
942         =  not (fun_id `elem` bndrs)
943         && (ok_fun_id fun_id || all ok_lam bndrs)
944     ok_fun _fun = False
945
946     ok_fun_id fun
947         | isLocalId fun       = isEvaldUnfolding (idUnfolding fun)
948         | isDataConWorkId fun = True
949         | isGlobalId fun      = idArity fun > 0
950
951     ok_lam v = isTyVar v || isDictId v
952
953     ok_arg b arg = varToCoreExpr b `cheapEqExpr` arg
954 \end{code}
955
956
957 %************************************************************************
958 %*                                                                      *
959                 Eta expansion
960 %*                                                                      *
961 %************************************************************************
962
963
964 We go for:
965    f = \x1..xn -> N  ==>   f = \x1..xn y1..ym -> N y1..ym
966                                  (n >= 0)
967
968 where (in both cases) 
969
970         * The xi can include type variables
971
972         * The yi are all value variables
973
974         * N is a NORMAL FORM (i.e. no redexes anywhere)
975           wanting a suitable number of extra args.
976
977 The biggest reason for doing this is for cases like
978
979         f = \x -> case x of
980                     True  -> \y -> e1
981                     False -> \y -> e2
982
983 Here we want to get the lambdas together.  A good exmaple is the nofib
984 program fibheaps, which gets 25% more allocation if you don't do this
985 eta-expansion.
986
987 We may have to sandwich some coerces between the lambdas
988 to make the types work.   exprEtaExpandArity looks through coerces
989 when computing arity; and etaExpand adds the coerces as necessary when
990 actually computing the expansion.
991
992 \begin{code}
993 tryEtaExpansion :: DynFlags -> OutExpr -> SimplM OutExpr
994 -- There is at least one runtime binder in the binders
995 tryEtaExpansion dflags body = do
996     us <- getUniquesM
997     return (etaExpand fun_arity us body (exprType body))
998   where
999     fun_arity = exprEtaExpandArity dflags body
1000 \end{code}
1001
1002
1003 %************************************************************************
1004 %*                                                                      *
1005 \subsection{Floating lets out of big lambdas}
1006 %*                                                                      *
1007 %************************************************************************
1008
1009 Note [Floating and type abstraction]
1010 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1011 Consider this:
1012         x = /\a. C e1 e2
1013 We'd like to float this to 
1014         y1 = /\a. e1
1015         y2 = /\a. e2
1016         x = /\a. C (y1 a) (y2 a)
1017 for the usual reasons: we want to inline x rather vigorously.
1018
1019 You may think that this kind of thing is rare.  But in some programs it is
1020 common.  For example, if you do closure conversion you might get:
1021
1022         data a :-> b = forall e. (e -> a -> b) :$ e
1023
1024         f_cc :: forall a. a :-> a
1025         f_cc = /\a. (\e. id a) :$ ()
1026
1027 Now we really want to inline that f_cc thing so that the
1028 construction of the closure goes away. 
1029
1030 So I have elaborated simplLazyBind to understand right-hand sides that look
1031 like
1032         /\ a1..an. body
1033
1034 and treat them specially. The real work is done in SimplUtils.abstractFloats,
1035 but there is quite a bit of plumbing in simplLazyBind as well.
1036
1037 The same transformation is good when there are lets in the body:
1038
1039         /\abc -> let(rec) x = e in b
1040    ==>
1041         let(rec) x' = /\abc -> let x = x' a b c in e
1042         in 
1043         /\abc -> let x = x' a b c in b
1044
1045 This is good because it can turn things like:
1046
1047         let f = /\a -> letrec g = ... g ... in g
1048 into
1049         letrec g' = /\a -> ... g' a ...
1050         in
1051         let f = /\ a -> g' a
1052
1053 which is better.  In effect, it means that big lambdas don't impede
1054 let-floating.
1055
1056 This optimisation is CRUCIAL in eliminating the junk introduced by
1057 desugaring mutually recursive definitions.  Don't eliminate it lightly!
1058
1059 [May 1999]  If we do this transformation *regardless* then we can
1060 end up with some pretty silly stuff.  For example, 
1061
1062         let 
1063             st = /\ s -> let { x1=r1 ; x2=r2 } in ...
1064         in ..
1065 becomes
1066         let y1 = /\s -> r1
1067             y2 = /\s -> r2
1068             st = /\s -> ...[y1 s/x1, y2 s/x2]
1069         in ..
1070
1071 Unless the "..." is a WHNF there is really no point in doing this.
1072 Indeed it can make things worse.  Suppose x1 is used strictly,
1073 and is of the form
1074
1075         x1* = case f y of { (a,b) -> e }
1076
1077 If we abstract this wrt the tyvar we then can't do the case inline
1078 as we would normally do.
1079
1080 That's why the whole transformation is part of the same process that
1081 floats let-bindings and constructor arguments out of RHSs.  In particular,
1082 it is guarded by the doFloatFromRhs call in simplLazyBind.
1083
1084
1085 \begin{code}
1086 abstractFloats :: [OutTyVar] -> SimplEnv -> OutExpr -> SimplM ([OutBind], OutExpr)
1087 abstractFloats main_tvs body_env body
1088   = ASSERT( notNull body_floats )
1089     do  { (subst, float_binds) <- mapAccumLM abstract empty_subst body_floats
1090         ; return (float_binds, CoreSubst.substExpr subst body) }
1091   where
1092     main_tv_set = mkVarSet main_tvs
1093     body_floats = getFloats body_env
1094     empty_subst = CoreSubst.mkEmptySubst (seInScope body_env)
1095
1096     abstract :: CoreSubst.Subst -> OutBind -> SimplM (CoreSubst.Subst, OutBind)
1097     abstract subst (NonRec id rhs)
1098       = do { (poly_id, poly_app) <- mk_poly tvs_here id
1099            ; let poly_rhs = mkLams tvs_here rhs'
1100                  subst'   = CoreSubst.extendIdSubst subst id poly_app
1101            ; return (subst', (NonRec poly_id poly_rhs)) }
1102       where
1103         rhs' = CoreSubst.substExpr subst rhs
1104         tvs_here | any isCoVar main_tvs = main_tvs      -- Note [Abstract over coercions]
1105                  | otherwise 
1106                  = varSetElems (main_tv_set `intersectVarSet` exprSomeFreeVars isTyVar rhs')
1107         
1108                 -- Abstract only over the type variables free in the rhs
1109                 -- wrt which the new binding is abstracted.  But the naive
1110                 -- approach of abstract wrt the tyvars free in the Id's type
1111                 -- fails. Consider:
1112                 --      /\ a b -> let t :: (a,b) = (e1, e2)
1113                 --                    x :: a     = fst t
1114                 --                in ...
1115                 -- Here, b isn't free in x's type, but we must nevertheless
1116                 -- abstract wrt b as well, because t's type mentions b.
1117                 -- Since t is floated too, we'd end up with the bogus:
1118                 --      poly_t = /\ a b -> (e1, e2)
1119                 --      poly_x = /\ a   -> fst (poly_t a *b*)
1120                 -- So for now we adopt the even more naive approach of
1121                 -- abstracting wrt *all* the tyvars.  We'll see if that
1122                 -- gives rise to problems.   SLPJ June 98
1123
1124     abstract subst (Rec prs)
1125        = do { (poly_ids, poly_apps) <- mapAndUnzipM (mk_poly tvs_here) ids
1126             ; let subst' = CoreSubst.extendSubstList subst (ids `zip` poly_apps)
1127                   poly_rhss = [mkLams tvs_here (CoreSubst.substExpr subst' rhs) | rhs <- rhss]
1128             ; return (subst', Rec (poly_ids `zip` poly_rhss)) }
1129        where
1130          (ids,rhss) = unzip prs
1131                 -- For a recursive group, it's a bit of a pain to work out the minimal
1132                 -- set of tyvars over which to abstract:
1133                 --      /\ a b c.  let x = ...a... in
1134                 --                 letrec { p = ...x...q...
1135                 --                          q = .....p...b... } in
1136                 --                 ...
1137                 -- Since 'x' is abstracted over 'a', the {p,q} group must be abstracted
1138                 -- over 'a' (because x is replaced by (poly_x a)) as well as 'b'.  
1139                 -- Since it's a pain, we just use the whole set, which is always safe
1140                 -- 
1141                 -- If you ever want to be more selective, remember this bizarre case too:
1142                 --      x::a = x
1143                 -- Here, we must abstract 'x' over 'a'.
1144          tvs_here = main_tvs
1145
1146     mk_poly tvs_here var
1147       = do { uniq <- getUniqueM
1148            ; let  poly_name = setNameUnique (idName var) uniq           -- Keep same name
1149                   poly_ty   = mkForAllTys tvs_here (idType var) -- But new type of course
1150                   poly_id   = mkLocalId poly_name poly_ty 
1151            ; return (poly_id, mkTyApps (Var poly_id) (mkTyVarTys tvs_here)) }
1152                 -- In the olden days, it was crucial to copy the occInfo of the original var, 
1153                 -- because we were looking at occurrence-analysed but as yet unsimplified code!
1154                 -- In particular, we mustn't lose the loop breakers.  BUT NOW we are looking
1155                 -- at already simplified code, so it doesn't matter
1156                 -- 
1157                 -- It's even right to retain single-occurrence or dead-var info:
1158                 -- Suppose we started with  /\a -> let x = E in B
1159                 -- where x occurs once in B. Then we transform to:
1160                 --      let x' = /\a -> E in /\a -> let x* = x' a in B
1161                 -- where x* has an INLINE prag on it.  Now, once x* is inlined,
1162                 -- the occurrences of x' will be just the occurrences originally
1163                 -- pinned on x.
1164 \end{code}
1165
1166 Note [Abstract over coercions]
1167 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1168 If a coercion variable (g :: a ~ Int) is free in the RHS, then so is the
1169 type variable a.  Rather than sort this mess out, we simply bale out and abstract
1170 wrt all the type variables if any of them are coercion variables.
1171
1172
1173 Historical note: if you use let-bindings instead of a substitution, beware of this:
1174
1175                 -- Suppose we start with:
1176                 --
1177                 --      x = /\ a -> let g = G in E
1178                 --
1179                 -- Then we'll float to get
1180                 --
1181                 --      x = let poly_g = /\ a -> G
1182                 --          in /\ a -> let g = poly_g a in E
1183                 --
1184                 -- But now the occurrence analyser will see just one occurrence
1185                 -- of poly_g, not inside a lambda, so the simplifier will
1186                 -- PreInlineUnconditionally poly_g back into g!  Badk to square 1!
1187                 -- (I used to think that the "don't inline lone occurrences" stuff
1188                 --  would stop this happening, but since it's the *only* occurrence,
1189                 --  PreInlineUnconditionally kicks in first!)
1190                 --
1191                 -- Solution: put an INLINE note on g's RHS, so that poly_g seems
1192                 --           to appear many times.  (NB: mkInlineMe eliminates
1193                 --           such notes on trivial RHSs, so do it manually.)
1194
1195 %************************************************************************
1196 %*                                                                      *
1197                 prepareAlts
1198 %*                                                                      *
1199 %************************************************************************
1200
1201 prepareAlts tries these things:
1202
1203 1.  If several alternatives are identical, merge them into
1204     a single DEFAULT alternative.  I've occasionally seen this 
1205     making a big difference:
1206
1207         case e of               =====>     case e of
1208           C _ -> f x                         D v -> ....v....
1209           D v -> ....v....                   DEFAULT -> f x
1210           DEFAULT -> f x
1211
1212    The point is that we merge common RHSs, at least for the DEFAULT case.
1213    [One could do something more elaborate but I've never seen it needed.]
1214    To avoid an expensive test, we just merge branches equal to the *first*
1215    alternative; this picks up the common cases
1216         a) all branches equal
1217         b) some branches equal to the DEFAULT (which occurs first)
1218
1219 2.  Case merging:
1220        case e of b {             ==>   case e of b {
1221          p1 -> rhs1                      p1 -> rhs1
1222          ...                             ...
1223          pm -> rhsm                      pm -> rhsm
1224          _  -> case b of b' {            pn -> let b'=b in rhsn
1225                      pn -> rhsn          ...
1226                      ...                 po -> let b'=b in rhso
1227                      po -> rhso          _  -> let b'=b in rhsd
1228                      _  -> rhsd
1229        }  
1230     
1231     which merges two cases in one case when -- the default alternative of
1232     the outer case scrutises the same variable as the outer case This
1233     transformation is called Case Merging.  It avoids that the same
1234     variable is scrutinised multiple times.
1235
1236
1237 The case where transformation (1) showed up was like this (lib/std/PrelCError.lhs):
1238
1239         x | p `is` 1 -> e1
1240           | p `is` 2 -> e2
1241         ...etc...
1242
1243 where @is@ was something like
1244         
1245         p `is` n = p /= (-1) && p == n
1246
1247 This gave rise to a horrible sequence of cases
1248
1249         case p of
1250           (-1) -> $j p
1251           1    -> e1
1252           DEFAULT -> $j p
1253
1254 and similarly in cascade for all the join points!
1255
1256 Note [Dead binders]
1257 ~~~~~~~~~~~~~~~~~~~~
1258 We do this *here*, looking at un-simplified alternatives, because we
1259 have to check that r doesn't mention the variables bound by the
1260 pattern in each alternative, so the binder-info is rather useful.
1261
1262 \begin{code}
1263 prepareAlts :: SimplEnv -> OutExpr -> OutId -> [InAlt] -> SimplM ([AltCon], [InAlt])
1264 prepareAlts env scrut case_bndr' alts
1265   = do  { dflags <- getDOptsSmpl
1266         ; alts <- combineIdenticalAlts case_bndr' alts
1267
1268         ; let (alts_wo_default, maybe_deflt) = findDefault alts
1269               alt_cons = [con | (con,_,_) <- alts_wo_default]
1270               imposs_deflt_cons = nub (imposs_cons ++ alt_cons)
1271                 -- "imposs_deflt_cons" are handled 
1272                 --   EITHER by the context, 
1273                 --   OR by a non-DEFAULT branch in this case expression.
1274
1275         ; default_alts <- prepareDefault dflags env case_bndr' mb_tc_app 
1276                                          imposs_deflt_cons maybe_deflt
1277
1278         ; let trimmed_alts = filterOut impossible_alt alts_wo_default
1279               merged_alts = mergeAlts trimmed_alts default_alts
1280                 -- We need the mergeAlts in case the new default_alt 
1281                 -- has turned into a constructor alternative.
1282                 -- The merge keeps the inner DEFAULT at the front, if there is one
1283                 -- and interleaves the alternatives in the right order
1284
1285         ; return (imposs_deflt_cons, merged_alts) }
1286   where
1287     mb_tc_app = splitTyConApp_maybe (idType case_bndr')
1288     Just (_, inst_tys) = mb_tc_app 
1289
1290     imposs_cons = case scrut of
1291                     Var v -> otherCons (idUnfolding v)
1292                     other -> []
1293
1294     impossible_alt :: CoreAlt -> Bool
1295     impossible_alt (con, _, _) | con `elem` imposs_cons = True
1296     impossible_alt (DataAlt con, _, _) = dataConCannotMatch inst_tys con
1297     impossible_alt alt                 = False
1298
1299
1300 --------------------------------------------------
1301 --      1. Merge identical branches
1302 --------------------------------------------------
1303 combineIdenticalAlts :: OutId -> [InAlt] -> SimplM [InAlt]
1304
1305 combineIdenticalAlts case_bndr alts@((con1,bndrs1,rhs1) : con_alts)
1306   | all isDeadBinder bndrs1,                    -- Remember the default 
1307     length filtered_alts < length con_alts      -- alternative comes first
1308         -- Also Note [Dead binders]
1309   = do  { tick (AltMerge case_bndr)
1310         ; return ((DEFAULT, [], rhs1) : filtered_alts) }
1311   where
1312     filtered_alts        = filter keep con_alts
1313     keep (con,bndrs,rhs) = not (all isDeadBinder bndrs && rhs `cheapEqExpr` rhs1)
1314
1315 combineIdenticalAlts case_bndr alts = return alts
1316
1317 -------------------------------------------------------------------------
1318 --                      Prepare the default alternative
1319 -------------------------------------------------------------------------
1320 prepareDefault :: DynFlags
1321                -> SimplEnv
1322                -> OutId         -- Case binder; need just for its type. Note that as an
1323                                 --   OutId, it has maximum information; this is important.
1324                                 --   Test simpl013 is an example
1325                -> Maybe (TyCon, [Type]) -- Type of scrutinee, decomposed
1326                -> [AltCon]      -- These cons can't happen when matching the default
1327                -> Maybe InExpr  -- Rhs
1328                -> SimplM [InAlt]        -- Still unsimplified
1329                                         -- We use a list because it's what mergeAlts expects,
1330                                         -- And becuase case-merging can cause many to show up
1331
1332 ------- Merge nested cases ----------
1333 prepareDefault dflags env outer_bndr bndr_ty imposs_cons (Just deflt_rhs)
1334   | dopt Opt_CaseMerge dflags
1335   , Case (Var inner_scrut_var) inner_bndr _ inner_alts <- deflt_rhs
1336   , DoneId inner_scrut_var' <- substId env inner_scrut_var
1337         -- Remember, inner_scrut_var is an InId, but outer_bndr is an OutId
1338   , inner_scrut_var' == outer_bndr
1339         -- NB: the substId means that if the outer scrutinee was a 
1340         --     variable, and inner scrutinee is the same variable, 
1341         --     then inner_scrut_var' will be outer_bndr
1342         --     via the magic of simplCaseBinder
1343   = do  { tick (CaseMerge outer_bndr)
1344
1345         ; let munge_rhs rhs = bindCaseBndr inner_bndr (Var outer_bndr) rhs
1346         ; return [(con, args, munge_rhs rhs) | (con, args, rhs) <- inner_alts,
1347                                                not (con `elem` imposs_cons) ]
1348                 -- NB: filter out any imposs_cons.  Example:
1349                 --      case x of 
1350                 --        A -> e1
1351                 --        DEFAULT -> case x of 
1352                 --                      A -> e2
1353                 --                      B -> e3
1354                 -- When we merge, we must ensure that e1 takes 
1355                 -- precedence over e2 as the value for A!  
1356         }
1357         -- Warning: don't call prepareAlts recursively!
1358         -- Firstly, there's no point, because inner alts have already had
1359         -- mkCase applied to them, so they won't have a case in their default
1360         -- Secondly, if you do, you get an infinite loop, because the bindCaseBndr
1361         -- in munge_rhs may put a case into the DEFAULT branch!
1362
1363
1364 --------- Fill in known constructor -----------
1365 prepareDefault dflags env case_bndr (Just (tycon, inst_tys)) imposs_cons (Just deflt_rhs)
1366   |     -- This branch handles the case where we are 
1367         -- scrutinisng an algebraic data type
1368     isAlgTyCon tycon            -- It's a data type, tuple, or unboxed tuples.  
1369   , not (isNewTyCon tycon)      -- We can have a newtype, if we are just doing an eval:
1370                                 --      case x of { DEFAULT -> e }
1371                                 -- and we don't want to fill in a default for them!
1372   , Just all_cons <- tyConDataCons_maybe tycon
1373   , not (null all_cons)         -- This is a tricky corner case.  If the data type has no constructors,
1374                                 -- which GHC allows, then the case expression will have at most a default
1375                                 -- alternative.  We don't want to eliminate that alternative, because the
1376                                 -- invariant is that there's always one alternative.  It's more convenient
1377                                 -- to leave     
1378                                 --      case x of { DEFAULT -> e }     
1379                                 -- as it is, rather than transform it to
1380                                 --      error "case cant match"
1381                                 -- which would be quite legitmate.  But it's a really obscure corner, and
1382                                 -- not worth wasting code on.
1383   , let imposs_data_cons = [con | DataAlt con <- imposs_cons]   -- We now know it's a data type 
1384         impossible con  = con `elem` imposs_data_cons || dataConCannotMatch inst_tys con
1385   = case filterOut impossible all_cons of
1386         []    -> return []      -- Eliminate the default alternative
1387                                 -- altogether if it can't match
1388
1389         [con] ->        -- It matches exactly one constructor, so fill it in
1390                  do { tick (FillInCaseDefault case_bndr)
1391                     ; us <- getUniquesM
1392                     ; let (ex_tvs, co_tvs, arg_ids) =
1393                               dataConRepInstPat us con inst_tys
1394                     ; return [(DataAlt con, ex_tvs ++ co_tvs ++ arg_ids, deflt_rhs)] }
1395
1396         two_or_more -> return [(DEFAULT, [], deflt_rhs)]
1397
1398 --------- Catch-all cases -----------
1399 prepareDefault dflags env case_bndr bndr_ty imposs_cons (Just deflt_rhs)
1400   = return [(DEFAULT, [], deflt_rhs)]
1401
1402 prepareDefault dflags env case_bndr bndr_ty imposs_cons Nothing
1403   = return []   -- No default branch
1404 \end{code}
1405
1406
1407
1408 =================================================================================
1409
1410 mkCase tries these things
1411
1412 1.  Eliminate the case altogether if possible
1413
1414 2.  Case-identity:
1415
1416         case e of               ===> e
1417                 True  -> True;
1418                 False -> False
1419
1420     and similar friends.
1421
1422
1423 \begin{code}
1424 mkCase :: OutExpr -> OutId -> OutType
1425        -> [OutAlt]              -- Increasing order
1426        -> SimplM OutExpr
1427
1428 --------------------------------------------------
1429 --      1. Check for empty alternatives
1430 --------------------------------------------------
1431
1432 -- This isn't strictly an error.  It's possible that the simplifer might "see"
1433 -- that an inner case has no accessible alternatives before it "sees" that the
1434 -- entire branch of an outer case is inaccessible.  So we simply
1435 -- put an error case here insteadd
1436 mkCase scrut case_bndr ty []
1437   = pprTrace "mkCase: null alts" (ppr case_bndr <+> ppr scrut) $
1438     return (mkApps (Var rUNTIME_ERROR_ID)
1439                    [Type ty, Lit (mkStringLit "Impossible alternative")])
1440
1441
1442 --------------------------------------------------
1443 --      2. Identity case
1444 --------------------------------------------------
1445
1446 mkCase scrut case_bndr ty alts  -- Identity case
1447   | all identity_alt alts
1448   = do tick (CaseIdentity case_bndr)
1449        return (re_cast scrut)
1450   where
1451     identity_alt (con, args, rhs) = check_eq con args (de_cast rhs)
1452
1453     check_eq DEFAULT       _    (Var v)   = v == case_bndr
1454     check_eq (LitAlt lit') _    (Lit lit) = lit == lit'
1455     check_eq (DataAlt con) args rhs       = rhs `cheapEqExpr` mkConApp con (arg_tys ++ varsToCoreExprs args)
1456                                          || rhs `cheapEqExpr` Var case_bndr
1457     check_eq con args rhs = False
1458
1459     arg_tys = map Type (tyConAppArgs (idType case_bndr))
1460
1461         -- We've seen this:
1462         --      case e of x { _ -> x `cast` c }
1463         -- And we definitely want to eliminate this case, to give
1464         --      e `cast` c
1465         -- So we throw away the cast from the RHS, and reconstruct
1466         -- it at the other end.  All the RHS casts must be the same
1467         -- if (all identity_alt alts) holds.
1468         -- 
1469         -- Don't worry about nested casts, because the simplifier combines them
1470     de_cast (Cast e _) = e
1471     de_cast e          = e
1472
1473     re_cast scrut = case head alts of
1474                         (_,_,Cast _ co) -> Cast scrut co
1475                         other           -> scrut
1476
1477
1478
1479 --------------------------------------------------
1480 --      Catch-all
1481 --------------------------------------------------
1482 mkCase scrut bndr ty alts = return (Case scrut bndr ty alts)
1483 \end{code}
1484
1485
1486 When adding auxiliary bindings for the case binder, it's worth checking if
1487 its dead, because it often is, and occasionally these mkCase transformations
1488 cascade rather nicely.
1489
1490 \begin{code}
1491 bindCaseBndr bndr rhs body
1492   | isDeadBinder bndr = body
1493   | otherwise         = bindNonRec bndr rhs body
1494 \end{code}