configure.ac: drop unused HAVE_BIN_SH
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.9], [glasgow-haskell-bugs@haskell.org], [ghc])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands,
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42 FP_PROG_SORT
43
44 dnl ----------------------------------------------------------
45 FP_SETUP_PROJECT_VERSION
46
47 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
48 AC_SUBST([release], [1])
49
50 # First off, a distrib sanity check..
51 AC_CONFIG_SRCDIR([mk/config.mk.in])
52
53 dnl * We require autoconf version 2.60
54 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
55 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
56 dnl Using autoconf 2.59 started to give nonsense like this
57 dnl  #define SIZEOF_CHAR 0
58 dnl recently.
59 AC_PREREQ([2.60])
60
61 # -------------------------------------------------------------------------
62 # Prepare to generate the following header files
63 #
64 #
65 AC_CONFIG_HEADER(mk/config.h)
66
67 # No, semi-sadly, we don't do `--srcdir'...
68 if test x"$srcdir" != 'x.' ; then
69     echo "This configuration does not support the \`--srcdir' option.."
70     exit 1
71 fi
72
73 dnl --------------------------------------------------------------
74 dnl * Project specific configuration options
75 dnl --------------------------------------------------------------
76 dnl What follows is a bunch of options that can either be configured
77 dnl through command line options to the configure script or by
78 dnl supplying defns in the build tree's mk/build.mk. Having the option to
79 dnl use either is considered a Feature.
80
81 dnl ** What command to use to compile compiler sources ?
82 dnl --------------------------------------------------------------
83
84 AC_ARG_WITH([ghc],
85 [AC_HELP_STRING([--with-ghc=ARG],
86   [Use ARG as the path to GHC  [default=autodetect]])],
87   [WithGhc="$withval"],
88   [if test "$GHC" = ""; then
89     AC_PATH_PROG([GHC], [ghc])
90   fi
91   WithGhc="$GHC"])
92
93 dnl ** Tell the make system which OS we are using
94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
95 AC_SUBST(OSTYPE)
96
97 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
98 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
99                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
100         EnableBootstrapWithDevelSnaphost=YES,
101         EnableBootstrapWithDevelSnaphost=NO
102 )
103
104 if test "$WithGhc" != ""; then
105   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
106
107   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
108      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
109   fi
110
111   AC_SUBST(GhcVersion)dnl
112   AC_SUBST(GhcMajVersion)dnl
113   AC_SUBST(GhcMinVersion)dnl
114   AC_SUBST(GhcPatchLevel)dnl
115   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
116   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
117
118   BOOTSTRAPPING_GHC_INFO_FIELD([OS_STAGE0],[target os])
119   BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
120   dnl ToDo, once "ld command" is reliably available.
121   dnl Then, we can remove the LD_STAGE0 hack in mk/build-package-date.mk
122   dnl BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
123   if test "x$OS_STAGE0" != "xOSDarwin"; then
124     BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
125     BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
126     BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
127   else
128     AR_STAGE0='$(AR)'
129     AR_OPTS_STAGE0='$(AR_OPTS)'
130     ArSupportsAtFile_STAGE0='$(ArSupportsAtFile)'
131   fi
132 fi
133
134 dnl ** Must have GHC to build GHC
135 if test "$WithGhc" = ""
136 then
137     AC_MSG_ERROR([GHC is required.])
138 fi
139 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.4],
140     [AC_MSG_ERROR([GHC version 7.4 or later is required to compile GHC.])])dnl
141
142 if test `expr $GhcMinVersion % 2` = "1"
143 then
144     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
145     then
146         AC_MSG_ERROR([
147      $WithGhc is a development snapshot of GHC, version $GhcVersion.
148      Bootstrapping using this version of GHC is not supported, and may not
149      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
150      or --with-ghc to specify a different GHC to use.])
151     fi
152 fi
153
154 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.5],
155                     GHC_PACKAGE_DB_FLAG=package-conf,
156                     GHC_PACKAGE_DB_FLAG=package-db)
157 AC_SUBST(GHC_PACKAGE_DB_FLAG)
158
159 # GHC 7.7+ needs -fcmm-sink when compiling Parser.hs. See #8182
160 FP_COMPARE_VERSIONS([$GhcVersion],[-gt],[7.7],
161                     CMM_SINK_BOOTSTRAP_IS_NEEDED=YES,
162                     CMM_SINK_BOOTSTRAP_IS_NEEDED=NO)
163 AC_SUBST(CMM_SINK_BOOTSTRAP_IS_NEEDED)
164
165 # GHC is passed to Cabal, so we need a native path
166 if test "${WithGhc}" != ""
167 then
168     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
169
170     if test "$ghc_host_os" = "mingw32"
171     then
172         if test "${OSTYPE}" = "msys"
173         then
174             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
175         else
176             # Canonicalise to <drive>:/path/to/ghc
177             WithGhc=`cygpath -m "${WithGhc}"`
178         fi
179         echo "GHC path canonicalised to: ${WithGhc}"
180     fi
181 fi
182 AC_SUBST([WithGhc])
183
184 dnl ** Without optimization some INLINE trickery fails for GHCi
185 SRC_CC_OPTS="-O"
186
187 dnl--------------------------------------------------------------------
188 dnl * Choose host(/target/build) platform
189 dnl--------------------------------------------------------------------
190 dnl If we aren't explicitly told what values to use with configure flags,
191 dnl we ask the bootstrapping compiler what platform it is for
192
193 if test "${WithGhc}" != ""
194 then
195         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
196         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
197         if test "$bootstrap_host" != "$bootstrap_target"
198         then
199                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
200         fi
201 fi
202
203 # We have to run these unconditionally, but we may discard their
204 # results in the following code
205 AC_CANONICAL_BUILD
206 AC_CANONICAL_HOST
207 AC_CANONICAL_TARGET
208
209 FPTOOLS_SET_PLATFORM_VARS
210
211 # Verify that the installed (bootstrap) GHC is capable of generating
212 # code for the requested build platform.
213 if test "$BuildPlatform" != "$bootstrap_target"
214 then
215     echo "This GHC (${WithGhc}) does not generate code for the build platform"
216     echo "   GHC target platform    : $bootstrap_target"
217     echo "   Desired build platform : $BuildPlatform"
218     exit 1
219 fi
220
221 # Testing if we shall enable shared libs support on Solaris.
222 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
223
224 SOLARIS_BROKEN_SHLD=NO
225
226 case $host in
227      i386-*-solaris2)
228      # here we go with the test
229      MINOR=`uname -r|cut -d '.' -f 2-`
230      if test "$MINOR" -lt "11"; then
231          SOLARIS_BROKEN_SHLD=YES
232      fi
233      ;;
234 esac
235
236 AC_SUBST(SOLARIS_BROKEN_SHLD)
237
238 dnl ** Do an unregisterised build?
239 dnl --------------------------------------------------------------
240 case "$HostArch" in
241     i386|x86_64|powerpc|arm)
242         UnregisterisedDefault=NO
243         ;;
244     *)
245         UnregisterisedDefault=YES
246         ;;
247 esac
248 AC_ARG_ENABLE(unregisterised,
249 [AC_HELP_STRING([--enable-unregisterised],
250 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
251 [ if test x"$enableval" = x"yes"; then
252         Unregisterised=YES
253   else
254         Unregisterised=NO
255   fi
256 ],
257 [Unregisterised="$UnregisterisedDefault"]
258 )
259 AC_SUBST(Unregisterised)
260
261 AC_ARG_WITH(hc,
262 [AC_HELP_STRING([--with-hc=ARG],
263         [Use ARG as the path to the compiler for compiling ordinary
264          Haskell code  (default= value of --with-ghc)])],
265 [WithHc="$withval"],
266 [WithHc=$WithGhc]
267 )
268 AC_SUBST(WithHc)
269
270 # This uses GHC, so put it after the "GHC is required" check above:
271 FP_INTREE_GHC_PWD
272 FP_FIND_ROOT
273
274 if test "$HostOS" = "mingw32"
275 then
276     test -d inplace || mkdir inplace
277
278     if test "$HostArch" = "i386"
279     then
280         # NB. If you update the tarballs to a new version of gcc, don't
281         # forget to tweak the paths in driver/gcc/gcc.c.
282         if ! test -d inplace/mingw ||
283              test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma  ||
284              test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma  ||
285              test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma   ||
286              test inplace/mingw -ot ghc-tarballs/mingw/libgcc*.tar.gz      ||
287              test inplace/mingw -ot ghc-tarballs/mingw/libgmp*.tar.gz      ||
288              test inplace/mingw -ot ghc-tarballs/mingw/libmpc*.tar.gz      ||
289              test inplace/mingw -ot ghc-tarballs/mingw/libmpfr*.tar.gz     ||
290              test inplace/mingw -ot ghc-tarballs/mingw/libstdc*.tar.lzma   ||
291              test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dev.tar.gz ||
292              test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dll.tar.gz ||
293              test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
294         then
295             AC_MSG_NOTICE([Making in-tree mingw tree])
296             rm -rf inplace/mingw
297             mkdir inplace/mingw
298             (
299                 cd inplace/mingw &&
300                 tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma  &&
301                 tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma  &&
302                 tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma   &&
303                 tar --lzma -xf ../../ghc-tarballs/mingw/libgcc*.tar.lzma    &&
304                 tar --lzma -xf ../../ghc-tarballs/mingw/libgmp*.tar.lzma    &&
305                 tar --lzma -xf ../../ghc-tarballs/mingw/libmpc*.tar.lzma    &&
306                 tar --lzma -xf ../../ghc-tarballs/mingw/libmpfr*.tar.lzma   &&
307                 tar --lzma -xf ../../ghc-tarballs/mingw/libstdc*.tar.lzma   &&
308                 tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dev.tar.gz &&
309                 tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dll.tar.gz &&
310                 tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma    &&
311                 mv bin/gcc.exe bin/realgcc.exe
312             )
313             PATH=`pwd`/inplace/mingw/bin:$PATH inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
314             AC_MSG_NOTICE([In-tree mingw tree created])
315         fi
316     else
317         # NB. If you update the tarballs to a new version of gcc, don't
318         # forget to tweak the paths in driver/gcc/gcc.c.
319         if ! test -d inplace/mingw ||
320              test inplace/mingw -ot ghc-tarballs/mingw64/*.tar.bz2
321         then
322             AC_MSG_NOTICE([Making in-tree mingw tree])
323             rm -rf inplace/mingw
324             mkdir inplace/mingw
325             (
326                 cd inplace/mingw &&
327                 tar -jxf ../../ghc-tarballs/mingw64/*.tar.bz2
328             )
329             AC_MSG_NOTICE([In-tree mingw tree created])
330         fi
331     fi
332
333     mingwbin="$hardtop/inplace/mingw/bin/"
334     CC="${mingwbin}gcc.exe"
335     LD="${mingwbin}ld.exe"
336     NM="${mingwbin}nm.exe"
337     RANLIB="${mingwbin}ranlib.exe"
338     OBJDUMP="${mingwbin}objdump.exe"
339     fp_prog_ar="${mingwbin}ar.exe"
340
341     if ! test -d inplace/perl ||
342          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
343     then
344         AC_MSG_NOTICE([Making in-tree perl tree])
345         rm -rf inplace/perl
346         mkdir inplace/perl
347         (
348             cd inplace/perl &&
349             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
350         )
351         AC_MSG_NOTICE([In-tree perl tree created])
352     fi
353 fi
354
355 # system libffi
356
357 AC_ARG_WITH([system-libffi],
358 [AC_HELP_STRING([--with-system-libffi],
359   [Use system provided libffi for RTS [default=no]])
360 ])
361
362 AS_IF([test "x$with_system_libffi" = "xyes"],
363   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
364 )
365
366
367 AC_SUBST(UseSystemLibFFI)
368
369 AC_ARG_WITH([ffi-includes],
370 [AC_HELP_STRING([--with-ffi-includes=ARG],
371   [Find includes for libffi in ARG [default=system default]])
372 ],
373 [
374  if test "x$UseSystemLibFFI" != "xYES"; then
375     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
376  else
377     FFIIncludeDir="$withval"
378     LIBFFI_CFLAGS="-I$withval"
379  fi
380 ])
381
382 AC_SUBST(FFIIncludeDir)
383
384 AC_ARG_WITH([ffi-libraries],
385 [AC_HELP_STRING([--with-ffi-libraries=ARG],
386   [Find libffi in ARG [default=system default]])
387 ],
388 [
389  if test "x$UseSystemLibFFI" != "xYES"; then
390     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
391  else
392     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
393  fi
394 ])
395
396 AC_SUBST(FFILibDir)
397
398 AS_IF([test "$UseSystemLibFFI" = "YES"], [
399  CFLAGS2="$CFLAGS"
400  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
401  LDFLAGS2="$LDFLAGS"
402  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
403  AC_CHECK_LIB(ffi, ffi_call,
404   [AC_CHECK_HEADERS([ffi.h], [break], [])
405    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
406   [AC_MSG_ERROR([Cannot find system libffi])])
407  CFLAGS="$CFLAGS2"
408  LDFLAGS="$LDFLAGS2"
409 ])
410
411 FP_ICONV
412 FP_GMP
413
414 XCODE_VERSION()
415
416 SplitObjsBroken=NO
417 if test "$TargetOS_CPP" = "darwin"
418 then
419     # Split objects is broken (#4013) with XCode < 3.2
420     if test "$XCodeVersion1" -lt 3
421     then
422         SplitObjsBroken=YES
423     else
424         if test "$XCodeVersion1" -eq 3
425         then
426             if test "$XCodeVersion2" -lt 2
427             then
428                 SplitObjsBroken=YES
429             fi
430         fi
431     fi
432 fi
433 AC_SUBST([SplitObjsBroken])
434
435 dnl ** Building a cross compiler?
436 dnl --------------------------------------------------------------
437 CrossCompiling=NO
438 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
439 if test "$target" != "$host" ; then
440     CrossCompiling=YES
441     cross_compiling=yes   # This tells configure that it can accept just 'target',
442                           # otherwise you get
443                           #   configure: error: cannot run C compiled programs.
444                           #   If you meant to cross compile, use `--host'.
445 fi
446 if test "$build" != "$host" ; then
447    AC_MSG_ERROR([
448 You've selected:
449
450   BUILD:  $build   (the architecture we're building on)
451   HOST:   $host    (the architecture the compiler we're building will execute on)
452   TARGET: $target  (the architecture the compiler we're building will produce code for)
453
454 BUILD must equal HOST; that is, we do not support building GHC itself
455 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
456 1 will be a cross-compiler, and stage 2 will be the cross-compiled
457 GHC.
458 ])
459 fi
460 if test "$CrossCompiling" = "YES"
461 then
462   CrossCompilePrefix="${target}-"
463 else
464   CrossCompilePrefix=""
465 fi
466 TargetPlatformFull="${target}"
467 AC_SUBST(CrossCompiling)
468 AC_SUBST(CrossCompilePrefix)
469 AC_SUBST(TargetPlatformFull)
470
471 dnl ** Which gcc to use?
472 dnl --------------------------------------------------------------
473 FIND_GCC([WhatGccIsCalled], [gcc], [gcc])
474 CC="$WhatGccIsCalled"
475 export CC
476
477 # If --with-gcc was used, and we're not cross-compiling, then it also
478 # applies to the stage0 compiler.
479 MAYBE_OVERRIDE_STAGE0([gcc],[CC_STAGE0])
480 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
481
482 dnl ** what cpp to use?
483 dnl --------------------------------------------------------------
484 AC_ARG_WITH(hs-cpp,
485 [AC_HELP_STRING([--with-hs-cpp=ARG],
486         [Use ARG as the path to cpp [default=autodetect]])],
487 [
488     if test "$HostOS" = "mingw32"
489     then
490         AC_MSG_WARN([Request to use $withval will be ignored])
491     else
492         HaskellCPPCmd=$withval
493     fi
494 ],
495 [
496         HaskellCPPCmd=$WhatGccIsCalled
497 ]
498 )
499
500
501
502 dnl ** what cpp flags to use?
503 dnl -----------------------------------------------------------
504 AC_ARG_WITH(hs-cpp-flags,
505   [AC_HELP_STRING([--with-hs-cpp-flags=ARG],
506           [Use ARG as the path to hs cpp [default=autodetect]])],
507   [
508       if test "$HostOS" = "mingw32"
509       then
510           AC_MSG_WARN([Request to use $withval will be ignored])
511       else
512           HaskellCPPArgs=$withval
513       fi
514   ],
515 [
516   $HaskellCPPCmd -x c /dev/null -dM -E > conftest.txt 2>&1
517   if grep "__clang__" conftest.txt >/dev/null 2>&1; then
518     HaskellCPPArgs="-E -undef -traditional -Wno-invalid-pp-token -Wno-unicode -Wno-trigraphs "
519   else
520       $HaskellCPPCmd  -v > conftest.txt 2>&1
521       if  grep "gcc" conftest.txt >/dev/null 2>&1; then
522           HaskellCPPArgs="-E -undef -traditional "
523         else
524           $HaskellCPPCmd  --version > conftest.txt 2>&1
525           if grep "cpphs" conftest.txt >/dev/null 2>&1; then
526             HaskellCPPArgs="--cpp -traditional"
527           else
528             AC_MSG_WARN([configure can't recognize your CPP program, you may need to set --with-hs-cpp-flags=FLAGS explicitly])
529             HaskellCPPArgs=""
530           fi
531       fi
532   fi
533   ]
534 )
535
536
537 dnl ** Which ld to use?
538 dnl --------------------------------------------------------------
539 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld], [ld])
540 LdCmd="$LD"
541 AC_SUBST([LdCmd])
542
543 dnl ** Which nm to use?
544 dnl --------------------------------------------------------------
545 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
546 NmCmd="$NM"
547 AC_SUBST([NmCmd])
548
549 dnl ** Which ar to use?
550 dnl --------------------------------------------------------------
551 FP_ARG_WITH_PATH_GNU_PROG([AR], [ar], [ar])
552 ArCmd="$AR"
553 fp_prog_ar="$AR"
554 AC_SUBST([ArCmd])
555
556 dnl ** Which ranlib to use?
557 dnl --------------------------------------------------------------
558 FP_ARG_WITH_PATH_GNU_PROG([RANLIB], [ranlib], [ranlib])
559 RanlibCmd="$RANLIB"
560 RANLIB="$RanlibCmd"
561
562
563 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
564 case $HostOS_CPP in
565 cygwin32|mingw32)
566     dnl ** Which objdump to use?
567     dnl --------------------------------------------------------------
568     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
569     ObjdumpCmd="$OBJDUMP"
570     AC_SUBST([ObjdumpCmd])
571     ;;
572 esac
573
574 dnl ** Which LLVM llc to use?
575 dnl --------------------------------------------------------------
576 FIND_LLVM_PROG([LLC], [llc], [llc])
577 LlcCmd="$LLC"
578 AC_SUBST([LlcCmd])
579
580 dnl ** Which LLVM opt to use?
581 dnl --------------------------------------------------------------
582 FIND_LLVM_PROG([OPT], [opt], [opt])
583 OptCmd="$OPT"
584 AC_SUBST([OptCmd])
585
586 dnl --------------------------------------------------------------
587 dnl End of configure script option section
588 dnl --------------------------------------------------------------
589
590
591 dnl --------------------------------------------------------------
592 dnl * General configuration checks
593 dnl --------------------------------------------------------------
594
595 dnl ** Can the unix package be built?
596 dnl --------------------------------------------------------------
597
598 if test "$TargetOS" = "mingw32"
599 then
600     GhcLibsWithUnix=NO
601 else
602     GhcLibsWithUnix=YES
603 fi
604 AC_SUBST([GhcLibsWithUnix])
605
606 dnl ** does #! work?
607 AC_SYS_INTERPRETER()
608
609 dnl ** look for `perl'
610 case $HostOS_CPP in
611 cygwin32|mingw32)
612     PerlCmd=$hardtop/inplace/perl/perl
613     ;;
614 *)
615     AC_PATH_PROG(PerlCmd,perl)
616     if test -z "$PerlCmd"
617     then
618         echo "You must install perl before you can continue"
619         echo "Perhaps it is already installed, but not in your PATH?"
620         exit 1
621     else
622         FPTOOLS_CHECK_PERL_VERSION
623     fi
624     ;;
625 esac
626
627 dnl ** look for GCC and find out which version
628 dnl     Figure out which C compiler to use.  Gcc is preferred.
629 dnl     If gcc, make sure it's at least 3.0
630 dnl
631 FP_GCC_VERSION
632
633 dnl ** look to see if we have a C compiler using an llvm back end.
634 dnl
635 FP_CC_LLVM_BACKEND
636
637 FP_PROG_LD_IS_GNU
638 FP_PROG_LD_BUILD_ID
639 FP_PROG_LD_NO_COMPACT_UNWIND
640 FP_PROG_LD_FILELIST
641
642
643 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
644 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
645 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
646 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
647 # Stage 3 won't be supported by cross-compilation
648
649 FP_GCC_EXTRA_FLAGS
650
651 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
652 AC_PROG_CPP
653
654 AC_SUBST(CONF_CC_OPTS_STAGE0)
655 AC_SUBST(CONF_CC_OPTS_STAGE1)
656 AC_SUBST(CONF_CC_OPTS_STAGE2)
657 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
658 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
659 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
660 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
661 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
662 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
663 AC_SUBST(CONF_CPP_OPTS_STAGE0)
664 AC_SUBST(CONF_CPP_OPTS_STAGE1)
665 AC_SUBST(CONF_CPP_OPTS_STAGE2)
666
667 dnl ** Set up the variables for the platform in the settings file.
668 dnl May need to use gcc to find platform details.
669 dnl --------------------------------------------------------------
670 FPTOOLS_SET_HASKELL_PLATFORM_VARS
671
672 dnl ** figure out how to do context diffs
673 FP_PROG_CONTEXT_DIFF
674
675 dnl Let's make sure install-sh is executable here.  If we got it from
676 dnl a darcs repo, it might not be (see bug #978).
677 chmod +x install-sh
678 dnl ** figure out how to do a BSD-ish install
679 AC_PROG_INSTALL
680
681 dnl ** how to invoke `ar' and `ranlib'
682 FP_PROG_AR_SUPPORTS_ATFILE
683 FP_PROG_AR_NEEDS_RANLIB
684
685 dnl ** Check to see whether ln -s works
686 AC_PROG_LN_S
687
688 FP_SETTINGS
689
690 dnl ** Find the path to sed
691 AC_PATH_PROGS(SedCmd,gsed sed,sed)
692
693
694 dnl ** check for time command
695 AC_PATH_PROG(TimeCmd,time)
696
697 dnl ** check for tar
698 dnl   if GNU tar is named gtar, look for it first.
699 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
700
701 dnl ** check for patch
702 dnl if GNU patch is named gpatch, look for it first
703 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
704
705 dnl ** check for dtrace (currently only implemented for Mac OS X)
706 HaveDtrace=NO
707 AC_PATH_PROG(DtraceCmd,dtrace)
708 if test -n "$DtraceCmd"; then
709   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
710     HaveDtrace=YES
711   fi
712 fi
713 AC_SUBST(HaveDtrace)
714
715 AC_PATH_PROG(HSCOLOUR,HsColour)
716 # HsColour is passed to Cabal, so we need a native path
717 if test "$HostOS"      = "mingw32" && \
718    test "${OSTYPE}"   != "msys"    && \
719    test "${HSCOLOUR}" != ""
720 then
721     # Canonicalise to <drive>:/path/to/gcc
722     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
723 fi
724
725 dnl ** check for DocBook toolchain
726 FP_CHECK_DOCBOOK_DTD
727 FP_DOCBOOK_XSL
728 FP_PROG_DBLATEX
729
730 dnl ** check for ghc-pkg command
731 FP_PROG_GHC_PKG
732
733 dnl ** check for installed happy binary + version
734 FPTOOLS_HAPPY
735
736 dnl ** check for installed alex binary + version
737 FPTOOLS_ALEX
738
739 dnl --------------------------------------------------
740 dnl ### program checking section ends here ###
741 dnl --------------------------------------------------
742
743 dnl --------------------------------------------------
744 dnl * Platform header file and syscall feature tests
745 dnl ### checking the state of the local header files and syscalls ###
746
747 dnl ** check for full ANSI header (.h) files
748 AC_HEADER_STDC
749
750 dnl ** Enable large file support.  NB. do this before testing the type of
751 dnl    off_t, because it will affect the result of that test.
752 AC_SYS_LARGEFILE
753
754 dnl ** check for specific header (.h) files that we are interested in
755 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
756
757 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
758 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
759 [[#if HAVE_SYS_PARAM_H
760 # include <sys/param.h>
761 #endif
762 ]])
763
764 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
765 AC_HEADER_TIME
766
767 dnl ** do we have long longs?
768 AC_CHECK_TYPES([long long])
769
770 dnl ** what are the sizes of various types
771 AC_CHECK_SIZEOF(char,               1)
772 AC_CHECK_SIZEOF(double,             8)
773 AC_CHECK_SIZEOF(float,              4)
774 AC_CHECK_SIZEOF(int,                4)
775 AC_CHECK_SIZEOF(long,               4)
776 if test "$ac_cv_type_long_long" = yes; then
777 AC_CHECK_SIZEOF(long long,          8)
778 fi
779 AC_CHECK_SIZEOF(short,              2)
780 AC_CHECK_SIZEOF(unsigned char,      1)
781 AC_CHECK_SIZEOF(unsigned int,       4)
782 AC_CHECK_SIZEOF(unsigned long,      4)
783 if test "$ac_cv_type_long_long" = yes; then
784 AC_CHECK_SIZEOF(unsigned long long, 8)
785 fi
786 AC_CHECK_SIZEOF(unsigned short,     2)
787 AC_CHECK_SIZEOF(void *,             4)
788
789 dnl for use in settings.in
790 WordSize=$ac_cv_sizeof_void_p
791 AC_SUBST(WordSize)
792
793 dnl ** what are alignment constraints on various types
794 FP_CHECK_ALIGNMENT(char)
795 FP_CHECK_ALIGNMENT(double)
796 FP_CHECK_ALIGNMENT(float)
797 FP_CHECK_ALIGNMENT(int)
798 FP_CHECK_ALIGNMENT(long)
799 if test "$ac_cv_type_long_long" = yes; then
800 FP_CHECK_ALIGNMENT(long long)
801 fi
802 FP_CHECK_ALIGNMENT(short)
803 FP_CHECK_ALIGNMENT(unsigned char)
804 FP_CHECK_ALIGNMENT(unsigned int)
805 FP_CHECK_ALIGNMENT(unsigned long)
806 if test "$ac_cv_type_long_long" = yes; then
807 FP_CHECK_ALIGNMENT(unsigned long long)
808 fi
809 FP_CHECK_ALIGNMENT(unsigned short)
810 FP_CHECK_ALIGNMENT(void *)
811
812 FP_CHECK_FUNC([WinExec],
813   [@%:@include <windows.h>], [WinExec("",0)])
814
815 FP_CHECK_FUNC([GetModuleFileName],
816   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
817
818 dnl ** check for more functions
819 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
820 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
821
822 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
823 dnl ** _POSIX_C_SOURCE is defined
824 AC_CHECK_DECLS([ctime_r], , ,
825 [#define _POSIX_SOURCE 1
826 #define _POSIX_C_SOURCE 199506L
827 #include <time.h>])
828
829 dnl ** check for mingwex library
830 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
831 AC_SUBST(HaveLibMingwEx)
832
833 if test $HaveLibMingwEx = YES ; then
834   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
835 fi
836
837 dnl ** check for math library
838 dnl    Keep that check as early as possible.
839 dnl    as we need to know whether we need libm
840 dnl    for math functions or not
841 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
842 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
843 if test $HaveLibM = YES
844 then
845   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
846 fi
847
848 dnl ** check whether this machine has BFD and libiberty installed (used for debugging)
849 dnl    the order of these tests matters: bfd needs libiberty
850 AC_CHECK_LIB(iberty, xmalloc)
851 AC_CHECK_LIB(bfd,    bfd_uncompress_section_contents)
852
853 dnl ################################################################
854 dnl Check for libraries
855 dnl ################################################################
856
857 dnl ** check whether we need -ldl to get dlopen()
858
859 AC_CHECK_LIB(dl, dlopen,
860     [HaveLibDL=YES
861      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
862      LIBS="$LIBS -ldl"],
863     [HaveLibDL=NO])
864 AC_SUBST(HaveLibDL)
865
866 dnl --------------------------------------------------
867 dnl * Miscellaneous feature tests
868 dnl --------------------------------------------------
869
870 dnl ** can we get alloca?
871 AC_FUNC_ALLOCA
872
873 dnl ** working vfork?
874 AC_FUNC_FORK
875
876 dnl ** determine whether or not const works
877 AC_C_CONST
878
879 dnl ** are we big endian?
880 AC_C_BIGENDIAN
881 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
882
883 dnl ** check for leading underscores in symbol names
884 FP_LEADING_UNDERSCORE
885
886 FP_VISIBILITY_HIDDEN
887
888 dnl ** check for librt
889 AC_CHECK_LIB(rt, clock_gettime)
890 AC_CHECK_FUNCS(clock_gettime timer_settime)
891 FP_CHECK_TIMER_CREATE
892
893 dnl ** check for Apple's "interesting" long double compatibility scheme
894 AC_MSG_CHECKING(for printf\$LDBLStub)
895 AC_TRY_LINK_FUNC(printf\$LDBLStub,
896     [
897         AC_MSG_RESULT(yes)
898         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
899             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
900     ],
901     [
902         AC_MSG_RESULT(no)
903         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
904             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
905     ])
906
907 dnl ** check for eventfd which is needed by the I/O manager
908 AC_CHECK_HEADERS([sys/eventfd.h])
909 AC_CHECK_FUNCS([eventfd])
910
911 dnl ** Check for __thread support in the compiler
912 AC_MSG_CHECKING(for __thread support)
913 AC_COMPILE_IFELSE(
914   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
915   [
916    AC_MSG_RESULT(yes)
917    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
918   ],
919   [
920    AC_MSG_RESULT(no)
921    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
922   ])
923
924
925 dnl ** checking for PAPI
926 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
927 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
928 AC_SUBST(HavePapiLib)
929 AC_SUBST(HavePapiHeader)
930
931 AC_CHECK_FUNCS(__mingw_vfprintf)
932
933 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
934    HavePapi=YES
935 else
936    HavePapi=NO
937 fi
938 AC_SUBST(HavePapi)
939
940 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
941    test "$XsltprocCmd" = ""
942 then
943     BUILD_DOCBOOK_HTML=NO
944 else
945     BUILD_DOCBOOK_HTML=YES
946 fi
947 AC_SUBST(BUILD_DOCBOOK_HTML)
948
949 if test "$DblatexCmd" = ""
950 then
951     BUILD_DOCBOOK_PS=NO
952     BUILD_DOCBOOK_PDF=NO
953 else
954     BUILD_DOCBOOK_PS=YES
955     BUILD_DOCBOOK_PDF=YES
956 fi
957 AC_SUBST(BUILD_DOCBOOK_PS)
958 AC_SUBST(BUILD_DOCBOOK_PDF)
959
960 LIBRARY_VERSION(base)
961 LIBRARY_VERSION(Cabal, Cabal/Cabal)
962 LIBRARY_VERSION(ghc-prim)
963 LIBRARY_ghc_VERSION="$ProjectVersion"
964 AC_SUBST(LIBRARY_ghc_VERSION)
965
966 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
967    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
968 fi
969
970 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal settings docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/configure.ac])
971 AC_OUTPUT
972
973 # We got caught by
974 #     http://savannah.gnu.org/bugs/index.php?1516
975 #     $(eval ...) inside conditionals causes errors
976 # with make 3.80, so warn the user if it looks like they're about to
977 # try to use it.
978 # We would use "grep -q" here, but Solaris's grep doesn't support it.
979 checkMake380() {
980     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
981     then
982         echo
983         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
984         echo "This version cannot be used to build GHC."
985         echo "Please use GNU make >= 3.81."
986     fi
987 }
988
989 checkMake380 make
990 checkMake380 gmake
991
992 echo ["
993 ----------------------------------------------------------------------
994 Configure completed successfully.
995
996    Building GHC version  : $ProjectVersion
997
998    Build platform        : $BuildPlatform
999    Host platform         : $HostPlatform
1000    Target platform       : $TargetPlatform
1001 "]
1002
1003 echo ["\
1004    Bootstrapping using   : $WithGhc
1005       which is version   : $GhcVersion
1006 "]
1007
1008 if test "x$CC_LLVM_BACKEND" = "x1"; then
1009     if test "x$CC_CLANG_BACKEND" = "x1"; then
1010         CompilerName="clang        "
1011     else
1012         CompilerName="llvm-gcc     "
1013     fi
1014 else
1015     CompilerName="gcc          "
1016 fi
1017
1018 echo ["\
1019    Using $CompilerName       : $WhatGccIsCalled
1020       which is version       : $GccVersion
1021    Building a cross compiler : $CrossCompiling
1022    cpp       : $HaskellCPPCmd
1023    cpp-flags : $HaskellCPPArgs
1024    ld        : $LdCmd
1025    Happy     : $HappyCmd ($HappyVersion)
1026    Alex      : $AlexCmd ($AlexVersion)
1027    Perl      : $PerlCmd
1028    dblatex   : $DblatexCmd
1029    xsltproc  : $XsltprocCmd
1030
1031    Using LLVM tools
1032       llc   : $LlcCmd
1033       opt   : $OptCmd"]
1034
1035 if test "$HSCOLOUR" = ""; then
1036 echo ["
1037    HsColour was not found; documentation will not contain source links
1038 "]
1039 else
1040 echo ["\
1041    HsColour : $HSCOLOUR
1042 "]
1043 fi
1044
1045 echo ["\
1046    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
1047    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
1048    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
1049
1050 echo ["----------------------------------------------------------------------
1051 "]
1052
1053 echo "\
1054 For a standard build of GHC (fully optimised with profiling), type (g)make.
1055
1056 To make changes to the default build configuration, copy the file
1057 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1058
1059 For more information on how to configure your GHC build, see
1060    http://ghc.haskell.org/trac/ghc/wiki/Building
1061 "