Merge branch 'master' of darcs.haskell.org:/home/darcs/ghc
[ghc.git] / compiler / types / TyCon.lhs
1 %
2 % (c) The University of Glasgow 2006
3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
4 %
5
6 The @TyCon@ datatype
7
8 \begin{code}
9
10 module TyCon(
11         -- * Main TyCon data types
12         TyCon, FieldLabel,
13
14         AlgTyConRhs(..), visibleDataCons,
15         TyConParent(..), isNoParent,
16         SynTyConRhs(..), 
17
18         -- ** Constructing TyCons
19         mkAlgTyCon,
20         mkClassTyCon,
21         mkFunTyCon,
22         mkPrimTyCon,
23         mkKindTyCon,
24         mkLiftedPrimTyCon,
25         mkTupleTyCon,
26         mkSynTyCon,
27         mkForeignTyCon,
28         mkPromotedDataCon,
29         mkPromotedTyCon,
30
31         -- ** Predicates on TyCons
32         isAlgTyCon,
33         isClassTyCon, isFamInstTyCon,
34         isFunTyCon,
35         isPrimTyCon,
36         isTupleTyCon, isUnboxedTupleTyCon, isBoxedTupleTyCon,
37         isSynTyCon, isOpenSynFamilyTyCon,
38         isDecomposableTyCon,
39         isForeignTyCon, 
40         isPromotedDataCon, isPromotedTyCon,
41         isPromotedDataCon_maybe, isPromotedTyCon_maybe,
42         promotableTyCon_maybe, promoteTyCon,
43
44         isInjectiveTyCon,
45         isDataTyCon, isProductTyCon, isEnumerationTyCon,
46         isNewTyCon, isAbstractTyCon,
47         isFamilyTyCon, isSynFamilyTyCon, isDataFamilyTyCon,
48         isUnLiftedTyCon,
49         isGadtSyntaxTyCon, isDistinctTyCon, isDistinctAlgRhs,
50         isTyConAssoc, tyConAssoc_maybe,
51         isRecursiveTyCon,
52         isImplicitTyCon,
53
54         -- ** Extracting information out of TyCons
55         tyConName,
56         tyConKind,
57         tyConUnique,
58         tyConTyVars,
59         tyConCType, tyConCType_maybe,
60         tyConDataCons, tyConDataCons_maybe, 
61         tyConSingleDataCon_maybe, tyConSingleAlgDataCon_maybe,
62         tyConFamilySize,
63         tyConStupidTheta,
64         tyConArity,
65         tyConParent,
66         tyConTuple_maybe, tyConClass_maybe,
67         tyConFamInst_maybe, tyConFamInstSig_maybe, tyConFamilyCoercion_maybe,
68         synTyConDefn_maybe, synTyConRhs_maybe, 
69         tyConExtName,           -- External name for foreign types
70         algTyConRhs,
71         newTyConRhs, newTyConEtadRhs, unwrapNewTyCon_maybe,
72         tupleTyConBoxity, tupleTyConSort, tupleTyConArity,
73
74         -- ** Manipulating TyCons
75         tcExpandTyCon_maybe, coreExpandTyCon_maybe,
76         makeTyConAbstract,
77         newTyConCo, newTyConCo_maybe,
78         pprPromotionQuote,
79
80         -- * Primitive representations of Types
81         PrimRep(..),
82         tyConPrimRep,
83         primRepSizeW
84 ) where
85
86 #include "HsVersions.h"
87
88 import {-# SOURCE #-} TypeRep ( Kind, Type, PredType )
89 import {-# SOURCE #-} DataCon ( DataCon, isVanillaDataCon )
90
91 import Var
92 import Class
93 import BasicTypes
94 import DynFlags
95 import ForeignCall
96 import Name
97 import CoAxiom
98 import PrelNames
99 import Maybes
100 import Outputable
101 import FastString
102 import Constants
103 import Util
104 import qualified Data.Data as Data
105 import Data.Typeable (Typeable)
106 \end{code}
107
108 -----------------------------------------------
109         Notes about type families
110 -----------------------------------------------
111
112 Note [Type synonym families]
113 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
114 * Type synonym families, also known as "type functions", map directly
115   onto the type functions in FC:
116
117         type family F a :: *
118         type instance F Int = Bool
119         ..etc...
120
121 * Reply "yes" to isSynFamilyTyCon, and isFamilyTyCon
122
123 * From the user's point of view (F Int) and Bool are simply
124   equivalent types.
125
126 * A Haskell 98 type synonym is a degenerate form of a type synonym
127   family.
128
129 * Type functions can't appear in the LHS of a type function:
130         type instance F (F Int) = ...   -- BAD!
131
132 * Translation of type family decl:
133         type family F a :: *
134   translates to
135     a SynTyCon 'F', whose SynTyConRhs is SynFamilyTyCon
136
137 * Translation of type family decl:
138         type family F a :: *
139   translates to
140     a SynTyCon 'F', whose SynTyConRhs is SynFamilyTyCon
141
142 * In the future we might want to support
143     * closed type families (esp when we have proper kinds)
144     * injective type families (allow decomposition)
145   but we don't at the moment [2010]
146
147 Note [Data type families]
148 ~~~~~~~~~~~~~~~~~~~~~~~~~
149 See also Note [Wrappers for data instance tycons] in MkId.lhs
150
151 * Data type families are declared thus
152         data family T a :: *
153         data instance T Int = T1 | T2 Bool
154
155   Here T is the "family TyCon".
156
157 * Reply "yes" to isDataFamilyTyCon, and isFamilyTyCon
158
159 * The user does not see any "equivalent types" as he did with type
160   synonym families.  He just sees constructors with types
161         T1 :: T Int
162         T2 :: Bool -> T Int
163
164 * Here's the FC version of the above declarations:
165
166         data T a
167         data R:TInt = T1 | T2 Bool
168         axiom ax_ti : T Int ~ R:TInt
169
170   The R:TInt is the "representation TyCons".
171   It has an AlgTyConParent of
172         FamInstTyCon T [Int] ax_ti
173
174 * The data contructor T2 has a wrapper (which is what the
175   source-level "T2" invokes):
176
177         $WT2 :: Bool -> T Int
178         $WT2 b = T2 b `cast` sym ax_ti
179
180 * A data instance can declare a fully-fledged GADT:
181
182         data instance T (a,b) where
183           X1 :: T (Int,Bool)
184           X2 :: a -> b -> T (a,b)
185
186   Here's the FC version of the above declaration:
187
188         data R:TPair a where
189           X1 :: R:TPair Int Bool
190           X2 :: a -> b -> R:TPair a b
191         axiom ax_pr :: T (a,b) ~ R:TPair a b
192
193         $WX1 :: forall a b. a -> b -> T (a,b)
194         $WX1 a b (x::a) (y::b) = X2 a b x y `cast` sym (ax_pr a b)
195
196   The R:TPair are the "representation TyCons".
197   We have a bit of work to do, to unpick the result types of the
198   data instance declaration for T (a,b), to get the result type in the
199   representation; e.g.  T (a,b) --> R:TPair a b
200
201   The representation TyCon R:TList, has an AlgTyConParent of
202
203         FamInstTyCon T [(a,b)] ax_pr
204
205 * Notice that T is NOT translated to a FC type function; it just
206   becomes a "data type" with no constructors, which can be coerced inot
207   into R:TInt, R:TPair by the axioms.  These axioms
208   axioms come into play when (and *only* when) you
209         - use a data constructor
210         - do pattern matching
211   Rather like newtype, in fact
212
213   As a result
214
215   - T behaves just like a data type so far as decomposition is concerned
216
217   - (T Int) is not implicitly converted to R:TInt during type inference.
218     Indeed the latter type is unknown to the programmer.
219
220   - There *is* an instance for (T Int) in the type-family instance
221     environment, but it is only used for overlap checking
222
223   - It's fine to have T in the LHS of a type function:
224     type instance F (T a) = [a]
225
226   It was this last point that confused me!  The big thing is that you
227   should not think of a data family T as a *type function* at all, not
228   even an injective one!  We can't allow even injective type functions
229   on the LHS of a type function:
230         type family injective G a :: *
231         type instance F (G Int) = Bool
232   is no good, even if G is injective, because consider
233         type instance G Int = Bool
234         type instance F Bool = Char
235
236   So a data type family is not an injective type function. It's just a
237   data type with some axioms that connect it to other data types.
238
239 Note [Associated families and their parent class]
240 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
241 *Associated* families are just like *non-associated* families, except
242 that they have a TyConParent of AssocFamilyTyCon, which identifies the
243 parent class.
244
245 However there is an important sharing relationship between
246   * the tyConTyVars of the parent Class
247   * the tyConTyvars of the associated TyCon
248
249    class C a b where
250      data T p a
251      type F a q b
252
253 Here the 'a' and 'b' are shared with the 'Class'; that is, they have
254 the same Unique.
255
256 This is important. In an instance declaration we expect
257   * all the shared variables to be instantiated the same way
258   * the non-shared variables of the associated type should not
259     be instantiated at all
260
261   instance C [x] (Tree y) where
262      data T p [x] = T1 x | T2 p
263      type F [x] q (Tree y) = (x,y,q)
264
265 %************************************************************************
266 %*                                                                      *
267 \subsection{The data type}
268 %*                                                                      *
269 %************************************************************************
270
271 \begin{code}
272 -- | TyCons represent type constructors. Type constructors are introduced by things such as:
273 --
274 -- 1) Data declarations: @data Foo = ...@ creates the @Foo@ type constructor of kind @*@
275 --
276 -- 2) Type synonyms: @type Foo = ...@ creates the @Foo@ type constructor
277 --
278 -- 3) Newtypes: @newtype Foo a = MkFoo ...@ creates the @Foo@ type constructor of kind @* -> *@
279 --
280 -- 4) Class declarations: @class Foo where@ creates the @Foo@ type constructor of kind @*@
281 --
282 -- This data type also encodes a number of primitive, built in type constructors such as those
283 -- for function and tuple types.
284
285 -- If you edit this type, you may need to update the GHC formalism
286 -- See Note [GHC Formalism] in coreSyn/CoreLint.lhs
287 data TyCon
288   = -- | The function type constructor, @(->)@
289     FunTyCon {
290         tyConUnique :: Unique,
291         tyConName   :: Name,
292         tc_kind   :: Kind,
293         tyConArity  :: Arity
294     }
295
296   -- | Algebraic type constructors, which are defined to be those
297   -- arising @data@ type and @newtype@ declarations.  All these
298   -- constructors are lifted and boxed. See 'AlgTyConRhs' for more
299   -- information.
300   | AlgTyCon {
301         tyConUnique :: Unique,
302         tyConName   :: Name,
303         tc_kind     :: Kind,
304         tyConArity  :: Arity,
305
306         tyConTyVars :: [TyVar],   -- ^ The kind and type variables used in the type constructor.
307                                   -- Invariant: length tyvars = arity
308                                   -- Precisely, this list scopes over:
309                                   --
310                                   -- 1. The 'algTcStupidTheta'
311                                   -- 2. The cached types in 'algTyConRhs.NewTyCon'
312                                   -- 3. The family instance types if present
313                                   --
314                                   -- Note that it does /not/ scope over the data constructors.
315         tyConCType   :: Maybe CType, -- The C type that should be used
316                                      -- for this type when using the FFI
317                                      -- and CAPI
318
319         algTcGadtSyntax  :: Bool,       -- ^ Was the data type declared with GADT syntax?
320                                         -- If so, that doesn't mean it's a true GADT;
321                                         -- only that the "where" form was used.
322                                         -- This field is used only to guide pretty-printing
323
324         algTcStupidTheta :: [PredType], -- ^ The \"stupid theta\" for the data type
325                                         -- (always empty for GADTs).
326                                         -- A \"stupid theta\" is the context to the left
327                                         -- of an algebraic type declaration,
328                                         -- e.g. @Eq a@ in the declaration
329                                         --    @data Eq a => T a ...@.
330
331         algTcRhs :: AlgTyConRhs,  -- ^ Contains information about the
332                                   -- data constructors of the algebraic type
333
334         algTcRec :: RecFlag,      -- ^ Tells us whether the data type is part
335                                   -- of a mutually-recursive group or not
336
337         algTcParent :: TyConParent,     -- ^ Gives the class or family declaration 'TyCon'
338                                         -- for derived 'TyCon's representing class
339                                         -- or family instances, respectively.
340                                         -- See also 'synTcParent'
341         
342         tcPromoted :: Maybe TyCon    -- ^ Promoted TyCon, if any
343     }
344
345   -- | Represents the infinite family of tuple type constructors,
346   --   @()@, @(a,b)@, @(# a, b #)@ etc.
347   | TupleTyCon {
348         tyConUnique    :: Unique,
349         tyConName      :: Name,
350         tc_kind        :: Kind,
351         tyConArity     :: Arity,
352         tyConTupleSort :: TupleSort,
353         tyConTyVars    :: [TyVar],
354         dataCon        :: DataCon, -- ^ Corresponding tuple data constructor
355         tcPromoted     :: Maybe TyCon    -- Nothing for unboxed tuples
356     }
357
358   -- | Represents type synonyms
359   | SynTyCon {
360         tyConUnique  :: Unique,
361         tyConName    :: Name,
362         tc_kind    :: Kind,
363         tyConArity   :: Arity,
364
365         tyConTyVars  :: [TyVar],        -- Bound tyvars
366
367         synTcRhs     :: SynTyConRhs Type,  -- ^ Contains information about the
368                                            -- expansion of the synonym
369
370         synTcParent  :: TyConParent     -- ^ Gives the family declaration 'TyCon'
371                                         -- of 'TyCon's representing family instances
372
373     }
374
375   -- | Primitive types; cannot be defined in Haskell. This includes
376   -- the usual suspects (such as @Int#@) as well as foreign-imported
377   -- types and kinds
378   | PrimTyCon {
379         tyConUnique   :: Unique,
380         tyConName     :: Name,
381         tc_kind       :: Kind,
382         tyConArity    :: Arity,         -- SLPJ Oct06: I'm not sure what the significance
383                                         --             of the arity of a primtycon is!
384
385         primTyConRep  :: PrimRep,       -- ^ Many primitive tycons are unboxed, but some are
386                                         --   boxed (represented by pointers). This 'PrimRep'
387                                         --   holds that information.
388                                         -- Only relevant if tc_kind = *
389
390         isUnLifted   :: Bool,           -- ^ Most primitive tycons are unlifted
391                                         --   (may not contain bottom)
392                                         --   but foreign-imported ones may be lifted
393
394         tyConExtName :: Maybe FastString   -- ^ @Just e@ for foreign-imported types,
395                                            --   holds the name of the imported thing
396     }
397
398   -- | Represents promoted data constructor.
399   | PromotedDataCon {         -- See Note [Promoted data constructors]
400         tyConUnique :: Unique, -- ^ Same Unique as the data constructor
401         tyConName   :: Name,   -- ^ Same Name as the data constructor
402         tyConArity  :: Arity,
403         tc_kind     :: Kind,   -- ^ Translated type of the data constructor
404         dataCon     :: DataCon -- ^ Corresponding data constructor
405     }
406
407   -- | Represents promoted type constructor.
408   | PromotedTyCon {
409         tyConUnique :: Unique, -- ^ Same Unique as the type constructor
410         tyConName   :: Name,   -- ^ Same Name as the type constructor
411         tyConArity  :: Arity,  -- ^ n if ty_con :: * -> ... -> *  n times
412         tc_kind     :: Kind,   -- ^ Always TysPrim.superKind
413         ty_con      :: TyCon   -- ^ Corresponding type constructor
414     }
415
416   deriving Typeable
417
418 -- | Names of the fields in an algebraic record type
419 type FieldLabel = Name
420
421 -- | Represents right-hand-sides of 'TyCon's for algebraic types
422 data AlgTyConRhs
423
424     -- | Says that we know nothing about this data type, except that
425     -- it's represented by a pointer.  Used when we export a data type
426     -- abstractly into an .hi file.
427   = AbstractTyCon
428       Bool      -- True  <=> It's definitely a distinct data type,
429                 --           equal only to itself; ie not a newtype
430                 -- False <=> Not sure
431                 -- See Note [AbstractTyCon and type equality]
432
433     -- | Represents an open type family without a fixed right hand
434     -- side.  Additional instances can appear at any time.
435     --
436     -- These are introduced by either a top level declaration:
437     --
438     -- > data T a :: *
439     --
440     -- Or an associated data type declaration, within a class declaration:
441     --
442     -- > class C a b where
443     -- >   data T b :: *
444   | DataFamilyTyCon
445
446     -- | Information about those 'TyCon's derived from a @data@
447     -- declaration. This includes data types with no constructors at
448     -- all.
449   | DataTyCon {
450         data_cons :: [DataCon],
451                           -- ^ The data type constructors; can be empty if the user
452                           --   declares the type to have no constructors
453                           --
454                           -- INVARIANT: Kept in order of increasing 'DataCon' tag
455                           --      (see the tag assignment in DataCon.mkDataCon)
456
457         is_enum :: Bool   -- ^ Cached value: is this an enumeration type?
458                           --   See Note [Enumeration types]
459     }
460
461   -- | Information about those 'TyCon's derived from a @newtype@ declaration
462   | NewTyCon {
463         data_con :: DataCon,    -- ^ The unique constructor for the @newtype@.
464                                 --   It has no existentials
465
466         nt_rhs :: Type,         -- ^ Cached value: the argument type of the constructor,
467                                 -- which is just the representation type of the 'TyCon'
468                                 -- (remember that @newtype@s do not exist at runtime
469                                 -- so need a different representation type).
470                                 --
471                                 -- The free 'TyVar's of this type are the 'tyConTyVars'
472                                 -- from the corresponding 'TyCon'
473
474         nt_etad_rhs :: ([TyVar], Type),
475                         -- ^ Same as the 'nt_rhs', but this time eta-reduced.
476                         -- Hence the list of 'TyVar's in this field may be
477                         -- shorter than the declared arity of the 'TyCon'.
478
479                         -- See Note [Newtype eta]
480         nt_co :: CoAxiom Unbranched
481                              -- The axiom coercion that creates the @newtype@ from
482                              -- the representation 'Type'.
483
484                              -- See Note [Newtype coercions]
485                              -- Invariant: arity = #tvs in nt_etad_rhs;
486                              -- See Note [Newtype eta]
487                              -- Watch out!  If any newtypes become transparent
488                              -- again check Trac #1072.
489     }
490 \end{code}
491
492 Note [AbstractTyCon and type equality]
493 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
494 TODO
495
496 \begin{code}
497
498 -- | Extract those 'DataCon's that we are able to learn about.  Note
499 -- that visibility in this sense does not correspond to visibility in
500 -- the context of any particular user program!
501 visibleDataCons :: AlgTyConRhs -> [DataCon]
502 visibleDataCons (AbstractTyCon {})            = []
503 visibleDataCons DataFamilyTyCon {}            = []
504 visibleDataCons (DataTyCon{ data_cons = cs }) = cs
505 visibleDataCons (NewTyCon{ data_con = c })    = [c]
506
507 -- ^ Both type classes as well as family instances imply implicit
508 -- type constructors.  These implicit type constructors refer to their parent
509 -- structure (ie, the class or family from which they derive) using a type of
510 -- the following form.  We use 'TyConParent' for both algebraic and synonym
511 -- types, but the variant 'ClassTyCon' will only be used by algebraic 'TyCon's.
512 data TyConParent
513   = -- | An ordinary type constructor has no parent.
514     NoParentTyCon
515
516   -- | Type constructors representing a class dictionary.
517   -- See Note [ATyCon for classes] in TypeRep
518   | ClassTyCon
519         Class           -- INVARIANT: the classTyCon of this Class is the current tycon
520
521   -- | An *associated* type of a class.
522   | AssocFamilyTyCon
523         Class           -- The class in whose declaration the family is declared
524                         -- See Note [Associated families and their parent class]
525
526   -- | Type constructors representing an instance of a *data* family. Parameters:
527   --
528   --  1) The type family in question
529   --
530   --  2) Instance types; free variables are the 'tyConTyVars'
531   --  of the current 'TyCon' (not the family one). INVARIANT:
532   --  the number of types matches the arity of the family 'TyCon'
533   --
534   --  3) A 'CoTyCon' identifying the representation
535   --  type with the type instance family
536   | FamInstTyCon          -- See Note [Data type families]
537         (CoAxiom Unbranched)  -- The coercion constructor,
538                               -- always of kind   T ty1 ty2 ~ R:T a b c
539                               -- where T is the family TyCon,
540                               -- and R:T is the representation TyCon (ie this one)
541                               -- and a,b,c are the tyConTyVars of this TyCon
542
543           -- Cached fields of the CoAxiom, but adjusted to
544           -- use the tyConTyVars of this TyCon
545         TyCon   -- The family TyCon
546         [Type]  -- Argument types (mentions the tyConTyVars of this TyCon)
547                 -- Match in length the tyConTyVars of the family TyCon
548
549         -- E.g.  data intance T [a] = ...
550         -- gives a representation tycon:
551         --      data R:TList a = ...
552         --      axiom co a :: T [a] ~ R:TList a
553         -- with R:TList's algTcParent = FamInstTyCon T [a] co
554
555 instance Outputable TyConParent where
556     ppr NoParentTyCon           = text "No parent"
557     ppr (ClassTyCon cls)        = text "Class parent" <+> ppr cls
558     ppr (AssocFamilyTyCon cls)  = text "Class parent (assoc. family)" <+> ppr cls
559     ppr (FamInstTyCon _ tc tys) = text "Family parent (family instance)" <+> ppr tc <+> sep (map ppr tys)
560
561 -- | Checks the invariants of a 'TyConParent' given the appropriate type class name, if any
562 okParent :: Name -> TyConParent -> Bool
563 okParent _       NoParentTyCon               = True
564 okParent tc_name (AssocFamilyTyCon cls)      = tc_name `elem` map tyConName (classATs cls)
565 okParent tc_name (ClassTyCon cls)            = tc_name == tyConName (classTyCon cls)
566 okParent _       (FamInstTyCon _ fam_tc tys) = tyConArity fam_tc == length tys
567
568 isNoParent :: TyConParent -> Bool
569 isNoParent NoParentTyCon = True
570 isNoParent _             = False
571
572 --------------------
573
574 -- | Information pertaining to the expansion of a type synonym (@type@)
575 data SynTyConRhs ty
576   = -- | An ordinary type synonyn.
577     SynonymTyCon
578        ty             -- This 'Type' is the rhs, and may mention from 'tyConTyVars'.
579                       -- It acts as a template for the expansion when the 'TyCon'
580                       -- is applied to some types.
581
582    -- | A type synonym family  e.g. @type family F x y :: * -> *@
583    | SynFamilyTyCon {
584         synf_open :: Bool,         -- See Note [Closed type families]
585         synf_injective :: Bool 
586      }
587 \end{code}
588
589 Note [Closed type families]
590 ~~~~~~~~~~~~~~~~~~~~~~~~~
591 * In an open type family you can add new instances later.  This is the 
592   usual case.  
593
594 * In a closed type family you can only put instnaces where the family
595   is defined.  GHC doesn't support syntax for this yet.
596
597 Note [Promoted data constructors]
598 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
599 A data constructor can be promoted to become a type constructor,
600 via the PromotedTyCon alternative in TyCon.
601
602 * Only data constructors with  
603      (a) no kind polymorphism
604      (b) no constraints in its type (eg GADTs)
605   are promoted.  Existentials are ok; see Trac #7347.
606
607 * The TyCon promoted from a DataCon has the *same* Name and Unique as
608   the DataCon.  Eg. If the data constructor Data.Maybe.Just(unique 78,
609   say) is promoted to a TyCon whose name is Data.Maybe.Just(unique 78)
610
611 * The *kind* of a promoted DataCon may be polymorphic.  Example:
612     type of DataCon           Just :: forall (a:*). a -> Maybe a
613     kind of (promoted) tycon  Just :: forall (a:box). a -> Maybe a
614   The kind is not identical to the type, because of the */box
615   kind signature on the forall'd variable; so the tc_kind field of
616   PromotedTyCon is not identical to the dataConUserType of the
617   DataCon.  But it's the same modulo changing the variable kinds,
618   done by DataCon.promoteType.
619
620 * Small note: We promote the *user* type of the DataCon.  Eg
621      data T = MkT {-# UNPACK #-} !(Bool, Bool)
622   The promoted kind is
623      MkT :: (Bool,Bool) -> T
624   *not*
625      MkT :: Bool -> Bool -> T
626
627 Note [Enumeration types]
628 ~~~~~~~~~~~~~~~~~~~~~~~~
629 We define datatypes with no constructors to *not* be
630 enumerations; this fixes trac #2578,  Otherwise we
631 end up generating an empty table for
632   <mod>_<type>_closure_tbl
633 which is used by tagToEnum# to map Int# to constructors
634 in an enumeration. The empty table apparently upset
635 the linker.
636
637 Moreover, all the data constructor must be enumerations, meaning
638 they have type  (forall abc. T a b c).  GADTs are not enumerations.
639 For example consider
640     data T a where
641       T1 :: T Int
642       T2 :: T Bool
643       T3 :: T a
644 What would [T1 ..] be?  [T1,T3] :: T Int? Easiest thing is to exclude them.
645 See Trac #4528.
646
647 Note [Newtype coercions]
648 ~~~~~~~~~~~~~~~~~~~~~~~~
649 The NewTyCon field nt_co is a CoAxiom which is used for coercing from
650 the representation type of the newtype, to the newtype itself. For
651 example,
652
653    newtype T a = MkT (a -> a)
654
655 the NewTyCon for T will contain nt_co = CoT where CoT t : T t ~ t -> t.
656
657 In the case that the right hand side is a type application
658 ending with the same type variables as the left hand side, we
659 "eta-contract" the coercion.  So if we had
660
661    newtype S a = MkT [a]
662
663 then we would generate the arity 0 axiom CoS : S ~ [].  The
664 primary reason we do this is to make newtype deriving cleaner.
665
666 In the paper we'd write
667         axiom CoT : (forall t. T t) ~ (forall t. [t])
668 and then when we used CoT at a particular type, s, we'd say
669         CoT @ s
670 which encodes as (TyConApp instCoercionTyCon [TyConApp CoT [], s])
671
672 Note [Newtype eta]
673 ~~~~~~~~~~~~~~~~~~
674 Consider
675         newtype Parser m a = MkParser (Foogle m a)
676 Are these two types equal (to Core)?
677         Monad (Parser m)
678         Monad (Foogle m)
679 Well, yes.  But to see that easily we eta-reduce the RHS type of
680 Parser, in this case to ([], Froogle), so that even unsaturated applications
681 of Parser will work right.  This eta reduction is done when the type
682 constructor is built, and cached in NewTyCon.  The cached field is
683 only used in coreExpandTyCon_maybe.
684
685 Here's an example that I think showed up in practice
686 Source code:
687         newtype T a = MkT [a]
688         newtype Foo m = MkFoo (forall a. m a -> Int)
689
690         w1 :: Foo []
691         w1 = ...
692
693         w2 :: Foo T
694         w2 = MkFoo (\(MkT x) -> case w1 of MkFoo f -> f x)
695
696 After desugaring, and discarding the data constructors for the newtypes,
697 we get:
698         w2 :: Foo T
699         w2 = w1
700 And now Lint complains unless Foo T == Foo [], and that requires T==[]
701
702 This point carries over to the newtype coercion, because we need to
703 say
704         w2 = w1 `cast` Foo CoT
705
706 so the coercion tycon CoT must have
707         kind:    T ~ []
708  and    arity:   0
709
710 %************************************************************************
711 %*                                                                      *
712 \subsection{PrimRep}
713 %*                                                                      *
714 %************************************************************************
715
716 Note [rep swamp]
717
718 GHC has a rich selection of types that represent "primitive types" of
719 one kind or another.  Each of them makes a different set of
720 distinctions, and mostly the differences are for good reasons,
721 although it's probably true that we could merge some of these.
722
723 Roughly in order of "includes more information":
724
725  - A Width (cmm/CmmType) is simply a binary value with the specified
726    number of bits.  It may represent a signed or unsigned integer, a
727    floating-point value, or an address.
728
729     data Width = W8 | W16 | W32 | W64 | W80 | W128
730
731  - Size, which is used in the native code generator, is Width +
732    floating point information.
733
734    data Size = II8 | II16 | II32 | II64 | FF32 | FF64 | FF80
735
736    it is necessary because e.g. the instruction to move a 64-bit float
737    on x86 (movsd) is different from the instruction to move a 64-bit
738    integer (movq), so the mov instruction is parameterised by Size.
739
740  - CmmType wraps Width with more information: GC ptr, float, or
741    other value.
742
743     data CmmType = CmmType CmmCat Width
744     
745     data CmmCat     -- "Category" (not exported)
746        = GcPtrCat   -- GC pointer
747        | BitsCat    -- Non-pointer
748        | FloatCat   -- Float
749
750    It is important to have GcPtr information in Cmm, since we generate
751    info tables containing pointerhood for the GC from this.  As for
752    why we have float (and not signed/unsigned) here, see Note [Signed
753    vs unsigned].
754
755  - ArgRep makes only the distinctions necessary for the call and
756    return conventions of the STG machine.  It is essentially CmmType
757    + void.
758
759  - PrimRep makes a few more distinctions than ArgRep: it divides
760    non-GC-pointers into signed/unsigned and addresses, information
761    that is necessary for passing these values to foreign functions.
762
763 There's another tension here: whether the type encodes its size in
764 bytes, or whether its size depends on the machine word size.  Width
765 and CmmType have the size built-in, whereas ArgRep and PrimRep do not.
766
767 This means to turn an ArgRep/PrimRep into a CmmType requires DynFlags.
768
769 On the other hand, CmmType includes some "nonsense" values, such as
770 CmmType GcPtrCat W32 on a 64-bit machine.
771
772 \begin{code}
773 -- | A 'PrimRep' is an abstraction of a type.  It contains information that
774 -- the code generator needs in order to pass arguments, return results,
775 -- and store values of this type.
776 data PrimRep
777   = VoidRep
778   | PtrRep
779   | IntRep              -- ^ Signed, word-sized value
780   | WordRep             -- ^ Unsigned, word-sized value
781   | Int64Rep            -- ^ Signed, 64 bit value (with 32-bit words only)
782   | Word64Rep           -- ^ Unsigned, 64 bit value (with 32-bit words only)
783   | AddrRep             -- ^ A pointer, but /not/ to a Haskell value (use 'PtrRep')
784   | FloatRep
785   | DoubleRep
786   deriving( Eq, Show )
787
788 instance Outputable PrimRep where
789   ppr r = text (show r)
790
791 -- | Find the size of a 'PrimRep', in words
792 primRepSizeW :: DynFlags -> PrimRep -> Int
793 primRepSizeW _      IntRep   = 1
794 primRepSizeW _      WordRep  = 1
795 primRepSizeW dflags Int64Rep = wORD64_SIZE `quot` wORD_SIZE dflags
796 primRepSizeW dflags Word64Rep= wORD64_SIZE `quot` wORD_SIZE dflags
797 primRepSizeW _      FloatRep = 1    -- NB. might not take a full word
798 primRepSizeW dflags DoubleRep= dOUBLE_SIZE dflags `quot` wORD_SIZE dflags
799 primRepSizeW _      AddrRep  = 1
800 primRepSizeW _      PtrRep   = 1
801 primRepSizeW _      VoidRep  = 0
802 \end{code}
803
804 %************************************************************************
805 %*                                                                      *
806 \subsection{TyCon Construction}
807 %*                                                                      *
808 %************************************************************************
809
810 Note: the TyCon constructors all take a Kind as one argument, even though
811 they could, in principle, work out their Kind from their other arguments.
812 But to do so they need functions from Types, and that makes a nasty
813 module mutual-recursion.  And they aren't called from many places.
814 So we compromise, and move their Kind calculation to the call site.
815
816 \begin{code}
817 -- | Given the name of the function type constructor and it's kind, create the
818 -- corresponding 'TyCon'. It is reccomended to use 'TypeRep.funTyCon' if you want
819 -- this functionality
820 mkFunTyCon :: Name -> Kind -> TyCon
821 mkFunTyCon name kind
822   = FunTyCon {
823         tyConUnique = nameUnique name,
824         tyConName   = name,
825         tc_kind   = kind,
826         tyConArity  = 2
827     }
828
829 -- | This is the making of an algebraic 'TyCon'. Notably, you have to
830 -- pass in the generic (in the -XGenerics sense) information about the
831 -- type constructor - you can get hold of it easily (see Generics
832 -- module)
833 mkAlgTyCon :: Name
834            -> Kind              -- ^ Kind of the resulting 'TyCon'
835            -> [TyVar]           -- ^ 'TyVar's scoped over: see 'tyConTyVars'.
836                                 --   Arity is inferred from the length of this list
837            -> Maybe CType       -- ^ The C type this type corresponds to
838                                 --   when using the CAPI FFI
839            -> [PredType]        -- ^ Stupid theta: see 'algTcStupidTheta'
840            -> AlgTyConRhs       -- ^ Information about dat aconstructors
841            -> TyConParent
842            -> RecFlag           -- ^ Is the 'TyCon' recursive?
843            -> Bool              -- ^ Was the 'TyCon' declared with GADT syntax?
844            -> Maybe TyCon       -- ^ Promoted version
845            -> TyCon
846 mkAlgTyCon name kind tyvars cType stupid rhs parent is_rec gadt_syn prom_tc
847   = AlgTyCon {
848         tyConName        = name,
849         tyConUnique      = nameUnique name,
850         tc_kind          = kind,
851         tyConArity       = length tyvars,
852         tyConTyVars      = tyvars,
853         tyConCType       = cType,
854         algTcStupidTheta = stupid,
855         algTcRhs         = rhs,
856         algTcParent      = ASSERT2( okParent name parent, ppr name $$ ppr parent ) parent,
857         algTcRec         = is_rec,
858         algTcGadtSyntax  = gadt_syn,
859         tcPromoted       = prom_tc
860     }
861
862 -- | Simpler specialization of 'mkAlgTyCon' for classes
863 mkClassTyCon :: Name -> Kind -> [TyVar] -> AlgTyConRhs -> Class -> RecFlag -> TyCon
864 mkClassTyCon name kind tyvars rhs clas is_rec
865   = mkAlgTyCon name kind tyvars Nothing [] rhs (ClassTyCon clas) 
866                is_rec False 
867                Nothing    -- Class TyCons are not pormoted
868
869 mkTupleTyCon :: Name
870              -> Kind    -- ^ Kind of the resulting 'TyCon'
871              -> Arity   -- ^ Arity of the tuple
872              -> [TyVar] -- ^ 'TyVar's scoped over: see 'tyConTyVars'
873              -> DataCon
874              -> TupleSort    -- ^ Whether the tuple is boxed or unboxed
875              -> Maybe TyCon  -- ^ Promoted version
876              -> TyCon
877 mkTupleTyCon name kind arity tyvars con sort prom_tc
878   = TupleTyCon {
879         tyConUnique = nameUnique name,
880         tyConName = name,
881         tc_kind = kind,
882         tyConArity = arity,
883         tyConTupleSort = sort,
884         tyConTyVars = tyvars,
885         dataCon = con,
886         tcPromoted = prom_tc
887     }
888
889 -- ^ Foreign-imported (.NET) type constructors are represented
890 -- as primitive, but /lifted/, 'TyCons' for now. They are lifted
891 -- because the Haskell type @T@ representing the (foreign) .NET
892 -- type @T@ is actually implemented (in ILX) as a @thunk<T>@
893 mkForeignTyCon :: Name
894                -> Maybe FastString -- ^ Name of the foreign imported thing, maybe
895                -> Kind
896                -> Arity
897                -> TyCon
898 mkForeignTyCon name ext_name kind arity
899   = PrimTyCon {
900         tyConName    = name,
901         tyConUnique  = nameUnique name,
902         tc_kind    = kind,
903         tyConArity   = arity,
904         primTyConRep = PtrRep, -- they all do
905         isUnLifted   = False,
906         tyConExtName = ext_name
907     }
908
909
910 -- | Create an unlifted primitive 'TyCon', such as @Int#@
911 mkPrimTyCon :: Name  -> Kind -> Arity -> PrimRep -> TyCon
912 mkPrimTyCon name kind arity rep
913   = mkPrimTyCon' name kind arity rep True
914
915 -- | Kind constructors
916 mkKindTyCon :: Name -> Kind -> TyCon
917 mkKindTyCon name kind
918   = mkPrimTyCon' name kind 0 VoidRep True
919
920 -- | Create a lifted primitive 'TyCon' such as @RealWorld@
921 mkLiftedPrimTyCon :: Name  -> Kind -> Arity -> PrimRep -> TyCon
922 mkLiftedPrimTyCon name kind arity rep
923   = mkPrimTyCon' name kind arity rep False
924
925 mkPrimTyCon' :: Name  -> Kind -> Arity -> PrimRep -> Bool -> TyCon
926 mkPrimTyCon' name kind arity rep is_unlifted
927   = PrimTyCon {
928         tyConName    = name,
929         tyConUnique  = nameUnique name,
930         tc_kind    = kind,
931         tyConArity   = arity,
932         primTyConRep = rep,
933         isUnLifted   = is_unlifted,
934         tyConExtName = Nothing
935     }
936
937 -- | Create a type synonym 'TyCon'
938 mkSynTyCon :: Name -> Kind -> [TyVar] -> SynTyConRhs Type -> TyConParent -> TyCon
939 mkSynTyCon name kind tyvars rhs parent
940   = SynTyCon {
941         tyConName = name,
942         tyConUnique = nameUnique name,
943         tc_kind = kind,
944         tyConArity = length tyvars,
945         tyConTyVars = tyvars,
946         synTcRhs = rhs,
947         synTcParent = parent
948     }
949
950 -- | Create a promoted data constructor 'TyCon'
951 -- Somewhat dodgily, we give it the same Name
952 -- as the data constructor itself; when we pretty-print
953 -- the TyCon we add a quote; see the Outputable TyCon instance
954 mkPromotedDataCon :: DataCon -> Name -> Unique -> Kind -> Arity -> TyCon
955 mkPromotedDataCon con name unique kind arity
956   = PromotedDataCon {
957         tyConName   = name,
958         tyConUnique = unique,
959         tyConArity  = arity,
960         tc_kind     = kind,
961         dataCon     = con
962   }
963
964 -- | Create a promoted type constructor 'TyCon'
965 -- Somewhat dodgily, we give it the same Name
966 -- as the type constructor itself
967 mkPromotedTyCon :: TyCon -> Kind -> TyCon
968 mkPromotedTyCon tc kind
969   = PromotedTyCon {
970         tyConName   = getName tc,
971         tyConUnique = getUnique tc,
972         tyConArity  = tyConArity tc,
973         tc_kind     = kind,
974         ty_con      = tc
975   }
976 \end{code}
977
978 \begin{code}
979 isFunTyCon :: TyCon -> Bool
980 isFunTyCon (FunTyCon {}) = True
981 isFunTyCon _             = False
982
983 -- | Test if the 'TyCon' is algebraic but abstract (invisible data constructors)
984 isAbstractTyCon :: TyCon -> Bool
985 isAbstractTyCon (AlgTyCon { algTcRhs = AbstractTyCon {} }) = True
986 isAbstractTyCon _ = False
987
988 -- | Make an algebraic 'TyCon' abstract. Panics if the supplied 'TyCon' is not algebraic
989 makeTyConAbstract :: TyCon -> TyCon
990 makeTyConAbstract tc@(AlgTyCon { algTcRhs = rhs })
991   = tc { algTcRhs = AbstractTyCon (isDistinctAlgRhs rhs) }
992 makeTyConAbstract tc = pprPanic "makeTyConAbstract" (ppr tc)
993
994 -- | Does this 'TyCon' represent something that cannot be defined in Haskell?
995 isPrimTyCon :: TyCon -> Bool
996 isPrimTyCon (PrimTyCon {}) = True
997 isPrimTyCon _              = False
998
999 -- | Is this 'TyCon' unlifted (i.e. cannot contain bottom)? Note that this can only
1000 -- be true for primitive and unboxed-tuple 'TyCon's
1001 isUnLiftedTyCon :: TyCon -> Bool
1002 isUnLiftedTyCon (PrimTyCon  {isUnLifted = is_unlifted}) = is_unlifted
1003 isUnLiftedTyCon (TupleTyCon {tyConTupleSort = sort})    = not (isBoxed (tupleSortBoxity sort))
1004 isUnLiftedTyCon _                                       = False
1005
1006 -- | Returns @True@ if the supplied 'TyCon' resulted from either a
1007 -- @data@ or @newtype@ declaration
1008 isAlgTyCon :: TyCon -> Bool
1009 isAlgTyCon (AlgTyCon {})   = True
1010 isAlgTyCon (TupleTyCon {}) = True
1011 isAlgTyCon _               = False
1012
1013 isDataTyCon :: TyCon -> Bool
1014 -- ^ Returns @True@ for data types that are /definitely/ represented by
1015 -- heap-allocated constructors.  These are scrutinised by Core-level
1016 -- @case@ expressions, and they get info tables allocated for them.
1017 --
1018 -- Generally, the function will be true for all @data@ types and false
1019 -- for @newtype@s, unboxed tuples and type family 'TyCon's. But it is
1020 -- not guaranteed to return @True@ in all cases that it could.
1021 --
1022 -- NB: for a data type family, only the /instance/ 'TyCon's
1023 --     get an info table.  The family declaration 'TyCon' does not
1024 isDataTyCon (AlgTyCon {algTcRhs = rhs})
1025   = case rhs of
1026         DataTyCon {}       -> True
1027         NewTyCon {}        -> False
1028         DataFamilyTyCon {} -> False
1029         AbstractTyCon {}   -> False      -- We don't know, so return False
1030 isDataTyCon (TupleTyCon {tyConTupleSort = sort}) = isBoxed (tupleSortBoxity sort)
1031 isDataTyCon _ = False
1032
1033 -- | 'isDistinctTyCon' is true of 'TyCon's that are equal only to
1034 -- themselves, even via coercions (except for unsafeCoerce).
1035 -- This excludes newtypes, type functions, type synonyms.
1036 -- It relates directly to the FC consistency story:
1037 --     If the axioms are consistent,
1038 --     and  co : S tys ~ T tys, and S,T are "distinct" TyCons,
1039 --     then S=T.
1040 -- Cf Note [Pruning dead case alternatives] in Unify
1041 isDistinctTyCon :: TyCon -> Bool
1042 isDistinctTyCon (AlgTyCon {algTcRhs = rhs}) = isDistinctAlgRhs rhs
1043 isDistinctTyCon (FunTyCon {})               = True
1044 isDistinctTyCon (TupleTyCon {})             = True
1045 isDistinctTyCon (PrimTyCon {})              = True
1046 isDistinctTyCon (PromotedDataCon {})        = True
1047 isDistinctTyCon _                           = False
1048
1049 isDistinctAlgRhs :: AlgTyConRhs -> Bool
1050 isDistinctAlgRhs (DataTyCon {})           = True
1051 isDistinctAlgRhs (DataFamilyTyCon {})     = True
1052 isDistinctAlgRhs (AbstractTyCon distinct) = distinct
1053 isDistinctAlgRhs (NewTyCon {})            = False
1054
1055 -- | Is this 'TyCon' that for a @newtype@
1056 isNewTyCon :: TyCon -> Bool
1057 isNewTyCon (AlgTyCon {algTcRhs = NewTyCon {}}) = True
1058 isNewTyCon _                                   = False
1059
1060 -- | Take a 'TyCon' apart into the 'TyVar's it scopes over, the 'Type' it expands
1061 -- into, and (possibly) a coercion from the representation type to the @newtype@.
1062 -- Returns @Nothing@ if this is not possible.
1063 unwrapNewTyCon_maybe :: TyCon -> Maybe ([TyVar], Type, CoAxiom Unbranched)
1064 unwrapNewTyCon_maybe (AlgTyCon { tyConTyVars = tvs,
1065                                  algTcRhs = NewTyCon { nt_co = co,
1066                                                        nt_rhs = rhs }})
1067                            = Just (tvs, rhs, co)
1068 unwrapNewTyCon_maybe _     = Nothing
1069
1070 isProductTyCon :: TyCon -> Bool
1071 -- | A /product/ 'TyCon' must both:
1072 --
1073 -- 1. Have /one/ constructor
1074 --
1075 -- 2. /Not/ be existential
1076 --
1077 -- However other than this there are few restrictions: they may be @data@ or @newtype@
1078 -- 'TyCon's of any boxity and may even be recursive.
1079 isProductTyCon tc@(AlgTyCon {}) = case algTcRhs tc of
1080                                     DataTyCon{ data_cons = [data_con] }
1081                                                 -> isVanillaDataCon data_con
1082                                     NewTyCon {} -> True
1083                                     _           -> False
1084 isProductTyCon (TupleTyCon {})  = True
1085 isProductTyCon _                = False
1086
1087 -- | Is this a 'TyCon' representing a type synonym (@type@)?
1088 isSynTyCon :: TyCon -> Bool
1089 isSynTyCon (SynTyCon {}) = True
1090 isSynTyCon _             = False
1091
1092 -- As for newtypes, it is in some contexts important to distinguish between
1093 -- closed synonyms and synonym families, as synonym families have no unique
1094 -- right hand side to which a synonym family application can expand.
1095 --
1096
1097 isDecomposableTyCon :: TyCon -> Bool
1098 -- True iff we can decompose (T a b c) into ((T a b) c)
1099 -- Specifically NOT true of synonyms (open and otherwise)
1100 isDecomposableTyCon (SynTyCon {}) = False
1101 isDecomposableTyCon _other        = True
1102
1103 -- | Is this an algebraic 'TyCon' declared with the GADT syntax?
1104 isGadtSyntaxTyCon :: TyCon -> Bool
1105 isGadtSyntaxTyCon (AlgTyCon { algTcGadtSyntax = res }) = res
1106 isGadtSyntaxTyCon _                                    = False
1107
1108 -- | Is this an algebraic 'TyCon' which is just an enumeration of values?
1109 isEnumerationTyCon :: TyCon -> Bool
1110 -- See Note [Enumeration types] in TyCon
1111 isEnumerationTyCon (AlgTyCon {algTcRhs = DataTyCon { is_enum = res }}) = res
1112 isEnumerationTyCon (TupleTyCon {tyConArity = arity}) = arity == 0
1113 isEnumerationTyCon _                                                   = False
1114
1115 -- | Is this a 'TyCon', synonym or otherwise, that may have further instances appear?
1116 isFamilyTyCon :: TyCon -> Bool
1117 isFamilyTyCon (SynTyCon {synTcRhs = SynFamilyTyCon {}})  = True
1118 isFamilyTyCon (AlgTyCon {algTcRhs = DataFamilyTyCon {}}) = True
1119 isFamilyTyCon _ = False
1120
1121 -- | Is this a synonym 'TyCon' that can have may have further instances appear?
1122 isSynFamilyTyCon :: TyCon -> Bool
1123 isSynFamilyTyCon (SynTyCon {synTcRhs = SynFamilyTyCon {}}) = True
1124 isSynFamilyTyCon _ = False
1125
1126 isOpenSynFamilyTyCon :: TyCon -> Bool
1127 isOpenSynFamilyTyCon (SynTyCon {synTcRhs = SynFamilyTyCon { synf_open = is_open } }) = is_open
1128 isOpenSynFamilyTyCon _ = False
1129
1130 -- | Is this a synonym 'TyCon' that can have may have further instances appear?
1131 isDataFamilyTyCon :: TyCon -> Bool
1132 isDataFamilyTyCon (AlgTyCon {algTcRhs = DataFamilyTyCon {}}) = True
1133 isDataFamilyTyCon _ = False
1134
1135 -- | Injective 'TyCon's can be decomposed, so that
1136 --     T ty1 ~ T ty2  =>  ty1 ~ ty2
1137 isInjectiveTyCon :: TyCon -> Bool
1138 isInjectiveTyCon tc = not (isSynTyCon tc)
1139         -- Ultimately we may have injective associated types
1140         -- in which case this test will become more interesting
1141         --
1142         -- It'd be unusual to call isInjectiveTyCon on a regular H98
1143         -- type synonym, because you should probably have expanded it first
1144         -- But regardless, it's not injective!
1145
1146 -- | Are we able to extract informationa 'TyVar' to class argument list
1147 -- mappping from a given 'TyCon'?
1148 isTyConAssoc :: TyCon -> Bool
1149 isTyConAssoc tc = isJust (tyConAssoc_maybe tc)
1150
1151 tyConAssoc_maybe :: TyCon -> Maybe Class
1152 tyConAssoc_maybe tc = case tyConParent tc of
1153                         AssocFamilyTyCon cls -> Just cls
1154                         _                    -> Nothing
1155
1156 -- The unit tycon didn't used to be classed as a tuple tycon
1157 -- but I thought that was silly so I've undone it
1158 -- If it can't be for some reason, it should be a AlgTyCon
1159 isTupleTyCon :: TyCon -> Bool
1160 -- ^ Does this 'TyCon' represent a tuple?
1161 --
1162 -- NB: when compiling @Data.Tuple@, the tycons won't reply @True@ to
1163 -- 'isTupleTyCon', becuase they are built as 'AlgTyCons'.  However they
1164 -- get spat into the interface file as tuple tycons, so I don't think
1165 -- it matters.
1166 isTupleTyCon (TupleTyCon {}) = True
1167 isTupleTyCon _               = False
1168
1169 -- | Is this the 'TyCon' for an unboxed tuple?
1170 isUnboxedTupleTyCon :: TyCon -> Bool
1171 isUnboxedTupleTyCon (TupleTyCon {tyConTupleSort = sort}) = not (isBoxed (tupleSortBoxity sort))
1172 isUnboxedTupleTyCon _                                    = False
1173
1174 -- | Is this the 'TyCon' for a boxed tuple?
1175 isBoxedTupleTyCon :: TyCon -> Bool
1176 isBoxedTupleTyCon (TupleTyCon {tyConTupleSort = sort}) = isBoxed (tupleSortBoxity sort)
1177 isBoxedTupleTyCon _                                    = False
1178
1179 -- | Extract the boxity of the given 'TyCon', if it is a 'TupleTyCon'.
1180 -- Panics otherwise
1181 tupleTyConBoxity :: TyCon -> Boxity
1182 tupleTyConBoxity tc = tupleSortBoxity (tyConTupleSort tc)
1183
1184 -- | Extract the 'TupleSort' of the given 'TyCon', if it is a 'TupleTyCon'.
1185 -- Panics otherwise
1186 tupleTyConSort :: TyCon -> TupleSort
1187 tupleTyConSort tc = tyConTupleSort tc
1188
1189 -- | Extract the arity of the given 'TyCon', if it is a 'TupleTyCon'.
1190 -- Panics otherwise
1191 tupleTyConArity :: TyCon -> Arity
1192 tupleTyConArity tc = tyConArity tc
1193
1194 -- | Is this a recursive 'TyCon'?
1195 isRecursiveTyCon :: TyCon -> Bool
1196 isRecursiveTyCon (AlgTyCon {algTcRec = Recursive}) = True
1197 isRecursiveTyCon _                                 = False
1198
1199 promotableTyCon_maybe :: TyCon -> Maybe TyCon
1200 promotableTyCon_maybe (AlgTyCon { tcPromoted = prom })   = prom
1201 promotableTyCon_maybe (TupleTyCon { tcPromoted = prom }) = prom
1202 promotableTyCon_maybe _                                  = Nothing
1203
1204 promoteTyCon :: TyCon -> TyCon
1205 promoteTyCon tc = case promotableTyCon_maybe tc of
1206                     Just prom_tc -> prom_tc
1207                     Nothing      -> pprPanic "promoteTyCon" (ppr tc)
1208
1209 -- | Is this the 'TyCon' of a foreign-imported type constructor?
1210 isForeignTyCon :: TyCon -> Bool
1211 isForeignTyCon (PrimTyCon {tyConExtName = Just _}) = True
1212 isForeignTyCon _                                   = False
1213
1214 -- | Is this a PromotedTyCon?
1215 isPromotedTyCon :: TyCon -> Bool
1216 isPromotedTyCon (PromotedTyCon {}) = True
1217 isPromotedTyCon _                  = False
1218
1219 -- | Retrieves the promoted TyCon if this is a PromotedTyCon;
1220 isPromotedTyCon_maybe :: TyCon -> Maybe TyCon
1221 isPromotedTyCon_maybe (PromotedTyCon { ty_con = tc }) = Just tc
1222 isPromotedTyCon_maybe _ = Nothing
1223
1224 -- | Is this a PromotedDataCon?
1225 isPromotedDataCon :: TyCon -> Bool
1226 isPromotedDataCon (PromotedDataCon {}) = True
1227 isPromotedDataCon _                    = False
1228
1229 -- | Retrieves the promoted DataCon if this is a PromotedDataCon;
1230 isPromotedDataCon_maybe :: TyCon -> Maybe DataCon
1231 isPromotedDataCon_maybe (PromotedDataCon { dataCon = dc }) = Just dc
1232 isPromotedDataCon_maybe _ = Nothing
1233
1234 -- | Identifies implicit tycons that, in particular, do not go into interface
1235 -- files (because they are implicitly reconstructed when the interface is
1236 -- read).
1237 --
1238 -- Note that:
1239 --
1240 -- * Associated families are implicit, as they are re-constructed from
1241 --   the class declaration in which they reside, and
1242 --
1243 -- * Family instances are /not/ implicit as they represent the instance body
1244 --   (similar to a @dfun@ does that for a class instance).
1245 isImplicitTyCon :: TyCon -> Bool
1246 isImplicitTyCon tycon
1247   | isTyConAssoc tycon = True
1248   | isSynTyCon tycon   = False
1249   | isAlgTyCon tycon   = isTupleTyCon tycon
1250   | otherwise          = True
1251         -- 'otherwise' catches: FunTyCon, PrimTyCon,
1252         -- PromotedDataCon, PomotedTypeTyCon
1253
1254 tyConCType_maybe :: TyCon -> Maybe CType
1255 tyConCType_maybe tc@(AlgTyCon {}) = tyConCType tc
1256 tyConCType_maybe _ = Nothing
1257 \end{code}
1258
1259
1260 -----------------------------------------------
1261 --      Expand type-constructor applications
1262 -----------------------------------------------
1263
1264 \begin{code}
1265 tcExpandTyCon_maybe, coreExpandTyCon_maybe
1266         :: TyCon
1267         -> [tyco]                 -- ^ Arguments to 'TyCon'
1268         -> Maybe ([(TyVar,tyco)],
1269                   Type,
1270                   [tyco])         -- ^ Returns a 'TyVar' substitution, the body type
1271                                   -- of the synonym (not yet substituted) and any arguments
1272                                   -- remaining from the application
1273
1274 -- ^ Used to create the view the /typechecker/ has on 'TyCon's.
1275 -- We expand (closed) synonyms only, cf. 'coreExpandTyCon_maybe'
1276 tcExpandTyCon_maybe (SynTyCon {tyConTyVars = tvs,
1277                                synTcRhs = SynonymTyCon rhs }) tys
1278    = expand tvs rhs tys
1279 tcExpandTyCon_maybe _ _ = Nothing
1280
1281 ---------------
1282
1283 -- ^ Used to create the view /Core/ has on 'TyCon's. We expand
1284 -- not only closed synonyms like 'tcExpandTyCon_maybe',
1285 -- but also non-recursive @newtype@s
1286 coreExpandTyCon_maybe tycon tys = tcExpandTyCon_maybe tycon tys
1287
1288
1289 ----------------
1290 expand  :: [TyVar] -> Type                 -- Template
1291         -> [a]                             -- Args
1292         -> Maybe ([(TyVar,a)], Type, [a])  -- Expansion
1293 expand tvs rhs tys
1294   = case n_tvs `compare` length tys of
1295         LT -> Just (tvs `zip` tys, rhs, drop n_tvs tys)
1296         EQ -> Just (tvs `zip` tys, rhs, [])
1297         GT -> Nothing
1298    where
1299      n_tvs = length tvs
1300 \end{code}
1301
1302 \begin{code}
1303 tyConKind :: TyCon -> Kind
1304 tyConKind = tc_kind
1305
1306 -- | As 'tyConDataCons_maybe', but returns the empty list of constructors if no constructors
1307 -- could be found
1308 tyConDataCons :: TyCon -> [DataCon]
1309 -- It's convenient for tyConDataCons to return the
1310 -- empty list for type synonyms etc
1311 tyConDataCons tycon = tyConDataCons_maybe tycon `orElse` []
1312
1313 -- | Determine the 'DataCon's originating from the given 'TyCon', if the 'TyCon' is the
1314 -- sort that can have any constructors (note: this does not include abstract algebraic types)
1315 tyConDataCons_maybe :: TyCon -> Maybe [DataCon]
1316 tyConDataCons_maybe (AlgTyCon {algTcRhs = DataTyCon { data_cons = cons }}) = Just cons
1317 tyConDataCons_maybe (AlgTyCon {algTcRhs = NewTyCon { data_con = con }})    = Just [con]
1318 tyConDataCons_maybe (TupleTyCon {dataCon = con})                           = Just [con]
1319 tyConDataCons_maybe _                                                      = Nothing
1320
1321 -- | Determine the number of value constructors a 'TyCon' has. Panics if the 'TyCon'
1322 -- is not algebraic or a tuple
1323 tyConFamilySize  :: TyCon -> Int
1324 tyConFamilySize (AlgTyCon   {algTcRhs = DataTyCon {data_cons = cons}}) =
1325   length cons
1326 tyConFamilySize (AlgTyCon   {algTcRhs = NewTyCon {}})        = 1
1327 tyConFamilySize (AlgTyCon   {algTcRhs = DataFamilyTyCon {}}) = 0
1328 tyConFamilySize (TupleTyCon {})                              = 1
1329 tyConFamilySize other = pprPanic "tyConFamilySize:" (ppr other)
1330
1331 -- | Extract an 'AlgTyConRhs' with information about data constructors from an algebraic or tuple
1332 -- 'TyCon'. Panics for any other sort of 'TyCon'
1333 algTyConRhs :: TyCon -> AlgTyConRhs
1334 algTyConRhs (AlgTyCon {algTcRhs = rhs}) = rhs
1335 algTyConRhs (TupleTyCon {dataCon = con, tyConArity = arity})
1336     = DataTyCon { data_cons = [con], is_enum = arity == 0 }
1337 algTyConRhs other = pprPanic "algTyConRhs" (ppr other)
1338 \end{code}
1339
1340 \begin{code}
1341 -- | Extract the bound type variables and type expansion of a type synonym 'TyCon'. Panics if the
1342 -- 'TyCon' is not a synonym
1343 newTyConRhs :: TyCon -> ([TyVar], Type)
1344 newTyConRhs (AlgTyCon {tyConTyVars = tvs, algTcRhs = NewTyCon { nt_rhs = rhs }}) = (tvs, rhs)
1345 newTyConRhs tycon = pprPanic "newTyConRhs" (ppr tycon)
1346
1347 -- | Extract the bound type variables and type expansion of an eta-contracted type synonym 'TyCon'.
1348 -- Panics if the 'TyCon' is not a synonym
1349 newTyConEtadRhs :: TyCon -> ([TyVar], Type)
1350 newTyConEtadRhs (AlgTyCon {algTcRhs = NewTyCon { nt_etad_rhs = tvs_rhs }}) = tvs_rhs
1351 newTyConEtadRhs tycon = pprPanic "newTyConEtadRhs" (ppr tycon)
1352
1353 -- | Extracts the @newtype@ coercion from such a 'TyCon', which can be used to construct something
1354 -- with the @newtype@s type from its representation type (right hand side). If the supplied 'TyCon'
1355 -- is not a @newtype@, returns @Nothing@
1356 newTyConCo_maybe :: TyCon -> Maybe (CoAxiom Unbranched)
1357 newTyConCo_maybe (AlgTyCon {algTcRhs = NewTyCon { nt_co = co }}) = Just co
1358 newTyConCo_maybe _                                               = Nothing
1359
1360 newTyConCo :: TyCon -> CoAxiom Unbranched
1361 newTyConCo tc = case newTyConCo_maybe tc of
1362                  Just co -> co
1363                  Nothing -> pprPanic "newTyConCo" (ppr tc)
1364
1365 -- | Find the primitive representation of a 'TyCon'
1366 tyConPrimRep :: TyCon -> PrimRep
1367 tyConPrimRep (PrimTyCon {primTyConRep = rep}) = rep
1368 tyConPrimRep tc = ASSERT(not (isUnboxedTupleTyCon tc)) PtrRep
1369 \end{code}
1370
1371 \begin{code}
1372 -- | Find the \"stupid theta\" of the 'TyCon'. A \"stupid theta\" is the context to the left of
1373 -- an algebraic type declaration, e.g. @Eq a@ in the declaration @data Eq a => T a ...@
1374 tyConStupidTheta :: TyCon -> [PredType]
1375 tyConStupidTheta (AlgTyCon {algTcStupidTheta = stupid}) = stupid
1376 tyConStupidTheta (TupleTyCon {})                        = []
1377 tyConStupidTheta tycon = pprPanic "tyConStupidTheta" (ppr tycon)
1378 \end{code}
1379
1380 \begin{code}
1381 -- | Extract the 'TyVar's bound by a vanilla type synonym (not familiy)
1382 -- and the corresponding (unsubstituted) right hand side.
1383 synTyConDefn_maybe :: TyCon -> Maybe ([TyVar], Type)
1384 synTyConDefn_maybe (SynTyCon {tyConTyVars = tyvars, synTcRhs = SynonymTyCon ty})
1385   = Just (tyvars, ty)
1386 synTyConDefn_maybe _ = Nothing
1387
1388 -- | Extract the information pertaining to the right hand side of a type synonym (@type@) declaration.
1389 synTyConRhs_maybe :: TyCon -> Maybe (SynTyConRhs Type)
1390 synTyConRhs_maybe (SynTyCon {synTcRhs = rhs}) = Just rhs
1391 synTyConRhs_maybe _                           = Nothing
1392 \end{code}
1393
1394 \begin{code}
1395 -- | If the given 'TyCon' has a /single/ data constructor, i.e. it is a @data@ type with one
1396 -- alternative, a tuple type or a @newtype@ then that constructor is returned. If the 'TyCon'
1397 -- has more than one constructor, or represents a primitive or function type constructor then
1398 -- @Nothing@ is returned. In any other case, the function panics
1399 tyConSingleDataCon_maybe :: TyCon -> Maybe DataCon
1400 tyConSingleDataCon_maybe (TupleTyCon {dataCon = c})                            = Just c
1401 tyConSingleDataCon_maybe (AlgTyCon {algTcRhs = DataTyCon { data_cons = [c] }}) = Just c
1402 tyConSingleDataCon_maybe (AlgTyCon {algTcRhs = NewTyCon { data_con = c }})     = Just c
1403 tyConSingleDataCon_maybe _                                                     = Nothing
1404
1405 tyConSingleAlgDataCon_maybe :: TyCon -> Maybe DataCon
1406 -- Returns (Just con) for single-constructor *algebraic* data types
1407 -- *not* newtypes
1408 tyConSingleAlgDataCon_maybe (TupleTyCon {dataCon = c})                            = Just c
1409 tyConSingleAlgDataCon_maybe (AlgTyCon {algTcRhs = DataTyCon { data_cons = [c] }}) = Just c
1410 tyConSingleAlgDataCon_maybe _                                                     = Nothing
1411 \end{code}
1412
1413 \begin{code}
1414 -- | Is this 'TyCon' that for a class instance?
1415 isClassTyCon :: TyCon -> Bool
1416 isClassTyCon (AlgTyCon {algTcParent = ClassTyCon _}) = True
1417 isClassTyCon _                                       = False
1418
1419 -- | If this 'TyCon' is that for a class instance, return the class it is for.
1420 -- Otherwise returns @Nothing@
1421 tyConClass_maybe :: TyCon -> Maybe Class
1422 tyConClass_maybe (AlgTyCon {algTcParent = ClassTyCon clas}) = Just clas
1423 tyConClass_maybe _                                          = Nothing
1424
1425 tyConTuple_maybe :: TyCon -> Maybe TupleSort
1426 tyConTuple_maybe (TupleTyCon {tyConTupleSort = sort}) = Just sort
1427 tyConTuple_maybe _                                    = Nothing
1428
1429 ----------------------------------------------------------------------------
1430 tyConParent :: TyCon -> TyConParent
1431 tyConParent (AlgTyCon {algTcParent = parent}) = parent
1432 tyConParent (SynTyCon {synTcParent = parent}) = parent
1433 tyConParent _                                 = NoParentTyCon
1434
1435 ----------------------------------------------------------------------------
1436 -- | Is this 'TyCon' that for a data family instance?
1437 isFamInstTyCon :: TyCon -> Bool
1438 isFamInstTyCon tc = case tyConParent tc of
1439                       FamInstTyCon {} -> True
1440                       _               -> False
1441
1442 tyConFamInstSig_maybe :: TyCon -> Maybe (TyCon, [Type], CoAxiom Unbranched)
1443 tyConFamInstSig_maybe tc
1444   = case tyConParent tc of
1445       FamInstTyCon ax f ts -> Just (f, ts, ax)
1446       _                    -> Nothing
1447
1448 -- | If this 'TyCon' is that of a family instance, return the family in question
1449 -- and the instance types. Otherwise, return @Nothing@
1450 tyConFamInst_maybe :: TyCon -> Maybe (TyCon, [Type])
1451 tyConFamInst_maybe tc
1452   = case tyConParent tc of
1453       FamInstTyCon _ f ts -> Just (f, ts)
1454       _                   -> Nothing
1455
1456 -- | If this 'TyCon' is that of a family instance, return a 'TyCon' which represents
1457 -- a coercion identifying the representation type with the type instance family.
1458 -- Otherwise, return @Nothing@
1459 tyConFamilyCoercion_maybe :: TyCon -> Maybe (CoAxiom Unbranched)
1460 tyConFamilyCoercion_maybe tc
1461   = case tyConParent tc of
1462       FamInstTyCon co _ _ -> Just co
1463       _                   -> Nothing
1464 \end{code}
1465
1466
1467 %************************************************************************
1468 %*                                                                      *
1469 \subsection[TyCon-instances]{Instance declarations for @TyCon@}
1470 %*                                                                      *
1471 %************************************************************************
1472
1473 @TyCon@s are compared by comparing their @Unique@s.
1474
1475 The strictness analyser needs @Ord@. It is a lexicographic order with
1476 the property @(a<=b) || (b<=a)@.
1477
1478 \begin{code}
1479 instance Eq TyCon where
1480     a == b = case (a `compare` b) of { EQ -> True;   _ -> False }
1481     a /= b = case (a `compare` b) of { EQ -> False;  _ -> True  }
1482
1483 instance Ord TyCon where
1484     a <= b = case (a `compare` b) of { LT -> True;  EQ -> True;  GT -> False }
1485     a <  b = case (a `compare` b) of { LT -> True;  EQ -> False; GT -> False }
1486     a >= b = case (a `compare` b) of { LT -> False; EQ -> True;  GT -> True  }
1487     a >  b = case (a `compare` b) of { LT -> False; EQ -> False; GT -> True  }
1488     compare a b = getUnique a `compare` getUnique b
1489
1490 instance Uniquable TyCon where
1491     getUnique tc = tyConUnique tc
1492
1493 instance Outputable TyCon where
1494   -- At the moment a promoted TyCon has the same Name as its
1495   -- corresponding TyCon, so we add the quote to distinguish it here
1496   ppr tc = pprPromotionQuote tc <> ppr (tyConName tc)
1497
1498 pprPromotionQuote :: TyCon -> SDoc
1499 pprPromotionQuote (PromotedDataCon {}) = char '\''   -- Quote promoted DataCons in types
1500 pprPromotionQuote (PromotedTyCon {})   = ifPprDebug (char '\'') 
1501 pprPromotionQuote _                    = empty       -- However, we don't quote TyCons in kinds
1502                                                      -- e.g.   type family T a :: Bool -> *
1503                                                      -- cf Trac #5952.  Except with -dppr-debug
1504
1505 instance NamedThing TyCon where
1506     getName = tyConName
1507
1508 instance Data.Data TyCon where
1509     -- don't traverse?
1510     toConstr _   = abstractConstr "TyCon"
1511     gunfold _ _  = error "gunfold"
1512     dataTypeOf _ = mkNoRepType "TyCon"
1513
1514 \end{code}