Fix #11230.
[ghc.git] / compiler / coreSyn / CoreSubst.hs
1 {-
2 (c) The University of Glasgow 2006
3 (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
4
5
6 Utility functions on @Core@ syntax
7 -}
8
9 {-# LANGUAGE CPP #-}
10 module CoreSubst (
11 -- * Main data types
12 Subst(..), -- Implementation exported for supercompiler's Renaming.hs only
13 TvSubstEnv, IdSubstEnv, InScopeSet,
14
15 -- ** Substituting into expressions and related types
16 deShadowBinds, substSpec, substRulesForImportedIds,
17 substTy, substCo, substExpr, substExprSC, substBind, substBindSC,
18 substUnfolding, substUnfoldingSC,
19 lookupIdSubst, lookupTCvSubst, substIdOcc,
20 substTickish, substDVarSet,
21
22 -- ** Operations on substitutions
23 emptySubst, mkEmptySubst, mkSubst, mkOpenSubst, substInScope, isEmptySubst,
24 extendIdSubst, extendIdSubstList, extendTCvSubst, extendTCvSubstList,
25 extendSubst, extendSubstList, extendSubstWithVar, zapSubstEnv,
26 addInScopeSet, extendInScope, extendInScopeList, extendInScopeIds,
27 isInScope, setInScope,
28 delBndr, delBndrs,
29
30 -- ** Substituting and cloning binders
31 substBndr, substBndrs, substRecBndrs,
32 cloneBndr, cloneBndrs, cloneIdBndr, cloneIdBndrs, cloneRecIdBndrs,
33
34 -- ** Simple expression optimiser
35 simpleOptPgm, simpleOptExpr, simpleOptExprWith,
36 exprIsConApp_maybe, exprIsLiteral_maybe, exprIsLambda_maybe,
37 ) where
38
39 #include "HsVersions.h"
40
41 import CoreSyn
42 import CoreFVs
43 import CoreSeq
44 import CoreUtils
45 import Literal ( Literal(MachStr) )
46 import qualified Data.ByteString as BS
47 import OccurAnal( occurAnalyseExpr, occurAnalysePgm )
48
49 import qualified Type
50 import qualified Coercion
51
52 -- We are defining local versions
53 import Type hiding ( substTy, extendTCvSubst, extendTCvSubstList
54 , isInScope, substTyVarBndr, cloneTyVarBndr )
55 import Coercion hiding ( substCo, substCoVarBndr )
56
57 import TyCon ( tyConArity )
58 import DataCon
59 import PrelNames
60 import OptCoercion ( optCoercion )
61 import PprCore ( pprCoreBindings, pprRules )
62 import Module ( Module )
63 import VarSet
64 import VarEnv
65 import Id
66 import Name ( Name )
67 import Var
68 import IdInfo
69 import UniqSupply
70 import Maybes
71 import ErrUtils
72 import DynFlags
73 import BasicTypes ( isAlwaysActive )
74 import Util
75 import Pair
76 import Outputable
77 import PprCore () -- Instances
78 import FastString
79
80 import Data.List
81
82 import TysWiredIn
83
84 {-
85 ************************************************************************
86 * *
87 \subsection{Substitutions}
88 * *
89 ************************************************************************
90 -}
91
92 -- | A substitution environment, containing 'Id', 'TyVar', and 'CoVar'
93 -- substitutions.
94 --
95 -- Some invariants apply to how you use the substitution:
96 --
97 -- 1. #in_scope_invariant# The in-scope set contains at least those 'Id's and 'TyVar's that will be in scope /after/
98 -- applying the substitution to a term. Precisely, the in-scope set must be a superset of the free vars of the
99 -- substitution range that might possibly clash with locally-bound variables in the thing being substituted in.
100 --
101 -- 2. #apply_once# You may apply the substitution only /once/
102 --
103 -- There are various ways of setting up the in-scope set such that the first of these invariants hold:
104 --
105 -- * Arrange that the in-scope set really is all the things in scope
106 --
107 -- * Arrange that it's the free vars of the range of the substitution
108 --
109 -- * Make it empty, if you know that all the free vars of the substitution are fresh, and hence can't possibly clash
110 data Subst
111 = Subst InScopeSet -- Variables in in scope (both Ids and TyVars) /after/
112 -- applying the substitution
113 IdSubstEnv -- Substitution for Ids
114 TvSubstEnv -- Substitution from TyVars to Types
115 CvSubstEnv -- Substitution from CoVars to Coercions
116
117 -- INVARIANT 1: See #in_scope_invariant#
118 -- This is what lets us deal with name capture properly
119 -- It's a hard invariant to check...
120 --
121 -- INVARIANT 2: The substitution is apply-once; see Note [Apply once] with
122 -- Types.TvSubstEnv
123 --
124 -- INVARIANT 3: See Note [Extending the Subst]
125
126 {-
127 Note [Extending the Subst]
128 ~~~~~~~~~~~~~~~~~~~~~~~~~~
129 For a core Subst, which binds Ids as well, we make a different choice for Ids
130 than we do for TyVars.
131
132 For TyVars, see Note [Extending the TCvSubst] with Type.TvSubstEnv
133
134 For Ids, we have a different invariant
135 The IdSubstEnv is extended *only* when the Unique on an Id changes
136 Otherwise, we just extend the InScopeSet
137
138 In consequence:
139
140 * If all subst envs are empty, substExpr would be a
141 no-op, so substExprSC ("short cut") does nothing.
142
143 However, substExpr still goes ahead and substitutes. Reason: we may
144 want to replace existing Ids with new ones from the in-scope set, to
145 avoid space leaks.
146
147 * In substIdBndr, we extend the IdSubstEnv only when the unique changes
148
149 * If the CvSubstEnv, TvSubstEnv and IdSubstEnv are all empty,
150 substExpr does nothing (Note that the above rule for substIdBndr
151 maintains this property. If the incoming envts are both empty, then
152 substituting the type and IdInfo can't change anything.)
153
154 * In lookupIdSubst, we *must* look up the Id in the in-scope set, because
155 it may contain non-trivial changes. Example:
156 (/\a. \x:a. ...x...) Int
157 We extend the TvSubstEnv with [a |-> Int]; but x's unique does not change
158 so we only extend the in-scope set. Then we must look up in the in-scope
159 set when we find the occurrence of x.
160
161 * The requirement to look up the Id in the in-scope set means that we
162 must NOT take no-op short cut when the IdSubst is empty.
163 We must still look up every Id in the in-scope set.
164
165 * (However, we don't need to do so for expressions found in the IdSubst
166 itself, whose range is assumed to be correct wrt the in-scope set.)
167
168 Why do we make a different choice for the IdSubstEnv than the
169 TvSubstEnv and CvSubstEnv?
170
171 * For Ids, we change the IdInfo all the time (e.g. deleting the
172 unfolding), and adding it back later, so using the TyVar convention
173 would entail extending the substitution almost all the time
174
175 * The simplifier wants to look up in the in-scope set anyway, in case it
176 can see a better unfolding from an enclosing case expression
177
178 * For TyVars, only coercion variables can possibly change, and they are
179 easy to spot
180 -}
181
182 -- | An environment for substituting for 'Id's
183 type IdSubstEnv = IdEnv CoreExpr
184
185 ----------------------------
186 isEmptySubst :: Subst -> Bool
187 isEmptySubst (Subst _ id_env tv_env cv_env)
188 = isEmptyVarEnv id_env && isEmptyVarEnv tv_env && isEmptyVarEnv cv_env
189
190 emptySubst :: Subst
191 emptySubst = Subst emptyInScopeSet emptyVarEnv emptyVarEnv emptyVarEnv
192
193 mkEmptySubst :: InScopeSet -> Subst
194 mkEmptySubst in_scope = Subst in_scope emptyVarEnv emptyVarEnv emptyVarEnv
195
196 mkSubst :: InScopeSet -> TvSubstEnv -> CvSubstEnv -> IdSubstEnv -> Subst
197 mkSubst in_scope tvs cvs ids = Subst in_scope ids tvs cvs
198
199 -- | Find the in-scope set: see "CoreSubst#in_scope_invariant"
200 substInScope :: Subst -> InScopeSet
201 substInScope (Subst in_scope _ _ _) = in_scope
202
203 -- | Remove all substitutions for 'Id's and 'Var's that might have been built up
204 -- while preserving the in-scope set
205 zapSubstEnv :: Subst -> Subst
206 zapSubstEnv (Subst in_scope _ _ _) = Subst in_scope emptyVarEnv emptyVarEnv emptyVarEnv
207
208 -- | Add a substitution for an 'Id' to the 'Subst': you must ensure that the in-scope set is
209 -- such that the "CoreSubst#in_scope_invariant" is true after extending the substitution like this
210 extendIdSubst :: Subst -> Id -> CoreExpr -> Subst
211 -- ToDo: add an ASSERT that fvs(subst-result) is already in the in-scope set
212 extendIdSubst (Subst in_scope ids tvs cvs) v r = Subst in_scope (extendVarEnv ids v r) tvs cvs
213
214 -- | Adds multiple 'Id' substitutions to the 'Subst': see also 'extendIdSubst'
215 extendIdSubstList :: Subst -> [(Id, CoreExpr)] -> Subst
216 extendIdSubstList (Subst in_scope ids tvs cvs) prs = Subst in_scope (extendVarEnvList ids prs) tvs cvs
217
218 -- | Add a substitution for a 'TyVar' to the 'Subst': the 'TyVar' *must*
219 -- be a real TyVar, and not a CoVar
220 extend_tv_subst :: Subst -> TyVar -> Type -> Subst
221 extend_tv_subst (Subst in_scope ids tvs cvs) tv ty
222 = ASSERT( isTyVar tv )
223 Subst in_scope ids (extendVarEnv tvs tv ty) cvs
224
225 -- | Add a substitution for a 'TyVar' to the 'Subst': you must ensure that the in-scope set is
226 -- such that the "CoreSubst#in_scope_invariant" is true after extending the substitution like this
227 extendTCvSubst :: Subst -> TyVar -> Type -> Subst
228 extendTCvSubst subst v r
229 | isTyVar v
230 = extend_tv_subst subst v r
231 | Just co <- isCoercionTy_maybe r
232 = extendCvSubst subst v co
233 | otherwise
234 = pprPanic "CoreSubst.extendTCvSubst" (ppr v <+> ptext (sLit "|->") <+> ppr r)
235
236 -- | Adds multiple 'TyVar' substitutions to the 'Subst': see also 'extendTCvSubst'
237 extendTCvSubstList :: Subst -> [(TyVar,Type)] -> Subst
238 extendTCvSubstList subst vrs
239 = foldl' extend subst vrs
240 where extend subst (v, r) = extendTCvSubst subst v r
241
242 -- | Add a substitution from a 'CoVar' to a 'Coercion' to the 'Subst': you must ensure that the in-scope set is
243 -- such that the "CoreSubst#in_scope_invariant" is true after extending the substitution like this
244 extendCvSubst :: Subst -> CoVar -> Coercion -> Subst
245 extendCvSubst (Subst in_scope ids tvs cvs) v r = Subst in_scope ids tvs (extendVarEnv cvs v r)
246
247 -- | Add a substitution appropriate to the thing being substituted
248 -- (whether an expression, type, or coercion). See also
249 -- 'extendIdSubst', 'extendTCvSubst'
250 extendSubst :: Subst -> Var -> CoreArg -> Subst
251 extendSubst subst var arg
252 = case arg of
253 Type ty -> ASSERT( isTyVar var ) extend_tv_subst subst var ty
254 Coercion co -> ASSERT( isCoVar var ) extendCvSubst subst var co
255 _ -> ASSERT( isId var ) extendIdSubst subst var arg
256
257 extendSubstWithVar :: Subst -> Var -> Var -> Subst
258 extendSubstWithVar subst v1 v2
259 | isTyVar v1 = ASSERT( isTyVar v2 ) extend_tv_subst subst v1 (mkTyVarTy v2)
260 | isCoVar v1 = ASSERT( isCoVar v2 ) extendCvSubst subst v1 (mkCoVarCo v2)
261 | otherwise = ASSERT( isId v2 ) extendIdSubst subst v1 (Var v2)
262
263 -- | Add a substitution as appropriate to each of the terms being
264 -- substituted (whether expressions, types, or coercions). See also
265 -- 'extendSubst'.
266 extendSubstList :: Subst -> [(Var,CoreArg)] -> Subst
267 extendSubstList subst [] = subst
268 extendSubstList subst ((var,rhs):prs) = extendSubstList (extendSubst subst var rhs) prs
269
270 -- | Find the substitution for an 'Id' in the 'Subst'
271 lookupIdSubst :: SDoc -> Subst -> Id -> CoreExpr
272 lookupIdSubst doc (Subst in_scope ids _ _) v
273 | not (isLocalId v) = Var v
274 | Just e <- lookupVarEnv ids v = e
275 | Just v' <- lookupInScope in_scope v = Var v'
276 -- Vital! See Note [Extending the Subst]
277 | otherwise = WARN( True, ptext (sLit "CoreSubst.lookupIdSubst") <+> doc <+> ppr v
278 $$ ppr in_scope)
279 Var v
280
281 -- | Find the substitution for a 'TyVar' in the 'Subst'
282 lookupTCvSubst :: Subst -> TyVar -> Type
283 lookupTCvSubst (Subst _ _ tvs cvs) v
284 | isTyVar v
285 = lookupVarEnv tvs v `orElse` Type.mkTyVarTy v
286 | otherwise
287 = mkCoercionTy $ lookupVarEnv cvs v `orElse` mkCoVarCo v
288
289 delBndr :: Subst -> Var -> Subst
290 delBndr (Subst in_scope ids tvs cvs) v
291 | isCoVar v = Subst in_scope ids tvs (delVarEnv cvs v)
292 | isTyVar v = Subst in_scope ids (delVarEnv tvs v) cvs
293 | otherwise = Subst in_scope (delVarEnv ids v) tvs cvs
294
295 delBndrs :: Subst -> [Var] -> Subst
296 delBndrs (Subst in_scope ids tvs cvs) vs
297 = Subst in_scope (delVarEnvList ids vs) (delVarEnvList tvs vs) (delVarEnvList cvs vs)
298 -- Easiest thing is just delete all from all!
299
300 -- | Simultaneously substitute for a bunch of variables
301 -- No left-right shadowing
302 -- ie the substitution for (\x \y. e) a1 a2
303 -- so neither x nor y scope over a1 a2
304 mkOpenSubst :: InScopeSet -> [(Var,CoreArg)] -> Subst
305 mkOpenSubst in_scope pairs = Subst in_scope
306 (mkVarEnv [(id,e) | (id, e) <- pairs, isId id])
307 (mkVarEnv [(tv,ty) | (tv, Type ty) <- pairs])
308 (mkVarEnv [(v,co) | (v, Coercion co) <- pairs])
309
310 ------------------------------
311 isInScope :: Var -> Subst -> Bool
312 isInScope v (Subst in_scope _ _ _) = v `elemInScopeSet` in_scope
313
314 -- | Add the 'Var' to the in-scope set, but do not remove
315 -- any existing substitutions for it
316 addInScopeSet :: Subst -> VarSet -> Subst
317 addInScopeSet (Subst in_scope ids tvs cvs) vs
318 = Subst (in_scope `extendInScopeSetSet` vs) ids tvs cvs
319
320 -- | Add the 'Var' to the in-scope set: as a side effect,
321 -- and remove any existing substitutions for it
322 extendInScope :: Subst -> Var -> Subst
323 extendInScope (Subst in_scope ids tvs cvs) v
324 = Subst (in_scope `extendInScopeSet` v)
325 (ids `delVarEnv` v) (tvs `delVarEnv` v) (cvs `delVarEnv` v)
326
327 -- | Add the 'Var's to the in-scope set: see also 'extendInScope'
328 extendInScopeList :: Subst -> [Var] -> Subst
329 extendInScopeList (Subst in_scope ids tvs cvs) vs
330 = Subst (in_scope `extendInScopeSetList` vs)
331 (ids `delVarEnvList` vs) (tvs `delVarEnvList` vs) (cvs `delVarEnvList` vs)
332
333 -- | Optimized version of 'extendInScopeList' that can be used if you are certain
334 -- all the things being added are 'Id's and hence none are 'TyVar's or 'CoVar's
335 extendInScopeIds :: Subst -> [Id] -> Subst
336 extendInScopeIds (Subst in_scope ids tvs cvs) vs
337 = Subst (in_scope `extendInScopeSetList` vs)
338 (ids `delVarEnvList` vs) tvs cvs
339
340 setInScope :: Subst -> InScopeSet -> Subst
341 setInScope (Subst _ ids tvs cvs) in_scope = Subst in_scope ids tvs cvs
342
343 -- Pretty printing, for debugging only
344
345 instance Outputable Subst where
346 ppr (Subst in_scope ids tvs cvs)
347 = ptext (sLit "<InScope =") <+> braces (fsep (map ppr (varEnvElts (getInScopeVars in_scope))))
348 $$ ptext (sLit " IdSubst =") <+> ppr ids
349 $$ ptext (sLit " TvSubst =") <+> ppr tvs
350 $$ ptext (sLit " CvSubst =") <+> ppr cvs
351 <> char '>'
352
353 {-
354 ************************************************************************
355 * *
356 Substituting expressions
357 * *
358 ************************************************************************
359 -}
360
361 -- | Apply a substitution to an entire 'CoreExpr'. Remember, you may only
362 -- apply the substitution /once/: see "CoreSubst#apply_once"
363 --
364 -- Do *not* attempt to short-cut in the case of an empty substitution!
365 -- See Note [Extending the Subst]
366 substExprSC :: SDoc -> Subst -> CoreExpr -> CoreExpr
367 substExprSC _doc subst orig_expr
368 | isEmptySubst subst = orig_expr
369 | otherwise = -- pprTrace "enter subst-expr" (doc $$ ppr orig_expr) $
370 subst_expr subst orig_expr
371
372 substExpr :: SDoc -> Subst -> CoreExpr -> CoreExpr
373 substExpr _doc subst orig_expr = subst_expr subst orig_expr
374
375 subst_expr :: Subst -> CoreExpr -> CoreExpr
376 subst_expr subst expr
377 = go expr
378 where
379 go (Var v) = lookupIdSubst (text "subst_expr") subst v
380 go (Type ty) = Type (substTy subst ty)
381 go (Coercion co) = Coercion (substCo subst co)
382 go (Lit lit) = Lit lit
383 go (App fun arg) = App (go fun) (go arg)
384 go (Tick tickish e) = mkTick (substTickish subst tickish) (go e)
385 go (Cast e co) = Cast (go e) (substCo subst co)
386 -- Do not optimise even identity coercions
387 -- Reason: substitution applies to the LHS of RULES, and
388 -- if you "optimise" an identity coercion, you may
389 -- lose a binder. We optimise the LHS of rules at
390 -- construction time
391
392 go (Lam bndr body) = Lam bndr' (subst_expr subst' body)
393 where
394 (subst', bndr') = substBndr subst bndr
395
396 go (Let bind body) = Let bind' (subst_expr subst' body)
397 where
398 (subst', bind') = substBind subst bind
399
400 go (Case scrut bndr ty alts) = Case (go scrut) bndr' (substTy subst ty) (map (go_alt subst') alts)
401 where
402 (subst', bndr') = substBndr subst bndr
403
404 go_alt subst (con, bndrs, rhs) = (con, bndrs', subst_expr subst' rhs)
405 where
406 (subst', bndrs') = substBndrs subst bndrs
407
408 -- | Apply a substitution to an entire 'CoreBind', additionally returning an updated 'Subst'
409 -- that should be used by subsequent substitutions.
410 substBind, substBindSC :: Subst -> CoreBind -> (Subst, CoreBind)
411
412 substBindSC subst bind -- Short-cut if the substitution is empty
413 | not (isEmptySubst subst)
414 = substBind subst bind
415 | otherwise
416 = case bind of
417 NonRec bndr rhs -> (subst', NonRec bndr' rhs)
418 where
419 (subst', bndr') = substBndr subst bndr
420 Rec pairs -> (subst', Rec (bndrs' `zip` rhss'))
421 where
422 (bndrs, rhss) = unzip pairs
423 (subst', bndrs') = substRecBndrs subst bndrs
424 rhss' | isEmptySubst subst' = rhss
425 | otherwise = map (subst_expr subst') rhss
426
427 substBind subst (NonRec bndr rhs) = (subst', NonRec bndr' (subst_expr subst rhs))
428 where
429 (subst', bndr') = substBndr subst bndr
430
431 substBind subst (Rec pairs) = (subst', Rec (bndrs' `zip` rhss'))
432 where
433 (bndrs, rhss) = unzip pairs
434 (subst', bndrs') = substRecBndrs subst bndrs
435 rhss' = map (subst_expr subst') rhss
436
437 -- | De-shadowing the program is sometimes a useful pre-pass. It can be done simply
438 -- by running over the bindings with an empty substitution, because substitution
439 -- returns a result that has no-shadowing guaranteed.
440 --
441 -- (Actually, within a single /type/ there might still be shadowing, because
442 -- 'substTy' is a no-op for the empty substitution, but that's probably OK.)
443 --
444 -- [Aug 09] This function is not used in GHC at the moment, but seems so
445 -- short and simple that I'm going to leave it here
446 deShadowBinds :: CoreProgram -> CoreProgram
447 deShadowBinds binds = snd (mapAccumL substBind emptySubst binds)
448
449 {-
450 ************************************************************************
451 * *
452 Substituting binders
453 * *
454 ************************************************************************
455
456 Remember that substBndr and friends are used when doing expression
457 substitution only. Their only business is substitution, so they
458 preserve all IdInfo (suitably substituted). For example, we *want* to
459 preserve occ info in rules.
460 -}
461
462 -- | Substitutes a 'Var' for another one according to the 'Subst' given, returning
463 -- the result and an updated 'Subst' that should be used by subsequent substitutions.
464 -- 'IdInfo' is preserved by this process, although it is substituted into appropriately.
465 substBndr :: Subst -> Var -> (Subst, Var)
466 substBndr subst bndr
467 | isTyVar bndr = substTyVarBndr subst bndr
468 | isCoVar bndr = substCoVarBndr subst bndr
469 | otherwise = substIdBndr (text "var-bndr") subst subst bndr
470
471 -- | Applies 'substBndr' to a number of 'Var's, accumulating a new 'Subst' left-to-right
472 substBndrs :: Subst -> [Var] -> (Subst, [Var])
473 substBndrs subst bndrs = mapAccumL substBndr subst bndrs
474
475 -- | Substitute in a mutually recursive group of 'Id's
476 substRecBndrs :: Subst -> [Id] -> (Subst, [Id])
477 substRecBndrs subst bndrs
478 = (new_subst, new_bndrs)
479 where -- Here's the reason we need to pass rec_subst to subst_id
480 (new_subst, new_bndrs) = mapAccumL (substIdBndr (text "rec-bndr") new_subst) subst bndrs
481
482 substIdBndr :: SDoc
483 -> Subst -- ^ Substitution to use for the IdInfo
484 -> Subst -> Id -- ^ Substitution and Id to transform
485 -> (Subst, Id) -- ^ Transformed pair
486 -- NB: unfolding may be zapped
487
488 substIdBndr _doc rec_subst subst@(Subst in_scope env tvs cvs) old_id
489 = -- pprTrace "substIdBndr" (doc $$ ppr old_id $$ ppr in_scope) $
490 (Subst (in_scope `extendInScopeSet` new_id) new_env tvs cvs, new_id)
491 where
492 id1 = uniqAway in_scope old_id -- id1 is cloned if necessary
493 id2 | no_type_change = id1
494 | otherwise = setIdType id1 (substTy subst old_ty)
495
496 old_ty = idType old_id
497 no_type_change = (isEmptyVarEnv tvs && isEmptyVarEnv cvs) ||
498 isEmptyVarSet (tyCoVarsOfType old_ty)
499
500 -- new_id has the right IdInfo
501 -- The lazy-set is because we're in a loop here, with
502 -- rec_subst, when dealing with a mutually-recursive group
503 new_id = maybeModifyIdInfo mb_new_info id2
504 mb_new_info = substIdInfo rec_subst id2 (idInfo id2)
505 -- NB: unfolding info may be zapped
506
507 -- Extend the substitution if the unique has changed
508 -- See the notes with substTyVarBndr for the delVarEnv
509 new_env | no_change = delVarEnv env old_id
510 | otherwise = extendVarEnv env old_id (Var new_id)
511
512 no_change = id1 == old_id
513 -- See Note [Extending the Subst]
514 -- it's /not/ necessary to check mb_new_info and no_type_change
515
516 {-
517 Now a variant that unconditionally allocates a new unique.
518 It also unconditionally zaps the OccInfo.
519 -}
520
521 -- | Very similar to 'substBndr', but it always allocates a new 'Unique' for
522 -- each variable in its output. It substitutes the IdInfo though.
523 cloneIdBndr :: Subst -> UniqSupply -> Id -> (Subst, Id)
524 cloneIdBndr subst us old_id
525 = clone_id subst subst (old_id, uniqFromSupply us)
526
527 -- | Applies 'cloneIdBndr' to a number of 'Id's, accumulating a final
528 -- substitution from left to right
529 cloneIdBndrs :: Subst -> UniqSupply -> [Id] -> (Subst, [Id])
530 cloneIdBndrs subst us ids
531 = mapAccumL (clone_id subst) subst (ids `zip` uniqsFromSupply us)
532
533 cloneBndrs :: Subst -> UniqSupply -> [Var] -> (Subst, [Var])
534 -- Works for all kinds of variables (typically case binders)
535 -- not just Ids
536 cloneBndrs subst us vs
537 = mapAccumL (\subst (v, u) -> cloneBndr subst u v) subst (vs `zip` uniqsFromSupply us)
538
539 cloneBndr :: Subst -> Unique -> Var -> (Subst, Var)
540 cloneBndr subst uniq v
541 | isTyVar v = cloneTyVarBndr subst v uniq
542 | otherwise = clone_id subst subst (v,uniq) -- Works for coercion variables too
543
544 -- | Clone a mutually recursive group of 'Id's
545 cloneRecIdBndrs :: Subst -> UniqSupply -> [Id] -> (Subst, [Id])
546 cloneRecIdBndrs subst us ids
547 = (subst', ids')
548 where
549 (subst', ids') = mapAccumL (clone_id subst') subst
550 (ids `zip` uniqsFromSupply us)
551
552 -- Just like substIdBndr, except that it always makes a new unique
553 -- It is given the unique to use
554 clone_id :: Subst -- Substitution for the IdInfo
555 -> Subst -> (Id, Unique) -- Substitution and Id to transform
556 -> (Subst, Id) -- Transformed pair
557
558 clone_id rec_subst subst@(Subst in_scope idvs tvs cvs) (old_id, uniq)
559 = (Subst (in_scope `extendInScopeSet` new_id) new_idvs tvs new_cvs, new_id)
560 where
561 id1 = setVarUnique old_id uniq
562 id2 = substIdType subst id1
563 new_id = maybeModifyIdInfo (substIdInfo rec_subst id2 (idInfo old_id)) id2
564 (new_idvs, new_cvs) | isCoVar old_id = (idvs, extendVarEnv cvs old_id (mkCoVarCo new_id))
565 | otherwise = (extendVarEnv idvs old_id (Var new_id), cvs)
566
567 {-
568 ************************************************************************
569 * *
570 Types and Coercions
571 * *
572 ************************************************************************
573
574 For types and coercions we just call the corresponding functions in
575 Type and Coercion, but we have to repackage the substitution, from a
576 Subst to a TCvSubst.
577 -}
578
579 substTyVarBndr :: Subst -> TyVar -> (Subst, TyVar)
580 substTyVarBndr (Subst in_scope id_env tv_env cv_env) tv
581 = case Type.substTyVarBndr (TCvSubst in_scope tv_env cv_env) tv of
582 (TCvSubst in_scope' tv_env' cv_env', tv')
583 -> (Subst in_scope' id_env tv_env' cv_env', tv')
584
585 cloneTyVarBndr :: Subst -> TyVar -> Unique -> (Subst, TyVar)
586 cloneTyVarBndr (Subst in_scope id_env tv_env cv_env) tv uniq
587 = case Type.cloneTyVarBndr (TCvSubst in_scope tv_env cv_env) tv uniq of
588 (TCvSubst in_scope' tv_env' cv_env', tv')
589 -> (Subst in_scope' id_env tv_env' cv_env', tv')
590
591 substCoVarBndr :: Subst -> TyVar -> (Subst, TyVar)
592 substCoVarBndr (Subst in_scope id_env tv_env cv_env) cv
593 = case Coercion.substCoVarBndr (TCvSubst in_scope tv_env cv_env) cv of
594 (TCvSubst in_scope' tv_env' cv_env', cv')
595 -> (Subst in_scope' id_env tv_env' cv_env', cv')
596
597 -- | See 'Type.substTy'
598 substTy :: Subst -> Type -> Type
599 substTy subst ty = Type.substTy (getTCvSubst subst) ty
600
601 getTCvSubst :: Subst -> TCvSubst
602 getTCvSubst (Subst in_scope _ tenv cenv) = TCvSubst in_scope tenv cenv
603
604 -- | See 'Coercion.substCo'
605 substCo :: Subst -> Coercion -> Coercion
606 substCo subst co = Coercion.substCo (getTCvSubst subst) co
607
608 {-
609 ************************************************************************
610 * *
611 \section{IdInfo substitution}
612 * *
613 ************************************************************************
614 -}
615
616 substIdType :: Subst -> Id -> Id
617 substIdType subst@(Subst _ _ tv_env cv_env) id
618 | (isEmptyVarEnv tv_env && isEmptyVarEnv cv_env) || isEmptyVarSet (tyCoVarsOfType old_ty) = id
619 | otherwise = setIdType id (substTy subst old_ty)
620 -- The tyCoVarsOfType is cheaper than it looks
621 -- because we cache the free tyvars of the type
622 -- in a Note in the id's type itself
623 where
624 old_ty = idType id
625
626 ------------------
627 -- | Substitute into some 'IdInfo' with regard to the supplied new 'Id'.
628 substIdInfo :: Subst -> Id -> IdInfo -> Maybe IdInfo
629 substIdInfo subst new_id info
630 | nothing_to_do = Nothing
631 | otherwise = Just (info `setRuleInfo` substSpec subst new_id old_rules
632 `setUnfoldingInfo` substUnfolding subst old_unf)
633 where
634 old_rules = ruleInfo info
635 old_unf = unfoldingInfo info
636 nothing_to_do = isEmptyRuleInfo old_rules && isClosedUnfolding old_unf
637
638
639 ------------------
640 -- | Substitutes for the 'Id's within an unfolding
641 substUnfolding, substUnfoldingSC :: Subst -> Unfolding -> Unfolding
642 -- Seq'ing on the returned Unfolding is enough to cause
643 -- all the substitutions to happen completely
644
645 substUnfoldingSC subst unf -- Short-cut version
646 | isEmptySubst subst = unf
647 | otherwise = substUnfolding subst unf
648
649 substUnfolding subst df@(DFunUnfolding { df_bndrs = bndrs, df_args = args })
650 = df { df_bndrs = bndrs', df_args = args' }
651 where
652 (subst',bndrs') = substBndrs subst bndrs
653 args' = map (substExpr (text "subst-unf:dfun") subst') args
654
655 substUnfolding subst unf@(CoreUnfolding { uf_tmpl = tmpl, uf_src = src })
656 -- Retain an InlineRule!
657 | not (isStableSource src) -- Zap an unstable unfolding, to save substitution work
658 = NoUnfolding
659 | otherwise -- But keep a stable one!
660 = seqExpr new_tmpl `seq`
661 unf { uf_tmpl = new_tmpl }
662 where
663 new_tmpl = substExpr (text "subst-unf") subst tmpl
664
665 substUnfolding _ unf = unf -- NoUnfolding, OtherCon
666
667 ------------------
668 substIdOcc :: Subst -> Id -> Id
669 -- These Ids should not be substituted to non-Ids
670 substIdOcc subst v = case lookupIdSubst (text "substIdOcc") subst v of
671 Var v' -> v'
672 other -> pprPanic "substIdOcc" (vcat [ppr v <+> ppr other, ppr subst])
673
674 ------------------
675 -- | Substitutes for the 'Id's within the 'WorkerInfo' given the new function 'Id'
676 substSpec :: Subst -> Id -> RuleInfo -> RuleInfo
677 substSpec subst new_id (RuleInfo rules rhs_fvs)
678 = seqRuleInfo new_spec `seq` new_spec
679 where
680 subst_ru_fn = const (idName new_id)
681 new_spec = RuleInfo (map (substRule subst subst_ru_fn) rules)
682 (substDVarSet subst rhs_fvs)
683
684 ------------------
685 substRulesForImportedIds :: Subst -> [CoreRule] -> [CoreRule]
686 substRulesForImportedIds subst rules
687 = map (substRule subst not_needed) rules
688 where
689 not_needed name = pprPanic "substRulesForImportedIds" (ppr name)
690
691 ------------------
692 substRule :: Subst -> (Name -> Name) -> CoreRule -> CoreRule
693
694 -- The subst_ru_fn argument is applied to substitute the ru_fn field
695 -- of the rule:
696 -- - Rules for *imported* Ids never change ru_fn
697 -- - Rules for *local* Ids are in the IdInfo for that Id,
698 -- and the ru_fn field is simply replaced by the new name
699 -- of the Id
700 substRule _ _ rule@(BuiltinRule {}) = rule
701 substRule subst subst_ru_fn rule@(Rule { ru_bndrs = bndrs, ru_args = args
702 , ru_fn = fn_name, ru_rhs = rhs
703 , ru_local = is_local })
704 = rule { ru_bndrs = bndrs'
705 , ru_fn = if is_local
706 then subst_ru_fn fn_name
707 else fn_name
708 , ru_args = map (substExpr doc subst') args
709 , ru_rhs = substExpr (text "foo") subst' rhs }
710 -- Do NOT optimise the RHS (previously we did simplOptExpr here)
711 -- See Note [Substitute lazily]
712 where
713 doc = ptext (sLit "subst-rule") <+> ppr fn_name
714 (subst', bndrs') = substBndrs subst bndrs
715
716 ------------------
717 substVects :: Subst -> [CoreVect] -> [CoreVect]
718 substVects subst = map (substVect subst)
719
720 ------------------
721 substVect :: Subst -> CoreVect -> CoreVect
722 substVect subst (Vect v rhs) = Vect v (simpleOptExprWith subst rhs)
723 substVect _subst vd@(NoVect _) = vd
724 substVect _subst vd@(VectType _ _ _) = vd
725 substVect _subst vd@(VectClass _) = vd
726 substVect _subst vd@(VectInst _) = vd
727
728 ------------------
729 substDVarSet :: Subst -> DVarSet -> DVarSet
730 substDVarSet subst fvs
731 = mkDVarSet $ fst $ foldr (subst_fv subst) ([], emptyVarSet) $ dVarSetElems fvs
732 where
733 subst_fv subst fv acc
734 | isId fv = expr_fvs (lookupIdSubst (text "substDVarSet") subst fv) isLocalVar emptyVarSet $! acc
735 | otherwise = tyCoVarsOfTypeAcc (lookupTCvSubst subst fv) (const True) emptyVarSet $! acc
736
737 ------------------
738 substTickish :: Subst -> Tickish Id -> Tickish Id
739 substTickish subst (Breakpoint n ids) = Breakpoint n (map do_one ids)
740 where do_one = getIdFromTrivialExpr . lookupIdSubst (text "subst_tickish") subst
741 substTickish _subst other = other
742
743 {- Note [Substitute lazily]
744 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
745 The functions that substitute over IdInfo must be pretty lazy, becuause
746 they are knot-tied by substRecBndrs.
747
748 One case in point was Trac #10627 in which a rule for a function 'f'
749 referred to 'f' (at a differnet type) on the RHS. But instead of just
750 substituting in the rhs of the rule, we were calling simpleOptExpr, which
751 looked at the idInfo for 'f'; result <<loop>>.
752
753 In any case we don't need to optimise the RHS of rules, or unfoldings,
754 because the simplifier will do that.
755
756
757 Note [substTickish]
758 ~~~~~~~~~~~~~~~~~~~~~~
759 A Breakpoint contains a list of Ids. What happens if we ever want to
760 substitute an expression for one of these Ids?
761
762 First, we ensure that we only ever substitute trivial expressions for
763 these Ids, by marking them as NoOccInfo in the occurrence analyser.
764 Then, when substituting for the Id, we unwrap any type applications
765 and abstractions to get back to an Id, with getIdFromTrivialExpr.
766
767 Second, we have to ensure that we never try to substitute a literal
768 for an Id in a breakpoint. We ensure this by never storing an Id with
769 an unlifted type in a Breakpoint - see Coverage.mkTickish.
770 Breakpoints can't handle free variables with unlifted types anyway.
771 -}
772
773 {-
774 Note [Worker inlining]
775 ~~~~~~~~~~~~~~~~~~~~~~
776 A worker can get sustituted away entirely.
777 - it might be trivial
778 - it might simply be very small
779 We do not treat an InlWrapper as an 'occurrence' in the occurrence
780 analyser, so it's possible that the worker is not even in scope any more.
781
782 In all all these cases we simply drop the special case, returning to
783 InlVanilla. The WARN is just so I can see if it happens a lot.
784
785
786 ************************************************************************
787 * *
788 The Very Simple Optimiser
789 * *
790 ************************************************************************
791
792 Note [Getting the map/coerce RULE to work]
793 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
794 We wish to allow the "map/coerce" RULE to fire:
795
796 {-# RULES "map/coerce" map coerce = coerce #-}
797
798 The naive core produced for this is
799
800 forall a b (dict :: Coercible * a b).
801 map @a @b (coerce @a @b @dict) = coerce @[a] @[b] @dict'
802
803 where dict' :: Coercible [a] [b]
804 dict' = ...
805
806 This matches literal uses of `map coerce` in code, but that's not what we
807 want. We want it to match, say, `map MkAge` (where newtype Age = MkAge Int)
808 too. Some of this is addressed by compulsorily unfolding coerce on the LHS,
809 yielding
810
811 forall a b (dict :: Coercible * a b).
812 map @a @b (\(x :: a) -> case dict of
813 MkCoercible (co :: a ~R# b) -> x |> co) = ...
814
815 Getting better. But this isn't exactly what gets produced. This is because
816 Coercible essentially has ~R# as a superclass, and superclasses get eagerly
817 extracted during solving. So we get this:
818
819 forall a b (dict :: Coercible * a b).
820 case Coercible_SCSel @* @a @b dict of
821 _ [Dead] -> map @a @b (\(x :: a) -> case dict of
822 MkCoercible (co :: a ~R# b) -> x |> co) = ...
823
824 Unfortunately, this still abstracts over a Coercible dictionary. We really
825 want it to abstract over the ~R# evidence. So, we have Desugar.unfold_coerce,
826 which transforms the above to (see also Note [Desugaring coerce as cast] in
827 Desugar)
828
829 forall a b (co :: a ~R# b).
830 let dict = MkCoercible @* @a @b co in
831 case Coercible_SCSel @* @a @b dict of
832 _ [Dead] -> map @a @b (\(x :: a) -> case dict of
833 MkCoercible (co :: a ~R# b) -> x |> co) = let dict = ... in ...
834
835 Now, we need simpleOptExpr to fix this up. It does so by taking three
836 separate actions:
837 1. Inline certain non-recursive bindings. The choice whether to inline
838 is made in maybe_substitute. Note the rather specific check for
839 MkCoercible in there.
840
841 2. Stripping case expressions like the Coercible_SCSel one.
842 See the `Case` case of simple_opt_expr's `go` function.
843
844 3. Look for case expressions that unpack something that was
845 just packed and inline them. This is also done in simple_opt_expr's
846 `go` function.
847
848 This is all a fair amount of special-purpose hackery, but it's for
849 a good cause. And it won't hurt other RULES and such that it comes across.
850
851 -}
852
853 simpleOptExpr :: CoreExpr -> CoreExpr
854 -- Do simple optimisation on an expression
855 -- The optimisation is very straightforward: just
856 -- inline non-recursive bindings that are used only once,
857 -- or where the RHS is trivial
858 --
859 -- We also inline bindings that bind a Eq# box: see
860 -- See Note [Getting the map/coerce RULE to work].
861 --
862 -- The result is NOT guaranteed occurrence-analysed, because
863 -- in (let x = y in ....) we substitute for x; so y's occ-info
864 -- may change radically
865
866 simpleOptExpr expr
867 = -- pprTrace "simpleOptExpr" (ppr init_subst $$ ppr expr)
868 simpleOptExprWith init_subst expr
869 where
870 init_subst = mkEmptySubst (mkInScopeSet (exprFreeVars expr))
871 -- It's potentially important to make a proper in-scope set
872 -- Consider let x = ..y.. in \y. ...x...
873 -- Then we should remember to clone y before substituting
874 -- for x. It's very unlikely to occur, because we probably
875 -- won't *be* substituting for x if it occurs inside a
876 -- lambda.
877 --
878 -- It's a bit painful to call exprFreeVars, because it makes
879 -- three passes instead of two (occ-anal, and go)
880
881 simpleOptExprWith :: Subst -> InExpr -> OutExpr
882 simpleOptExprWith subst expr = simple_opt_expr subst (occurAnalyseExpr expr)
883
884 ----------------------
885 simpleOptPgm :: DynFlags -> Module
886 -> CoreProgram -> [CoreRule] -> [CoreVect]
887 -> IO (CoreProgram, [CoreRule], [CoreVect])
888 simpleOptPgm dflags this_mod binds rules vects
889 = do { dumpIfSet_dyn dflags Opt_D_dump_occur_anal "Occurrence analysis"
890 (pprCoreBindings occ_anald_binds $$ pprRules rules );
891
892 ; return (reverse binds', substRulesForImportedIds subst' rules, substVects subst' vects) }
893 where
894 occ_anald_binds = occurAnalysePgm this_mod (\_ -> False) {- No rules active -}
895 rules vects emptyVarEnv binds
896 (subst', binds') = foldl do_one (emptySubst, []) occ_anald_binds
897
898 do_one (subst, binds') bind
899 = case simple_opt_bind subst bind of
900 (subst', Nothing) -> (subst', binds')
901 (subst', Just bind') -> (subst', bind':binds')
902
903 ----------------------
904 type InVar = Var
905 type OutVar = Var
906 type InId = Id
907 type OutId = Id
908 type InExpr = CoreExpr
909 type OutExpr = CoreExpr
910
911 -- In these functions the substitution maps InVar -> OutExpr
912
913 ----------------------
914 simple_opt_expr :: Subst -> InExpr -> OutExpr
915 simple_opt_expr subst expr
916 = go expr
917 where
918 in_scope_env = (substInScope subst, simpleUnfoldingFun)
919
920 go (Var v) = lookupIdSubst (text "simpleOptExpr") subst v
921 go (App e1 e2) = simple_app subst e1 [go e2]
922 go (Type ty) = Type (substTy subst ty)
923 go (Coercion co) = Coercion (optCoercion (getTCvSubst subst) co)
924 go (Lit lit) = Lit lit
925 go (Tick tickish e) = mkTick (substTickish subst tickish) (go e)
926 go (Cast e co) | isReflCo co' = go e
927 | otherwise = Cast (go e) co'
928 where
929 co' = optCoercion (getTCvSubst subst) co
930
931 go (Let bind body) = case simple_opt_bind subst bind of
932 (subst', Nothing) -> simple_opt_expr subst' body
933 (subst', Just bind) -> Let bind (simple_opt_expr subst' body)
934
935 go lam@(Lam {}) = go_lam [] subst lam
936 go (Case e b ty as)
937 -- See Note [Getting the map/coerce RULE to work]
938 | isDeadBinder b
939 , Just (con, _tys, es) <- exprIsConApp_maybe in_scope_env e'
940 , Just (altcon, bs, rhs) <- findAlt (DataAlt con) as
941 = case altcon of
942 DEFAULT -> go rhs
943 _ -> mkLets (catMaybes mb_binds) $ simple_opt_expr subst' rhs
944 where (subst', mb_binds) = mapAccumL simple_opt_out_bind subst
945 (zipEqual "simpleOptExpr" bs es)
946
947 -- Note [Getting the map/coerce RULE to work]
948 | isDeadBinder b
949 , [(DEFAULT, _, rhs)] <- as
950 , isCoercionType (varType b)
951 , (Var fun, _args) <- collectArgs e
952 , fun `hasKey` coercibleSCSelIdKey
953 -- without this last check, we get #11230
954 = go rhs
955
956 | otherwise
957 = Case e' b' (substTy subst ty)
958 (map (go_alt subst') as)
959 where
960 e' = go e
961 (subst', b') = subst_opt_bndr subst b
962
963 ----------------------
964 go_alt subst (con, bndrs, rhs)
965 = (con, bndrs', simple_opt_expr subst' rhs)
966 where
967 (subst', bndrs') = subst_opt_bndrs subst bndrs
968
969 ----------------------
970 -- go_lam tries eta reduction
971 go_lam bs' subst (Lam b e)
972 = go_lam (b':bs') subst' e
973 where
974 (subst', b') = subst_opt_bndr subst b
975 go_lam bs' subst e
976 | Just etad_e <- tryEtaReduce bs e' = etad_e
977 | otherwise = mkLams bs e'
978 where
979 bs = reverse bs'
980 e' = simple_opt_expr subst e
981
982 ----------------------
983 -- simple_app collects arguments for beta reduction
984 simple_app :: Subst -> InExpr -> [OutExpr] -> CoreExpr
985 simple_app subst (App e1 e2) as
986 = simple_app subst e1 (simple_opt_expr subst e2 : as)
987 simple_app subst (Lam b e) (a:as)
988 = case maybe_substitute subst b a of
989 Just ext_subst -> simple_app ext_subst e as
990 Nothing -> Let (NonRec b2 a) (simple_app subst' e as)
991 where
992 (subst', b') = subst_opt_bndr subst b
993 b2 = add_info subst' b b'
994 simple_app subst (Var v) as
995 | isCompulsoryUnfolding (idUnfolding v)
996 , isAlwaysActive (idInlineActivation v)
997 -- See Note [Unfold compulsory unfoldings in LHSs]
998 = simple_app subst (unfoldingTemplate (idUnfolding v)) as
999 simple_app subst (Tick t e) as
1000 -- Okay to do "(Tick t e) x ==> Tick t (e x)"?
1001 | t `tickishScopesLike` SoftScope
1002 = mkTick t $ simple_app subst e as
1003 simple_app subst e as
1004 = foldl App (simple_opt_expr subst e) as
1005
1006 ----------------------
1007 simple_opt_bind,simple_opt_bind' :: Subst -> CoreBind -> (Subst, Maybe CoreBind)
1008 simple_opt_bind s b -- Can add trace stuff here
1009 = simple_opt_bind' s b
1010
1011 simple_opt_bind' subst (Rec prs)
1012 = (subst'', res_bind)
1013 where
1014 res_bind = Just (Rec (reverse rev_prs'))
1015 (subst', bndrs') = subst_opt_bndrs subst (map fst prs)
1016 (subst'', rev_prs') = foldl do_pr (subst', []) (prs `zip` bndrs')
1017 do_pr (subst, prs) ((b,r), b')
1018 = case maybe_substitute subst b r2 of
1019 Just subst' -> (subst', prs)
1020 Nothing -> (subst, (b2,r2):prs)
1021 where
1022 b2 = add_info subst b b'
1023 r2 = simple_opt_expr subst r
1024
1025 simple_opt_bind' subst (NonRec b r)
1026 = simple_opt_out_bind subst (b, simple_opt_expr subst r)
1027
1028 ----------------------
1029 simple_opt_out_bind :: Subst -> (InVar, OutExpr) -> (Subst, Maybe CoreBind)
1030 simple_opt_out_bind subst (b, r')
1031 | Just ext_subst <- maybe_substitute subst b r'
1032 = (ext_subst, Nothing)
1033 | otherwise
1034 = (subst', Just (NonRec b2 r'))
1035 where
1036 (subst', b') = subst_opt_bndr subst b
1037 b2 = add_info subst' b b'
1038
1039 ----------------------
1040 maybe_substitute :: Subst -> InVar -> OutExpr -> Maybe Subst
1041 -- (maybe_substitute subst in_var out_rhs)
1042 -- either extends subst with (in_var -> out_rhs)
1043 -- or returns Nothing
1044 maybe_substitute subst b r
1045 | Type ty <- r -- let a::* = TYPE ty in <body>
1046 = ASSERT( isTyVar b )
1047 Just (extendTCvSubst subst b ty)
1048
1049 | Coercion co <- r
1050 = ASSERT( isCoVar b )
1051 Just (extendCvSubst subst b co)
1052
1053 | isId b -- let x = e in <body>
1054 , not (isCoVar b) -- See Note [Do not inline CoVars unconditionally]
1055 -- in SimplUtils
1056 , safe_to_inline (idOccInfo b)
1057 , isAlwaysActive (idInlineActivation b) -- Note [Inline prag in simplOpt]
1058 , not (isStableUnfolding (idUnfolding b))
1059 , not (isExportedId b)
1060 , not (isUnLiftedType (idType b)) || exprOkForSpeculation r
1061 = Just (extendIdSubst subst b r)
1062
1063 | otherwise
1064 = Nothing
1065 where
1066 -- Unconditionally safe to inline
1067 safe_to_inline :: OccInfo -> Bool
1068 safe_to_inline (IAmALoopBreaker {}) = False
1069 safe_to_inline IAmDead = True
1070 safe_to_inline (OneOcc in_lam one_br _) = (not in_lam && one_br) || trivial
1071 safe_to_inline NoOccInfo = trivial
1072
1073 trivial | exprIsTrivial r = True
1074 | (Var fun, args) <- collectArgs r
1075 , Just dc <- isDataConWorkId_maybe fun
1076 , dc `hasKey` heqDataConKey || dc `hasKey` coercibleDataConKey
1077 , all exprIsTrivial args = True
1078 -- See Note [Getting the map/coerce RULE to work]
1079 | otherwise = False
1080
1081 ----------------------
1082 subst_opt_bndr :: Subst -> InVar -> (Subst, OutVar)
1083 subst_opt_bndr subst bndr
1084 | isTyVar bndr = substTyVarBndr subst bndr
1085 | isCoVar bndr = substCoVarBndr subst bndr
1086 | otherwise = subst_opt_id_bndr subst bndr
1087
1088 subst_opt_id_bndr :: Subst -> InId -> (Subst, OutId)
1089 -- Nuke all fragile IdInfo, unfolding, and RULES;
1090 -- it gets added back later by add_info
1091 -- Rather like SimplEnv.substIdBndr
1092 --
1093 -- It's important to zap fragile OccInfo (which CoreSubst.substIdBndr
1094 -- carefully does not do) because simplOptExpr invalidates it
1095
1096 subst_opt_id_bndr subst@(Subst in_scope id_subst tv_subst cv_subst) old_id
1097 = (Subst new_in_scope new_id_subst tv_subst cv_subst, new_id)
1098 where
1099 id1 = uniqAway in_scope old_id
1100 id2 = setIdType id1 (substTy subst (idType old_id))
1101 new_id = zapFragileIdInfo id2 -- Zaps rules, worker-info, unfolding
1102 -- and fragile OccInfo
1103 new_in_scope = in_scope `extendInScopeSet` new_id
1104
1105 -- Extend the substitution if the unique has changed,
1106 -- or there's some useful occurrence information
1107 -- See the notes with substTyVarBndr for the delSubstEnv
1108 new_id_subst | new_id /= old_id
1109 = extendVarEnv id_subst old_id (Var new_id)
1110 | otherwise
1111 = delVarEnv id_subst old_id
1112
1113 ----------------------
1114 subst_opt_bndrs :: Subst -> [InVar] -> (Subst, [OutVar])
1115 subst_opt_bndrs subst bndrs
1116 = mapAccumL subst_opt_bndr subst bndrs
1117
1118 ----------------------
1119 add_info :: Subst -> InVar -> OutVar -> OutVar
1120 add_info subst old_bndr new_bndr
1121 | isTyVar old_bndr = new_bndr
1122 | otherwise = maybeModifyIdInfo mb_new_info new_bndr
1123 where mb_new_info = substIdInfo subst new_bndr (idInfo old_bndr)
1124
1125 simpleUnfoldingFun :: IdUnfoldingFun
1126 simpleUnfoldingFun id
1127 | isAlwaysActive (idInlineActivation id) = idUnfolding id
1128 | otherwise = noUnfolding
1129
1130 {-
1131 Note [Inline prag in simplOpt]
1132 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1133 If there's an INLINE/NOINLINE pragma that restricts the phase in
1134 which the binder can be inlined, we don't inline here; after all,
1135 we don't know what phase we're in. Here's an example
1136
1137 foo :: Int -> Int -> Int
1138 {-# INLINE foo #-}
1139 foo m n = inner m
1140 where
1141 {-# INLINE [1] inner #-}
1142 inner m = m+n
1143
1144 bar :: Int -> Int
1145 bar n = foo n 1
1146
1147 When inlining 'foo' in 'bar' we want the let-binding for 'inner'
1148 to remain visible until Phase 1
1149
1150 Note [Unfold compulsory unfoldings in LHSs]
1151 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1152 When the user writes `RULES map coerce = coerce` as a rule, the rule
1153 will only ever match if simpleOptExpr replaces coerce by its unfolding
1154 on the LHS, because that is the core that the rule matching engine
1155 will find. So do that for everything that has a compulsory
1156 unfolding. Also see Note [Desugaring coerce as cast] in Desugar.
1157
1158 However, we don't want to inline 'seq', which happens to also have a
1159 compulsory unfolding, so we only do this unfolding only for things
1160 that are always-active. See Note [User-defined RULES for seq] in MkId.
1161
1162
1163 ************************************************************************
1164 * *
1165 exprIsConApp_maybe
1166 * *
1167 ************************************************************************
1168
1169 Note [exprIsConApp_maybe]
1170 ~~~~~~~~~~~~~~~~~~~~~~~~~
1171 exprIsConApp_maybe is a very important function. There are two principal
1172 uses:
1173 * case e of { .... }
1174 * cls_op e, where cls_op is a class operation
1175
1176 In both cases you want to know if e is of form (C e1..en) where C is
1177 a data constructor.
1178
1179 However e might not *look* as if
1180
1181
1182 Note [exprIsConApp_maybe on literal strings]
1183 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1184 See #9400.
1185
1186 Conceptually, a string literal "abc" is just ('a':'b':'c':[]), but in Core
1187 they are represented as unpackCString# "abc"# by MkCore.mkStringExprFS, or
1188 unpackCStringUtf8# when the literal contains multi-byte UTF8 characters.
1189
1190 For optimizations we want to be able to treat it as a list, so they can be
1191 decomposed when used in a case-statement. exprIsConApp_maybe detects those
1192 calls to unpackCString# and returns:
1193
1194 Just (':', [Char], ['a', unpackCString# "bc"]).
1195
1196 We need to be careful about UTF8 strings here. ""# contains a ByteString, so
1197 we must parse it back into a FastString to split off the first character.
1198 That way we can treat unpackCString# and unpackCStringUtf8# in the same way.
1199 -}
1200
1201 data ConCont = CC [CoreExpr] Coercion
1202 -- Substitution already applied
1203
1204 -- | Returns @Just (dc, [t1..tk], [x1..xn])@ if the argument expression is
1205 -- a *saturated* constructor application of the form @dc t1..tk x1 .. xn@,
1206 -- where t1..tk are the *universally-qantified* type args of 'dc'
1207 exprIsConApp_maybe :: InScopeEnv -> CoreExpr -> Maybe (DataCon, [Type], [CoreExpr])
1208 exprIsConApp_maybe (in_scope, id_unf) expr
1209 = go (Left in_scope) expr (CC [] (mkRepReflCo (exprType expr)))
1210 where
1211 go :: Either InScopeSet Subst
1212 -> CoreExpr -> ConCont
1213 -> Maybe (DataCon, [Type], [CoreExpr])
1214 go subst (Tick t expr) cont
1215 | not (tickishIsCode t) = go subst expr cont
1216 go subst (Cast expr co1) (CC [] co2)
1217 = go subst expr (CC [] (subst_co subst co1 `mkTransCo` co2))
1218 go subst (App fun arg) (CC args co)
1219 = go subst fun (CC (subst_arg subst arg : args) co)
1220 go subst (Lam var body) (CC (arg:args) co)
1221 | exprIsTrivial arg -- Don't duplicate stuff!
1222 = go (extend subst var arg) body (CC args co)
1223 go (Right sub) (Var v) cont
1224 = go (Left (substInScope sub))
1225 (lookupIdSubst (text "exprIsConApp" <+> ppr expr) sub v)
1226 cont
1227
1228 go (Left in_scope) (Var fun) cont@(CC args co)
1229
1230 | Just con <- isDataConWorkId_maybe fun
1231 , count isValArg args == idArity fun
1232 = dealWithCoercion co con args
1233
1234 -- Look through dictionary functions; see Note [Unfolding DFuns]
1235 | DFunUnfolding { df_bndrs = bndrs, df_con = con, df_args = dfun_args } <- unfolding
1236 , bndrs `equalLength` args -- See Note [DFun arity check]
1237 , let subst = mkOpenSubst in_scope (bndrs `zip` args)
1238 = dealWithCoercion co con (map (substExpr (text "exprIsConApp1") subst) dfun_args)
1239
1240 -- Look through unfoldings, but only arity-zero one;
1241 -- if arity > 0 we are effectively inlining a function call,
1242 -- and that is the business of callSiteInline.
1243 -- In practice, without this test, most of the "hits" were
1244 -- CPR'd workers getting inlined back into their wrappers,
1245 | idArity fun == 0
1246 , Just rhs <- expandUnfolding_maybe unfolding
1247 , let in_scope' = extendInScopeSetSet in_scope (exprFreeVars rhs)
1248 = go (Left in_scope') rhs cont
1249
1250 | (fun `hasKey` unpackCStringIdKey)
1251 || (fun `hasKey` unpackCStringUtf8IdKey)
1252 , [Lit (MachStr str)] <- args
1253 = dealWithStringLiteral fun str co
1254 where
1255 unfolding = id_unf fun
1256
1257 go _ _ _ = Nothing
1258
1259 ----------------------------
1260 -- Operations on the (Either InScopeSet CoreSubst)
1261 -- The Left case is wildly dominant
1262 subst_co (Left {}) co = co
1263 subst_co (Right s) co = CoreSubst.substCo s co
1264
1265 subst_arg (Left {}) e = e
1266 subst_arg (Right s) e = substExpr (text "exprIsConApp2") s e
1267
1268 extend (Left in_scope) v e = Right (extendSubst (mkEmptySubst in_scope) v e)
1269 extend (Right s) v e = Right (extendSubst s v e)
1270
1271 -- See Note [exprIsConApp_maybe on literal strings]
1272 dealWithStringLiteral :: Var -> BS.ByteString -> Coercion
1273 -> Maybe (DataCon, [Type], [CoreExpr])
1274
1275 -- This is not possible with user-supplied empty literals, MkCore.mkStringExprFS
1276 -- turns those into [] automatically, but just in case something else in GHC
1277 -- generates a string literal directly.
1278 dealWithStringLiteral _ str co
1279 | BS.null str
1280 = dealWithCoercion co nilDataCon [Type charTy]
1281
1282 dealWithStringLiteral fun str co
1283 = let strFS = mkFastStringByteString str
1284
1285 char = mkConApp charDataCon [mkCharLit (headFS strFS)]
1286 charTail = fastStringToByteString (tailFS strFS)
1287
1288 -- In singleton strings, just add [] instead of unpackCstring# ""#.
1289 rest = if BS.null charTail
1290 then mkConApp nilDataCon [Type charTy]
1291 else App (Var fun)
1292 (Lit (MachStr charTail))
1293
1294 in dealWithCoercion co consDataCon [Type charTy, char, rest]
1295
1296 dealWithCoercion :: Coercion -> DataCon -> [CoreExpr]
1297 -> Maybe (DataCon, [Type], [CoreExpr])
1298 dealWithCoercion co dc dc_args
1299 | isReflCo co
1300 , let (univ_ty_args, rest_args) = splitAtList (dataConUnivTyVars dc) dc_args
1301 = Just (dc, map exprToType univ_ty_args, rest_args)
1302
1303 | Pair _from_ty to_ty <- coercionKind co
1304 , Just (to_tc, to_tc_arg_tys) <- splitTyConApp_maybe to_ty
1305 , to_tc == dataConTyCon dc
1306 -- These two tests can fail; we might see
1307 -- (C x y) `cast` (g :: T a ~ S [a]),
1308 -- where S is a type function. In fact, exprIsConApp
1309 -- will probably not be called in such circumstances,
1310 -- but there't nothing wrong with it
1311
1312 = -- Here we do the KPush reduction rule as described in "Down with kinds"
1313 -- The transformation applies iff we have
1314 -- (C e1 ... en) `cast` co
1315 -- where co :: (T t1 .. tn) ~ to_ty
1316 -- The left-hand one must be a T, because exprIsConApp returned True
1317 -- but the right-hand one might not be. (Though it usually will.)
1318 let
1319 tc_arity = tyConArity to_tc
1320 dc_univ_tyvars = dataConUnivTyVars dc
1321 dc_ex_tyvars = dataConExTyVars dc
1322 arg_tys = dataConRepArgTys dc
1323
1324 non_univ_args = dropList dc_univ_tyvars dc_args
1325 (ex_args, val_args) = splitAtList dc_ex_tyvars non_univ_args
1326
1327 -- Make the "Psi" from the paper
1328 omegas = decomposeCo tc_arity co
1329 (psi_subst, to_ex_arg_tys)
1330 = liftCoSubstWithEx Representational
1331 dc_univ_tyvars
1332 omegas
1333 dc_ex_tyvars
1334 (map exprToType ex_args)
1335
1336 -- Cast the value arguments (which include dictionaries)
1337 new_val_args = zipWith cast_arg arg_tys val_args
1338 cast_arg arg_ty arg = mkCast arg (psi_subst arg_ty)
1339
1340 to_ex_args = map Type to_ex_arg_tys
1341
1342 dump_doc = vcat [ppr dc, ppr dc_univ_tyvars, ppr dc_ex_tyvars,
1343 ppr arg_tys, ppr dc_args,
1344 ppr ex_args, ppr val_args, ppr co, ppr _from_ty, ppr to_ty, ppr to_tc ]
1345 in
1346 ASSERT2( eqType _from_ty (mkTyConApp to_tc (map exprToType $ takeList dc_univ_tyvars dc_args)), dump_doc )
1347 ASSERT2( equalLength val_args arg_tys, dump_doc )
1348 Just (dc, to_tc_arg_tys, to_ex_args ++ new_val_args)
1349
1350 | otherwise
1351 = Nothing
1352
1353 {-
1354 Note [Unfolding DFuns]
1355 ~~~~~~~~~~~~~~~~~~~~~~
1356 DFuns look like
1357
1358 df :: forall a b. (Eq a, Eq b) -> Eq (a,b)
1359 df a b d_a d_b = MkEqD (a,b) ($c1 a b d_a d_b)
1360 ($c2 a b d_a d_b)
1361
1362 So to split it up we just need to apply the ops $c1, $c2 etc
1363 to the very same args as the dfun. It takes a little more work
1364 to compute the type arguments to the dictionary constructor.
1365
1366 Note [DFun arity check]
1367 ~~~~~~~~~~~~~~~~~~~~~~~
1368 Here we check that the total number of supplied arguments (inclding
1369 type args) matches what the dfun is expecting. This may be *less*
1370 than the ordinary arity of the dfun: see Note [DFun unfoldings] in CoreSyn
1371 -}
1372
1373 exprIsLiteral_maybe :: InScopeEnv -> CoreExpr -> Maybe Literal
1374 -- Same deal as exprIsConApp_maybe, but much simpler
1375 -- Nevertheless we do need to look through unfoldings for
1376 -- Integer literals, which are vigorously hoisted to top level
1377 -- and not subsequently inlined
1378 exprIsLiteral_maybe env@(_, id_unf) e
1379 = case e of
1380 Lit l -> Just l
1381 Tick _ e' -> exprIsLiteral_maybe env e' -- dubious?
1382 Var v | Just rhs <- expandUnfolding_maybe (id_unf v)
1383 -> exprIsLiteral_maybe env rhs
1384 _ -> Nothing
1385
1386 {-
1387 Note [exprIsLambda_maybe]
1388 ~~~~~~~~~~~~~~~~~~~~~~~~~~
1389 exprIsLambda_maybe will, given an expression `e`, try to turn it into the form
1390 `Lam v e'` (returned as `Just (v,e')`). Besides using lambdas, it looks through
1391 casts (using the Push rule), and it unfolds function calls if the unfolding
1392 has a greater arity than arguments are present.
1393
1394 Currently, it is used in Rules.match, and is required to make
1395 "map coerce = coerce" match.
1396 -}
1397
1398 exprIsLambda_maybe :: InScopeEnv -> CoreExpr
1399 -> Maybe (Var, CoreExpr,[Tickish Id])
1400 -- See Note [exprIsLambda_maybe]
1401
1402 -- The simple case: It is a lambda already
1403 exprIsLambda_maybe _ (Lam x e)
1404 = Just (x, e, [])
1405
1406 -- Still straightforward: Ticks that we can float out of the way
1407 exprIsLambda_maybe (in_scope_set, id_unf) (Tick t e)
1408 | tickishFloatable t
1409 , Just (x, e, ts) <- exprIsLambda_maybe (in_scope_set, id_unf) e
1410 = Just (x, e, t:ts)
1411
1412 -- Also possible: A casted lambda. Push the coercion inside
1413 exprIsLambda_maybe (in_scope_set, id_unf) (Cast casted_e co)
1414 | Just (x, e,ts) <- exprIsLambda_maybe (in_scope_set, id_unf) casted_e
1415 -- Only do value lambdas.
1416 -- this implies that x is not in scope in gamma (makes this code simpler)
1417 , not (isTyVar x) && not (isCoVar x)
1418 , ASSERT( not $ x `elemVarSet` tyCoVarsOfCo co) True
1419 , Just (x',e') <- pushCoercionIntoLambda in_scope_set x e co
1420 , let res = Just (x',e',ts)
1421 = --pprTrace "exprIsLambda_maybe:Cast" (vcat [ppr casted_e,ppr co,ppr res)])
1422 res
1423
1424 -- Another attempt: See if we find a partial unfolding
1425 exprIsLambda_maybe (in_scope_set, id_unf) e
1426 | (Var f, as, ts) <- collectArgsTicks tickishFloatable e
1427 , idArity f > length (filter isValArg as)
1428 -- Make sure there is hope to get a lambda
1429 , Just rhs <- expandUnfolding_maybe (id_unf f)
1430 -- Optimize, for beta-reduction
1431 , let e' = simpleOptExprWith (mkEmptySubst in_scope_set) (rhs `mkApps` as)
1432 -- Recurse, because of possible casts
1433 , Just (x', e'', ts') <- exprIsLambda_maybe (in_scope_set, id_unf) e'
1434 , let res = Just (x', e'', ts++ts')
1435 = -- pprTrace "exprIsLambda_maybe:Unfold" (vcat [ppr e, ppr (x',e'')])
1436 res
1437
1438 exprIsLambda_maybe _ _e
1439 = -- pprTrace "exprIsLambda_maybe:Fail" (vcat [ppr _e])
1440 Nothing
1441
1442
1443 pushCoercionIntoLambda
1444 :: InScopeSet -> Var -> CoreExpr -> Coercion -> Maybe (Var, CoreExpr)
1445 pushCoercionIntoLambda in_scope x e co
1446 -- This implements the Push rule from the paper on coercions
1447 -- Compare with simplCast in Simplify
1448 | ASSERT(not (isTyVar x) && not (isCoVar x)) True
1449 , Pair s1s2 t1t2 <- coercionKind co
1450 , Just (_s1,_s2) <- splitFunTy_maybe s1s2
1451 , Just (t1,_t2) <- splitFunTy_maybe t1t2
1452 = let [co1, co2] = decomposeCo 2 co
1453 -- Should we optimize the coercions here?
1454 -- Otherwise they might not match too well
1455 x' = x `setIdType` t1
1456 in_scope' = in_scope `extendInScopeSet` x'
1457 subst = extendIdSubst (mkEmptySubst in_scope')
1458 x
1459 (mkCast (Var x') co1)
1460 in Just (x', subst_expr subst e `mkCast` co2)
1461 | otherwise
1462 = pprTrace "exprIsLambda_maybe: Unexpected lambda in case" (ppr (Lam x e))
1463 Nothing