Remove an out-of-date comment
[ghc.git] / compiler / typecheck / TcRnDriver.lhs
1 %
2 % (c) The University of Glasgow 2006
3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
4 %
5 \section[TcModule]{Typechecking a whole module}
6
7 \begin{code}
8 module TcRnDriver (
9 #ifdef GHCI
10         tcRnStmt, tcRnExpr, tcRnType,
11         tcRnLookupRdrName,
12         tcRnLookupName,
13         tcRnGetInfo,
14         getModuleExports, 
15 #endif
16         tcRnModule, 
17         tcTopSrcDecls,
18         tcRnExtCore
19     ) where
20
21 #ifdef GHCI
22 import {-# SOURCE #-} TcSplice ( tcSpliceDecls )
23 #endif
24
25 import DynFlags
26 import StaticFlags
27 import HsSyn
28 import RdrHsSyn
29 import PrelNames
30 import RdrName
31 import TcHsSyn
32 import TcExpr
33 import TcRnMonad
34 import Coercion
35 import Inst
36 import FamInst
37 import InstEnv
38 import FamInstEnv
39 import TcAnnotations
40 import TcBinds
41 import TcDefaults
42 import TcEnv
43 import TcRules
44 import TcForeign
45 import TcInstDcls
46 import TcIface
47 import MkIface
48 import IfaceSyn
49 import TcSimplify
50 import TcTyClsDecls
51 import TcUnify  ( withBox )
52 import LoadIface
53 import RnNames
54 import RnEnv
55 import RnSource
56 import PprCore
57 import CoreSyn
58 import ErrUtils
59 import Id
60 import VarEnv
61 import Var
62 import Module
63 import LazyUniqFM
64 import Name
65 import NameEnv
66 import NameSet
67 import TyCon
68 import TysPrim
69 import SrcLoc
70 import HscTypes
71 import ListSetOps
72 import Outputable
73 import DataCon
74 import Type
75 import Class
76 import Data.List ( sortBy )
77
78 #ifdef GHCI
79 import TcHsType
80 import TcMType
81 import TcMatches
82 import RnTypes
83 import RnExpr
84 import IfaceEnv
85 import MkId
86 import BasicTypes
87 import TidyPgm    ( globaliseAndTidyId )
88 import TcType     ( isUnitTy, isTauTy, tyClsNamesOfDFunHead )
89 import TysWiredIn ( unitTy, mkListTy )
90 #endif
91
92 import FastString
93 import Maybes
94 import Util
95 import Bag
96
97 import Control.Monad
98
99 #include "HsVersions.h"
100 \end{code}
101
102 %************************************************************************
103 %*                                                                      *
104         Typecheck and rename a module
105 %*                                                                      *
106 %************************************************************************
107
108
109 \begin{code}
110 tcRnModule :: HscEnv 
111            -> HscSource
112            -> Bool              -- True <=> save renamed syntax
113            -> Located (HsModule RdrName)
114            -> IO (Messages, Maybe TcGblEnv)
115
116 tcRnModule hsc_env hsc_src save_rn_syntax
117          (L loc (HsModule maybe_mod export_ies 
118                           import_decls local_decls mod_deprec
119                           maybe_doc_hdr))
120  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
121
122    let { this_pkg = thisPackage (hsc_dflags hsc_env) ;
123          this_mod = case maybe_mod of
124                         Nothing  -> mAIN        -- 'module M where' is omitted
125                         Just (L _ mod) -> mkModule this_pkg mod } ;
126                                                 -- The normal case
127                 
128    initTc hsc_env hsc_src save_rn_syntax this_mod $ 
129    setSrcSpan loc $
130    do {         -- Deal with imports;
131         tcg_env <- tcRnImports hsc_env this_mod import_decls ;
132         setGblEnv tcg_env               $ do {
133
134                 -- Load the hi-boot interface for this module, if any
135                 -- We do this now so that the boot_names can be passed
136                 -- to tcTyAndClassDecls, because the boot_names are 
137                 -- automatically considered to be loop breakers
138                 --
139                 -- Do this *after* tcRnImports, so that we know whether
140                 -- a module that we import imports us; and hence whether to
141                 -- look for a hi-boot file
142         boot_iface <- tcHiBootIface hsc_src this_mod ;
143
144                 -- Rename and type check the declarations
145         traceRn (text "rn1a") ;
146         tcg_env <- if isHsBoot hsc_src then
147                         tcRnHsBootDecls local_decls
148                    else 
149                         tcRnSrcDecls boot_iface local_decls ;
150         setGblEnv tcg_env               $ do {
151
152                 -- Report the use of any deprecated things
153                 -- We do this *before* processsing the export list so
154                 -- that we don't bleat about re-exporting a deprecated
155                 -- thing (especially via 'module Foo' export item)
156                 -- That is, only uses in the *body* of the module are complained about
157         traceRn (text "rn3") ;
158         failIfErrsM ;   -- finishWarnings crashes sometimes 
159                         -- as a result of typechecker repairs (e.g. unboundNames)
160         tcg_env <- finishWarnings (hsc_dflags hsc_env) mod_deprec tcg_env ;
161
162                 -- Process the export list
163         traceRn (text "rn4a: before exports");
164         tcg_env <- rnExports (isJust maybe_mod) export_ies tcg_env ;
165         traceRn (text "rn4b: after exportss") ;
166
167                 -- Check that main is exported (must be after rnExports)
168         checkMainExported tcg_env ;
169
170         -- Compare the hi-boot iface (if any) with the real thing
171         -- Must be done after processing the exports
172         tcg_env <- checkHiBootIface tcg_env boot_iface ;
173
174         -- The new type env is already available to stuff slurped from 
175         -- interface files, via TcEnv.updateGlobalTypeEnv
176         -- It's important that this includes the stuff in checkHiBootIface, 
177         -- because the latter might add new bindings for boot_dfuns, 
178         -- which may be mentioned in imported unfoldings
179
180                 -- Don't need to rename the Haddock documentation,
181                 -- it's not parsed by GHC anymore.
182         tcg_env <- return (tcg_env { tcg_doc_hdr = maybe_doc_hdr }) ;
183
184                 -- Report unused names
185         reportUnusedNames export_ies tcg_env ;
186
187                 -- Dump output and return
188         tcDump tcg_env ;
189         return tcg_env
190     }}}}
191 \end{code}
192
193
194 %************************************************************************
195 %*                                                                      *
196                 Import declarations
197 %*                                                                      *
198 %************************************************************************
199
200 \begin{code}
201 tcRnImports :: HscEnv -> Module -> [LImportDecl RdrName] -> TcM TcGblEnv
202 tcRnImports hsc_env this_mod import_decls
203   = do  { (rn_imports, rdr_env, imports,hpc_info) <- rnImports import_decls ;
204
205         ; let { dep_mods :: ModuleNameEnv (ModuleName, IsBootInterface)
206               ; dep_mods = imp_dep_mods imports
207
208                 -- We want instance declarations from all home-package
209                 -- modules below this one, including boot modules, except
210                 -- ourselves.  The 'except ourselves' is so that we don't
211                 -- get the instances from this module's hs-boot file
212               ; want_instances :: ModuleName -> Bool
213               ; want_instances mod = mod `elemUFM` dep_mods
214                                    && mod /= moduleName this_mod
215               ; (home_insts, home_fam_insts) = hptInstances hsc_env 
216                                                             want_instances
217               } ;
218
219                 -- Record boot-file info in the EPS, so that it's 
220                 -- visible to loadHiBootInterface in tcRnSrcDecls,
221                 -- and any other incrementally-performed imports
222         ; updateEps_ (\eps -> eps { eps_is_boot = dep_mods }) ;
223
224                 -- Update the gbl env
225         ; updGblEnv ( \ gbl -> 
226             gbl { 
227               tcg_rdr_env      = plusOccEnv (tcg_rdr_env gbl) rdr_env,
228               tcg_imports      = tcg_imports gbl `plusImportAvails` imports,
229               tcg_rn_imports   = rn_imports,
230               tcg_inst_env     = extendInstEnvList (tcg_inst_env gbl) home_insts,
231               tcg_fam_inst_env = extendFamInstEnvList (tcg_fam_inst_env gbl) 
232                                                       home_fam_insts,
233               tcg_hpc          = hpc_info
234             }) $ do {
235
236         ; traceRn (text "rn1" <+> ppr (imp_dep_mods imports))
237                 -- Fail if there are any errors so far
238                 -- The error printing (if needed) takes advantage 
239                 -- of the tcg_env we have now set
240 --      ; traceIf (text "rdr_env: " <+> ppr rdr_env)
241         ; failIfErrsM
242
243                 -- Load any orphan-module and family instance-module
244                 -- interfaces, so that their rules and instance decls will be
245                 -- found.
246         ; loadOrphanModules (imp_orphs  imports) False
247         ; loadOrphanModules (imp_finsts imports) True 
248
249                 -- Check type-familily consistency
250         ; traceRn (text "rn1: checking family instance consistency")
251         ; let { dir_imp_mods = moduleEnvKeys
252                              . imp_mods 
253                              $ imports }
254         ; checkFamInstConsistency (imp_finsts imports) dir_imp_mods ;
255
256         ; getGblEnv } }
257 \end{code}
258
259
260 %************************************************************************
261 %*                                                                      *
262         Type-checking external-core modules
263 %*                                                                      *
264 %************************************************************************
265
266 \begin{code}
267 tcRnExtCore :: HscEnv 
268             -> HsExtCore RdrName
269             -> IO (Messages, Maybe ModGuts)
270         -- Nothing => some error occurred 
271
272 tcRnExtCore hsc_env (HsExtCore this_mod decls src_binds)
273         -- The decls are IfaceDecls; all names are original names
274  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
275
276    initTc hsc_env ExtCoreFile False this_mod $ do {
277
278    let { ldecls  = map noLoc decls } ;
279
280        -- bring the type and class decls into scope
281        -- ToDo: check that this doesn't need to extract the val binds.
282        --       It seems that only the type and class decls need to be in scope below because
283        --          (a) tcTyAndClassDecls doesn't need the val binds, and 
284        --          (b) tcExtCoreBindings doesn't need anything
285        --              (in fact, it might not even need to be in the scope of
286        --               this tcg_env at all)
287    avails  <- getLocalNonValBinders (mkFakeGroup ldecls) ;
288    tc_envs <- extendGlobalRdrEnvRn avails emptyFsEnv {- no fixity decls -} ;
289
290    setEnvs tc_envs $ do {
291
292    rn_decls <- checkNoErrs $ rnTyClDecls ldecls ;
293
294         -- Dump trace of renaming part
295    rnDump (ppr rn_decls) ;
296
297         -- Typecheck them all together so that
298         -- any mutually recursive types are done right
299         -- Just discard the auxiliary bindings; they are generated 
300         -- only for Haskell source code, and should already be in Core
301    (tcg_env, _aux_binds) <- tcTyAndClassDecls emptyModDetails rn_decls ;
302
303    setGblEnv tcg_env $ do {
304         -- Make the new type env available to stuff slurped from interface files
305    
306         -- Now the core bindings
307    core_binds <- initIfaceExtCore (tcExtCoreBindings src_binds) ;
308
309         -- Wrap up
310    let {
311         bndrs      = bindersOfBinds core_binds ;
312         my_exports = map (Avail . idName) bndrs ;
313                 -- ToDo: export the data types also?
314
315         final_type_env = 
316              extendTypeEnvWithIds (tcg_type_env tcg_env) bndrs ;
317
318         mod_guts = ModGuts {    mg_module    = this_mod,
319                                 mg_boot      = False,
320                                 mg_used_names = emptyNameSet, -- ToDo: compute usage
321                                 mg_dir_imps  = emptyModuleEnv, -- ??
322                                 mg_deps      = noDependencies,  -- ??
323                                 mg_exports   = my_exports,
324                                 mg_types     = final_type_env,
325                                 mg_insts     = tcg_insts tcg_env,
326                                 mg_fam_insts = tcg_fam_insts tcg_env,
327                                 mg_inst_env  = tcg_inst_env tcg_env,
328                                 mg_fam_inst_env = tcg_fam_inst_env tcg_env,
329                                 mg_rules     = [],
330                                 mg_anns      = [],
331                                 mg_binds     = core_binds,
332
333                                 -- Stubs
334                                 mg_rdr_env   = emptyGlobalRdrEnv,
335                                 mg_fix_env   = emptyFixityEnv,
336                                 mg_warns     = NoWarnings,
337                                 mg_foreign   = NoStubs,
338                                 mg_hpc_info  = emptyHpcInfo False,
339                                 mg_modBreaks = emptyModBreaks,
340                                 mg_vect_info = noVectInfo
341                     } } ;
342
343    tcCoreDump mod_guts ;
344
345    return mod_guts
346    }}}}
347
348 mkFakeGroup :: [LTyClDecl a] -> HsGroup a
349 mkFakeGroup decls -- Rather clumsy; lots of unused fields
350   = emptyRdrGroup { hs_tyclds = decls }
351 \end{code}
352
353
354 %************************************************************************
355 %*                                                                      *
356         Type-checking the top level of a module
357 %*                                                                      *
358 %************************************************************************
359
360 \begin{code}
361 tcRnSrcDecls :: ModDetails -> [LHsDecl RdrName] -> TcM TcGblEnv
362         -- Returns the variables free in the decls
363         -- Reason: solely to report unused imports and bindings
364 tcRnSrcDecls boot_iface decls
365  = do {         -- Do all the declarations
366         (tc_envs, lie) <- getLIE $ tc_rn_src_decls boot_iface decls ;
367
368              --         Finish simplifying class constraints
369              -- 
370              -- tcSimplifyTop deals with constant or ambiguous InstIds.  
371              -- How could there be ambiguous ones?  They can only arise if a
372              -- top-level decl falls under the monomorphism restriction
373              -- and no subsequent decl instantiates its type.
374              --
375              -- We do this after checkMain, so that we use the type info 
376              -- thaat checkMain adds
377              -- 
378              -- We do it with both global and local env in scope:
379              --  * the global env exposes the instances to tcSimplifyTop
380              --  * the local env exposes the local Ids to tcSimplifyTop, 
381              --    so that we get better error messages (monomorphism restriction)
382         traceTc (text "Tc8") ;
383         inst_binds <- setEnvs tc_envs (tcSimplifyTop lie) ;
384
385             -- Backsubstitution.  This must be done last.
386             -- Even tcSimplifyTop may do some unification.
387         traceTc (text "Tc9") ;
388         let { (tcg_env, _) = tc_envs
389             ; TcGblEnv { tcg_type_env = type_env,
390                          tcg_binds = binds,
391                          tcg_rules = rules,
392                          tcg_fords = fords } = tcg_env
393             ; all_binds = binds `unionBags` inst_binds } ;
394
395         failIfErrsM ;   -- Don't zonk if there have been errors
396                         -- It's a waste of time; and we may get debug warnings
397                         -- about strangely-typed TyCons!
398
399         (bind_ids, binds', fords', rules') <- zonkTopDecls all_binds rules fords ;
400
401         
402         let { final_type_env = extendTypeEnvWithIds type_env bind_ids
403             ; tcg_env' = tcg_env { tcg_binds = binds',
404                                    tcg_rules = rules', 
405                                    tcg_fords = fords' } } ;
406
407         setGlobalTypeEnv tcg_env' final_type_env                                   
408    }
409
410 tc_rn_src_decls :: ModDetails -> [LHsDecl RdrName] -> TcM (TcGblEnv, TcLclEnv)
411 -- Loops around dealing with each top level inter-splice group 
412 -- in turn, until it's dealt with the entire module
413 tc_rn_src_decls boot_details ds
414  = do { let { (first_group, group_tail) = findSplice ds } ;
415                 -- If ds is [] we get ([], Nothing)
416
417         -- Deal with decls up to, but not including, the first splice
418         (tcg_env, rn_decls) <- rnTopSrcDecls first_group ;
419                 -- rnTopSrcDecls fails if there are any errors
420
421         (tcg_env, tcl_env) <- setGblEnv tcg_env $ 
422                               tcTopSrcDecls boot_details rn_decls ;
423
424         -- If there is no splice, we're nearly done
425         setEnvs (tcg_env, tcl_env) $ 
426         case group_tail of {
427            Nothing -> do { tcg_env <- checkMain ;       -- Check for `main'
428                            return (tcg_env, tcl_env) 
429                       } ;
430
431 #ifndef GHCI
432         -- There shouldn't be a splice
433            Just (SpliceDecl {}, _) -> do {
434         failWithTc (text "Can't do a top-level splice; need a bootstrapped compiler")
435 #else
436         -- If there's a splice, we must carry on
437            Just (SpliceDecl splice_expr, rest_ds) -> do {
438
439         -- Rename the splice expression, and get its supporting decls
440         (rn_splice_expr, splice_fvs) <- checkNoErrs (rnLExpr splice_expr) ;
441                 -- checkNoErrs: don't typecheck if renaming failed
442         rnDump (ppr rn_splice_expr) ;
443
444         -- Execute the splice
445         spliced_decls <- tcSpliceDecls rn_splice_expr ;
446
447         -- Glue them on the front of the remaining decls and loop
448         setGblEnv (tcg_env `addTcgDUs` usesOnly splice_fvs) $
449         tc_rn_src_decls boot_details (spliced_decls ++ rest_ds)
450 #endif /* GHCI */
451     } } }
452 \end{code}
453
454 %************************************************************************
455 %*                                                                      *
456         Compiling hs-boot source files, and
457         comparing the hi-boot interface with the real thing
458 %*                                                                      *
459 %************************************************************************
460
461 \begin{code}
462 tcRnHsBootDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
463 tcRnHsBootDecls decls
464    = do { let { (first_group, group_tail) = findSplice decls }
465
466                 -- Rename the declarations
467         ; (tcg_env, HsGroup { 
468                    hs_tyclds = tycl_decls, 
469                    hs_instds = inst_decls,
470                    hs_derivds = deriv_decls,
471                    hs_fords  = for_decls,
472                    hs_defds  = def_decls,  
473                    hs_ruleds = rule_decls, 
474                    hs_annds  = _,
475                    hs_valds  = val_binds }) <- rnTopSrcDecls first_group
476         ; setGblEnv tcg_env $ do {
477
478
479                 -- Check for illegal declarations
480         ; case group_tail of
481              Just (SpliceDecl d, _) -> badBootDecl "splice" d
482              Nothing                -> return ()
483         ; mapM_ (badBootDecl "foreign") for_decls
484         ; mapM_ (badBootDecl "default") def_decls
485         ; mapM_ (badBootDecl "rule")    rule_decls
486
487                 -- Typecheck type/class decls
488         ; traceTc (text "Tc2")
489         ; (tcg_env, aux_binds) <- tcTyAndClassDecls emptyModDetails tycl_decls
490         ; setGblEnv tcg_env     $ do {
491
492                 -- Typecheck instance decls
493                 -- Family instance declarations are rejected here
494         ; traceTc (text "Tc3")
495         ; (tcg_env, inst_infos, _deriv_binds) 
496             <- tcInstDecls1 tycl_decls inst_decls deriv_decls
497         ; setGblEnv tcg_env     $ do {
498
499                 -- Typecheck value declarations
500         ; traceTc (text "Tc5") 
501         ; val_ids <- tcHsBootSigs val_binds
502
503                 -- Wrap up
504                 -- No simplification or zonking to do
505         ; traceTc (text "Tc7a")
506         ; gbl_env <- getGblEnv 
507         
508                 -- Make the final type-env
509                 -- Include the dfun_ids so that their type sigs
510                 -- are written into the interface file. 
511                 -- And similarly the aux_ids from aux_binds
512         ; let { type_env0 = tcg_type_env gbl_env
513               ; type_env1 = extendTypeEnvWithIds type_env0 val_ids
514               ; type_env2 = extendTypeEnvWithIds type_env1 dfun_ids 
515               ; type_env3 = extendTypeEnvWithIds type_env2 aux_ids 
516               ; dfun_ids = map iDFunId inst_infos
517               ; aux_ids  = case aux_binds of
518                              ValBindsOut _ sigs -> [id | L _ (IdSig id) <- sigs]
519                              _                  -> panic "tcRnHsBoodDecls"
520               }
521
522         ; setGlobalTypeEnv gbl_env type_env3
523    }}}}
524
525 badBootDecl :: String -> Located decl -> TcM ()
526 badBootDecl what (L loc _) 
527   = addErrAt loc (char 'A' <+> text what 
528       <+> ptext (sLit "declaration is not (currently) allowed in a hs-boot file"))
529 \end{code}
530
531 Once we've typechecked the body of the module, we want to compare what
532 we've found (gathered in a TypeEnv) with the hi-boot details (if any).
533
534 \begin{code}
535 checkHiBootIface :: TcGblEnv -> ModDetails -> TcM TcGblEnv
536 -- Compare the hi-boot file for this module (if there is one)
537 -- with the type environment we've just come up with
538 -- In the common case where there is no hi-boot file, the list
539 -- of boot_names is empty.
540 --
541 -- The bindings we return give bindings for the dfuns defined in the
542 -- hs-boot file, such as        $fbEqT = $fEqT
543
544 checkHiBootIface
545         tcg_env@(TcGblEnv { tcg_src = hs_src, tcg_binds = binds,
546                             tcg_insts = local_insts, 
547                             tcg_type_env = local_type_env, tcg_exports = local_exports })
548         (ModDetails { md_insts = boot_insts, md_fam_insts = boot_fam_insts,
549                       md_types = boot_type_env, md_exports = boot_exports })
550   | isHsBoot hs_src     -- Current module is already a hs-boot file!
551   = return tcg_env      
552
553   | otherwise
554   = do  { traceTc (text "checkHiBootIface" <+> (ppr boot_type_env $$ ppr boot_insts $$ 
555                                 ppr boot_exports)) ;
556
557                 -- Check the exports of the boot module, one by one
558         ; mapM_ check_export boot_exports
559
560                 -- Check for no family instances
561         ; unless (null boot_fam_insts) $
562             panic ("TcRnDriver.checkHiBootIface: Cannot handle family " ++
563                    "instances in boot files yet...")
564             -- FIXME: Why?  The actual comparison is not hard, but what would
565             --        be the equivalent to the dfun bindings returned for class
566             --        instances?  We can't easily equate tycons...
567
568                 -- Check instance declarations
569         ; mb_dfun_prs <- mapM check_inst boot_insts
570         ; let tcg_env' = tcg_env { tcg_binds    = binds `unionBags` dfun_binds,
571                                    tcg_type_env = extendTypeEnvWithIds local_type_env boot_dfuns }
572               dfun_prs   = catMaybes mb_dfun_prs
573               boot_dfuns = map fst dfun_prs
574               dfun_binds = listToBag [ mkVarBind boot_dfun (nlHsVar dfun)
575                                      | (boot_dfun, dfun) <- dfun_prs ]
576
577         ; failIfErrsM
578         ; return tcg_env' }
579   where
580     check_export boot_avail     -- boot_avail is exported by the boot iface
581       | name `elem` dfun_names = return ()      
582       | isWiredInName name     = return ()      -- No checking for wired-in names.  In particular,
583                                                 -- 'error' is handled by a rather gross hack
584                                                 -- (see comments in GHC.Err.hs-boot)
585
586         -- Check that the actual module exports the same thing
587       | not (null missing_names)
588       = addErrAt (nameSrcSpan (head missing_names)) 
589                  (missingBootThing (head missing_names) "exported by")
590
591         -- If the boot module does not *define* the thing, we are done
592         -- (it simply re-exports it, and names match, so nothing further to do)
593       | isNothing mb_boot_thing = return ()
594
595         -- Check that the actual module also defines the thing, and 
596         -- then compare the definitions
597       | Just real_thing <- lookupTypeEnv local_type_env name,
598         Just boot_thing <- mb_boot_thing
599       = when (not (checkBootDecl boot_thing real_thing))
600             $ addErrAt (nameSrcSpan (getName boot_thing))
601                        (let boot_decl = tyThingToIfaceDecl 
602                                                (fromJust mb_boot_thing)
603                             real_decl = tyThingToIfaceDecl real_thing
604                         in bootMisMatch real_thing boot_decl real_decl)
605
606       | otherwise
607       = addErrTc (missingBootThing name "defined in")
608       where
609         name          = availName boot_avail
610         mb_boot_thing = lookupTypeEnv boot_type_env name
611         missing_names = case lookupNameEnv local_export_env name of
612                           Nothing    -> [name]
613                           Just avail -> availNames boot_avail `minusList` availNames avail
614                  
615     dfun_names = map getName boot_insts
616
617     local_export_env :: NameEnv AvailInfo
618     local_export_env = availsToNameEnv local_exports
619
620     check_inst :: Instance -> TcM (Maybe (Id, Id))
621         -- Returns a pair of the boot dfun in terms of the equivalent real dfun
622     check_inst boot_inst
623         = case [dfun | inst <- local_insts, 
624                        let dfun = instanceDFunId inst,
625                        idType dfun `tcEqType` boot_inst_ty ] of
626             [] -> do { addErrTc (instMisMatch boot_inst); return Nothing }
627             (dfun:_) -> return (Just (local_boot_dfun, dfun))
628         where
629           boot_dfun = instanceDFunId boot_inst
630           boot_inst_ty = idType boot_dfun
631           local_boot_dfun = Id.mkExportedLocalId (idName boot_dfun) boot_inst_ty
632
633
634 -- This has to compare the TyThing from the .hi-boot file to the TyThing
635 -- in the current source file.  We must be careful to allow alpha-renaming
636 -- where appropriate, and also the boot declaration is allowed to omit
637 -- constructors and class methods.
638 --
639 -- See rnfail055 for a good test of this stuff.
640
641 checkBootDecl :: TyThing -> TyThing -> Bool
642
643 checkBootDecl (AnId id1) (AnId id2)
644   = ASSERT(id1 == id2) 
645     (idType id1 `tcEqType` idType id2)
646
647 checkBootDecl (ATyCon tc1) (ATyCon tc2)
648   = checkBootTyCon tc1 tc2
649
650 checkBootDecl (AClass c1)  (AClass c2)
651   = let 
652        (clas_tyvars1, clas_fds1, sc_theta1, _, ats1, op_stuff1) 
653           = classExtraBigSig c1
654        (clas_tyvars2, clas_fds2, sc_theta2, _, ats2, op_stuff2) 
655           = classExtraBigSig c2
656
657        env0 = mkRnEnv2 emptyInScopeSet
658        env = rnBndrs2 env0 clas_tyvars1 clas_tyvars2
659
660        eqSig (id1, def_meth1) (id2, def_meth2)
661          = idName id1 == idName id2 &&
662            tcEqTypeX env op_ty1 op_ty2 &&
663            def_meth1 == def_meth2
664          where
665           (_, rho_ty1) = splitForAllTys (idType id1)
666           op_ty1 = funResultTy rho_ty1
667           (_, rho_ty2) = splitForAllTys (idType id2)
668           op_ty2 = funResultTy rho_ty2
669
670        eqFD (as1,bs1) (as2,bs2) = 
671          eqListBy (tcEqTypeX env) (mkTyVarTys as1) (mkTyVarTys as2) &&
672          eqListBy (tcEqTypeX env) (mkTyVarTys bs1) (mkTyVarTys bs2)
673
674        same_kind tv1 tv2 = eqKind (tyVarKind tv1) (tyVarKind tv2)
675     in
676        eqListBy same_kind clas_tyvars1 clas_tyvars2 &&
677              -- Checks kind of class
678        eqListBy eqFD clas_fds1 clas_fds2 &&
679        (null sc_theta1 && null op_stuff1 && null ats1
680         ||   -- Above tests for an "abstract" class
681         eqListBy (tcEqPredX env) sc_theta1 sc_theta2 &&
682         eqListBy eqSig op_stuff1 op_stuff2 &&
683         eqListBy checkBootTyCon ats1 ats2)
684
685 checkBootDecl (ADataCon dc1) (ADataCon _)
686   = pprPanic "checkBootDecl" (ppr dc1)
687
688 checkBootDecl _ _ = False -- probably shouldn't happen
689
690 ----------------
691 checkBootTyCon :: TyCon -> TyCon -> Bool
692 checkBootTyCon tc1 tc2
693   | not (eqKind (tyConKind tc1) (tyConKind tc2))
694   = False       -- First off, check the kind
695
696   | isSynTyCon tc1 && isSynTyCon tc2
697   = ASSERT(tc1 == tc2)
698     let tvs1 = tyConTyVars tc1; tvs2 = tyConTyVars tc2
699         env = rnBndrs2 env0 tvs1 tvs2
700
701         eqSynRhs (OpenSynTyCon k1 _) (OpenSynTyCon k2 _)
702             = tcEqTypeX env k1 k2
703         eqSynRhs (SynonymTyCon t1) (SynonymTyCon t2)
704             = tcEqTypeX env t1 t2
705         eqSynRhs _ _ = False
706     in
707     equalLength tvs1 tvs2 &&
708     eqSynRhs (synTyConRhs tc1) (synTyConRhs tc2)
709
710   | isAlgTyCon tc1 && isAlgTyCon tc2
711   = ASSERT(tc1 == tc2)
712     eqKind (tyConKind tc1) (tyConKind tc2) &&
713     eqListBy tcEqPred (tyConStupidTheta tc1) (tyConStupidTheta tc2) &&
714     eqAlgRhs (algTyConRhs tc1) (algTyConRhs tc2)
715
716   | isForeignTyCon tc1 && isForeignTyCon tc2
717   = eqKind (tyConKind tc1) (tyConKind tc2) &&
718     tyConExtName tc1 == tyConExtName tc2
719
720   | otherwise = False
721   where 
722         env0 = mkRnEnv2 emptyInScopeSet
723
724         eqAlgRhs AbstractTyCon _ = True
725         eqAlgRhs OpenTyCon{} OpenTyCon{} = True
726         eqAlgRhs tc1@DataTyCon{} tc2@DataTyCon{} =
727             eqListBy eqCon (data_cons tc1) (data_cons tc2)
728         eqAlgRhs tc1@NewTyCon{} tc2@NewTyCon{} =
729             eqCon (data_con tc1) (data_con tc2)
730         eqAlgRhs _ _ = False
731
732         eqCon c1 c2
733           =  dataConName c1 == dataConName c2
734           && dataConIsInfix c1 == dataConIsInfix c2
735           && dataConStrictMarks c1 == dataConStrictMarks c2
736           && dataConFieldLabels c1 == dataConFieldLabels c2
737           && let tvs1 = dataConUnivTyVars c1 ++ dataConExTyVars c1
738                  tvs2 = dataConUnivTyVars c2 ++ dataConExTyVars c2
739                  env = rnBndrs2 env0 tvs1 tvs2
740              in
741               equalLength tvs1 tvs2 &&              
742               eqListBy (tcEqPredX env)
743                         (dataConEqTheta c1 ++ dataConDictTheta c1)
744                         (dataConEqTheta c2 ++ dataConDictTheta c2) &&
745               eqListBy (tcEqTypeX env)
746                         (dataConOrigArgTys c1)
747                         (dataConOrigArgTys c2)
748
749 ----------------
750 missingBootThing :: Name -> String -> SDoc
751 missingBootThing name what
752   = ppr name <+> ptext (sLit "is exported by the hs-boot file, but not") 
753               <+> text what <+> ptext (sLit "the module")
754
755 bootMisMatch :: TyThing -> IfaceDecl -> IfaceDecl -> SDoc
756 bootMisMatch thing boot_decl real_decl
757   = vcat [ppr thing <+> ptext (sLit "has conflicting definitions in the module and its hs-boot file"),
758           ptext (sLit "Main module:") <+> ppr real_decl,
759           ptext (sLit "Boot file:  ") <+> ppr boot_decl]
760
761 instMisMatch :: Instance -> SDoc
762 instMisMatch inst
763   = hang (ppr inst)
764        2 (ptext (sLit "is defined in the hs-boot file, but not in the module itself"))
765 \end{code}
766
767
768 %************************************************************************
769 %*                                                                      *
770         Type-checking the top level of a module
771 %*                                                                      *
772 %************************************************************************
773
774 tcRnGroup takes a bunch of top-level source-code declarations, and
775  * renames them
776  * gets supporting declarations from interface files
777  * typechecks them
778  * zonks them
779  * and augments the TcGblEnv with the results
780
781 In Template Haskell it may be called repeatedly for each group of
782 declarations.  It expects there to be an incoming TcGblEnv in the
783 monad; it augments it and returns the new TcGblEnv.
784
785 \begin{code}
786 ------------------------------------------------
787 rnTopSrcDecls :: HsGroup RdrName -> TcM (TcGblEnv, HsGroup Name)
788 -- Fails if there are any errors
789 rnTopSrcDecls group
790  = do { -- Rename the source decls
791         (tcg_env, rn_decls) <- checkNoErrs $ rnSrcDecls group ;
792
793         -- save the renamed syntax, if we want it
794         let { tcg_env'
795                 | Just grp <- tcg_rn_decls tcg_env
796                   = tcg_env{ tcg_rn_decls = Just (appendGroups grp rn_decls) }
797                 | otherwise
798                    = tcg_env };
799
800                 -- Dump trace of renaming part
801         rnDump (ppr rn_decls) ;
802
803         return (tcg_env', rn_decls)
804    }
805
806 ------------------------------------------------
807 tcTopSrcDecls :: ModDetails -> HsGroup Name -> TcM (TcGblEnv, TcLclEnv)
808 tcTopSrcDecls boot_details
809         (HsGroup { hs_tyclds = tycl_decls, 
810                    hs_instds = inst_decls,
811                    hs_derivds = deriv_decls,
812                    hs_fords  = foreign_decls,
813                    hs_defds  = default_decls,
814                    hs_annds  = annotation_decls,
815                    hs_ruleds = rule_decls,
816                    hs_valds  = val_binds })
817  = do {         -- Type-check the type and class decls, and all imported decls
818                 -- The latter come in via tycl_decls
819         traceTc (text "Tc2") ;
820
821         (tcg_env, aux_binds) <- tcTyAndClassDecls boot_details tycl_decls ;
822                 -- If there are any errors, tcTyAndClassDecls fails here
823         
824         setGblEnv tcg_env       $ do {
825                 -- Source-language instances, including derivings,
826                 -- and import the supporting declarations
827         traceTc (text "Tc3") ;
828         (tcg_env, inst_infos, deriv_binds) 
829             <- tcInstDecls1 tycl_decls inst_decls deriv_decls;
830         setGblEnv tcg_env       $ do {
831
832                 -- Foreign import declarations next. 
833         traceTc (text "Tc4") ;
834         (fi_ids, fi_decls) <- tcForeignImports foreign_decls ;
835         tcExtendGlobalValEnv fi_ids     $ do {
836
837                 -- Default declarations
838         traceTc (text "Tc4a") ;
839         default_tys <- tcDefaults default_decls ;
840         updGblEnv (\gbl -> gbl { tcg_default = default_tys }) $ do {
841         
842                 -- Now GHC-generated derived bindings, generics, and selectors
843                 -- Do not generate warnings from compiler-generated code;
844                 -- hence the use of discardWarnings
845         (tc_aux_binds,   tcl_env) <- discardWarnings (tcTopBinds aux_binds) ;
846         (tc_deriv_binds, tcl_env) <- setLclTypeEnv tcl_env $ 
847                                      discardWarnings (tcTopBinds deriv_binds) ;
848
849                 -- Value declarations next
850         traceTc (text "Tc5") ;
851         (tc_val_binds, tcl_env) <- setLclTypeEnv tcl_env $
852                                    tcTopBinds val_binds;
853
854                 -- Second pass over class and instance declarations, 
855         traceTc (text "Tc6") ;
856         (inst_binds, tcl_env) <- setLclTypeEnv tcl_env $ 
857                                  tcInstDecls2 tycl_decls inst_infos ;
858                                         showLIE (text "after instDecls2") ;
859
860         setLclTypeEnv tcl_env $ do {    -- Environment doesn't change now
861
862                 -- Foreign exports
863         traceTc (text "Tc7") ;
864         (foe_binds, foe_decls) <- tcForeignExports foreign_decls ;
865
866                 -- Annotations
867         annotations <- tcAnnotations annotation_decls ;
868
869                 -- Rules
870         rules <- tcRules rule_decls ;
871
872                 -- Wrap up
873         traceTc (text "Tc7a") ;
874         tcg_env <- getGblEnv ;
875         let { all_binds = tc_val_binds   `unionBags`
876                           tc_deriv_binds `unionBags`
877                           tc_aux_binds   `unionBags`
878                           inst_binds     `unionBags`
879                           foe_binds;
880
881                 -- Extend the GblEnv with the (as yet un-zonked) 
882                 -- bindings, rules, foreign decls
883               tcg_env' = tcg_env {  tcg_binds = tcg_binds tcg_env `unionBags` all_binds,
884                                     tcg_rules = tcg_rules tcg_env ++ rules,
885                                     tcg_anns  = tcg_anns tcg_env ++ annotations,
886                                     tcg_fords = tcg_fords tcg_env ++ foe_decls ++ fi_decls } } ;
887         return (tcg_env', tcl_env)
888     }}}}}}
889 \end{code}
890
891
892 %************************************************************************
893 %*                                                                      *
894         Checking for 'main'
895 %*                                                                      *
896 %************************************************************************
897
898 \begin{code}
899 checkMain :: TcM TcGblEnv
900 -- If we are in module Main, check that 'main' is defined.
901 checkMain 
902   = do { tcg_env   <- getGblEnv ;
903          dflags    <- getDOpts ;
904          check_main dflags tcg_env
905     }
906
907 check_main :: DynFlags -> TcGblEnv -> TcM TcGblEnv
908 check_main dflags tcg_env
909  | mod /= main_mod
910  = traceTc (text "checkMain not" <+> ppr main_mod <+> ppr mod) >>
911    return tcg_env
912
913  | otherwise
914  = do   { mb_main <- lookupGlobalOccRn_maybe main_fn
915                 -- Check that 'main' is in scope
916                 -- It might be imported from another module!
917         ; case mb_main of {
918              Nothing -> do { traceTc (text "checkMain fail" <+> ppr main_mod <+> ppr main_fn)
919                            ; complain_no_main   
920                            ; return tcg_env } ;
921              Just main_name -> do
922
923         { traceTc (text "checkMain found" <+> ppr main_mod <+> ppr main_fn)
924         ; let loc = srcLocSpan (getSrcLoc main_name)
925         ; ioTyCon <- tcLookupTyCon ioTyConName
926         ; (main_expr, res_ty) 
927                 <- addErrCtxt mainCtxt    $
928                    withBox liftedTypeKind $ \res_ty -> 
929                    tcMonoExpr (L loc (HsVar main_name)) (mkTyConApp ioTyCon [res_ty])
930
931                 -- See Note [Root-main Id]
932                 -- Construct the binding
933                 --      :Main.main :: IO res_ty = runMainIO res_ty main 
934         ; run_main_id <- tcLookupId runMainIOName
935         ; let { root_main_name =  mkExternalName rootMainKey rOOT_MAIN 
936                                    (mkVarOccFS (fsLit "main")) 
937                                    (getSrcSpan main_name)
938               ; root_main_id = Id.mkExportedLocalId root_main_name 
939                                                     (mkTyConApp ioTyCon [res_ty])
940               ; co  = mkWpTyApps [res_ty]
941               ; rhs = nlHsApp (mkLHsWrap co (nlHsVar run_main_id)) main_expr
942               ; main_bind = mkVarBind root_main_id rhs }
943
944         ; return (tcg_env { tcg_main  = Just main_name,
945                             tcg_binds = tcg_binds tcg_env
946                                         `snocBag` main_bind,
947                             tcg_dus   = tcg_dus tcg_env
948                                         `plusDU` usesOnly (unitFV main_name)
949                         -- Record the use of 'main', so that we don't 
950                         -- complain about it being defined but not used
951                  })
952     }}}
953   where
954     mod          = tcg_mod tcg_env
955     main_mod     = mainModIs dflags
956     main_fn      = getMainFun dflags
957
958     complain_no_main | ghcLink dflags == LinkInMemory = return ()
959                      | otherwise = failWithTc noMainMsg
960         -- In interactive mode, don't worry about the absence of 'main'
961         -- In other modes, fail altogether, so that we don't go on
962         -- and complain a second time when processing the export list.
963
964     mainCtxt  = ptext (sLit "When checking the type of the") <+> pp_main_fn
965     noMainMsg = ptext (sLit "The") <+> pp_main_fn
966                 <+> ptext (sLit "is not defined in module") <+> quotes (ppr main_mod)
967     pp_main_fn = ppMainFn main_fn
968
969 ppMainFn :: RdrName -> SDoc
970 ppMainFn main_fn
971   | main_fn == main_RDR_Unqual
972   = ptext (sLit "function") <+> quotes (ppr main_fn)
973   | otherwise
974   = ptext (sLit "main function") <+> quotes (ppr main_fn)
975                
976 -- | Get the unqualified name of the function to use as the \"main\" for the main module.
977 -- Either returns the default name or the one configured on the command line with -main-is
978 getMainFun :: DynFlags -> RdrName
979 getMainFun dflags = case (mainFunIs dflags) of
980     Just fn -> mkRdrUnqual (mkVarOccFS (mkFastString fn))
981     Nothing -> main_RDR_Unqual
982
983 checkMainExported :: TcGblEnv -> TcM ()
984 checkMainExported tcg_env = do
985   dflags    <- getDOpts
986   case tcg_main tcg_env of
987     Nothing -> return () -- not the main module
988     Just main_name -> do
989       let main_mod = mainModIs dflags
990       checkTc (main_name `elem` concatMap availNames (tcg_exports tcg_env)) $
991               ptext (sLit "The") <+> ppMainFn (nameRdrName main_name) <+>
992               ptext (sLit "is not exported by module") <+> quotes (ppr main_mod)
993 \end{code}
994
995 Note [Root-main Id]
996 ~~~~~~~~~~~~~~~~~~~
997 The function that the RTS invokes is always :Main.main, which we call
998 root_main_id.  (Because GHC allows the user to have a module not
999 called Main as the main module, we can't rely on the main function
1000 being called "Main.main".  That's why root_main_id has a fixed module
1001 ":Main".)  
1002
1003 This is unusual: it's a LocalId whose Name has a Module from another
1004 module.  Tiresomely, we must filter it out again in MkIface, les we
1005 get two defns for 'main' in the interface file!
1006
1007
1008 %*********************************************************
1009 %*                                                       *
1010                 GHCi stuff
1011 %*                                                       *
1012 %*********************************************************
1013
1014 \begin{code}
1015 #ifdef GHCI
1016 setInteractiveContext :: HscEnv -> InteractiveContext -> TcRn a -> TcRn a
1017 setInteractiveContext hsc_env icxt thing_inside 
1018   = let -- Initialise the tcg_inst_env with instances from all home modules.  
1019         -- This mimics the more selective call to hptInstances in tcRnModule.
1020         (home_insts, home_fam_insts) = hptInstances hsc_env (\_ -> True)
1021     in
1022     updGblEnv (\env -> env { 
1023         tcg_rdr_env      = ic_rn_gbl_env icxt,
1024         tcg_inst_env     = extendInstEnvList    (tcg_inst_env env) home_insts,
1025         tcg_fam_inst_env = extendFamInstEnvList (tcg_fam_inst_env env) 
1026                                                 home_fam_insts 
1027       }) $
1028
1029     tcExtendGhciEnv (ic_tmp_ids icxt) $
1030         -- tcExtendGhciEnv does lots: 
1031         --   - it extends the local type env (tcl_env) with the given Ids,
1032         --   - it extends the local rdr env (tcl_rdr) with the Names from 
1033         --     the given Ids
1034         --   - it adds the free tyvars of the Ids to the tcl_tyvars
1035         --     set.
1036         --
1037         -- later ids in ic_tmp_ids must shadow earlier ones with the same
1038         -- OccName, and tcExtendIdEnv implements this behaviour.
1039
1040     do  { traceTc (text "setIC" <+> ppr (ic_tmp_ids icxt))
1041         ; thing_inside }
1042 \end{code}
1043
1044
1045 \begin{code}
1046 tcRnStmt :: HscEnv
1047          -> InteractiveContext
1048          -> LStmt RdrName
1049          -> IO (Messages, Maybe ([Id], LHsExpr Id))
1050                 -- The returned [Id] is the list of new Ids bound by
1051                 -- this statement.  It can be used to extend the
1052                 -- InteractiveContext via extendInteractiveContext.
1053                 --
1054                 -- The returned TypecheckedHsExpr is of type IO [ () ],
1055                 -- a list of the bound values, coerced to ().
1056
1057 tcRnStmt hsc_env ictxt rdr_stmt
1058   = initTcPrintErrors hsc_env iNTERACTIVE $ 
1059     setInteractiveContext hsc_env ictxt $ do {
1060
1061     -- Rename; use CmdLineMode because tcRnStmt is only used interactively
1062     (([rn_stmt], _), fvs) <- rnStmts GhciStmt [rdr_stmt] (return ((), emptyFVs)) ;
1063     traceRn (text "tcRnStmt" <+> vcat [ppr rdr_stmt, ppr rn_stmt, ppr fvs]) ;
1064     failIfErrsM ;
1065     rnDump (ppr rn_stmt) ;
1066     
1067     -- The real work is done here
1068     (bound_ids, tc_expr) <- mkPlan rn_stmt ;
1069     zonked_expr <- zonkTopLExpr tc_expr ;
1070     zonked_ids  <- zonkTopBndrs bound_ids ;
1071     
1072         -- None of the Ids should be of unboxed type, because we
1073         -- cast them all to HValues in the end!
1074     mapM_ bad_unboxed (filter (isUnLiftedType . idType) zonked_ids) ;
1075
1076     traceTc (text "tcs 1") ;
1077     let { global_ids = map globaliseAndTidyId zonked_ids } ;
1078         -- Note [Interactively-bound Ids in GHCi]
1079
1080 {- ---------------------------------------------
1081    At one stage I removed any shadowed bindings from the type_env;
1082    they are inaccessible but might, I suppose, cause a space leak if we leave them there.
1083    However, with Template Haskell they aren't necessarily inaccessible.  Consider this
1084    GHCi session
1085          Prelude> let f n = n * 2 :: Int
1086          Prelude> fName <- runQ [| f |]
1087          Prelude> $(return $ AppE fName (LitE (IntegerL 7)))
1088          14
1089          Prelude> let f n = n * 3 :: Int
1090          Prelude> $(return $ AppE fName (LitE (IntegerL 7)))
1091    In the last line we use 'fName', which resolves to the *first* 'f'
1092    in scope. If we delete it from the type env, GHCi crashes because
1093    it doesn't expect that.
1094  
1095    Hence this code is commented out
1096
1097 -------------------------------------------------- -}
1098
1099     dumpOptTcRn Opt_D_dump_tc 
1100         (vcat [text "Bound Ids" <+> pprWithCommas ppr global_ids,
1101                text "Typechecked expr" <+> ppr zonked_expr]) ;
1102
1103     return (global_ids, zonked_expr)
1104     }
1105   where
1106     bad_unboxed id = addErr (sep [ptext (sLit "GHCi can't bind a variable of unlifted type:"),
1107                                   nest 2 (ppr id <+> dcolon <+> ppr (idType id))])
1108 \end{code}
1109
1110 Note [Interactively-bound Ids in GHCi]
1111 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1112 The Ids bound by previous Stmts in Template Haskell are currently
1113         a) GlobalIds
1114         b) with an Internal Name (not External)
1115         c) and a tidied type
1116
1117  (a) They must be GlobalIds (not LocalIds) otherwise when we come to
1118      compile an expression using these ids later, the byte code
1119      generator will consider the occurrences to be free rather than
1120      global.
1121
1122  (b) They retain their Internal names becuase we don't have a suitable
1123      Module to name them with.  We could revisit this choice.
1124
1125  (c) Their types are tidied.  This is important, because :info may ask
1126      to look at them, and :info expects the things it looks up to have
1127      tidy types
1128         
1129
1130 --------------------------------------------------------------------------
1131                 Typechecking Stmts in GHCi
1132
1133 Here is the grand plan, implemented in tcUserStmt
1134
1135         What you type                   The IO [HValue] that hscStmt returns
1136         -------------                   ------------------------------------
1137         let pat = expr          ==>     let pat = expr in return [coerce HVal x, coerce HVal y, ...]
1138                                         bindings: [x,y,...]
1139
1140         pat <- expr             ==>     expr >>= \ pat -> return [coerce HVal x, coerce HVal y, ...]
1141                                         bindings: [x,y,...]
1142
1143         expr (of IO type)       ==>     expr >>= \ it -> return [coerce HVal it]
1144           [NB: result not printed]      bindings: [it]
1145           
1146         expr (of non-IO type,   ==>     let it = expr in print it >> return [coerce HVal it]
1147           result showable)              bindings: [it]
1148
1149         expr (of non-IO type, 
1150           result not showable)  ==>     error
1151
1152
1153 \begin{code}
1154 ---------------------------
1155 type PlanResult = ([Id], LHsExpr Id)
1156 type Plan = TcM PlanResult
1157
1158 runPlans :: [Plan] -> TcM PlanResult
1159 -- Try the plans in order.  If one fails (by raising an exn), try the next.
1160 -- If one succeeds, take it.
1161 runPlans []     = panic "runPlans"
1162 runPlans [p]    = p
1163 runPlans (p:ps) = tryTcLIE_ (runPlans ps) p
1164
1165 --------------------
1166 mkPlan :: LStmt Name -> TcM PlanResult
1167 mkPlan (L loc (ExprStmt expr _ _))      -- An expression typed at the prompt 
1168   = do  { uniq <- newUnique             -- is treated very specially
1169         ; let fresh_it  = itName uniq
1170               the_bind  = L loc $ mkFunBind (L loc fresh_it) matches
1171               matches   = [mkMatch [] expr emptyLocalBinds]
1172               let_stmt  = L loc $ LetStmt (HsValBinds (ValBindsOut [(NonRecursive,unitBag the_bind)] []))
1173               bind_stmt = L loc $ BindStmt (nlVarPat fresh_it) expr
1174                                            (HsVar bindIOName) noSyntaxExpr 
1175               print_it  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar fresh_it))
1176                                            (HsVar thenIOName) placeHolderType
1177
1178         -- The plans are:
1179         --      [it <- e; print it]     but not if it::()
1180         --      [it <- e]               
1181         --      [let it = e; print it]  
1182         ; runPlans [    -- Plan A
1183                     do { stuff@([it_id], _) <- tcGhciStmts [bind_stmt, print_it]
1184                        ; it_ty <- zonkTcType (idType it_id)
1185                        ; when (isUnitTy it_ty) failM
1186                        ; return stuff },
1187
1188                         -- Plan B; a naked bind statment
1189                     tcGhciStmts [bind_stmt],    
1190
1191                         -- Plan C; check that the let-binding is typeable all by itself.
1192                         -- If not, fail; if so, try to print it.
1193                         -- The two-step process avoids getting two errors: one from
1194                         -- the expression itself, and one from the 'print it' part
1195                         -- This two-step story is very clunky, alas
1196                     do { _ <- checkNoErrs (tcGhciStmts [let_stmt]) 
1197                                 --- checkNoErrs defeats the error recovery of let-bindings
1198                        ; tcGhciStmts [let_stmt, print_it] }
1199           ]}
1200
1201 mkPlan stmt@(L loc (BindStmt {}))
1202   | [L _ v] <- collectLStmtBinders stmt         -- One binder, for a bind stmt 
1203   = do  { let print_v  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar v))
1204                                            (HsVar thenIOName) placeHolderType
1205
1206         ; print_bind_result <- doptM Opt_PrintBindResult
1207         ; let print_plan = do
1208                   { stuff@([v_id], _) <- tcGhciStmts [stmt, print_v]
1209                   ; v_ty <- zonkTcType (idType v_id)
1210                   ; when (isUnitTy v_ty || not (isTauTy v_ty)) failM
1211                   ; return stuff }
1212
1213         -- The plans are:
1214         --      [stmt; print v]         but not if v::()
1215         --      [stmt]
1216         ; runPlans ((if print_bind_result then [print_plan] else []) ++
1217                     [tcGhciStmts [stmt]])
1218         }
1219
1220 mkPlan stmt
1221   = tcGhciStmts [stmt]
1222
1223 ---------------------------
1224 tcGhciStmts :: [LStmt Name] -> TcM PlanResult
1225 tcGhciStmts stmts
1226  = do { ioTyCon <- tcLookupTyCon ioTyConName ;
1227         ret_id  <- tcLookupId returnIOName ;            -- return @ IO
1228         let {
1229             ret_ty    = mkListTy unitTy ;
1230             io_ret_ty = mkTyConApp ioTyCon [ret_ty] ;
1231             tc_io_stmts stmts = tcStmts GhciStmt tcDoStmt stmts io_ret_ty ;
1232
1233             names = map unLoc (collectLStmtsBinders stmts) ;
1234
1235                 -- mk_return builds the expression
1236                 --      returnIO @ [()] [coerce () x, ..,  coerce () z]
1237                 --
1238                 -- Despite the inconvenience of building the type applications etc,
1239                 -- this *has* to be done in type-annotated post-typecheck form
1240                 -- because we are going to return a list of *polymorphic* values
1241                 -- coerced to type (). If we built a *source* stmt
1242                 --      return [coerce x, ..., coerce z]
1243                 -- then the type checker would instantiate x..z, and we wouldn't
1244                 -- get their *polymorphic* values.  (And we'd get ambiguity errs
1245                 -- if they were overloaded, since they aren't applied to anything.)
1246             mk_return ids = nlHsApp (nlHsTyApp ret_id [ret_ty]) 
1247                                     (noLoc $ ExplicitList unitTy (map mk_item ids)) ;
1248             mk_item id = nlHsApp (nlHsTyApp unsafeCoerceId [idType id, unitTy])
1249                                  (nlHsVar id) 
1250          } ;
1251
1252         -- OK, we're ready to typecheck the stmts
1253         traceTc (text "TcRnDriver.tcGhciStmts: tc stmts") ;
1254         ((tc_stmts, ids), lie) <- getLIE $ tc_io_stmts stmts $ \ _ ->
1255                                            mapM tcLookupId names ;
1256                                         -- Look up the names right in the middle,
1257                                         -- where they will all be in scope
1258
1259         -- Simplify the context
1260         traceTc (text "TcRnDriver.tcGhciStmts: simplify ctxt") ;
1261         const_binds <- checkNoErrs (tcSimplifyInteractive lie) ;
1262                 -- checkNoErrs ensures that the plan fails if context redn fails
1263
1264         traceTc (text "TcRnDriver.tcGhciStmts: done") ;
1265         return (ids, mkHsDictLet const_binds $
1266                      noLoc (HsDo GhciStmt tc_stmts (mk_return ids) io_ret_ty))
1267     }
1268 \end{code}
1269
1270
1271 tcRnExpr just finds the type of an expression
1272
1273 \begin{code}
1274 tcRnExpr :: HscEnv
1275          -> InteractiveContext
1276          -> LHsExpr RdrName
1277          -> IO (Messages, Maybe Type)
1278 tcRnExpr hsc_env ictxt rdr_expr
1279   = initTcPrintErrors hsc_env iNTERACTIVE $ 
1280     setInteractiveContext hsc_env ictxt $ do {
1281
1282     (rn_expr, _fvs) <- rnLExpr rdr_expr ;
1283     failIfErrsM ;
1284
1285         -- Now typecheck the expression; 
1286         -- it might have a rank-2 type (e.g. :t runST)
1287     ((_tc_expr, res_ty), lie)        <- getLIE (tcInferRho rn_expr) ;
1288     ((qtvs, dict_insts, _), lie_top) <- getLIE (tcSimplifyInfer smpl_doc (tyVarsOfType res_ty) lie)  ;
1289     _ <- tcSimplifyInteractive lie_top ;       -- Ignore the dicionary bindings
1290
1291     let { all_expr_ty = mkForAllTys qtvs $
1292                         mkFunTys (map (idType . instToId) dict_insts)   $
1293                         res_ty } ;
1294     zonkTcType all_expr_ty
1295     }
1296   where
1297     smpl_doc = ptext (sLit "main expression")
1298 \end{code}
1299
1300 tcRnType just finds the kind of a type
1301
1302 \begin{code}
1303 tcRnType :: HscEnv
1304          -> InteractiveContext
1305          -> LHsType RdrName
1306          -> IO (Messages, Maybe Kind)
1307 tcRnType hsc_env ictxt rdr_type
1308   = initTcPrintErrors hsc_env iNTERACTIVE $ 
1309     setInteractiveContext hsc_env ictxt $ do {
1310
1311     rn_type <- rnLHsType doc rdr_type ;
1312     failIfErrsM ;
1313
1314         -- Now kind-check the type
1315     (_ty', kind) <- kcLHsType rn_type ;
1316     return kind
1317     }
1318   where
1319     doc = ptext (sLit "In GHCi input")
1320
1321 #endif /* GHCi */
1322 \end{code}
1323
1324
1325 %************************************************************************
1326 %*                                                                      *
1327         More GHCi stuff, to do with browsing and getting info
1328 %*                                                                      *
1329 %************************************************************************
1330
1331 \begin{code}
1332 #ifdef GHCI
1333 -- | ASSUMES that the module is either in the 'HomePackageTable' or is
1334 -- a package module with an interface on disk.  If neither of these is
1335 -- true, then the result will be an error indicating the interface
1336 -- could not be found.
1337 getModuleExports :: HscEnv -> Module -> IO (Messages, Maybe [AvailInfo])
1338 getModuleExports hsc_env mod
1339   = let
1340       ic        = hsc_IC hsc_env
1341       checkMods = ic_toplev_scope ic ++ ic_exports ic
1342     in
1343     initTc hsc_env HsSrcFile False iNTERACTIVE (tcGetModuleExports mod checkMods)
1344
1345 -- Get the export avail info and also load all orphan and family-instance
1346 -- modules.  Finally, check that the family instances of all modules in the
1347 -- interactive context are consistent (these modules are in the second
1348 -- argument).
1349 tcGetModuleExports :: Module -> [Module] -> TcM [AvailInfo]
1350 tcGetModuleExports mod directlyImpMods
1351   = do { let doc = ptext (sLit "context for compiling statements")
1352        ; iface <- initIfaceTcRn $ loadSysInterface doc mod
1353
1354                 -- Load any orphan-module and family instance-module
1355                 -- interfaces, so their instances are visible.
1356        ; loadOrphanModules (dep_orphs (mi_deps iface)) False 
1357        ; loadOrphanModules (dep_finsts (mi_deps iface)) True
1358
1359                 -- Check that the family instances of all directly loaded
1360                 -- modules are consistent.
1361        ; checkFamInstConsistency (dep_finsts (mi_deps iface)) directlyImpMods
1362
1363        ; ifaceExportNames (mi_exports iface)
1364        }
1365
1366 tcRnLookupRdrName :: HscEnv -> RdrName -> IO (Messages, Maybe [Name])
1367 tcRnLookupRdrName hsc_env rdr_name 
1368   = initTcPrintErrors hsc_env iNTERACTIVE $ 
1369     setInteractiveContext hsc_env (hsc_IC hsc_env) $ 
1370     lookup_rdr_name rdr_name
1371
1372 lookup_rdr_name :: RdrName -> TcM [Name]
1373 lookup_rdr_name rdr_name = do {
1374         -- If the identifier is a constructor (begins with an
1375         -- upper-case letter), then we need to consider both
1376         -- constructor and type class identifiers.
1377     let { rdr_names = dataTcOccs rdr_name } ;
1378
1379         -- results :: [Either Messages Name]
1380     results <- mapM (tryTcErrs . lookupOccRn) rdr_names ;
1381
1382     traceRn (text "xx" <+> vcat [ppr rdr_names, ppr (map snd results)]);
1383         -- The successful lookups will be (Just name)
1384     let { (warns_s, good_names) = unzip [ (msgs, name) 
1385                                         | (msgs, Just name) <- results] ;
1386           errs_s = [msgs | (msgs, Nothing) <- results] } ;
1387
1388         -- Fail if nothing good happened, else add warnings
1389     if null good_names then
1390                 -- No lookup succeeded, so
1391                 -- pick the first error message and report it
1392                 -- ToDo: If one of the errors is "could be Foo.X or Baz.X",
1393                 --       while the other is "X is not in scope", 
1394                 --       we definitely want the former; but we might pick the latter
1395         do { addMessages (head errs_s) ; failM }
1396       else                      -- Add deprecation warnings
1397         mapM_ addMessages warns_s ;
1398     
1399     return good_names
1400  }
1401
1402 tcRnLookupName :: HscEnv -> Name -> IO (Messages, Maybe TyThing)
1403 tcRnLookupName hsc_env name
1404   = initTcPrintErrors hsc_env iNTERACTIVE $ 
1405     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1406     tcRnLookupName' name
1407
1408 -- To look up a name we have to look in the local environment (tcl_lcl)
1409 -- as well as the global environment, which is what tcLookup does. 
1410 -- But we also want a TyThing, so we have to convert:
1411
1412 tcRnLookupName' :: Name -> TcRn TyThing
1413 tcRnLookupName' name = do
1414    tcthing <- tcLookup name
1415    case tcthing of
1416      AGlobal thing    -> return thing
1417      ATcId{tct_id=id} -> return (AnId id)
1418      _ -> panic "tcRnLookupName'"
1419
1420 tcRnGetInfo :: HscEnv
1421             -> Name
1422             -> IO (Messages, Maybe (TyThing, Fixity, [Instance]))
1423
1424 -- Used to implement :info in GHCi
1425 --
1426 -- Look up a RdrName and return all the TyThings it might be
1427 -- A capitalised RdrName is given to us in the DataName namespace,
1428 -- but we want to treat it as *both* a data constructor 
1429 --  *and* as a type or class constructor; 
1430 -- hence the call to dataTcOccs, and we return up to two results
1431 tcRnGetInfo hsc_env name
1432   = initTcPrintErrors hsc_env iNTERACTIVE $ 
1433     let ictxt = hsc_IC hsc_env in
1434     setInteractiveContext hsc_env ictxt $ do
1435
1436         -- Load the interface for all unqualified types and classes
1437         -- That way we will find all the instance declarations
1438         -- (Packages have not orphan modules, and we assume that
1439         --  in the home package all relevant modules are loaded.)
1440     loadUnqualIfaces ictxt
1441
1442     thing  <- tcRnLookupName' name
1443     fixity <- lookupFixityRn name
1444     ispecs <- lookupInsts thing
1445     return (thing, fixity, ispecs)
1446
1447 lookupInsts :: TyThing -> TcM [Instance]
1448 lookupInsts (AClass cls)
1449   = do  { inst_envs <- tcGetInstEnvs
1450         ; return (classInstances inst_envs cls) }
1451
1452 lookupInsts (ATyCon tc)
1453   = do  { (pkg_ie, home_ie) <- tcGetInstEnvs
1454                 -- Load all instances for all classes that are
1455                 -- in the type environment (which are all the ones
1456                 -- we've seen in any interface file so far)
1457         ; return [ ispec        -- Search all
1458                  | ispec <- instEnvElts home_ie ++ instEnvElts pkg_ie
1459                  , let dfun = instanceDFunId ispec
1460                  , relevant dfun ] } 
1461   where
1462     relevant df = tc_name `elemNameSet` tyClsNamesOfDFunHead (idType df)
1463     tc_name     = tyConName tc            
1464
1465 lookupInsts _ = return []
1466
1467 loadUnqualIfaces :: InteractiveContext -> TcM ()
1468 -- Load the home module for everything that is in scope unqualified
1469 -- This is so that we can accurately report the instances for 
1470 -- something
1471 loadUnqualIfaces ictxt
1472   = initIfaceTcRn $
1473     mapM_ (loadSysInterface doc) (moduleSetElts (mkModuleSet unqual_mods))
1474   where
1475     unqual_mods = [ nameModule name
1476                   | gre <- globalRdrEnvElts (ic_rn_gbl_env ictxt),
1477                     let name = gre_name gre,
1478                     not (isInternalName name),
1479                     isTcOcc (nameOccName name),  -- Types and classes only
1480                     unQualOK gre ]               -- In scope unqualified
1481     doc = ptext (sLit "Need interface for module whose export(s) are in scope unqualified")
1482 #endif /* GHCI */
1483 \end{code}
1484
1485 %************************************************************************
1486 %*                                                                      *
1487                 Degugging output
1488 %*                                                                      *
1489 %************************************************************************
1490
1491 \begin{code}
1492 rnDump :: SDoc -> TcRn ()
1493 -- Dump, with a banner, if -ddump-rn
1494 rnDump doc = do { dumpOptTcRn Opt_D_dump_rn (mkDumpDoc "Renamer" doc) }
1495
1496 tcDump :: TcGblEnv -> TcRn ()
1497 tcDump env
1498  = do { dflags <- getDOpts ;
1499
1500         -- Dump short output if -ddump-types or -ddump-tc
1501         when (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1502              (dumpTcRn short_dump) ;
1503
1504         -- Dump bindings if -ddump-tc
1505         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump)
1506    }
1507   where
1508     short_dump = pprTcGblEnv env
1509     full_dump  = pprLHsBinds (tcg_binds env)
1510         -- NB: foreign x-d's have undefined's in their types; 
1511         --     hence can't show the tc_fords
1512
1513 tcCoreDump :: ModGuts -> TcM ()
1514 tcCoreDump mod_guts
1515  = do { dflags <- getDOpts ;
1516         when (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1517              (dumpTcRn (pprModGuts mod_guts)) ;
1518
1519         -- Dump bindings if -ddump-tc
1520         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump) }
1521   where
1522     full_dump = pprCoreBindings (mg_binds mod_guts)
1523
1524 -- It's unpleasant having both pprModGuts and pprModDetails here
1525 pprTcGblEnv :: TcGblEnv -> SDoc
1526 pprTcGblEnv (TcGblEnv { tcg_type_env  = type_env, 
1527                         tcg_insts     = insts, 
1528                         tcg_fam_insts = fam_insts, 
1529                         tcg_rules     = rules,
1530                         tcg_imports   = imports })
1531   = vcat [ ppr_types insts type_env
1532          , ppr_tycons fam_insts type_env
1533          , ppr_insts insts
1534          , ppr_fam_insts fam_insts
1535          , vcat (map ppr rules)
1536          , ppr_gen_tycons (typeEnvTyCons type_env)
1537          , ptext (sLit "Dependent modules:") <+> 
1538                 ppr (sortBy cmp_mp $ eltsUFM (imp_dep_mods imports))
1539          , ptext (sLit "Dependent packages:") <+> 
1540                 ppr (sortBy stablePackageIdCmp $ imp_dep_pkgs imports)]
1541   where         -- The two uses of sortBy are just to reduce unnecessary
1542                 -- wobbling in testsuite output
1543     cmp_mp (mod_name1, is_boot1) (mod_name2, is_boot2)
1544         = (mod_name1 `stableModuleNameCmp` mod_name2)
1545                   `thenCmp`     
1546           (is_boot1 `compare` is_boot2)
1547
1548 pprModGuts :: ModGuts -> SDoc
1549 pprModGuts (ModGuts { mg_types = type_env,
1550                       mg_rules = rules })
1551   = vcat [ ppr_types [] type_env,
1552            ppr_rules rules ]
1553
1554 ppr_types :: [Instance] -> TypeEnv -> SDoc
1555 ppr_types insts type_env
1556   = text "TYPE SIGNATURES" $$ nest 4 (ppr_sigs ids)
1557   where
1558     dfun_ids = map instanceDFunId insts
1559     ids = [id | id <- typeEnvIds type_env, want_sig id]
1560     want_sig id | opt_PprStyle_Debug = True
1561                 | otherwise          = isLocalId id && 
1562                                        isExternalName (idName id) && 
1563                                        not (id `elem` dfun_ids)
1564         -- isLocalId ignores data constructors, records selectors etc.
1565         -- The isExternalName ignores local dictionary and method bindings
1566         -- that the type checker has invented.  Top-level user-defined things 
1567         -- have External names.
1568
1569 ppr_tycons :: [FamInst] -> TypeEnv -> SDoc
1570 ppr_tycons fam_insts type_env
1571   = text "TYPE CONSTRUCTORS" $$ nest 4 (ppr_tydecls tycons)
1572   where
1573     fi_tycons = map famInstTyCon fam_insts
1574     tycons = [tycon | tycon <- typeEnvTyCons type_env, want_tycon tycon]
1575     want_tycon tycon | opt_PprStyle_Debug = True
1576                      | otherwise          = not (isImplicitTyCon tycon) &&
1577                                             isExternalName (tyConName tycon) &&
1578                                             not (tycon `elem` fi_tycons)
1579
1580 ppr_insts :: [Instance] -> SDoc
1581 ppr_insts []     = empty
1582 ppr_insts ispecs = text "INSTANCES" $$ nest 2 (pprInstances ispecs)
1583
1584 ppr_fam_insts :: [FamInst] -> SDoc
1585 ppr_fam_insts []        = empty
1586 ppr_fam_insts fam_insts = 
1587   text "FAMILY INSTANCES" $$ nest 2 (pprFamInsts fam_insts)
1588
1589 ppr_sigs :: [Var] -> SDoc
1590 ppr_sigs ids
1591         -- Print type signatures; sort by OccName 
1592   = vcat (map ppr_sig (sortLe le_sig ids))
1593   where
1594     le_sig id1 id2 = getOccName id1 <= getOccName id2
1595     ppr_sig id = ppr id <+> dcolon <+> ppr (tidyTopType (idType id))
1596
1597 ppr_tydecls :: [TyCon] -> SDoc
1598 ppr_tydecls tycons
1599         -- Print type constructor info; sort by OccName 
1600   = vcat (map ppr_tycon (sortLe le_sig tycons))
1601   where
1602     le_sig tycon1 tycon2 = getOccName tycon1 <= getOccName tycon2
1603     ppr_tycon tycon 
1604       | isCoercionTyCon tycon 
1605       = sep [ptext (sLit "coercion") <+> ppr tycon <+> ppr tvs
1606             , nest 2 (dcolon <+> pprEqPred (coercionKind (mkTyConApp tycon (mkTyVarTys tvs))))]
1607       | otherwise             = ppr (tyThingToIfaceDecl (ATyCon tycon))
1608       where
1609         tvs = take (tyConArity tycon) alphaTyVars
1610
1611 ppr_rules :: [CoreRule] -> SDoc
1612 ppr_rules [] = empty
1613 ppr_rules rs = vcat [ptext (sLit "{-# RULES"),
1614                       nest 4 (pprRules rs),
1615                       ptext (sLit "#-}")]
1616
1617 ppr_gen_tycons :: [TyCon] -> SDoc
1618 ppr_gen_tycons []  = empty
1619 ppr_gen_tycons tcs = vcat [ptext (sLit "Tycons with generics:"),
1620                            nest 2 (fsep (map ppr (filter tyConHasGenerics tcs)))]
1621 \end{code}