Catch a few more typos in comments
[ghc.git] / libraries / base / configure.ac
1 AC_PREREQ([2.60])
2 AC_INIT([Haskell base package], [1.0], [libraries@haskell.org], [base])
3
4 # Safety check: Ensure that we are in the correct source directory.
5 AC_CONFIG_SRCDIR([include/HsBase.h])
6
7 AC_CONFIG_HEADERS([include/HsBaseConfig.h include/EventConfig.h])
8
9 AC_CANONICAL_BUILD
10 AC_CANONICAL_HOST
11 AC_CANONICAL_TARGET
12
13 AC_PROG_CC
14 dnl make extensions visible to allow feature-tests to detect them lateron
15 AC_USE_SYSTEM_EXTENSIONS
16
17 AC_MSG_CHECKING(for WINDOWS platform)
18 case $host in
19     *mingw32*|*mingw64*|*cygwin*|*msys*)
20         WINDOWS=YES;;
21     *)
22         WINDOWS=NO;;
23 esac
24 AC_MSG_RESULT($WINDOWS)
25
26 # do we have long longs?
27 AC_CHECK_TYPES([long long])
28
29 dnl ** check for full ANSI header (.h) files
30 AC_HEADER_STDC
31
32 # check for specific header (.h) files that we are interested in
33 AC_CHECK_HEADERS([ctype.h errno.h fcntl.h inttypes.h limits.h signal.h sys/file.h sys/resource.h sys/select.h sys/stat.h sys/syscall.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/types.h sys/utsname.h sys/wait.h termios.h time.h unistd.h utime.h windows.h winsock.h langinfo.h poll.h sys/epoll.h sys/event.h sys/eventfd.h])
34
35 # Enable large file support. Do this before testing the types ino_t, off_t, and
36 # rlim_t, because it will affect the result of that test.
37 AC_SYS_LARGEFILE
38
39 dnl ** check for wide-char classifications
40 dnl FreeBSD has an emtpy wctype.h, so test one of the affected
41 dnl functions if it's really there.
42 AC_CHECK_HEADERS([wctype.h], [AC_CHECK_FUNCS(iswspace)])
43
44 AC_CHECK_FUNCS([lstat])
45 AC_CHECK_LIB([rt], [clock_gettime])
46 AC_CHECK_FUNCS([clock_gettime])
47 AC_CHECK_FUNCS([getclock getrusage times])
48 AC_CHECK_FUNCS([_chsize ftruncate])
49
50 AC_CHECK_FUNCS([epoll_ctl eventfd kevent kevent64 kqueue poll])
51
52 # event-related fun
53
54 if test "$ac_cv_header_sys_epoll_h" = yes && test "$ac_cv_func_epoll_ctl" = yes; then
55   AC_DEFINE([HAVE_EPOLL], [1], [Define if you have epoll support.])
56 fi
57
58 if test "$ac_cv_header_sys_event_h" = yes && test "$ac_cv_func_kqueue" = yes; then
59   AC_DEFINE([HAVE_KQUEUE], [1], [Define if you have kqueue support.])
60
61   AC_CHECK_SIZEOF([kev.filter], [], [#include <sys/event.h>
62 struct kevent kev;])
63
64   AC_CHECK_SIZEOF([kev.flags], [], [#include <sys/event.h>
65 struct kevent kev;])
66 fi
67
68 if test "$ac_cv_header_poll_h" = yes && test "$ac_cv_func_poll" = yes; then
69   AC_DEFINE([HAVE_POLL], [1], [Define if you have poll support.])
70 fi
71
72 # Linux open file descriptor locks
73 AC_CHECK_DECL([F_OFD_SETLK], [
74   AC_DEFINE([HAVE_OFD_LOCKING], [1], [Define if you have open file descriptor lock support.])
75 ])
76
77 # flock
78 AC_CHECK_FUNCS([flock])
79 if test "$ac_cv_header_sys_file_h" = yes && test "$ac_cv_func_flock" = yes; then
80   AC_DEFINE([HAVE_FLOCK], [1], [Define if you have flock support.])
81 fi
82
83 # unsetenv
84 AC_CHECK_FUNCS([unsetenv])
85
86 ###  POSIX.1003.1 unsetenv returns 0 or -1 (EINVAL), but older implementations
87 ###  in common use return void.
88 AC_CACHE_CHECK([return type of unsetenv], fptools_cv_func_unsetenv_return_type,
89   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+unsetenv>changequote([, ]),
90                    stdlib.h,
91                    [fptools_cv_func_unsetenv_return_type=void],
92                    [fptools_cv_func_unsetenv_return_type=int])])
93 case "$fptools_cv_func_unsetenv_return_type" in
94   "void" )
95     AC_DEFINE([UNSETENV_RETURNS_VOID], [1], [Define if stdlib.h declares unsetenv to return void.])
96   ;;
97 esac
98
99 dnl--------------------------------------------------------------------
100 dnl * Deal with arguments telling us iconv is somewhere odd
101 dnl--------------------------------------------------------------------
102
103 AC_ARG_WITH([iconv-includes],
104   [AC_HELP_STRING([--with-iconv-includes],
105     [directory containing iconv.h])],
106     [ICONV_INCLUDE_DIRS=$withval; CPPFLAGS="-I$withval $CPPFLAGS"],
107     [ICONV_INCLUDE_DIRS=])
108
109 AC_ARG_WITH([iconv-libraries],
110   [AC_HELP_STRING([--with-iconv-libraries],
111     [directory containing iconv library])],
112     [ICONV_LIB_DIRS=$withval; LDFLAGS="-L$withval $LDFLAGS"],
113     [ICONV_LIB_DIRS=])
114
115 AC_SUBST(ICONV_INCLUDE_DIRS)
116 AC_SUBST(ICONV_LIB_DIRS)
117
118 # map standard C types and ISO types to Haskell types
119 FPTOOLS_CHECK_HTYPE(char)
120 FPTOOLS_CHECK_HTYPE(signed char)
121 FPTOOLS_CHECK_HTYPE(unsigned char)
122 FPTOOLS_CHECK_HTYPE(short)
123 FPTOOLS_CHECK_HTYPE(unsigned short)
124 FPTOOLS_CHECK_HTYPE(int)
125 FPTOOLS_CHECK_HTYPE(unsigned int)
126 FPTOOLS_CHECK_HTYPE(long)
127 FPTOOLS_CHECK_HTYPE(unsigned long)
128 if test "$ac_cv_type_long_long" = yes; then
129 FPTOOLS_CHECK_HTYPE(long long)
130 FPTOOLS_CHECK_HTYPE(unsigned long long)
131 fi
132 FPTOOLS_CHECK_HTYPE(bool)
133 FPTOOLS_CHECK_HTYPE(float)
134 FPTOOLS_CHECK_HTYPE(double)
135 FPTOOLS_CHECK_HTYPE(ptrdiff_t)
136 FPTOOLS_CHECK_HTYPE(size_t)
137 FPTOOLS_CHECK_HTYPE(wchar_t)
138 FPTOOLS_CHECK_HTYPE(sig_atomic_t)
139 FPTOOLS_CHECK_HTYPE(clock_t)
140 FPTOOLS_CHECK_HTYPE(time_t)
141 FPTOOLS_CHECK_HTYPE(useconds_t)
142 FPTOOLS_CHECK_HTYPE_ELSE(suseconds_t,
143                          [if test "$WINDOWS" = "YES"
144                           then
145                               AC_CV_NAME=Int32
146                               AC_CV_NAME_supported=yes
147                           else
148                               AC_MSG_ERROR([type not found])
149                           fi])
150 FPTOOLS_CHECK_HTYPE(dev_t)
151 FPTOOLS_CHECK_HTYPE(ino_t)
152 FPTOOLS_CHECK_HTYPE(mode_t)
153 FPTOOLS_CHECK_HTYPE(off_t)
154 FPTOOLS_CHECK_HTYPE(pid_t)
155 FPTOOLS_CHECK_HTYPE(gid_t)
156 FPTOOLS_CHECK_HTYPE(uid_t)
157 FPTOOLS_CHECK_HTYPE(cc_t)
158 FPTOOLS_CHECK_HTYPE(speed_t)
159 FPTOOLS_CHECK_HTYPE(tcflag_t)
160 FPTOOLS_CHECK_HTYPE(nlink_t)
161 FPTOOLS_CHECK_HTYPE(ssize_t)
162 FPTOOLS_CHECK_HTYPE(rlim_t)
163 FPTOOLS_CHECK_HTYPE(blksize_t)
164 FPTOOLS_CHECK_HTYPE(blkcnt_t)
165 FPTOOLS_CHECK_HTYPE(clockid_t)
166 FPTOOLS_CHECK_HTYPE(fsblkcnt_t)
167 FPTOOLS_CHECK_HTYPE(fsfilcnt_t)
168 FPTOOLS_CHECK_HTYPE(id_t)
169 FPTOOLS_CHECK_HTYPE(key_t)
170 FPTOOLS_CHECK_HTYPE(timer_t)
171
172 FPTOOLS_CHECK_HTYPE(intptr_t)
173 FPTOOLS_CHECK_HTYPE(uintptr_t)
174 FPTOOLS_CHECK_HTYPE(intmax_t)
175 FPTOOLS_CHECK_HTYPE(uintmax_t)
176
177 # test errno values
178 FP_CHECK_CONSTS([E2BIG EACCES EADDRINUSE EADDRNOTAVAIL EADV EAFNOSUPPORT EAGAIN EALREADY EBADF EBADMSG EBADRPC EBUSY ECHILD ECOMM ECONNABORTED ECONNREFUSED ECONNRESET EDEADLK EDESTADDRREQ EDIRTY EDOM EDQUOT EEXIST EFAULT EFBIG EFTYPE EHOSTDOWN EHOSTUNREACH EIDRM EILSEQ EINPROGRESS EINTR EINVAL EIO EISCONN EISDIR ELOOP EMFILE EMLINK EMSGSIZE EMULTIHOP ENAMETOOLONG ENETDOWN ENETRESET ENETUNREACH ENFILE ENOBUFS ENODATA ENODEV ENOENT ENOEXEC ENOLCK ENOLINK ENOMEM ENOMSG ENONET ENOPROTOOPT ENOSPC ENOSR ENOSTR ENOSYS ENOTBLK ENOTCONN ENOTDIR ENOTEMPTY ENOTSOCK ENOTTY ENXIO EOPNOTSUPP EPERM EPFNOSUPPORT EPIPE EPROCLIM EPROCUNAVAIL EPROGMISMATCH EPROGUNAVAIL EPROTO EPROTONOSUPPORT EPROTOTYPE ERANGE EREMCHG EREMOTE EROFS ERPCMISMATCH ERREMOTE ESHUTDOWN ESOCKTNOSUPPORT ESPIPE ESRCH ESRMNT ESTALE ETIME ETIMEDOUT ETOOMANYREFS ETXTBSY EUSERS EWOULDBLOCK EXDEV ENOCIGAR ENOTSUP], [#include <stdio.h>
179 #include <errno.h>])
180
181 # we need SIGINT in TopHandler.lhs
182 FP_CHECK_CONSTS([SIGINT], [
183 #if HAVE_SIGNAL_H
184 #include <signal.h>
185 #endif])
186
187 dnl ** can we open files in binary mode?
188 FP_CHECK_CONST([O_BINARY], [#include <fcntl.h>], [0])
189
190 # We don't use iconv or libcharset on Windows, but if configure finds
191 # them then it can cause problems. So we don't even try looking if
192 # we are on Windows.
193 # See http://www.haskell.org/pipermail/cvs-ghc/2011-September/065980.html
194 if test "$WINDOWS" = "NO"
195 then
196
197 # We can't just use AC_SEARCH_LIBS for this, as on OpenBSD the iconv.h
198 # header needs to be included as iconv_open is #define'd to something
199 # else. We therefore use our own FP_SEARCH_LIBS_PROTO, which allows us
200 # to give prototype text.
201 FP_SEARCH_LIBS_PROTO(iconv,
202                      [
203 #include <stddef.h>
204 #include <iconv.h>
205                       ],
206                      [iconv_t cd;
207                       cd = iconv_open("", "");
208                       iconv(cd,NULL,NULL,NULL,NULL);
209                       iconv_close(cd);],
210                      iconv,
211                      [EXTRA_LIBS="$EXTRA_LIBS $ac_lib"],
212                      [AC_MSG_ERROR([iconv is required on non-Windows platforms])])
213
214 # If possible, we use libcharset instead of nl_langinfo(CODESET) to
215 # determine the current locale's character encoding.  Allow the user
216 # to disable this with --without-libcharset if they don't want a
217 # dependency on libcharset.
218 AC_ARG_WITH([libcharset],
219   [AS_HELP_STRING([--with-libcharset],
220     [Use libcharset [default=only if available]])],
221   [],
222   [with_libcharset=check])
223
224 AS_IF([test "x$with_libcharset" != xno],
225   FP_SEARCH_LIBS_PROTO(
226     [locale_charset],
227     [#include <libcharset.h>],
228     [const char* charset = locale_charset();],
229     [charset],
230     [AC_DEFINE([HAVE_LIBCHARSET], [1], [Define to 1 if you have libcharset.])
231      EXTRA_LIBS="$EXTRA_LIBS $ac_lib"]
232   ))
233
234 fi
235
236 # Hack - md5.h needs HsFFI.h.  Is there a better way to do this?
237 CFLAGS="-I../../includes $CFLAGS"
238 dnl Calling AC_CHECK_TYPE(T) makes AC_CHECK_SIZEOF(T) abort on failure
239 dnl instead of considering sizeof(T) as 0.
240 AC_CHECK_TYPE([struct MD5Context], [], [], [#include "include/md5.h"])
241 AC_CHECK_SIZEOF([struct MD5Context], [], [#include "include/md5.h"])
242
243 AC_SUBST(EXTRA_LIBS)
244 AC_CONFIG_FILES([base.buildinfo])
245
246 AC_OUTPUT