Fix #3525 - we were still checking for ParsePkgConf.hs, which is gone
[ghc.git] / aclocal.m4
1 # Extra autoconf macros for the Glasgow fptools
2 #
3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
4 # ensure we don't clash with any pre-supplied autoconf ones.
5
6
7 # FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
8 # ----------------------------------
9 # Little endian Arm on Linux with some ABIs has big endian word order
10 # in doubles. Define FLOAT_WORDS_BIGENDIAN if this is the case.
11 AC_DEFUN([FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN],
12   [AC_CACHE_CHECK([whether float word order is big endian], [fptools_cv_float_word_order_bigendian],
13     [AC_COMPILE_IFELSE(
14       [AC_LANG_PROGRAM(
15         [#include <endian.h>],
16         [#if defined(__FLOAT_WORD_ORDER) && __FLOAT_WORD_ORDER == BIG_ENDIAN
17              return 0;
18          #else
19              not float word order big endian
20          #endif]
21       )],
22       [fptools_cv_float_word_order_bigendian=yes],
23       [fptools_cv_float_word_order_bigendian=no])
24     ])
25   case $fptools_cv_float_word_order_bigendian in
26       yes)
27           AC_DEFINE([FLOAT_WORDS_BIGENDIAN], 1,
28           [Define to 1 if your processor stores words of floats with
29            the most significant byte first]) ;;
30   esac
31 ])
32
33
34 # FP_EVAL_STDERR(COMMAND)
35 # -----------------------
36 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
37 # into the file conftest.err and the exit status in the variable fp_status.
38 AC_DEFUN([FP_EVAL_STDERR],
39 [{ (eval $1) 2>conftest.er1
40   fp_status=$?
41   grep -v '^ *+' conftest.er1 >conftest.err
42   rm -f conftest.er1
43   (exit $fp_status); }[]dnl
44 ])# FP_EVAL_STDERR
45
46
47 # FP_PROG_CONTEXT_DIFF
48 # --------------------
49 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
50 #
51 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
52 #
53 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
54 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
55 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
56 [echo foo > conftest1
57 echo foo > conftest2
58 fp_cv_context_diff=no
59 for fp_var in '-U 1' '-u1' '-C 1' '-c1'
60 do
61   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
62     fp_cv_context_diff="diff $fp_var"
63     break
64   fi
65 done])
66 if test x"$fp_cv_context_diff" = xno; then
67    AC_MSG_ERROR([cannot figure out how to do context diffs])
68 fi
69 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
70 ])# FP_PROG_CONTEXT_DIFF
71
72
73 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
74 # --------------------------------------------------------
75 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
76 # compilation. Execute IF-FAILS when unable to determine the value. Works for
77 # cross-compilation, too.
78 #
79 # Implementation note: We are lazy and use an internal autoconf macro, but it
80 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
81 # little risk.
82 AC_DEFUN([FP_COMPUTE_INT],
83 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
84 ])# FP_COMPUTE_INT
85
86
87 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
88 # ------------------------------------------------------------------
89 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
90 # given type. Defines ALIGNMENT_TYPE.
91 AC_DEFUN([FP_CHECK_ALIGNMENT],
92 [AS_LITERAL_IF([$1], [],
93                [AC_FATAL([$0: requires literal arguments])])[]dnl
94 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
95 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
96 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
97 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
98   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
99                  [fp_Cache],
100                  [AC_INCLUDES_DEFAULT([$3])],
101                  [AC_MSG_ERROR([cannot compute alignment ($1)
102 See `config.log' for more details.], [77])])
103 else
104   fp_Cache=0
105 fi])[]dnl
106 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
107 m4_popdef([fp_Cache])[]dnl
108 ])# FP_CHECK_ALIGNMENT
109
110
111 # FP_LEADING_UNDERSCORE
112 # ---------------------
113 # Test for determining whether symbol names have a leading underscore. We assume
114 # that they _haven't_ if anything goes wrong. Sets the output variable
115 # LeadingUnderscore to YES or NO and defines LEADING_UNDERSCORE correspondingly.
116 #
117 # Some nlist implementations seem to try to be compatible by ignoring a leading
118 # underscore sometimes (eg. FreeBSD). We therefore have to work around this by
119 # checking for *no* leading underscore first. Sigh.  --SDM
120 #
121 # Similarly on OpenBSD, but this test doesn't help. -- dons
122 AC_DEFUN([FP_LEADING_UNDERSCORE],
123 [AC_CHECK_LIB([elf], [nlist], [LIBS="-lelf $LIBS"])
124 AC_CACHE_CHECK([leading underscore in symbol names], [fptools_cv_leading_underscore], [
125 # Hack!: nlist() under Digital UNIX insist on there being an _,
126 # but symbol table listings shows none. What is going on here?!?
127 #
128 # Another hack: cygwin doesn't come with nlist.h , so we hardwire
129 # the underscoredness of that "platform"
130 case $HostPlatform in
131 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
132   case $build in
133     i386-*2\.@<:@0-9@:>@ | i386-*3\.@<:@0-3@:>@ ) fptools_cv_leading_underscore=yes ;;
134     *) fptools_cv_leading_underscore=no ;;
135   esac ;;
136 alpha-dec-osf*) fptools_cv_leading_underscore=no;;
137 *cygwin32) fptools_cv_leading_underscore=yes;;
138 *mingw32) fptools_cv_leading_underscore=yes;;
139
140     # HACK: Apple doesn't seem to provide nlist in the 64-bit-libraries
141 x86_64-apple-darwin*) fptools_cv_leading_underscore=yes;;
142
143 *) AC_RUN_IFELSE([AC_LANG_SOURCE([[#ifdef HAVE_NLIST_H
144 #include <nlist.h>
145 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
146 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
147 #endif
148
149 int main(argc, argv)
150 int argc;
151 char **argv;
152 {
153 #ifdef HAVE_NLIST_H
154     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
155         exit(1);
156     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
157         exit(0);
158 #endif
159     exit(1);
160 }]])],[fptools_cv_leading_underscore=yes],[fptools_cv_leading_underscore=no],[fptools_cv_leading_underscore=no])
161 ;;
162 esac]);
163 AC_SUBST([LeadingUnderscore], [`echo $fptools_cv_leading_underscore | sed 'y/yesno/YESNO/'`])
164 if test x"$fptools_cv_leading_underscore" = xyes; then
165    AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.])
166 fi])# FP_LEADING_UNDERSCORE
167
168
169 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
170 # ----------------------------------------------------------------------------------
171 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
172 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
173 AC_DEFUN([FP_COMPARE_VERSIONS],
174 [fp_version1=$1; fp_version2=$3
175 fp_save_IFS=$IFS; IFS='.'
176 while test x"$fp_version1" != x || test x"$fp_version2" != x
177 do
178
179   set dummy $fp_version1; shift
180   fp_num1=""
181   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
182   test x"$fp_num1" = x && fp_num1="0"
183   fp_version1="[$]*"
184
185   set dummy $fp_version2; shift
186   fp_num2=""
187   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
188   test x"$fp_num2" = x && fp_num2="0"
189   fp_version2="[$]*"
190
191   test "$fp_num1" = "$fp_num2" || break;
192 done
193 IFS=$fp_save_IFS
194 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
195 ])# FP_COMPARE_VERSIONS
196
197
198 dnl
199 dnl Check for GreenCard and version.
200 dnl
201 AC_DEFUN([FPTOOLS_GREENCARD],
202 [
203 AC_PATH_PROG(GreenCardCmd,greencard)
204 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
205 changequote(, )dnl
206 [if test x"$GreenCardCmd" != x; then
207    fptools_cv_greencard_version="`$GreenCardCmd --version |
208                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
209 else
210    fptools_cv_greencard_version=""
211 fi
212 changequote([, ])dnl
213 ])
214 FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
215   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
216 GreenCardVersion=$fptools_cv_greencard_version
217 AC_SUBST(GreenCardVersion)
218 ])
219
220 dnl
221 dnl Check for Happy and version.  If we're building GHC, then we need
222 dnl at least Happy version 1.14.  If there's no installed Happy, we look
223 dnl for a happy source tree and point the build system at that instead.
224 dnl
225 AC_DEFUN([FPTOOLS_HAPPY],
226 [AC_PATH_PROG(HappyCmd,happy,)
227 # Happy is passed to Cabal, so we need a native path
228 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
229    test "${OSTYPE}"      != "msys"                  && \
230    test "${HappyCmd}"    != ""
231 then
232     # Canonicalise to <drive>:/path/to/gcc
233     HappyCmd=`cygpath -m ${HappyCmd}`
234     AC_MSG_NOTICE([normalized happy command to $HappyCmd])
235 fi
236
237 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
238 changequote(, )dnl
239 [if test x"$HappyCmd" != x; then
240    fptools_cv_happy_version=`"$HappyCmd" -v |
241                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'` ;
242 else
243    fptools_cv_happy_version="";
244 fi;
245 changequote([, ])dnl
246 ])
247 if test ! -f compiler/parser/Parser.hs || test ! -f compiler/cmm/CmmParse.hs || test ! -f compiler/parser/ParserCore.hs
248 then
249     FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.16],
250       [AC_MSG_ERROR([Happy version 1.16 or later is required to compile GHC.])])[]
251 fi
252 HappyVersion=$fptools_cv_happy_version;
253 AC_SUBST(HappyVersion)
254 ])
255
256 dnl
257 dnl Check for Alex and version.  If we're building GHC, then we need
258 dnl at least Alex version 2.0.1.
259 dnl
260 AC_DEFUN([FPTOOLS_ALEX],
261 [
262 AC_PATH_PROG(AlexCmd,alex,)
263 # Alex is passed to Cabal, so we need a native path
264 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
265    test "${OSTYPE}"      != "msys"                  && \
266    test "${AlexCmd}"     != ""
267 then
268     # Canonicalise to <drive>:/path/to/gcc
269     AlexCmd=`cygpath -m ${AlexCmd}`
270 fi
271
272 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
273 changequote(, )dnl
274 [if test x"$AlexCmd" != x; then
275    fptools_cv_alex_version=`"$AlexCmd" -v |
276                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'` ;
277 else
278    fptools_cv_alex_version="";
279 fi;
280 changequote([, ])dnl
281 ])
282 if test ! -f compiler/cmm/CmmLex.hs || test ! -f compiler/parser/Lexer.hs
283 then
284     FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.1.0],
285       [AC_MSG_ERROR([Alex version 2.1.0 or later is required to compile GHC.])])[]
286 fi
287 AlexVersion=$fptools_cv_alex_version;
288 AC_SUBST(AlexVersion)
289 ])
290
291
292 dnl
293 dnl Check for windres and version.
294 dnl 2.15.91 works
295 dnl 2.17.50 doesn't work
296 dnl 2.18.50 works
297 dnl
298 AC_DEFUN([FPTOOLS_WINDRES],
299 [
300 if test "x$HostPlatform"  = "xi386-unknown-mingw32"
301 then
302     AC_PATH_PROG(WindResCmd,windres,)
303     # Alex is passed to Cabal, so we need a native path
304     if test "${OSTYPE}"      != "msys"                  && \
305        test "${WindResCmd}"  != ""
306     then
307         # Canonicalise to <drive>:/path/to/gcc
308         WindResCmd=`cygpath -m ${WindResCmd}`
309     fi
310
311     AC_CACHE_CHECK([for version of windres], fptools_cv_windres_version,
312     changequote(, )dnl
313     [
314         if test x"$WindResCmd" != x
315         then
316             fptools_cv_windres_version="`$WindResCmd --version |
317                           grep 'GNU windres' |
318               sed -e 's/GNU windres[^0-9]* \([0-9\.]*\).*/\1/g'`" ;
319         else
320             fptools_cv_windres_version="";
321         fi
322         changequote([, ])dnl
323     ])
324     FP_COMPARE_VERSIONS([$fptools_cv_windres_version],[-eq],[2.17.50],
325       [AC_MSG_ERROR([Your windres version isn't compatible with GHC. 2.15.91 and 2.18.50 are known to work.])])[]
326     WindResVersion=$fptools_cv_windres_version;
327     AC_SUBST(WindResVersion)
328 fi
329 ])
330
331
332 # FP_PROG_LD
333 # ----------
334 # Sets the output variable LdCmd to the (non-Cygwin version of the) full path
335 # of ld. Exits if no ld can be found
336 AC_DEFUN([FP_PROG_LD],
337 [
338 if test -z "$1"
339 then
340   AC_PATH_PROG([fp_prog_ld_raw], [ld])
341   if test -z "$fp_prog_ld_raw"; then
342     AC_MSG_ERROR([cannot find ld in your PATH, no idea how to link])
343   fi
344   LdCmd=$fp_prog_ld_raw
345   case $HostPlatform in
346     *mingw32) if test x${OSTYPE} != xmsys; then
347               LdCmd="`cygpath -w ${fp_prog_ld_raw} | sed -e 's@\\\\@/@g'`"
348                 AC_MSG_NOTICE([normalized ld command to $LdCmd])
349               fi
350             # Insist on >= ld-2.15.x, since earlier versions doesn't handle
351             # the generation of relocatable object files with large amounts
352             # of relocations correctly. (cf. HSbase.o splittage-hack)
353             fp_prog_ld_version=`${LdCmd} --version | sed -n '/GNU ld/p' | tr -cd 0-9 | cut -b1-3`
354             FP_COMPARE_VERSIONS([$fp_prog_ld_version],[-lt],[214],
355                                   [AC_MSG_ERROR([GNU ld version later than 2.14 required to compile GHC on Windows.])])[]dnl
356               ;;
357   esac
358 else
359   LdCmd="$1"
360 fi
361 AC_SUBST([LdCmd])
362 ])# FP_PROG_LD
363
364
365 # FP_PROG_LD_X
366 # ------------
367 # Sets the output variable LdXFlag to -x if ld supports this flag, otherwise the
368 # variable's value is empty.
369 AC_DEFUN([FP_PROG_LD_X],
370 [AC_REQUIRE([FP_PROG_LD])
371 AC_CACHE_CHECK([whether ld understands -x], [fp_cv_ld_x],
372 [echo 'foo() {}' > conftest.c
373 ${CC-cc} -c conftest.c
374 if ${LdCmd} -r -x -o conftest2.o conftest.o > /dev/null 2>&1; then
375    fp_cv_ld_x=yes
376 else
377    fp_cv_ld_x=no
378 fi
379 rm -rf conftest*])
380 if test "$fp_cv_ld_x" = yes; then
381   LdXFlag=-x
382 else
383   LdXFlag=
384 fi
385 AC_SUBST([LdXFlag])
386 ])# FP_PROG_LD_X
387
388
389 # FP_PROG_LD_IS_GNU
390 # -----------------
391 # Sets the output variable LdIsGNULd to YES or NO, depending on whether it is
392 # GNU ld or not.
393 AC_DEFUN([FP_PROG_LD_IS_GNU],
394 [AC_REQUIRE([FP_PROG_LD])
395 AC_CACHE_CHECK([whether ld is GNU ld], [fp_cv_gnu_ld],
396 [if ${LdCmd} --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
397   fp_cv_gnu_ld=yes
398 else
399   fp_cv_gnu_ld=no
400 fi])
401 AC_SUBST([LdIsGNULd], [`echo $fp_cv_gnu_ld | sed 'y/yesno/YESNO/'`])
402 ])# FP_PROG_LD_IS_GNU
403
404
405 # FP_PROG_AR
406 # ----------
407 # Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
408 # version of it. Exits if no ar can be found
409 AC_DEFUN([FP_PROG_AR],
410 [AC_PATH_PROG([fp_prog_ar_raw], [ar])
411 if test -z "$fp_prog_ar_raw"; then
412   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
413 fi
414 fp_prog_ar=$fp_prog_ar_raw
415 case $HostPlatform in
416   *mingw32) if test x${OSTYPE} != xmsys; then
417               fp_prog_ar="`cygpath -w ${fp_prog_ar_raw} | sed -e 's@\\\\@/@g'`"
418               AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
419             fi
420             ;;
421 esac
422 ])# FP_PROG_AR
423
424
425 # FP_PROG_AR_IS_GNU
426 # -----------------
427 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
428 AC_DEFUN([FP_PROG_AR_IS_GNU],
429 [AC_REQUIRE([FP_PROG_AR])
430 AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
431 [if $fp_prog_ar_raw --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
432   fp_cv_prog_ar_is_gnu=yes
433 else
434   fp_cv_prog_ar_is_gnu=no
435 fi])
436 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
437 ])# FP_PROG_AR_IS_GNU
438
439
440 # FP_PROG_AR_ARGS
441 # ---------------
442 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
443 # to a non-Cygwin invocation of ar including these arguments.
444 AC_DEFUN([FP_PROG_AR_ARGS],
445 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
446 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
447 [
448 # GNU ar needs special treatment: it appears to have problems with
449 # object files with the same name if you use the 's' modifier, but
450 # simple 'ar q' works fine, and doesn't need a separate ranlib.
451 if test $fp_prog_ar_is_gnu = yes; then
452   fp_cv_prog_ar_args="q"
453 else
454   touch conftest.dummy
455   for fp_var in clqsZ clqs cqs clq cq ; do
456      rm -f conftest.a
457      if $fp_prog_ar_raw $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
458         fp_cv_prog_ar_args=$fp_var
459         break
460      fi
461   done
462   rm -f conftest*
463   if test -z "$fp_cv_prog_ar_args"; then
464     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
465   fi
466 fi])
467 fp_prog_ar_args=$fp_cv_prog_ar_args
468 AC_SUBST([ArCmd], ["$fp_prog_ar $fp_prog_ar_args"])
469
470 ])# FP_PROG_AR_ARGS
471
472
473 # FP_PROG_AR_NEEDS_RANLIB
474 # -----------------------
475 # Sets the output variable RANLIB to "ranlib" if it is needed and found,
476 # to ":" otherwise.
477 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
478 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
479 AC_REQUIRE([FP_PROG_AR_ARGS])
480 AC_REQUIRE([AC_PROG_CC])
481 AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
482 [if test $fp_prog_ar_is_gnu = yes; then
483   fp_cv_prog_ar_needs_ranlib=no
484 elif echo $TargetPlatform | grep "^.*-apple-darwin$"  > /dev/null 2> /dev/null; then
485   # It's quite tedious to check for Apple's crazy timestamps in .a files,
486   # so we hardcode it.
487   fp_cv_prog_ar_needs_ranlib=yes
488 elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
489   fp_cv_prog_ar_needs_ranlib=no
490 else
491   fp_cv_prog_ar_needs_ranlib=yes
492 fi])
493 if test $fp_cv_prog_ar_needs_ranlib = yes; then
494    AC_PROG_RANLIB
495 else
496   RANLIB=":"
497   AC_SUBST([RANLIB])
498 fi
499 ])# FP_PROG_AR_NEEDS_RANLIB
500
501
502 # FP_PROG_AR_SUPPORTS_INPUT
503 # -------------------------
504 # Sets the output variable ArSupportsInput to "-input" or "", depending on
505 # whether ar supports -input flag is supported or not.
506 AC_DEFUN([FP_PROG_AR_SUPPORTS_INPUT],
507 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
508 AC_REQUIRE([FP_PROG_AR_ARGS])
509 AC_CACHE_CHECK([whether $fp_prog_ar_raw supports -input], [fp_cv_prog_ar_supports_input],
510 [fp_cv_prog_ar_supports_input=no
511 if test $fp_prog_ar_is_gnu = no; then
512   rm -f conftest*
513   touch conftest.lst
514   if FP_EVAL_STDERR([$fp_prog_ar_raw $fp_prog_ar_args conftest.a -input conftest.lst]) >/dev/null; then
515     test -s conftest.err || fp_cv_prog_ar_supports_input=yes
516   fi
517   rm -f conftest*
518 fi])
519 if test $fp_cv_prog_ar_supports_input = yes; then
520     ArSupportsInput="-input"
521 else
522     ArSupportsInput=""
523 fi
524 AC_SUBST([ArSupportsInput])
525 ])# FP_PROG_AR_SUPPORTS_INPUT
526
527
528 dnl
529 dnl AC_SHEBANG_PERL - can we she-bang perl?
530 dnl
531 AC_DEFUN([FPTOOLS_SHEBANG_PERL],
532 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
533 [echo "#!$PerlCmd"'
534 exit $1;
535 ' > conftest
536 chmod u+x conftest
537 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
538 if test $? -ne 69; then
539    fptools_cv_shebang_perl=yes
540 else
541    fptools_cv_shebang_perl=no
542 fi
543 rm -f conftest
544 ])])
545
546
547 # FP_HAVE_GCC
548 # -----------
549 # Extra testing of the result AC_PROG_CC, testing the gcc version no. Sets the
550 # output variables HaveGcc and GccVersion.
551 AC_DEFUN([FP_HAVE_GCC],
552 [AC_REQUIRE([AC_PROG_CC])
553 if test -z "$GCC"; then
554    fp_have_gcc=NO
555 else
556    fp_have_gcc=YES
557 fi
558 if test "$fp_have_gcc" = "NO" -a -d $srcdir/ghc; then
559   AC_MSG_ERROR([gcc is required])
560 fi
561 GccLT34=
562 AC_CACHE_CHECK([version of gcc], [fp_cv_gcc_version],
563 [if test "$fp_have_gcc" = "YES"; then
564    fp_cv_gcc_version="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [[^0-9]]*\([[0-9.]]*\).*/\1/g'`"
565    FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-lt], [3.0],
566      [AC_MSG_ERROR([Need at least gcc version 3.0 (3.4+ recommended)])])
567    # See #2770: gcc 2.95 doesn't work any more, apparently.  There probably
568    # isn't a very good reason for that, but for now just make configure
569    # fail.
570    FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-lt], [3.4], GccLT34=YES)
571  else
572    fp_cv_gcc_version="not-installed"
573  fi
574 ])
575 AC_SUBST([HaveGcc], [$fp_have_gcc])
576 AC_SUBST([GccVersion], [$fp_cv_gcc_version])
577 AC_SUBST(GccLT34)
578 ])# FP_HAVE_GCC
579
580 AC_DEFUN([FP_MINGW_GCC],
581 [
582   case $HostOS_CPP in
583     mingw*)  AC_MSG_CHECKING([whether $CC is a mingw gcc])
584              if $CC -v 2>&1 | grep mingw >/dev/null; then
585                 AC_MSG_RESULT([yes])
586              else
587                 AC_MSG_RESULT([no])
588                 AC_MSG_ERROR([Please use --with-gcc to specify a mingw gcc])
589              fi;;
590     *) ;;       
591   esac
592 ])
593
594 dnl Small feature test for perl version. Assumes PerlCmd
595 dnl contains path to perl binary.
596 dnl
597 dnl (Perl versions prior to v5.6 does not contain the string "v5";
598 dnl instead they display version strings such as "version 5.005".)
599 dnl
600 AC_DEFUN([FPTOOLS_CHECK_PERL_VERSION],
601 [$PerlCmd -v >conftest.out 2>&1
602    if grep "v5" conftest.out >/dev/null 2>&1; then
603       :
604    else
605       AC_MSG_ERROR([your version of perl probably won't work, try upgrading it.])
606    fi
607 rm -fr conftest*
608 ])
609
610
611 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
612 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
613 # -----------------------------------------------------
614 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
615 # of PROG-TO-CHECK-FOR when found.
616 AC_DEFUN([FP_CHECK_PROG],
617 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
618 )# FP_CHECK_PROC
619
620
621 # FP_PROG_FIND
622 # ------------
623 # Find a non-WinDoze version of the "find" utility.
624 AC_DEFUN([FP_PROG_FIND],
625 [AC_PATH_PROGS([fp_prog_find], [gfind find], find)
626 echo foo > conftest.txt
627 $fp_prog_find conftest.txt -print > conftest.out 2>&1
628 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
629   # OK, looks like a real "find".
630   case $HostPlatform in
631     *mingw32)
632       if test x${OSTYPE} != xmsys
633       then
634             fp_prog_find="`cygpath --mixed ${fp_prog_find}`"
635         AC_MSG_NOTICE([normalized find command to $fp_prog_find])
636       fi ;;
637     *) ;;
638   esac
639   FindCmd="$fp_prog_find"
640 else
641   # Found a poor WinDoze version of "find", ignore it.
642   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
643   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
644 fi
645 rm -f conftest.txt conftest.out
646 AC_SUBST([FindCmd])[]dnl
647 ])# FP_PROG_FIND
648
649
650 # FP_PROG_SORT
651 # ------------
652 # Find a Unix-like sort
653 AC_DEFUN([FP_PROG_SORT],
654 [AC_PATH_PROG([fp_prog_sort], [sort])
655 echo conwip > conftest.txt
656 $fp_prog_sort -f conftest.txt > conftest.out 2>&1
657 if grep 'conwip' conftest.out > /dev/null 2>&1 ; then
658   # The goods
659   SortCmd="$fp_prog_sort"
660 else
661   # Summink else..pick next one.
662   AC_MSG_WARN([$fp_prog_sort looks like a non-*nix sort, ignoring it])
663   FP_CHECK_PROG([SortCmd], [sort], [], [], [$fp_prog_sort])
664 fi
665 rm -f conftest.txt conftest.out
666 AC_SUBST([SortCmd])[]dnl
667 ])# FP_PROG_SORT
668
669 dnl
670 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
671 dnl values of the second argument to the result of running
672 dnl the commands given by the third. It does not cache its
673 dnl result, so it is suitable for checks which should be
674 dnl run every time.
675 dnl
676 AC_DEFUN([FPTOOLS_NOCACHE_CHECK],
677 [AC_MSG_CHECKING([$1])
678  $3
679  AC_MSG_RESULT([$][$2])
680 ])
681
682 dnl
683 dnl FPTOOLS_GHC_VERSION(version)
684 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
685 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
686 dnl
687 dnl Test for version of installed ghc.  Uses $GHC.
688 dnl [original version pinched from c2hs]
689 dnl
690 AC_DEFUN([FPTOOLS_GHC_VERSION],
691 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
692 ["${WithGhc-ghc}" --version > conftestghc 2>&1
693   cat conftestghc >&AS_MESSAGE_LOG_FD
694 #Useless Use Of cat award...
695   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
696   rm -fr conftest*
697   if test "[$]fptools_version_of_ghc" = ""
698   then
699     fptools_version_of_ghc='unknown'
700   fi
701 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
702 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
703 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
704 #
705 if test "[$]fptools_version_of_ghc[_pl]" = ""
706 then
707   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
708   fptools_version_of_ghc[_pl]="0"
709 else
710   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
711 fi
712 #
713 ifelse($#, [1], [dnl
714 [$1]="[$]fptools_version_of_ghc[_all]"
715 ], $#, [2], [dnl
716 [$1]="[$]fptools_version_of_ghc[_major]"
717 [$2]="[$]fptools_version_of_ghc[_minor]"
718 ], $#, [3], [dnl
719 [$1]="[$]fptools_version_of_ghc[_major]"
720 [$2]="[$]fptools_version_of_ghc[_minor]"
721 [$3]="[$]fptools_version_of_ghc[_pl]"
722 ], $#, [4], [dnl
723 [$1]="[$]fptools_version_of_ghc[_all]"
724 [$2]="[$]fptools_version_of_ghc[_major]"
725 [$3]="[$]fptools_version_of_ghc[_minor]"
726 [$4]="[$]fptools_version_of_ghc[_pl]"
727 ])
728 ])
729 ])dnl
730
731
732 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
733 # ---------------------------------------------------------------------------------
734 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
735 # additional flexibility of specifying the PROLOGUE and BODY.
736 AC_DEFUN([FP_CHECK_FUNC],
737 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
738 AC_CACHE_CHECK([for $1], fp_func,
739 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
740                 [AS_VAR_SET(fp_func, yes)],
741                 [AS_VAR_SET(fp_func, no)])])
742 AS_IF([test AS_VAR_GET(fp_func) = yes],
743       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
744                 [Define to 1 if you have the `]$1[' function.]) $4],
745       [$5])dnl
746 AS_VAR_POPDEF([fp_func])dnl
747 ])# FP_CHECK_FUNC
748
749
750 # FP_GEN_DOCBOOK_XML
751 # ------------------
752 # Generates a DocBook XML V4.2 document in conftest.xml.
753 #
754 # It took a lot of experimentation to find a document that will cause
755 # xsltproc to fail with an error code when the relevant
756 # stylesheets/DTDs are not found.  I couldn't make xsltproc fail with
757 # a single-file document, it seems a multi-file document is needed.
758 # -- SDM 2009-06-03
759 #
760 AC_DEFUN([FP_GEN_DOCBOOK_XML],
761 [rm -f conftest.xml conftest-book.xml
762 cat > conftest.xml << EOF
763 <?xml version="1.0" encoding="iso-8859-1"?>
764 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.2//EN"
765    "http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd" [[
766 <!ENTITY conftest-book SYSTEM "conftest-book.xml">
767 ]]>
768 <book id="test">
769 &conftest-book;
770 </book>
771 EOF
772 cat >conftest-book.xml << EOF
773 <?xml version="1.0" encoding="iso-8859-1"?>
774   <title>A DocBook &ldquo;Test Document&rdquo;</title>
775   <chapter id="id-one">
776     <title>A Chapter Title</title>
777     <para>This is a paragraph, referencing <xref linkend="id-two"/>.</para>
778   </chapter>
779   <chapter id="id-two">
780     <title>Another Chapter Title</title>
781     <para>This is another paragraph, referencing <xref linkend="id-one"/>.</para>
782   </chapter>
783 EOF
784 ]) # FP_GEN_DOCBOOK_XML
785
786
787 # FP_PROG_DBLATEX
788 # ----------------
789 # Sets the output variable DblatexCmd to the full path of dblatex,
790 # which we use for building PDF and PS docs.
791 # DblatexCmd is empty if dblatex could not be found.
792 AC_DEFUN([FP_PROG_DBLATEX],
793 [AC_PATH_PROG([DblatexCmd], [dblatex])
794 if test -z "$DblatexCmd"; then
795   AC_MSG_WARN([cannot find dblatex in your PATH, you will not be able to build the PDF and PS documentation])
796 fi
797 ])# FP_PROG_DBLATEX
798
799
800 # FP_PROG_XSLTPROC
801 # ----------------
802 # Sets the output variable XsltprocCmd to the full path of the XSLT processor
803 # xsltproc. XsltprocCmd is empty if xsltproc could not be found.
804 AC_DEFUN([FP_PROG_XSLTPROC],
805 [AC_PATH_PROG([XsltprocCmd], [xsltproc])
806 if test -z "$XsltprocCmd"; then
807   AC_MSG_WARN([cannot find xsltproc in your PATH, you will not be able to build the HTML documentation])
808 fi
809 ])# FP_PROG_XSLTPROC
810
811
812 # FP_DOCBOOK_XSL
813 # ----------------------------
814 # Check that we can process a DocBook XML document to HTML using xsltproc.
815 AC_DEFUN([FP_DOCBOOK_XSL],
816 [AC_REQUIRE([FP_PROG_XSLTPROC])dnl
817 if test -n "$XsltprocCmd"; then
818   AC_CACHE_CHECK([for DocBook XSL stylesheet], fp_cv_dir_docbook_xsl,
819   [FP_GEN_DOCBOOK_XML
820   fp_cv_dir_docbook_xsl=no
821   if $XsltprocCmd --nonet http://docbook.sourceforge.net/release/xsl/current/html/chunk.xsl conftest.xml > /dev/null 2>&1; then
822      fp_cv_dir_docbook_xsl=yes
823   fi
824   rm -rf conftest*])
825 fi
826 if test x"$fp_cv_dir_docbook_xsl" = xno; then
827   AC_MSG_WARN([cannot find DocBook XSL stylesheets, you will not be able to build the documentation])
828   HAVE_DOCBOOK_XSL=NO
829 else
830   HAVE_DOCBOOK_XSL=YES
831 fi
832 AC_SUBST([HAVE_DOCBOOK_XSL])
833 ])# FP_DOCBOOK_XSL
834
835
836 # FP_PROG_XMLLINT
837 # ----------------
838 # Sets the output variable XmllintCmd to the full path of the XSLT processor
839 # xmllint. XmllintCmd is empty if xmllint could not be found.
840 AC_DEFUN([FP_PROG_XMLLINT],
841 [AC_PATH_PROG([XmllintCmd], [xmllint])
842 if test -z "$XmllintCmd"; then
843   AC_MSG_WARN([cannot find xmllint in your PATH, you will not be able to validate your documentation])
844 fi
845 ])# FP_PROG_XMLLINT
846
847
848 # FP_CHECK_DOCBOOK_DTD
849 # --------------------
850 AC_DEFUN([FP_CHECK_DOCBOOK_DTD],
851 [AC_REQUIRE([FP_PROG_XMLLINT])dnl
852 if test -n "$XmllintCmd"; then
853   AC_MSG_CHECKING([for DocBook DTD])
854   FP_GEN_DOCBOOK_XML
855   if $XmllintCmd --nonet --valid --noout conftest.xml ; then
856     AC_MSG_RESULT([ok])
857   else
858     AC_MSG_RESULT([failed])
859     AC_MSG_WARN([cannot find a DTD for DocBook XML V4.2, you will not be able to validate your documentation])
860     AC_MSG_WARN([check your XML_CATALOG_FILES environment variable and/or /etc/xml/catalog])
861   fi
862   rm -rf conftest*
863 fi
864 ])# FP_CHECK_DOCBOOK_DTD
865
866
867 # FP_GEN_FO
868 # ------------------
869 # Generates a formatting objects document in conftest.fo.
870 AC_DEFUN([FP_GEN_FO],
871 [rm -f conftest.fo
872 cat > conftest.fo << EOF
873 <?xml version="1.0"?>
874 <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
875   <fo:layout-master-set>
876     <fo:simple-page-master master-name="blank">
877       <fo:region-body/>
878     </fo:simple-page-master>
879   </fo:layout-master-set>
880   <fo:page-sequence master-reference="blank">
881     <fo:flow flow-name="xsl-region-body">
882       <fo:block>
883         Test!
884       </fo:block>
885     </fo:flow>
886   </fo:page-sequence>
887 </fo:root>
888 EOF
889 ]) # FP_GEN_FO
890
891
892 # FP_PROG_FOP
893 # -----------
894 # Set the output variable 'FopCmd' to the first working 'fop' in the current
895 # 'PATH'. Note that /usr/bin/fop is broken in SuSE 9.1 (unpatched), so try
896 # /usr/share/fop/fop.sh in that case (or no 'fop'), too.
897 AC_DEFUN([FP_PROG_FOP],
898 [AC_PATH_PROGS([FopCmd1], [fop fop.sh])
899 if test -n "$FopCmd1"; then
900   AC_CACHE_CHECK([for $FopCmd1 usability], [fp_cv_fop_usability],
901     [FP_GEN_FO
902     if "$FopCmd1" -fo conftest.fo -ps conftest.ps > /dev/null 2>&1; then
903       fp_cv_fop_usability=yes
904     else
905       fp_cv_fop_usability=no
906     fi
907     rm -rf conftest*])
908   if test x"$fp_cv_fop_usability" = xyes; then
909      FopCmd=$FopCmd1
910   fi
911 fi
912 if test -z "$FopCmd"; then
913   AC_PATH_PROGS([FopCmd2], [fop.sh], , [/usr/share/fop])
914   FopCmd=$FopCmd2
915 fi
916 AC_SUBST([FopCmd])
917 ])# FP_PROG_FOP
918
919
920 # FP_PROG_HSTAGS
921 # ----------------
922 # Sets the output variable HstagsCmd to the full Haskell tags program path.
923 # HstagsCmd is empty if no such program could be found.
924 AC_DEFUN([FP_PROG_HSTAGS],
925 [AC_PATH_PROG([HstagsCmd], [hasktags])
926 if test -z "$HstagsCmd"; then
927   AC_MSG_WARN([cannot find hasktags in your PATH, you will not be able to build the tags])
928 fi
929 ])# FP_PROG_HSTAGS
930
931
932 # FP_PROG_GHC_PKG
933 # ----------------
934 # Try to find a ghc-pkg matching the ghc mentioned in the environment variable
935 # WithGhc. If the latter is unset or no matching ghc-pkg can be found, try to
936 # find a plain ghc-pkg. Sets the output variable GhcPkgCmd.
937 AC_DEFUN([FP_PROG_GHC_PKG],
938 [AC_CACHE_CHECK([for ghc-pkg matching $WithGhc], fp_cv_matching_ghc_pkg,
939 [fp_ghc_pkg_guess=`echo $WithGhc | sed 's,ghc\(@<:@^/\\@:>@*\)$,ghc-pkg\1,'`
940 if "$fp_ghc_pkg_guess" -l > /dev/null 2>&1; then
941   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
942 elif "$fp_ghc_pkg_guess" list > /dev/null 2>&1; then
943   # from 6.10, ghc-pkg doesn't support the old -l syntax any more
944   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
945 else
946   fp_cv_matching_ghc_pkg=no
947 fi])
948 if test x"$fp_cv_matching_ghc_pkg" = xno; then
949   AC_PATH_PROG([GhcPkgCmd], [ghc-pkg])
950 else
951   GhcPkgCmd=$fp_cv_matching_ghc_pkg
952 fi])# FP_PROG_GHC_PKG
953
954
955 # FP_GCC_EXTRA_FLAGS
956 # ------------------
957 # Determine which extra flags we need to pass gcc when we invoke it
958 # to compile .hc code.
959 #
960 # Some OSs (Mandrake Linux, in particular) configure GCC with
961 # -momit-leaf-frame-pointer on by default. If this is the case, we
962 # need to turn it off for mangling to work. The test is currently a
963 # bit crude, using only the version number of gcc.
964
965 # -fwrapv is needed for gcc to emit well-behaved code in the presence of
966 # integer wrap around. (Trac #952)
967 #
968 # -fno-unit-at-a-time or -fno-toplevel-reoder is necessary to avoid gcc
969 # reordering things in the module and confusing the manger and/or splitter.
970 # (eg. Trac #1427)
971 #
972 AC_DEFUN([FP_GCC_EXTRA_FLAGS],
973 [AC_REQUIRE([FP_HAVE_GCC])
974 AC_CACHE_CHECK([for extra options to pass gcc when compiling via C], [fp_cv_gcc_extra_opts],
975 [fp_cv_gcc_extra_opts=
976  FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [3.4],
977   [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fwrapv"],
978   [])
979  case $TargetPlatform in
980   i386-*|x86_64-*) 
981      FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [3.2],
982       [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -mno-omit-leaf-frame-pointer"],
983       [])
984     FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [3.4],
985      [FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [4.2],
986        [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fno-toplevel-reorder"],
987        [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fno-unit-at-a-time"]
988      )],
989      [])
990   ;;
991   sparc-*-solaris2) 
992     FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [4.2],
993       [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fno-toplevel-reorder"],
994       [])
995   ;;
996  esac
997 ])
998 AC_SUBST([GccExtraViaCOpts],$fp_cv_gcc_extra_opts)
999 ])
1000
1001
1002 # FP_SETUP_PROJECT_VERSION
1003 # ---------------------
1004 AC_DEFUN([FP_SETUP_PROJECT_VERSION],
1005 [
1006 if test "$RELEASE" = "NO"; then
1007     AC_MSG_CHECKING([for GHC version date])
1008     if test -f VERSION_DATE; then
1009         PACKAGE_VERSION=${PACKAGE_VERSION}.`cat VERSION_DATE`
1010         AC_MSG_RESULT(given $PACKAGE_VERSION)
1011     elif test -d .git; then
1012         changequote(, )dnl
1013         ver_date=`git log -n 1 --date=short --pretty=format:%ci | sed "s/^.*\([0-9][0-9][0-9][0-9]\)-\([0-9][0-9]\)-\([0-9][0-9]\).*$/\1\2\3/"`
1014         if echo $ver_date | grep '^[0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]$' 2>&1 >/dev/null; then true; else
1015         changequote([, ])dnl
1016                 AC_MSG_ERROR([failed to detect version date: check that git is in your path])
1017         fi
1018         PACKAGE_VERSION=${PACKAGE_VERSION}.$ver_date
1019         AC_MSG_RESULT(inferred $PACKAGE_VERSION)
1020     elif test -d _darcs; then
1021         # TODO: Remove this branch after conversion to Git
1022         changequote(, )dnl
1023         ver_date=`darcs changes --quiet --no-summary --xml | head -500 | grep 'date=' | sed "s/^.*date='\([0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]\).*$/\1/g" | ${SortCmd} -n | tail -1`
1024         if echo $ver_date | grep '^[0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]$' 2>&1 >/dev/null; then true; else
1025         changequote([, ])dnl
1026                 AC_MSG_ERROR([failed to detect version date: check that darcs is in your path])
1027         fi
1028         PACKAGE_VERSION=${PACKAGE_VERSION}.$ver_date
1029         AC_MSG_RESULT(inferred $PACKAGE_VERSION)
1030     elif test -f VERSION; then
1031         PACKAGE_VERSION=`cat VERSION`
1032         AC_MSG_RESULT(given $PACKAGE_VERSION)
1033     else
1034         AC_MSG_WARN([cannot determine snapshot version: no .git or _darcs directory and no VERSION file])
1035     fi
1036 fi
1037
1038 # Some renamings
1039 AC_SUBST([ProjectName], [$PACKAGE_NAME])
1040 AC_SUBST([ProjectVersion], [$PACKAGE_VERSION])
1041
1042 # Split PACKAGE_VERSION into (possibly empty) parts
1043 VERSION_MAJOR=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
1044 VERSION_TMP=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
1045 VERSION_MINOR=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
1046 ProjectPatchLevel=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
1047
1048 # Calculate project version as an integer, using 2 digits for minor version
1049 case $VERSION_MINOR in
1050   ?) ProjectVersionInt=${VERSION_MAJOR}0${VERSION_MINOR} ;;
1051   ??) ProjectVersionInt=${VERSION_MAJOR}${VERSION_MINOR} ;;
1052   *) AC_MSG_ERROR([bad minor version in $PACKAGE_VERSION]) ;;
1053 esac
1054 AC_SUBST([ProjectVersionInt])
1055
1056 # The project patchlevel is zero unless stated otherwise
1057 test -z "$ProjectPatchLevel" && ProjectPatchLevel=0
1058
1059 # Remove dots from the patch level; this allows us to have versions like 6.4.1.20050508
1060 ProjectPatchLevel=`echo $ProjectPatchLevel | sed 's/\.//'`
1061
1062 AC_SUBST([ProjectPatchLevel])
1063 ])# FP_SETUP_PROJECT_VERSION
1064
1065
1066 # Check for a working timer_create().  We need a pretty detailed check
1067 # here, because there exist partially-working implementations of
1068 # timer_create() in certain versions of Linux (see bug #1933).
1069 #
1070 AC_DEFUN([FP_CHECK_TIMER_CREATE],
1071   [AC_CACHE_CHECK([for a working timer_create(CLOCK_REALTIME)], 
1072     [fptools_cv_timer_create_works],
1073     [AC_TRY_RUN([
1074 #include <stdio.h>
1075 #ifdef HAVE_STDLIB_H
1076 #include <stdlib.h>
1077 #endif
1078 #ifdef HAVE_TIME_H
1079 #include <time.h>
1080 #endif
1081 #ifdef HAVE_SIGNAL_H
1082 #include <signal.h>
1083 #endif
1084 #ifdef HAVE_UNISTD_H
1085 #include <unistd.h>
1086 #endif
1087
1088 static volatile int tock = 0;
1089 static void handler(int i)
1090 {
1091    tock = 1;
1092 }
1093
1094 static void timeout(int i)
1095 {
1096   // timer_settime() has been known to hang, so just in case
1097   // we install a 1-second timeout (see #2257)
1098   exit(99);
1099 }
1100
1101 int main(int argc, char *argv[])
1102 {
1103
1104     struct sigevent ev;
1105     timer_t timer;
1106     struct itimerspec it;
1107     struct sigaction action;
1108     int m,n,count = 0;
1109
1110     ev.sigev_notify = SIGEV_SIGNAL;
1111     ev.sigev_signo  = SIGVTALRM;
1112
1113     action.sa_handler = handler;
1114     action.sa_flags = 0;
1115     sigemptyset(&action.sa_mask);
1116     if (sigaction(SIGVTALRM, &action, NULL) == -1) {
1117         fprintf(stderr,"SIGVTALRM problem\n");
1118         exit(3);
1119     }
1120
1121     action.sa_handler = timeout;
1122     action.sa_flags = 0;
1123     sigemptyset(&action.sa_mask);
1124     if (sigaction(SIGALRM, &action, NULL) == -1) {
1125       fprintf(stderr,"SIGALRM problem\n");
1126       exit(3);
1127     }
1128     alarm(1);
1129
1130     if (timer_create(CLOCK_PROCESS_CPUTIME_ID, &ev, &timer) != 0) {
1131         fprintf(stderr,"No CLOCK_PROCESS_CPUTIME_ID timer\n");
1132        exit(1);
1133     }
1134
1135     it.it_value.tv_sec = 0;
1136     it.it_value.tv_nsec = 1;
1137     it.it_interval = it.it_value;
1138     if (timer_settime(timer, 0, &it, NULL) != 0) {
1139         fprintf(stderr,"settime problem\n");
1140         exit(4);
1141     }
1142
1143     tock = 0;
1144
1145     for(n = 3; n < 20000; n++){
1146         for(m = 2; m <= n/2; m++){
1147             if (!(n%m)) count++;
1148             if (tock) goto out;
1149         }
1150     }
1151 out:
1152
1153     if (!tock) {
1154         fprintf(stderr,"no CLOCK_PROCESS_CPUTIME_ID signal\n");
1155         exit(5);
1156     }
1157
1158     timer_delete(timer);
1159
1160     if (timer_create(CLOCK_REALTIME, &ev, &timer) != 0) {
1161         fprintf(stderr,"No CLOCK_REALTIME timer\n");
1162         exit(2);
1163     }
1164
1165     it.it_value.tv_sec = 0;
1166     it.it_value.tv_nsec = 1000000;
1167     it.it_interval = it.it_value;
1168     if (timer_settime(timer, 0, &it, NULL) != 0) {
1169         fprintf(stderr,"settime problem\n");
1170         exit(4);
1171     }
1172
1173     tock = 0;
1174
1175     usleep(3000);
1176
1177     if (!tock) {
1178         fprintf(stderr,"no CLOCK_REALTIME signal\n");
1179         exit(5);
1180     }
1181
1182     timer_delete(timer);
1183
1184     exit(0);
1185 }
1186      ],
1187      [fptools_cv_timer_create_works=yes],
1188      [fptools_cv_timer_create_works=no])
1189   ])
1190 case $fptools_cv_timer_create_works in
1191     yes) AC_DEFINE([USE_TIMER_CREATE], 1, 
1192                    [Define to 1 if we can use timer_create(CLOCK_PROCESS_CPUTIME_ID,...)]);;
1193 esac
1194 ])
1195
1196 # FP_ARG_GMP
1197 # -------------
1198 AC_DEFUN([FP_ARG_GMP],
1199 [
1200 AC_ARG_WITH([gmp-includes],
1201   [AC_HELP_STRING([--with-gmp-includes],
1202     [directory containing gmp.h])],
1203     [gmp_includes=$withval],
1204     [gmp_includes=NONE])
1205
1206 AC_ARG_WITH([gmp-libraries],
1207   [AC_HELP_STRING([--with-gmp-libraries],
1208     [directory containing gmp library])],
1209     [gmp_libraries=$withval],
1210     [gmp_libraries=NONE])
1211 ])# FP_ARG_GMP
1212
1213 AC_DEFUN([CHECK_GMP],
1214 [AC_REQUIRE([AC_PROG_CPP])
1215 AC_REQUIRE([AC_PROG_CC])
1216 ])
1217
1218 # FP_CHECK_MACOSX_DEPLOYMENT_TARGET
1219 # ---------------------------------
1220 AC_DEFUN([FP_CHECK_MACOSX_DEPLOYMENT_TARGET],
1221 [
1222 if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple"; then
1223   AC_MSG_CHECKING([Mac OS X deployment target])
1224   case $FP_MACOSX_DEPLOYMENT_TARGET in
1225     none)  ;;
1226     10.4)  MACOSX_DEPLOYMENT_VERSION=10.4
1227            MACOSX_DEPLOYMENT_SDK=/Developer/SDKs/MacOSX10.4u.sdk
1228            ;;
1229     10.4u) MACOSX_DEPLOYMENT_VERSION=10.4
1230            MACOSX_DEPLOYMENT_SDK=/Developer/SDKs/MacOSX10.4u.sdk
1231            ;;
1232     *)     MACOSX_DEPLOYMENT_VERSION=$FP_MACOSX_DEPLOYMENT_TARGET
1233            MACOSX_DEPLOYMENT_SDK=/Developer/SDKs/MacOSX${FP_MACOSX_DEPLOYMENT_TARGET}.sdk
1234            ;;
1235   esac
1236   if test "x$FP_MACOSX_DEPLOYMENT_TARGET" = "xnone"; then
1237     AC_MSG_RESULT(none)
1238   else
1239     if test ! -d $MACOSX_DEPLOYMENT_SDK; then
1240       AC_MSG_ERROR([Unknown deployment target $FP_MACOSX_DEPLOYMENT_TARGET])
1241     fi
1242     AC_MSG_RESULT([${MACOSX_DEPLOYMENT_VERSION} (${MACOSX_DEPLOYMENT_SDK})])
1243   fi
1244 fi
1245 ])
1246
1247 # --------------------------------------------------------------
1248 # Calculate absolute path to build tree
1249 # --------------------------------------------------------------
1250
1251 AC_DEFUN([FP_FIND_ROOT],[
1252 AC_MSG_CHECKING(for path to top of build tree)
1253
1254 dnl This would be
1255 dnl     make -C utils/ghc-pwd clean && make -C utils/ghc-pwd
1256 dnl except we don't want to have to know what make is called. Sigh.
1257 if test ! -f utils/ghc-pwd/ghc-pwd && test ! -f utils/ghc-pwd/ghc-pwd.exe; then
1258   cd utils/ghc-pwd
1259   rm -f *.o
1260   rm -f *.hi
1261   rm -f ghc-pwd
1262   rm -f ghc-pwd.exe
1263   $WithGhc -v0 --make ghc-pwd -o ghc-pwd
1264   cd ../..
1265 fi
1266
1267 hardtop=`utils/ghc-pwd/ghc-pwd`
1268
1269 if ! test -d "$hardtop"; then
1270   AC_MSG_ERROR([cannot determine current directory])
1271 fi   
1272
1273 dnl Remove common automounter nonsense
1274 dnl
1275 hardtop=`echo $hardtop | sed 's|^/tmp_mnt.*\(/local/.*\)$|\1|' | sed 's|^/tmp_mnt/|/|'`
1276
1277 AC_SUBST(hardtop)
1278
1279 AC_MSG_RESULT(${hardtop})
1280
1281 # We don't support building in directories with spaces.
1282 case "$hardtop" in
1283   *' '*) AC_MSG_ERROR([
1284    The build system does not support building in a directory containing
1285    space characters.  Suggestion: move the build tree somewhere else.])
1286  ;;
1287 esac
1288 ])
1289
1290 # LocalWords:  fi