Fix detection of llvm-x.x
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.11], [glasgow-haskell-bugs@haskell.org], [ghc])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands,
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42 FP_PROG_SORT
43
44 dnl ----------------------------------------------------------
45 FP_SETUP_PROJECT_VERSION
46
47 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
48 AC_SUBST([release], [1])
49
50 # First off, a distrib sanity check..
51 AC_CONFIG_SRCDIR([mk/config.mk.in])
52
53 dnl * We require autoconf version 2.60
54 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
55 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
56 dnl Using autoconf 2.59 started to give nonsense like this
57 dnl  #define SIZEOF_CHAR 0
58 dnl recently.
59 AC_PREREQ([2.60])
60
61 # -------------------------------------------------------------------------
62 # Prepare to generate the following header files
63 #
64 #
65 AC_CONFIG_HEADER(mk/config.h)
66
67 # No, semi-sadly, we don't do `--srcdir'...
68 if test x"$srcdir" != 'x.' ; then
69     echo "This configuration does not support the \`--srcdir' option.."
70     exit 1
71 fi
72
73 dnl --------------------------------------------------------------
74 dnl * Project specific configuration options
75 dnl --------------------------------------------------------------
76 dnl What follows is a bunch of options that can either be configured
77 dnl through command line options to the configure script or by
78 dnl supplying defns in the build tree's mk/build.mk. Having the option to
79 dnl use either is considered a Feature.
80
81 dnl ** What command to use to compile compiler sources ?
82 dnl --------------------------------------------------------------
83
84 AC_ARG_WITH([ghc],
85 [AC_HELP_STRING([--with-ghc=ARG],
86   [Use ARG as the path to GHC  [default=autodetect]])],
87   [WithGhc="$withval"],
88   [if test "$GHC" = ""; then
89     AC_PATH_PROG([GHC], [ghc])
90   fi
91   WithGhc="$GHC"])
92
93 dnl ** Tell the make system which OS we are using
94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
95 AC_SUBST(OSTYPE)
96
97 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
98 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
99                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
100         EnableBootstrapWithDevelSnaphost=YES,
101         EnableBootstrapWithDevelSnaphost=NO
102 )
103
104 if test "$WithGhc" != ""; then
105   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
106
107   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
108      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
109   fi
110
111   AC_SUBST(GhcVersion)dnl
112   AC_SUBST(GhcMajVersion)dnl
113   AC_SUBST(GhcMinVersion)dnl
114   AC_SUBST(GhcPatchLevel)dnl
115   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
116   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
117
118   BOOTSTRAPPING_GHC_INFO_FIELD([OS_STAGE0],[target os])
119   BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
120   dnl ToDo, once "ld command" is reliably available.
121   dnl Then, we can remove the LD_STAGE0 hack in mk/build-package-date.mk
122   dnl BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
123   if test "x$OS_STAGE0" != "xOSDarwin"; then
124     BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
125     BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
126     BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
127   else
128     AR_STAGE0='$(AR)'
129     AR_OPTS_STAGE0='$(AR_OPTS)'
130     ArSupportsAtFile_STAGE0='$(ArSupportsAtFile)'
131   fi
132 fi
133
134 dnl ** Must have GHC to build GHC
135 if test "$WithGhc" = ""
136 then
137     AC_MSG_ERROR([GHC is required.])
138 fi
139 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.6],
140     [AC_MSG_ERROR([GHC version 7.6 or later is required to compile GHC.])])
141
142 if test `expr $GhcMinVersion % 2` = "1"
143 then
144     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
145     then
146         AC_MSG_ERROR([
147      $WithGhc is a development snapshot of GHC, version $GhcVersion.
148      Bootstrapping using this version of GHC is not supported, and may not
149      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
150      or --with-ghc to specify a different GHC to use.])
151     fi
152 fi
153
154 GHC_PACKAGE_DB_FLAG=package-db
155 AC_SUBST(GHC_PACKAGE_DB_FLAG)
156
157 # GHC 7.7+ needs -fcmm-sink when compiling Parser.hs. See #8182
158 FP_COMPARE_VERSIONS([$GhcVersion],[-gt],[7.7],
159                     CMM_SINK_BOOTSTRAP_IS_NEEDED=YES,
160                     CMM_SINK_BOOTSTRAP_IS_NEEDED=NO)
161 AC_SUBST(CMM_SINK_BOOTSTRAP_IS_NEEDED)
162
163 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.9],
164                     SUPPORTS_PACKAGE_KEY=NO,
165                     SUPPORTS_PACKAGE_KEY=YES)
166 AC_SUBST(SUPPORTS_PACKAGE_KEY)
167
168 # GHC is passed to Cabal, so we need a native path
169 if test "${WithGhc}" != ""
170 then
171     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
172
173     if test "$ghc_host_os" = "mingw32"
174     then
175         if test "${OSTYPE}" = "msys"
176         then
177             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
178         else
179             # Canonicalise to <drive>:/path/to/ghc
180             WithGhc=`cygpath -m "${WithGhc}"`
181         fi
182         echo "GHC path canonicalised to: ${WithGhc}"
183     fi
184 fi
185 AC_SUBST([WithGhc])
186
187 dnl ** Without optimization some INLINE trickery fails for GHCi
188 SRC_CC_OPTS="-O"
189
190 dnl--------------------------------------------------------------------
191 dnl * Choose host(/target/build) platform
192 dnl--------------------------------------------------------------------
193 dnl If we aren't explicitly told what values to use with configure flags,
194 dnl we ask the bootstrapping compiler what platform it is for
195
196 if test "${WithGhc}" != ""
197 then
198         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
199         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
200         if test "$bootstrap_host" != "$bootstrap_target"
201         then
202                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
203         fi
204 fi
205
206 # We have to run these unconditionally, but we may discard their
207 # results in the following code
208 AC_CANONICAL_BUILD
209 AC_CANONICAL_HOST
210 AC_CANONICAL_TARGET
211
212 FPTOOLS_SET_PLATFORM_VARS
213
214 # Verify that the installed (bootstrap) GHC is capable of generating
215 # code for the requested build platform.
216 if test "$BuildPlatform" != "$bootstrap_target"
217 then
218     echo "This GHC (${WithGhc}) does not generate code for the build platform"
219     echo "   GHC target platform    : $bootstrap_target"
220     echo "   Desired build platform : $BuildPlatform"
221     exit 1
222 fi
223
224 # Testing if we shall enable shared libs support on Solaris.
225 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
226
227 SOLARIS_BROKEN_SHLD=NO
228
229 case $host in
230      i386-*-solaris2)
231      # here we go with the test
232      MINOR=`uname -r|cut -d '.' -f 2-`
233      if test "$MINOR" -lt "11"; then
234          SOLARIS_BROKEN_SHLD=YES
235      fi
236      ;;
237 esac
238
239 AC_SUBST(SOLARIS_BROKEN_SHLD)
240
241 dnl ** Do an unregisterised build?
242 dnl --------------------------------------------------------------
243 case "$HostArch" in
244     i386|x86_64|powerpc|arm)
245         UnregisterisedDefault=NO
246         ;;
247     *)
248         UnregisterisedDefault=YES
249         ;;
250 esac
251 AC_ARG_ENABLE(unregisterised,
252 [AC_HELP_STRING([--enable-unregisterised],
253 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
254 [ if test x"$enableval" = x"yes"; then
255         Unregisterised=YES
256   else
257         Unregisterised=NO
258   fi
259 ],
260 [Unregisterised="$UnregisterisedDefault"]
261 )
262 AC_SUBST(Unregisterised)
263
264 AC_ARG_WITH(hc,
265 [AC_HELP_STRING([--with-hc=ARG],
266         [Use ARG as the path to the compiler for compiling ordinary
267          Haskell code  (default= value of --with-ghc)])],
268 [WithHc="$withval"],
269 [WithHc=$WithGhc]
270 )
271 AC_SUBST(WithHc)
272
273 # This uses GHC, so put it after the "GHC is required" check above:
274 FP_INTREE_GHC_PWD
275 FP_FIND_ROOT
276
277 if test "$HostOS" = "mingw32"
278 then
279     test -d inplace || mkdir inplace
280
281     if test "$HostArch" = "i386"
282     then
283         # NB. If you update the tarballs to a new version of gcc, don't
284         # forget to tweak the paths in driver/gcc/gcc.c.
285         if ! test -d inplace/mingw ||
286              test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma  ||
287              test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma  ||
288              test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma   ||
289              test inplace/mingw -ot ghc-tarballs/mingw/libgcc*.tar.gz      ||
290              test inplace/mingw -ot ghc-tarballs/mingw/libgmp*.tar.gz      ||
291              test inplace/mingw -ot ghc-tarballs/mingw/libmpc*.tar.gz      ||
292              test inplace/mingw -ot ghc-tarballs/mingw/libmpfr*.tar.gz     ||
293              test inplace/mingw -ot ghc-tarballs/mingw/libstdc*.tar.lzma   ||
294              test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dev.tar.gz ||
295              test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dll.tar.gz ||
296              test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
297         then
298             AC_MSG_NOTICE([Making in-tree mingw tree])
299             rm -rf inplace/mingw
300             mkdir inplace/mingw
301             (
302                 cd inplace/mingw &&
303                 tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma  &&
304                 tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma  &&
305                 tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma   &&
306                 tar --lzma -xf ../../ghc-tarballs/mingw/libgcc*.tar.lzma    &&
307                 tar --lzma -xf ../../ghc-tarballs/mingw/libgmp*.tar.lzma    &&
308                 tar --lzma -xf ../../ghc-tarballs/mingw/libmpc*.tar.lzma    &&
309                 tar --lzma -xf ../../ghc-tarballs/mingw/libmpfr*.tar.lzma   &&
310                 tar --lzma -xf ../../ghc-tarballs/mingw/libstdc*.tar.lzma   &&
311                 tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dev.tar.gz &&
312                 tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dll.tar.gz &&
313                 tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma    &&
314                 mv bin/gcc.exe bin/realgcc.exe
315             )
316             PATH=`pwd`/inplace/mingw/bin:$PATH inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
317             AC_MSG_NOTICE([In-tree mingw tree created])
318         fi
319     else
320         # NB. If you update the tarballs to a new version of gcc, don't
321         # forget to tweak the paths in driver/gcc/gcc.c.
322         if ! test -d inplace/mingw ||
323              test inplace/mingw -ot ghc-tarballs/mingw64/*.tar.bz2
324         then
325             AC_MSG_NOTICE([Making in-tree mingw tree])
326             rm -rf inplace/mingw
327             mkdir inplace/mingw
328             (
329                 cd inplace/mingw &&
330                 tar -jxf ../../ghc-tarballs/mingw64/*.tar.bz2
331             )
332             AC_MSG_NOTICE([In-tree mingw tree created])
333         fi
334     fi
335
336     mingwbin="$hardtop/inplace/mingw/bin/"
337     CC="${mingwbin}gcc.exe"
338     LD="${mingwbin}ld.exe"
339     NM="${mingwbin}nm.exe"
340     RANLIB="${mingwbin}ranlib.exe"
341     OBJDUMP="${mingwbin}objdump.exe"
342     fp_prog_ar="${mingwbin}ar.exe"
343
344     if ! test -d inplace/perl ||
345          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
346     then
347         AC_MSG_NOTICE([Making in-tree perl tree])
348         rm -rf inplace/perl
349         mkdir inplace/perl
350         (
351             cd inplace/perl &&
352             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
353         )
354         AC_MSG_NOTICE([In-tree perl tree created])
355     fi
356 fi
357
358 FP_ICONV
359 FP_GMP
360 FP_CURSES
361
362 XCODE_VERSION()
363
364 SplitObjsBroken=NO
365 if test "$TargetOS_CPP" = "darwin"
366 then
367     # Split objects is broken (#4013) with XCode < 3.2
368     if test "$XCodeVersion1" -lt 3
369     then
370         SplitObjsBroken=YES
371     else
372         if test "$XCodeVersion1" -eq 3
373         then
374             if test "$XCodeVersion2" -lt 2
375             then
376                 SplitObjsBroken=YES
377             fi
378         fi
379     fi
380 fi
381 AC_SUBST([SplitObjsBroken])
382
383 dnl ** Building a cross compiler?
384 dnl --------------------------------------------------------------
385 CrossCompiling=NO
386 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
387 if test "$target" != "$host" ; then
388     CrossCompiling=YES
389     cross_compiling=yes   # This tells configure that it can accept just 'target',
390                           # otherwise you get
391                           #   configure: error: cannot run C compiled programs.
392                           #   If you meant to cross compile, use `--host'.
393 fi
394 if test "$build" != "$host" ; then
395    AC_MSG_ERROR([
396 You've selected:
397
398   BUILD:  $build   (the architecture we're building on)
399   HOST:   $host    (the architecture the compiler we're building will execute on)
400   TARGET: $target  (the architecture the compiler we're building will produce code for)
401
402 BUILD must equal HOST; that is, we do not support building GHC itself
403 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
404 1 will be a cross-compiler, and stage 2 will be the cross-compiled
405 GHC.
406 ])
407 fi
408 if test "$CrossCompiling" = "YES"
409 then
410   CrossCompilePrefix="${target}-"
411 else
412   CrossCompilePrefix=""
413 fi
414 TargetPlatformFull="${target}"
415 AC_SUBST(CrossCompiling)
416 AC_SUBST(CrossCompilePrefix)
417 AC_SUBST(TargetPlatformFull)
418
419 dnl ** Which gcc to use?
420 dnl --------------------------------------------------------------
421 FIND_GCC([WhatGccIsCalled], [gcc], [gcc])
422 CC="$WhatGccIsCalled"
423 export CC
424
425 # If --with-gcc was used, and we're not cross-compiling, then it also
426 # applies to the stage0 compiler.
427 MAYBE_OVERRIDE_STAGE0([gcc],[CC_STAGE0])
428 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
429
430 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
431 AC_PROG_CPP
432
433 # --with-hs-cpp/--with-hs-cpp-flags
434 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
435 AC_SUBST([HaskellCPPCmd])
436 AC_SUBST([HaskellCPPArgs])
437
438 dnl ** Which ld to use?
439 dnl --------------------------------------------------------------
440 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld], [ld])
441 LdCmd="$LD"
442 AC_SUBST([LdCmd])
443
444 dnl ** Which nm to use?
445 dnl --------------------------------------------------------------
446 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
447 NmCmd="$NM"
448 AC_SUBST([NmCmd])
449
450 dnl ** Which ar to use?
451 dnl --------------------------------------------------------------
452 FP_ARG_WITH_PATH_GNU_PROG([AR], [ar], [ar])
453 ArCmd="$AR"
454 fp_prog_ar="$AR"
455 AC_SUBST([ArCmd])
456
457 dnl ** Which ranlib to use?
458 dnl --------------------------------------------------------------
459 FP_ARG_WITH_PATH_GNU_PROG([RANLIB], [ranlib], [ranlib])
460 RanlibCmd="$RANLIB"
461 RANLIB="$RanlibCmd"
462
463
464 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
465 case $HostOS_CPP in
466 cygwin32|mingw32)
467     dnl ** Which objdump to use?
468     dnl --------------------------------------------------------------
469     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
470     ObjdumpCmd="$OBJDUMP"
471     AC_SUBST([ObjdumpCmd])
472     ;;
473 esac
474
475 dnl ** Which LLVM llc to use?
476 dnl --------------------------------------------------------------
477 FIND_LLVM_PROG([LLC], [llc], [llc])
478 LlcCmd="$LLC"
479 AC_SUBST([LlcCmd])
480
481 dnl ** Which LLVM opt to use?
482 dnl --------------------------------------------------------------
483 FIND_LLVM_PROG([OPT], [opt], [opt])
484 OptCmd="$OPT"
485 AC_SUBST([OptCmd])
486
487 dnl --------------------------------------------------------------
488 dnl End of configure script option section
489 dnl --------------------------------------------------------------
490
491
492 dnl --------------------------------------------------------------
493 dnl * General configuration checks
494 dnl --------------------------------------------------------------
495
496 dnl ** Bug 9439: Some GHC 7.8 releases had broken LLVM code generator.
497 dnl Unfortunately we don't know whether the user is going to request a
498 dnl build with the LLVM backend as this is only given in build.mk.
499 dnl
500 dnl Instead, we try to do as much work as possible here, checking
501 dnl whether -fllvm is the stage 0 compiler's default. If so we
502 dnl fail. If not, we check whether -fllvm is affected explicitly and
503 dnl if so set a flag. The build system will later check this flag
504 dnl after the desired build flags are known.
505 if test -n "$LlcCmd" && test -n "$OptCmd"
506 then
507     AC_MSG_CHECKING(whether bootstrap compiler is affected by bug 9439)
508     echo "main = putStrLn \"%function\"" > conftestghc.hs
509
510     # Check whether LLVM backend is default for this platform
511     "${WithGhc}" -pgmlc="${LlcCmd}" -pgmlo="${OptCmd}" conftestghc.hs 2>&1 >/dev/null
512     res=`./conftestghc`
513     if test "x$res" = "x%object"
514     then
515         AC_MSG_RESULT(yes)
516         echo "Buggy bootstrap compiler"
517         echo ""
518         echo "The stage 0 compiler $WithGhc is affected by GHC Bug \#9439"
519         echo "and therefore will miscompile the LLVM backend if -fllvm is"
520         echo "used."
521         echo
522         echo "Please use another bootstrap compiler"
523         exit 1
524     fi
525
526     # -fllvm is not the default, but set a flag so the Makefile can check
527     # -for it in the build flags later on
528     "${WithGhc}" -fforce-recomp -pgmlc="${LlcCmd}" -pgmlo="${OptCmd}" -fllvm conftestghc.hs 2>&1 >/dev/null
529     if test $? = 0
530     then
531         res=`./conftestghc`
532         if test "x$res" = "x%object"
533         then
534             AC_MSG_RESULT(yes)
535             GHC_LLVM_AFFECTED_BY_9439=1
536         elif test "x$res" = "x%function"
537         then
538             AC_MSG_RESULT(no)
539             GHC_LLVM_AFFECTED_BY_9439=0
540         else
541             AC_MSG_WARN(unexpected output $res)
542         fi
543     else
544         AC_MSG_RESULT(failed to compile, assuming no)
545     fi
546 fi
547 AC_SUBST([GHC_LLVM_AFFECTED_BY_9439])
548
549 dnl ** Can the unix package be built?
550 dnl --------------------------------------------------------------
551
552 if test "$TargetOS" = "mingw32"
553 then
554     GhcLibsWithUnix=NO
555 else
556     GhcLibsWithUnix=YES
557 fi
558 AC_SUBST([GhcLibsWithUnix])
559
560 dnl ** does #! work?
561 AC_SYS_INTERPRETER()
562
563 dnl ** look for `perl'
564 case $HostOS_CPP in
565 cygwin32|mingw32)
566     PerlCmd=$hardtop/inplace/perl/perl
567     ;;
568 *)
569     AC_PATH_PROG(PerlCmd,perl)
570     if test -z "$PerlCmd"
571     then
572         echo "You must install perl before you can continue"
573         echo "Perhaps it is already installed, but not in your PATH?"
574         exit 1
575     else
576         FPTOOLS_CHECK_PERL_VERSION
577     fi
578     ;;
579 esac
580
581 dnl ** look for GCC and find out which version
582 dnl     Figure out which C compiler to use.  Gcc is preferred.
583 dnl     If gcc, make sure it's at least 3.0
584 dnl
585 FP_GCC_VERSION
586
587 dnl ** look to see if we have a C compiler using an llvm back end.
588 dnl
589 FP_CC_LLVM_BACKEND
590
591 FP_PROG_LD_IS_GNU
592 FP_PROG_LD_BUILD_ID
593 FP_PROG_LD_NO_COMPACT_UNWIND
594 FP_PROG_LD_FILELIST
595
596
597 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
598 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
599 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
600 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
601 # Stage 3 won't be supported by cross-compilation
602
603 FP_GCC_EXTRA_FLAGS
604
605 AC_SUBST(CONF_CC_OPTS_STAGE0)
606 AC_SUBST(CONF_CC_OPTS_STAGE1)
607 AC_SUBST(CONF_CC_OPTS_STAGE2)
608 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
609 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
610 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
611 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
612 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
613 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
614 AC_SUBST(CONF_CPP_OPTS_STAGE0)
615 AC_SUBST(CONF_CPP_OPTS_STAGE1)
616 AC_SUBST(CONF_CPP_OPTS_STAGE2)
617
618 dnl ** Set up the variables for the platform in the settings file.
619 dnl May need to use gcc to find platform details.
620 dnl --------------------------------------------------------------
621 FPTOOLS_SET_HASKELL_PLATFORM_VARS
622
623 dnl ** figure out how to do context diffs
624 FP_PROG_CONTEXT_DIFF
625
626 dnl Let's make sure install-sh is executable here.  If we got it from
627 dnl a darcs repo, it might not be (see bug #978).
628 chmod +x install-sh
629 dnl ** figure out how to do a BSD-ish install
630 AC_PROG_INSTALL
631
632 dnl ** how to invoke `ar' and `ranlib'
633 FP_PROG_AR_SUPPORTS_ATFILE
634 FP_PROG_AR_NEEDS_RANLIB
635
636 dnl ** Check to see whether ln -s works
637 AC_PROG_LN_S
638
639 FP_SETTINGS
640
641 dnl ** Find the path to sed
642 AC_PATH_PROGS(SedCmd,gsed sed,sed)
643
644
645 dnl ** check for time command
646 AC_PATH_PROG(TimeCmd,time)
647
648 dnl ** check for tar
649 dnl   if GNU tar is named gtar, look for it first.
650 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
651
652 dnl ** check for patch
653 dnl if GNU patch is named gpatch, look for it first
654 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
655
656 dnl ** check for dtrace (currently only implemented for Mac OS X)
657 HaveDtrace=NO
658 AC_PATH_PROG(DtraceCmd,dtrace)
659 if test -n "$DtraceCmd"; then
660   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
661     HaveDtrace=YES
662   fi
663 fi
664 AC_SUBST(HaveDtrace)
665
666 AC_PATH_PROG(HSCOLOUR,HsColour)
667 # HsColour is passed to Cabal, so we need a native path
668 if test "$HostOS"      = "mingw32" && \
669    test "${OSTYPE}"   != "msys"    && \
670    test "${HSCOLOUR}" != ""
671 then
672     # Canonicalise to <drive>:/path/to/gcc
673     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
674 fi
675
676 dnl ** check for DocBook toolchain
677 FP_CHECK_DOCBOOK_DTD
678 FP_DOCBOOK_XSL
679 FP_PROG_DBLATEX
680
681 dnl ** check for ghc-pkg command
682 FP_PROG_GHC_PKG
683
684 dnl ** check for installed happy binary + version
685 FPTOOLS_HAPPY
686
687 dnl ** check for installed alex binary + version
688 FPTOOLS_ALEX
689
690 dnl --------------------------------------------------
691 dnl ### program checking section ends here ###
692 dnl --------------------------------------------------
693
694 dnl --------------------------------------------------
695 dnl * Platform header file and syscall feature tests
696 dnl ### checking the state of the local header files and syscalls ###
697
698 dnl ** check for full ANSI header (.h) files
699 AC_HEADER_STDC
700
701 dnl ** Enable large file support.  NB. do this before testing the type of
702 dnl    off_t, because it will affect the result of that test.
703 AC_SYS_LARGEFILE
704
705 dnl ** check for specific header (.h) files that we are interested in
706 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
707
708 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
709 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
710 [[#if HAVE_SYS_PARAM_H
711 # include <sys/param.h>
712 #endif
713 ]])
714
715 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
716 AC_HEADER_TIME
717
718 dnl ** do we have long longs?
719 AC_CHECK_TYPES([long long])
720
721 dnl ** what are the sizes of various types
722 AC_CHECK_SIZEOF(char,               1)
723 AC_CHECK_SIZEOF(double,             8)
724 AC_CHECK_SIZEOF(float,              4)
725 AC_CHECK_SIZEOF(int,                4)
726 AC_CHECK_SIZEOF(long,               4)
727 if test "$ac_cv_type_long_long" = yes; then
728 AC_CHECK_SIZEOF(long long,          8)
729 fi
730 AC_CHECK_SIZEOF(short,              2)
731 AC_CHECK_SIZEOF(unsigned char,      1)
732 AC_CHECK_SIZEOF(unsigned int,       4)
733 AC_CHECK_SIZEOF(unsigned long,      4)
734 if test "$ac_cv_type_long_long" = yes; then
735 AC_CHECK_SIZEOF(unsigned long long, 8)
736 fi
737 AC_CHECK_SIZEOF(unsigned short,     2)
738 AC_CHECK_SIZEOF(void *,             4)
739
740 dnl for use in settings.in
741 WordSize=$ac_cv_sizeof_void_p
742 AC_SUBST(WordSize)
743
744 dnl ** what are alignment constraints on various types
745 FP_CHECK_ALIGNMENT(char)
746 FP_CHECK_ALIGNMENT(double)
747 FP_CHECK_ALIGNMENT(float)
748 FP_CHECK_ALIGNMENT(int)
749 FP_CHECK_ALIGNMENT(long)
750 if test "$ac_cv_type_long_long" = yes; then
751 FP_CHECK_ALIGNMENT(long long)
752 fi
753 FP_CHECK_ALIGNMENT(short)
754 FP_CHECK_ALIGNMENT(unsigned char)
755 FP_CHECK_ALIGNMENT(unsigned int)
756 FP_CHECK_ALIGNMENT(unsigned long)
757 if test "$ac_cv_type_long_long" = yes; then
758 FP_CHECK_ALIGNMENT(unsigned long long)
759 fi
760 FP_CHECK_ALIGNMENT(unsigned short)
761 FP_CHECK_ALIGNMENT(void *)
762
763 FP_CHECK_FUNC([WinExec],
764   [@%:@include <windows.h>], [WinExec("",0)])
765
766 FP_CHECK_FUNC([GetModuleFileName],
767   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
768
769 dnl ** check for more functions
770 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
771 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
772
773 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
774 dnl ** _POSIX_C_SOURCE is defined
775 AC_CHECK_DECLS([ctime_r], , ,
776 [#define _POSIX_SOURCE 1
777 #define _POSIX_C_SOURCE 199506L
778 #include <time.h>])
779
780 dnl ** check for mingwex library
781 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
782 AC_SUBST(HaveLibMingwEx)
783
784 if test $HaveLibMingwEx = YES ; then
785   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
786 fi
787
788 dnl ** check for math library
789 dnl    Keep that check as early as possible.
790 dnl    as we need to know whether we need libm
791 dnl    for math functions or not
792 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
793 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
794 if test $HaveLibM = YES
795 then
796   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
797 fi
798
799 FP_BFD_SUPPORT
800
801 dnl ################################################################
802 dnl Check for libraries
803 dnl ################################################################
804
805 # system libffi
806
807 AC_ARG_WITH([system-libffi],
808 [AC_HELP_STRING([--with-system-libffi],
809   [Use system provided libffi for RTS [default=no]])
810 ])
811
812 AS_IF([test "x$with_system_libffi" = "xyes"],
813   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
814 )
815
816
817 AC_SUBST(UseSystemLibFFI)
818
819 AC_ARG_WITH([ffi-includes],
820 [AC_HELP_STRING([--with-ffi-includes=ARG],
821   [Find includes for libffi in ARG [default=system default]])
822 ],
823 [
824  if test "x$UseSystemLibFFI" != "xYES"; then
825     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
826  else
827     FFIIncludeDir="$withval"
828     LIBFFI_CFLAGS="-I$withval"
829  fi
830 ])
831
832 AC_SUBST(FFIIncludeDir)
833
834 AC_ARG_WITH([ffi-libraries],
835 [AC_HELP_STRING([--with-ffi-libraries=ARG],
836   [Find libffi in ARG [default=system default]])
837 ],
838 [
839  if test "x$UseSystemLibFFI" != "xYES"; then
840     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
841  else
842     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
843  fi
844 ])
845
846 AC_SUBST(FFILibDir)
847
848 AS_IF([test "$UseSystemLibFFI" = "YES"], [
849  CFLAGS2="$CFLAGS"
850  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
851  LDFLAGS2="$LDFLAGS"
852  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
853  AC_CHECK_LIB(ffi, ffi_call,
854   [AC_CHECK_HEADERS([ffi.h], [break], [])
855    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
856   [AC_MSG_ERROR([Cannot find system libffi])])
857  CFLAGS="$CFLAGS2"
858  LDFLAGS="$LDFLAGS2"
859 ])
860
861 dnl ** check whether we need -ldl to get dlopen()
862 AC_CHECK_LIB(dl, dlopen)
863
864 dnl --------------------------------------------------
865 dnl * Miscellaneous feature tests
866 dnl --------------------------------------------------
867
868 dnl ** can we get alloca?
869 AC_FUNC_ALLOCA
870
871 dnl ** working vfork?
872 AC_FUNC_FORK
873
874 dnl ** determine whether or not const works
875 AC_C_CONST
876
877 dnl ** are we big endian?
878 AC_C_BIGENDIAN
879 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
880
881 dnl ** check for leading underscores in symbol names
882 FP_LEADING_UNDERSCORE
883
884 FP_VISIBILITY_HIDDEN
885
886 dnl ** check for librt
887 AC_CHECK_LIB(rt, clock_gettime)
888 AC_CHECK_FUNCS(clock_gettime timer_settime)
889 FP_CHECK_TIMER_CREATE
890
891 dnl ** check for Apple's "interesting" long double compatibility scheme
892 AC_MSG_CHECKING(for printf\$LDBLStub)
893 AC_TRY_LINK_FUNC(printf\$LDBLStub,
894     [
895         AC_MSG_RESULT(yes)
896         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
897             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
898     ],
899     [
900         AC_MSG_RESULT(no)
901         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
902             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
903     ])
904
905 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
906 dnl    a different single-argument version.
907 AC_CHECK_LIB(pthread, pthread_setname_np)
908 AC_MSG_CHECKING(for pthread_setname_np)
909 AC_TRY_LINK(
910 [
911 #define _GNU_SOURCE
912 #include <pthread.h>
913 ],
914 [pthread_setname_np(pthread_self(), "name");],
915     AC_MSG_RESULT(yes)
916     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
917       [Define to 1 if you have the glibc version of pthread_setname_np]),
918     AC_MSG_RESULT(no)
919 )
920
921 dnl ** check for eventfd which is needed by the I/O manager
922 AC_CHECK_HEADERS([sys/eventfd.h])
923 AC_CHECK_FUNCS([eventfd])
924
925 dnl ** Check for __thread support in the compiler
926 AC_MSG_CHECKING(for __thread support)
927 AC_COMPILE_IFELSE(
928   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
929   [
930    AC_MSG_RESULT(yes)
931    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
932   ],
933   [
934    AC_MSG_RESULT(no)
935    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
936   ])
937
938
939 dnl ** checking for PAPI
940 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
941 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
942 AC_SUBST(HavePapiLib)
943 AC_SUBST(HavePapiHeader)
944
945 AC_CHECK_FUNCS(__mingw_vfprintf)
946
947 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
948    HavePapi=YES
949 else
950    HavePapi=NO
951 fi
952 AC_SUBST(HavePapi)
953
954 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
955    test "$XsltprocCmd" = ""
956 then
957     BUILD_DOCBOOK_HTML=NO
958 else
959     BUILD_DOCBOOK_HTML=YES
960 fi
961 AC_SUBST(BUILD_DOCBOOK_HTML)
962
963 if test "$DblatexCmd" = ""
964 then
965     BUILD_DOCBOOK_PS=NO
966     BUILD_DOCBOOK_PDF=NO
967 else
968     BUILD_DOCBOOK_PS=YES
969     BUILD_DOCBOOK_PDF=YES
970 fi
971 AC_SUBST(BUILD_DOCBOOK_PS)
972 AC_SUBST(BUILD_DOCBOOK_PDF)
973
974 LIBRARY_VERSION(base)
975 LIBRARY_VERSION(Cabal, Cabal/Cabal)
976 LIBRARY_VERSION(ghc-prim)
977 LIBRARY_ghc_VERSION="$ProjectVersion"
978 AC_SUBST(LIBRARY_ghc_VERSION)
979
980 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
981    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
982 fi
983
984 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal settings docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/configure.ac])
985 AC_OUTPUT
986
987 # We got caught by
988 #     http://savannah.gnu.org/bugs/index.php?1516
989 #     $(eval ...) inside conditionals causes errors
990 # with make 3.80, so warn the user if it looks like they're about to
991 # try to use it.
992 # We would use "grep -q" here, but Solaris's grep doesn't support it.
993 checkMake380() {
994     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
995     then
996         echo
997         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
998         echo "This version cannot be used to build GHC."
999         echo "Please use GNU make >= 3.81."
1000     fi
1001 }
1002
1003 checkMake380 make
1004 checkMake380 gmake
1005
1006 echo ["
1007 ----------------------------------------------------------------------
1008 Configure completed successfully.
1009
1010    Building GHC version  : $ProjectVersion
1011           Git commit id  : $ProjectGitCommitId
1012
1013    Build platform        : $BuildPlatform
1014    Host platform         : $HostPlatform
1015    Target platform       : $TargetPlatform
1016 "]
1017
1018 echo ["\
1019    Bootstrapping using   : $WithGhc
1020       which is version   : $GhcVersion
1021 "]
1022
1023 if test "x$CC_LLVM_BACKEND" = "x1"; then
1024     if test "x$CC_CLANG_BACKEND" = "x1"; then
1025         CompilerName="clang        "
1026     else
1027         CompilerName="llvm-gcc     "
1028     fi
1029 else
1030     CompilerName="gcc          "
1031 fi
1032
1033 echo ["\
1034    Using $CompilerName       : $WhatGccIsCalled
1035       which is version       : $GccVersion
1036    Building a cross compiler : $CrossCompiling
1037    hs-cpp       : $HaskellCPPCmd
1038    hs-cpp-flags : $HaskellCPPArgs
1039    ld           : $LdCmd
1040    Happy        : $HappyCmd ($HappyVersion)
1041    Alex         : $AlexCmd ($AlexVersion)
1042    Perl         : $PerlCmd
1043    dblatex      : $DblatexCmd
1044    xsltproc     : $XsltprocCmd
1045
1046    Using LLVM tools
1047       llc   : $LlcCmd
1048       opt   : $OptCmd"]
1049
1050 if test "$HSCOLOUR" = ""; then
1051 echo ["
1052    HsColour was not found; documentation will not contain source links
1053 "]
1054 else
1055 echo ["\
1056    HsColour : $HSCOLOUR
1057 "]
1058 fi
1059
1060 echo ["\
1061    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
1062    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
1063    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
1064
1065 echo ["----------------------------------------------------------------------
1066 "]
1067
1068 echo "\
1069 For a standard build of GHC (fully optimised with profiling), type (g)make.
1070
1071 To make changes to the default build configuration, copy the file
1072 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1073
1074 For more information on how to configure your GHC build, see
1075    http://ghc.haskell.org/trac/ghc/wiki/Building
1076 "