Remove mapAccumL, mapAccumR, mapAccumB
[ghc.git] / compiler / types / Type.lhs
1 %
2 % (c) The University of Glasgow 2006
3 % (c) The GRASP/AQUA Project, Glasgow University, 1998
4 %
5
6 Type - public interface
7
8 \begin{code}
9 module Type (
10         -- re-exports from TypeRep
11         TyThing(..), Type, PredType(..), ThetaType, 
12         funTyCon,
13
14         -- Kinds
15         Kind, SimpleKind, KindVar,
16         kindFunResult, splitKindFunTys, splitKindFunTysN,
17
18         liftedTypeKindTyCon, openTypeKindTyCon, unliftedTypeKindTyCon,
19         argTypeKindTyCon, ubxTupleKindTyCon,
20
21         liftedTypeKind, unliftedTypeKind, openTypeKind,
22         argTypeKind, ubxTupleKind,
23
24         tySuperKind, coSuperKind, 
25
26         isLiftedTypeKind, isUnliftedTypeKind, isOpenTypeKind,
27         isUbxTupleKind, isArgTypeKind, isKind, isTySuperKind, 
28         isCoSuperKind, isSuperKind, isCoercionKind, isEqPred,
29         mkArrowKind, mkArrowKinds,
30
31         isSubArgTypeKind, isSubOpenTypeKind, isSubKind, defaultKind, eqKind,
32         isSubKindCon,
33
34         -- Re-exports from TyCon
35         PrimRep(..),
36
37         mkTyVarTy, mkTyVarTys, getTyVar, getTyVar_maybe, isTyVarTy,
38
39         mkAppTy, mkAppTys, splitAppTy, splitAppTys, 
40         splitAppTy_maybe, repSplitAppTy_maybe,
41
42         mkFunTy, mkFunTys, splitFunTy, splitFunTy_maybe, 
43         splitFunTys, splitFunTysN,
44         funResultTy, funArgTy, zipFunTys, isFunTy,
45
46         mkTyConApp, mkTyConTy, 
47         tyConAppTyCon, tyConAppArgs, 
48         splitTyConApp_maybe, splitTyConApp, 
49         splitNewTyConApp_maybe, splitNewTyConApp,
50
51         repType, repType', typePrimRep, coreView, tcView, kindView,
52
53         mkForAllTy, mkForAllTys, splitForAllTy_maybe, splitForAllTys, 
54         applyTy, applyTys, isForAllTy, dropForAlls,
55
56         -- Source types
57         predTypeRep, mkPredTy, mkPredTys, pprSourceTyCon, mkFamilyTyConApp,
58
59         -- Newtypes
60         splitRecNewType_maybe, newTyConInstRhs,
61
62         -- Lifting and boxity
63         isUnLiftedType, isUnboxedTupleType, isAlgType, isPrimitiveType,
64         isStrictType, isStrictPred, 
65
66         -- Free variables
67         tyVarsOfType, tyVarsOfTypes, tyVarsOfPred, tyVarsOfTheta,
68         typeKind, addFreeTyVars,
69
70         -- Tidying up for printing
71         tidyType,      tidyTypes,
72         tidyOpenType,  tidyOpenTypes,
73         tidyTyVarBndr, tidyFreeTyVars,
74         tidyOpenTyVar, tidyOpenTyVars,
75         tidyTopType,   tidyPred,
76         tidyKind,
77
78         -- Comparison
79         coreEqType, tcEqType, tcEqTypes, tcCmpType, tcCmpTypes, 
80         tcEqPred, tcCmpPred, tcEqTypeX, 
81
82         -- Seq
83         seqType, seqTypes,
84
85         -- Type substitutions
86         TvSubstEnv, emptyTvSubstEnv,    -- Representation widely visible
87         TvSubst(..), emptyTvSubst,      -- Representation visible to a few friends
88         mkTvSubst, mkOpenTvSubst, zipOpenTvSubst, zipTopTvSubst, mkTopTvSubst, notElemTvSubst,
89         getTvSubstEnv, setTvSubstEnv, getTvInScope, extendTvInScope,
90         extendTvSubst, extendTvSubstList, isInScope, composeTvSubst, zipTyEnv,
91         isEmptyTvSubst,
92
93         -- Performing substitution on types
94         substTy, substTys, substTyWith, substTheta, 
95         substPred, substTyVar, substTyVars, substTyVarBndr, deShadowTy, lookupTyVar,
96
97         -- Pretty-printing
98         pprType, pprParendType, pprTypeApp, pprTyThingCategory, pprForAll,
99         pprPred, pprTheta, pprThetaArrow, pprClassPred, pprKind, pprParendKind
100     ) where
101
102 #include "HsVersions.h"
103
104 -- We import the representation and primitive functions from TypeRep.
105 -- Many things are reexported, but not the representation!
106
107 import TypeRep
108
109 -- friends:
110 import Var
111 import VarEnv
112 import VarSet
113
114 import Name
115 import Class
116 import PrelNames
117 import TyCon
118
119 -- others
120 import StaticFlags
121 import Util
122 import Outputable
123 import UniqSet
124
125 import Data.List
126 import Data.Maybe       ( isJust )
127 \end{code}
128
129
130 %************************************************************************
131 %*                                                                      *
132                 Type representation
133 %*                                                                      *
134 %************************************************************************
135
136 In Core, we "look through" non-recursive newtypes and PredTypes.
137
138 \begin{code}
139 {-# INLINE coreView #-}
140 coreView :: Type -> Maybe Type
141 -- Strips off the *top layer only* of a type to give 
142 -- its underlying representation type. 
143 -- Returns Nothing if there is nothing to look through.
144 --
145 -- In the case of newtypes, it returns
146 --      *either* a vanilla TyConApp (recursive newtype, or non-saturated)
147 --      *or*     the newtype representation (otherwise), meaning the
148 --                      type written in the RHS of the newtype decl,
149 --                      which may itself be a newtype
150 --
151 -- Example: newtype R = MkR S
152 --          newtype S = MkS T
153 --          newtype T = MkT (T -> T)
154 --   expandNewTcApp on R gives Just S
155 --                  on S gives Just T
156 --                  on T gives Nothing   (no expansion)
157
158 -- By being non-recursive and inlined, this case analysis gets efficiently
159 -- joined onto the case analysis that the caller is already doing
160 coreView (NoteTy _ ty)     = Just ty
161 coreView (PredTy p)
162   | isEqPred p             = Nothing
163   | otherwise              = Just (predTypeRep p)
164 coreView (TyConApp tc tys) | Just (tenv, rhs, tys') <- coreExpandTyCon_maybe tc tys 
165                            = Just (mkAppTys (substTy (mkTopTvSubst tenv) rhs) tys')
166                                 -- Its important to use mkAppTys, rather than (foldl AppTy),
167                                 -- because the function part might well return a 
168                                 -- partially-applied type constructor; indeed, usually will!
169 coreView ty                = Nothing
170
171
172
173 -----------------------------------------------
174 {-# INLINE tcView #-}
175 tcView :: Type -> Maybe Type
176 -- Same, but for the type checker, which just looks through synonyms
177 tcView (NoteTy _ ty)     = Just ty
178 tcView (TyConApp tc tys) | Just (tenv, rhs, tys') <- tcExpandTyCon_maybe tc tys 
179                          = Just (mkAppTys (substTy (mkTopTvSubst tenv) rhs) tys')
180 tcView ty                = Nothing
181
182 -----------------------------------------------
183 {-# INLINE kindView #-}
184 kindView :: Kind -> Maybe Kind
185 -- C.f. coreView, tcView
186 -- For the moment, we don't even handle synonyms in kinds
187 kindView (NoteTy _ k) = Just k
188 kindView other        = Nothing
189 \end{code}
190
191
192 %************************************************************************
193 %*                                                                      *
194 \subsection{Constructor-specific functions}
195 %*                                                                      *
196 %************************************************************************
197
198
199 ---------------------------------------------------------------------
200                                 TyVarTy
201                                 ~~~~~~~
202 \begin{code}
203 mkTyVarTy  :: TyVar   -> Type
204 mkTyVarTy  = TyVarTy
205
206 mkTyVarTys :: [TyVar] -> [Type]
207 mkTyVarTys = map mkTyVarTy -- a common use of mkTyVarTy
208
209 getTyVar :: String -> Type -> TyVar
210 getTyVar msg ty = case getTyVar_maybe ty of
211                     Just tv -> tv
212                     Nothing -> panic ("getTyVar: " ++ msg)
213
214 isTyVarTy :: Type -> Bool
215 isTyVarTy ty = isJust (getTyVar_maybe ty)
216
217 getTyVar_maybe :: Type -> Maybe TyVar
218 getTyVar_maybe ty | Just ty' <- coreView ty = getTyVar_maybe ty'
219 getTyVar_maybe (TyVarTy tv)                 = Just tv  
220 getTyVar_maybe other                        = Nothing
221
222 \end{code}
223
224
225 ---------------------------------------------------------------------
226                                 AppTy
227                                 ~~~~~
228 We need to be pretty careful with AppTy to make sure we obey the 
229 invariant that a TyConApp is always visibly so.  mkAppTy maintains the
230 invariant: use it.
231
232 \begin{code}
233 mkAppTy orig_ty1 orig_ty2
234   = mk_app orig_ty1
235   where
236     mk_app (NoteTy _ ty1)    = mk_app ty1
237     mk_app (TyConApp tc tys) = mkTyConApp tc (tys ++ [orig_ty2])
238     mk_app ty1               = AppTy orig_ty1 orig_ty2
239         -- Note that the TyConApp could be an 
240         -- under-saturated type synonym.  GHC allows that; e.g.
241         --      type Foo k = k a -> k a
242         --      type Id x = x
243         --      foo :: Foo Id -> Foo Id
244         --
245         -- Here Id is partially applied in the type sig for Foo,
246         -- but once the type synonyms are expanded all is well
247
248 mkAppTys :: Type -> [Type] -> Type
249 mkAppTys orig_ty1 []        = orig_ty1
250         -- This check for an empty list of type arguments
251         -- avoids the needless loss of a type synonym constructor.
252         -- For example: mkAppTys Rational []
253         --   returns to (Ratio Integer), which has needlessly lost
254         --   the Rational part.
255 mkAppTys orig_ty1 orig_tys2
256   = mk_app orig_ty1
257   where
258     mk_app (NoteTy _ ty1)    = mk_app ty1
259     mk_app (TyConApp tc tys) = mkTyConApp tc (tys ++ orig_tys2)
260                                 -- mkTyConApp: see notes with mkAppTy
261     mk_app ty1               = foldl AppTy orig_ty1 orig_tys2
262
263 -------------
264 splitAppTy_maybe :: Type -> Maybe (Type, Type)
265 splitAppTy_maybe ty | Just ty' <- coreView ty
266                     = splitAppTy_maybe ty'
267 splitAppTy_maybe ty = repSplitAppTy_maybe ty
268
269 -------------
270 repSplitAppTy_maybe :: Type -> Maybe (Type,Type)
271 -- Does the AppTy split, but assumes that any view stuff is already done
272 repSplitAppTy_maybe (FunTy ty1 ty2)   = Just (TyConApp funTyCon [ty1], ty2)
273 repSplitAppTy_maybe (AppTy ty1 ty2)   = Just (ty1, ty2)
274 repSplitAppTy_maybe (TyConApp tc tys) = case snocView tys of
275                                                 Just (tys', ty') -> Just (TyConApp tc tys', ty')
276                                                 Nothing          -> Nothing
277 repSplitAppTy_maybe other = Nothing
278 -------------
279 splitAppTy :: Type -> (Type, Type)
280 splitAppTy ty = case splitAppTy_maybe ty of
281                         Just pr -> pr
282                         Nothing -> panic "splitAppTy"
283
284 -------------
285 splitAppTys :: Type -> (Type, [Type])
286 splitAppTys ty = split ty ty []
287   where
288     split orig_ty ty args | Just ty' <- coreView ty = split orig_ty ty' args
289     split orig_ty (AppTy ty arg)        args = split ty ty (arg:args)
290     split orig_ty (TyConApp tc tc_args) args = (TyConApp tc [], tc_args ++ args)
291     split orig_ty (FunTy ty1 ty2)       args = ASSERT( null args )
292                                                (TyConApp funTyCon [], [ty1,ty2])
293     split orig_ty ty                    args = (orig_ty, args)
294
295 \end{code}
296
297
298 ---------------------------------------------------------------------
299                                 FunTy
300                                 ~~~~~
301
302 \begin{code}
303 mkFunTy :: Type -> Type -> Type
304 mkFunTy (PredTy (EqPred ty1 ty2)) res = mkForAllTy (mkWildCoVar (PredTy (EqPred ty1 ty2))) res
305 mkFunTy arg res = FunTy arg res
306
307 mkFunTys :: [Type] -> Type -> Type
308 mkFunTys tys ty = foldr mkFunTy ty tys
309
310 isFunTy :: Type -> Bool 
311 isFunTy ty = isJust (splitFunTy_maybe ty)
312
313 splitFunTy :: Type -> (Type, Type)
314 splitFunTy ty | Just ty' <- coreView ty = splitFunTy ty'
315 splitFunTy (FunTy arg res)   = (arg, res)
316 splitFunTy other             = pprPanic "splitFunTy" (ppr other)
317
318 splitFunTy_maybe :: Type -> Maybe (Type, Type)
319 splitFunTy_maybe ty | Just ty' <- coreView ty = splitFunTy_maybe ty'
320 splitFunTy_maybe (FunTy arg res)   = Just (arg, res)
321 splitFunTy_maybe other             = Nothing
322
323 splitFunTys :: Type -> ([Type], Type)
324 splitFunTys ty = split [] ty ty
325   where
326     split args orig_ty ty | Just ty' <- coreView ty = split args orig_ty ty'
327     split args orig_ty (FunTy arg res)   = split (arg:args) res res
328     split args orig_ty ty                = (reverse args, orig_ty)
329
330 splitFunTysN :: Int -> Type -> ([Type], Type)
331 -- Split off exactly n arg tys
332 splitFunTysN 0 ty = ([], ty)
333 splitFunTysN n ty = case splitFunTy ty of { (arg, res) ->
334                     case splitFunTysN (n-1) res of { (args, res) ->
335                     (arg:args, res) }}
336
337 zipFunTys :: Outputable a => [a] -> Type -> ([(a,Type)], Type)
338 zipFunTys orig_xs orig_ty = split [] orig_xs orig_ty orig_ty
339   where
340     split acc []     nty ty                = (reverse acc, nty)
341     split acc xs     nty ty 
342           | Just ty' <- coreView ty        = split acc xs nty ty'
343     split acc (x:xs) nty (FunTy arg res)   = split ((x,arg):acc) xs res res
344     split acc (x:xs) nty ty                = pprPanic "zipFunTys" (ppr orig_xs <+> ppr orig_ty)
345     
346 funResultTy :: Type -> Type
347 funResultTy ty | Just ty' <- coreView ty = funResultTy ty'
348 funResultTy (FunTy arg res)   = res
349 funResultTy ty                = pprPanic "funResultTy" (ppr ty)
350
351 funArgTy :: Type -> Type
352 funArgTy ty | Just ty' <- coreView ty = funArgTy ty'
353 funArgTy (FunTy arg res)   = arg
354 funArgTy ty                = pprPanic "funArgTy" (ppr ty)
355 \end{code}
356
357
358 ---------------------------------------------------------------------
359                                 TyConApp
360                                 ~~~~~~~~
361 @mkTyConApp@ is a key function, because it builds a TyConApp, FunTy or PredTy,
362 as apppropriate.
363
364 \begin{code}
365 mkTyConApp :: TyCon -> [Type] -> Type
366 mkTyConApp tycon tys
367   | isFunTyCon tycon, [ty1,ty2] <- tys
368   = FunTy ty1 ty2
369
370   | otherwise
371   = TyConApp tycon tys
372
373 mkTyConTy :: TyCon -> Type
374 mkTyConTy tycon = mkTyConApp tycon []
375
376 -- splitTyConApp "looks through" synonyms, because they don't
377 -- mean a distinct type, but all other type-constructor applications
378 -- including functions are returned as Just ..
379
380 tyConAppTyCon :: Type -> TyCon
381 tyConAppTyCon ty = fst (splitTyConApp ty)
382
383 tyConAppArgs :: Type -> [Type]
384 tyConAppArgs ty = snd (splitTyConApp ty)
385
386 splitTyConApp :: Type -> (TyCon, [Type])
387 splitTyConApp ty = case splitTyConApp_maybe ty of
388                         Just stuff -> stuff
389                         Nothing    -> pprPanic "splitTyConApp" (ppr ty)
390
391 splitTyConApp_maybe :: Type -> Maybe (TyCon, [Type])
392 splitTyConApp_maybe ty | Just ty' <- coreView ty = splitTyConApp_maybe ty'
393 splitTyConApp_maybe (TyConApp tc tys) = Just (tc, tys)
394 splitTyConApp_maybe (FunTy arg res)   = Just (funTyCon, [arg,res])
395 splitTyConApp_maybe other             = Nothing
396
397 -- Sometimes we do NOT want to look throught a newtype.  When case matching
398 -- on a newtype we want a convenient way to access the arguments of a newty
399 -- constructor so as to properly form a coercion.
400 splitNewTyConApp :: Type -> (TyCon, [Type])
401 splitNewTyConApp ty = case splitNewTyConApp_maybe ty of
402                         Just stuff -> stuff
403                         Nothing    -> pprPanic "splitNewTyConApp" (ppr ty)
404 splitNewTyConApp_maybe :: Type -> Maybe (TyCon, [Type])
405 splitNewTyConApp_maybe ty | Just ty' <- tcView ty = splitNewTyConApp_maybe ty'
406 splitNewTyConApp_maybe (TyConApp tc tys) = Just (tc, tys)
407 splitNewTyConApp_maybe (FunTy arg res)   = Just (funTyCon, [arg,res])
408 splitNewTyConApp_maybe other          = Nothing
409
410 -- get instantiated newtype rhs, the arguments had better saturate 
411 -- the constructor
412 newTyConInstRhs :: TyCon -> [Type] -> Type
413 newTyConInstRhs tycon tys =
414     let (tvs, ty) = newTyConRhs tycon in substTyWith tvs tys ty
415 \end{code}
416
417
418 ---------------------------------------------------------------------
419                                 SynTy
420                                 ~~~~~
421
422 Notes on type synonyms
423 ~~~~~~~~~~~~~~~~~~~~~~
424 The various "split" functions (splitFunTy, splitRhoTy, splitForAllTy) try
425 to return type synonyms whereever possible. Thus
426
427         type Foo a = a -> a
428
429 we want 
430         splitFunTys (a -> Foo a) = ([a], Foo a)
431 not                                ([a], a -> a)
432
433 The reason is that we then get better (shorter) type signatures in 
434 interfaces.  Notably this plays a role in tcTySigs in TcBinds.lhs.
435
436
437                 Representation types
438                 ~~~~~~~~~~~~~~~~~~~~
439 repType looks through 
440         (a) for-alls, and
441         (b) synonyms
442         (c) predicates
443         (d) usage annotations
444         (e) all newtypes, including recursive ones, but not newtype families
445 It's useful in the back end.
446
447 \begin{code}
448 repType :: Type -> Type
449 -- Only applied to types of kind *; hence tycons are saturated
450 repType ty | Just ty' <- coreView ty = repType ty'
451 repType (ForAllTy _ ty)  = repType ty
452 repType (TyConApp tc tys)
453   | isClosedNewTyCon tc  = -- Recursive newtypes are opaque to coreView
454                            -- but we must expand them here.  Sure to
455                            -- be saturated because repType is only applied
456                            -- to types of kind *
457                            ASSERT( {- isRecursiveTyCon tc && -} tys `lengthIs` tyConArity tc )
458                            repType (new_type_rep tc tys)
459 repType ty = ty
460
461 -- repType' aims to be a more thorough version of repType
462 -- For now it simply looks through the TyConApp args too
463 repType' ty -- | pprTrace "repType'" (ppr ty $$ ppr (go1 ty)) False = undefined
464             | otherwise = go1 ty 
465  where 
466         go1 = go . repType
467         go (TyConApp tc tys) = mkTyConApp tc (map repType' tys)
468         go ty = ty
469
470
471 -- new_type_rep doesn't ask any questions: 
472 -- it just expands newtype, whether recursive or not
473 new_type_rep new_tycon tys = ASSERT( tys `lengthIs` tyConArity new_tycon )
474                              case newTyConRep new_tycon of
475                                  (tvs, rep_ty) -> substTyWith tvs tys rep_ty
476
477 -- ToDo: this could be moved to the code generator, using splitTyConApp instead
478 -- of inspecting the type directly.
479 typePrimRep :: Type -> PrimRep
480 typePrimRep ty = case repType ty of
481                    TyConApp tc _ -> tyConPrimRep tc
482                    FunTy _ _     -> PtrRep
483                    AppTy _ _     -> PtrRep      -- See note below
484                    TyVarTy _     -> PtrRep
485                    other         -> pprPanic "typePrimRep" (ppr ty)
486         -- Types of the form 'f a' must be of kind *, not *#, so
487         -- we are guaranteed that they are represented by pointers.
488         -- The reason is that f must have kind *->*, not *->*#, because
489         -- (we claim) there is no way to constrain f's kind any other
490         -- way.
491
492 \end{code}
493
494
495 ---------------------------------------------------------------------
496                                 ForAllTy
497                                 ~~~~~~~~
498
499 \begin{code}
500 mkForAllTy :: TyVar -> Type -> Type
501 mkForAllTy tyvar ty
502   = mkForAllTys [tyvar] ty
503
504 mkForAllTys :: [TyVar] -> Type -> Type
505 mkForAllTys tyvars ty = foldr ForAllTy ty tyvars
506
507 isForAllTy :: Type -> Bool
508 isForAllTy (NoteTy _ ty)  = isForAllTy ty
509 isForAllTy (ForAllTy _ _) = True
510 isForAllTy other_ty       = False
511
512 splitForAllTy_maybe :: Type -> Maybe (TyVar, Type)
513 splitForAllTy_maybe ty = splitFAT_m ty
514   where
515     splitFAT_m ty | Just ty' <- coreView ty = splitFAT_m ty'
516     splitFAT_m (ForAllTy tyvar ty)          = Just(tyvar, ty)
517     splitFAT_m _                            = Nothing
518
519 splitForAllTys :: Type -> ([TyVar], Type)
520 splitForAllTys ty = split ty ty []
521    where
522      split orig_ty ty tvs | Just ty' <- coreView ty = split orig_ty ty' tvs
523      split orig_ty (ForAllTy tv ty)  tvs = split ty ty (tv:tvs)
524      split orig_ty t                 tvs = (reverse tvs, orig_ty)
525
526 dropForAlls :: Type -> Type
527 dropForAlls ty = snd (splitForAllTys ty)
528 \end{code}
529
530 -- (mkPiType now in CoreUtils)
531
532 applyTy, applyTys
533 ~~~~~~~~~~~~~~~~~
534 Instantiate a for-all type with one or more type arguments.
535 Used when we have a polymorphic function applied to type args:
536         f t1 t2
537 Then we use (applyTys type-of-f [t1,t2]) to compute the type of
538 the expression. 
539
540 \begin{code}
541 applyTy :: Type -> Type -> Type
542 applyTy ty arg | Just ty' <- coreView ty = applyTy ty' arg
543 applyTy (ForAllTy tv ty) arg = substTyWith [tv] [arg] ty
544 applyTy other            arg = panic "applyTy"
545
546 applyTys :: Type -> [Type] -> Type
547 -- This function is interesting because 
548 --      a) the function may have more for-alls than there are args
549 --      b) less obviously, it may have fewer for-alls
550 -- For case (b) think of 
551 --      applyTys (forall a.a) [forall b.b, Int]
552 -- This really can happen, via dressing up polymorphic types with newtype
553 -- clothing.  Here's an example:
554 --      newtype R = R (forall a. a->a)
555 --      foo = case undefined :: R of
556 --              R f -> f ()
557
558 applyTys orig_fun_ty []      = orig_fun_ty
559 applyTys orig_fun_ty arg_tys 
560   | n_tvs == n_args     -- The vastly common case
561   = substTyWith tvs arg_tys rho_ty
562   | n_tvs > n_args      -- Too many for-alls
563   = substTyWith (take n_args tvs) arg_tys 
564                 (mkForAllTys (drop n_args tvs) rho_ty)
565   | otherwise           -- Too many type args
566   = ASSERT2( n_tvs > 0, ppr orig_fun_ty )       -- Zero case gives infnite loop!
567     applyTys (substTyWith tvs (take n_tvs arg_tys) rho_ty)
568              (drop n_tvs arg_tys)
569   where
570     (tvs, rho_ty) = splitForAllTys orig_fun_ty 
571     n_tvs = length tvs
572     n_args = length arg_tys     
573 \end{code}
574
575
576 %************************************************************************
577 %*                                                                      *
578 \subsection{Source types}
579 %*                                                                      *
580 %************************************************************************
581
582 A "source type" is a type that is a separate type as far as the type checker is
583 concerned, but which has low-level representation as far as the back end is concerned.
584
585 Source types are always lifted.
586
587 The key function is predTypeRep which gives the representation of a source type:
588
589 \begin{code}
590 mkPredTy :: PredType -> Type
591 mkPredTy pred = PredTy pred
592
593 mkPredTys :: ThetaType -> [Type]
594 mkPredTys preds = map PredTy preds
595
596 predTypeRep :: PredType -> Type
597 -- Convert a PredType to its "representation type";
598 -- the post-type-checking type used by all the Core passes of GHC.
599 -- Unwraps only the outermost level; for example, the result might
600 -- be a newtype application
601 predTypeRep (IParam _ ty)     = ty
602 predTypeRep (ClassP clas tys) = mkTyConApp (classTyCon clas) tys
603         -- Result might be a newtype application, but the consumer will
604         -- look through that too if necessary
605 predTypeRep (EqPred ty1 ty2) = pprPanic "predTypeRep" (ppr (EqPred ty1 ty2))
606
607 mkFamilyTyConApp :: TyCon -> [Type] -> Type
608 -- Given a family instance TyCon and its arg types, return the
609 -- corresponding family type.  E.g.
610 --      data family T a
611 --      data instance T (Maybe b) = MkT b       -- Instance tycon :RTL
612 -- Then 
613 --      mkFamilyTyConApp :RTL Int  =  T (Maybe Int)
614 mkFamilyTyConApp tc tys
615   | Just (fam_tc, fam_tys) <- tyConFamInst_maybe tc
616   , let fam_subst = zipTopTvSubst (tyConTyVars tc) tys
617   = mkTyConApp fam_tc (substTys fam_subst fam_tys)
618   | otherwise
619   = mkTyConApp tc tys
620
621 -- Pretty prints a tycon, using the family instance in case of a
622 -- representation tycon.  For example
623 --      e.g.  data T [a] = ...
624 -- In that case we want to print `T [a]', where T is the family TyCon
625 pprSourceTyCon tycon 
626   | Just (fam_tc, tys) <- tyConFamInst_maybe tycon
627   = ppr $ fam_tc `TyConApp` tys        -- can't be FunTyCon
628   | otherwise
629   = ppr tycon
630 \end{code}
631
632
633 %************************************************************************
634 %*                                                                      *
635                 NewTypes
636 %*                                                                      *
637 %************************************************************************
638
639 \begin{code}
640 splitRecNewType_maybe :: Type -> Maybe Type
641 -- Sometimes we want to look through a recursive newtype, and that's what happens here
642 -- It only strips *one layer* off, so the caller will usually call itself recursively
643 -- Only applied to types of kind *, hence the newtype is always saturated
644 splitRecNewType_maybe ty | Just ty' <- coreView ty = splitRecNewType_maybe ty'
645 splitRecNewType_maybe (TyConApp tc tys)
646   | isClosedNewTyCon tc
647   = ASSERT( tys `lengthIs` tyConArity tc )      -- splitRecNewType_maybe only be applied 
648                                                 --      to *types* (of kind *)
649     ASSERT( isRecursiveTyCon tc )               -- Guaranteed by coreView
650     case newTyConRhs tc of
651         (tvs, rep_ty) -> ASSERT( length tvs == length tys )
652                          Just (substTyWith tvs tys rep_ty)
653         
654 splitRecNewType_maybe other = Nothing
655 \end{code}
656
657
658 %************************************************************************
659 %*                                                                      *
660 \subsection{Kinds and free variables}
661 %*                                                                      *
662 %************************************************************************
663
664 ---------------------------------------------------------------------
665                 Finding the kind of a type
666                 ~~~~~~~~~~~~~~~~~~~~~~~~~~
667 \begin{code}
668 typeKind :: Type -> Kind
669 typeKind (TyConApp tycon tys) = ASSERT( not (isCoercionTyCon tycon) )
670                                    -- We should be looking for the coercion kind,
671                                    -- not the type kind
672                                 foldr (\_ k -> kindFunResult k) (tyConKind tycon) tys
673 typeKind (NoteTy _ ty)        = typeKind ty
674 typeKind (PredTy pred)        = predKind pred
675 typeKind (AppTy fun arg)      = kindFunResult (typeKind fun)
676 typeKind (ForAllTy tv ty)     = typeKind ty
677 typeKind (TyVarTy tyvar)      = tyVarKind tyvar
678 typeKind (FunTy arg res)
679     -- Hack alert.  The kind of (Int -> Int#) is liftedTypeKind (*), 
680     --              not unliftedTypKind (#)
681     -- The only things that can be after a function arrow are
682     --   (a) types (of kind openTypeKind or its sub-kinds)
683     --   (b) kinds (of super-kind TY) (e.g. * -> (* -> *))
684     | isTySuperKind k         = k
685     | otherwise               = ASSERT( isSubOpenTypeKind k) liftedTypeKind 
686     where
687       k = typeKind res
688
689 predKind :: PredType -> Kind
690 predKind (EqPred {}) = coSuperKind      -- A coercion kind!
691 predKind (ClassP {}) = liftedTypeKind   -- Class and implicitPredicates are
692 predKind (IParam {}) = liftedTypeKind   -- always represented by lifted types
693 \end{code}
694
695
696 ---------------------------------------------------------------------
697                 Free variables of a type
698                 ~~~~~~~~~~~~~~~~~~~~~~~~
699 \begin{code}
700 tyVarsOfType :: Type -> TyVarSet
701 -- NB: for type synonyms tyVarsOfType does *not* expand the synonym
702 tyVarsOfType (TyVarTy tv)               = unitVarSet tv
703 tyVarsOfType (TyConApp tycon tys)       = tyVarsOfTypes tys
704 tyVarsOfType (NoteTy (FTVNote tvs) ty2) = tvs
705 tyVarsOfType (PredTy sty)               = tyVarsOfPred sty
706 tyVarsOfType (FunTy arg res)            = tyVarsOfType arg `unionVarSet` tyVarsOfType res
707 tyVarsOfType (AppTy fun arg)            = tyVarsOfType fun `unionVarSet` tyVarsOfType arg
708 tyVarsOfType (ForAllTy tyvar ty)        = delVarSet (tyVarsOfType ty) tyvar
709
710 tyVarsOfTypes :: [Type] -> TyVarSet
711 tyVarsOfTypes tys = foldr (unionVarSet.tyVarsOfType) emptyVarSet tys
712
713 tyVarsOfPred :: PredType -> TyVarSet
714 tyVarsOfPred (IParam _ ty)    = tyVarsOfType ty
715 tyVarsOfPred (ClassP _ tys)   = tyVarsOfTypes tys
716 tyVarsOfPred (EqPred ty1 ty2) = tyVarsOfType ty1 `unionVarSet` tyVarsOfType ty2
717
718 tyVarsOfTheta :: ThetaType -> TyVarSet
719 tyVarsOfTheta = foldr (unionVarSet . tyVarsOfPred) emptyVarSet
720
721 -- Add a Note with the free tyvars to the top of the type
722 addFreeTyVars :: Type -> Type
723 addFreeTyVars ty@(NoteTy (FTVNote _) _)      = ty
724 addFreeTyVars ty                             = NoteTy (FTVNote (tyVarsOfType ty)) ty
725 \end{code}
726
727
728 %************************************************************************
729 %*                                                                      *
730 \subsection{TidyType}
731 %*                                                                      *
732 %************************************************************************
733
734 tidyTy tidies up a type for printing in an error message, or in
735 an interface file.
736
737 It doesn't change the uniques at all, just the print names.
738
739 \begin{code}
740 tidyTyVarBndr :: TidyEnv -> TyVar -> (TidyEnv, TyVar)
741 tidyTyVarBndr env@(tidy_env, subst) tyvar
742   = case tidyOccName tidy_env (getOccName name) of
743       (tidy', occ') -> ((tidy', subst'), tyvar'')
744         where
745           subst' = extendVarEnv subst tyvar tyvar''
746           tyvar' = setTyVarName tyvar name'
747           name'  = tidyNameOcc name occ'
748                 -- Don't forget to tidy the kind for coercions!
749           tyvar'' | isCoVar tyvar = setTyVarKind tyvar' kind'
750                   | otherwise     = tyvar'
751           kind'  = tidyType env (tyVarKind tyvar)
752   where
753     name = tyVarName tyvar
754
755 tidyFreeTyVars :: TidyEnv -> TyVarSet -> TidyEnv
756 -- Add the free tyvars to the env in tidy form,
757 -- so that we can tidy the type they are free in
758 tidyFreeTyVars env tyvars = fst (tidyOpenTyVars env (varSetElems tyvars))
759
760 tidyOpenTyVars :: TidyEnv -> [TyVar] -> (TidyEnv, [TyVar])
761 tidyOpenTyVars env tyvars = mapAccumL tidyOpenTyVar env tyvars
762
763 tidyOpenTyVar :: TidyEnv -> TyVar -> (TidyEnv, TyVar)
764 -- Treat a new tyvar as a binder, and give it a fresh tidy name
765 tidyOpenTyVar env@(tidy_env, subst) tyvar
766   = case lookupVarEnv subst tyvar of
767         Just tyvar' -> (env, tyvar')            -- Already substituted
768         Nothing     -> tidyTyVarBndr env tyvar  -- Treat it as a binder
769
770 tidyType :: TidyEnv -> Type -> Type
771 tidyType env@(tidy_env, subst) ty
772   = go ty
773   where
774     go (TyVarTy tv)         = case lookupVarEnv subst tv of
775                                 Nothing  -> TyVarTy tv
776                                 Just tv' -> TyVarTy tv'
777     go (TyConApp tycon tys) = let args = map go tys
778                               in args `seqList` TyConApp tycon args
779     go (NoteTy note ty)     = (NoteTy $! (go_note note)) $! (go ty)
780     go (PredTy sty)         = PredTy (tidyPred env sty)
781     go (AppTy fun arg)      = (AppTy $! (go fun)) $! (go arg)
782     go (FunTy fun arg)      = (FunTy $! (go fun)) $! (go arg)
783     go (ForAllTy tv ty)     = ForAllTy tvp $! (tidyType envp ty)
784                               where
785                                 (envp, tvp) = tidyTyVarBndr env tv
786
787     go_note note@(FTVNote ftvs) = note  -- No need to tidy the free tyvars
788
789 tidyTypes env tys = map (tidyType env) tys
790
791 tidyPred :: TidyEnv -> PredType -> PredType
792 tidyPred env (IParam n ty)     = IParam n (tidyType env ty)
793 tidyPred env (ClassP clas tys) = ClassP clas (tidyTypes env tys)
794 tidyPred env (EqPred ty1 ty2)  = EqPred (tidyType env ty1) (tidyType env ty2)
795 \end{code}
796
797
798 @tidyOpenType@ grabs the free type variables, tidies them
799 and then uses @tidyType@ to work over the type itself
800
801 \begin{code}
802 tidyOpenType :: TidyEnv -> Type -> (TidyEnv, Type)
803 tidyOpenType env ty
804   = (env', tidyType env' ty)
805   where
806     env' = tidyFreeTyVars env (tyVarsOfType ty)
807
808 tidyOpenTypes :: TidyEnv -> [Type] -> (TidyEnv, [Type])
809 tidyOpenTypes env tys = mapAccumL tidyOpenType env tys
810
811 tidyTopType :: Type -> Type
812 tidyTopType ty = tidyType emptyTidyEnv ty
813 \end{code}
814
815 \begin{code}
816
817 tidyKind :: TidyEnv -> Kind -> (TidyEnv, Kind)
818 tidyKind env k = tidyOpenType env k
819
820 \end{code}
821
822
823 %************************************************************************
824 %*                                                                      *
825 \subsection{Liftedness}
826 %*                                                                      *
827 %************************************************************************
828
829 \begin{code}
830 isUnLiftedType :: Type -> Bool
831         -- isUnLiftedType returns True for forall'd unlifted types:
832         --      x :: forall a. Int#
833         -- I found bindings like these were getting floated to the top level.
834         -- They are pretty bogus types, mind you.  It would be better never to
835         -- construct them
836
837 isUnLiftedType ty | Just ty' <- coreView ty = isUnLiftedType ty'
838 isUnLiftedType (ForAllTy tv ty)  = isUnLiftedType ty
839 isUnLiftedType (TyConApp tc _)   = isUnLiftedTyCon tc
840 isUnLiftedType other             = False        
841
842 isUnboxedTupleType :: Type -> Bool
843 isUnboxedTupleType ty = case splitTyConApp_maybe ty of
844                            Just (tc, ty_args) -> isUnboxedTupleTyCon tc
845                            other              -> False
846
847 -- Should only be applied to *types*; hence the assert
848 isAlgType :: Type -> Bool
849 isAlgType ty = case splitTyConApp_maybe ty of
850                         Just (tc, ty_args) -> ASSERT( ty_args `lengthIs` tyConArity tc )
851                                               isAlgTyCon tc
852                         other              -> False
853 \end{code}
854
855 @isStrictType@ computes whether an argument (or let RHS) should
856 be computed strictly or lazily, based only on its type.
857 Works just like isUnLiftedType, except that it has a special case 
858 for dictionaries.  Since it takes account of ClassP, you might think
859 this function should be in TcType, but isStrictType is used by DataCon,
860 which is below TcType in the hierarchy, so it's convenient to put it here.
861
862 \begin{code}
863 isStrictType (PredTy pred)     = isStrictPred pred
864 isStrictType ty | Just ty' <- coreView ty = isStrictType ty'
865 isStrictType (ForAllTy tv ty)  = isStrictType ty
866 isStrictType (TyConApp tc _)   = isUnLiftedTyCon tc
867 isStrictType other             = False  
868
869 isStrictPred (ClassP clas _) = opt_DictsStrict && not (isNewTyCon (classTyCon clas))
870 isStrictPred other           = False
871         -- We may be strict in dictionary types, but only if it 
872         -- has more than one component.
873         -- [Being strict in a single-component dictionary risks
874         --  poking the dictionary component, which is wrong.]
875 \end{code}
876
877 \begin{code}
878 isPrimitiveType :: Type -> Bool
879 -- Returns types that are opaque to Haskell.
880 -- Most of these are unlifted, but now that we interact with .NET, we
881 -- may have primtive (foreign-imported) types that are lifted
882 isPrimitiveType ty = case splitTyConApp_maybe ty of
883                         Just (tc, ty_args) -> ASSERT( ty_args `lengthIs` tyConArity tc )
884                                               isPrimTyCon tc
885                         other              -> False
886 \end{code}
887
888
889 %************************************************************************
890 %*                                                                      *
891 \subsection{Sequencing on types
892 %*                                                                      *
893 %************************************************************************
894
895 \begin{code}
896 seqType :: Type -> ()
897 seqType (TyVarTy tv)      = tv `seq` ()
898 seqType (AppTy t1 t2)     = seqType t1 `seq` seqType t2
899 seqType (FunTy t1 t2)     = seqType t1 `seq` seqType t2
900 seqType (NoteTy note t2)  = seqNote note `seq` seqType t2
901 seqType (PredTy p)        = seqPred p
902 seqType (TyConApp tc tys) = tc `seq` seqTypes tys
903 seqType (ForAllTy tv ty)  = tv `seq` seqType ty
904
905 seqTypes :: [Type] -> ()
906 seqTypes []       = ()
907 seqTypes (ty:tys) = seqType ty `seq` seqTypes tys
908
909 seqNote :: TyNote -> ()
910 seqNote (FTVNote set) = sizeUniqSet set `seq` ()
911
912 seqPred :: PredType -> ()
913 seqPred (ClassP c tys)   = c `seq` seqTypes tys
914 seqPred (IParam n ty)    = n `seq` seqType ty
915 seqPred (EqPred ty1 ty2) = seqType ty1 `seq` seqType ty2
916 \end{code}
917
918
919 %************************************************************************
920 %*                                                                      *
921                 Equality for Core types 
922         (We don't use instances so that we know where it happens)
923 %*                                                                      *
924 %************************************************************************
925
926 Note that eqType works right even for partial applications of newtypes.
927 See Note [Newtype eta] in TyCon.lhs
928
929 \begin{code}
930 coreEqType :: Type -> Type -> Bool
931 coreEqType t1 t2
932   = eq rn_env t1 t2
933   where
934     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfType t1 `unionVarSet` tyVarsOfType t2))
935
936     eq env (TyVarTy tv1)       (TyVarTy tv2)     = rnOccL env tv1 == rnOccR env tv2
937     eq env (ForAllTy tv1 t1)   (ForAllTy tv2 t2) = eq (rnBndr2 env tv1 tv2) t1 t2
938     eq env (AppTy s1 t1)       (AppTy s2 t2)     = eq env s1 s2 && eq env t1 t2
939     eq env (FunTy s1 t1)       (FunTy s2 t2)     = eq env s1 s2 && eq env t1 t2
940     eq env (TyConApp tc1 tys1) (TyConApp tc2 tys2) 
941         | tc1 == tc2, all2 (eq env) tys1 tys2 = True
942                         -- The lengths should be equal because
943                         -- the two types have the same kind
944         -- NB: if the type constructors differ that does not 
945         --     necessarily mean that the types aren't equal
946         --     (synonyms, newtypes)
947         -- Even if the type constructors are the same, but the arguments
948         -- differ, the two types could be the same (e.g. if the arg is just
949         -- ignored in the RHS).  In both these cases we fall through to an 
950         -- attempt to expand one side or the other.
951
952         -- Now deal with newtypes, synonyms, pred-tys
953     eq env t1 t2 | Just t1' <- coreView t1 = eq env t1' t2 
954                  | Just t2' <- coreView t2 = eq env t1 t2' 
955
956         -- Fall through case; not equal!
957     eq env t1 t2 = False
958 \end{code}
959
960
961 %************************************************************************
962 %*                                                                      *
963                 Comparision for source types 
964         (We don't use instances so that we know where it happens)
965 %*                                                                      *
966 %************************************************************************
967
968 Note that 
969         tcEqType, tcCmpType 
970 do *not* look through newtypes, PredTypes
971
972 \begin{code}
973 tcEqType :: Type -> Type -> Bool
974 tcEqType t1 t2 = isEqual $ cmpType t1 t2
975
976 tcEqTypes :: [Type] -> [Type] -> Bool
977 tcEqTypes tys1 tys2 = isEqual $ cmpTypes tys1 tys2
978
979 tcCmpType :: Type -> Type -> Ordering
980 tcCmpType t1 t2 = cmpType t1 t2
981
982 tcCmpTypes :: [Type] -> [Type] -> Ordering
983 tcCmpTypes tys1 tys2 = cmpTypes tys1 tys2
984
985 tcEqPred :: PredType -> PredType -> Bool
986 tcEqPred p1 p2 = isEqual $ cmpPred p1 p2
987
988 tcCmpPred :: PredType -> PredType -> Ordering
989 tcCmpPred p1 p2 = cmpPred p1 p2
990
991 tcEqTypeX :: RnEnv2 -> Type -> Type -> Bool
992 tcEqTypeX env t1 t2 = isEqual $ cmpTypeX env t1 t2
993 \end{code}
994
995 Now here comes the real worker
996
997 \begin{code}
998 cmpType :: Type -> Type -> Ordering
999 cmpType t1 t2 = cmpTypeX rn_env t1 t2
1000   where
1001     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfType t1 `unionVarSet` tyVarsOfType t2))
1002
1003 cmpTypes :: [Type] -> [Type] -> Ordering
1004 cmpTypes ts1 ts2 = cmpTypesX rn_env ts1 ts2
1005   where
1006     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfTypes ts1 `unionVarSet` tyVarsOfTypes ts2))
1007
1008 cmpPred :: PredType -> PredType -> Ordering
1009 cmpPred p1 p2 = cmpPredX rn_env p1 p2
1010   where
1011     rn_env = mkRnEnv2 (mkInScopeSet (tyVarsOfPred p1 `unionVarSet` tyVarsOfPred p2))
1012
1013 cmpTypeX :: RnEnv2 -> Type -> Type -> Ordering  -- Main workhorse
1014 cmpTypeX env t1 t2 | Just t1' <- tcView t1 = cmpTypeX env t1' t2
1015                    | Just t2' <- tcView t2 = cmpTypeX env t1 t2'
1016
1017 cmpTypeX env (TyVarTy tv1)       (TyVarTy tv2)       = rnOccL env tv1 `compare` rnOccR env tv2
1018 cmpTypeX env (ForAllTy tv1 t1)   (ForAllTy tv2 t2)   = cmpTypeX (rnBndr2 env tv1 tv2) t1 t2
1019 cmpTypeX env (AppTy s1 t1)       (AppTy s2 t2)       = cmpTypeX env s1 s2 `thenCmp` cmpTypeX env t1 t2
1020 cmpTypeX env (FunTy s1 t1)       (FunTy s2 t2)       = cmpTypeX env s1 s2 `thenCmp` cmpTypeX env t1 t2
1021 cmpTypeX env (PredTy p1)         (PredTy p2)         = cmpPredX env p1 p2
1022 cmpTypeX env (TyConApp tc1 tys1) (TyConApp tc2 tys2) = (tc1 `compare` tc2) `thenCmp` cmpTypesX env tys1 tys2
1023 cmpTypeX env t1                 (NoteTy _ t2)        = cmpTypeX env t1 t2
1024
1025     -- Deal with the rest: TyVarTy < AppTy < FunTy < TyConApp < ForAllTy < PredTy
1026 cmpTypeX env (AppTy _ _) (TyVarTy _) = GT
1027     
1028 cmpTypeX env (FunTy _ _) (TyVarTy _) = GT
1029 cmpTypeX env (FunTy _ _) (AppTy _ _) = GT
1030     
1031 cmpTypeX env (TyConApp _ _) (TyVarTy _) = GT
1032 cmpTypeX env (TyConApp _ _) (AppTy _ _) = GT
1033 cmpTypeX env (TyConApp _ _) (FunTy _ _) = GT
1034     
1035 cmpTypeX env (ForAllTy _ _) (TyVarTy _)    = GT
1036 cmpTypeX env (ForAllTy _ _) (AppTy _ _)    = GT
1037 cmpTypeX env (ForAllTy _ _) (FunTy _ _)    = GT
1038 cmpTypeX env (ForAllTy _ _) (TyConApp _ _) = GT
1039
1040 cmpTypeX env (PredTy _)   t2            = GT
1041
1042 cmpTypeX env _ _ = LT
1043
1044 -------------
1045 cmpTypesX :: RnEnv2 -> [Type] -> [Type] -> Ordering
1046 cmpTypesX env []        []        = EQ
1047 cmpTypesX env (t1:tys1) (t2:tys2) = cmpTypeX env t1 t2 `thenCmp` cmpTypesX env tys1 tys2
1048 cmpTypesX env []        tys       = LT
1049 cmpTypesX env ty        []        = GT
1050
1051 -------------
1052 cmpPredX :: RnEnv2 -> PredType -> PredType -> Ordering
1053 cmpPredX env (IParam n1 ty1) (IParam n2 ty2) = (n1 `compare` n2) `thenCmp` cmpTypeX env ty1 ty2
1054         -- Compare names only for implicit parameters
1055         -- This comparison is used exclusively (I believe) 
1056         -- for the Avails finite map built in TcSimplify
1057         -- If the types differ we keep them distinct so that we see 
1058         -- a distinct pair to run improvement on 
1059 cmpPredX env (ClassP c1 tys1) (ClassP c2 tys2) = (c1 `compare` c2) `thenCmp` (cmpTypesX env tys1 tys2)
1060 cmpPredX env (EqPred ty1 ty2) (EqPred ty1' ty2') = (cmpTypeX env ty1 ty1') `thenCmp` (cmpTypeX env ty2 ty2')
1061
1062 -- Constructor order: IParam < ClassP < EqPred
1063 cmpPredX env (IParam {})     _              = LT
1064 cmpPredX env (ClassP {})    (IParam {})     = GT
1065 cmpPredX env (ClassP {})    (EqPred {})     = LT
1066 cmpPredX env (EqPred {})    _               = GT
1067 \end{code}
1068
1069 PredTypes are used as a FM key in TcSimplify, 
1070 so we take the easy path and make them an instance of Ord
1071
1072 \begin{code}
1073 instance Eq  PredType where { (==)    = tcEqPred }
1074 instance Ord PredType where { compare = tcCmpPred }
1075 \end{code}
1076
1077
1078 %************************************************************************
1079 %*                                                                      *
1080                 Type substitutions
1081 %*                                                                      *
1082 %************************************************************************
1083
1084 \begin{code}
1085 data TvSubst            
1086   = TvSubst InScopeSet  -- The in-scope type variables
1087             TvSubstEnv  -- The substitution itself
1088         -- See Note [Apply Once]
1089         -- and Note [Extending the TvSubstEnv]
1090
1091 {- ----------------------------------------------------------
1092
1093 Note [Apply Once]
1094 ~~~~~~~~~~~~~~~~~
1095 We use TvSubsts to instantiate things, and we might instantiate
1096         forall a b. ty
1097 \with the types
1098         [a, b], or [b, a].
1099 So the substition might go [a->b, b->a].  A similar situation arises in Core
1100 when we find a beta redex like
1101         (/\ a /\ b -> e) b a
1102 Then we also end up with a substition that permutes type variables. Other
1103 variations happen to; for example [a -> (a, b)].  
1104
1105         ***************************************************
1106         *** So a TvSubst must be applied precisely once ***
1107         ***************************************************
1108
1109 A TvSubst is not idempotent, but, unlike the non-idempotent substitution
1110 we use during unifications, it must not be repeatedly applied.
1111
1112 Note [Extending the TvSubst]
1113 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1114 The following invariant should hold of a TvSubst
1115
1116         The in-scope set is needed *only* to
1117         guide the generation of fresh uniques
1118
1119         In particular, the *kind* of the type variables in 
1120         the in-scope set is not relevant
1121
1122 This invariant allows a short-cut when the TvSubstEnv is empty:
1123 if the TvSubstEnv is empty --- i.e. (isEmptyTvSubt subst) holds ---
1124 then (substTy subst ty) does nothing.
1125
1126 For example, consider:
1127         (/\a. /\b:(a~Int). ...b..) Int
1128 We substitute Int for 'a'.  The Unique of 'b' does not change, but
1129 nevertheless we add 'b' to the TvSubstEnv, because b's type does change
1130
1131 This invariant has several crucial consequences:
1132
1133 * In substTyVarBndr, we need extend the TvSubstEnv 
1134         - if the unique has changed
1135         - or if the kind has changed
1136
1137 * In substTyVar, we do not need to consult the in-scope set;
1138   the TvSubstEnv is enough
1139
1140 * In substTy, substTheta, we can short-circuit when the TvSubstEnv is empty
1141   
1142
1143 -------------------------------------------------------------- -}
1144
1145
1146 type TvSubstEnv = TyVarEnv Type
1147         -- A TvSubstEnv is used both inside a TvSubst (with the apply-once
1148         -- invariant discussed in Note [Apply Once]), and also independently
1149         -- in the middle of matching, and unification (see Types.Unify)
1150         -- So you have to look at the context to know if it's idempotent or
1151         -- apply-once or whatever
1152 emptyTvSubstEnv :: TvSubstEnv
1153 emptyTvSubstEnv = emptyVarEnv
1154
1155 composeTvSubst :: InScopeSet -> TvSubstEnv -> TvSubstEnv -> TvSubstEnv
1156 -- (compose env1 env2)(x) is env1(env2(x)); i.e. apply env2 then env1
1157 -- It assumes that both are idempotent
1158 -- Typically, env1 is the refinement to a base substitution env2
1159 composeTvSubst in_scope env1 env2
1160   = env1 `plusVarEnv` mapVarEnv (substTy subst1) env2
1161         -- First apply env1 to the range of env2
1162         -- Then combine the two, making sure that env1 loses if
1163         -- both bind the same variable; that's why env1 is the
1164         --  *left* argument to plusVarEnv, because the right arg wins
1165   where
1166     subst1 = TvSubst in_scope env1
1167
1168 emptyTvSubst = TvSubst emptyInScopeSet emptyVarEnv
1169
1170 isEmptyTvSubst :: TvSubst -> Bool
1171          -- See Note [Extending the TvSubstEnv]
1172 isEmptyTvSubst (TvSubst _ env) = isEmptyVarEnv env
1173
1174 mkTvSubst :: InScopeSet -> TvSubstEnv -> TvSubst
1175 mkTvSubst = TvSubst
1176
1177 getTvSubstEnv :: TvSubst -> TvSubstEnv
1178 getTvSubstEnv (TvSubst _ env) = env
1179
1180 getTvInScope :: TvSubst -> InScopeSet
1181 getTvInScope (TvSubst in_scope _) = in_scope
1182
1183 isInScope :: Var -> TvSubst -> Bool
1184 isInScope v (TvSubst in_scope _) = v `elemInScopeSet` in_scope
1185
1186 notElemTvSubst :: TyVar -> TvSubst -> Bool
1187 notElemTvSubst tv (TvSubst _ env) = not (tv `elemVarEnv` env)
1188
1189 setTvSubstEnv :: TvSubst -> TvSubstEnv -> TvSubst
1190 setTvSubstEnv (TvSubst in_scope _) env = TvSubst in_scope env
1191
1192 extendTvInScope :: TvSubst -> [Var] -> TvSubst
1193 extendTvInScope (TvSubst in_scope env) vars = TvSubst (extendInScopeSetList in_scope vars) env
1194
1195 extendTvSubst :: TvSubst -> TyVar -> Type -> TvSubst
1196 extendTvSubst (TvSubst in_scope env) tv ty = TvSubst in_scope (extendVarEnv env tv ty)
1197
1198 extendTvSubstList :: TvSubst -> [TyVar] -> [Type] -> TvSubst
1199 extendTvSubstList (TvSubst in_scope env) tvs tys 
1200   = TvSubst in_scope (extendVarEnvList env (tvs `zip` tys))
1201
1202 -- mkOpenTvSubst and zipOpenTvSubst generate the in-scope set from
1203 -- the types given; but it's just a thunk so with a bit of luck
1204 -- it'll never be evaluated
1205
1206 mkOpenTvSubst :: TvSubstEnv -> TvSubst
1207 mkOpenTvSubst env = TvSubst (mkInScopeSet (tyVarsOfTypes (varEnvElts env))) env
1208
1209 zipOpenTvSubst :: [TyVar] -> [Type] -> TvSubst
1210 zipOpenTvSubst tyvars tys 
1211 #ifdef DEBUG
1212   | length tyvars /= length tys
1213   = pprTrace "zipOpenTvSubst" (ppr tyvars $$ ppr tys) emptyTvSubst
1214   | otherwise
1215 #endif
1216   = TvSubst (mkInScopeSet (tyVarsOfTypes tys)) (zipTyEnv tyvars tys)
1217
1218 -- mkTopTvSubst is called when doing top-level substitutions.
1219 -- Here we expect that the free vars of the range of the
1220 -- substitution will be empty.
1221 mkTopTvSubst :: [(TyVar, Type)] -> TvSubst
1222 mkTopTvSubst prs = TvSubst emptyInScopeSet (mkVarEnv prs)
1223
1224 zipTopTvSubst :: [TyVar] -> [Type] -> TvSubst
1225 zipTopTvSubst tyvars tys 
1226 #ifdef DEBUG
1227   | length tyvars /= length tys
1228   = pprTrace "zipTopTvSubst" (ppr tyvars $$ ppr tys) emptyTvSubst
1229   | otherwise
1230 #endif
1231   = TvSubst emptyInScopeSet (zipTyEnv tyvars tys)
1232
1233 zipTyEnv :: [TyVar] -> [Type] -> TvSubstEnv
1234 zipTyEnv tyvars tys
1235 #ifdef DEBUG
1236   | length tyvars /= length tys
1237   = pprTrace "mkTopTvSubst" (ppr tyvars $$ ppr tys) emptyVarEnv
1238   | otherwise
1239 #endif
1240   = zip_ty_env tyvars tys emptyVarEnv
1241
1242 -- Later substitutions in the list over-ride earlier ones, 
1243 -- but there should be no loops
1244 zip_ty_env []       []       env = env
1245 zip_ty_env (tv:tvs) (ty:tys) env = zip_ty_env tvs tys (extendVarEnv env tv ty)
1246         -- There used to be a special case for when 
1247         --      ty == TyVarTy tv
1248         -- (a not-uncommon case) in which case the substitution was dropped.
1249         -- But the type-tidier changes the print-name of a type variable without
1250         -- changing the unique, and that led to a bug.   Why?  Pre-tidying, we had 
1251         -- a type {Foo t}, where Foo is a one-method class.  So Foo is really a newtype.
1252         -- And it happened that t was the type variable of the class.  Post-tiding, 
1253         -- it got turned into {Foo t2}.  The ext-core printer expanded this using
1254         -- sourceTypeRep, but that said "Oh, t == t2" because they have the same unique,
1255         -- and so generated a rep type mentioning t not t2.  
1256         --
1257         -- Simplest fix is to nuke the "optimisation"
1258 zip_ty_env tvs      tys      env   = pprTrace "Var/Type length mismatch: " (ppr tvs $$ ppr tys) env
1259 -- zip_ty_env _ _ env = env
1260
1261 instance Outputable TvSubst where
1262   ppr (TvSubst ins env) 
1263     = brackets $ sep[ ptext SLIT("TvSubst"),
1264                       nest 2 (ptext SLIT("In scope:") <+> ppr ins), 
1265                       nest 2 (ptext SLIT("Env:") <+> ppr env) ]
1266 \end{code}
1267
1268 %************************************************************************
1269 %*                                                                      *
1270                 Performing type substitutions
1271 %*                                                                      *
1272 %************************************************************************
1273
1274 \begin{code}
1275 substTyWith :: [TyVar] -> [Type] -> Type -> Type
1276 substTyWith tvs tys = ASSERT( length tvs == length tys )
1277                       substTy (zipOpenTvSubst tvs tys)
1278
1279 substTy :: TvSubst -> Type  -> Type
1280 substTy subst ty | isEmptyTvSubst subst = ty
1281                  | otherwise            = subst_ty subst ty
1282
1283 substTys :: TvSubst -> [Type] -> [Type]
1284 substTys subst tys | isEmptyTvSubst subst = tys
1285                    | otherwise            = map (subst_ty subst) tys
1286
1287 substTheta :: TvSubst -> ThetaType -> ThetaType
1288 substTheta subst theta
1289   | isEmptyTvSubst subst = theta
1290   | otherwise            = map (substPred subst) theta
1291
1292 substPred :: TvSubst -> PredType -> PredType
1293 substPred subst (IParam n ty)     = IParam n (subst_ty subst ty)
1294 substPred subst (ClassP clas tys) = ClassP clas (map (subst_ty subst) tys)
1295 substPred subst (EqPred ty1 ty2)  = EqPred (subst_ty subst ty1) (subst_ty subst ty2)
1296
1297 deShadowTy :: TyVarSet -> Type -> Type  -- Remove any nested binders mentioning tvs
1298 deShadowTy tvs ty 
1299   = subst_ty (mkTvSubst in_scope emptyTvSubstEnv) ty
1300   where
1301     in_scope = mkInScopeSet tvs
1302
1303 subst_ty :: TvSubst -> Type -> Type
1304 -- subst_ty is the main workhorse for type substitution
1305 --
1306 -- Note that the in_scope set is poked only if we hit a forall
1307 -- so it may often never be fully computed 
1308 subst_ty subst ty
1309    = go ty
1310   where
1311     go (TyVarTy tv)                = substTyVar subst tv
1312     go (TyConApp tc tys)           = let args = map go tys
1313                                      in  args `seqList` TyConApp tc args
1314
1315     go (PredTy p)                  = PredTy $! (substPred subst p)
1316
1317     go (NoteTy (FTVNote _) ty2)    = go ty2             -- Discard the free tyvar note
1318
1319     go (FunTy arg res)             = (FunTy $! (go arg)) $! (go res)
1320     go (AppTy fun arg)             = mkAppTy (go fun) $! (go arg)
1321                 -- The mkAppTy smart constructor is important
1322                 -- we might be replacing (a Int), represented with App
1323                 -- by [Int], represented with TyConApp
1324     go (ForAllTy tv ty)            = case substTyVarBndr subst tv of
1325                                         (subst', tv') -> ForAllTy tv' $! (subst_ty subst' ty)
1326
1327 substTyVar :: TvSubst -> TyVar  -> Type
1328 substTyVar subst@(TvSubst in_scope env) tv
1329   = case lookupTyVar subst tv of {
1330         Nothing -> TyVarTy tv;
1331         Just ty -> ty   -- See Note [Apply Once]
1332     } 
1333
1334 substTyVars :: TvSubst -> [TyVar] -> [Type]
1335 substTyVars subst tvs = map (substTyVar subst) tvs
1336
1337 lookupTyVar :: TvSubst -> TyVar  -> Maybe Type
1338         -- See Note [Extending the TvSubst]
1339 lookupTyVar (TvSubst in_scope env) tv = lookupVarEnv env tv
1340
1341 substTyVarBndr :: TvSubst -> TyVar -> (TvSubst, TyVar)  
1342 substTyVarBndr subst@(TvSubst in_scope env) old_var
1343   = (TvSubst (in_scope `extendInScopeSet` new_var) new_env, new_var)
1344   where
1345     is_co_var = isCoVar old_var
1346
1347     new_env | no_change = delVarEnv env old_var
1348             | otherwise = extendVarEnv env old_var (TyVarTy new_var)
1349
1350     no_change = new_var == old_var && not is_co_var
1351         -- no_change means that the new_var is identical in
1352         -- all respects to the old_var (same unique, same kind)
1353         -- See Note [Extending the TvSubst]
1354         --
1355         -- In that case we don't need to extend the substitution
1356         -- to map old to new.  But instead we must zap any 
1357         -- current substitution for the variable. For example:
1358         --      (\x.e) with id_subst = [x |-> e']
1359         -- Here we must simply zap the substitution for x
1360
1361     new_var = uniqAway in_scope subst_old_var
1362         -- The uniqAway part makes sure the new variable is not already in scope
1363
1364     subst_old_var -- subst_old_var is old_var with the substitution applied to its kind
1365                   -- It's only worth doing the substitution for coercions,
1366                   -- becuase only they can have free type variables
1367         | is_co_var = setTyVarKind old_var (substTy subst (tyVarKind old_var))
1368         | otherwise = old_var
1369 \end{code}
1370
1371 ----------------------------------------------------
1372 -- Kind Stuff
1373
1374 Kinds
1375 ~~~~~
1376 There's a little subtyping at the kind level:  
1377
1378                  ?
1379                 / \
1380                /   \
1381               ??   (#)
1382              /  \
1383             *   #
1384
1385 where   *    [LiftedTypeKind]   means boxed type
1386         #    [UnliftedTypeKind] means unboxed type
1387         (#)  [UbxTupleKind]     means unboxed tuple
1388         ??   [ArgTypeKind]      is the lub of *,#
1389         ?    [OpenTypeKind]     means any type at all
1390
1391 In particular:
1392
1393         error :: forall a:?. String -> a
1394         (->)  :: ?? -> ? -> *
1395         (\(x::t) -> ...)        Here t::?? (i.e. not unboxed tuple)
1396
1397 \begin{code}
1398 type KindVar = TyVar  -- invariant: KindVar will always be a 
1399                       -- TcTyVar with details MetaTv TauTv ...
1400 -- kind var constructors and functions are in TcType
1401
1402 type SimpleKind = Kind
1403 \end{code}
1404
1405 Kind inference
1406 ~~~~~~~~~~~~~~
1407 During kind inference, a kind variable unifies only with 
1408 a "simple kind", sk
1409         sk ::= * | sk1 -> sk2
1410 For example 
1411         data T a = MkT a (T Int#)
1412 fails.  We give T the kind (k -> *), and the kind variable k won't unify
1413 with # (the kind of Int#).
1414
1415 Type inference
1416 ~~~~~~~~~~~~~~
1417 When creating a fresh internal type variable, we give it a kind to express 
1418 constraints on it.  E.g. in (\x->e) we make up a fresh type variable for x, 
1419 with kind ??.  
1420
1421 During unification we only bind an internal type variable to a type
1422 whose kind is lower in the sub-kind hierarchy than the kind of the tyvar.
1423
1424 When unifying two internal type variables, we collect their kind constraints by
1425 finding the GLB of the two.  Since the partial order is a tree, they only
1426 have a glb if one is a sub-kind of the other.  In that case, we bind the
1427 less-informative one to the more informative one.  Neat, eh?
1428
1429
1430 \begin{code}
1431
1432 \end{code}
1433
1434 %************************************************************************
1435 %*                                                                      *
1436         Functions over Kinds            
1437 %*                                                                      *
1438 %************************************************************************
1439
1440 \begin{code}
1441 kindFunResult :: Kind -> Kind
1442 kindFunResult k = funResultTy k
1443
1444 splitKindFunTys :: Kind -> ([Kind],Kind)
1445 splitKindFunTys k = splitFunTys k
1446
1447 splitKindFunTysN :: Int -> Kind -> ([Kind],Kind)
1448 splitKindFunTysN k = splitFunTysN k
1449
1450 isUbxTupleKind, isOpenTypeKind, isArgTypeKind, isUnliftedTypeKind :: Kind -> Bool
1451
1452 isOpenTypeKindCon tc    = tyConUnique tc == openTypeKindTyConKey
1453
1454 isOpenTypeKind (TyConApp tc _) = isOpenTypeKindCon tc
1455 isOpenTypeKind other           = False
1456
1457 isUbxTupleKindCon tc = tyConUnique tc == ubxTupleKindTyConKey
1458
1459 isUbxTupleKind (TyConApp tc _) = isUbxTupleKindCon tc
1460 isUbxTupleKind other           = False
1461
1462 isArgTypeKindCon tc = tyConUnique tc == argTypeKindTyConKey
1463
1464 isArgTypeKind (TyConApp tc _) = isArgTypeKindCon tc
1465 isArgTypeKind other = False
1466
1467 isUnliftedTypeKindCon tc = tyConUnique tc == unliftedTypeKindTyConKey
1468
1469 isUnliftedTypeKind (TyConApp tc _) = isUnliftedTypeKindCon tc
1470 isUnliftedTypeKind other           = False
1471
1472 isSubOpenTypeKind :: Kind -> Bool
1473 -- True of any sub-kind of OpenTypeKind (i.e. anything except arrow)
1474 isSubOpenTypeKind (FunTy k1 k2)    = ASSERT2 ( isKind k1, text "isSubOpenTypeKind" <+> ppr k1 <+> text "::" <+> ppr (typeKind k1) ) 
1475                                      ASSERT2 ( isKind k2, text "isSubOpenTypeKind" <+> ppr k2 <+> text "::" <+> ppr (typeKind k2) ) 
1476                                      False
1477 isSubOpenTypeKind (TyConApp kc []) = ASSERT( isKind (TyConApp kc []) ) True
1478 isSubOpenTypeKind other            = ASSERT( isKind other ) False
1479          -- This is a conservative answer
1480          -- It matters in the call to isSubKind in
1481          -- checkExpectedKind.
1482
1483 isSubArgTypeKindCon kc
1484   | isUnliftedTypeKindCon kc = True
1485   | isLiftedTypeKindCon kc   = True
1486   | isArgTypeKindCon kc      = True
1487   | otherwise                = False
1488
1489 isSubArgTypeKind :: Kind -> Bool
1490 -- True of any sub-kind of ArgTypeKind 
1491 isSubArgTypeKind (TyConApp kc []) = isSubArgTypeKindCon kc
1492 isSubArgTypeKind other            = False
1493
1494 isSuperKind :: Type -> Bool
1495 isSuperKind (TyConApp (skc) []) = isSuperKindTyCon skc
1496 isSuperKind other = False
1497
1498 isKind :: Kind -> Bool
1499 isKind k = isSuperKind (typeKind k)
1500
1501
1502
1503 isSubKind :: Kind -> Kind -> Bool
1504 -- (k1 `isSubKind` k2) checks that k1 <: k2
1505 isSubKind (TyConApp kc1 []) (TyConApp kc2 []) = kc1 `isSubKindCon` kc2
1506 isSubKind (FunTy a1 r1) (FunTy a2 r2)         = (a2 `isSubKind` a1) && (r1 `isSubKind` r2)
1507 isSubKind (PredTy (EqPred ty1 ty2)) (PredTy (EqPred ty1' ty2')) 
1508   = ty1 `tcEqType` ty1' && ty2 `tcEqType` ty2'
1509 isSubKind k1            k2                    = False
1510
1511 eqKind :: Kind -> Kind -> Bool
1512 eqKind = tcEqType
1513
1514 isSubKindCon :: TyCon -> TyCon -> Bool
1515 -- (kc1 `isSubKindCon` kc2) checks that kc1 <: kc2
1516 isSubKindCon kc1 kc2
1517   | isLiftedTypeKindCon kc1   && isLiftedTypeKindCon kc2   = True
1518   | isUnliftedTypeKindCon kc1 && isUnliftedTypeKindCon kc2 = True
1519   | isUbxTupleKindCon kc1     && isUbxTupleKindCon kc2     = True
1520   | isOpenTypeKindCon kc2                                  = True 
1521                            -- we already know kc1 is not a fun, its a TyCon
1522   | isArgTypeKindCon kc2      && isSubArgTypeKindCon kc1   = True
1523   | otherwise                                              = False
1524
1525 defaultKind :: Kind -> Kind
1526 -- Used when generalising: default kind '?' and '??' to '*'
1527 -- 
1528 -- When we generalise, we make generic type variables whose kind is
1529 -- simple (* or *->* etc).  So generic type variables (other than
1530 -- built-in constants like 'error') always have simple kinds.  This is important;
1531 -- consider
1532 --      f x = True
1533 -- We want f to get type
1534 --      f :: forall (a::*). a -> Bool
1535 -- Not 
1536 --      f :: forall (a::??). a -> Bool
1537 -- because that would allow a call like (f 3#) as well as (f True),
1538 --and the calling conventions differ.  This defaulting is done in TcMType.zonkTcTyVarBndr.
1539 defaultKind k 
1540   | isSubOpenTypeKind k = liftedTypeKind
1541   | isSubArgTypeKind k  = liftedTypeKind
1542   | otherwise        = k
1543
1544 isEqPred :: PredType -> Bool
1545 isEqPred (EqPred _ _) = True
1546 isEqPred other        = False
1547 \end{code}