Merge branch 'master' of http://darcs.haskell.org/ghc
[ghc.git] / compiler / basicTypes / Unique.lhs
1 %
2 % (c) The University of Glasgow 2006
3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
4 %
5
6 @Uniques@ are used to distinguish entities in the compiler (@Ids@,
7 @Classes@, etc.) from each other.  Thus, @Uniques@ are the basic
8 comparison key in the compiler.
9
10 If there is any single operation that needs to be fast, it is @Unique@
11 comparison.  Unsurprisingly, there is quite a bit of huff-and-puff
12 directed to that end.
13
14 Some of the other hair in this code is to be able to use a
15 ``splittable @UniqueSupply@'' if requested/possible (not standard
16 Haskell).
17
18 \begin{code}
19 {-# LANGUAGE BangPatterns #-}
20
21 {-# OPTIONS -fno-warn-tabs #-}
22 -- The above warning supression flag is a temporary kludge.
23 -- While working on this module you are encouraged to remove it and
24 -- detab the module (please do the detabbing in a separate patch). See
25 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#TabsvsSpaces
26 -- for details
27
28 module Unique (
29         -- * Main data types
30         Unique, Uniquable(..), 
31         
32         -- ** Constructors, desctructors and operations on 'Unique's
33         hasKey,
34
35         pprUnique, 
36
37         mkUniqueGrimily,                -- Used in UniqSupply only!
38         getKey, getKeyFastInt,          -- Used in Var, UniqFM, Name only!
39         mkUnique, unpkUnique,           -- Used in BinIface only
40
41         incrUnique,                     -- Used for renumbering
42         deriveUnique,                   -- Ditto
43         newTagUnique,                   -- Used in CgCase
44         initTyVarUnique,
45
46         -- ** Making built-in uniques
47
48         -- now all the built-in Uniques (and functions to make them)
49         -- [the Oh-So-Wonderful Haskell module system wins again...]
50         mkAlphaTyVarUnique,
51         mkPrimOpIdUnique,
52         mkTupleTyConUnique, mkTupleDataConUnique,
53         mkPreludeMiscIdUnique, mkPreludeDataConUnique,
54         mkPreludeTyConUnique, mkPreludeClassUnique,
55         mkPArrDataConUnique,
56
57     mkVarOccUnique, mkDataOccUnique, mkTvOccUnique, mkTcOccUnique,
58         mkRegSingleUnique, mkRegPairUnique, mkRegClassUnique, mkRegSubUnique,
59         mkCostCentreUnique,
60
61         mkBuiltinUnique,
62         mkPseudoUniqueD,
63         mkPseudoUniqueE,
64         mkPseudoUniqueH
65     ) where
66
67 #include "HsVersions.h"
68
69 import BasicTypes
70 import FastTypes
71 import FastString
72 import Outputable
73 -- import StaticFlags
74 import Util
75
76 #if defined(__GLASGOW_HASKELL__)
77 --just for implementing a fast [0,61) -> Char function
78 import GHC.Exts (indexCharOffAddr#, Char(..))
79 #else
80 import Data.Array
81 #endif
82 import Data.Char        ( chr, ord )
83 \end{code}
84
85 %************************************************************************
86 %*                                                                      *
87 \subsection[Unique-type]{@Unique@ type and operations}
88 %*                                                                      *
89 %************************************************************************
90
91 The @Chars@ are ``tag letters'' that identify the @UniqueSupply@.
92 Fast comparison is everything on @Uniques@:
93
94 \begin{code}
95 --why not newtype Int?
96
97 -- | The type of unique identifiers that are used in many places in GHC
98 -- for fast ordering and equality tests. You should generate these with
99 -- the functions from the 'UniqSupply' module
100 data Unique = MkUnique FastInt
101 \end{code}
102
103 Now come the functions which construct uniques from their pieces, and vice versa.
104 The stuff about unique *supplies* is handled further down this module.
105
106 \begin{code}
107 unpkUnique      :: Unique -> (Char, Int)        -- The reverse
108
109 mkUniqueGrimily :: Int -> Unique                -- A trap-door for UniqSupply
110 getKey          :: Unique -> Int                -- for Var
111 getKeyFastInt   :: Unique -> FastInt            -- for Var
112
113 incrUnique      :: Unique -> Unique
114 deriveUnique    :: Unique -> Int -> Unique
115 newTagUnique    :: Unique -> Char -> Unique
116 \end{code}
117
118
119 \begin{code}
120 mkUniqueGrimily x = MkUnique (iUnbox x)
121
122 {-# INLINE getKey #-}
123 getKey (MkUnique x) = iBox x
124 {-# INLINE getKeyFastInt #-}
125 getKeyFastInt (MkUnique x) = x
126
127 incrUnique (MkUnique i) = MkUnique (i +# _ILIT(1))
128
129 -- deriveUnique uses an 'X' tag so that it won't clash with
130 -- any of the uniques produced any other way
131 deriveUnique (MkUnique i) delta = mkUnique 'X' (iBox i + delta)
132
133 -- newTagUnique changes the "domain" of a unique to a different char
134 newTagUnique u c = mkUnique c i where (_,i) = unpkUnique u
135
136 -- pop the Char in the top 8 bits of the Unique(Supply)
137
138 -- No 64-bit bugs here, as long as we have at least 32 bits. --JSM
139
140 -- and as long as the Char fits in 8 bits, which we assume anyway!
141
142 mkUnique :: Char -> Int -> Unique       -- Builds a unique from pieces
143 -- NOT EXPORTED, so that we can see all the Chars that 
144 --               are used in this one module
145 mkUnique c i
146   = MkUnique (tag `bitOrFastInt` bits)
147   where
148     !tag  = fastOrd (cUnbox c) `shiftLFastInt` _ILIT(24)
149     !bits = iUnbox i `bitAndFastInt` _ILIT(16777215){-``0x00ffffff''-}
150
151 unpkUnique (MkUnique u)
152   = let
153         -- as long as the Char may have its eighth bit set, we
154         -- really do need the logical right-shift here!
155         tag = cBox (fastChr (u `shiftRLFastInt` _ILIT(24)))
156         i   = iBox (u `bitAndFastInt` _ILIT(16777215){-``0x00ffffff''-})
157     in
158     (tag, i)
159 \end{code}
160
161
162
163 %************************************************************************
164 %*                                                                      *
165 \subsection[Uniquable-class]{The @Uniquable@ class}
166 %*                                                                      *
167 %************************************************************************
168
169 \begin{code}
170 -- | Class of things that we can obtain a 'Unique' from
171 class Uniquable a where
172     getUnique :: a -> Unique
173
174 hasKey          :: Uniquable a => a -> Unique -> Bool
175 x `hasKey` k    = getUnique x == k
176
177 instance Uniquable FastString where
178  getUnique fs = mkUniqueGrimily (iBox (uniqueOfFS fs))
179
180 instance Uniquable Int where
181  getUnique i = mkUniqueGrimily i
182 \end{code}
183
184
185 %************************************************************************
186 %*                                                                      *
187 \subsection[Unique-instances]{Instance declarations for @Unique@}
188 %*                                                                      *
189 %************************************************************************
190
191 And the whole point (besides uniqueness) is fast equality.  We don't
192 use `deriving' because we want {\em precise} control of ordering
193 (equality on @Uniques@ is v common).
194
195 \begin{code}
196 eqUnique, ltUnique, leUnique :: Unique -> Unique -> Bool
197 eqUnique (MkUnique u1) (MkUnique u2) = u1 ==# u2
198 ltUnique (MkUnique u1) (MkUnique u2) = u1 <#  u2
199 leUnique (MkUnique u1) (MkUnique u2) = u1 <=# u2
200
201 cmpUnique :: Unique -> Unique -> Ordering
202 cmpUnique (MkUnique u1) (MkUnique u2)
203   = if u1 ==# u2 then EQ else if u1 <# u2 then LT else GT
204
205 instance Eq Unique where
206     a == b = eqUnique a b
207     a /= b = not (eqUnique a b)
208
209 instance Ord Unique where
210     a  < b = ltUnique a b
211     a <= b = leUnique a b
212     a  > b = not (leUnique a b)
213     a >= b = not (ltUnique a b)
214     compare a b = cmpUnique a b
215
216 -----------------
217 instance Uniquable Unique where
218     getUnique u = u
219 \end{code}
220
221 We do sometimes make strings with @Uniques@ in them:
222 \begin{code}
223 showUnique :: Unique -> String
224 showUnique uniq
225   = case unpkUnique uniq of
226       (tag, u) -> finish_show tag u (iToBase62 u)
227
228 finish_show :: Char -> Int -> String -> String
229 finish_show 't' u _pp_u | u < 26
230   = -- Special case to make v common tyvars, t1, t2, ...
231     -- come out as a, b, ... (shorter, easier to read)
232     [chr (ord 'a' + u)]
233 finish_show tag _ pp_u = tag : pp_u
234
235 pprUnique :: Unique -> SDoc
236 pprUnique u = text (showUnique u)
237
238 instance Outputable Unique where
239     ppr = pprUnique
240
241 instance Show Unique where
242     show uniq = showUnique uniq
243 \end{code}
244
245 %************************************************************************
246 %*                                                                      *
247 \subsection[Utils-base62]{Base-62 numbers}
248 %*                                                                      *
249 %************************************************************************
250
251 A character-stingy way to read/write numbers (notably Uniques).
252 The ``62-its'' are \tr{[0-9a-zA-Z]}.  We don't handle negative Ints.
253 Code stolen from Lennart.
254
255 \begin{code}
256 iToBase62 :: Int -> String
257 iToBase62 n_
258   = ASSERT(n_ >= 0) go (iUnbox n_) ""
259   where
260     go n cs | n <# _ILIT(62)
261              = case chooseChar62 n of { c -> c `seq` (c : cs) }
262              | otherwise
263              =  case (quotRem (iBox n) 62) of { (q_, r_) ->
264                 case iUnbox q_ of { q -> case iUnbox r_ of { r ->
265                 case (chooseChar62 r) of { c -> c `seq`
266                 (go q (c : cs)) }}}}
267
268     chooseChar62 :: FastInt -> Char
269     {-# INLINE chooseChar62 #-}
270 #if defined(__GLASGOW_HASKELL__)
271     --then FastInt == Int#
272     chooseChar62 n = C# (indexCharOffAddr# chars62 n)
273     !chars62 = "0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ"#
274 #else
275     --Haskell98 arrays are portable
276     chooseChar62 n = (!) chars62 n
277     chars62 = listArray (0,61) "0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ"
278 #endif
279 \end{code}
280
281 %************************************************************************
282 %*                                                                      *
283 \subsection[Uniques-prelude]{@Uniques@ for wired-in Prelude things}
284 %*                                                                      *
285 %************************************************************************
286
287 Allocation of unique supply characters:
288         v,t,u : for renumbering value-, type- and usage- vars.
289         B:   builtin
290         C-E: pseudo uniques     (used in native-code generator)
291         X:   uniques derived by deriveUnique
292         _:   unifiable tyvars   (above)
293         0-9: prelude things below
294              (no numbers left any more..)
295         ::   (prelude) parallel array data constructors
296
297         other a-z: lower case chars for unique supplies.  Used so far:
298
299         d       desugarer
300         f       AbsC flattener
301         g       SimplStg
302         n       Native codegen
303         r       Hsc name cache
304         s       simplifier
305
306 \begin{code}
307 mkAlphaTyVarUnique     :: Int -> Unique
308 mkPreludeClassUnique   :: Int -> Unique
309 mkPreludeTyConUnique   :: Int -> Unique
310 mkTupleTyConUnique     :: TupleSort -> Int -> Unique
311 mkPreludeDataConUnique :: Int -> Unique
312 mkTupleDataConUnique   :: TupleSort -> Int -> Unique
313 mkPrimOpIdUnique       :: Int -> Unique
314 mkPreludeMiscIdUnique  :: Int -> Unique
315 mkPArrDataConUnique    :: Int -> Unique
316
317 mkAlphaTyVarUnique i            = mkUnique '1' i
318
319 mkPreludeClassUnique i          = mkUnique '2' i
320
321 -- Prelude type constructors occupy *three* slots.
322 -- The first is for the tycon itself; the latter two
323 -- are for the generic to/from Ids.  See TysWiredIn.mk_tc_gen_info.
324
325 mkPreludeTyConUnique i          = mkUnique '3' (3*i)
326 mkTupleTyConUnique BoxedTuple   a       = mkUnique '4' (3*a)
327 mkTupleTyConUnique UnboxedTuple a       = mkUnique '5' (3*a)
328 mkTupleTyConUnique ConstraintTuple a    = mkUnique 'k' (3*a)
329
330 -- Data constructor keys occupy *two* slots.  The first is used for the
331 -- data constructor itself and its wrapper function (the function that
332 -- evaluates arguments as necessary and calls the worker). The second is
333 -- used for the worker function (the function that builds the constructor
334 -- representation).
335
336 mkPreludeDataConUnique i        = mkUnique '6' (2*i)    -- Must be alphabetic
337 mkTupleDataConUnique BoxedTuple   a = mkUnique '7' (2*a)        -- ditto (*may* be used in C labels)
338 mkTupleDataConUnique UnboxedTuple    a = mkUnique '8' (2*a)
339 mkTupleDataConUnique ConstraintTuple a = mkUnique 'h' (2*a)
340
341 mkPrimOpIdUnique op         = mkUnique '9' op
342 mkPreludeMiscIdUnique  i    = mkUnique '0' i
343
344 -- No numbers left anymore, so I pick something different for the character tag 
345 mkPArrDataConUnique a           = mkUnique ':' (2*a)
346
347 -- The "tyvar uniques" print specially nicely: a, b, c, etc.
348 -- See pprUnique for details
349
350 initTyVarUnique :: Unique
351 initTyVarUnique = mkUnique 't' 0
352
353 mkPseudoUniqueD, mkPseudoUniqueE, mkPseudoUniqueH,
354    mkBuiltinUnique :: Int -> Unique
355
356 mkBuiltinUnique i = mkUnique 'B' i
357 mkPseudoUniqueD i = mkUnique 'D' i -- used in NCG for getUnique on RealRegs
358 mkPseudoUniqueE i = mkUnique 'E' i -- used in NCG spiller to create spill VirtualRegs
359 mkPseudoUniqueH i = mkUnique 'H' i -- used in NCG spiller to create spill VirtualRegs
360
361 mkRegSingleUnique, mkRegPairUnique, mkRegSubUnique, mkRegClassUnique :: Int -> Unique
362 mkRegSingleUnique = mkUnique 'R'
363 mkRegSubUnique    = mkUnique 'S'
364 mkRegPairUnique   = mkUnique 'P'
365 mkRegClassUnique  = mkUnique 'L'
366
367 mkCostCentreUnique :: Int -> Unique
368 mkCostCentreUnique = mkUnique 'C'
369
370 mkVarOccUnique, mkDataOccUnique, mkTvOccUnique, mkTcOccUnique :: FastString -> Unique
371 -- See Note [The Unique of an OccName] in OccName
372 mkVarOccUnique  fs = mkUnique 'i' (iBox (uniqueOfFS fs))
373 mkDataOccUnique fs = mkUnique 'd' (iBox (uniqueOfFS fs))
374 mkTvOccUnique   fs = mkUnique 'v' (iBox (uniqueOfFS fs))
375 mkTcOccUnique   fs = mkUnique 'c' (iBox (uniqueOfFS fs))
376 \end{code}
377