Remove ghc-7.8 `-package-name`-compat handling
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.1], [glasgow-haskell-bugs@haskell.org], [ghc])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands,
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42 FP_PROG_SORT
43
44 dnl ----------------------------------------------------------
45 FP_SETUP_PROJECT_VERSION
46
47 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
48 AC_SUBST([release], [1])
49
50 # First off, a distrib sanity check..
51 AC_CONFIG_SRCDIR([mk/config.mk.in])
52
53 dnl * We require autoconf version 2.60
54 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
55 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
56 dnl Using autoconf 2.59 started to give nonsense like this
57 dnl  #define SIZEOF_CHAR 0
58 dnl recently.
59 AC_PREREQ([2.60])
60
61 # -------------------------------------------------------------------------
62 # Prepare to generate the following header files
63 #
64 #
65 AC_CONFIG_HEADER(mk/config.h)
66
67 # No, semi-sadly, we don't do `--srcdir'...
68 if test x"$srcdir" != 'x.' ; then
69     echo "This configuration does not support the \`--srcdir' option.."
70     exit 1
71 fi
72
73 dnl --------------------------------------------------------------
74 dnl * Project specific configuration options
75 dnl --------------------------------------------------------------
76 dnl What follows is a bunch of options that can either be configured
77 dnl through command line options to the configure script or by
78 dnl supplying defns in the build tree's mk/build.mk. Having the option to
79 dnl use either is considered a Feature.
80
81 dnl ** What command to use to compile compiler sources ?
82 dnl --------------------------------------------------------------
83
84 AC_ARG_WITH([ghc],
85 [AC_HELP_STRING([--with-ghc=ARG],
86   [Use ARG as the path to GHC  [default=autodetect]])],
87   [WithGhc="$withval"],
88   [if test "$GHC" = ""; then
89     AC_PATH_PROG([GHC], [ghc])
90   fi
91   WithGhc="$GHC"])
92
93 dnl ** Tell the make system which OS we are using
94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
95 AC_SUBST(OSTYPE)
96
97 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
98 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
99                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
100         EnableBootstrapWithDevelSnaphost=YES,
101         EnableBootstrapWithDevelSnaphost=NO
102 )
103
104 AC_ARG_ENABLE(tarballs-autodownload,
105 [AC_HELP_STRING([--enable-tarballs-autodownload],
106                 [Automatically download Windows distribution binaries if needed.])],
107         TarballsAutodownload=YES,
108         TarballsAutodownload=NO
109 )
110 if test "$WithGhc" != ""; then
111   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
112
113   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
114      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
115   fi
116
117   AC_SUBST(GhcVersion)dnl
118   AC_SUBST(GhcMajVersion)dnl
119   AC_SUBST(GhcMinVersion)dnl
120   AC_SUBST(GhcPatchLevel)dnl
121   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
122   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
123
124   BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
125   dnl ToDo, once "ld command" is reliably available.
126   dnl Then, we can remove the LD_STAGE0 hack in mk/build-package-date.mk
127   dnl BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
128   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
129   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
130   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
131 fi
132
133 dnl ** Must have GHC to build GHC
134 if test "$WithGhc" = ""
135 then
136     AC_MSG_ERROR([GHC is required.])
137 fi
138 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.10],
139     [AC_MSG_ERROR([GHC version 7.10 or later is required to compile GHC.])])
140
141 if test `expr $GhcMinVersion % 2` = "1"
142 then
143     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
144     then
145         AC_MSG_ERROR([
146      $WithGhc is a development snapshot of GHC, version $GhcVersion.
147      Bootstrapping using this version of GHC is not supported, and may not
148      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
149      or --with-ghc to specify a different GHC to use.])
150     fi
151 fi
152
153 GHC_PACKAGE_DB_FLAG=package-db
154 AC_SUBST(GHC_PACKAGE_DB_FLAG)
155
156 # GHC 7.7+ needs -fcmm-sink when compiling Parser.hs. See #8182
157 FP_COMPARE_VERSIONS([$GhcVersion],[-gt],[7.7],
158                     CMM_SINK_BOOTSTRAP_IS_NEEDED=YES,
159                     CMM_SINK_BOOTSTRAP_IS_NEEDED=NO)
160 AC_SUBST(CMM_SINK_BOOTSTRAP_IS_NEEDED)
161
162 # GHC is passed to Cabal, so we need a native path
163 if test "${WithGhc}" != ""
164 then
165     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
166
167     if test "$ghc_host_os" = "mingw32"
168     then
169         if test "${OSTYPE}" = "msys"
170         then
171             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
172         else
173             # Canonicalise to <drive>:/path/to/ghc
174             WithGhc=`cygpath -m "${WithGhc}"`
175         fi
176         echo "GHC path canonicalised to: ${WithGhc}"
177     fi
178 fi
179 AC_SUBST([WithGhc])
180
181 dnl ** Without optimization some INLINE trickery fails for GHCi
182 SRC_CC_OPTS="-O"
183
184 dnl--------------------------------------------------------------------
185 dnl * Choose host(/target/build) platform
186 dnl--------------------------------------------------------------------
187 dnl If we aren't explicitly told what values to use with configure flags,
188 dnl we ask the bootstrapping compiler what platform it is for
189
190 if test "${WithGhc}" != ""
191 then
192         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
193         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
194         if test "$bootstrap_host" != "$bootstrap_target"
195         then
196                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
197         fi
198 fi
199
200 # We have to run these unconditionally, but we may discard their
201 # results in the following code
202 AC_CANONICAL_BUILD
203 AC_CANONICAL_HOST
204 AC_CANONICAL_TARGET
205
206 FPTOOLS_SET_PLATFORM_VARS
207
208 # Verify that the installed (bootstrap) GHC is capable of generating
209 # code for the requested build platform.
210 if test "$BuildPlatform" != "$bootstrap_target"
211 then
212     echo "This GHC (${WithGhc}) does not generate code for the build platform"
213     echo "   GHC target platform    : $bootstrap_target"
214     echo "   Desired build platform : $BuildPlatform"
215     exit 1
216 fi
217
218 # Testing if we shall enable shared libs support on Solaris.
219 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
220
221 SOLARIS_BROKEN_SHLD=NO
222
223 case $host in
224      i386-*-solaris2)
225      # here we go with the test
226      MINOR=`uname -r|cut -d '.' -f 2-`
227      if test "$MINOR" -lt "11"; then
228          SOLARIS_BROKEN_SHLD=YES
229      fi
230      ;;
231 esac
232
233 AC_SUBST(SOLARIS_BROKEN_SHLD)
234
235 dnl ** Do an unregisterised build?
236 dnl --------------------------------------------------------------
237 case "$HostArch" in
238     i386|x86_64|powerpc|powerpc64|powerpc64le|arm)
239         UnregisterisedDefault=NO
240         ;;
241     *)
242         UnregisterisedDefault=YES
243         ;;
244 esac
245 AC_ARG_ENABLE(unregisterised,
246 [AC_HELP_STRING([--enable-unregisterised],
247 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
248 [ if test x"$enableval" = x"yes"; then
249         Unregisterised=YES
250   else
251         Unregisterised=NO
252   fi
253 ],
254 [Unregisterised="$UnregisterisedDefault"]
255 )
256 AC_SUBST(Unregisterised)
257
258 AC_ARG_WITH(hc,
259 [AC_HELP_STRING([--with-hc=ARG],
260         [Use ARG as the path to the compiler for compiling ordinary
261          Haskell code  (default= value of --with-ghc)])],
262 [WithHc="$withval"],
263 [WithHc=$WithGhc]
264 )
265 AC_SUBST(WithHc)
266
267 # This uses GHC, so put it after the "GHC is required" check above:
268 FP_INTREE_GHC_PWD
269 FP_FIND_ROOT
270
271 fail() {
272     echo >&2
273     echo "$1" >&2
274     exit 1
275 }
276
277
278 if test "$HostOS" = "mingw32"
279 then
280     # Find the mingw-w64 7z file to extract.
281     # NB. If you update the tarballs to a new version of gcc, don't
282     # forget to tweak the paths in driver/gcc/gcc.c.
283     if test "$HostArch" = "i386"
284     then
285         mingw_arch="i686"
286         tarball_dest_dir="mingw-w64/x86"
287         tarball_mingw_dir="mingw32"
288     else
289         mingw_arch="x86_64"
290         tarball_dest_dir="mingw-w64/x86_64"
291         tarball_mingw_dir="mingw64"
292     fi
293 fi
294
295 set_up_tarballs() {
296     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
297     local action
298     if test "$TarballsAutodownload" = "NO"
299     then
300         action="verify"
301     else
302         action="download"
303     fi
304     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
305     case $? in
306         0)
307            rm missing-win32-tarballs
308            ;;
309         2)
310            echo
311            echo "Error:"
312            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
313            echo
314            echo "  * run configure with the --enable-tarballs-autodownload option"
315            echo
316            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
317            echo
318            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
319            echo "    them in the ghc-tarballs directory."
320            echo
321            exit 1
322            ;;
323         *)
324            echo
325            echo "Error fetching msys2 tarballs; see errors above."
326            exit 1
327            ;;
328     esac
329
330     # Extract all the tarballs in one go
331     if ! test -d inplace/mingw
332     then
333         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
334         rm -rf inplace/mingw
335         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
336         ( cd inplace &&
337         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
338         rm ".MTREE" &&
339         rm ".PKGINFO" &&
340         cd .. ) || fail "Error: Could not extract Windows toolchains."
341
342         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
343         touch inplace/mingw
344
345         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
346         # make a wrapper around it to give it the proper paths
347         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
348         PATH=`pwd`/inplace/mingw/bin:$PATH
349         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
350
351         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
352     fi
353 }
354
355 if test "$HostOS" = "mingw32"
356 then
357     test -d inplace || mkdir inplace
358
359     # NB. Download and extract the MingW-w64 distribution if required
360     set_up_tarballs
361
362     mingwbin="$hardtop/inplace/mingw/bin/"
363     CC="${mingwbin}gcc.exe"
364     LD="${mingwbin}ld.exe"
365     NM="${mingwbin}nm.exe"
366     RANLIB="${mingwbin}ranlib.exe"
367     OBJDUMP="${mingwbin}objdump.exe"
368     fp_prog_ar="${mingwbin}ar.exe"
369
370     # NB. Download the perl binaries if required
371     if ! test -d inplace/perl ||
372          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
373     then
374         AC_MSG_NOTICE([Making in-tree perl tree])
375         rm -rf inplace/perl
376         mkdir inplace/perl
377         (
378             cd inplace/perl &&
379             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
380         )
381         AC_MSG_NOTICE([In-tree perl tree created])
382     fi
383 fi
384
385 FP_ICONV
386 FP_GMP
387 FP_CURSES
388
389 XCODE_VERSION()
390
391 SplitObjsBroken=NO
392 if test "$TargetOS_CPP" = "darwin"
393 then
394     # Split objects is broken (#4013) with XCode < 3.2
395     if test "$XCodeVersion1" -lt 3
396     then
397         SplitObjsBroken=YES
398     else
399         if test "$XCodeVersion1" -eq 3
400         then
401             if test "$XCodeVersion2" -lt 2
402             then
403                 SplitObjsBroken=YES
404             fi
405         fi
406     fi
407 fi
408 AC_SUBST([SplitObjsBroken])
409
410 dnl ** Building a cross compiler?
411 dnl --------------------------------------------------------------
412 CrossCompiling=NO
413 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
414 if test "$target" != "$host" ; then
415     CrossCompiling=YES
416     cross_compiling=yes   # This tells configure that it can accept just 'target',
417                           # otherwise you get
418                           #   configure: error: cannot run C compiled programs.
419                           #   If you meant to cross compile, use `--host'.
420 fi
421 if test "$build" != "$host" ; then
422    AC_MSG_ERROR([
423 You've selected:
424
425   BUILD:  $build   (the architecture we're building on)
426   HOST:   $host    (the architecture the compiler we're building will execute on)
427   TARGET: $target  (the architecture the compiler we're building will produce code for)
428
429 BUILD must equal HOST; that is, we do not support building GHC itself
430 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
431 1 will be a cross-compiler, and stage 2 will be the cross-compiled
432 GHC.
433 ])
434 fi
435 if test "$CrossCompiling" = "YES"
436 then
437   CrossCompilePrefix="${target}-"
438 else
439   CrossCompilePrefix=""
440 fi
441 TargetPlatformFull="${target}"
442 AC_SUBST(CrossCompiling)
443 AC_SUBST(CrossCompilePrefix)
444 AC_SUBST(TargetPlatformFull)
445
446 dnl ** Which gcc to use?
447 dnl --------------------------------------------------------------
448 FIND_GCC([WhatGccIsCalled], [gcc], [gcc])
449 CC="$WhatGccIsCalled"
450 export CC
451
452 # If --with-gcc was used, and we're not cross-compiling, then it also
453 # applies to the stage0 compiler.
454 MAYBE_OVERRIDE_STAGE0([gcc],[CC_STAGE0])
455 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
456
457 dnl make extensions visible to allow feature-tests to detect them lateron
458 AC_USE_SYSTEM_EXTENSIONS
459
460 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
461 AC_PROG_CPP
462
463 # --with-hs-cpp/--with-hs-cpp-flags
464 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
465 AC_SUBST([HaskellCPPCmd])
466 AC_SUBST([HaskellCPPArgs])
467
468 dnl ** Which ld to use?
469 dnl --------------------------------------------------------------
470 FIND_LD([LdCmd])
471 AC_SUBST([LdCmd])
472
473 dnl ** Which nm to use?
474 dnl --------------------------------------------------------------
475 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
476 NmCmd="$NM"
477 AC_SUBST([NmCmd])
478
479 dnl ** Which objdump to use?
480 dnl --------------------------------------------------------------
481 FP_ARG_WITH_PATH_GNU_PROG_OPTIONAL([OBJDUMP], [objdump], [objdump])
482 ObjdumpCmd="$OBJDUMP"
483 AC_SUBST([ObjdumpCmd])
484
485 dnl ** Which ar to use?
486 dnl --------------------------------------------------------------
487 FP_ARG_WITH_PATH_GNU_PROG([AR], [ar], [ar])
488 ArCmd="$AR"
489 fp_prog_ar="$AR"
490 AC_SUBST([ArCmd])
491
492 dnl ** Which ranlib to use?
493 dnl --------------------------------------------------------------
494 FP_ARG_WITH_PATH_GNU_PROG([RANLIB], [ranlib], [ranlib])
495 RanlibCmd="$RANLIB"
496 RANLIB="$RanlibCmd"
497
498
499 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
500 case $HostOS_CPP in
501 cygwin32|mingw32)
502     dnl ** Which objdump to use?
503     dnl --------------------------------------------------------------
504     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
505     ObjdumpCmd="$OBJDUMP"
506     AC_SUBST([ObjdumpCmd])
507     ;;
508 esac
509
510 # Here is where we re-target which specific version of the LLVM
511 # tools we are looking for. In the past, GHC supported a number of
512 # versions of LLVM simultaneously, but that stopped working around
513 # 3.5/3.6 release of LLVM.
514 LlvmVersion=3.7
515 AC_SUBST([LlvmVersion])
516 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
517 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
518
519 dnl ** Which LLVM llc to use?
520 dnl --------------------------------------------------------------
521 FIND_LLVM_PROG([LLC], [llc], [llc], [$LlvmVersion])
522 LlcCmd="$LLC"
523 AC_SUBST([LlcCmd])
524
525 dnl ** Which LLVM opt to use?
526 dnl --------------------------------------------------------------
527 FIND_LLVM_PROG([OPT], [opt], [opt], [$LlvmVersion])
528 OptCmd="$OPT"
529 AC_SUBST([OptCmd])
530
531 dnl --------------------------------------------------------------
532 dnl End of configure script option section
533 dnl --------------------------------------------------------------
534
535
536 dnl --------------------------------------------------------------
537 dnl * General configuration checks
538 dnl --------------------------------------------------------------
539
540 dnl ** Bug 9439: Some GHC 7.8 releases had broken LLVM code generator.
541 dnl Unfortunately we don't know whether the user is going to request a
542 dnl build with the LLVM backend as this is only given in build.mk.
543 dnl
544 dnl Instead, we try to do as much work as possible here, checking
545 dnl whether -fllvm is the stage 0 compiler's default. If so we
546 dnl fail. If not, we check whether -fllvm is affected explicitly and
547 dnl if so set a flag. The build system will later check this flag
548 dnl after the desired build flags are known.
549
550 dnl This problem is further complicated by the fact that the llvm
551 dnl version used by the bootstrap compiler may be different from the
552 dnl version we arre trying to compile GHC against. Therefore, we need
553 dnl to find the boostrap compiler's `settings` file then check to see
554 dnl if the `opt` and `llc` command strings are non-empty and if these
555 dnl programs exist. Only if they exist to we test for bug #9439.
556
557 FIND_GHC_BOOTSTRAP_PROG([BootstrapLlcCmd], [${WithGhc}], "LLVM llc command")
558 FIND_GHC_BOOTSTRAP_PROG([BootstrapOptCmd], [${WithGhc}], "LLVM opt command")
559
560 if test -n "$BootstrapLlcCmd" && test -n "$BootstrapOptCmd"
561 then
562     AC_MSG_CHECKING(whether bootstrap compiler is affected by bug 9439)
563     echo "main = putStrLn \"%function\"" > conftestghc.hs
564
565     # Check whether LLVM backend is default for this platform
566     "${WithGhc}" -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" conftestghc.hs 2>&1 >/dev/null
567     res=`./conftestghc`
568     if test "x$res" = "x%object"
569     then
570         AC_MSG_RESULT(yes)
571         echo "Buggy bootstrap compiler"
572         echo ""
573         echo "The stage 0 compiler $WithGhc is affected by GHC Bug \#9439"
574         echo "and therefore will miscompile the LLVM backend if -fllvm is"
575         echo "used."
576         echo
577         echo "Please use another bootstrap compiler"
578         exit 1
579     fi
580
581     # -fllvm is not the default, but set a flag so the Makefile can check
582     # -for it in the build flags later on
583     "${WithGhc}" -fforce-recomp -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" -fllvm conftestghc.hs 2>&1 >/dev/null
584     if test $? = 0
585     then
586         res=`./conftestghc`
587         if test "x$res" = "x%object"
588         then
589             AC_MSG_RESULT(yes)
590             GHC_LLVM_AFFECTED_BY_9439=1
591         elif test "x$res" = "x%function"
592         then
593             AC_MSG_RESULT(no)
594             GHC_LLVM_AFFECTED_BY_9439=0
595         else
596             AC_MSG_WARN(unexpected output $res)
597         fi
598     else
599         AC_MSG_RESULT(failed to compile, assuming no)
600     fi
601 fi
602 AC_SUBST([GHC_LLVM_AFFECTED_BY_9439])
603
604 dnl ** Can the unix package be built?
605 dnl --------------------------------------------------------------
606
607 if test "$TargetOS" = "mingw32"
608 then
609     GhcLibsWithUnix=NO
610 else
611     GhcLibsWithUnix=YES
612 fi
613 AC_SUBST([GhcLibsWithUnix])
614
615 dnl ** does #! work?
616 AC_SYS_INTERPRETER()
617
618 dnl ** look for `perl'
619 case $HostOS_CPP in
620 cygwin32|mingw32)
621     PerlCmd=$hardtop/inplace/perl/perl
622     ;;
623 *)
624     AC_PATH_PROG(PerlCmd,perl)
625     if test -z "$PerlCmd"
626     then
627         echo "You must install perl before you can continue"
628         echo "Perhaps it is already installed, but not in your PATH?"
629         exit 1
630     else
631         FPTOOLS_CHECK_PERL_VERSION
632     fi
633     ;;
634 esac
635
636 dnl ** look for GCC and find out which version
637 dnl     Figure out which C compiler to use.  Gcc is preferred.
638 dnl     If gcc, make sure it's at least 3.0
639 dnl
640 FP_GCC_VERSION
641
642 dnl ** look to see if we have a C compiler using an llvm back end.
643 dnl
644 FP_CC_LLVM_BACKEND
645
646 FP_PROG_LD_IS_GNU
647 FP_PROG_LD_BUILD_ID
648 FP_PROG_LD_NO_COMPACT_UNWIND
649 FP_PROG_LD_FILELIST
650
651
652 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
653 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
654 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
655 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
656 # Stage 3 won't be supported by cross-compilation
657
658 FP_GCC_EXTRA_FLAGS
659
660 AC_SUBST(CONF_CC_OPTS_STAGE0)
661 AC_SUBST(CONF_CC_OPTS_STAGE1)
662 AC_SUBST(CONF_CC_OPTS_STAGE2)
663 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
664 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
665 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
666 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
667 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
668 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
669 AC_SUBST(CONF_CPP_OPTS_STAGE0)
670 AC_SUBST(CONF_CPP_OPTS_STAGE1)
671 AC_SUBST(CONF_CPP_OPTS_STAGE2)
672
673 dnl ** Set up the variables for the platform in the settings file.
674 dnl May need to use gcc to find platform details.
675 dnl --------------------------------------------------------------
676 FPTOOLS_SET_HASKELL_PLATFORM_VARS
677
678 dnl ** figure out how to do context diffs
679 FP_PROG_CONTEXT_DIFF
680
681 dnl Let's make sure install-sh is executable here.  If we got it from
682 dnl a darcs repo, it might not be (see bug #978).
683 chmod +x install-sh
684 dnl ** figure out how to do a BSD-ish install
685 AC_PROG_INSTALL
686
687 dnl ** how to invoke `ar' and `ranlib'
688 FP_PROG_AR_SUPPORTS_ATFILE
689 FP_PROG_AR_NEEDS_RANLIB
690
691 dnl ** Check to see whether ln -s works
692 AC_PROG_LN_S
693
694 FP_SETTINGS
695
696 dnl ** Find the path to sed
697 AC_PATH_PROGS(SedCmd,gsed sed,sed)
698
699
700 dnl ** check for time command
701 AC_PATH_PROG(TimeCmd,time)
702
703 dnl ** check for tar
704 dnl   if GNU tar is named gtar, look for it first.
705 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
706
707 dnl ** check for patch
708 dnl if GNU patch is named gpatch, look for it first
709 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
710
711 dnl ** check for dtrace (currently only implemented for Mac OS X)
712 HaveDtrace=NO
713 AC_PATH_PROG(DtraceCmd,dtrace)
714 if test -n "$DtraceCmd"; then
715   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
716     HaveDtrace=YES
717   fi
718 fi
719 AC_SUBST(HaveDtrace)
720
721 AC_PATH_PROG(HSCOLOUR,HsColour)
722 # HsColour is passed to Cabal, so we need a native path
723 if test "$HostOS"      = "mingw32" && \
724    test "${OSTYPE}"   != "msys"    && \
725    test "${HSCOLOUR}" != ""
726 then
727     # Canonicalise to <drive>:/path/to/gcc
728     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
729 fi
730
731 dnl ** check for Sphinx toolchain
732 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
733 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
734 changequote(, )dnl
735 [if test -n "$SPHINXBUILD"; then
736   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
737 fi;
738 changequote([, ])dnl
739 ])
740 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
741     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
742
743 dnl ** check for xelatex
744 AC_PATH_PROG(XELATEX,xelatex)
745
746 dnl ** check for ghc-pkg command
747 FP_PROG_GHC_PKG
748
749 dnl ** check for installed happy binary + version
750 FPTOOLS_HAPPY
751
752 dnl ** check for installed alex binary + version
753 FPTOOLS_ALEX
754
755 dnl --------------------------------------------------
756 dnl ### program checking section ends here ###
757 dnl --------------------------------------------------
758
759 dnl --------------------------------------------------
760 dnl * Platform header file and syscall feature tests
761 dnl ### checking the state of the local header files and syscalls ###
762
763 dnl ** check for full ANSI header (.h) files
764 AC_HEADER_STDC
765
766 dnl ** Enable large file support.  NB. do this before testing the type of
767 dnl    off_t, because it will affect the result of that test.
768 AC_SYS_LARGEFILE
769
770 dnl ** check for specific header (.h) files that we are interested in
771 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
772
773 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
774 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
775 [[#if HAVE_SYS_PARAM_H
776 # include <sys/param.h>
777 #endif
778 ]])
779
780 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
781 AC_HEADER_TIME
782
783 dnl ** do we have long longs?
784 AC_CHECK_TYPES([long long])
785
786 dnl ** what are the sizes of various types
787 AC_CHECK_SIZEOF(char,               1)
788 AC_CHECK_SIZEOF(double,             8)
789 AC_CHECK_SIZEOF(float,              4)
790 AC_CHECK_SIZEOF(int,                4)
791 AC_CHECK_SIZEOF(long,               4)
792 if test "$ac_cv_type_long_long" = yes; then
793 AC_CHECK_SIZEOF(long long,          8)
794 fi
795 AC_CHECK_SIZEOF(short,              2)
796 AC_CHECK_SIZEOF(unsigned char,      1)
797 AC_CHECK_SIZEOF(unsigned int,       4)
798 AC_CHECK_SIZEOF(unsigned long,      4)
799 if test "$ac_cv_type_long_long" = yes; then
800 AC_CHECK_SIZEOF(unsigned long long, 8)
801 fi
802 AC_CHECK_SIZEOF(unsigned short,     2)
803 AC_CHECK_SIZEOF(void *,             4)
804
805 dnl for use in settings.in
806 WordSize=$ac_cv_sizeof_void_p
807 AC_SUBST(WordSize)
808
809 dnl ** what are alignment constraints on various types
810 FP_CHECK_ALIGNMENT(char)
811 FP_CHECK_ALIGNMENT(double)
812 FP_CHECK_ALIGNMENT(float)
813 FP_CHECK_ALIGNMENT(int)
814 FP_CHECK_ALIGNMENT(long)
815 if test "$ac_cv_type_long_long" = yes; then
816 FP_CHECK_ALIGNMENT(long long)
817 fi
818 FP_CHECK_ALIGNMENT(short)
819 FP_CHECK_ALIGNMENT(unsigned char)
820 FP_CHECK_ALIGNMENT(unsigned int)
821 FP_CHECK_ALIGNMENT(unsigned long)
822 if test "$ac_cv_type_long_long" = yes; then
823 FP_CHECK_ALIGNMENT(unsigned long long)
824 fi
825 FP_CHECK_ALIGNMENT(unsigned short)
826 FP_CHECK_ALIGNMENT(void *)
827
828 FP_CHECK_FUNC([WinExec],
829   [@%:@include <windows.h>], [WinExec("",0)])
830
831 FP_CHECK_FUNC([GetModuleFileName],
832   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
833
834 dnl ** check for more functions
835 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
836 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
837
838 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
839 dnl ** _POSIX_C_SOURCE is defined
840 AC_CHECK_DECLS([ctime_r], , ,
841 [#define _POSIX_SOURCE 1
842 #define _POSIX_C_SOURCE 199506L
843 #include <time.h>])
844
845 dnl ** check for mingwex library
846 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
847 AC_SUBST(HaveLibMingwEx)
848
849 if test $HaveLibMingwEx = YES ; then
850   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
851 fi
852
853 dnl ** check for math library
854 dnl    Keep that check as early as possible.
855 dnl    as we need to know whether we need libm
856 dnl    for math functions or not
857 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
858 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
859 if test $HaveLibM = YES
860 then
861   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
862 fi
863
864 FP_BFD_SUPPORT
865
866 dnl ################################################################
867 dnl Check for libraries
868 dnl ################################################################
869
870 # system libffi
871
872 AC_ARG_WITH([system-libffi],
873 [AC_HELP_STRING([--with-system-libffi],
874   [Use system provided libffi for RTS [default=no]])
875 ])
876
877 AS_IF([test "x$with_system_libffi" = "xyes"],
878   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
879 )
880
881
882 AC_SUBST(UseSystemLibFFI)
883
884 AC_ARG_WITH([ffi-includes],
885 [AC_HELP_STRING([--with-ffi-includes=ARG],
886   [Find includes for libffi in ARG [default=system default]])
887 ],
888 [
889  if test "x$UseSystemLibFFI" != "xYES"; then
890     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
891  else
892     FFIIncludeDir="$withval"
893     LIBFFI_CFLAGS="-I$withval"
894  fi
895 ])
896
897 AC_SUBST(FFIIncludeDir)
898
899 AC_ARG_WITH([ffi-libraries],
900 [AC_HELP_STRING([--with-ffi-libraries=ARG],
901   [Find libffi in ARG [default=system default]])
902 ],
903 [
904  if test "x$UseSystemLibFFI" != "xYES"; then
905     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
906  else
907     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
908  fi
909 ])
910
911 AC_SUBST(FFILibDir)
912
913 AS_IF([test "$UseSystemLibFFI" = "YES"], [
914  CFLAGS2="$CFLAGS"
915  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
916  LDFLAGS2="$LDFLAGS"
917  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
918  if test "$HostOS" = "openbsd";
919  then
920    # OpenBSD's libffi is not directly linked to the libpthread but
921    # still requires pthread functionality. This means that any client
922    # binary which links with libffi also needs to link with
923    # libpthread. If it does not, then linking fails with unresolved
924    # symbols.
925    LDFLAGS="$LDFLAGS -lpthread"
926  fi
927  AC_CHECK_LIB(ffi, ffi_call,
928   [AC_CHECK_HEADERS([ffi.h], [break], [])
929    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
930   [AC_MSG_ERROR([Cannot find system libffi])])
931  CFLAGS="$CFLAGS2"
932  LDFLAGS="$LDFLAGS2"
933 ])
934
935 dnl ** check whether we need -ldl to get dlopen()
936 AC_CHECK_LIB(dl, dlopen)
937
938 dnl --------------------------------------------------
939 dnl * Miscellaneous feature tests
940 dnl --------------------------------------------------
941
942 dnl ** can we get alloca?
943 AC_FUNC_ALLOCA
944
945 dnl ** working vfork?
946 AC_FUNC_FORK
947
948 dnl ** determine whether or not const works
949 AC_C_CONST
950
951 dnl ** are we big endian?
952 AC_C_BIGENDIAN
953 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
954
955 dnl ** check for leading underscores in symbol names
956 FP_LEADING_UNDERSCORE
957
958 FP_VISIBILITY_HIDDEN
959
960 dnl ** check for librt
961 AC_CHECK_LIB(rt, clock_gettime)
962 AC_CHECK_FUNCS(clock_gettime timer_settime)
963 FP_CHECK_TIMER_CREATE
964
965 dnl ** check for Apple's "interesting" long double compatibility scheme
966 AC_MSG_CHECKING(for printf\$LDBLStub)
967 AC_TRY_LINK_FUNC(printf\$LDBLStub,
968     [
969         AC_MSG_RESULT(yes)
970         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
971             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
972     ],
973     [
974         AC_MSG_RESULT(no)
975         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
976             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
977     ])
978
979 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
980 dnl    a different single-argument version.
981 AC_CHECK_LIB(pthread, pthread_setname_np)
982 AC_MSG_CHECKING(for pthread_setname_np)
983 AC_TRY_LINK(
984 [
985 #define _GNU_SOURCE
986 #include <pthread.h>
987 ],
988 [pthread_setname_np(pthread_self(), "name");],
989     AC_MSG_RESULT(yes)
990     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
991       [Define to 1 if you have the glibc version of pthread_setname_np]),
992     AC_MSG_RESULT(no)
993 )
994
995 dnl ** check for eventfd which is needed by the I/O manager
996 AC_CHECK_HEADERS([sys/eventfd.h])
997 AC_CHECK_FUNCS([eventfd])
998
999 dnl ** Check for __thread support in the compiler
1000 AC_MSG_CHECKING(for __thread support)
1001 AC_COMPILE_IFELSE(
1002   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
1003   [
1004    AC_MSG_RESULT(yes)
1005    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1006   ],
1007   [
1008    AC_MSG_RESULT(no)
1009    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1010   ])
1011
1012
1013 AC_CHECK_FUNCS(__mingw_vfprintf)
1014
1015 dnl large address space support (see includes/rts/storage/MBlock.h)
1016 dnl
1017 dnl Darwin has vm_allocate/vm_protect
1018 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1019 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1020 dnl (They also have MADV_DONTNEED, but it means something else!)
1021 dnl
1022 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1023 dnl it counts page-table space as committed memory, and so quickly
1024 dnl runs out of paging file when we have multiple processes reserving
1025 dnl 1TB of address space, we get the following error:
1026 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1027 dnl
1028
1029 AC_ARG_ENABLE(large-address-space,
1030     [AC_HELP_STRING([--enable-large-address-space],
1031         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1032     EnableLargeAddressSpace=$enableval,
1033     EnableLargeAddressSpace=yes
1034 )
1035
1036 use_large_address_space=no
1037 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1038     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1039         if test "$ghc_host_os" = "darwin" ; then
1040             use_large_address_space=yes
1041         elif test "$ghc_host_os" = "openbsd" ; then
1042             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1043             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1044             # but is completely ignored by OS mmap
1045             use_large_address_space=no
1046         else
1047             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1048                 [
1049                 #include <unistd.h>
1050                 #include <sys/types.h>
1051                 #include <sys/mman.h>
1052                 #include <fcntl.h>
1053             ])
1054             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1055                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1056                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1057                     use_large_address_space=yes
1058             fi
1059         fi
1060     fi
1061 fi
1062 if test "$use_large_address_space" = "yes" ; then
1063    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1064 fi
1065
1066 AC_CHECK_LIB(dw, dwfl_begin, [HaveLibdw=YES], [HaveLibdw=NO])
1067 AC_SUBST(HaveLibdw)
1068
1069 if test -n "$SPHINXBUILD"; then
1070     BUILD_MAN=YES
1071     BUILD_SPHINX_HTML=YES
1072     if test -n "$XELATEX"; then
1073         BUILD_SPHINX_PDF=YES
1074     else
1075         BUILD_SPHINX_PDF=NO
1076     fi
1077 else
1078     BUILD_MAN=NO
1079     BUILD_SPHINX_HTML=NO
1080     BUILD_SPHINX_PDF=NO
1081 fi
1082 AC_SUBST(BUILD_MAN)
1083 AC_SUBST(BUILD_SPHINX_HTML)
1084 AC_SUBST(BUILD_SPHINX_PDF)
1085
1086 LIBRARY_VERSION(base)
1087 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1088 LIBRARY_VERSION(ghc-prim)
1089 LIBRARY_ghc_VERSION="$ProjectVersion"
1090 AC_SUBST(LIBRARY_ghc_VERSION)
1091
1092 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1093    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1094 fi
1095
1096 # Create the configuration for the Shake-based build system if it is present
1097 if test -e shake-build/cfg/system.config.in; then
1098     AC_CONFIG_FILES([shake-build/cfg/system.config])
1099 fi
1100
1101 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt distrib/configure.ac])
1102 AC_OUTPUT
1103
1104 # We got caught by
1105 #     http://savannah.gnu.org/bugs/index.php?1516
1106 #     $(eval ...) inside conditionals causes errors
1107 # with make 3.80, so warn the user if it looks like they're about to
1108 # try to use it.
1109 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1110 checkMake380() {
1111     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
1112     then
1113         echo
1114         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
1115         echo "This version cannot be used to build GHC."
1116         echo "Please use GNU make >= 3.81."
1117     fi
1118 }
1119
1120 checkMake380 make
1121 checkMake380 gmake
1122
1123 echo ["
1124 ----------------------------------------------------------------------
1125 Configure completed successfully.
1126
1127    Building GHC version  : $ProjectVersion
1128           Git commit id  : $ProjectGitCommitId
1129
1130    Build platform        : $BuildPlatform
1131    Host platform         : $HostPlatform
1132    Target platform       : $TargetPlatform
1133 "]
1134
1135 echo ["\
1136    Bootstrapping using   : $WithGhc
1137       which is version   : $GhcVersion
1138 "]
1139
1140 if test "x$CC_LLVM_BACKEND" = "x1"; then
1141     if test "x$CC_CLANG_BACKEND" = "x1"; then
1142         CompilerName="clang        "
1143     else
1144         CompilerName="llvm-gcc     "
1145     fi
1146 else
1147     CompilerName="gcc          "
1148 fi
1149
1150 echo ["\
1151    Using $CompilerName       : $WhatGccIsCalled
1152       which is version       : $GccVersion
1153    Building a cross compiler : $CrossCompiling
1154    hs-cpp       : $HaskellCPPCmd
1155    hs-cpp-flags : $HaskellCPPArgs
1156    ld           : $LdCmd
1157    nm           : $NmCmd
1158    objdump      : $ObjdumpCmd
1159    Happy        : $HappyCmd ($HappyVersion)
1160    Alex         : $AlexCmd ($AlexVersion)
1161    Perl         : $PerlCmd
1162    sphinx-build : $SPHINXBUILD
1163    xelatex      : $XELATEX
1164
1165    Using LLVM tools
1166       llc   : $LlcCmd
1167       opt   : $OptCmd"]
1168
1169 if test "$HSCOLOUR" = ""; then
1170 echo ["
1171    HsColour was not found; documentation will not contain source links
1172 "]
1173 else
1174 echo ["\
1175    HsColour : $HSCOLOUR
1176 "]
1177 fi
1178
1179 echo ["\
1180    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1181    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"]
1182
1183 echo ["----------------------------------------------------------------------
1184 "]
1185
1186 echo "\
1187 For a standard build of GHC (fully optimised with profiling), type (g)make.
1188
1189 To make changes to the default build configuration, copy the file
1190 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1191
1192 For more information on how to configure your GHC build, see
1193    http://ghc.haskell.org/trac/ghc/wiki/Building
1194 "