Fix incorrectly hidden RTS symbols
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2004
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [6.11], [glasgow-haskell-bugs@haskell.org], [ghc])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 6.7.20070204).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # darcs repository.  If this is a source distribution (not a darcs
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'sh boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands, 
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42
43 dnl ** Find sort command (for the benefit of Win32 environs)
44 FP_PROG_SORT
45
46 dnl ----------------------------------------------------------
47 FP_SETUP_PROJECT_VERSION
48
49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
50 AC_SUBST([release], [1])
51
52 # First off, a distrib sanity check..
53 AC_CONFIG_SRCDIR([mk/config.mk.in])
54
55 dnl * We require autoconf version 2.52
56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
58 AC_PREREQ([2.52])
59
60 # -------------------------------------------------------------------------
61 # Prepare to generate the following header files
62 #
63 #
64 AC_CONFIG_HEADER(mk/config.h)
65
66 # No, semi-sadly, we don't do `--srcdir'...
67 if test x"$srcdir" != 'x.' ; then
68     echo "This configuration does not support the \`--srcdir' option.."
69     exit 1
70 fi
71
72 dnl --------------------------------------------------------------
73 dnl * Project specific configuration options
74 dnl --------------------------------------------------------------
75 dnl What follows is a bunch of options that can either be configured
76 dnl through command line options to the configure script or by
77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
78 dnl use either is considered a Feature.
79
80 dnl ** What command to use to compile compiler sources ?
81 dnl --------------------------------------------------------------
82
83 AC_ARG_WITH([ghc],
84 [AC_HELP_STRING([--with-ghc=ARG],
85   [Use ARG as the path to GHC  [default=autodetect]])],
86   [WithGhc="$withval"],
87   [if test "$GHC" = ""; then
88     AC_PATH_PROG([GHC], [ghc])
89   fi
90   WithGhc="$GHC"])
91
92 dnl ** Booting from .hc files?
93 dnl --------------------------------------------------------------
94 AC_ARG_ENABLE(hc-boot,
95 [AC_HELP_STRING([--enable-hc-boot],
96 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
97  (This option is mostly of interest to porters.) [default=no]])],
98 [ if test x"$enableval" = x"yes"; then
99         BootingFromHc=YES
100   else
101         BootingFromHc=NO
102   fi
103 ],
104 [BootingFromHc=NO]
105 )
106 AC_SUBST(BootingFromHc)
107
108 dnl ** Booting from unregisterised .hc files?
109 dnl --------------------------------------------------------------
110 AC_ARG_ENABLE(hc-boot-unregisterised,
111 [AC_HELP_STRING([--enable-hc-boot-unregisterised],
112 [ With --enable-hc-boot, treat the intermediate .hc files as
113  unregisterised rather than registerised code.
114  (This option is mostly of interest to porters.) [default=no]])],
115 [ if test x"$enableval" = x"yes"; then
116         BootingFromUnregisterisedHc=YES
117   else
118         BootingFromUnregisterisedHc=NO
119   fi
120 ],
121 [BootingFromUnregisterisedHc=NO]
122 )
123 AC_SUBST(BootingFromUnregisterisedHc)
124
125 if test "$BootingFromHc" = "NO"; then
126 if test "$BootingFromUnregisterisedHc" = "YES"; then
127 AC_MSG_ERROR([--enable-hc-boot-unregisterised requires --enable-hc-boot.])
128 fi;
129 fi;
130
131 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
132 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
133                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
134         EnableBootstrapWithDevelSnaphost=YES,
135         EnableBootstrapWithDevelSnaphost=NO
136 )
137
138 if test "$WithGhc" != ""; then
139   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
140
141   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
142      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
143   fi
144
145   AC_SUBST(GhcVersion)dnl
146   AC_SUBST(GhcMajVersion)dnl
147   AC_SUBST(GhcMinVersion)dnl
148   AC_SUBST(GhcPatchLevel)dnl
149   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
150   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
151   if test $GhcCanonVersion -ge 609; then ghc_ge_609=YES; else ghc_ge_609=NO; fi
152   AC_SUBST(ghc_ge_609)dnl
153 fi
154
155 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
156 if test "$BootingFromHc" = "NO" -a -d "$srcdir/compiler"; then
157   if test "$WithGhc" = ""; then
158      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
159   fi
160   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.8],
161     [AC_MSG_ERROR([GHC version 6.8 or later is required to compile GHC.])])dnl
162
163   if test `expr $GhcMinVersion % 2` = "1"; then
164      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
165         AC_MSG_ERROR([
166      $WithGhc is a development snapshot of GHC, version $GhcVersion.
167      Bootstrapping using this version of GHC is not supported, and may not
168      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
169      or --with-ghc to specify a different GHC to use.])
170      fi
171   fi
172 fi;
173
174 # GHC is passed to Cabal, so we need a native path
175 if test "${WithGhc}" != ""
176 then
177     ghc_host=`${WithGhc} +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
178
179     if test "$ghc_host" = "i386-unknown-mingw32"
180     then
181         if test "${OSTYPE}" = "msys"
182         then
183             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
184         else
185             # Canonicalise to <drive>:/path/to/ghc
186             WithGhc=`cygpath -m ${WithGhc}`
187         fi
188         echo "GHC path canonicalised to: ${WithGhc}"
189     fi
190 fi
191 AC_SUBST([WithGhc])
192
193 dnl ** Without optimization some INLINE trickery fails for GHCi
194 SRC_CC_OPTS="-O"
195
196 dnl Allow to specify iconv options to the toplevel configure script
197 dnl so they can be properly passed to sub-builds.
198 dnl Note: ICONV_LIB_DIRS and ICONV_INCLUDE_DIRS are not predefined
199 dnl to the empty string to allow them to be overridden from the
200 dnl environment.
201
202 AC_ARG_WITH([iconv-includes],
203   [AC_HELP_STRING([--with-iconv-includes],
204     [directory containing iconv.h])],
205     [ICONV_INCLUDE_DIRS=$withval])
206
207 AC_ARG_WITH([iconv-libraries],
208   [AC_HELP_STRING([--with-iconv-libraries],
209     [directory containing iconv library])],
210     [ICONV_LIB_DIRS=$withval])
211
212 AC_SUBST(ICONV_INCLUDE_DIRS)
213 AC_SUBST(ICONV_LIB_DIRS)
214
215 dnl--------------------------------------------------------------------
216 dnl * Choose host(/target/build) platform
217 dnl--------------------------------------------------------------------
218 dnl We don't use the standard autoconf macros for this, but instead
219 dnl ask the bootstrapping compiler what platform it is for
220
221 dnl Guess host/target/build platform(s) if necessary.
222 m4_divert_once([HELP_CANON],
223 [[
224 System types:
225   --build=BUILD     configure for building on BUILD [guessed]
226   --host=HOST       cross-compile to build programs to run on HOST [guessed]
227   --target=TARGET   configure for building compilers for TARGET [guessed]]])dnl
228
229 if test "$build" = ""
230 then
231     if test "${WithGhc}" != ""
232     then
233         build=`${WithGhc} +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
234         echo "Build platform inferred as: $build"
235     else
236         echo "Can't work out build platform"
237         exit 1
238     fi
239 fi
240
241 if test "$host" = ""
242 then
243     if test "${WithGhc}" != ""
244     then
245         host=`${WithGhc} +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
246         echo "Host platform inferred as: $host"
247     else
248         echo "Can't work out host platform"
249         exit 1
250     fi
251 fi
252
253 if test "$target" = ""
254 then
255     if test "${WithGhc}" != ""
256     then
257         target=`${WithGhc} +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
258         echo "Target platform inferred as: $target"
259     else
260         echo "Can't work out target platform"
261         exit 1
262     fi
263 fi
264
265 exeext=''
266 soext='.so'
267 case $host in
268 *-unknown-cygwin32)
269     AC_MSG_WARN([GHC does not support the Cygwin target at the moment])
270     AC_MSG_WARN([I'm assuming you wanted to build for i386-unknown-mingw32])
271     exit 1
272     ;;
273 *-unknown-mingw32)
274     exeext='.exe'
275     soext='.dll'
276     ;;
277 i386-apple-darwin|powerpc-apple-darwin)
278     soext='.dylib'
279     CFLAGS="$CFLAGS -m32"
280     LDFLAGS="$LDFLAGS -m32"
281     SRC_CC_OPTS="$SRC_CC_OPTS -m32"
282     SRC_LD_OPTS="$SRC_LD_OPTS -m32"
283     ;;
284 x86_64-apple-darwin)
285     soext='.dylib'
286     CFLAGS="$CFLAGS -m64"
287     LDFLAGS="$LDFLAGS -m64"
288     SRC_CC_OPTS="$SRC_CC_OPTS -m64"
289     SRC_LD_OPTS="$SRC_LD_OPTS -m64"
290     ;;
291 esac
292
293 checkArch() {
294     case $1 in
295     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
296         ;;
297     *)
298         echo "Unknown arch $1"
299         exit 1
300         ;;
301     esac
302 }
303
304 checkVendor() {
305     case $1 in
306     dec|unknown|hp|apple|next|sun|sgi|ibm)
307         ;;
308     *)
309         echo "Unknown vendor $1"
310         exit 1
311         ;;
312     esac
313 }
314
315 checkOS() {
316     case $1 in
317     linux|freebsd|netbsd|openbsd|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix)
318         ;;
319     *)
320         echo "Unknown OS '$1'"
321         exit 1
322         ;;
323     esac
324 }
325
326 BuildPlatform=$build
327 BuildArch=`echo "$build" | sed 's/-.*//'`
328 BuildVendor=`echo "$build" | sed -e 's/.*-\(.*\)-.*/\1/'`
329 BuildOS=`echo "$build" | sed 's/.*-//'`
330 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
331 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
332 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
333 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
334
335 checkArch "$BuildArch"
336 checkVendor "$BuildVendor"
337 checkOS "$BuildOS"
338
339 HostPlatform=$host
340 HostArch=`echo "$host" | sed 's/-.*//'`
341 HostVendor=`echo "$host" | sed -e 's/.*-\(.*\)-.*/\1/'`
342 HostOS=`echo "$host" | sed 's/.*-//'`
343 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
344 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
345 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
346 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
347
348 checkArch "$HostArch"
349 checkVendor "$HostVendor"
350 checkOS "$HostOS"
351
352 TargetPlatform=$target
353 TargetArch=`echo "$target" | sed 's/-.*//'`
354 TargetVendor=`echo "$target" | sed -e 's/.*-\(.*\)-.*/\1/'`
355 TargetOS=`echo "$target" | sed 's/.*-//'`
356 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
357 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
358 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
359 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
360
361 checkArch "$TargetArch"
362 checkVendor "$TargetVendor"
363 checkOS "$TargetOS"
364
365 AC_SUBST(BuildPlatform)
366 AC_SUBST(HostPlatform)
367 AC_SUBST(TargetPlatform)
368 AC_SUBST(HostPlatform_CPP)
369 AC_SUBST(BuildPlatform_CPP)
370 AC_SUBST(TargetPlatform_CPP)
371
372 AC_SUBST(HostArch_CPP)
373 AC_SUBST(BuildArch_CPP)
374 AC_SUBST(TargetArch_CPP)
375
376 AC_SUBST(HostOS_CPP)
377 AC_SUBST(BuildOS_CPP)
378 AC_SUBST(TargetOS_CPP)
379
380 AC_SUBST(HostVendor_CPP)
381 AC_SUBST(BuildVendor_CPP)
382 AC_SUBST(TargetVendor_CPP)
383
384 AC_SUBST(exeext)
385 AC_SUBST(soext)
386
387 AC_ARG_WITH(hc,
388 [AC_HELP_STRING([--with-hc=ARG],
389         [Use ARG as the path to the compiler for compiling ordinary
390          Haskell code  (default= value of --with-ghc)])],
391 [WithHc="$withval"],
392 [WithHc=$WithGhc]
393 )
394 AC_SUBST(WithHc)
395
396 AC_PATH_PROGS(NHC,nhc nhc98)
397 AC_PATH_PROG(HBC,hbc)
398
399 dnl ** Which gcc to use?
400 dnl --------------------------------------------------------------
401 AC_ARG_WITH(gcc,
402 [AC_HELP_STRING([--with-gcc=ARG],
403         [Use ARG as the path to GCC  [default=autodetect]])],
404 [WhatGccIsCalled="$withval"
405  if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
406     test "${OSTYPE}"      != "msys"                  && \
407     test "${withval}"     != ""
408  then
409      # Canonicalise to <drive>:/path/to/gcc
410      withval=`cygpath -m ${withval}`
411  fi;
412  CC="$withval"
413  export CC
414  ],
415 [WhatGccIsCalled="gcc"]
416 )
417 AC_SUBST(WhatGccIsCalled)
418
419 dnl ** Which ld to use?
420 dnl --------------------------------------------------------------
421 AC_ARG_WITH(ld,
422 [AC_HELP_STRING([--with-ld=ARG],
423         [Use ARG as the path to LD  [default=autodetect]])],
424 [if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
425     test "${OSTYPE}"      != "msys"                  && \
426     test "${withval}"     != ""
427  then
428      # Canonicalise to <drive>:/path/to/ld
429      withval=`cygpath -m ${withval}`
430  fi;
431  LD=$withval
432  FP_PROG_LD([$LD])
433  ],
434  [FP_PROG_LD()]
435 )
436
437 # This uses GHC, so put it after the "GHC is required" check above:
438 FP_FIND_ROOT
439
440 dnl ** Enable the construction of Win32 DLLs?
441 dnl --------------------------------------------------------------
442 dnl
443 dnl [ The ability to build the RTS and libraries as separate DLLs used
444 dnl   to be supported, but isn't currently (updates to the RTS, compiler
445 dnl   and build system would be required to bring it back again.)
446 dnl   Hence, exposing it as an option is false advertisement, so better
447 dnl   disable it to avoid confusion (but leave it commented-out rather
448 dnl   than removed in order to remind ourselves to bring back the
449 dnl   feature at some stage.) ]
450 dnl
451 dnl AC_ARG_ENABLE(win32-dlls,
452 dnl [  --enable-win32-dlls
453 dnl         If on a Win32 platform running mingw32/cygwin, enable the
454 dnl         construction of DLLs containing ghc-compiled code.
455 dnl ],
456 dnl [
457 dnl case $HostOS_CPP in
458 dnl cygwin32) ;;
459 dnl mingw32)  ;;
460 dnl *)    echo "Unrecognised win32 platform: $HostPlatform"
461 dnl       exit 1
462 dnl       ;;
463 dnl esac
464 dnl EnableWin32DLLs=YES
465 dnl ],
466 dnl [EnableWin32DLLs=NO]
467 dnl )
468 dnl AC_SUBST(EnableWin32DLLs)
469 dnl if test x"$EnableWin32DLLs" = "xYES" ; then
470 dnl  AC_DEFINE(HAVE_WIN32_DLL_SUPPORT)
471 dnl fi
472
473 dnl ** Mac OS X: explicit deployment target
474 dnl --------------------------------------------------------------
475 AC_ARG_WITH([macosx-deployment-target],
476 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
477         [Build for Mac OS VERSION and higher  (default= version of build host)])],
478 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
479  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
480    # ignore everywhere, but on Mac OS
481    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
482    FP_MACOSX_DEPLOYMENT_TARGET=none
483  fi],
484 [FP_MACOSX_DEPLOYMENT_TARGET=none]
485 )
486 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
487 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
488 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
489
490 dnl --------------------------------------------------------------
491 dnl End of configure script option section
492 dnl --------------------------------------------------------------
493
494
495 dnl --------------------------------------------------------------
496 dnl * General configuration checks
497 dnl --------------------------------------------------------------
498
499 dnl ** Can the unix package be built?
500 dnl --------------------------------------------------------------
501
502 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
503    GhcLibsWithUnix=NO
504 else
505    GhcLibsWithUnix=YES
506 fi
507 AC_SUBST([GhcLibsWithUnix])
508
509 dnl ** does #! work?
510 AC_SYS_INTERPRETER()
511
512 dnl ** look for `perl', but only in /bin on Windows
513 case $HostOS_CPP in
514 cygwin32|mingw32)
515       AC_CHECK_PROG(PerlCmd,perl,/bin/perl,,/bin)
516       if test -z "$PerlCmd"; then
517          echo "You must install the version of Perl shipped with GHC"
518          echo "(or a compatible one) in /bin."
519          exit 1
520       fi
521    ;;
522 *)
523    AC_PATH_PROG(PerlCmd,perl)
524    if test -z "$PerlCmd"; then
525       echo "You must install perl before you can continue"
526       echo "Perhaps it is already installed, but not in your PATH?"
527       exit 1
528    else
529    FPTOOLS_CHECK_PERL_VERSION
530    fi
531    ;;
532 esac
533
534 dnl ** does #! path/to/perl work? (sometimes it's too long...)
535 FPTOOLS_SHEBANG_PERL
536
537 dnl ** check for Python
538 AC_PATH_PROG(PythonCmd,python)
539
540 dnl ** look for GCC and find out which version
541 dnl     Figure out which C compiler to use.  Gcc is preferred.
542 dnl     If gcc, make sure it's at least 2.1
543 dnl
544 FP_HAVE_GCC
545 FP_MINGW_GCC
546 FP_GCC_EXTRA_FLAGS
547
548 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
549 AC_PROG_CPP
550
551 AC_SUBST(SRC_CC_OPTS)
552 AC_SUBST(SRC_LD_OPTS)
553
554 dnl ** figure out how to do context diffs
555 FP_PROG_CONTEXT_DIFF
556
557 dnl Let's make sure install-sh is executable here.  If we got it from
558 dnl a darcs repo, it might not be (see bug #978).
559 chmod +x install-sh
560 dnl ** figure out how to do a BSD-ish install
561 AC_PROG_INSTALL
562
563 dnl If you can run configure, you certainly have /bin/sh
564 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
565
566 dnl ** how to invoke `ar' and `ranlib'
567 FP_PROG_AR_NEEDS_RANLIB
568 FP_PROG_AR_SUPPORTS_INPUT
569
570 dnl ** Check to see whether ln -s works
571 AC_PROG_LN_S
572
573
574 dnl ** Find the path to sed
575 AC_PATH_PROG(SedCmd,sed)
576
577
578 dnl ** check for time command
579 AC_PATH_PROG(TimeCmd,time)
580
581 dnl ** check for tar
582 dnl   if GNU tar is named gtar, look for it first.
583 AC_PATH_PROGS(TarCmd,gtar tar,tar)
584
585 dnl ** check for patch
586 dnl if GNU patch is named gpatch, look for it first
587 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
588
589 AC_PATH_PROG(HSCOLOUR,HsColour)
590 # HsColour is passed to Cabal, so we need a native path
591 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
592    test "${OSTYPE}"      != "msys"                  && \
593    test "${HSCOLOUR}"    != ""
594 then
595     # Canonicalise to <drive>:/path/to/gcc
596     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
597 fi
598
599 dnl ** check for DocBook toolchain
600 FP_CHECK_DOCBOOK_DTD
601 FP_DOCBOOK_XSL
602 FP_PROG_DBLATEX
603
604 FP_PROG_HSTAGS
605
606 dnl ** check for ghc-pkg command
607 FP_PROG_GHC_PKG
608
609 dnl ** check for installed happy binary + version
610 dnl    (don't do it if we're booting from .hc files though.)
611 if test "$BootingFromHc" = "NO"; then
612 FPTOOLS_HAPPY
613 fi;
614
615 dnl ** check for installed alex binary + version
616 dnl    (don't do it if we're booting from .hc files though.)
617 if test "$BootingFromHc" = "NO"; then
618 FPTOOLS_ALEX
619 fi;
620
621 dnl Check we have an acceptable version of windres
622 FPTOOLS_WINDRES
623
624 dnl --------------------------------------------------
625 dnl ### program checking section ends here ###
626 dnl --------------------------------------------------
627
628 dnl --------------------------------------------------
629 dnl * Platform header file and syscall feature tests
630 dnl ### checking the state of the local header files and syscalls ###
631
632 dnl ** check for full ANSI header (.h) files
633 AC_HEADER_STDC
634
635 dnl ** Enable large file support.  NB. do this before testing the type of
636 dnl    off_t, because it will affect the result of that test.
637 AC_SYS_LARGEFILE
638
639 dnl ** check for specific header (.h) files that we are interested in
640 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/mman.h sys/resource.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
641
642 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
643 AC_HEADER_TIME
644
645 dnl ** do we have long longs?
646 AC_CHECK_TYPES([long long])
647
648 dnl ** what are the sizes of various types
649 AC_CHECK_SIZEOF(char,               1)
650 AC_CHECK_SIZEOF(double,             8)
651 AC_CHECK_SIZEOF(float,              4)
652 AC_CHECK_SIZEOF(int,                4)
653 AC_CHECK_SIZEOF(long,               4)
654 if test "$ac_cv_type_long_long" = yes; then
655 AC_CHECK_SIZEOF(long long,          8)
656 fi
657 AC_CHECK_SIZEOF(short,              2)
658 AC_CHECK_SIZEOF(unsigned char,      1)
659 AC_CHECK_SIZEOF(unsigned int,       4)
660 AC_CHECK_SIZEOF(unsigned long,      4)
661 if test "$ac_cv_type_long_long" = yes; then
662 AC_CHECK_SIZEOF(unsigned long long, 8)
663 fi
664 AC_CHECK_SIZEOF(unsigned short,     2)
665 AC_CHECK_SIZEOF(void *,             4)
666
667 dnl ** what are alignment constraints on various types
668 FP_CHECK_ALIGNMENT(char)
669 FP_CHECK_ALIGNMENT(double)
670 FP_CHECK_ALIGNMENT(float)
671 FP_CHECK_ALIGNMENT(int)
672 FP_CHECK_ALIGNMENT(long)
673 if test "$ac_cv_type_long_long" = yes; then
674 FP_CHECK_ALIGNMENT(long long)
675 fi
676 FP_CHECK_ALIGNMENT(short)
677 FP_CHECK_ALIGNMENT(unsigned char)
678 FP_CHECK_ALIGNMENT(unsigned int)
679 FP_CHECK_ALIGNMENT(unsigned long)
680 if test "$ac_cv_type_long_long" = yes; then
681 FP_CHECK_ALIGNMENT(unsigned long long)
682 fi
683 FP_CHECK_ALIGNMENT(unsigned short)
684 FP_CHECK_ALIGNMENT(void *)
685
686 FP_CHECK_FUNC([WinExec],
687   [@%:@include <windows.h>], [WinExec("",0)])
688
689 FP_CHECK_FUNC([GetModuleFileName],
690   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
691
692 dnl ** check return type of signal handlers
693 dnl Foo: assumes we can use prototypes.
694 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
695 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
696 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
697 dnl #include <signal.h>
698 dnl #ifdef signal
699 dnl #undef signal
700 dnl #endif
701 dnl void (*signal (int, void (*)(int)))(int);
702 dnl ]],
703 dnl [[int i;]])],
704 dnl [ac_cv_type_signal_handler=void_int],
705 dnl [ac_cv_type_signal_handler=int_void])])
706 dnl if test "$ac_cv_type_signal_handler" = void_int; then
707 dnl AC_DEFINE(VOID_INT_SIGNALS)
708 dnl fi
709
710 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
711 AC_TYPE_SIGNAL
712 if test "$ac_cv_type_signal" = void; then
713   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
714 fi
715
716 dnl ** check for more functions
717 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
718 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
719
720 AC_TRY_RUN([
721 #include <sys/types.h>
722 #include <sys/time.h>
723 int main(void) {
724   struct itimerval tval;
725   tval.it_value.tv_sec = 1;
726   tval.it_value.tv_usec = 0;
727   tval.it_interval = tval.it_value;
728   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
729 }
730 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
731
732 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
733 dnl ** _POSIX_C_SOURCE is defined
734 AC_CHECK_DECLS([ctime_r], , ,
735 [#define _POSIX_SOURCE 1
736 #define _POSIX_C_SOURCE 199506L
737 #include <time.h>])
738
739 dnl ** check for mingwex library
740 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
741 AC_SUBST(HaveLibMingwEx)
742
743 if test $HaveLibMingwEx = YES ; then
744   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
745 fi
746
747 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
748 dnl    the order of these tests matters: bfd needs liberty
749 AC_CHECK_LIB(iberty, xmalloc)
750 AC_CHECK_LIB(bfd,    bfd_init)
751
752 dnl ** check for math library
753 AC_CHECK_FUNC(atan,[fp_libm_not_needed=yes;LIBM=],[fp_libm_not_needed=dunno])
754 if test x"$fp_libm_not_needed" = xdunno; then
755    AC_CHECK_LIB([m], [atan], [LIBS="-lm $LIBS"; LIBM="-lm"],[LIBM=])
756 fi
757 AC_SUBST([LIBM])
758
759 dnl ################################################################
760 dnl Check for libraries
761 dnl ################################################################
762
763 dnl ** check whether we need -ldl to get dlopen()
764
765 AC_CHECK_LIB(dl, dlopen,
766     [HaveLibDL=YES
767      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
768      LIBS="$LIBS -ldl"],
769     [HaveLibDL=NO])
770 AC_SUBST(HaveLibDL)
771
772 dnl --------------------------------------------------
773 dnl * Miscellaneous feature tests
774 dnl --------------------------------------------------
775
776 dnl ** can we get alloca?
777 AC_FUNC_ALLOCA
778
779 dnl ** Working vfork?
780 AC_FUNC_FORK
781
782 dnl ** determine whether or not const works
783 AC_C_CONST
784
785 dnl ** are we big endian?
786 AC_C_BIGENDIAN
787 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
788
789 dnl ** check for leading underscores in symbol names
790 FP_LEADING_UNDERSCORE
791
792 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
793 FP_PROG_LD_X
794 FP_PROG_LD_IS_GNU
795
796 dnl ** check for Apple-style dead-stripping support
797 dnl    (.subsections-via-symbols assembler directive)
798
799
800 AC_MSG_CHECKING(for .subsections_via_symbols)
801 AC_COMPILE_IFELSE(
802     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
803     [AC_MSG_RESULT(yes)
804      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
805                [Define to 1 if Apple-style dead-stripping is supported.])
806     ],
807     [AC_MSG_RESULT(no)])
808
809 dnl *** check for GNU non-executable stack note support (ELF only)
810 dnl     (.section .note.GNU-stack,"",@progbits)
811
812 AC_MSG_CHECKING(for GNU non-executable stack support)
813 AC_COMPILE_IFELSE(
814     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
815     [AC_MSG_RESULT(yes)
816      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
817                [Define to 1 if GNU non-executable stack notes are supported.])
818     ],
819     [AC_MSG_RESULT(no)])
820
821 dnl ** check for librt
822 AC_CHECK_LIB(rt, clock_gettime)
823 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
824 FP_CHECK_TIMER_CREATE
825
826 dnl ** check for Apple's "interesting" long double compatibility scheme
827 AC_MSG_CHECKING(for printf\$LDBLStub)
828 AC_TRY_LINK_FUNC(printf\$LDBLStub,
829     [
830         AC_MSG_RESULT(yes)
831         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
832             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
833     ],
834     [
835         AC_MSG_RESULT(no)
836         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
837             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
838     ])
839
840 # test for GTK+
841 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
842 if test -n "$GTK_CONFIG"; then
843   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
844     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
845   else
846     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
847     GTK_CONFIG=
848   fi
849 fi
850 AC_SUBST([GTK_CONFIG])
851
852 #Checking for PAPI
853 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
854 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
855 AC_SUBST(HavePapiLib)
856 AC_SUBST(HavePapiHeader)
857
858 AC_CHECK_FUNCS(__mingw_vfprintf)
859
860 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
861    HavePapi=YES
862 else
863    HavePapi=NO
864 fi
865 AC_SUBST(HavePapi)
866
867 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
868    test "$XsltprocCmd" = ""
869 then
870     BUILD_DOCBOOK_HTML=NO
871 else
872     BUILD_DOCBOOK_HTML=YES
873 fi
874 AC_SUBST(BUILD_DOCBOOK_HTML)
875
876 if test "$DblatexCmd" = ""
877 then
878     BUILD_DOCBOOK_PS=NO
879     BUILD_DOCBOOK_PDF=NO
880 else
881     BUILD_DOCBOOK_PS=YES
882     BUILD_DOCBOOK_PDF=YES
883 fi
884 AC_SUBST(BUILD_DOCBOOK_PS)
885 AC_SUBST(BUILD_DOCBOOK_PDF)
886
887 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
888    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
889 fi
890
891 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal ghc.spec extra-gcc-opts docs/users_guide/ug-book.xml distrib/ghc.iss])
892 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
893 AC_OUTPUT
894
895 # We get caught by
896 #     http://savannah.gnu.org/bugs/index.php?1516
897 #     $(eval ...) inside conditionals causes errors
898 # with make 3.80, so warn the user if it looks like they're about to
899 # try to use it.
900 # We would use "grep -q" here, but Solaris's grep doesn't support it.
901 checkMake380() {
902     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
903     then
904         echo
905         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
906         echo "This version cannot be used to build GHC."
907         echo "Please use GNU make >= 3.81."
908     fi
909 }
910
911 checkMake380 make
912 checkMake380 gmake
913
914 echo ["
915 ----------------------------------------------------------------------
916 Configure completed successfully.
917
918    Building GHC version  : $ProjectVersion
919
920    Build platform        : $BuildPlatform
921    Host platform         : $HostPlatform
922    Target platform       : $TargetPlatform
923 "]
924
925 if test "$BootingFromHc" = "YES"; then
926 echo ["\
927    Bootstrapping from HC files.
928 "]
929 else
930 echo ["\
931    Bootstrapping using   : $WithGhc
932       which is version   : $GhcVersion
933 "]
934 fi
935
936 echo ["\
937    Using GCC             : $WhatGccIsCalled
938       which is version   : $GccVersion
939
940    ld       : $LdCmd
941    Happy    : $HappyCmd ($HappyVersion)
942    Alex     : $AlexCmd ($AlexVersion)
943    Python   : $PythonCmd
944    Perl     : $PerlCmd
945    dblatex  : $DblatexCmd
946    xsltproc : $XsltprocCmd"]
947
948 if test "$HSCOLOUR" = ""; then
949 echo ["
950    HsColour was not found; documentation will not contain source links
951 "]
952 else
953 echo ["\
954    HsColour : $HSCOLOUR
955 "]
956 fi
957
958 echo ["\
959    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
960    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
961    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
962
963 echo ["----------------------------------------------------------------------
964 "]
965
966 echo "\
967 For a standard build of GHC (fully optimised with profiling), type (g)make.
968
969 To make changes to the default build configuration, copy the file
970 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
971
972 For more information on how to configure your GHC build, see
973    http://hackage.haskell.org/trac/ghc/wiki/Building
974 "