Merge branch 'master' of http://darcs.haskell.org/ghc
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2004
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.3], [glasgow-haskell-bugs@haskell.org], [ghc])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 6.7.20070204).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # darcs repository.  If this is a source distribution (not a darcs
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands, 
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42
43 dnl ** Find sort command (for the benefit of Win32 environs)
44 FP_PROG_SORT
45
46 dnl ----------------------------------------------------------
47 FP_SETUP_PROJECT_VERSION
48
49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
50 AC_SUBST([release], [1])
51
52 # First off, a distrib sanity check..
53 AC_CONFIG_SRCDIR([mk/config.mk.in])
54
55 dnl * We require autoconf version 2.52
56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
58 AC_PREREQ([2.52])
59
60 # -------------------------------------------------------------------------
61 # Prepare to generate the following header files
62 #
63 #
64 AC_CONFIG_HEADER(mk/config.h)
65
66 # No, semi-sadly, we don't do `--srcdir'...
67 if test x"$srcdir" != 'x.' ; then
68     echo "This configuration does not support the \`--srcdir' option.."
69     exit 1
70 fi
71
72 dnl --------------------------------------------------------------
73 dnl * Project specific configuration options
74 dnl --------------------------------------------------------------
75 dnl What follows is a bunch of options that can either be configured
76 dnl through command line options to the configure script or by
77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
78 dnl use either is considered a Feature.
79
80 dnl ** What command to use to compile compiler sources ?
81 dnl --------------------------------------------------------------
82
83 AC_ARG_WITH([ghc],
84 [AC_HELP_STRING([--with-ghc=ARG],
85   [Use ARG as the path to GHC  [default=autodetect]])],
86   [WithGhc="$withval"],
87   [if test "$GHC" = ""; then
88     AC_PATH_PROG([GHC], [ghc])
89   fi
90   WithGhc="$GHC"])
91
92
93 dnl ** Tell the make system which OS we are using
94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something 
95 AC_SUBST(OSTYPE)
96
97 dnl ** Booting from .hc files?
98 dnl --------------------------------------------------------------
99 AC_ARG_ENABLE(hc-boot,
100 [AC_HELP_STRING([--enable-hc-boot],
101 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
102  (This option is mostly of interest to porters.) [default=no]])],
103 [ if test x"$enableval" = x"yes"; then
104         BootingFromHc=YES
105   else
106         BootingFromHc=NO
107   fi
108 ],
109 [BootingFromHc=NO]
110 )
111 AC_SUBST(BootingFromHc)
112
113 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
114 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
115                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
116         EnableBootstrapWithDevelSnaphost=YES,
117         EnableBootstrapWithDevelSnaphost=NO
118 )
119
120 if test "$WithGhc" != ""; then
121   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
122
123   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
124      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
125   fi
126
127   AC_SUBST(GhcVersion)dnl
128   AC_SUBST(GhcMajVersion)dnl
129   AC_SUBST(GhcMinVersion)dnl
130   AC_SUBST(GhcPatchLevel)dnl
131   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
132   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
133   if test $GhcCanonVersion -ge 613; then ghc_ge_613=YES; else ghc_ge_613=NO; fi
134   AC_SUBST(ghc_ge_613)dnl
135
136   BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command],['$(CC)'])
137   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command],['$(AR)'])
138   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags],['$(AR_OPTS)'])
139   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file],['$(ArSupportsAtFile)'])
140 fi
141
142 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
143 if test "$BootingFromHc" = "NO"; then
144   if test "$WithGhc" = ""; then
145      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
146   fi
147   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.12],
148     [AC_MSG_ERROR([GHC version 6.12 or later is required to compile GHC.])])dnl
149
150   if test `expr $GhcMinVersion % 2` = "1"; then
151      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
152         AC_MSG_ERROR([
153      $WithGhc is a development snapshot of GHC, version $GhcVersion.
154      Bootstrapping using this version of GHC is not supported, and may not
155      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
156      or --with-ghc to specify a different GHC to use.])
157      fi
158   fi
159 fi;
160
161 # GHC is passed to Cabal, so we need a native path
162 if test "${WithGhc}" != ""
163 then
164     ghc_host=`"${WithGhc}" +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
165
166     if test "$ghc_host" = "i386-unknown-mingw32"
167     then
168         if test "${OSTYPE}" = "msys"
169         then
170             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
171         else
172             # Canonicalise to <drive>:/path/to/ghc
173             WithGhc=`cygpath -m "${WithGhc}"`
174         fi
175         echo "GHC path canonicalised to: ${WithGhc}"
176     fi
177 fi
178 AC_SUBST([WithGhc])
179
180 dnl ** Without optimization some INLINE trickery fails for GHCi
181 SRC_CC_OPTS="-O"
182
183 FP_ICONV
184 FP_GMP
185
186 dnl--------------------------------------------------------------------
187 dnl * Choose host(/target/build) platform
188 dnl--------------------------------------------------------------------
189 dnl If we aren't explicitly told what values to use with configure flags,
190 dnl we ask the bootstrapping compiler what platform it is for
191
192 if test "${WithGhc}" != ""
193 then
194         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
195         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
196         if test "$bootstrap_host" != "$bootstrap_target"
197         then
198                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
199         fi
200 fi
201
202 # We have to run these unconditionally, but we may discard their
203 # results in the following code
204 AC_CANONICAL_BUILD
205 AC_CANONICAL_HOST
206 AC_CANONICAL_TARGET
207
208 FPTOOLS_SET_PLATFORM_VARS
209
210 # Testing if we shall enable shared libs support on Solaris.
211 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
212
213 SOLARIS_BROKEN_SHLD=NO
214
215 case $host in
216      i386-*-solaris2)
217      # here we go with the test
218      MINOR=`uname -r|cut -d '.' -f 2-`
219      if test "$MINOR" -lt "11"; then
220         SOLARIS_BROKEN_SHLD=YES
221      fi
222      ;;
223 esac
224
225 checkArch() {
226     case $1 in
227     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
228         ;;
229     *)
230         echo "Unknown arch $1"
231         exit 1
232         ;;
233     esac
234 }
235
236 checkVendor() {
237     case $1 in
238     dec|unknown|hp|apple|next|sun|sgi|ibm)
239         ;;
240     *)
241         echo "Unknown vendor $1"
242         exit 1
243         ;;
244     esac
245 }
246
247 checkOS() {
248     case $1 in
249     linux|freebsd|netbsd|openbsd|dragonfly|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix|haiku)
250         ;;
251     *)
252         echo "Unknown OS '$1'"
253         exit 1
254         ;;
255     esac
256 }
257
258 BuildPlatform="$BuildArch-$BuildVendor-$BuildOS"
259 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
260 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
261 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
262 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
263
264 checkArch "$BuildArch"
265 checkVendor "$BuildVendor"
266 checkOS "$BuildOS"
267
268 HostPlatform="$HostArch-$HostVendor-$HostOS"
269 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
270 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
271 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
272 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
273
274 checkArch "$HostArch"
275 checkVendor "$HostVendor"
276 checkOS "$HostOS"
277
278 TargetPlatform="$TargetArch-$TargetVendor-$TargetOS"
279 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
280 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
281 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
282 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
283
284 checkArch "$TargetArch"
285 checkVendor "$TargetVendor"
286 checkOS "$TargetOS"
287
288 # Verify that the installed (bootstrap) GHC is capable of generating
289 # code for the requested build platform.
290 if test "$BootingFromHc" = "NO"
291 then
292     if test "$BuildPlatform" != "$bootstrap_target"
293     then
294         echo "This GHC (${WithGhc}) does not generate code for the build platform"
295         echo "   GHC target platform    : $bootstrap_target"
296         echo "   Desired build platform : $BuildPlatform"
297         exit 1
298     fi
299 fi
300
301 echo "GHC build  : $BuildPlatform"
302 echo "GHC host   : $HostPlatform"
303 echo "GHC target : $TargetPlatform"
304
305 AC_SUBST(BuildPlatform)
306 AC_SUBST(HostPlatform)
307 AC_SUBST(TargetPlatform)
308 AC_SUBST(HostPlatform_CPP)
309 AC_SUBST(BuildPlatform_CPP)
310 AC_SUBST(TargetPlatform_CPP)
311
312 AC_SUBST(HostArch_CPP)
313 AC_SUBST(BuildArch_CPP)
314 AC_SUBST(TargetArch_CPP)
315
316 AC_SUBST(HostOS_CPP)
317 AC_SUBST(BuildOS_CPP)
318 AC_SUBST(TargetOS_CPP)
319
320 AC_SUBST(HostVendor_CPP)
321 AC_SUBST(BuildVendor_CPP)
322 AC_SUBST(TargetVendor_CPP)
323
324 AC_SUBST(exeext)
325 AC_SUBST(soext)
326
327 AC_SUBST(SOLARIS_BROKEN_SHLD)
328
329 AC_ARG_WITH(hc,
330 [AC_HELP_STRING([--with-hc=ARG],
331         [Use ARG as the path to the compiler for compiling ordinary
332          Haskell code  (default= value of --with-ghc)])],
333 [WithHc="$withval"],
334 [WithHc=$WithGhc]
335 )
336 AC_SUBST(WithHc)
337
338 # This uses GHC, so put it after the "GHC is required" check above:
339 FP_INTREE_GHC_PWD
340 FP_FIND_ROOT
341
342 if test "$HostOS" = "mingw32"
343 then
344     test -d inplace || mkdir inplace
345
346     CC="$hardtop/inplace/mingw/bin/gcc.exe"
347     LD="$hardtop/inplace/mingw/bin/ld.exe"
348     NM="$hardtop/inplace/mingw/bin/nm.exe"
349     fp_prog_ar_raw="$hardtop/inplace/mingw/bin/ar.exe"
350
351     # NB. If you update the tarbballs to a new version of gcc, don't
352     # forget to tweak the paths in driver/gcc/gcc.c.
353     if ! test -d inplace/mingw ||
354          test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma  ||
355          test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma  ||
356          test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma   ||
357          test inplace/mingw -ot ghc-tarballs/mingw/libgcc*.tar.gz      ||
358          test inplace/mingw -ot ghc-tarballs/mingw/libgmp*.tar.gz      ||
359          test inplace/mingw -ot ghc-tarballs/mingw/libmpc*.tar.gz      ||
360          test inplace/mingw -ot ghc-tarballs/mingw/libmpfr*.tar.gz     ||
361          test inplace/mingw -ot ghc-tarballs/mingw/libstdc*.tar.lzma   ||
362          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dev.tar.gz ||
363          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dll.tar.gz ||
364          test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
365     then
366         AC_MSG_NOTICE([Making in-tree mingw tree])
367         rm -rf inplace/mingw
368         mkdir inplace/mingw
369         (
370             cd inplace/mingw &&
371             tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma  &&
372             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma  &&
373             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma   &&
374             tar --lzma -xf ../../ghc-tarballs/mingw/libgcc*.tar.lzma    &&
375             tar --lzma -xf ../../ghc-tarballs/mingw/libgmp*.tar.lzma    &&
376             tar --lzma -xf ../../ghc-tarballs/mingw/libmpc*.tar.lzma    &&
377             tar --lzma -xf ../../ghc-tarballs/mingw/libmpfr*.tar.lzma   &&
378             tar --lzma -xf ../../ghc-tarballs/mingw/libstdc*.tar.lzma   &&
379             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dev.tar.gz &&
380             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dll.tar.gz &&
381             tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma    &&
382             mv bin/gcc.exe bin/realgcc.exe
383         )
384         PATH=`pwd`/inplace/mingw/bin:$PATH inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
385         if ! test -e inplace/mingw/bin/gcc.exe
386         then
387             AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
388         fi
389         AC_MSG_NOTICE([In-tree mingw tree created])
390     fi
391     if ! test -d inplace/perl ||
392          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
393     then
394         AC_MSG_NOTICE([Making in-tree perl tree])
395         rm -rf inplace/perl
396         mkdir inplace
397         mkdir inplace/perl
398         (
399             cd inplace/perl &&
400             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
401         )
402         AC_MSG_NOTICE([In-tree perl tree created])
403     fi
404 fi
405
406 SplitObjsBroken=NO
407 if test "$TargetOS_CPP" = "darwin"
408 then
409     AC_MSG_CHECKING(XCode version)
410     XCodeVersion=`xcodebuild -version | grep Xcode | sed "s/Xcode //"`
411     # Old XCode versions don't actually give the XCode version
412     if test "$XCodeVersion" = ""
413     then
414         AC_MSG_RESULT(not found (too old?))
415         SplitObjsBroken=YES
416     else
417         AC_MSG_RESULT($XCodeVersion)
418         XCodeVersion1=`echo "$XCodeVersion" | sed 's/\..*//'`
419 changequote(, )dnl
420         XCodeVersion2=`echo "$XCodeVersion" | sed 's/[^.]*\.\([^.]*\).*/\1/'`
421 changequote([, ])dnl
422         AC_MSG_NOTICE(XCode version component 1: $XCodeVersion1)
423         AC_MSG_NOTICE(XCode version component 2: $XCodeVersion2)
424         # Split objects is broken (#4013) with XCode < 3.2
425         if test "$XCodeVersion1" -lt 3
426         then
427             SplitObjsBroken=YES
428         else
429             if test "$XCodeVersion1" -eq 3
430             then
431                 if test "$XCodeVersion2" -lt 2
432                 then
433                     SplitObjsBroken=YES
434                 fi
435             fi
436         fi
437     fi
438 fi
439 AC_SUBST([SplitObjsBroken])
440
441 dnl ** Which gcc to use?
442 dnl --------------------------------------------------------------
443 if test "$TargetOS_CPP" = "darwin" &&
444    test "$XCodeVersion1" -ge 4
445 then
446   # From Xcode 4, use 'gcc-4.2' to force the use of the gcc legacy backend (instead of the LLVM
447   # backend)
448   FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc-4.2])
449 else
450   FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc])
451 fi
452 export CC
453 WhatGccIsCalled="$CC"
454 AC_SUBST(WhatGccIsCalled)
455
456 dnl ** Which ld to use?
457 dnl --------------------------------------------------------------
458 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld])
459 LdCmd="$LD"
460 AC_SUBST([LdCmd])
461
462 dnl ** Which nm to use?
463 dnl --------------------------------------------------------------
464 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm])
465 NmCmd="$NM"
466 AC_SUBST([NmCmd])
467
468 dnl ** Mac OS X: explicit deployment target
469 dnl --------------------------------------------------------------
470 AC_ARG_WITH([macosx-deployment-target],
471 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
472         [Build for Mac OS VERSION and higher  (default= version of build host)])],
473 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
474  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
475    # ignore everywhere, but on Mac OS
476    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
477    FP_MACOSX_DEPLOYMENT_TARGET=none
478  fi],
479 [FP_MACOSX_DEPLOYMENT_TARGET=none]
480 )
481 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
482 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
483 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
484
485 dnl --------------------------------------------------------------
486 dnl End of configure script option section
487 dnl --------------------------------------------------------------
488
489
490 dnl --------------------------------------------------------------
491 dnl * General configuration checks
492 dnl --------------------------------------------------------------
493
494 dnl ** Can the unix package be built?
495 dnl --------------------------------------------------------------
496
497 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
498    GhcLibsWithUnix=NO
499 else
500    GhcLibsWithUnix=YES
501 fi
502 AC_SUBST([GhcLibsWithUnix])
503
504 dnl ** does #! work?
505 AC_SYS_INTERPRETER()
506
507 dnl ** look for `perl'
508 case $HostOS_CPP in
509 cygwin32|mingw32)
510     PerlCmd=$hardtop/inplace/perl/perl
511     ;;
512 *)
513     AC_PATH_PROG(PerlCmd,perl)
514     if test -z "$PerlCmd"
515     then
516         echo "You must install perl before you can continue"
517         echo "Perhaps it is already installed, but not in your PATH?"
518         exit 1
519     else
520         FPTOOLS_CHECK_PERL_VERSION
521     fi
522     ;;
523 esac
524
525 dnl ** does #! path/to/perl work? (sometimes it's too long...)
526 FPTOOLS_SHEBANG_PERL
527
528 dnl ** check for Python
529 AC_PATH_PROG(PythonCmd,python)
530
531 dnl ** look for GCC and find out which version
532 dnl     Figure out which C compiler to use.  Gcc is preferred.
533 dnl     If gcc, make sure it's at least 2.1
534 dnl
535 FP_GCC_VERSION
536
537 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
538 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
539 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
540 # Stage 3 won't be supported by cross-compilation
541 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
542
543 FP_GCC_EXTRA_FLAGS
544
545 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
546 AC_PROG_CPP
547
548 AC_SUBST(CONF_CC_OPTS_STAGE0)
549 AC_SUBST(CONF_CC_OPTS_STAGE1)
550 AC_SUBST(CONF_CC_OPTS_STAGE2)
551 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
552 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
553 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
554 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
555 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
556 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
557 AC_SUBST(CONF_CPP_OPTS_STAGE0)
558 AC_SUBST(CONF_CPP_OPTS_STAGE1)
559 AC_SUBST(CONF_CPP_OPTS_STAGE2)
560
561 FP_SETTINGS
562
563 dnl ** figure out how to do context diffs
564 FP_PROG_CONTEXT_DIFF
565
566 dnl Let's make sure install-sh is executable here.  If we got it from
567 dnl a darcs repo, it might not be (see bug #978).
568 chmod +x install-sh
569 dnl ** figure out how to do a BSD-ish install
570 AC_PROG_INSTALL
571
572 dnl If you can run configure, you certainly have /bin/sh
573 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
574
575 dnl ** how to invoke `ar' and `ranlib'
576 FP_PROG_AR_SUPPORTS_ATFILE
577 FP_PROG_AR_NEEDS_RANLIB
578
579 dnl ** Check to see whether ln -s works
580 AC_PROG_LN_S
581
582
583 dnl ** Find the path to sed
584 AC_PATH_PROGS(SedCmd,gsed sed,sed)
585
586
587 dnl ** check for time command
588 AC_PATH_PROG(TimeCmd,time)
589
590 dnl ** check for tar
591 dnl   if GNU tar is named gtar, look for it first.
592 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
593
594 dnl ** check for patch
595 dnl if GNU patch is named gpatch, look for it first
596 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
597
598 dnl ** check for dtrace (currently only implemented for Mac OS X)
599 HaveDtrace=NO
600 AC_PATH_PROG(DtraceCmd,dtrace)
601 if test -n "$DtraceCmd"; then
602   if test "x$TargetOS_CPP-$TargetVendor_CPP" == "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" == "xsolaris2-unknown"; then
603     HaveDtrace=YES
604   fi
605 fi
606 AC_SUBST(HaveDtrace)
607
608 AC_PATH_PROG(HSCOLOUR,HsColour)
609 # HsColour is passed to Cabal, so we need a native path
610 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
611    test "${OSTYPE}"      != "msys"                  && \
612    test "${HSCOLOUR}"    != ""
613 then
614     # Canonicalise to <drive>:/path/to/gcc
615     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
616 fi
617
618 dnl ** check for DocBook toolchain
619 FP_CHECK_DOCBOOK_DTD
620 FP_DOCBOOK_XSL
621 FP_PROG_DBLATEX
622
623 dnl ** check for ghc-pkg command
624 FP_PROG_GHC_PKG
625
626 dnl ** check for installed happy binary + version
627 dnl    (don't do it if we're booting from .hc files though.)
628 if test "$BootingFromHc" = "NO"; then
629 FPTOOLS_HAPPY
630 fi;
631
632 dnl ** check for installed alex binary + version
633 dnl    (don't do it if we're booting from .hc files though.)
634 if test "$BootingFromHc" = "NO"; then
635 FPTOOLS_ALEX
636 fi;
637
638 dnl --------------------------------------------------
639 dnl ### program checking section ends here ###
640 dnl --------------------------------------------------
641
642 dnl --------------------------------------------------
643 dnl * Platform header file and syscall feature tests
644 dnl ### checking the state of the local header files and syscalls ###
645
646 dnl ** check for full ANSI header (.h) files
647 AC_HEADER_STDC
648
649 dnl ** Enable large file support.  NB. do this before testing the type of
650 dnl    off_t, because it will affect the result of that test.
651 AC_SYS_LARGEFILE
652
653 dnl ** check for specific header (.h) files that we are interested in
654 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/cpuset.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
655
656 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
657 AC_HEADER_TIME
658
659 dnl ** do we have long longs?
660 AC_CHECK_TYPES([long long])
661
662 dnl ** what are the sizes of various types
663 AC_CHECK_SIZEOF(char,               1)
664 AC_CHECK_SIZEOF(double,             8)
665 AC_CHECK_SIZEOF(float,              4)
666 AC_CHECK_SIZEOF(int,                4)
667 AC_CHECK_SIZEOF(long,               4)
668 if test "$ac_cv_type_long_long" = yes; then
669 AC_CHECK_SIZEOF(long long,          8)
670 fi
671 AC_CHECK_SIZEOF(short,              2)
672 AC_CHECK_SIZEOF(unsigned char,      1)
673 AC_CHECK_SIZEOF(unsigned int,       4)
674 AC_CHECK_SIZEOF(unsigned long,      4)
675 if test "$ac_cv_type_long_long" = yes; then
676 AC_CHECK_SIZEOF(unsigned long long, 8)
677 fi
678 AC_CHECK_SIZEOF(unsigned short,     2)
679 AC_CHECK_SIZEOF(void *,             4)
680
681 dnl ** what are alignment constraints on various types
682 FP_CHECK_ALIGNMENT(char)
683 FP_CHECK_ALIGNMENT(double)
684 FP_CHECK_ALIGNMENT(float)
685 FP_CHECK_ALIGNMENT(int)
686 FP_CHECK_ALIGNMENT(long)
687 if test "$ac_cv_type_long_long" = yes; then
688 FP_CHECK_ALIGNMENT(long long)
689 fi
690 FP_CHECK_ALIGNMENT(short)
691 FP_CHECK_ALIGNMENT(unsigned char)
692 FP_CHECK_ALIGNMENT(unsigned int)
693 FP_CHECK_ALIGNMENT(unsigned long)
694 if test "$ac_cv_type_long_long" = yes; then
695 FP_CHECK_ALIGNMENT(unsigned long long)
696 fi
697 FP_CHECK_ALIGNMENT(unsigned short)
698 FP_CHECK_ALIGNMENT(void *)
699
700 FP_CHECK_FUNC([WinExec],
701   [@%:@include <windows.h>], [WinExec("",0)])
702
703 FP_CHECK_FUNC([GetModuleFileName],
704   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
705
706 dnl ** check return type of signal handlers
707 dnl Foo: assumes we can use prototypes.
708 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
709 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
710 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
711 dnl #include <signal.h>
712 dnl #ifdef signal
713 dnl #undef signal
714 dnl #endif
715 dnl void (*signal (int, void (*)(int)))(int);
716 dnl ]],
717 dnl [[int i;]])],
718 dnl [ac_cv_type_signal_handler=void_int],
719 dnl [ac_cv_type_signal_handler=int_void])])
720 dnl if test "$ac_cv_type_signal_handler" = void_int; then
721 dnl AC_DEFINE(VOID_INT_SIGNALS)
722 dnl fi
723
724 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
725 AC_TYPE_SIGNAL
726 if test "$ac_cv_type_signal" = void; then
727   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
728 fi
729
730 dnl ** check for more functions
731 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
732 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
733
734 AC_TRY_RUN([
735 #include <sys/types.h>
736 #include <sys/time.h>
737 int main(void) {
738   struct itimerval tval;
739   tval.it_value.tv_sec = 1;
740   tval.it_value.tv_usec = 0;
741   tval.it_interval = tval.it_value;
742   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
743 }
744 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
745
746 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
747 dnl ** _POSIX_C_SOURCE is defined
748 AC_CHECK_DECLS([ctime_r], , ,
749 [#define _POSIX_SOURCE 1
750 #define _POSIX_C_SOURCE 199506L
751 #include <time.h>])
752
753 dnl ** check for mingwex library
754 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
755 AC_SUBST(HaveLibMingwEx)
756
757 if test $HaveLibMingwEx = YES ; then
758   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
759 fi
760
761 dnl ** check for math library
762 dnl    Keep that check as early as possible.
763 dnl    as we need to know whether we need libm
764 dnl    for math functions or not
765 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
766 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
767 if test $HaveLibM = YES
768 then
769   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
770 fi
771
772 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
773 dnl    the order of these tests matters: bfd needs liberty
774 AC_CHECK_LIB(iberty, xmalloc)
775 AC_CHECK_LIB(bfd,    bfd_uncompress_section_contents)
776
777 dnl ################################################################
778 dnl Check for libraries
779 dnl ################################################################
780
781 dnl ** check whether we need -ldl to get dlopen()
782
783 AC_CHECK_LIB(dl, dlopen,
784     [HaveLibDL=YES
785      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
786      LIBS="$LIBS -ldl"],
787     [HaveLibDL=NO])
788 AC_SUBST(HaveLibDL)
789
790 dnl --------------------------------------------------
791 dnl * Miscellaneous feature tests
792 dnl --------------------------------------------------
793
794 dnl ** can we get alloca?
795 AC_FUNC_ALLOCA
796
797 dnl ** Working vfork?
798 AC_FUNC_FORK
799
800 dnl ** determine whether or not const works
801 AC_C_CONST
802
803 dnl ** are we big endian?
804 AC_C_BIGENDIAN
805 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
806
807 dnl ** check for leading underscores in symbol names
808 FP_LEADING_UNDERSCORE
809
810 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
811 FP_PROG_LD_X
812 FP_PROG_LD_IS_GNU
813 FP_PROG_LD_BUILD_ID
814
815 dnl ** check for Apple-style dead-stripping support
816 dnl    (.subsections-via-symbols assembler directive)
817
818
819 AC_MSG_CHECKING(for .subsections_via_symbols)
820 AC_COMPILE_IFELSE(
821     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
822     [AC_MSG_RESULT(yes)
823      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
824                [Define to 1 if Apple-style dead-stripping is supported.])
825     ],
826     [AC_MSG_RESULT(no)])
827
828 dnl *** check for GNU non-executable stack note support (ELF only)
829 dnl     (.section .note.GNU-stack,"",@progbits)
830
831 dnl This test doesn't work with "gcc -g" in gcc 4.4 (GHC trac #3889:
832 dnl     Error: can't resolve `.note.GNU-stack' {.note.GNU-stack section} - `.Ltext0' {.text section}
833 dnl so we empty CFLAGS while running this test
834 CFLAGS2="$CFLAGS"
835 CFLAGS=
836 AC_MSG_CHECKING(for GNU non-executable stack support)
837 AC_COMPILE_IFELSE(
838     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
839     [AC_MSG_RESULT(yes)
840      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
841                [Define to 1 if GNU non-executable stack notes are supported.])
842     ],
843     [AC_MSG_RESULT(no)])
844 CFLAGS="$CFLAGS2"
845
846 FP_VISIBILITY_HIDDEN
847
848 dnl ** check for librt
849 AC_CHECK_LIB(rt, clock_gettime)
850 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
851 FP_CHECK_TIMER_CREATE
852
853 dnl ** check for Apple's "interesting" long double compatibility scheme
854 AC_MSG_CHECKING(for printf\$LDBLStub)
855 AC_TRY_LINK_FUNC(printf\$LDBLStub,
856     [
857         AC_MSG_RESULT(yes)
858         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
859             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
860     ],
861     [
862         AC_MSG_RESULT(no)
863         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
864             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
865     ])
866
867 dnl ** check for eventfd which is needed by the I/O manager
868 AC_CHECK_HEADERS([sys/eventfd.h])
869 AC_CHECK_FUNCS([eventfd])
870
871 # test for GTK+
872 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
873 if test -n "$GTK_CONFIG"; then
874   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
875     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
876   else
877     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
878     GTK_CONFIG=
879   fi
880 fi
881 AC_SUBST([GTK_CONFIG])
882
883 #Checking for PAPI
884 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
885 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
886 AC_SUBST(HavePapiLib)
887 AC_SUBST(HavePapiHeader)
888
889 AC_CHECK_FUNCS(__mingw_vfprintf)
890
891 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
892    HavePapi=YES
893 else
894    HavePapi=NO
895 fi
896 AC_SUBST(HavePapi)
897
898 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
899    test "$XsltprocCmd" = ""
900 then
901     BUILD_DOCBOOK_HTML=NO
902 else
903     BUILD_DOCBOOK_HTML=YES
904 fi
905 AC_SUBST(BUILD_DOCBOOK_HTML)
906
907 if test "$DblatexCmd" = ""
908 then
909     BUILD_DOCBOOK_PS=NO
910     BUILD_DOCBOOK_PDF=NO
911 else
912     BUILD_DOCBOOK_PS=YES
913     BUILD_DOCBOOK_PDF=YES
914 fi
915 AC_SUBST(BUILD_DOCBOOK_PS)
916 AC_SUBST(BUILD_DOCBOOK_PDF)
917
918 LIBRARY_VERSION(base)
919 LIBRARY_VERSION(Cabal, Cabal/cabal)
920 LIBRARY_VERSION(ghc-prim)
921 LIBRARY_ghc_VERSION="$ProjectVersion"
922 AC_SUBST(LIBRARY_ghc_VERSION)
923
924 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
925    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
926 fi
927
928 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal ghc.spec settings docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/ghc.iss distrib/configure.ac])
929 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
930 AC_OUTPUT
931
932 # We get caught by
933 #     http://savannah.gnu.org/bugs/index.php?1516
934 #     $(eval ...) inside conditionals causes errors
935 # with make 3.80, so warn the user if it looks like they're about to
936 # try to use it.
937 # We would use "grep -q" here, but Solaris's grep doesn't support it.
938 checkMake380() {
939     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
940     then
941         echo
942         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
943         echo "This version cannot be used to build GHC."
944         echo "Please use GNU make >= 3.81."
945     fi
946 }
947
948 checkMake380 make
949 checkMake380 gmake
950
951 echo ["
952 ----------------------------------------------------------------------
953 Configure completed successfully.
954
955    Building GHC version  : $ProjectVersion
956
957    Build platform        : $BuildPlatform
958    Host platform         : $HostPlatform
959    Target platform       : $TargetPlatform
960 "]
961
962 if test "$BootingFromHc" = "YES"; then
963 echo ["\
964    Bootstrapping from HC files.
965 "]
966 else
967 echo ["\
968    Bootstrapping using   : $WithGhc
969       which is version   : $GhcVersion
970 "]
971 fi
972
973 echo ["\
974    Using GCC             : $WhatGccIsCalled
975       which is version   : $GccVersion
976
977    ld       : $LdCmd
978    Happy    : $HappyCmd ($HappyVersion)
979    Alex     : $AlexCmd ($AlexVersion)
980    Python   : $PythonCmd
981    Perl     : $PerlCmd
982    dblatex  : $DblatexCmd
983    xsltproc : $XsltprocCmd"]
984
985 if test "$HSCOLOUR" = ""; then
986 echo ["
987    HsColour was not found; documentation will not contain source links
988 "]
989 else
990 echo ["\
991    HsColour : $HSCOLOUR
992 "]
993 fi
994
995 echo ["\
996    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
997    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
998    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
999
1000 echo ["----------------------------------------------------------------------
1001 "]
1002
1003 echo "\
1004 For a standard build of GHC (fully optimised with profiling), type (g)make.
1005
1006 To make changes to the default build configuration, copy the file
1007 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1008
1009 For more information on how to configure your GHC build, see
1010    http://hackage.haskell.org/trac/ghc/wiki/Building
1011 "