Make -fscc-profiling a dynamic flag
[ghc.git] / compiler / ghci / ByteCodeGen.lhs
1 %
2 % (c) The University of Glasgow 2002-2006
3 %
4
5 ByteCodeGen: Generate bytecode from Core
6
7 \begin{code}
8 {-# OPTIONS -fno-warn-tabs #-}
9 -- The above warning supression flag is a temporary kludge.
10 -- While working on this module you are encouraged to remove it and
11 -- detab the module (please do the detabbing in a separate patch). See
12 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#TabsvsSpaces
13 -- for details
14
15 module ByteCodeGen ( UnlinkedBCO, byteCodeGen, coreExprToBCOs ) where
16
17 #include "HsVersions.h"
18
19 import ByteCodeInstr
20 import ByteCodeItbls
21 import ByteCodeAsm
22 import ByteCodeLink
23 import LibFFI
24
25 import Outputable
26 import Name
27 import MkId
28 import Id
29 import ForeignCall
30 import HscTypes
31 import CoreUtils
32 import CoreSyn
33 import PprCore
34 import Literal
35 import PrimOp
36 import CoreFVs
37 import Type
38 import DataCon
39 import TyCon
40 import Util
41 import VarSet
42 import TysPrim
43 import DynFlags
44 import ErrUtils
45 import Unique
46 import FastString
47 import Panic
48 import SMRep
49 import ClosureInfo
50 import Bitmap
51 import OrdList
52 import Constants
53
54 import Data.List
55 import Foreign
56 import Foreign.C
57
58 import Control.Monad
59 import Data.Char
60
61 import UniqSupply
62 import BreakArray
63 import Data.Maybe
64 import Module
65
66 import Data.Map (Map)
67 import qualified Data.Map as Map
68 import qualified FiniteMap as Map
69 import Data.Ord
70
71 -- -----------------------------------------------------------------------------
72 -- Generating byte code for a complete module
73
74 byteCodeGen :: DynFlags
75             -> Module
76             -> CoreProgram
77             -> [TyCon]
78             -> ModBreaks
79             -> IO CompiledByteCode
80 byteCodeGen dflags this_mod binds tycs modBreaks
81    = do showPass dflags "ByteCodeGen"
82
83         let flatBinds = [ (bndr, freeVars rhs)
84                         | (bndr, rhs) <- flattenBinds binds]
85
86         us <- mkSplitUniqSupply 'y'
87         (BcM_State _dflags _us _this_mod _final_ctr mallocd _, proto_bcos)
88            <- runBc dflags us this_mod modBreaks (mapM schemeTopBind flatBinds)
89
90         when (notNull mallocd)
91              (panic "ByteCodeGen.byteCodeGen: missing final emitBc?")
92
93         dumpIfSet_dyn dflags Opt_D_dump_BCOs
94            "Proto-BCOs" (vcat (intersperse (char ' ') (map ppr proto_bcos)))
95
96         assembleBCOs dflags proto_bcos tycs
97
98 -- -----------------------------------------------------------------------------
99 -- Generating byte code for an expression
100
101 -- Returns: (the root BCO for this expression,
102 --           a list of auxilary BCOs resulting from compiling closures)
103 coreExprToBCOs :: DynFlags
104                -> Module
105                -> CoreExpr
106                -> IO UnlinkedBCO
107 coreExprToBCOs dflags this_mod expr
108  = do showPass dflags "ByteCodeGen"
109
110       -- create a totally bogus name for the top-level BCO; this
111       -- should be harmless, since it's never used for anything
112       let invented_name  = mkSystemVarName (mkPseudoUniqueE 0) (fsLit "ExprTopLevel")
113           invented_id    = Id.mkLocalId invented_name (panic "invented_id's type")
114
115       -- the uniques are needed to generate fresh variables when we introduce new
116       -- let bindings for ticked expressions
117       us <- mkSplitUniqSupply 'y'
118       (BcM_State _dflags _us _this_mod _final_ctr mallocd _ , proto_bco)
119          <- runBc dflags us this_mod emptyModBreaks $
120               schemeTopBind (invented_id, freeVars expr)
121
122       when (notNull mallocd)
123            (panic "ByteCodeGen.coreExprToBCOs: missing final emitBc?")
124
125       dumpIfSet_dyn dflags Opt_D_dump_BCOs "Proto-BCOs" (ppr proto_bco)
126
127       assembleBCO dflags proto_bco
128
129
130 -- -----------------------------------------------------------------------------
131 -- Compilation schema for the bytecode generator
132
133 type BCInstrList = OrdList BCInstr
134
135 type Sequel = Word -- back off to this depth before ENTER
136
137 -- Maps Ids to the offset from the stack _base_ so we don't have
138 -- to mess with it after each push/pop.
139 type BCEnv = Map Id Word -- To find vars on the stack
140
141 {-
142 ppBCEnv :: BCEnv -> SDoc
143 ppBCEnv p
144    = text "begin-env"
145      $$ nest 4 (vcat (map pp_one (sortBy cmp_snd (Map.toList p))))
146      $$ text "end-env"
147      where
148         pp_one (var, offset) = int offset <> colon <+> ppr var <+> ppr (idCgRep var)
149         cmp_snd x y = compare (snd x) (snd y)
150 -}
151
152 -- Create a BCO and do a spot of peephole optimisation on the insns
153 -- at the same time.
154 mkProtoBCO
155    :: name
156    -> BCInstrList
157    -> Either  [AnnAlt Id VarSet] (AnnExpr Id VarSet)
158    -> Int
159    -> Word16
160    -> [StgWord]
161    -> Bool      -- True <=> is a return point, rather than a function
162    -> [BcPtr]
163    -> ProtoBCO name
164 mkProtoBCO nm instrs_ordlist origin arity bitmap_size bitmap is_ret mallocd_blocks
165    = ProtoBCO {
166         protoBCOName = nm,
167         protoBCOInstrs = maybe_with_stack_check,
168         protoBCOBitmap = bitmap,
169         protoBCOBitmapSize = bitmap_size,
170         protoBCOArity = arity,
171         protoBCOExpr = origin,
172         protoBCOPtrs = mallocd_blocks
173       }
174      where
175         -- Overestimate the stack usage (in words) of this BCO,
176         -- and if >= iNTERP_STACK_CHECK_THRESH, add an explicit
177         -- stack check.  (The interpreter always does a stack check
178         -- for iNTERP_STACK_CHECK_THRESH words at the start of each
179         -- BCO anyway, so we only need to add an explicit one in the
180         -- (hopefully rare) cases when the (overestimated) stack use
181         -- exceeds iNTERP_STACK_CHECK_THRESH.
182         maybe_with_stack_check
183            | is_ret && stack_usage < fromIntegral aP_STACK_SPLIM = peep_d
184                 -- don't do stack checks at return points,
185                 -- everything is aggregated up to the top BCO
186                 -- (which must be a function).
187                 -- That is, unless the stack usage is >= AP_STACK_SPLIM,
188                 -- see bug #1466.
189            | stack_usage >= fromIntegral iNTERP_STACK_CHECK_THRESH
190            = STKCHECK stack_usage : peep_d
191            | otherwise
192            = peep_d     -- the supposedly common case
193
194         -- We assume that this sum doesn't wrap
195         stack_usage = sum (map bciStackUse peep_d)
196
197         -- Merge local pushes
198         peep_d = peep (fromOL instrs_ordlist)
199
200         peep (PUSH_L off1 : PUSH_L off2 : PUSH_L off3 : rest)
201            = PUSH_LLL off1 (off2-1) (off3-2) : peep rest
202         peep (PUSH_L off1 : PUSH_L off2 : rest)
203            = PUSH_LL off1 (off2-1) : peep rest
204         peep (i:rest)
205            = i : peep rest
206         peep []
207            = []
208
209 argBits :: [CgRep] -> [Bool]
210 argBits [] = []
211 argBits (rep : args)
212   | isFollowableArg rep = False : argBits args
213   | otherwise = take (cgRepSizeW rep) (repeat True) ++ argBits args
214
215 -- -----------------------------------------------------------------------------
216 -- schemeTopBind
217
218 -- Compile code for the right-hand side of a top-level binding
219
220 schemeTopBind :: (Id, AnnExpr Id VarSet) -> BcM (ProtoBCO Name)
221
222
223 schemeTopBind (id, rhs)
224   | Just data_con <- isDataConWorkId_maybe id,
225     isNullaryRepDataCon data_con = do
226         -- Special case for the worker of a nullary data con.
227         -- It'll look like this:        Nil = /\a -> Nil a
228         -- If we feed it into schemeR, we'll get
229         --      Nil = Nil
230         -- because mkConAppCode treats nullary constructor applications
231         -- by just re-using the single top-level definition.  So
232         -- for the worker itself, we must allocate it directly.
233     -- ioToBc (putStrLn $ "top level BCO")
234     emitBc (mkProtoBCO (getName id) (toOL [PACK data_con 0, ENTER])
235                        (Right rhs) 0 0 [{-no bitmap-}] False{-not alts-})
236
237   | otherwise
238   = schemeR [{- No free variables -}] (id, rhs)
239
240
241 -- -----------------------------------------------------------------------------
242 -- schemeR
243
244 -- Compile code for a right-hand side, to give a BCO that,
245 -- when executed with the free variables and arguments on top of the stack,
246 -- will return with a pointer to the result on top of the stack, after
247 -- removing the free variables and arguments.
248 --
249 -- Park the resulting BCO in the monad.  Also requires the
250 -- variable to which this value was bound, so as to give the
251 -- resulting BCO a name.
252
253 schemeR :: [Id]                 -- Free vars of the RHS, ordered as they
254                                 -- will appear in the thunk.  Empty for
255                                 -- top-level things, which have no free vars.
256         -> (Id, AnnExpr Id VarSet)
257         -> BcM (ProtoBCO Name)
258 schemeR fvs (nm, rhs)
259 {-
260    | trace (showSDoc (
261               (char ' '
262                $$ (ppr.filter (not.isTyVar).varSetElems.fst) rhs
263                $$ pprCoreExpr (deAnnotate rhs)
264                $$ char ' '
265               ))) False
266    = undefined
267    | otherwise
268 -}
269    = schemeR_wrk fvs nm rhs (collect rhs)
270
271 collect :: AnnExpr Id VarSet -> ([Var], AnnExpr' Id VarSet)
272 collect (_, e) = go [] e
273   where
274     go xs e | Just e' <- bcView e = go xs e'
275     go xs (AnnLam x (_,e)) 
276       | UbxTupleRep _ <- repType (idType x)
277       = unboxedTupleException
278       | otherwise
279       = go (x:xs) e
280     go xs not_lambda = (reverse xs, not_lambda)
281
282 schemeR_wrk :: [Id] -> Id -> AnnExpr Id VarSet -> ([Var], AnnExpr' Var VarSet) -> BcM (ProtoBCO Name)
283 schemeR_wrk fvs nm original_body (args, body)
284    = let
285          all_args  = reverse args ++ fvs
286          arity     = length all_args
287          -- all_args are the args in reverse order.  We're compiling a function
288          -- \fv1..fvn x1..xn -> e
289          -- i.e. the fvs come first
290
291          szsw_args = map (fromIntegral . idSizeW) all_args
292          szw_args  = sum szsw_args
293          p_init    = Map.fromList (zip all_args (mkStackOffsets 0 szsw_args))
294
295          -- make the arg bitmap
296          bits = argBits (reverse (map idCgRep all_args))
297          bitmap_size = genericLength bits
298          bitmap = mkBitmap bits
299      in do
300      body_code <- schemeER_wrk szw_args p_init body
301
302      emitBc (mkProtoBCO (getName nm) body_code (Right original_body)
303                  arity bitmap_size bitmap False{-not alts-})
304
305 -- introduce break instructions for ticked expressions
306 schemeER_wrk :: Word -> BCEnv -> AnnExpr' Id VarSet -> BcM BCInstrList
307 schemeER_wrk d p rhs
308   | AnnTick (Breakpoint tick_no fvs) (_annot, newRhs) <- rhs
309   = do  code <- schemeE (fromIntegral d) 0 p newRhs
310         arr <- getBreakArray
311         this_mod <- getCurrentModule
312         let idOffSets = getVarOffSets d p fvs
313         let breakInfo = BreakInfo
314                         { breakInfo_module = this_mod
315                         , breakInfo_number = tick_no
316                         , breakInfo_vars = idOffSets
317                         , breakInfo_resty = exprType (deAnnotate' newRhs)
318                         }
319         let breakInstr = case arr of
320                          BA arr# ->
321                              BRK_FUN arr# (fromIntegral tick_no) breakInfo
322         return $ breakInstr `consOL` code
323    | otherwise = schemeE (fromIntegral d) 0 p rhs
324
325 getVarOffSets :: Word -> BCEnv -> [Id] -> [(Id, Word16)]
326 getVarOffSets d p = catMaybes . map (getOffSet d p)
327
328 getOffSet :: Word -> BCEnv -> Id -> Maybe (Id, Word16)
329 getOffSet d env id
330    = case lookupBCEnv_maybe id env of
331         Nothing     -> Nothing
332         Just offset -> Just (id, trunc16 $ d - offset)
333
334 trunc16 :: Word -> Word16
335 trunc16 w
336     | w > fromIntegral (maxBound :: Word16)
337     = panic "stack depth overflow"
338     | otherwise
339     = fromIntegral w
340
341 fvsToEnv :: BCEnv -> VarSet -> [Id]
342 -- Takes the free variables of a right-hand side, and
343 -- delivers an ordered list of the local variables that will
344 -- be captured in the thunk for the RHS
345 -- The BCEnv argument tells which variables are in the local
346 -- environment: these are the ones that should be captured
347 --
348 -- The code that constructs the thunk, and the code that executes
349 -- it, have to agree about this layout
350 fvsToEnv p fvs = [v | v <- varSetElems fvs,
351                       isId v,           -- Could be a type variable
352                       v `Map.member` p]
353
354 -- -----------------------------------------------------------------------------
355 -- schemeE
356
357 returnUnboxedAtom :: Word -> Sequel -> BCEnv
358                  -> AnnExpr' Id VarSet -> CgRep
359                  -> BcM BCInstrList
360 -- Returning an unlifted value.
361 -- Heave it on the stack, SLIDE, and RETURN.
362 returnUnboxedAtom d s p e e_rep
363    = do (push, szw) <- pushAtom d p e
364         return (push                       -- value onto stack
365                 `appOL`  mkSLIDE szw (d-s) -- clear to sequel
366                 `snocOL` RETURN_UBX e_rep) -- go
367
368 -- Compile code to apply the given expression to the remaining args
369 -- on the stack, returning a HNF.
370 schemeE :: Word -> Sequel -> BCEnv -> AnnExpr' Id VarSet -> BcM BCInstrList
371
372 schemeE d s p e
373    | Just e' <- bcView e
374    = schemeE d s p e'
375
376 -- Delegate tail-calls to schemeT.
377 schemeE d s p e@(AnnApp _ _) = schemeT d s p e
378
379 schemeE d s p e@(AnnLit lit)     = returnUnboxedAtom d s p e (typeCgRep (literalType lit))
380 schemeE d s p e@(AnnCoercion {}) = returnUnboxedAtom d s p e VoidArg
381
382 schemeE d s p e@(AnnVar v)
383     | isUnLiftedType (idType v) = returnUnboxedAtom d s p e (bcIdCgRep v)
384     | otherwise                 = schemeT d s p e
385
386 schemeE d s p (AnnLet (AnnNonRec x (_,rhs)) (_,body))
387    | (AnnVar v, args_r_to_l) <- splitApp rhs,
388      Just data_con <- isDataConWorkId_maybe v,
389      dataConRepArity data_con == length args_r_to_l
390    = do -- Special case for a non-recursive let whose RHS is a
391         -- saturatred constructor application.
392         -- Just allocate the constructor and carry on
393         alloc_code <- mkConAppCode d s p data_con args_r_to_l
394         body_code <- schemeE (d+1) s (Map.insert x d p) body
395         return (alloc_code `appOL` body_code)
396
397 -- General case for let.  Generates correct, if inefficient, code in
398 -- all situations.
399 schemeE d s p (AnnLet binds (_,body))
400    = let (xs,rhss) = case binds of AnnNonRec x rhs  -> ([x],[rhs])
401                                    AnnRec xs_n_rhss -> unzip xs_n_rhss
402          n_binds = genericLength xs
403
404          fvss  = map (fvsToEnv p' . fst) rhss
405
406          -- Sizes of free vars
407          sizes = map (\rhs_fvs -> sum (map (fromIntegral . idSizeW) rhs_fvs)) fvss
408
409          -- the arity of each rhs
410          arities = map (genericLength . fst . collect) rhss
411
412          -- This p', d' defn is safe because all the items being pushed
413          -- are ptrs, so all have size 1.  d' and p' reflect the stack
414          -- after the closures have been allocated in the heap (but not
415          -- filled in), and pointers to them parked on the stack.
416          p'    = Map.insertList (zipE xs (mkStackOffsets d (genericReplicate n_binds 1))) p
417          d'    = d + fromIntegral n_binds
418          zipE  = zipEqual "schemeE"
419
420          -- ToDo: don't build thunks for things with no free variables
421          build_thunk _ [] size bco off arity
422             = return (PUSH_BCO bco `consOL` unitOL (mkap (off+size) size))
423            where
424                 mkap | arity == 0 = MKAP
425                      | otherwise  = MKPAP
426          build_thunk dd (fv:fvs) size bco off arity = do
427               (push_code, pushed_szw) <- pushAtom dd p' (AnnVar fv)
428               more_push_code <- build_thunk (dd + fromIntegral pushed_szw) fvs size bco off arity
429               return (push_code `appOL` more_push_code)
430
431          alloc_code = toOL (zipWith mkAlloc sizes arities)
432            where mkAlloc sz 0
433                     | is_tick     = ALLOC_AP_NOUPD sz
434                     | otherwise   = ALLOC_AP sz
435                  mkAlloc sz arity = ALLOC_PAP arity sz
436
437          is_tick = case binds of
438                      AnnNonRec id _ -> occNameFS (getOccName id) == tickFS
439                      _other -> False
440
441          compile_bind d' fvs x rhs size arity off = do
442                 bco <- schemeR fvs (x,rhs)
443                 build_thunk d' fvs size bco off arity
444
445          compile_binds =
446             [ compile_bind d' fvs x rhs size arity n
447             | (fvs, x, rhs, size, arity, n) <-
448                 zip6 fvss xs rhss sizes arities [n_binds, n_binds-1 .. 1]
449             ]
450      in do
451      body_code <- schemeE d' s p' body
452      thunk_codes <- sequence compile_binds
453      return (alloc_code `appOL` concatOL thunk_codes `appOL` body_code)
454
455 -- introduce a let binding for a ticked case expression. This rule
456 -- *should* only fire when the expression was not already let-bound
457 -- (the code gen for let bindings should take care of that).  Todo: we
458 -- call exprFreeVars on a deAnnotated expression, this may not be the
459 -- best way to calculate the free vars but it seemed like the least
460 -- intrusive thing to do
461 schemeE d s p exp@(AnnTick (Breakpoint _id _fvs) _rhs)
462    = if isUnLiftedType ty
463         then do
464           -- If the result type is unlifted, then we must generate
465           --   let f = \s . tick<n> e
466           --   in  f realWorld#
467           -- When we stop at the breakpoint, _result will have an unlifted
468           -- type and hence won't be bound in the environment, but the
469           -- breakpoint will otherwise work fine.
470           id <- newId (mkFunTy realWorldStatePrimTy ty)
471           st <- newId realWorldStatePrimTy
472           let letExp = AnnLet (AnnNonRec id (fvs, AnnLam st (emptyVarSet, exp)))
473                               (emptyVarSet, (AnnApp (emptyVarSet, AnnVar id)
474                                                     (emptyVarSet, AnnVar realWorldPrimId)))
475           schemeE d s p letExp
476         else do
477           id <- newId ty
478           -- Todo: is emptyVarSet correct on the next line?
479           let letExp = AnnLet (AnnNonRec id (fvs, exp)) (emptyVarSet, AnnVar id)
480           schemeE d s p letExp
481    where exp' = deAnnotate' exp
482          fvs  = exprFreeVars exp'
483          ty   = exprType exp'
484
485 -- ignore other kinds of tick
486 schemeE d s p (AnnTick _ (_, rhs)) = schemeE d s p rhs
487
488 schemeE d s p (AnnCase (_,scrut) _ _ []) = schemeE d s p scrut
489         -- no alts: scrut is guaranteed to diverge
490
491 schemeE d s p (AnnCase scrut bndr _ [(DataAlt dc, [bind1, bind2], rhs)])
492    | isUnboxedTupleCon dc
493    , UnaryRep rep_ty1 <- repType (idType bind1), UnaryRep rep_ty2 <- repType (idType bind2)
494         -- Convert
495         --      case .... of x { (# VoidArg'd-thing, a #) -> ... }
496         -- to
497         --      case .... of a { DEFAULT -> ... }
498         -- becuse the return convention for both are identical.
499         --
500         -- Note that it does not matter losing the void-rep thing from the
501         -- envt (it won't be bound now) because we never look such things up.
502    , Just res <- case () of
503                    _ | VoidRep <- typePrimRep rep_ty1
504                      -> Just $ doCase d s p scrut bind2 [(DEFAULT, [], rhs)] (Just bndr){-unboxed tuple-}
505                      | VoidRep <- typePrimRep rep_ty2
506                      -> Just $ doCase d s p scrut bind1 [(DEFAULT, [], rhs)] (Just bndr){-unboxed tuple-}
507                      | otherwise
508                      -> Nothing
509    = res
510
511 schemeE d s p (AnnCase scrut bndr _ [(DataAlt dc, [bind1], rhs)])
512    | isUnboxedTupleCon dc, UnaryRep _ <- repType (idType bind1)
513         -- Similarly, convert
514         --      case .... of x { (# a #) -> ... }
515         -- to
516         --      case .... of a { DEFAULT -> ... }
517    = --trace "automagic mashing of case alts (# a #)"  $
518      doCase d s p scrut bind1 [(DEFAULT, [], rhs)] (Just bndr){-unboxed tuple-}
519
520 schemeE d s p (AnnCase scrut bndr _ [(DEFAULT, [], rhs)])
521    | Just (tc, tys) <- splitTyConApp_maybe (idType bndr)
522    , isUnboxedTupleTyCon tc
523    , Just res <- case tys of
524         [ty]       | UnaryRep _ <- repType ty
525                    , let bind = bndr `setIdType` ty
526                    -> Just $ doCase d s p scrut bind [(DEFAULT, [], rhs)] (Just bndr){-unboxed tuple-}
527         [ty1, ty2] | UnaryRep rep_ty1 <- repType ty1
528                    , UnaryRep rep_ty2 <- repType ty2
529                    -> case () of
530                        _ | VoidRep <- typePrimRep rep_ty1
531                          , let bind2 = bndr `setIdType` ty2
532                          -> Just $ doCase d s p scrut bind2 [(DEFAULT, [], rhs)] (Just bndr){-unboxed tuple-}
533                          | VoidRep <- typePrimRep rep_ty2
534                          , let bind1 = bndr `setIdType` ty1
535                          -> Just $ doCase d s p scrut bind1 [(DEFAULT, [], rhs)] (Just bndr){-unboxed tuple-}
536                          | otherwise
537                          -> Nothing
538         _ -> Nothing
539    = res
540
541 schemeE d s p (AnnCase scrut bndr _ alts)
542    = doCase d s p scrut bndr alts Nothing{-not an unboxed tuple-}
543
544 schemeE _ _ _ expr
545    = pprPanic "ByteCodeGen.schemeE: unhandled case"
546                (pprCoreExpr (deAnnotate' expr))
547
548 {-
549    Ticked Expressions
550    ------------------
551
552   The idea is that the "breakpoint<n,fvs> E" is really just an annotation on
553   the code. When we find such a thing, we pull out the useful information,
554   and then compile the code as if it was just the expression E.
555
556 -}
557
558 -- Compile code to do a tail call.  Specifically, push the fn,
559 -- slide the on-stack app back down to the sequel depth,
560 -- and enter.  Four cases:
561 --
562 -- 0.  (Nasty hack).
563 --     An application "GHC.Prim.tagToEnum# <type> unboxed-int".
564 --     The int will be on the stack.  Generate a code sequence
565 --     to convert it to the relevant constructor, SLIDE and ENTER.
566 --
567 -- 1.  The fn denotes a ccall.  Defer to generateCCall.
568 --
569 -- 2.  (Another nasty hack).  Spot (# a::VoidArg, b #) and treat
570 --     it simply as  b  -- since the representations are identical
571 --     (the VoidArg takes up zero stack space).  Also, spot
572 --     (# b #) and treat it as  b.
573 --
574 -- 3.  Application of a constructor, by defn saturated.
575 --     Split the args into ptrs and non-ptrs, and push the nonptrs,
576 --     then the ptrs, and then do PACK and RETURN.
577 --
578 -- 4.  Otherwise, it must be a function call.  Push the args
579 --     right to left, SLIDE and ENTER.
580
581 schemeT :: Word         -- Stack depth
582         -> Sequel       -- Sequel depth
583         -> BCEnv        -- stack env
584         -> AnnExpr' Id VarSet
585         -> BcM BCInstrList
586
587 schemeT d s p app
588
589 --   | trace ("schemeT: env in = \n" ++ showSDocDebug (ppBCEnv p)) False
590 --   = panic "schemeT ?!?!"
591
592 --   | trace ("\nschemeT\n" ++ showSDoc (pprCoreExpr (deAnnotate' app)) ++ "\n") False
593 --   = error "?!?!"
594
595    -- Case 0
596    | Just (arg, constr_names) <- maybe_is_tagToEnum_call
597    = do (push, arg_words) <- pushAtom d p arg
598         tagToId_sequence <- implement_tagToId constr_names
599         return (push `appOL`  tagToId_sequence
600                        `appOL`  mkSLIDE 1 (d - s + fromIntegral arg_words)
601                        `snocOL` ENTER)
602
603    -- Case 1
604    | Just (CCall ccall_spec) <- isFCallId_maybe fn
605    = generateCCall d s p ccall_spec fn args_r_to_l
606
607    -- Case 2: Constructor application
608    | Just con <- maybe_saturated_dcon,
609      isUnboxedTupleCon con
610    = case args_r_to_l of
611         [arg1,arg2] | isVoidArgAtom arg1 ->
612                   unboxedTupleReturn d s p arg2
613         [arg1,arg2] | isVoidArgAtom arg2 ->
614                   unboxedTupleReturn d s p arg1
615         _other -> unboxedTupleException
616
617    -- Case 3: Ordinary data constructor
618    | Just con <- maybe_saturated_dcon
619    = do alloc_con <- mkConAppCode d s p con args_r_to_l
620         return (alloc_con         `appOL`
621                 mkSLIDE 1 (d - s) `snocOL`
622                 ENTER)
623
624    -- Case 4: Tail call of function
625    | otherwise
626    = doTailCall d s p fn args_r_to_l
627
628    where
629       -- Detect and extract relevant info for the tagToEnum kludge.
630       maybe_is_tagToEnum_call
631          = let extract_constr_Names ty
632                  | UnaryRep rep_ty <- repType ty
633                  , Just tyc <- tyConAppTyCon_maybe rep_ty,
634                    isDataTyCon tyc
635                    = map (getName . dataConWorkId) (tyConDataCons tyc)
636                    -- NOTE: use the worker name, not the source name of
637                    -- the DataCon.  See DataCon.lhs for details.
638                  | otherwise
639                    = pprPanic "maybe_is_tagToEnum_call.extract_constr_Ids" (ppr ty)
640            in
641            case app of
642               (AnnApp (_, AnnApp (_, AnnVar v) (_, AnnType t)) arg)
643                  -> case isPrimOpId_maybe v of
644                        Just TagToEnumOp -> Just (snd arg, extract_constr_Names t)
645                        _                -> Nothing
646               _ -> Nothing
647
648         -- Extract the args (R->L) and fn
649         -- The function will necessarily be a variable,
650         -- because we are compiling a tail call
651       (AnnVar fn, args_r_to_l) = splitApp app
652
653       -- Only consider this to be a constructor application iff it is
654       -- saturated.  Otherwise, we'll call the constructor wrapper.
655       n_args = length args_r_to_l
656       maybe_saturated_dcon
657         = case isDataConWorkId_maybe fn of
658                 Just con | dataConRepArity con == n_args -> Just con
659                 _ -> Nothing
660
661 -- -----------------------------------------------------------------------------
662 -- Generate code to build a constructor application,
663 -- leaving it on top of the stack
664
665 mkConAppCode :: Word -> Sequel -> BCEnv
666              -> DataCon                 -- The data constructor
667              -> [AnnExpr' Id VarSet]    -- Args, in *reverse* order
668              -> BcM BCInstrList
669
670 mkConAppCode _ _ _ con []       -- Nullary constructor
671   = ASSERT( isNullaryRepDataCon con )
672     return (unitOL (PUSH_G (getName (dataConWorkId con))))
673         -- Instead of doing a PACK, which would allocate a fresh
674         -- copy of this constructor, use the single shared version.
675
676 mkConAppCode orig_d _ p con args_r_to_l
677   = ASSERT( dataConRepArity con == length args_r_to_l )
678     do_pushery orig_d (non_ptr_args ++ ptr_args)
679  where
680         -- The args are already in reverse order, which is the way PACK
681         -- expects them to be.  We must push the non-ptrs after the ptrs.
682       (ptr_args, non_ptr_args) = partition isPtrAtom args_r_to_l
683
684       do_pushery d (arg:args)
685          = do (push, arg_words) <- pushAtom d p arg
686               more_push_code <- do_pushery (d + fromIntegral arg_words) args
687               return (push `appOL` more_push_code)
688       do_pushery d []
689          = return (unitOL (PACK con n_arg_words))
690          where
691            n_arg_words = trunc16 $ d - orig_d
692
693
694 -- -----------------------------------------------------------------------------
695 -- Returning an unboxed tuple with one non-void component (the only
696 -- case we can handle).
697 --
698 -- Remember, we don't want to *evaluate* the component that is being
699 -- returned, even if it is a pointed type.  We always just return.
700
701 unboxedTupleReturn
702         :: Word -> Sequel -> BCEnv
703         -> AnnExpr' Id VarSet -> BcM BCInstrList
704 unboxedTupleReturn d s p arg = returnUnboxedAtom d s p arg (atomRep arg)
705
706 -- -----------------------------------------------------------------------------
707 -- Generate code for a tail-call
708
709 doTailCall
710         :: Word -> Sequel -> BCEnv
711         -> Id -> [AnnExpr' Id VarSet]
712         -> BcM BCInstrList
713 doTailCall init_d s p fn args
714   = do_pushes init_d args (map atomRep args)
715   where
716   do_pushes d [] reps = do
717         ASSERT( null reps ) return ()
718         (push_fn, sz) <- pushAtom d p (AnnVar fn)
719         ASSERT( sz == 1 ) return ()
720         return (push_fn `appOL` (
721                   mkSLIDE (trunc16 $ d - init_d + 1) (init_d - s) `appOL`
722                   unitOL ENTER))
723   do_pushes d args reps = do
724       let (push_apply, n, rest_of_reps) = findPushSeq reps
725           (these_args, rest_of_args) = splitAt n args
726       (next_d, push_code) <- push_seq d these_args
727       instrs <- do_pushes (next_d + 1) rest_of_args rest_of_reps
728       --                          ^^^ for the PUSH_APPLY_ instruction
729       return (push_code `appOL` (push_apply `consOL` instrs))
730
731   push_seq d [] = return (d, nilOL)
732   push_seq d (arg:args) = do
733     (push_code, sz) <- pushAtom d p arg
734     (final_d, more_push_code) <- push_seq (d + fromIntegral sz) args
735     return (final_d, push_code `appOL` more_push_code)
736
737 -- v. similar to CgStackery.findMatch, ToDo: merge
738 findPushSeq :: [CgRep] -> (BCInstr, Int, [CgRep])
739 findPushSeq (PtrArg: PtrArg: PtrArg: PtrArg: PtrArg: PtrArg: rest)
740   = (PUSH_APPLY_PPPPPP, 6, rest)
741 findPushSeq (PtrArg: PtrArg: PtrArg: PtrArg: PtrArg: rest)
742   = (PUSH_APPLY_PPPPP, 5, rest)
743 findPushSeq (PtrArg: PtrArg: PtrArg: PtrArg: rest)
744   = (PUSH_APPLY_PPPP, 4, rest)
745 findPushSeq (PtrArg: PtrArg: PtrArg: rest)
746   = (PUSH_APPLY_PPP, 3, rest)
747 findPushSeq (PtrArg: PtrArg: rest)
748   = (PUSH_APPLY_PP, 2, rest)
749 findPushSeq (PtrArg: rest)
750   = (PUSH_APPLY_P, 1, rest)
751 findPushSeq (VoidArg: rest)
752   = (PUSH_APPLY_V, 1, rest)
753 findPushSeq (NonPtrArg: rest)
754   = (PUSH_APPLY_N, 1, rest)
755 findPushSeq (FloatArg: rest)
756   = (PUSH_APPLY_F, 1, rest)
757 findPushSeq (DoubleArg: rest)
758   = (PUSH_APPLY_D, 1, rest)
759 findPushSeq (LongArg: rest)
760   = (PUSH_APPLY_L, 1, rest)
761 findPushSeq _
762   = panic "ByteCodeGen.findPushSeq"
763
764 -- -----------------------------------------------------------------------------
765 -- Case expressions
766
767 doCase  :: Word -> Sequel -> BCEnv
768         -> AnnExpr Id VarSet -> Id -> [AnnAlt Id VarSet]
769         -> Maybe Id  -- Just x <=> is an unboxed tuple case with scrut binder, don't enter the result
770         -> BcM BCInstrList
771 doCase d s p (_,scrut) bndr alts is_unboxed_tuple
772   | UbxTupleRep _ <- repType (idType bndr)
773   = unboxedTupleException
774   | otherwise
775   = let
776         -- Top of stack is the return itbl, as usual.
777         -- underneath it is the pointer to the alt_code BCO.
778         -- When an alt is entered, it assumes the returned value is
779         -- on top of the itbl.
780         ret_frame_sizeW :: Word
781         ret_frame_sizeW = 2
782
783         -- An unlifted value gets an extra info table pushed on top
784         -- when it is returned.
785         unlifted_itbl_sizeW :: Word
786         unlifted_itbl_sizeW | isAlgCase = 0
787                             | otherwise = 1
788
789         -- depth of stack after the return value has been pushed
790         d_bndr = d + ret_frame_sizeW + fromIntegral (idSizeW bndr)
791
792         -- depth of stack after the extra info table for an unboxed return
793         -- has been pushed, if any.  This is the stack depth at the
794         -- continuation.
795         d_alts = d_bndr + unlifted_itbl_sizeW
796
797         -- Env in which to compile the alts, not including
798         -- any vars bound by the alts themselves
799         d_bndr' = fromIntegral d_bndr - 1
800         p_alts0 = Map.insert bndr d_bndr' p
801         p_alts = case is_unboxed_tuple of
802                    Just ubx_bndr -> Map.insert ubx_bndr d_bndr' p_alts0
803                    Nothing       -> p_alts0
804
805         bndr_ty = idType bndr
806         isAlgCase = not (isUnLiftedType bndr_ty) && isNothing is_unboxed_tuple
807
808         -- given an alt, return a discr and code for it.
809         codeAlt (DEFAULT, _, (_,rhs))
810            = do rhs_code <- schemeE d_alts s p_alts rhs
811                 return (NoDiscr, rhs_code)
812
813         codeAlt alt@(_, bndrs, (_,rhs))
814            -- primitive or nullary constructor alt: no need to UNPACK
815            | null real_bndrs = do
816                 rhs_code <- schemeE d_alts s p_alts rhs
817                 return (my_discr alt, rhs_code)
818            | any (\bndr -> case repType (idType bndr) of UbxTupleRep _ -> True; _ -> False) bndrs
819            = unboxedTupleException
820            -- algebraic alt with some binders
821            | otherwise =
822              let
823                  (ptrs,nptrs) = partition (isFollowableArg.idCgRep) real_bndrs
824                  ptr_sizes    = map (fromIntegral . idSizeW) ptrs
825                  nptrs_sizes  = map (fromIntegral . idSizeW) nptrs
826                  bind_sizes   = ptr_sizes ++ nptrs_sizes
827                  size         = sum ptr_sizes + sum nptrs_sizes
828                  -- the UNPACK instruction unpacks in reverse order...
829                  p' = Map.insertList
830                         (zip (reverse (ptrs ++ nptrs))
831                           (mkStackOffsets d_alts (reverse bind_sizes)))
832                         p_alts
833              in do
834              MASSERT(isAlgCase)
835              rhs_code <- schemeE (d_alts + size) s p' rhs
836              return (my_discr alt, unitOL (UNPACK (trunc16 size)) `appOL` rhs_code)
837            where
838              real_bndrs = filterOut isTyVar bndrs
839
840         my_discr (DEFAULT, _, _) = NoDiscr {-shouldn't really happen-}
841         my_discr (DataAlt dc, _, _)
842            | isUnboxedTupleCon dc
843            = unboxedTupleException
844            | otherwise
845            = DiscrP (fromIntegral (dataConTag dc - fIRST_TAG))
846         my_discr (LitAlt l, _, _)
847            = case l of MachInt i     -> DiscrI (fromInteger i)
848                        MachWord w    -> DiscrW (fromInteger w)
849                        MachFloat r   -> DiscrF (fromRational r)
850                        MachDouble r  -> DiscrD (fromRational r)
851                        MachChar i    -> DiscrI (ord i)
852                        _ -> pprPanic "schemeE(AnnCase).my_discr" (ppr l)
853
854         maybe_ncons
855            | not isAlgCase = Nothing
856            | otherwise
857            = case [dc | (DataAlt dc, _, _) <- alts] of
858                 []     -> Nothing
859                 (dc:_) -> Just (tyConFamilySize (dataConTyCon dc))
860
861         -- the bitmap is relative to stack depth d, i.e. before the
862         -- BCO, info table and return value are pushed on.
863         -- This bit of code is v. similar to buildLivenessMask in CgBindery,
864         -- except that here we build the bitmap from the known bindings of
865         -- things that are pointers, whereas in CgBindery the code builds the
866         -- bitmap from the free slots and unboxed bindings.
867         -- (ToDo: merge?)
868         --
869         -- NOTE [7/12/2006] bug #1013, testcase ghci/should_run/ghci002.
870         -- The bitmap must cover the portion of the stack up to the sequel only.
871         -- Previously we were building a bitmap for the whole depth (d), but we
872         -- really want a bitmap up to depth (d-s).  This affects compilation of
873         -- case-of-case expressions, which is the only time we can be compiling a
874         -- case expression with s /= 0.
875         bitmap_size = trunc16 $ d-s
876         bitmap_size' :: Int
877         bitmap_size' = fromIntegral bitmap_size
878         bitmap = intsToReverseBitmap bitmap_size'{-size-}
879                         (sort (filter (< bitmap_size') rel_slots))
880           where
881           binds = Map.toList p
882           -- NB: unboxed tuple cases bind the scrut binder to the same offset
883           -- as one of the alt binders, so we have to remove any duplicates here:
884           rel_slots = nub $ map fromIntegral $ concat (map spread binds)
885           spread (id, offset) | isFollowableArg (bcIdCgRep id) = [ rel_offset ]
886                               | otherwise                      = []
887                 where rel_offset = trunc16 $ d - fromIntegral offset - 1
888
889      in do
890      alt_stuff <- mapM codeAlt alts
891      alt_final <- mkMultiBranch maybe_ncons alt_stuff
892
893      let
894          alt_bco_name = getName bndr
895          alt_bco = mkProtoBCO alt_bco_name alt_final (Left alts)
896                        0{-no arity-} bitmap_size bitmap True{-is alts-}
897 --     trace ("case: bndr = " ++ showSDocDebug (ppr bndr) ++ "\ndepth = " ++ show d ++ "\nenv = \n" ++ showSDocDebug (ppBCEnv p) ++
898 --            "\n      bitmap = " ++ show bitmap) $ do
899      scrut_code <- schemeE (d + ret_frame_sizeW)
900                            (d + ret_frame_sizeW)
901                            p scrut
902      alt_bco' <- emitBc alt_bco
903      let push_alts
904             | isAlgCase = PUSH_ALTS alt_bco'
905             | otherwise = PUSH_ALTS_UNLIFTED alt_bco' (typeCgRep bndr_ty)
906      return (push_alts `consOL` scrut_code)
907
908
909 -- -----------------------------------------------------------------------------
910 -- Deal with a CCall.
911
912 -- Taggedly push the args onto the stack R->L,
913 -- deferencing ForeignObj#s and adjusting addrs to point to
914 -- payloads in Ptr/Byte arrays.  Then, generate the marshalling
915 -- (machine) code for the ccall, and create bytecodes to call that and
916 -- then return in the right way.
917
918 generateCCall :: Word -> Sequel         -- stack and sequel depths
919               -> BCEnv
920               -> CCallSpec              -- where to call
921               -> Id                     -- of target, for type info
922               -> [AnnExpr' Id VarSet]   -- args (atoms)
923               -> BcM BCInstrList
924
925 generateCCall d0 s p (CCallSpec target cconv safety) fn args_r_to_l
926    = let
927          -- useful constants
928          addr_sizeW :: Word16
929          addr_sizeW = fromIntegral (cgRepSizeW NonPtrArg)
930
931          -- Get the args on the stack, with tags and suitably
932          -- dereferenced for the CCall.  For each arg, return the
933          -- depth to the first word of the bits for that arg, and the
934          -- CgRep of what was actually pushed.
935
936          pargs _ [] = return []
937          pargs d (a:az)
938             = let UnaryRep arg_ty = repType (exprType (deAnnotate' a))
939
940               in case tyConAppTyCon_maybe arg_ty of
941                     -- Don't push the FO; instead push the Addr# it
942                     -- contains.
943                     Just t
944                      | t == arrayPrimTyCon || t == mutableArrayPrimTyCon
945                        -> do dflags <- getDynFlags
946                              rest <- pargs (d + fromIntegral addr_sizeW) az
947                              code <- parg_ArrayishRep (fromIntegral (arrPtrsHdrSize dflags)) d p a
948                              return ((code,AddrRep):rest)
949
950                      | t == byteArrayPrimTyCon || t == mutableByteArrayPrimTyCon
951                        -> do dflags <- getDynFlags
952                              rest <- pargs (d + fromIntegral addr_sizeW) az
953                              code <- parg_ArrayishRep (fromIntegral (arrWordsHdrSize dflags)) d p a
954                              return ((code,AddrRep):rest)
955
956                     -- Default case: push taggedly, but otherwise intact.
957                     _
958                        -> do (code_a, sz_a) <- pushAtom d p a
959                              rest <- pargs (d + fromIntegral sz_a) az
960                              return ((code_a, atomPrimRep a) : rest)
961
962          -- Do magic for Ptr/Byte arrays.  Push a ptr to the array on
963          -- the stack but then advance it over the headers, so as to
964          -- point to the payload.
965          parg_ArrayishRep :: Word16 -> Word -> BCEnv -> AnnExpr' Id VarSet
966                           -> BcM BCInstrList
967          parg_ArrayishRep hdrSize d p a
968             = do (push_fo, _) <- pushAtom d p a
969                  -- The ptr points at the header.  Advance it over the
970                  -- header and then pretend this is an Addr#.
971                  return (push_fo `snocOL` SWIZZLE 0 hdrSize)
972
973      in do
974      code_n_reps <- pargs d0 args_r_to_l
975      let
976          (pushs_arg, a_reps_pushed_r_to_l) = unzip code_n_reps
977          a_reps_sizeW = fromIntegral (sum (map primRepSizeW a_reps_pushed_r_to_l))
978
979          push_args    = concatOL pushs_arg
980          d_after_args = d0 + a_reps_sizeW
981          a_reps_pushed_RAW
982             | null a_reps_pushed_r_to_l || head a_reps_pushed_r_to_l /= VoidRep
983             = panic "ByteCodeGen.generateCCall: missing or invalid World token?"
984             | otherwise
985             = reverse (tail a_reps_pushed_r_to_l)
986
987          -- Now: a_reps_pushed_RAW are the reps which are actually on the stack.
988          -- push_args is the code to do that.
989          -- d_after_args is the stack depth once the args are on.
990
991          -- Get the result rep.
992          (returns_void, r_rep)
993             = case maybe_getCCallReturnRep (idType fn) of
994                  Nothing -> (True,  VoidRep)
995                  Just rr -> (False, rr)
996          {-
997          Because the Haskell stack grows down, the a_reps refer to
998          lowest to highest addresses in that order.  The args for the call
999          are on the stack.  Now push an unboxed Addr# indicating
1000          the C function to call.  Then push a dummy placeholder for the
1001          result.  Finally, emit a CCALL insn with an offset pointing to the
1002          Addr# just pushed, and a literal field holding the mallocville
1003          address of the piece of marshalling code we generate.
1004          So, just prior to the CCALL insn, the stack looks like this
1005          (growing down, as usual):
1006
1007             <arg_n>
1008             ...
1009             <arg_1>
1010             Addr# address_of_C_fn
1011             <placeholder-for-result#> (must be an unboxed type)
1012
1013          The interpreter then calls the marshall code mentioned
1014          in the CCALL insn, passing it (& <placeholder-for-result#>),
1015          that is, the addr of the topmost word in the stack.
1016          When this returns, the placeholder will have been
1017          filled in.  The placeholder is slid down to the sequel
1018          depth, and we RETURN.
1019
1020          This arrangement makes it simple to do f-i-dynamic since the Addr#
1021          value is the first arg anyway.
1022
1023          The marshalling code is generated specifically for this
1024          call site, and so knows exactly the (Haskell) stack
1025          offsets of the args, fn address and placeholder.  It
1026          copies the args to the C stack, calls the stacked addr,
1027          and parks the result back in the placeholder.  The interpreter
1028          calls it as a normal C call, assuming it has a signature
1029             void marshall_code ( StgWord* ptr_to_top_of_stack )
1030          -}
1031          -- resolve static address
1032          get_target_info
1033             = case target of
1034                  DynamicTarget
1035                     -> return (False, panic "ByteCodeGen.generateCCall(dyn)")
1036
1037                  StaticTarget _ _ False ->
1038                      panic "generateCCall: unexpected FFI value import"
1039                  StaticTarget target _ True
1040                     -> do res <- ioToBc (lookupStaticPtr stdcall_adj_target)
1041                           return (True, res)
1042                    where
1043                       stdcall_adj_target
1044 #ifdef mingw32_TARGET_OS
1045                           | StdCallConv <- cconv
1046                           = let size = fromIntegral a_reps_sizeW * wORD_SIZE in
1047                             mkFastString (unpackFS target ++ '@':show size)
1048 #endif
1049                           | otherwise
1050                           = target
1051
1052      (is_static, static_target_addr) <- get_target_info
1053      let
1054
1055          -- Get the arg reps, zapping the leading Addr# in the dynamic case
1056          a_reps --  | trace (showSDoc (ppr a_reps_pushed_RAW)) False = error "???"
1057                 | is_static = a_reps_pushed_RAW
1058                 | otherwise = if null a_reps_pushed_RAW
1059                               then panic "ByteCodeGen.generateCCall: dyn with no args"
1060                               else tail a_reps_pushed_RAW
1061
1062          -- push the Addr#
1063          (push_Addr, d_after_Addr)
1064             | is_static
1065             = (toOL [PUSH_UBX (Right static_target_addr) addr_sizeW],
1066                d_after_args + fromIntegral addr_sizeW)
1067             | otherwise -- is already on the stack
1068             = (nilOL, d_after_args)
1069
1070          -- Push the return placeholder.  For a call returning nothing,
1071          -- this is a VoidArg (tag).
1072          r_sizeW   = fromIntegral (primRepSizeW r_rep)
1073          d_after_r = d_after_Addr + fromIntegral r_sizeW
1074          r_lit     = mkDummyLiteral r_rep
1075          push_r    = (if   returns_void
1076                       then nilOL
1077                       else unitOL (PUSH_UBX (Left r_lit) r_sizeW))
1078
1079          -- generate the marshalling code we're going to call
1080
1081          -- Offset of the next stack frame down the stack.  The CCALL
1082          -- instruction needs to describe the chunk of stack containing
1083          -- the ccall args to the GC, so it needs to know how large it
1084          -- is.  See comment in Interpreter.c with the CCALL instruction.
1085          stk_offset   = trunc16 $ d_after_r - s
1086
1087      -- the only difference in libffi mode is that we prepare a cif
1088      -- describing the call type by calling libffi, and we attach the
1089      -- address of this to the CCALL instruction.
1090      token <- ioToBc $ prepForeignCall cconv a_reps r_rep
1091      let addr_of_marshaller = castPtrToFunPtr token
1092
1093      recordItblMallocBc (ItblPtr (castFunPtrToPtr addr_of_marshaller))
1094      let
1095          -- do the call
1096          do_call      = unitOL (CCALL stk_offset (castFunPtrToPtr addr_of_marshaller)
1097                                  (fromIntegral (fromEnum (playInterruptible safety))))
1098          -- slide and return
1099          wrapup       = mkSLIDE r_sizeW (d_after_r - fromIntegral r_sizeW - s)
1100                         `snocOL` RETURN_UBX (primRepToCgRep r_rep)
1101          --trace (show (arg1_offW, args_offW  ,  (map cgRepSizeW a_reps) )) $
1102      return (
1103          push_args `appOL`
1104          push_Addr `appOL` push_r `appOL` do_call `appOL` wrapup
1105          )
1106
1107 -- Make a dummy literal, to be used as a placeholder for FFI return
1108 -- values on the stack.
1109 mkDummyLiteral :: PrimRep -> Literal
1110 mkDummyLiteral pr
1111    = case pr of
1112         IntRep    -> MachInt 0
1113         WordRep   -> MachWord 0
1114         AddrRep   -> MachNullAddr
1115         DoubleRep -> MachDouble 0
1116         FloatRep  -> MachFloat 0
1117         Int64Rep  -> MachInt64 0
1118         Word64Rep -> MachWord64 0
1119         _         -> panic "mkDummyLiteral"
1120
1121
1122 -- Convert (eg)
1123 --     GHC.Prim.Char# -> GHC.Prim.State# GHC.Prim.RealWorld
1124 --                   -> (# GHC.Prim.State# GHC.Prim.RealWorld, GHC.Prim.Int# #)
1125 --
1126 -- to  Just IntRep
1127 -- and check that an unboxed pair is returned wherein the first arg is VoidArg'd.
1128 --
1129 -- Alternatively, for call-targets returning nothing, convert
1130 --
1131 --     GHC.Prim.Char# -> GHC.Prim.State# GHC.Prim.RealWorld
1132 --                   -> (# GHC.Prim.State# GHC.Prim.RealWorld #)
1133 --
1134 -- to  Nothing
1135
1136 maybe_getCCallReturnRep :: Type -> Maybe PrimRep
1137 maybe_getCCallReturnRep fn_ty
1138    = let (_a_tys, r_ty) = splitFunTys (dropForAlls fn_ty)
1139          maybe_r_rep_to_go
1140             = if isSingleton r_reps then Nothing else Just (r_reps !! 1)
1141          r_reps = case repType r_ty of
1142                       UbxTupleRep reps -> map typePrimRep reps
1143                       UnaryRep _       -> blargh
1144          ok = ( ( r_reps `lengthIs` 2 && VoidRep == head r_reps)
1145                 || r_reps == [VoidRep] )
1146               && case maybe_r_rep_to_go of
1147                     Nothing    -> True
1148                     Just r_rep -> r_rep /= PtrRep
1149                                   -- if it was, it would be impossible
1150                                   -- to create a valid return value
1151                                   -- placeholder on the stack
1152
1153          blargh :: a -- Used at more than one type
1154          blargh = pprPanic "maybe_getCCallReturn: can't handle:"
1155                            (pprType fn_ty)
1156      in
1157      --trace (showSDoc (ppr (a_reps, r_reps))) $
1158      if ok then maybe_r_rep_to_go else blargh
1159
1160 -- Compile code which expects an unboxed Int on the top of stack,
1161 -- (call it i), and pushes the i'th closure in the supplied list
1162 -- as a consequence.
1163 implement_tagToId :: [Name] -> BcM BCInstrList
1164 implement_tagToId names
1165    = ASSERT( notNull names )
1166      do labels <- getLabelsBc (genericLength names)
1167         label_fail <- getLabelBc
1168         label_exit <- getLabelBc
1169         let infos = zip4 labels (tail labels ++ [label_fail])
1170                                 [0 ..] names
1171             steps = map (mkStep label_exit) infos
1172         return (concatOL steps
1173                   `appOL`
1174                   toOL [LABEL label_fail, CASEFAIL, LABEL label_exit])
1175      where
1176         mkStep l_exit (my_label, next_label, n, name_for_n)
1177            = toOL [LABEL my_label,
1178                    TESTEQ_I n next_label,
1179                    PUSH_G name_for_n,
1180                    JMP l_exit]
1181
1182
1183 -- -----------------------------------------------------------------------------
1184 -- pushAtom
1185
1186 -- Push an atom onto the stack, returning suitable code & number of
1187 -- stack words used.
1188 --
1189 -- The env p must map each variable to the highest- numbered stack
1190 -- slot for it.  For example, if the stack has depth 4 and we
1191 -- tagged-ly push (v :: Int#) on it, the value will be in stack[4],
1192 -- the tag in stack[5], the stack will have depth 6, and p must map v
1193 -- to 5 and not to 4.  Stack locations are numbered from zero, so a
1194 -- depth 6 stack has valid words 0 .. 5.
1195
1196 pushAtom :: Word -> BCEnv -> AnnExpr' Id VarSet -> BcM (BCInstrList, Word16)
1197
1198 pushAtom d p e
1199    | Just e' <- bcView e
1200    = pushAtom d p e'
1201
1202 pushAtom _ _ (AnnCoercion {})   -- Coercions are zero-width things, 
1203    = return (nilOL, 0)          -- treated just like a variable VoidArg
1204
1205 pushAtom d p (AnnVar v)
1206    | UnaryRep rep_ty <- repType (idType v)
1207    , VoidArg <- typeCgRep rep_ty
1208    = return (nilOL, 0)
1209
1210    | isFCallId v
1211    = pprPanic "pushAtom: shouldn't get an FCallId here" (ppr v)
1212
1213    | Just primop <- isPrimOpId_maybe v
1214    = return (unitOL (PUSH_PRIMOP primop), 1)
1215
1216    | Just d_v <- lookupBCEnv_maybe v p  -- v is a local variable
1217    = let l = trunc16 $ d - d_v + fromIntegral sz - 2
1218      in return (toOL (genericReplicate sz (PUSH_L l)), sz)
1219          -- d - d_v                 the number of words between the TOS
1220          --                         and the 1st slot of the object
1221          --
1222          -- d - d_v - 1             the offset from the TOS of the 1st slot
1223          --
1224          -- d - d_v - 1 + sz - 1    the offset from the TOS of the last slot
1225          --                         of the object.
1226          --
1227          -- Having found the last slot, we proceed to copy the right number of
1228          -- slots on to the top of the stack.
1229
1230     | otherwise  -- v must be a global variable
1231     = ASSERT(sz == 1)
1232       return (unitOL (PUSH_G (getName v)), sz)
1233
1234     where
1235          sz :: Word16
1236          sz = fromIntegral (idSizeW v)
1237
1238
1239 pushAtom _ _ (AnnLit lit)
1240    = case lit of
1241         MachLabel _ _ _ -> code NonPtrArg
1242         MachWord _    -> code NonPtrArg
1243         MachInt _     -> code NonPtrArg
1244         MachWord64 _  -> code LongArg
1245         MachInt64 _   -> code LongArg
1246         MachFloat _   -> code FloatArg
1247         MachDouble _  -> code DoubleArg
1248         MachChar _    -> code NonPtrArg
1249         MachNullAddr  -> code NonPtrArg
1250         MachStr s     -> pushStr s
1251         -- No LitInteger's should be left by the time this is called.
1252         -- CorePrep should have converted them all to a real core
1253         -- representation.
1254         LitInteger {} -> panic "pushAtom: LitInteger"
1255      where
1256         code rep
1257            = let size_host_words = fromIntegral (cgRepSizeW rep)
1258              in  return (unitOL (PUSH_UBX (Left lit) size_host_words),
1259                            size_host_words)
1260
1261         pushStr s
1262            = let getMallocvilleAddr
1263                     = case s of
1264                          FastBytes n fp ->
1265                             -- we could grab the Ptr from the ForeignPtr,
1266                             -- but then we have no way to control its lifetime.
1267                             -- In reality it'll probably stay alive long enoungh
1268                             -- by virtue of the global FastString table, but
1269                             -- to be on the safe side we copy the string into
1270                             -- a malloc'd area of memory.
1271                                 do ptr <- ioToBc (mallocBytes (n+1))
1272                                    recordMallocBc ptr
1273                                    ioToBc (
1274                                       withForeignPtr fp $ \p -> do
1275                                          memcpy ptr p (fromIntegral n)
1276                                          pokeByteOff ptr n (fromIntegral (ord '\0') :: Word8)
1277                                          return ptr
1278                                       )
1279              in do
1280                 addr <- getMallocvilleAddr
1281                 -- Get the addr on the stack, untaggedly
1282                 return (unitOL (PUSH_UBX (Right addr) 1), 1)
1283
1284 pushAtom _ _ expr
1285    = pprPanic "ByteCodeGen.pushAtom"
1286               (pprCoreExpr (deAnnotate (undefined, expr)))
1287
1288 foreign import ccall unsafe "memcpy"
1289  memcpy :: Ptr a -> Ptr b -> CSize -> IO ()
1290
1291
1292 -- -----------------------------------------------------------------------------
1293 -- Given a bunch of alts code and their discrs, do the donkey work
1294 -- of making a multiway branch using a switch tree.
1295 -- What a load of hassle!
1296
1297 mkMultiBranch :: Maybe Int      -- # datacons in tycon, if alg alt
1298                                 -- a hint; generates better code
1299                                 -- Nothing is always safe
1300               -> [(Discr, BCInstrList)]
1301               -> BcM BCInstrList
1302 mkMultiBranch maybe_ncons raw_ways = do
1303      lbl_default <- getLabelBc
1304
1305      let
1306          mkTree :: [(Discr, BCInstrList)] -> Discr -> Discr -> BcM BCInstrList
1307          mkTree [] _range_lo _range_hi = return (unitOL (JMP lbl_default))
1308              -- shouldn't happen?
1309
1310          mkTree [val] range_lo range_hi
1311             | range_lo == range_hi
1312             = return (snd val)
1313             | null defaults -- Note [CASEFAIL]
1314             = do lbl <- getLabelBc
1315                  return (testEQ (fst val) lbl
1316                             `consOL` (snd val
1317                             `appOL`  (LABEL lbl `consOL` unitOL CASEFAIL)))
1318             | otherwise
1319             = return (testEQ (fst val) lbl_default `consOL` snd val)
1320
1321             -- Note [CASEFAIL] It may be that this case has no default
1322             -- branch, but the alternatives are not exhaustive - this
1323             -- happens for GADT cases for example, where the types
1324             -- prove that certain branches are impossible.  We could
1325             -- just assume that the other cases won't occur, but if
1326             -- this assumption was wrong (because of a bug in GHC)
1327             -- then the result would be a segfault.  So instead we
1328             -- emit an explicit test and a CASEFAIL instruction that
1329             -- causes the interpreter to barf() if it is ever
1330             -- executed.
1331
1332          mkTree vals range_lo range_hi
1333             = let n = length vals `div` 2
1334                   vals_lo = take n vals
1335                   vals_hi = drop n vals
1336                   v_mid = fst (head vals_hi)
1337               in do
1338               label_geq <- getLabelBc
1339               code_lo <- mkTree vals_lo range_lo (dec v_mid)
1340               code_hi <- mkTree vals_hi v_mid range_hi
1341               return (testLT v_mid label_geq
1342                       `consOL` (code_lo
1343                       `appOL`   unitOL (LABEL label_geq)
1344                       `appOL`   code_hi))
1345
1346          the_default
1347             = case defaults of
1348                 []         -> nilOL
1349                 [(_, def)] -> LABEL lbl_default `consOL` def
1350                 _          -> panic "mkMultiBranch/the_default"
1351      instrs <- mkTree notd_ways init_lo init_hi
1352      return (instrs `appOL` the_default)
1353   where
1354          (defaults, not_defaults) = partition (isNoDiscr.fst) raw_ways
1355          notd_ways = sortBy (comparing fst) not_defaults
1356
1357          testLT (DiscrI i) fail_label = TESTLT_I i fail_label
1358          testLT (DiscrW i) fail_label = TESTLT_W i fail_label
1359          testLT (DiscrF i) fail_label = TESTLT_F i fail_label
1360          testLT (DiscrD i) fail_label = TESTLT_D i fail_label
1361          testLT (DiscrP i) fail_label = TESTLT_P i fail_label
1362          testLT NoDiscr    _          = panic "mkMultiBranch NoDiscr"
1363
1364          testEQ (DiscrI i) fail_label = TESTEQ_I i fail_label
1365          testEQ (DiscrW i) fail_label = TESTEQ_W i fail_label
1366          testEQ (DiscrF i) fail_label = TESTEQ_F i fail_label
1367          testEQ (DiscrD i) fail_label = TESTEQ_D i fail_label
1368          testEQ (DiscrP i) fail_label = TESTEQ_P i fail_label
1369          testEQ NoDiscr    _          = panic "mkMultiBranch NoDiscr"
1370
1371          -- None of these will be needed if there are no non-default alts
1372          (init_lo, init_hi)
1373             | null notd_ways
1374             = panic "mkMultiBranch: awesome foursome"
1375             | otherwise
1376             = case fst (head notd_ways) of
1377                 DiscrI _ -> ( DiscrI minBound,  DiscrI maxBound )
1378                 DiscrW _ -> ( DiscrW minBound,  DiscrW maxBound )
1379                 DiscrF _ -> ( DiscrF minF,      DiscrF maxF )
1380                 DiscrD _ -> ( DiscrD minD,      DiscrD maxD )
1381                 DiscrP _ -> ( DiscrP algMinBound, DiscrP algMaxBound )
1382                 NoDiscr -> panic "mkMultiBranch NoDiscr"
1383
1384          (algMinBound, algMaxBound)
1385             = case maybe_ncons of
1386                  -- XXX What happens when n == 0?
1387                  Just n  -> (0, fromIntegral n - 1)
1388                  Nothing -> (minBound, maxBound)
1389
1390          isNoDiscr NoDiscr = True
1391          isNoDiscr _       = False
1392
1393          dec (DiscrI i) = DiscrI (i-1)
1394          dec (DiscrW w) = DiscrW (w-1)
1395          dec (DiscrP i) = DiscrP (i-1)
1396          dec other      = other         -- not really right, but if you
1397                 -- do cases on floating values, you'll get what you deserve
1398
1399          -- same snotty comment applies to the following
1400          minF, maxF :: Float
1401          minD, maxD :: Double
1402          minF = -1.0e37
1403          maxF =  1.0e37
1404          minD = -1.0e308
1405          maxD =  1.0e308
1406
1407
1408 -- -----------------------------------------------------------------------------
1409 -- Supporting junk for the compilation schemes
1410
1411 -- Describes case alts
1412 data Discr
1413    = DiscrI Int
1414    | DiscrW Word
1415    | DiscrF Float
1416    | DiscrD Double
1417    | DiscrP Word16
1418    | NoDiscr
1419     deriving (Eq, Ord)
1420
1421 instance Outputable Discr where
1422    ppr (DiscrI i) = int i
1423    ppr (DiscrW w) = text (show w)
1424    ppr (DiscrF f) = text (show f)
1425    ppr (DiscrD d) = text (show d)
1426    ppr (DiscrP i) = ppr i
1427    ppr NoDiscr    = text "DEF"
1428
1429
1430 lookupBCEnv_maybe :: Id -> BCEnv -> Maybe Word
1431 lookupBCEnv_maybe = Map.lookup
1432
1433 idSizeW :: Id -> Int
1434 idSizeW = cgRepSizeW . bcIdCgRep
1435
1436 bcIdCgRep :: Id -> CgRep
1437 bcIdCgRep = primRepToCgRep . bcIdPrimRep
1438
1439 bcIdPrimRep :: Id -> PrimRep
1440 bcIdPrimRep = typePrimRep . bcIdUnaryType
1441
1442 bcIdUnaryType :: Id -> UnaryType
1443 bcIdUnaryType x = case repType (idType x) of
1444     UnaryRep rep_ty -> rep_ty
1445     UbxTupleRep [rep_ty] -> rep_ty
1446     UbxTupleRep [rep_ty1, rep_ty2]
1447       | VoidRep <- typePrimRep rep_ty1 -> rep_ty2
1448       | VoidRep <- typePrimRep rep_ty2 -> rep_ty1
1449     _ -> pprPanic "bcIdUnaryType" (ppr x $$ ppr (idType x))
1450
1451 -- See bug #1257
1452 unboxedTupleException :: a
1453 unboxedTupleException
1454    = ghcError
1455         (ProgramError
1456            ("Error: bytecode compiler can't handle unboxed tuples.\n"++
1457             "  Possibly due to foreign import/export decls in source.\n"++
1458             "  Workaround: use -fobject-code, or compile this module to .o separately."))
1459
1460
1461 mkSLIDE :: Word16 -> Word -> OrdList BCInstr
1462 mkSLIDE n d
1463     -- if the amount to slide doesn't fit in a word,
1464     -- generate multiple slide instructions
1465     | d > fromIntegral limit
1466     = SLIDE n limit `consOL` mkSLIDE n (d - fromIntegral limit)
1467     | d == 0
1468     = nilOL
1469     | otherwise
1470     = if d == 0 then nilOL else unitOL (SLIDE n $ fromIntegral d)
1471     where
1472         limit :: Word16
1473         limit = maxBound
1474
1475 splitApp :: AnnExpr' Var ann -> (AnnExpr' Var ann, [AnnExpr' Var ann])
1476         -- The arguments are returned in *right-to-left* order
1477 splitApp e | Just e' <- bcView e = splitApp e'
1478 splitApp (AnnApp (_,f) (_,a))    = case splitApp f of
1479                                       (f', as) -> (f', a:as)
1480 splitApp e                       = (e, [])
1481
1482
1483 bcView :: AnnExpr' Var ann -> Maybe (AnnExpr' Var ann)
1484 -- The "bytecode view" of a term discards
1485 --  a) type abstractions
1486 --  b) type applications
1487 --  c) casts
1488 --  d) ticks (but not breakpoints)
1489 -- Type lambdas *can* occur in random expressions,
1490 -- whereas value lambdas cannot; that is why they are nuked here
1491 bcView (AnnCast (_,e) _)             = Just e
1492 bcView (AnnLam v (_,e)) | isTyVar v  = Just e
1493 bcView (AnnApp (_,e) (_, AnnType _)) = Just e
1494 bcView (AnnTick Breakpoint{} _)      = Nothing
1495 bcView (AnnTick _other_tick (_,e))   = Just e
1496 bcView _                             = Nothing
1497
1498 isVoidArgAtom :: AnnExpr' Var ann -> Bool
1499 isVoidArgAtom e | Just e' <- bcView e = isVoidArgAtom e'
1500 isVoidArgAtom (AnnVar v)              = bcIdCgRep v == VoidArg
1501 isVoidArgAtom (AnnCoercion {})        = True
1502 isVoidArgAtom _                       = False
1503
1504 atomPrimRep :: AnnExpr' Id ann -> PrimRep
1505 atomPrimRep e | Just e' <- bcView e = atomPrimRep e'
1506 atomPrimRep (AnnVar v)              = bcIdPrimRep v
1507 atomPrimRep (AnnLit l)              = typePrimRep (literalType l)
1508 atomPrimRep (AnnCoercion {})        = VoidRep
1509 atomPrimRep other = pprPanic "atomPrimRep" (ppr (deAnnotate (undefined,other)))
1510
1511 atomRep :: AnnExpr' Id ann -> CgRep
1512 atomRep e = primRepToCgRep (atomPrimRep e)
1513
1514 isPtrAtom :: AnnExpr' Id ann -> Bool
1515 isPtrAtom e = atomRep e == PtrArg
1516
1517 -- Let szsw be the sizes in words of some items pushed onto the stack,
1518 -- which has initial depth d'.  Return the values which the stack environment
1519 -- should map these items to.
1520 mkStackOffsets :: Word -> [Word] -> [Word]
1521 mkStackOffsets original_depth szsw
1522    = map (subtract 1) (tail (scanl (+) original_depth szsw))
1523
1524 -- -----------------------------------------------------------------------------
1525 -- The bytecode generator's monad
1526
1527 type BcPtr = Either ItblPtr (Ptr ())
1528
1529 data BcM_State
1530    = BcM_State
1531         { bcm_dflags :: DynFlags
1532         , uniqSupply :: UniqSupply       -- for generating fresh variable names
1533         , thisModule :: Module           -- current module (for breakpoints)
1534         , nextlabel :: Word16            -- for generating local labels
1535         , malloced  :: [BcPtr]           -- thunks malloced for current BCO
1536                                          -- Should be free()d when it is GCd
1537         , breakArray :: BreakArray       -- array of breakpoint flags
1538         }
1539
1540 newtype BcM r = BcM (BcM_State -> IO (BcM_State, r))
1541
1542 ioToBc :: IO a -> BcM a
1543 ioToBc io = BcM $ \st -> do
1544   x <- io
1545   return (st, x)
1546
1547 runBc :: DynFlags -> UniqSupply -> Module -> ModBreaks -> BcM r
1548       -> IO (BcM_State, r)
1549 runBc dflags us this_mod modBreaks (BcM m)
1550    = m (BcM_State dflags us this_mod 0 [] breakArray)
1551    where
1552    breakArray = modBreaks_flags modBreaks
1553
1554 thenBc :: BcM a -> (a -> BcM b) -> BcM b
1555 thenBc (BcM expr) cont = BcM $ \st0 -> do
1556   (st1, q) <- expr st0
1557   let BcM k = cont q
1558   (st2, r) <- k st1
1559   return (st2, r)
1560
1561 thenBc_ :: BcM a -> BcM b -> BcM b
1562 thenBc_ (BcM expr) (BcM cont) = BcM $ \st0 -> do
1563   (st1, _) <- expr st0
1564   (st2, r) <- cont st1
1565   return (st2, r)
1566
1567 returnBc :: a -> BcM a
1568 returnBc result = BcM $ \st -> (return (st, result))
1569
1570 instance Monad BcM where
1571   (>>=) = thenBc
1572   (>>)  = thenBc_
1573   return = returnBc
1574
1575 instance HasDynFlags BcM where
1576     getDynFlags = BcM $ \st -> return (st, bcm_dflags st)
1577
1578 emitBc :: ([BcPtr] -> ProtoBCO Name) -> BcM (ProtoBCO Name)
1579 emitBc bco
1580   = BcM $ \st -> return (st{malloced=[]}, bco (malloced st))
1581
1582 recordMallocBc :: Ptr a -> BcM ()
1583 recordMallocBc a
1584   = BcM $ \st -> return (st{malloced = Right (castPtr a) : malloced st}, ())
1585
1586 recordItblMallocBc :: ItblPtr -> BcM ()
1587 recordItblMallocBc a
1588   = BcM $ \st -> return (st{malloced = Left a : malloced st}, ())
1589
1590 getLabelBc :: BcM Word16
1591 getLabelBc
1592   = BcM $ \st -> do let nl = nextlabel st
1593                     when (nl == maxBound) $
1594                         panic "getLabelBc: Ran out of labels"
1595                     return (st{nextlabel = nl + 1}, nl)
1596
1597 getLabelsBc :: Word16 -> BcM [Word16]
1598 getLabelsBc n
1599   = BcM $ \st -> let ctr = nextlabel st
1600                  in return (st{nextlabel = ctr+n}, [ctr .. ctr+n-1])
1601
1602 getBreakArray :: BcM BreakArray
1603 getBreakArray = BcM $ \st -> return (st, breakArray st)
1604
1605 newUnique :: BcM Unique
1606 newUnique = BcM $
1607    \st -> case takeUniqFromSupply (uniqSupply st) of
1608              (uniq, us) -> let newState = st { uniqSupply = us }
1609                            in  return (newState, uniq)
1610
1611 getCurrentModule :: BcM Module
1612 getCurrentModule = BcM $ \st -> return (st, thisModule st)
1613
1614 newId :: Type -> BcM Id
1615 newId ty = do
1616     uniq <- newUnique
1617     return $ mkSysLocal tickFS uniq ty
1618
1619 tickFS :: FastString
1620 tickFS = fsLit "ticked"
1621 \end{code}