Show valid substitutions for typed holes
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.3], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl this makes sure `./configure --target=<cross-compile-target>`
37 dnl works as expected, since we're slightly modifying how Autoconf
38 dnl interprets build/host/target and how this interacts with $CC tests
39 test -n "$target_alias" && ac_tool_prefix=$target_alias-
40
41 dnl ----------------------------------------------------------
42 dnl ** Find unixy sort and find commands,
43 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
44
45 dnl ** Find find command (for Win32's benefit)
46 FP_PROG_FIND
47 FP_PROG_SORT
48
49 dnl ----------------------------------------------------------
50 FP_SETUP_PROJECT_VERSION
51
52 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
53 AC_SUBST([release], [1])
54
55 # First off, a distrib sanity check..
56 AC_CONFIG_SRCDIR([mk/config.mk.in])
57
58 dnl * We require autoconf version 2.60
59 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
60 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
61 dnl Using autoconf 2.59 started to give nonsense like this
62 dnl  #define SIZEOF_CHAR 0
63 dnl recently.
64 AC_PREREQ([2.60])
65
66 # -------------------------------------------------------------------------
67 # Prepare to generate the following header files
68 #
69 #
70 AC_CONFIG_HEADER(mk/config.h)
71
72 # No, semi-sadly, we don't do `--srcdir'...
73 if test x"$srcdir" != 'x.' ; then
74     echo "This configuration does not support the \`--srcdir' option.."
75     exit 1
76 fi
77
78 dnl --------------------------------------------------------------
79 dnl * Project specific configuration options
80 dnl --------------------------------------------------------------
81 dnl What follows is a bunch of options that can either be configured
82 dnl through command line options to the configure script or by
83 dnl supplying defns in the build tree's mk/build.mk. Having the option to
84 dnl use either is considered a Feature.
85
86 dnl ** What command to use to compile compiler sources ?
87 dnl --------------------------------------------------------------
88
89 AC_ARG_WITH([ghc],
90 [AC_HELP_STRING([--with-ghc=ARG],
91   [Use ARG as the path to GHC  [default=autodetect]])],
92   [WithGhc="$withval"],
93   [if test "$GHC" = ""; then
94     AC_PATH_PROG([GHC], [ghc])
95   fi
96   WithGhc="$GHC"])
97
98 dnl ** Tell the make system which OS we are using
99 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
100 AC_SUBST(OSTYPE)
101
102 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
103 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
104                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
105         EnableBootstrapWithDevelSnaphost=YES,
106         EnableBootstrapWithDevelSnaphost=NO
107 )
108
109 AC_ARG_ENABLE(tarballs-autodownload,
110 [AC_HELP_STRING([--enable-tarballs-autodownload],
111                 [Automatically download Windows distribution binaries if needed.])],
112         TarballsAutodownload=YES,
113         TarballsAutodownload=NO
114 )
115
116 dnl CC_STAGE0 is like the "previous" variable CC (inherited by CC_STAGE[123])
117 dnl but instead used by stage0 for bootstrapping stage1
118 AC_ARG_VAR(CC_STAGE0, [C compiler command (bootstrap)])
119
120 if test "$WithGhc" != ""; then
121   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
122
123   if test "$GhcMajVersion" = "unknown" || test "$GhcMinVersion" = "unknown"; then
124      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
125   fi
126
127   AC_SUBST(GhcVersion)dnl
128   AC_SUBST(GhcMajVersion)dnl
129   AC_SUBST(GhcMinVersion)dnl
130   AC_SUBST(GhcPatchLevel)dnl
131   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
132   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
133
134   dnl infer CC_STAGE0 from `ghc --info` unless explicitly set by user
135   if test -z "$CC_STAGE0"; then
136     BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
137   fi
138
139   BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
140   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
141   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
142   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
143 fi
144
145 dnl ** Must have GHC to build GHC
146 if test "$WithGhc" = ""
147 then
148     AC_MSG_ERROR([GHC is required.])
149 fi
150 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.10],
151     [AC_MSG_ERROR([GHC version 7.10 or later is required to compile GHC.])])
152
153 if test `expr $GhcMinVersion % 2` = "1"
154 then
155     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
156     then
157         AC_MSG_ERROR([
158      $WithGhc is a development snapshot of GHC, version $GhcVersion.
159      Bootstrapping using this version of GHC is not supported, and may not
160      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
161      or --with-ghc to specify a different GHC to use.])
162     fi
163 fi
164
165 GHC_PACKAGE_DB_FLAG=package-db
166 AC_SUBST(GHC_PACKAGE_DB_FLAG)
167
168 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.11],
169                     SUPPORTS_THIS_UNIT_ID=NO,
170                     SUPPORTS_THIS_UNIT_ID=YES)
171 AC_SUBST(SUPPORTS_THIS_UNIT_ID)
172
173 # GHC is passed to Cabal, so we need a native path
174 if test "${WithGhc}" != ""
175 then
176     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
177
178     if test "$ghc_host_os" = "mingw32"
179     then
180         # Canonicalise to <drive>:/path/to/ghc
181         WithGhc=`cygpath -m "${WithGhc}"`
182
183         echo "GHC path canonicalised to: ${WithGhc}"
184     fi
185 fi
186 AC_SUBST([WithGhc])
187
188 dnl ** Without optimization some INLINE trickery fails for GHCi
189 SRC_CC_OPTS="-O"
190
191 dnl--------------------------------------------------------------------
192 dnl * Choose host(/target/build) platform
193 dnl--------------------------------------------------------------------
194 dnl If we aren't explicitly told what values to use with configure flags,
195 dnl we ask the bootstrapping compiler what platform it is for
196
197 if test "${WithGhc}" != ""
198 then
199         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
200         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
201         if test "$bootstrap_host" != "$bootstrap_target"
202         then
203                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
204         fi
205 fi
206
207 # We have to run these unconditionally, but we may discard their
208 # results in the following code
209 AC_CANONICAL_BUILD
210 AC_CANONICAL_HOST
211 AC_CANONICAL_TARGET
212
213 FPTOOLS_SET_PLATFORM_VARS
214
215 # Verify that the installed (bootstrap) GHC is capable of generating
216 # code for the requested build platform.
217 if test "$BuildPlatform" != "$bootstrap_target"
218 then
219     echo "This GHC (${WithGhc}) does not generate code for the build platform"
220     echo "   GHC target platform    : $bootstrap_target"
221     echo "   Desired build platform : $BuildPlatform"
222     exit 1
223 fi
224
225 # Testing if we shall enable shared libs support on Solaris.
226 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
227
228 SOLARIS_BROKEN_SHLD=NO
229
230 case $host in
231      i386-*-solaris2)
232      # here we go with the test
233      MINOR=`uname -r|cut -d '.' -f 2-`
234      if test "$MINOR" -lt "11"; then
235          SOLARIS_BROKEN_SHLD=YES
236      fi
237      ;;
238 esac
239
240 AC_SUBST(SOLARIS_BROKEN_SHLD)
241
242 dnl ** Do an unregisterised build?
243 dnl --------------------------------------------------------------
244 case "$HostArch" in
245     i386|x86_64|powerpc|powerpc64|powerpc64le|arm)
246         UnregisterisedDefault=NO
247         ;;
248     *)
249         UnregisterisedDefault=YES
250         ;;
251 esac
252 AC_ARG_ENABLE(unregisterised,
253 [AC_HELP_STRING([--enable-unregisterised],
254 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
255 [ if test x"$enableval" = x"yes"; then
256         Unregisterised=YES
257   else
258         Unregisterised=NO
259   fi
260 ],
261 [Unregisterised="$UnregisterisedDefault"]
262 )
263 AC_SUBST(Unregisterised)
264
265 dnl ** Does target have runtime linker support?
266 dnl --------------------------------------------------------------
267 case "$target" in
268     powerpc64-*|powerpc64le-*|powerpc-ibm-aix*)
269         HaskellHaveRTSLinker=NO
270         ;;
271     *)
272         HaskellHaveRTSLinker=YES
273         ;;
274 esac
275 AC_SUBST(HaskellHaveRTSLinker)
276
277 # Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
278 FP_FIND_ROOT
279
280 fail() {
281     echo >&2
282     echo "$1" >&2
283     exit 1
284 }
285
286
287 if test "$HostOS" = "mingw32"
288 then
289     # Find the mingw-w64 7z file to extract.
290     # NB. If you update the tarballs to a new version of gcc, don't
291     # forget to tweak the paths in driver/gcc/gcc.c.
292     if test "$HostArch" = "i386"
293     then
294         mingw_arch="i686"
295         tarball_dest_dir="mingw-w64/x86"
296         tarball_mingw_dir="mingw32"
297     else
298         mingw_arch="x86_64"
299         tarball_dest_dir="mingw-w64/x86_64"
300         tarball_mingw_dir="mingw64"
301     fi
302 fi
303
304 set_up_tarballs() {
305     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
306     local action
307     if test "$TarballsAutodownload" = "NO"
308     then
309         action="verify"
310     else
311         action="download"
312     fi
313     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
314     case $? in
315         0)
316            rm missing-win32-tarballs
317            ;;
318         2)
319            echo
320            echo "Error:"
321            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
322            echo
323            echo "  * run configure with the --enable-tarballs-autodownload option"
324            echo
325            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
326            echo
327            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
328            echo "    them in the ghc-tarballs directory."
329            echo
330            exit 1
331            ;;
332         *)
333            echo
334            echo "Error fetching msys2 tarballs; see errors above."
335            exit 1
336            ;;
337     esac
338
339     # Extract all the tarballs in one go
340     if ! test -d inplace/mingw
341     then
342         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
343         rm -rf inplace/mingw
344         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
345         ( cd inplace &&
346         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
347         rm ".MTREE" &&
348         rm ".PKGINFO" &&
349         cd .. ) || fail "Error: Could not extract Windows toolchains."
350
351         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
352         touch inplace/mingw
353
354         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
355         # make a wrapper around it to give it the proper paths
356         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
357         PATH=`pwd`/inplace/mingw/bin:$PATH
358         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
359
360         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
361     fi
362 }
363
364 if test "$HostOS" = "mingw32"
365 then
366     test -d inplace || mkdir inplace
367
368     # NB. Download and extract the MingW-w64 distribution if required
369     set_up_tarballs
370
371     mingwbin="$hardtop/inplace/mingw/bin/"
372     CC="${mingwbin}gcc.exe"
373     LD="${mingwbin}ld.exe"
374     NM="${mingwbin}nm.exe"
375     RANLIB="${mingwbin}ranlib.exe"
376     OBJDUMP="${mingwbin}objdump.exe"
377     Windres="${mingwbin}windres.exe"
378     DllWrap="${mingwbin}dllwrap.exe"
379     fp_prog_ar="${mingwbin}ar.exe"
380
381     # NB. Download the perl binaries if required
382     if ! test -d inplace/perl ||
383          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
384     then
385         AC_MSG_NOTICE([Making in-tree perl tree])
386         rm -rf inplace/perl
387         mkdir inplace/perl
388         (
389             cd inplace/perl &&
390             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
391         )
392         AC_MSG_NOTICE([In-tree perl tree created])
393     fi
394 fi
395
396 FP_ICONV
397 FP_GMP
398 FP_CURSES
399
400 XCODE_VERSION()
401
402
403 dnl ** Building a cross compiler?
404 dnl --------------------------------------------------------------
405 CrossCompiling=NO
406 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
407 if test "$TargetPlatform" != "$HostPlatform" ; then
408     CrossCompiling=YES
409     cross_compiling=yes   # This tells configure that it can accept just 'target',
410                           # otherwise you get
411                           #   configure: error: cannot run C compiled programs.
412                           #   If you meant to cross compile, use `--host'.
413 fi
414 if test "$BuildPlatform" != "$HostPlatform" ; then
415    AC_MSG_ERROR([
416 You've selected:
417
418   BUILD:  $BuildPlatform   (the architecture we're building on)
419   HOST:   $HostPlatform    (the architecture the compiler we're building will execute on)
420   TARGET: $TargetPlatform  (the architecture the compiler we're building will produce code for)
421
422 BUILD must equal HOST; that is, we do not support building GHC itself
423 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
424 1 will be a cross-compiler, and stage 2 will be the cross-compiled
425 GHC.
426 ])
427 fi
428 if test "$CrossCompiling" = "YES"
429 then
430   CrossCompilePrefix="${target}-"
431 else
432   CrossCompilePrefix=""
433 fi
434 # Despite its similarity in name to TargetPlatform, TargetPlatformFull is used
435 # in calls to subproject configure scripts and thus must be set to the autoconf
436 # triple, not the normalized GHC triple that TargetPlatform is set to.
437 #
438 # We use the non-canonicalized triple, target_alias, here since the subproject
439 # configure scripts will use this triple to construct the names of the toolchain
440 # executables. If we instead passed down the triple produced by
441 # AC_CANONICAL_TARGET then it may look for the target toolchain under the wrong
442 # name (this is a known problem in the case of the Android NDK, which has
443 # slightly odd triples).
444 #
445 # It may be better to just do away with the GHC triples altogether. This would
446 # all be taken care of for us if we configured the subprojects using
447 # AC_CONFIG_DIR, but unfortunately Cabal needs to be the one to do the
448 # configuration.
449 if test -z "${target_alias}"
450 then
451   # --target wasn't given; use result from AC_CANONICAL_TARGET
452   TargetPlatformFull="${target}"
453 else
454   TargetPlatformFull="${target_alias}"
455 fi
456 AC_SUBST(CrossCompiling)
457 AC_SUBST(CrossCompilePrefix)
458 AC_SUBST(TargetPlatformFull)
459
460 dnl ** Which gcc to use?
461 dnl --------------------------------------------------------------
462
463 AC_ARG_WITH([gcc],
464         AS_HELP_STRING([--with-gcc=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
465         AC_MSG_ERROR([--with-gcc=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
466
467 AC_ARG_WITH([clang],
468         AS_HELP_STRING([--with-clang=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
469         AC_MSG_ERROR([--with-clang=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
470
471 dnl detect compiler (prefer gcc over clang) and set $CC (unless CC already set),
472 dnl later CC is copied to CC_STAGE{1,2,3}
473 AC_PROG_CC([gcc clang])
474
475 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
476
477 dnl make extensions visible to allow feature-tests to detect them lateron
478 AC_USE_SYSTEM_EXTENSIONS
479
480 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
481 AC_PROG_CPP
482
483 # --with-hs-cpp/--with-hs-cpp-flags
484 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
485 AC_SUBST([HaskellCPPCmd])
486 AC_SUBST([HaskellCPPArgs])
487
488 FP_SET_CFLAGS_C99([CC],[CFLAGS],[CPPFLAGS])
489 FP_SET_CFLAGS_C99([CC_STAGE0],[CONF_CC_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
490 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
491 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
492
493 dnl ** Which ld to use?
494 dnl --------------------------------------------------------------
495 FIND_LD([LdCmd])
496 AC_SUBST([LdCmd])
497
498 dnl ** Which nm to use?
499 dnl --------------------------------------------------------------
500 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
501
502 if test "$TargetOS_CPP" = "darwin"
503 then
504     AC_MSG_CHECKING(whether nm program is broken)
505     # Some versions of XCode ship a broken version of `nm`. Detect and work
506     # around this issue. See : https://ghc.haskell.org/trac/ghc/ticket/11744
507     nmver=$(${NM} --version | grep version | sed 's/ //g')
508     case "$nmver" in
509         LLVMversion7.3.0|LLVMversion7.3.1)
510             AC_MSG_RESULT(yes)
511             echo "The detected nm program is broken."
512             echo
513             echo "See: https://ghc.haskell.org/trac/ghc/ticket/11744"
514             echo
515             echo "Try re-running configure with:"
516             echo
517             echo '   ./configure --with-nm=$(xcrun --find nm-classic)'
518             echo
519             exit 1
520             ;;
521         *)
522             AC_MSG_RESULT(no)
523             ;;
524         esac
525 fi
526
527 NmCmd="$NM"
528 AC_SUBST([NmCmd])
529
530 dnl ** Which objdump to use?
531 dnl --------------------------------------------------------------
532 FP_ARG_WITH_PATH_GNU_PROG_OPTIONAL([OBJDUMP], [objdump], [objdump])
533 ObjdumpCmd="$OBJDUMP"
534 AC_SUBST([ObjdumpCmd])
535
536 dnl ** Which ar to use?
537 dnl --------------------------------------------------------------
538 FP_ARG_WITH_PATH_GNU_PROG([AR], [ar], [ar])
539 ArCmd="$AR"
540 fp_prog_ar="$AR"
541 AC_SUBST([ArCmd])
542
543 dnl ** Which ranlib to use?
544 dnl --------------------------------------------------------------
545 FP_ARG_WITH_PATH_GNU_PROG([RANLIB], [ranlib], [ranlib])
546 RanlibCmd="$RANLIB"
547 RANLIB="$RanlibCmd"
548
549
550 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
551 case $HostOS_CPP in
552 cygwin32|mingw32)
553     dnl ** Which objdump to use?
554     dnl --------------------------------------------------------------
555     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
556     ObjdumpCmd="$OBJDUMP"
557     AC_SUBST([ObjdumpCmd])
558     ;;
559 esac
560
561 # Here is where we re-target which specific version of the LLVM
562 # tools we are looking for. In the past, GHC supported a number of
563 # versions of LLVM simultaneously, but that stopped working around
564 # 3.5/3.6 release of LLVM.
565 LlvmVersion=3.9
566 AC_SUBST([LlvmVersion])
567 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
568 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
569
570 dnl ** Which LLVM llc to use?
571 dnl --------------------------------------------------------------
572 FIND_LLVM_PROG([LLC], [llc], [llc], [$LlvmVersion])
573 LlcCmd="$LLC"
574 AC_SUBST([LlcCmd])
575
576 dnl ** Which LLVM opt to use?
577 dnl --------------------------------------------------------------
578 FIND_LLVM_PROG([OPT], [opt], [opt], [$LlvmVersion])
579 OptCmd="$OPT"
580 AC_SUBST([OptCmd])
581
582 dnl --------------------------------------------------------------
583 dnl End of configure script option section
584 dnl --------------------------------------------------------------
585
586
587 dnl --------------------------------------------------------------
588 dnl ** Can the unix package be built?
589 dnl --------------------------------------------------------------
590
591 if test "$TargetOS" = "mingw32"
592 then
593     GhcLibsWithUnix=NO
594 else
595     GhcLibsWithUnix=YES
596 fi
597 AC_SUBST([GhcLibsWithUnix])
598
599 dnl ** does #! work?
600 AC_SYS_INTERPRETER()
601
602 # Check for split-objs
603 SplitObjsBroken=NO
604 dnl ** look for `perl'
605 case $HostOS_CPP in
606 cygwin32|mingw32)
607   PerlCmd=$hardtop/inplace/perl/perl
608   ;;
609 *)
610     AC_PATH_PROG([PerlCmd],[perl])
611     if test -z "$PerlCmd"
612     then
613         AC_MSG_WARN([No Perl on PATH, disabling split object support])
614         SplitObjsBroken=YES
615     else
616         FPTOOLS_CHECK_PERL_VERSION
617     fi
618     ;;
619 esac
620 AC_SUBST([SplitObjsBroken])
621
622 dnl ** look for GCC and find out which version
623 dnl     Figure out which C compiler to use.  Gcc is preferred.
624 dnl     If gcc, make sure it's at least 3.0
625 dnl
626 FP_GCC_VERSION
627
628 dnl ** See whether gcc supports -no-pie
629 FP_GCC_SUPPORTS_NO_PIE
630
631 dnl ** look to see if we have a C compiler using an llvm back end.
632 dnl
633 FP_CC_LLVM_BACKEND
634
635 FP_PROG_LD_IS_GNU
636 FP_PROG_LD_BUILD_ID
637 FP_PROG_LD_NO_COMPACT_UNWIND
638 FP_PROG_LD_FILELIST
639
640
641 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
642 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
643 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
644 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
645 # Stage 3 won't be supported by cross-compilation
646
647 FP_GCC_EXTRA_FLAGS
648
649 # See rules/distdir-way-opts.mk for details.
650 # Flags passed to the C compiler
651 AC_SUBST(CONF_CC_OPTS_STAGE0)
652 AC_SUBST(CONF_CC_OPTS_STAGE1)
653 AC_SUBST(CONF_CC_OPTS_STAGE2)
654 # Flags passed to the C compiler when we ask it to link
655 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
656 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
657 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
658 # Flags passed to the linker when we ask it to link
659 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
660 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
661 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
662 # Flags passed to the C preprocessor
663 AC_SUBST(CONF_CPP_OPTS_STAGE0)
664 AC_SUBST(CONF_CPP_OPTS_STAGE1)
665 AC_SUBST(CONF_CPP_OPTS_STAGE2)
666 # Flags passed to the Haskell compiler
667 AC_SUBST(CONF_HC_OPTS_STAGE0)
668 AC_SUBST(CONF_HC_OPTS_STAGE1)
669 AC_SUBST(CONF_HC_OPTS_STAGE2)
670
671 dnl ** Set up the variables for the platform in the settings file.
672 dnl May need to use gcc to find platform details.
673 dnl --------------------------------------------------------------
674 FPTOOLS_SET_HASKELL_PLATFORM_VARS
675
676 dnl ** figure out how to do context diffs
677 FP_PROG_CONTEXT_DIFF
678
679 dnl Let's make sure install-sh is executable here.  If we got it from
680 dnl a darcs repo, it might not be (see bug #978).
681 chmod +x install-sh
682 dnl ** figure out how to do a BSD-ish install
683 AC_PROG_INSTALL
684
685 dnl ** how to invoke `ar' and `ranlib'
686 FP_PROG_AR_SUPPORTS_ATFILE
687 FP_PROG_AR_NEEDS_RANLIB
688
689 dnl ** Check to see whether ln -s works
690 AC_PROG_LN_S
691
692 FP_SETTINGS
693
694 dnl ** Find the path to sed
695 AC_PATH_PROGS(SedCmd,gsed sed,sed)
696
697
698 dnl ** check for time command
699 AC_PATH_PROG(TimeCmd,time)
700
701 dnl ** check for tar
702 dnl   if GNU tar is named gtar, look for it first.
703 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
704
705 dnl ** check for compressors
706 AC_PATH_PROGS(Bzip2Cmd,bzip2, bzip2)
707 AC_PATH_PROGS(GzipCmd,gzip, gzip)
708 AC_PATH_PROGS(XzCmd,pxz xz, xz)
709
710 dnl ** check for patch
711 dnl if GNU patch is named gpatch, look for it first
712 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
713
714 dnl ** check for dtrace (currently only implemented for Mac OS X)
715 HaveDtrace=NO
716 AC_PATH_PROG(DtraceCmd,dtrace)
717 if test -n "$DtraceCmd"; then
718   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
719     HaveDtrace=YES
720   fi
721 fi
722 AC_SUBST(HaveDtrace)
723
724 AC_PATH_PROG(HSCOLOUR,HsColour)
725 # HsColour is passed to Cabal, so we need a native path
726 if test "$HostOS"      = "mingw32" && \
727    test "${HSCOLOUR}" != ""
728 then
729     # Canonicalise to <drive>:/path/to/gcc
730     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
731 fi
732
733 dnl ** check for Sphinx toolchain
734 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
735 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
736 changequote(, )dnl
737 [if test -n "$SPHINXBUILD"; then
738   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
739 fi;
740 changequote([, ])dnl
741 ])
742 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
743     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
744
745 dnl ** check for xelatex
746 AC_PATH_PROG(XELATEX,xelatex)
747
748 dnl ** check for ghc-pkg command
749 FP_PROG_GHC_PKG
750
751 dnl ** check for installed happy binary + version
752 FPTOOLS_HAPPY
753
754 dnl ** check for installed alex binary + version
755 FPTOOLS_ALEX
756
757 dnl --------------------------------------------------
758 dnl ### program checking section ends here ###
759 dnl --------------------------------------------------
760
761 dnl --------------------------------------------------
762 dnl * Platform header file and syscall feature tests
763 dnl ### checking the state of the local header files and syscalls ###
764
765 dnl ** check for full ANSI header (.h) files
766 AC_HEADER_STDC
767
768 dnl ** Enable large file support.  NB. do this before testing the type of
769 dnl    off_t, because it will affect the result of that test.
770 AC_SYS_LARGEFILE
771
772 dnl ** check for specific header (.h) files that we are interested in
773 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
774
775 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
776 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
777 [[#if HAVE_SYS_PARAM_H
778 # include <sys/param.h>
779 #endif
780 ]])
781
782 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
783 AC_HEADER_TIME
784
785 dnl ** do we have long longs?
786 AC_CHECK_TYPES([long long])
787
788 dnl ** what are the sizes of various types
789 FP_CHECK_SIZEOF_AND_ALIGNMENT(char)
790 FP_CHECK_SIZEOF_AND_ALIGNMENT(double)
791 FP_CHECK_SIZEOF_AND_ALIGNMENT(float)
792 FP_CHECK_SIZEOF_AND_ALIGNMENT(int)
793 FP_CHECK_SIZEOF_AND_ALIGNMENT(long)
794 if test "$ac_cv_type_long_long" = yes; then
795 FP_CHECK_SIZEOF_AND_ALIGNMENT(long long)
796 fi
797 FP_CHECK_SIZEOF_AND_ALIGNMENT(short)
798 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned char)
799 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned int)
800 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long)
801 if test "$ac_cv_type_long_long" = yes; then
802 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long long)
803 fi
804 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned short)
805 FP_CHECK_SIZEOF_AND_ALIGNMENT(void *)
806
807 FP_CHECK_SIZEOF_AND_ALIGNMENT(int8_t)
808 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint8_t)
809 FP_CHECK_SIZEOF_AND_ALIGNMENT(int16_t)
810 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint16_t)
811 FP_CHECK_SIZEOF_AND_ALIGNMENT(int32_t)
812 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint32_t)
813 FP_CHECK_SIZEOF_AND_ALIGNMENT(int64_t)
814 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint64_t)
815
816
817 dnl for use in settings.in
818 WordSize=$ac_cv_sizeof_void_p
819 AC_SUBST(WordSize)
820 FP_CHECK_FUNC([WinExec],
821   [@%:@include <windows.h>], [WinExec("",0)])
822
823 FP_CHECK_FUNC([GetModuleFileName],
824   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
825
826 dnl ** check for more functions
827 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
828 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
829
830 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
831 dnl ** _POSIX_C_SOURCE is defined
832 AC_CHECK_DECLS([ctime_r], , ,
833 [#define _POSIX_SOURCE 1
834 #define _POSIX_C_SOURCE 199506L
835 #include <time.h>])
836
837 dnl ** check for mingwex library
838 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
839 AC_SUBST(HaveLibMingwEx)
840
841 if test $HaveLibMingwEx = YES ; then
842   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
843 fi
844
845 dnl ** check for math library
846 dnl    Keep that check as early as possible.
847 dnl    as we need to know whether we need libm
848 dnl    for math functions or not
849 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
850 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
851 if test $HaveLibM = YES
852 then
853   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
854 fi
855
856 FP_BFD_SUPPORT
857
858 dnl ################################################################
859 dnl Check for libraries
860 dnl ################################################################
861
862 # system libffi
863
864 AC_ARG_WITH([system-libffi],
865 [AC_HELP_STRING([--with-system-libffi],
866   [Use system provided libffi for RTS [default=no]])
867 ])
868
869 AS_IF([test "x$with_system_libffi" = "xyes"],
870   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
871 )
872
873
874 AC_SUBST(UseSystemLibFFI)
875
876 AC_ARG_WITH([ffi-includes],
877 [AC_HELP_STRING([--with-ffi-includes=ARG],
878   [Find includes for libffi in ARG [default=system default]])
879 ],
880 [
881  if test "x$UseSystemLibFFI" != "xYES"; then
882     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
883  else
884     FFIIncludeDir="$withval"
885     LIBFFI_CFLAGS="-I$withval"
886  fi
887 ])
888
889 AC_SUBST(FFIIncludeDir)
890
891 AC_ARG_WITH([ffi-libraries],
892 [AC_HELP_STRING([--with-ffi-libraries=ARG],
893   [Find libffi in ARG [default=system default]])
894 ],
895 [
896  if test "x$UseSystemLibFFI" != "xYES"; then
897     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
898  else
899     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
900  fi
901 ])
902
903 AC_SUBST(FFILibDir)
904
905 AS_IF([test "$UseSystemLibFFI" = "YES"], [
906  CFLAGS2="$CFLAGS"
907  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
908  LDFLAGS2="$LDFLAGS"
909  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
910  if test "$HostOS" = "openbsd";
911  then
912    # OpenBSD's libffi is not directly linked to the libpthread but
913    # still requires pthread functionality. This means that any client
914    # binary which links with libffi also needs to link with
915    # libpthread. If it does not, then linking fails with unresolved
916    # symbols.
917    LDFLAGS="$LDFLAGS -lpthread"
918  fi
919  AC_CHECK_LIB(ffi, ffi_call,
920   [AC_CHECK_HEADERS([ffi.h], [break], [])
921    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
922   [AC_MSG_ERROR([Cannot find system libffi])])
923  CFLAGS="$CFLAGS2"
924  LDFLAGS="$LDFLAGS2"
925 ])
926
927 dnl ** check whether we need -ldl to get dlopen()
928 AC_CHECK_LIB(dl, dlopen)
929
930 dnl --------------------------------------------------
931 dnl * Miscellaneous feature tests
932 dnl --------------------------------------------------
933
934 dnl ** can we get alloca?
935 AC_FUNC_ALLOCA
936
937 dnl ** working vfork?
938 AC_FUNC_FORK
939
940 dnl ** determine whether or not const works
941 AC_C_CONST
942
943 dnl ** are we big endian?
944 AC_C_BIGENDIAN
945 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
946
947 dnl ** check for leading underscores in symbol names
948 FP_LEADING_UNDERSCORE
949
950 FP_VISIBILITY_HIDDEN
951
952 dnl ** check for librt
953 AC_CHECK_LIB(rt, clock_gettime)
954 AC_CHECK_FUNCS(clock_gettime timer_settime)
955 FP_CHECK_TIMER_CREATE
956
957 dnl ** check for Apple's "interesting" long double compatibility scheme
958 AC_MSG_CHECKING(for printf\$LDBLStub)
959 AC_TRY_LINK_FUNC(printf\$LDBLStub,
960     [
961         AC_MSG_RESULT(yes)
962         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
963             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
964     ],
965     [
966         AC_MSG_RESULT(no)
967         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
968             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
969     ])
970
971 dnl Some platforms (e.g. Android's Bionic) have pthreads support available
972 dnl without linking against libpthread. Check whether -lpthread is necessary
973 dnl to use pthreads.
974 dnl
975 dnl Note that it is important that this happens before we AC_CHECK_LIB(thread)
976 AC_MSG_CHECKING(whether -lpthread is needed for pthreads)
977 AC_CHECK_FUNC(pthread_create,
978     [
979         AC_MSG_RESULT(no)
980         need_lpthread=0
981     ],
982     [
983         AC_CHECK_LIB(pthread, pthread_create,
984             [
985                 AC_MSG_RESULT(yes)
986                 need_lpthread=1
987             ],
988             [
989                 AC_MSG_RESULT([no pthreads support found.])
990                 need_lpthread=0
991             ])
992     ])
993 AC_DEFINE_UNQUOTED([NEED_PTHREAD_LIB], [$need_lpthread],
994     [Define 1 if we need to link code using pthreads with -lpthread])
995
996 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
997 dnl    a different single-argument version.
998 AC_CHECK_LIB(pthread, pthread_setname_np)
999 AC_MSG_CHECKING(for pthread_setname_np)
1000 AC_TRY_LINK(
1001 [
1002 #define _GNU_SOURCE
1003 #include <pthread.h>
1004 ],
1005 [pthread_setname_np(pthread_self(), "name");],
1006     AC_MSG_RESULT(yes)
1007     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
1008       [Define to 1 if you have the glibc version of pthread_setname_np]),
1009     AC_MSG_RESULT(no)
1010 )
1011
1012 dnl ** check for eventfd which is needed by the I/O manager
1013 AC_CHECK_HEADERS([sys/eventfd.h])
1014 AC_CHECK_FUNCS([eventfd])
1015
1016 dnl ** Check for __thread support in the compiler
1017 AC_MSG_CHECKING(for __thread support)
1018 AC_COMPILE_IFELSE(
1019   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
1020   [
1021    AC_MSG_RESULT(yes)
1022    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1023   ],
1024   [
1025    AC_MSG_RESULT(no)
1026    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1027   ])
1028
1029 dnl large address space support (see includes/rts/storage/MBlock.h)
1030 dnl
1031 dnl Darwin has vm_allocate/vm_protect
1032 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1033 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1034 dnl (They also have MADV_DONTNEED, but it means something else!)
1035 dnl
1036 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1037 dnl it counts page-table space as committed memory, and so quickly
1038 dnl runs out of paging file when we have multiple processes reserving
1039 dnl 1TB of address space, we get the following error:
1040 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1041 dnl
1042
1043 AC_ARG_ENABLE(large-address-space,
1044     [AC_HELP_STRING([--enable-large-address-space],
1045         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1046     EnableLargeAddressSpace=$enableval,
1047     EnableLargeAddressSpace=yes
1048 )
1049
1050 use_large_address_space=no
1051 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1052     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1053         if test "$ghc_host_os" = "darwin" ; then
1054             use_large_address_space=yes
1055         elif test "$ghc_host_os" = "openbsd" ; then
1056             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1057             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1058             # but is completely ignored by OS mmap
1059             use_large_address_space=no
1060         else
1061             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1062                 [
1063                 #include <unistd.h>
1064                 #include <sys/types.h>
1065                 #include <sys/mman.h>
1066                 #include <fcntl.h>
1067             ])
1068             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1069                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1070                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1071                     use_large_address_space=yes
1072             fi
1073         fi
1074     fi
1075 fi
1076 if test "$use_large_address_space" = "yes" ; then
1077    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1078 fi
1079
1080 dnl ** Use MMAP in the runtime linker?
1081 dnl --------------------------------------------------------------
1082
1083 case ${TargetOS} in
1084     linux|linux-android|freebsd|dragonfly|netbsd|openbsd|kfreebsdgnu|gnu|solaris2)
1085         RtsLinkerUseMmap=1
1086         ;;
1087     darwin|ios)
1088         # Don't use mmap on powerpc/darwin as the mmap there doesn't support
1089         # reallocating. Reallocating is needed to allocate jump islands just
1090         # after each object image. Jumps to these jump islands use relative
1091         # branches which are limited to offsets that can be represented in
1092         # 24-bits.
1093         if test "$TargetArch" != "powerpc" ; then
1094             RtsLinkerUseMmap=1
1095         else
1096             RtsLinkerUseMmap=0
1097         fi
1098         ;;
1099     *)
1100         # Windows (which doesn't have mmap) and everything else.
1101         RtsLinkerUseMmap=0
1102         ;;
1103     esac
1104
1105 AC_DEFINE_UNQUOTED([RTS_LINKER_USE_MMAP], [$RtsLinkerUseMmap],
1106                    [Use mmap in the runtime linker])
1107
1108 dnl ** Have libdw?
1109 dnl --------------------------------------------------------------
1110 UseLibdw=NO
1111 USE_LIBDW=0
1112 AC_ARG_ENABLE(dwarf-unwind,
1113     [AC_HELP_STRING([--enable-dwarf-unwind],
1114         [Enable DWARF unwinding support in the runtime system via elfutils' libdw [default=no]])],
1115     [AC_CHECK_LIB(dw, dwfl_attach_state, [UseLibdw=YES], [UseLibdw=NO])],
1116     [UseLibdw=NO]
1117 )
1118 AC_SUBST(UseLibdw)
1119 if test $UseLibdw = "YES" ; then
1120         USE_LIBDW=1
1121 fi
1122 AC_DEFINE_UNQUOTED([USE_LIBDW], [$USE_LIBDW], [Set to 1 to use libdw])
1123
1124 dnl ** Have libnuma?
1125 dnl --------------------------------------------------------------
1126 HaveLibNuma=0
1127 AC_CHECK_HEADERS([numa.h numaif.h])
1128
1129 if test "$ac_cv_header_numa_h$ac_cv_header_numaif_h" = "yesyes" ; then
1130     AC_CHECK_LIB(numa, numa_available,HaveLibNuma=1)
1131 fi
1132 AC_DEFINE_UNQUOTED([HAVE_LIBNUMA], [$HaveLibNuma], [Define to 1 if you have libnuma])
1133
1134 dnl ** Documentation
1135 dnl --------------------------------------------------------------
1136 if test -n "$SPHINXBUILD"; then
1137     BUILD_MAN=YES
1138     BUILD_SPHINX_HTML=YES
1139     if test -n "$XELATEX"; then
1140         BUILD_SPHINX_PDF=YES
1141     else
1142         BUILD_SPHINX_PDF=NO
1143     fi
1144 else
1145     BUILD_MAN=NO
1146     BUILD_SPHINX_HTML=NO
1147     BUILD_SPHINX_PDF=NO
1148 fi
1149 AC_SUBST(BUILD_MAN)
1150 AC_SUBST(BUILD_SPHINX_HTML)
1151 AC_SUBST(BUILD_SPHINX_PDF)
1152
1153 LIBRARY_VERSION(base)
1154 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1155 LIBRARY_VERSION(ghc-prim)
1156 LIBRARY_VERSION(ghc-compact)
1157 LIBRARY_ghc_VERSION="$ProjectVersion"
1158 AC_SUBST(LIBRARY_ghc_VERSION)
1159
1160 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1161    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1162 fi
1163
1164 # Create the configuration for the Hadrian build system if it is present
1165 if test -e hadrian/cfg/system.config.in; then
1166     AC_CONFIG_FILES([hadrian/cfg/system.config])
1167 fi
1168
1169 # We got caught by
1170 #     http://savannah.gnu.org/bugs/index.php?1516
1171 #     $(eval ...) inside conditionals causes errors
1172 # with make 3.80, so warn the user if it looks like they're about to
1173 # try to use it.
1174 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1175 print_make_warning=""
1176 checkMake380() {
1177     make_ver=`$1 --version 2>&1 | head -1`
1178     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1179     then
1180         print_make_warning="true"
1181     fi
1182     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1183     then
1184         MakeCmd=$1
1185         AC_SUBST(MakeCmd)
1186     fi
1187 }
1188
1189 checkMake380 make
1190 checkMake380 gmake
1191
1192 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghc-boot-th/ghc-boot-th.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt utils/mkUserGuidePart/mkUserGuidePart.cabal distrib/configure.ac])
1193 AC_OUTPUT
1194 [
1195 if test "$print_make_warning" = "true"; then
1196    echo
1197    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1198    echo "This version cannot be used to build GHC."
1199    echo "Please use GNU make >= 3.81."
1200 fi
1201
1202 echo "
1203 ----------------------------------------------------------------------
1204 Configure completed successfully.
1205
1206    Building GHC version  : $ProjectVersion
1207           Git commit id  : $ProjectGitCommitId
1208
1209    Build platform        : $BuildPlatform
1210    Host platform         : $HostPlatform
1211    Target platform       : $TargetPlatform
1212 "
1213
1214 echo "\
1215    Bootstrapping using   : $WithGhc
1216       which is version   : $GhcVersion
1217 "
1218
1219 if test "x$CC_LLVM_BACKEND" = "x1"; then
1220     if test "x$CC_CLANG_BACKEND" = "x1"; then
1221         CompilerName="clang        "
1222     else
1223         CompilerName="llvm-gcc     "
1224     fi
1225 else
1226     CompilerName="gcc          "
1227 fi
1228
1229 echo "\
1230    Using (for bootstrapping) : $CC_STAGE0
1231    Using $CompilerName       : $CC
1232       which is version       : $GccVersion
1233    Building a cross compiler : $CrossCompiling
1234    Unregisterised            : $Unregisterised
1235    hs-cpp       : $HaskellCPPCmd
1236    hs-cpp-flags : $HaskellCPPArgs
1237    ld           : $LdCmd
1238    nm           : $NmCmd
1239    objdump      : $ObjdumpCmd
1240    Happy        : $HappyCmd ($HappyVersion)
1241    Alex         : $AlexCmd ($AlexVersion)
1242    Perl         : $PerlCmd
1243    sphinx-build : $SPHINXBUILD
1244    xelatex      : $XELATEX
1245
1246    Using LLVM tools
1247       llc   : $LlcCmd
1248       opt   : $OptCmd"
1249
1250 if test "$HSCOLOUR" = ""; then
1251 echo "
1252    HsColour was not found; documentation will not contain source links
1253 "
1254 else
1255 echo "\
1256    HsColour : $HSCOLOUR
1257 "
1258 fi
1259
1260 echo "\
1261    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1262    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"
1263
1264 echo "----------------------------------------------------------------------
1265 "
1266
1267 echo "\
1268 For a standard build of GHC (fully optimised with profiling), type (g)make.
1269
1270 To make changes to the default build configuration, copy the file
1271 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1272
1273 For more information on how to configure your GHC build, see
1274    http://ghc.haskell.org/trac/ghc/wiki/Building
1275 "]