Drop pre-AMP compatibility CPP conditionals
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.1], [glasgow-haskell-bugs@haskell.org], [ghc])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands,
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42 FP_PROG_SORT
43
44 dnl ----------------------------------------------------------
45 FP_SETUP_PROJECT_VERSION
46
47 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
48 AC_SUBST([release], [1])
49
50 # First off, a distrib sanity check..
51 AC_CONFIG_SRCDIR([mk/config.mk.in])
52
53 dnl * We require autoconf version 2.60
54 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
55 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
56 dnl Using autoconf 2.59 started to give nonsense like this
57 dnl  #define SIZEOF_CHAR 0
58 dnl recently.
59 AC_PREREQ([2.60])
60
61 # -------------------------------------------------------------------------
62 # Prepare to generate the following header files
63 #
64 #
65 AC_CONFIG_HEADER(mk/config.h)
66
67 # No, semi-sadly, we don't do `--srcdir'...
68 if test x"$srcdir" != 'x.' ; then
69     echo "This configuration does not support the \`--srcdir' option.."
70     exit 1
71 fi
72
73 dnl --------------------------------------------------------------
74 dnl * Project specific configuration options
75 dnl --------------------------------------------------------------
76 dnl What follows is a bunch of options that can either be configured
77 dnl through command line options to the configure script or by
78 dnl supplying defns in the build tree's mk/build.mk. Having the option to
79 dnl use either is considered a Feature.
80
81 dnl ** What command to use to compile compiler sources ?
82 dnl --------------------------------------------------------------
83
84 AC_ARG_WITH([ghc],
85 [AC_HELP_STRING([--with-ghc=ARG],
86   [Use ARG as the path to GHC  [default=autodetect]])],
87   [WithGhc="$withval"],
88   [if test "$GHC" = ""; then
89     AC_PATH_PROG([GHC], [ghc])
90   fi
91   WithGhc="$GHC"])
92
93 dnl ** Tell the make system which OS we are using
94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
95 AC_SUBST(OSTYPE)
96
97 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
98 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
99                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
100         EnableBootstrapWithDevelSnaphost=YES,
101         EnableBootstrapWithDevelSnaphost=NO
102 )
103
104 AC_ARG_ENABLE(tarballs-autodownload,
105 [AC_HELP_STRING([--enable-tarballs-autodownload],
106                 [Automatically download Windows distribution binaries if needed.])],
107         TarballsAutodownload=YES,
108         TarballsAutodownload=NO
109 )
110 if test "$WithGhc" != ""; then
111   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
112
113   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
114      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
115   fi
116
117   AC_SUBST(GhcVersion)dnl
118   AC_SUBST(GhcMajVersion)dnl
119   AC_SUBST(GhcMinVersion)dnl
120   AC_SUBST(GhcPatchLevel)dnl
121   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
122   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
123
124   BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
125   dnl ToDo, once "ld command" is reliably available.
126   dnl Then, we can remove the LD_STAGE0 hack in mk/build-package-date.mk
127   dnl BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
128   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
129   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
130   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
131 fi
132
133 dnl ** Must have GHC to build GHC
134 if test "$WithGhc" = ""
135 then
136     AC_MSG_ERROR([GHC is required.])
137 fi
138 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.10],
139     [AC_MSG_ERROR([GHC version 7.10 or later is required to compile GHC.])])
140
141 if test `expr $GhcMinVersion % 2` = "1"
142 then
143     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
144     then
145         AC_MSG_ERROR([
146      $WithGhc is a development snapshot of GHC, version $GhcVersion.
147      Bootstrapping using this version of GHC is not supported, and may not
148      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
149      or --with-ghc to specify a different GHC to use.])
150     fi
151 fi
152
153 GHC_PACKAGE_DB_FLAG=package-db
154 AC_SUBST(GHC_PACKAGE_DB_FLAG)
155
156 # GHC 7.7+ needs -fcmm-sink when compiling Parser.hs. See #8182
157 FP_COMPARE_VERSIONS([$GhcVersion],[-gt],[7.7],
158                     CMM_SINK_BOOTSTRAP_IS_NEEDED=YES,
159                     CMM_SINK_BOOTSTRAP_IS_NEEDED=NO)
160 AC_SUBST(CMM_SINK_BOOTSTRAP_IS_NEEDED)
161
162 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.9],
163                     SUPPORTS_COMPONENT_ID=NO,
164                     SUPPORTS_COMPONENT_ID=YES)
165 AC_SUBST(SUPPORTS_COMPONENT_ID)
166
167 # GHC is passed to Cabal, so we need a native path
168 if test "${WithGhc}" != ""
169 then
170     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
171
172     if test "$ghc_host_os" = "mingw32"
173     then
174         if test "${OSTYPE}" = "msys"
175         then
176             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
177         else
178             # Canonicalise to <drive>:/path/to/ghc
179             WithGhc=`cygpath -m "${WithGhc}"`
180         fi
181         echo "GHC path canonicalised to: ${WithGhc}"
182     fi
183 fi
184 AC_SUBST([WithGhc])
185
186 dnl ** Without optimization some INLINE trickery fails for GHCi
187 SRC_CC_OPTS="-O"
188
189 dnl--------------------------------------------------------------------
190 dnl * Choose host(/target/build) platform
191 dnl--------------------------------------------------------------------
192 dnl If we aren't explicitly told what values to use with configure flags,
193 dnl we ask the bootstrapping compiler what platform it is for
194
195 if test "${WithGhc}" != ""
196 then
197         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
198         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
199         if test "$bootstrap_host" != "$bootstrap_target"
200         then
201                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
202         fi
203 fi
204
205 # We have to run these unconditionally, but we may discard their
206 # results in the following code
207 AC_CANONICAL_BUILD
208 AC_CANONICAL_HOST
209 AC_CANONICAL_TARGET
210
211 FPTOOLS_SET_PLATFORM_VARS
212
213 # Verify that the installed (bootstrap) GHC is capable of generating
214 # code for the requested build platform.
215 if test "$BuildPlatform" != "$bootstrap_target"
216 then
217     echo "This GHC (${WithGhc}) does not generate code for the build platform"
218     echo "   GHC target platform    : $bootstrap_target"
219     echo "   Desired build platform : $BuildPlatform"
220     exit 1
221 fi
222
223 # Testing if we shall enable shared libs support on Solaris.
224 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
225
226 SOLARIS_BROKEN_SHLD=NO
227
228 case $host in
229      i386-*-solaris2)
230      # here we go with the test
231      MINOR=`uname -r|cut -d '.' -f 2-`
232      if test "$MINOR" -lt "11"; then
233          SOLARIS_BROKEN_SHLD=YES
234      fi
235      ;;
236 esac
237
238 AC_SUBST(SOLARIS_BROKEN_SHLD)
239
240 dnl ** Do an unregisterised build?
241 dnl --------------------------------------------------------------
242 case "$HostArch" in
243     i386|x86_64|powerpc|powerpc64|powerpc64le|arm)
244         UnregisterisedDefault=NO
245         ;;
246     *)
247         UnregisterisedDefault=YES
248         ;;
249 esac
250 AC_ARG_ENABLE(unregisterised,
251 [AC_HELP_STRING([--enable-unregisterised],
252 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
253 [ if test x"$enableval" = x"yes"; then
254         Unregisterised=YES
255   else
256         Unregisterised=NO
257   fi
258 ],
259 [Unregisterised="$UnregisterisedDefault"]
260 )
261 AC_SUBST(Unregisterised)
262
263 AC_ARG_WITH(hc,
264 [AC_HELP_STRING([--with-hc=ARG],
265         [Use ARG as the path to the compiler for compiling ordinary
266          Haskell code  (default= value of --with-ghc)])],
267 [WithHc="$withval"],
268 [WithHc=$WithGhc]
269 )
270 AC_SUBST(WithHc)
271
272 # This uses GHC, so put it after the "GHC is required" check above:
273 FP_INTREE_GHC_PWD
274 FP_FIND_ROOT
275
276 fail() {
277     echo >&2
278     echo "$1" >&2
279     exit 1
280 }
281
282
283 if test "$HostOS" = "mingw32"
284 then
285     # Find the mingw-w64 7z file to extract.
286     # NB. If you update the tarballs to a new version of gcc, don't
287     # forget to tweak the paths in driver/gcc/gcc.c.
288     if test "$HostArch" = "i386"
289     then
290         mingw_arch="i686"
291         tarball_dest_dir="mingw-w64/x86"
292         tarball_mingw_dir="mingw32"
293     else
294         mingw_arch="x86_64"
295         tarball_dest_dir="mingw-w64/x86_64"
296         tarball_mingw_dir="mingw64"
297     fi
298 fi
299
300 set_up_tarballs() {
301     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
302     local action
303     if test "$TarballsAutodownload" = "NO"
304     then
305         action="verify"
306     else
307         action="download"
308     fi
309     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
310     case $? in
311         0)
312            rm missing-win32-tarballs
313            ;;
314         2)
315            echo
316            echo "Error:"
317            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
318            echo
319            echo "  * run configure with the --enable-tarballs-autodownload option"
320            echo
321            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
322            echo
323            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
324            echo "    them in the ghc-tarballs directory."
325            echo
326            exit 1
327            ;;
328         *)
329            echo
330            echo "Error fetching msys2 tarballs; see errors above."
331            exit 1
332            ;;
333     esac
334
335     # Extract all the tarballs in one go
336     if ! test -d inplace/mingw
337     then
338         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
339         rm -rf inplace/mingw
340         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
341         ( cd inplace &&
342         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
343         rm ".MTREE" &&
344         rm ".PKGINFO" &&
345         cd .. ) || fail "Error: Could not extract Windows toolchains."
346
347         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
348         touch inplace/mingw
349
350         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
351         # make a wrapper around it to give it the proper paths
352         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
353         PATH=`pwd`/inplace/mingw/bin:$PATH
354         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
355
356         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
357     fi
358 }
359
360 if test "$HostOS" = "mingw32"
361 then
362     test -d inplace || mkdir inplace
363
364     # NB. Download and extract the MingW-w64 distribution if required
365     set_up_tarballs
366
367     mingwbin="$hardtop/inplace/mingw/bin/"
368     CC="${mingwbin}gcc.exe"
369     LD="${mingwbin}ld.exe"
370     NM="${mingwbin}nm.exe"
371     RANLIB="${mingwbin}ranlib.exe"
372     OBJDUMP="${mingwbin}objdump.exe"
373     fp_prog_ar="${mingwbin}ar.exe"
374
375     # NB. Download the perl binaries if required
376     if ! test -d inplace/perl ||
377          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
378     then
379         AC_MSG_NOTICE([Making in-tree perl tree])
380         rm -rf inplace/perl
381         mkdir inplace/perl
382         (
383             cd inplace/perl &&
384             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
385         )
386         AC_MSG_NOTICE([In-tree perl tree created])
387     fi
388 fi
389
390 FP_ICONV
391 FP_GMP
392 FP_CURSES
393
394 XCODE_VERSION()
395
396 SplitObjsBroken=NO
397 if test "$TargetOS_CPP" = "darwin"
398 then
399     # Split objects is broken (#4013) with XCode < 3.2
400     if test "$XCodeVersion1" -lt 3
401     then
402         SplitObjsBroken=YES
403     else
404         if test "$XCodeVersion1" -eq 3
405         then
406             if test "$XCodeVersion2" -lt 2
407             then
408                 SplitObjsBroken=YES
409             fi
410         fi
411     fi
412 fi
413 AC_SUBST([SplitObjsBroken])
414
415 dnl ** Building a cross compiler?
416 dnl --------------------------------------------------------------
417 CrossCompiling=NO
418 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
419 if test "$target" != "$host" ; then
420     CrossCompiling=YES
421     cross_compiling=yes   # This tells configure that it can accept just 'target',
422                           # otherwise you get
423                           #   configure: error: cannot run C compiled programs.
424                           #   If you meant to cross compile, use `--host'.
425 fi
426 if test "$build" != "$host" ; then
427    AC_MSG_ERROR([
428 You've selected:
429
430   BUILD:  $build   (the architecture we're building on)
431   HOST:   $host    (the architecture the compiler we're building will execute on)
432   TARGET: $target  (the architecture the compiler we're building will produce code for)
433
434 BUILD must equal HOST; that is, we do not support building GHC itself
435 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
436 1 will be a cross-compiler, and stage 2 will be the cross-compiled
437 GHC.
438 ])
439 fi
440 if test "$CrossCompiling" = "YES"
441 then
442   CrossCompilePrefix="${target}-"
443 else
444   CrossCompilePrefix=""
445 fi
446 TargetPlatformFull="${target}"
447 AC_SUBST(CrossCompiling)
448 AC_SUBST(CrossCompilePrefix)
449 AC_SUBST(TargetPlatformFull)
450
451 dnl ** Which gcc to use?
452 dnl --------------------------------------------------------------
453 FIND_GCC([WhatGccIsCalled], [gcc], [gcc])
454 CC="$WhatGccIsCalled"
455 export CC
456
457 # If --with-gcc was used, and we're not cross-compiling, then it also
458 # applies to the stage0 compiler.
459 MAYBE_OVERRIDE_STAGE0([gcc],[CC_STAGE0])
460 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
461
462 dnl make extensions visible to allow feature-tests to detect them lateron
463 AC_USE_SYSTEM_EXTENSIONS
464
465 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
466 AC_PROG_CPP
467
468 # --with-hs-cpp/--with-hs-cpp-flags
469 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
470 AC_SUBST([HaskellCPPCmd])
471 AC_SUBST([HaskellCPPArgs])
472
473 dnl ** Which ld to use?
474 dnl --------------------------------------------------------------
475 FIND_LD([LdCmd])
476 AC_SUBST([LdCmd])
477
478 dnl ** Which nm to use?
479 dnl --------------------------------------------------------------
480 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
481 NmCmd="$NM"
482 AC_SUBST([NmCmd])
483
484 dnl ** Which objdump to use?
485 dnl --------------------------------------------------------------
486 FP_ARG_WITH_PATH_GNU_PROG_OPTIONAL([OBJDUMP], [objdump], [objdump])
487 ObjdumpCmd="$OBJDUMP"
488 AC_SUBST([ObjdumpCmd])
489
490 dnl ** Which ar to use?
491 dnl --------------------------------------------------------------
492 FP_ARG_WITH_PATH_GNU_PROG([AR], [ar], [ar])
493 ArCmd="$AR"
494 fp_prog_ar="$AR"
495 AC_SUBST([ArCmd])
496
497 dnl ** Which ranlib to use?
498 dnl --------------------------------------------------------------
499 FP_ARG_WITH_PATH_GNU_PROG([RANLIB], [ranlib], [ranlib])
500 RanlibCmd="$RANLIB"
501 RANLIB="$RanlibCmd"
502
503
504 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
505 case $HostOS_CPP in
506 cygwin32|mingw32)
507     dnl ** Which objdump to use?
508     dnl --------------------------------------------------------------
509     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
510     ObjdumpCmd="$OBJDUMP"
511     AC_SUBST([ObjdumpCmd])
512     ;;
513 esac
514
515 # Here is where we re-target which specific version of the LLVM
516 # tools we are looking for. In the past, GHC supported a number of
517 # versions of LLVM simultaneously, but that stopped working around
518 # 3.5/3.6 release of LLVM.
519 LlvmVersion=3.7
520 AC_SUBST([LlvmVersion])
521 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
522 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
523
524 dnl ** Which LLVM llc to use?
525 dnl --------------------------------------------------------------
526 FIND_LLVM_PROG([LLC], [llc], [llc], [$LlvmVersion])
527 LlcCmd="$LLC"
528 AC_SUBST([LlcCmd])
529
530 dnl ** Which LLVM opt to use?
531 dnl --------------------------------------------------------------
532 FIND_LLVM_PROG([OPT], [opt], [opt], [$LlvmVersion])
533 OptCmd="$OPT"
534 AC_SUBST([OptCmd])
535
536 dnl --------------------------------------------------------------
537 dnl End of configure script option section
538 dnl --------------------------------------------------------------
539
540
541 dnl --------------------------------------------------------------
542 dnl * General configuration checks
543 dnl --------------------------------------------------------------
544
545 dnl ** Bug 9439: Some GHC 7.8 releases had broken LLVM code generator.
546 dnl Unfortunately we don't know whether the user is going to request a
547 dnl build with the LLVM backend as this is only given in build.mk.
548 dnl
549 dnl Instead, we try to do as much work as possible here, checking
550 dnl whether -fllvm is the stage 0 compiler's default. If so we
551 dnl fail. If not, we check whether -fllvm is affected explicitly and
552 dnl if so set a flag. The build system will later check this flag
553 dnl after the desired build flags are known.
554
555 dnl This problem is further complicated by the fact that the llvm
556 dnl version used by the bootstrap compiler may be different from the
557 dnl version we arre trying to compile GHC against. Therefore, we need
558 dnl to find the boostrap compiler's `settings` file then check to see
559 dnl if the `opt` and `llc` command strings are non-empty and if these
560 dnl programs exist. Only if they exist to we test for bug #9439.
561
562 FIND_GHC_BOOTSTRAP_PROG([BootstrapLlcCmd], [${WithGhc}], "LLVM llc command")
563 FIND_GHC_BOOTSTRAP_PROG([BootstrapOptCmd], [${WithGhc}], "LLVM opt command")
564
565 if test -n "$BootstrapLlcCmd" && test -n "$BootstrapOptCmd"
566 then
567     AC_MSG_CHECKING(whether bootstrap compiler is affected by bug 9439)
568     echo "main = putStrLn \"%function\"" > conftestghc.hs
569
570     # Check whether LLVM backend is default for this platform
571     "${WithGhc}" -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" conftestghc.hs 2>&1 >/dev/null
572     res=`./conftestghc`
573     if test "x$res" = "x%object"
574     then
575         AC_MSG_RESULT(yes)
576         echo "Buggy bootstrap compiler"
577         echo ""
578         echo "The stage 0 compiler $WithGhc is affected by GHC Bug \#9439"
579         echo "and therefore will miscompile the LLVM backend if -fllvm is"
580         echo "used."
581         echo
582         echo "Please use another bootstrap compiler"
583         exit 1
584     fi
585
586     # -fllvm is not the default, but set a flag so the Makefile can check
587     # -for it in the build flags later on
588     "${WithGhc}" -fforce-recomp -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" -fllvm conftestghc.hs 2>&1 >/dev/null
589     if test $? = 0
590     then
591         res=`./conftestghc`
592         if test "x$res" = "x%object"
593         then
594             AC_MSG_RESULT(yes)
595             GHC_LLVM_AFFECTED_BY_9439=1
596         elif test "x$res" = "x%function"
597         then
598             AC_MSG_RESULT(no)
599             GHC_LLVM_AFFECTED_BY_9439=0
600         else
601             AC_MSG_WARN(unexpected output $res)
602         fi
603     else
604         AC_MSG_RESULT(failed to compile, assuming no)
605     fi
606 fi
607 AC_SUBST([GHC_LLVM_AFFECTED_BY_9439])
608
609 dnl ** Can the unix package be built?
610 dnl --------------------------------------------------------------
611
612 if test "$TargetOS" = "mingw32"
613 then
614     GhcLibsWithUnix=NO
615 else
616     GhcLibsWithUnix=YES
617 fi
618 AC_SUBST([GhcLibsWithUnix])
619
620 dnl ** does #! work?
621 AC_SYS_INTERPRETER()
622
623 dnl ** look for `perl'
624 case $HostOS_CPP in
625 cygwin32|mingw32)
626     PerlCmd=$hardtop/inplace/perl/perl
627     ;;
628 *)
629     AC_PATH_PROG(PerlCmd,perl)
630     if test -z "$PerlCmd"
631     then
632         echo "You must install perl before you can continue"
633         echo "Perhaps it is already installed, but not in your PATH?"
634         exit 1
635     else
636         FPTOOLS_CHECK_PERL_VERSION
637     fi
638     ;;
639 esac
640
641 dnl ** look for GCC and find out which version
642 dnl     Figure out which C compiler to use.  Gcc is preferred.
643 dnl     If gcc, make sure it's at least 3.0
644 dnl
645 FP_GCC_VERSION
646
647 dnl ** look to see if we have a C compiler using an llvm back end.
648 dnl
649 FP_CC_LLVM_BACKEND
650
651 FP_PROG_LD_IS_GNU
652 FP_PROG_LD_BUILD_ID
653 FP_PROG_LD_NO_COMPACT_UNWIND
654 FP_PROG_LD_FILELIST
655
656
657 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
658 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
659 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
660 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
661 # Stage 3 won't be supported by cross-compilation
662
663 FP_GCC_EXTRA_FLAGS
664
665 AC_SUBST(CONF_CC_OPTS_STAGE0)
666 AC_SUBST(CONF_CC_OPTS_STAGE1)
667 AC_SUBST(CONF_CC_OPTS_STAGE2)
668 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
669 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
670 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
671 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
672 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
673 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
674 AC_SUBST(CONF_CPP_OPTS_STAGE0)
675 AC_SUBST(CONF_CPP_OPTS_STAGE1)
676 AC_SUBST(CONF_CPP_OPTS_STAGE2)
677
678 dnl ** Set up the variables for the platform in the settings file.
679 dnl May need to use gcc to find platform details.
680 dnl --------------------------------------------------------------
681 FPTOOLS_SET_HASKELL_PLATFORM_VARS
682
683 dnl ** figure out how to do context diffs
684 FP_PROG_CONTEXT_DIFF
685
686 dnl Let's make sure install-sh is executable here.  If we got it from
687 dnl a darcs repo, it might not be (see bug #978).
688 chmod +x install-sh
689 dnl ** figure out how to do a BSD-ish install
690 AC_PROG_INSTALL
691
692 dnl ** how to invoke `ar' and `ranlib'
693 FP_PROG_AR_SUPPORTS_ATFILE
694 FP_PROG_AR_NEEDS_RANLIB
695
696 dnl ** Check to see whether ln -s works
697 AC_PROG_LN_S
698
699 FP_SETTINGS
700
701 dnl ** Find the path to sed
702 AC_PATH_PROGS(SedCmd,gsed sed,sed)
703
704
705 dnl ** check for time command
706 AC_PATH_PROG(TimeCmd,time)
707
708 dnl ** check for tar
709 dnl   if GNU tar is named gtar, look for it first.
710 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
711
712 dnl ** check for patch
713 dnl if GNU patch is named gpatch, look for it first
714 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
715
716 dnl ** check for dtrace (currently only implemented for Mac OS X)
717 HaveDtrace=NO
718 AC_PATH_PROG(DtraceCmd,dtrace)
719 if test -n "$DtraceCmd"; then
720   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
721     HaveDtrace=YES
722   fi
723 fi
724 AC_SUBST(HaveDtrace)
725
726 AC_PATH_PROG(HSCOLOUR,HsColour)
727 # HsColour is passed to Cabal, so we need a native path
728 if test "$HostOS"      = "mingw32" && \
729    test "${OSTYPE}"   != "msys"    && \
730    test "${HSCOLOUR}" != ""
731 then
732     # Canonicalise to <drive>:/path/to/gcc
733     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
734 fi
735
736 dnl ** check for Sphinx toolchain
737 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
738 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
739 changequote(, )dnl
740 [if test -n "$SPHINXBUILD"; then
741   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
742 fi;
743 changequote([, ])dnl
744 ])
745 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
746     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
747
748 dnl ** check for xelatex
749 AC_PATH_PROG(XELATEX,xelatex)
750
751 dnl ** check for ghc-pkg command
752 FP_PROG_GHC_PKG
753
754 dnl ** check for installed happy binary + version
755 FPTOOLS_HAPPY
756
757 dnl ** check for installed alex binary + version
758 FPTOOLS_ALEX
759
760 dnl --------------------------------------------------
761 dnl ### program checking section ends here ###
762 dnl --------------------------------------------------
763
764 dnl --------------------------------------------------
765 dnl * Platform header file and syscall feature tests
766 dnl ### checking the state of the local header files and syscalls ###
767
768 dnl ** check for full ANSI header (.h) files
769 AC_HEADER_STDC
770
771 dnl ** Enable large file support.  NB. do this before testing the type of
772 dnl    off_t, because it will affect the result of that test.
773 AC_SYS_LARGEFILE
774
775 dnl ** check for specific header (.h) files that we are interested in
776 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
777
778 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
779 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
780 [[#if HAVE_SYS_PARAM_H
781 # include <sys/param.h>
782 #endif
783 ]])
784
785 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
786 AC_HEADER_TIME
787
788 dnl ** do we have long longs?
789 AC_CHECK_TYPES([long long])
790
791 dnl ** what are the sizes of various types
792 AC_CHECK_SIZEOF(char,               1)
793 AC_CHECK_SIZEOF(double,             8)
794 AC_CHECK_SIZEOF(float,              4)
795 AC_CHECK_SIZEOF(int,                4)
796 AC_CHECK_SIZEOF(long,               4)
797 if test "$ac_cv_type_long_long" = yes; then
798 AC_CHECK_SIZEOF(long long,          8)
799 fi
800 AC_CHECK_SIZEOF(short,              2)
801 AC_CHECK_SIZEOF(unsigned char,      1)
802 AC_CHECK_SIZEOF(unsigned int,       4)
803 AC_CHECK_SIZEOF(unsigned long,      4)
804 if test "$ac_cv_type_long_long" = yes; then
805 AC_CHECK_SIZEOF(unsigned long long, 8)
806 fi
807 AC_CHECK_SIZEOF(unsigned short,     2)
808 AC_CHECK_SIZEOF(void *,             4)
809
810 dnl for use in settings.in
811 WordSize=$ac_cv_sizeof_void_p
812 AC_SUBST(WordSize)
813
814 dnl ** what are alignment constraints on various types
815 FP_CHECK_ALIGNMENT(char)
816 FP_CHECK_ALIGNMENT(double)
817 FP_CHECK_ALIGNMENT(float)
818 FP_CHECK_ALIGNMENT(int)
819 FP_CHECK_ALIGNMENT(long)
820 if test "$ac_cv_type_long_long" = yes; then
821 FP_CHECK_ALIGNMENT(long long)
822 fi
823 FP_CHECK_ALIGNMENT(short)
824 FP_CHECK_ALIGNMENT(unsigned char)
825 FP_CHECK_ALIGNMENT(unsigned int)
826 FP_CHECK_ALIGNMENT(unsigned long)
827 if test "$ac_cv_type_long_long" = yes; then
828 FP_CHECK_ALIGNMENT(unsigned long long)
829 fi
830 FP_CHECK_ALIGNMENT(unsigned short)
831 FP_CHECK_ALIGNMENT(void *)
832
833 FP_CHECK_FUNC([WinExec],
834   [@%:@include <windows.h>], [WinExec("",0)])
835
836 FP_CHECK_FUNC([GetModuleFileName],
837   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
838
839 dnl ** check for more functions
840 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
841 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
842
843 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
844 dnl ** _POSIX_C_SOURCE is defined
845 AC_CHECK_DECLS([ctime_r], , ,
846 [#define _POSIX_SOURCE 1
847 #define _POSIX_C_SOURCE 199506L
848 #include <time.h>])
849
850 dnl ** check for mingwex library
851 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
852 AC_SUBST(HaveLibMingwEx)
853
854 if test $HaveLibMingwEx = YES ; then
855   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
856 fi
857
858 dnl ** check for math library
859 dnl    Keep that check as early as possible.
860 dnl    as we need to know whether we need libm
861 dnl    for math functions or not
862 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
863 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
864 if test $HaveLibM = YES
865 then
866   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
867 fi
868
869 FP_BFD_SUPPORT
870
871 dnl ################################################################
872 dnl Check for libraries
873 dnl ################################################################
874
875 # system libffi
876
877 AC_ARG_WITH([system-libffi],
878 [AC_HELP_STRING([--with-system-libffi],
879   [Use system provided libffi for RTS [default=no]])
880 ])
881
882 AS_IF([test "x$with_system_libffi" = "xyes"],
883   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
884 )
885
886
887 AC_SUBST(UseSystemLibFFI)
888
889 AC_ARG_WITH([ffi-includes],
890 [AC_HELP_STRING([--with-ffi-includes=ARG],
891   [Find includes for libffi in ARG [default=system default]])
892 ],
893 [
894  if test "x$UseSystemLibFFI" != "xYES"; then
895     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
896  else
897     FFIIncludeDir="$withval"
898     LIBFFI_CFLAGS="-I$withval"
899  fi
900 ])
901
902 AC_SUBST(FFIIncludeDir)
903
904 AC_ARG_WITH([ffi-libraries],
905 [AC_HELP_STRING([--with-ffi-libraries=ARG],
906   [Find libffi in ARG [default=system default]])
907 ],
908 [
909  if test "x$UseSystemLibFFI" != "xYES"; then
910     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
911  else
912     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
913  fi
914 ])
915
916 AC_SUBST(FFILibDir)
917
918 AS_IF([test "$UseSystemLibFFI" = "YES"], [
919  CFLAGS2="$CFLAGS"
920  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
921  LDFLAGS2="$LDFLAGS"
922  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
923  if test "$HostOS" = "openbsd";
924  then
925    # OpenBSD's libffi is not directly linked to the libpthread but
926    # still requires pthread functionality. This means that any client
927    # binary which links with libffi also needs to link with
928    # libpthread. If it does not, then linking fails with unresolved
929    # symbols.
930    LDFLAGS="$LDFLAGS -lpthread"
931  fi
932  AC_CHECK_LIB(ffi, ffi_call,
933   [AC_CHECK_HEADERS([ffi.h], [break], [])
934    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
935   [AC_MSG_ERROR([Cannot find system libffi])])
936  CFLAGS="$CFLAGS2"
937  LDFLAGS="$LDFLAGS2"
938 ])
939
940 dnl ** check whether we need -ldl to get dlopen()
941 AC_CHECK_LIB(dl, dlopen)
942
943 dnl --------------------------------------------------
944 dnl * Miscellaneous feature tests
945 dnl --------------------------------------------------
946
947 dnl ** can we get alloca?
948 AC_FUNC_ALLOCA
949
950 dnl ** working vfork?
951 AC_FUNC_FORK
952
953 dnl ** determine whether or not const works
954 AC_C_CONST
955
956 dnl ** are we big endian?
957 AC_C_BIGENDIAN
958 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
959
960 dnl ** check for leading underscores in symbol names
961 FP_LEADING_UNDERSCORE
962
963 FP_VISIBILITY_HIDDEN
964
965 dnl ** check for librt
966 AC_CHECK_LIB(rt, clock_gettime)
967 AC_CHECK_FUNCS(clock_gettime timer_settime)
968 FP_CHECK_TIMER_CREATE
969
970 dnl ** check for Apple's "interesting" long double compatibility scheme
971 AC_MSG_CHECKING(for printf\$LDBLStub)
972 AC_TRY_LINK_FUNC(printf\$LDBLStub,
973     [
974         AC_MSG_RESULT(yes)
975         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
976             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
977     ],
978     [
979         AC_MSG_RESULT(no)
980         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
981             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
982     ])
983
984 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
985 dnl    a different single-argument version.
986 AC_CHECK_LIB(pthread, pthread_setname_np)
987 AC_MSG_CHECKING(for pthread_setname_np)
988 AC_TRY_LINK(
989 [
990 #define _GNU_SOURCE
991 #include <pthread.h>
992 ],
993 [pthread_setname_np(pthread_self(), "name");],
994     AC_MSG_RESULT(yes)
995     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
996       [Define to 1 if you have the glibc version of pthread_setname_np]),
997     AC_MSG_RESULT(no)
998 )
999
1000 dnl ** check for eventfd which is needed by the I/O manager
1001 AC_CHECK_HEADERS([sys/eventfd.h])
1002 AC_CHECK_FUNCS([eventfd])
1003
1004 dnl ** Check for __thread support in the compiler
1005 AC_MSG_CHECKING(for __thread support)
1006 AC_COMPILE_IFELSE(
1007   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
1008   [
1009    AC_MSG_RESULT(yes)
1010    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1011   ],
1012   [
1013    AC_MSG_RESULT(no)
1014    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1015   ])
1016
1017
1018 AC_CHECK_FUNCS(__mingw_vfprintf)
1019
1020 dnl large address space support (see includes/rts/storage/MBlock.h)
1021 dnl
1022 dnl Darwin has vm_allocate/vm_protect
1023 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1024 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1025 dnl (They also have MADV_DONTNEED, but it means something else!)
1026 dnl
1027 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1028 dnl it counts page-table space as committed memory, and so quickly
1029 dnl runs out of paging file when we have multiple processes reserving
1030 dnl 1TB of address space, we get the following error:
1031 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1032 dnl
1033
1034 AC_ARG_ENABLE(large-address-space,
1035     [AC_HELP_STRING([--enable-large-address-space],
1036         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1037     EnableLargeAddressSpace=$enableval,
1038     EnableLargeAddressSpace=yes
1039 )
1040
1041 use_large_address_space=no
1042 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1043     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1044         if test "$ghc_host_os" = "darwin" ; then
1045             use_large_address_space=yes
1046         elif test "$ghc_host_os" = "openbsd" ; then
1047             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1048             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1049             # but is completely ignored by OS mmap
1050             use_large_address_space=no
1051         else
1052             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1053                 [
1054                 #include <unistd.h>
1055                 #include <sys/types.h>
1056                 #include <sys/mman.h>
1057                 #include <fcntl.h>
1058             ])
1059             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1060                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1061                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1062                     use_large_address_space=yes
1063             fi
1064         fi
1065     fi
1066 fi
1067 if test "$use_large_address_space" = "yes" ; then
1068    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1069 fi
1070
1071 AC_CHECK_LIB(dw, dwfl_begin, [HaveLibdw=YES], [HaveLibdw=NO])
1072 AC_SUBST(HaveLibdw)
1073
1074 if test -n "$SPHINXBUILD"; then
1075     BUILD_MAN=YES
1076     BUILD_SPHINX_HTML=YES
1077     if test -n "$XELATEX"; then
1078         BUILD_SPHINX_PDF=YES
1079     else
1080         BUILD_SPHINX_PDF=NO
1081     fi
1082 else
1083     BUILD_MAN=NO
1084     BUILD_SPHINX_HTML=NO
1085     BUILD_SPHINX_PDF=NO
1086 fi
1087 AC_SUBST(BUILD_MAN)
1088 AC_SUBST(BUILD_SPHINX_HTML)
1089 AC_SUBST(BUILD_SPHINX_PDF)
1090
1091 LIBRARY_VERSION(base)
1092 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1093 LIBRARY_VERSION(ghc-prim)
1094 LIBRARY_ghc_VERSION="$ProjectVersion"
1095 AC_SUBST(LIBRARY_ghc_VERSION)
1096
1097 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1098    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1099 fi
1100
1101 # Create the configuration for the Shake-based build system if it is present
1102 if test -e shake-build/cfg/system.config.in; then
1103     AC_CONFIG_FILES([shake-build/cfg/system.config])
1104 fi
1105
1106 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt distrib/configure.ac])
1107 AC_OUTPUT
1108
1109 # We got caught by
1110 #     http://savannah.gnu.org/bugs/index.php?1516
1111 #     $(eval ...) inside conditionals causes errors
1112 # with make 3.80, so warn the user if it looks like they're about to
1113 # try to use it.
1114 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1115 checkMake380() {
1116     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
1117     then
1118         echo
1119         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
1120         echo "This version cannot be used to build GHC."
1121         echo "Please use GNU make >= 3.81."
1122     fi
1123 }
1124
1125 checkMake380 make
1126 checkMake380 gmake
1127
1128 echo ["
1129 ----------------------------------------------------------------------
1130 Configure completed successfully.
1131
1132    Building GHC version  : $ProjectVersion
1133           Git commit id  : $ProjectGitCommitId
1134
1135    Build platform        : $BuildPlatform
1136    Host platform         : $HostPlatform
1137    Target platform       : $TargetPlatform
1138 "]
1139
1140 echo ["\
1141    Bootstrapping using   : $WithGhc
1142       which is version   : $GhcVersion
1143 "]
1144
1145 if test "x$CC_LLVM_BACKEND" = "x1"; then
1146     if test "x$CC_CLANG_BACKEND" = "x1"; then
1147         CompilerName="clang        "
1148     else
1149         CompilerName="llvm-gcc     "
1150     fi
1151 else
1152     CompilerName="gcc          "
1153 fi
1154
1155 echo ["\
1156    Using $CompilerName       : $WhatGccIsCalled
1157       which is version       : $GccVersion
1158    Building a cross compiler : $CrossCompiling
1159    hs-cpp       : $HaskellCPPCmd
1160    hs-cpp-flags : $HaskellCPPArgs
1161    ld           : $LdCmd
1162    nm           : $NmCmd
1163    objdump      : $ObjdumpCmd
1164    Happy        : $HappyCmd ($HappyVersion)
1165    Alex         : $AlexCmd ($AlexVersion)
1166    Perl         : $PerlCmd
1167    sphinx-build : $SPHINXBUILD
1168    xelatex      : $XELATEX
1169
1170    Using LLVM tools
1171       llc   : $LlcCmd
1172       opt   : $OptCmd"]
1173
1174 if test "$HSCOLOUR" = ""; then
1175 echo ["
1176    HsColour was not found; documentation will not contain source links
1177 "]
1178 else
1179 echo ["\
1180    HsColour : $HSCOLOUR
1181 "]
1182 fi
1183
1184 echo ["\
1185    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1186    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"]
1187
1188 echo ["----------------------------------------------------------------------
1189 "]
1190
1191 echo "\
1192 For a standard build of GHC (fully optimised with profiling), type (g)make.
1193
1194 To make changes to the default build configuration, copy the file
1195 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1196
1197 For more information on how to configure your GHC build, see
1198    http://ghc.haskell.org/trac/ghc/wiki/Building
1199 "