Remove nhc98-specific files and content
[ghc.git] / libraries / base / Data / Traversable.hs
1 {-# LANGUAGE Trustworthy #-}
2 {-# LANGUAGE CPP #-}
3
4 -----------------------------------------------------------------------------
5 -- |
6 -- Module : Data.Traversable
7 -- Copyright : Conor McBride and Ross Paterson 2005
8 -- License : BSD-style (see the LICENSE file in the distribution)
9 --
10 -- Maintainer : libraries@haskell.org
11 -- Stability : experimental
12 -- Portability : portable
13 --
14 -- Class of data structures that can be traversed from left to right,
15 -- performing an action on each element.
16 --
17 -- See also
18 --
19 -- * \"Applicative Programming with Effects\",
20 -- by Conor McBride and Ross Paterson,
21 -- /Journal of Functional Programming/ 18:1 (2008) 1-13, online at
22 -- <http://www.soi.city.ac.uk/~ross/papers/Applicative.html>.
23 --
24 -- * \"The Essence of the Iterator Pattern\",
25 -- by Jeremy Gibbons and Bruno Oliveira,
26 -- in /Mathematically-Structured Functional Programming/, 2006, online at
27 -- <http://web.comlab.ox.ac.uk/oucl/work/jeremy.gibbons/publications/#iterator>.
28 --
29 -- * \"An Investigation of the Laws of Traversals\",
30 -- by Mauro Jaskelioff and Ondrej Rypacek,
31 -- in /Mathematically-Structured Functional Programming/, 2012, online at
32 -- <http://arxiv.org/pdf/1202.2919>.
33 --
34 -- Note that the functions 'mapM' and 'sequence' generalize "Prelude"
35 -- functions of the same names from lists to any 'Traversable' functor.
36 -- To avoid ambiguity, either import the "Prelude" hiding these names
37 -- or qualify uses of these function names with an alias for this module.
38 --
39 -----------------------------------------------------------------------------
40
41 module Data.Traversable (
42 -- * The 'Traversable' class
43 Traversable(..),
44 -- * Utility functions
45 for,
46 forM,
47 mapAccumL,
48 mapAccumR,
49 -- * General definitions for superclass methods
50 fmapDefault,
51 foldMapDefault,
52 ) where
53
54 import Prelude hiding (mapM, sequence, foldr)
55 import qualified Prelude (mapM, foldr)
56 import Control.Applicative
57 import Data.Foldable (Foldable())
58 import Data.Monoid (Monoid)
59
60 #if defined(__GLASGOW_HASKELL__)
61 import GHC.Arr
62 #elif defined(__HUGS__)
63 import Hugs.Array
64 #endif
65
66 -- | Functors representing data structures that can be traversed from
67 -- left to right.
68 --
69 -- Minimal complete definition: 'traverse' or 'sequenceA'.
70 --
71 -- A definition of 'traverse' must satisfy the following laws:
72 --
73 -- [/naturality/]
74 -- @t . 'traverse' f = 'traverse' (t . f)@
75 -- for every applicative transformation @t@
76 --
77 -- [/identity/]
78 -- @'traverse' Identity = Identity@
79 --
80 -- [/composition/]
81 -- @'traverse' (Compose . 'fmap' g . f) = Compose . 'fmap' ('traverse' g) . 'traverse' f@
82 --
83 -- A definition of 'sequenceA' must satisfy the following laws:
84 --
85 -- [/naturality/]
86 -- @t . 'sequenceA' = 'sequenceA' . 'fmap' t@
87 -- for every applicative transformation @t@
88 --
89 -- [/identity/]
90 -- @'sequenceA' . 'fmap' Identity = Identity@
91 --
92 -- [/composition/]
93 -- @'sequenceA' . 'fmap' Compose = Compose . 'fmap' 'sequenceA' . 'sequenceA'@
94 --
95 -- where an /applicative transformation/ is a function
96 --
97 -- @t :: (Applicative f, Applicative g) => f a -> g a@
98 --
99 -- preserving the 'Applicative' operations, i.e.
100 --
101 -- * @t ('pure' x) = 'pure' x@
102 --
103 -- * @t (x '<*>' y) = t x '<*>' t y@
104 --
105 -- and the identity functor @Identity@ and composition of functors @Compose@
106 -- are defined as
107 --
108 -- > newtype Identity a = Identity a
109 -- >
110 -- > instance Functor Identity where
111 -- > fmap f (Identity x) = Identity (f x)
112 -- >
113 -- > instance Applicative Indentity where
114 -- > pure x = Identity x
115 -- > Identity f <*> Identity x = Identity (f x)
116 -- >
117 -- > newtype Compose f g a = Compose (f (g a))
118 -- >
119 -- > instance (Functor f, Functor g) => Functor (Compose f g) where
120 -- > fmap f (Compose x) = Compose (fmap (fmap f) x)
121 -- >
122 -- > instance (Applicative f, Applicative g) => Applicative (Compose f g) where
123 -- > pure x = Compose (pure (pure x))
124 -- > Compose f <*> Compose x = Compose ((<*>) <$> f <*> x)
125 --
126 -- (The naturality law is implied by parametricity.)
127 --
128 -- Instances are similar to 'Functor', e.g. given a data type
129 --
130 -- > data Tree a = Empty | Leaf a | Node (Tree a) a (Tree a)
131 --
132 -- a suitable instance would be
133 --
134 -- > instance Traversable Tree where
135 -- > traverse f Empty = pure Empty
136 -- > traverse f (Leaf x) = Leaf <$> f x
137 -- > traverse f (Node l k r) = Node <$> traverse f l <*> f k <*> traverse f r
138 --
139 -- This is suitable even for abstract types, as the laws for '<*>'
140 -- imply a form of associativity.
141 --
142 -- The superclass instances should satisfy the following:
143 --
144 -- * In the 'Functor' instance, 'fmap' should be equivalent to traversal
145 -- with the identity applicative functor ('fmapDefault').
146 --
147 -- * In the 'Foldable' instance, 'Data.Foldable.foldMap' should be
148 -- equivalent to traversal with a constant applicative functor
149 -- ('foldMapDefault').
150 --
151 class (Functor t, Foldable t) => Traversable t where
152 -- | Map each element of a structure to an action, evaluate
153 -- these actions from left to right, and collect the results.
154 traverse :: Applicative f => (a -> f b) -> t a -> f (t b)
155 traverse f = sequenceA . fmap f
156
157 -- | Evaluate each action in the structure from left to right,
158 -- and collect the results.
159 sequenceA :: Applicative f => t (f a) -> f (t a)
160 sequenceA = traverse id
161
162 -- | Map each element of a structure to a monadic action, evaluate
163 -- these actions from left to right, and collect the results.
164 mapM :: Monad m => (a -> m b) -> t a -> m (t b)
165 mapM f = unwrapMonad . traverse (WrapMonad . f)
166
167 -- | Evaluate each monadic action in the structure from left to right,
168 -- and collect the results.
169 sequence :: Monad m => t (m a) -> m (t a)
170 sequence = mapM id
171
172 -- instances for Prelude types
173
174 instance Traversable Maybe where
175 traverse _ Nothing = pure Nothing
176 traverse f (Just x) = Just <$> f x
177
178 instance Traversable [] where
179 {-# INLINE traverse #-} -- so that traverse can fuse
180 traverse f = Prelude.foldr cons_f (pure [])
181 where cons_f x ys = (:) <$> f x <*> ys
182
183 mapM = Prelude.mapM
184
185 instance Ix i => Traversable (Array i) where
186 traverse f arr = listArray (bounds arr) `fmap` traverse f (elems arr)
187
188 -- general functions
189
190 -- | 'for' is 'traverse' with its arguments flipped.
191 for :: (Traversable t, Applicative f) => t a -> (a -> f b) -> f (t b)
192 {-# INLINE for #-}
193 for = flip traverse
194
195 -- | 'forM' is 'mapM' with its arguments flipped.
196 forM :: (Traversable t, Monad m) => t a -> (a -> m b) -> m (t b)
197 {-# INLINE forM #-}
198 forM = flip mapM
199
200 -- left-to-right state transformer
201 newtype StateL s a = StateL { runStateL :: s -> (s, a) }
202
203 instance Functor (StateL s) where
204 fmap f (StateL k) = StateL $ \ s -> let (s', v) = k s in (s', f v)
205
206 instance Applicative (StateL s) where
207 pure x = StateL (\ s -> (s, x))
208 StateL kf <*> StateL kv = StateL $ \ s ->
209 let (s', f) = kf s
210 (s'', v) = kv s'
211 in (s'', f v)
212
213 -- |The 'mapAccumL' function behaves like a combination of 'fmap'
214 -- and 'foldl'; it applies a function to each element of a structure,
215 -- passing an accumulating parameter from left to right, and returning
216 -- a final value of this accumulator together with the new structure.
217 mapAccumL :: Traversable t => (a -> b -> (a, c)) -> a -> t b -> (a, t c)
218 mapAccumL f s t = runStateL (traverse (StateL . flip f) t) s
219
220 -- right-to-left state transformer
221 newtype StateR s a = StateR { runStateR :: s -> (s, a) }
222
223 instance Functor (StateR s) where
224 fmap f (StateR k) = StateR $ \ s -> let (s', v) = k s in (s', f v)
225
226 instance Applicative (StateR s) where
227 pure x = StateR (\ s -> (s, x))
228 StateR kf <*> StateR kv = StateR $ \ s ->
229 let (s', v) = kv s
230 (s'', f) = kf s'
231 in (s'', f v)
232
233 -- |The 'mapAccumR' function behaves like a combination of 'fmap'
234 -- and 'foldr'; it applies a function to each element of a structure,
235 -- passing an accumulating parameter from right to left, and returning
236 -- a final value of this accumulator together with the new structure.
237 mapAccumR :: Traversable t => (a -> b -> (a, c)) -> a -> t b -> (a, t c)
238 mapAccumR f s t = runStateR (traverse (StateR . flip f) t) s
239
240 -- | This function may be used as a value for `fmap` in a `Functor`
241 -- instance, provided that 'traverse' is defined. (Using
242 -- `fmapDefault` with a `Traversable` instance defined only by
243 -- 'sequenceA' will result in infinite recursion.)
244 fmapDefault :: Traversable t => (a -> b) -> t a -> t b
245 {-# INLINE fmapDefault #-}
246 fmapDefault f = getId . traverse (Id . f)
247
248 -- | This function may be used as a value for `Data.Foldable.foldMap`
249 -- in a `Foldable` instance.
250 foldMapDefault :: (Traversable t, Monoid m) => (a -> m) -> t a -> m
251 foldMapDefault f = getConst . traverse (Const . f)
252
253 -- local instances
254
255 newtype Id a = Id { getId :: a }
256
257 instance Functor Id where
258 fmap f (Id x) = Id (f x)
259
260 instance Applicative Id where
261 pure = Id
262 Id f <*> Id x = Id (f x)
263