Cache coercion roles in NthCo
[ghc.git] / compiler / coreSyn / CoreUtils.hs
1 {-
2 (c) The University of Glasgow 2006
3 (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
4
5
6 Utility functions on @Core@ syntax
7 -}
8
9 {-# LANGUAGE CPP #-}
10
11 -- | Commonly useful utilites for manipulating the Core language
12 module CoreUtils (
13 -- * Constructing expressions
14 mkCast,
15 mkTick, mkTicks, mkTickNoHNF, tickHNFArgs,
16 bindNonRec, needsCaseBinding,
17 mkAltExpr,
18
19 -- * Taking expressions apart
20 findDefault, addDefault, findAlt, isDefaultAlt,
21 mergeAlts, trimConArgs,
22 filterAlts, combineIdenticalAlts, refineDefaultAlt,
23
24 -- * Properties of expressions
25 exprType, coreAltType, coreAltsType, isExprLevPoly,
26 exprIsDupable, exprIsTrivial, getIdFromTrivialExpr, exprIsBottom,
27 getIdFromTrivialExpr_maybe,
28 exprIsCheap, exprIsExpandable, exprIsCheapX, CheapAppFun,
29 exprIsHNF, exprOkForSpeculation, exprOkForSideEffects, exprIsWorkFree,
30 exprIsBig, exprIsConLike,
31 rhsIsStatic, isCheapApp, isExpandableApp,
32 exprIsTickedString, exprIsTickedString_maybe,
33 exprIsTopLevelBindable,
34 altsAreExhaustive,
35
36 -- * Equality
37 cheapEqExpr, cheapEqExpr', eqExpr,
38 diffExpr, diffBinds,
39
40 -- * Eta reduction
41 tryEtaReduce,
42
43 -- * Manipulating data constructors and types
44 exprToType, exprToCoercion_maybe,
45 applyTypeToArgs, applyTypeToArg,
46 dataConRepInstPat, dataConRepFSInstPat,
47 isEmptyTy,
48
49 -- * Working with ticks
50 stripTicksTop, stripTicksTopE, stripTicksTopT,
51 stripTicksE, stripTicksT,
52
53 -- * StaticPtr
54 collectMakeStaticArgs,
55
56 -- * Join points
57 isJoinBind
58 ) where
59
60 #include "HsVersions.h"
61
62 import GhcPrelude
63
64 import CoreSyn
65 import PrelNames ( makeStaticName )
66 import PprCore
67 import CoreFVs( exprFreeVars )
68 import Var
69 import SrcLoc
70 import VarEnv
71 import VarSet
72 import Name
73 import Literal
74 import DataCon
75 import PrimOp
76 import Id
77 import IdInfo
78 import PrelNames( absentErrorIdKey )
79 import Type
80 import TyCoRep( TyBinder(..) )
81 import Coercion
82 import TyCon
83 import Unique
84 import Outputable
85 import TysPrim
86 import DynFlags
87 import FastString
88 import Maybes
89 import ListSetOps ( minusList )
90 import BasicTypes ( Arity, isConLike )
91 import Platform
92 import Util
93 import Pair
94 import Data.ByteString ( ByteString )
95 import Data.Function ( on )
96 import Data.List
97 import Data.Ord ( comparing )
98 import OrdList
99 import qualified Data.Set as Set
100 import UniqSet
101
102 {-
103 ************************************************************************
104 * *
105 \subsection{Find the type of a Core atom/expression}
106 * *
107 ************************************************************************
108 -}
109
110 exprType :: CoreExpr -> Type
111 -- ^ Recover the type of a well-typed Core expression. Fails when
112 -- applied to the actual 'CoreSyn.Type' expression as it cannot
113 -- really be said to have a type
114 exprType (Var var) = idType var
115 exprType (Lit lit) = literalType lit
116 exprType (Coercion co) = coercionType co
117 exprType (Let bind body)
118 | NonRec tv rhs <- bind -- See Note [Type bindings]
119 , Type ty <- rhs = substTyWithUnchecked [tv] [ty] (exprType body)
120 | otherwise = exprType body
121 exprType (Case _ _ ty _) = ty
122 exprType (Cast _ co) = pSnd (coercionKind co)
123 exprType (Tick _ e) = exprType e
124 exprType (Lam binder expr) = mkLamType binder (exprType expr)
125 exprType e@(App _ _)
126 = case collectArgs e of
127 (fun, args) -> applyTypeToArgs e (exprType fun) args
128
129 exprType other = pprTrace "exprType" (pprCoreExpr other) alphaTy
130
131 coreAltType :: CoreAlt -> Type
132 -- ^ Returns the type of the alternatives right hand side
133 coreAltType (_,bs,rhs)
134 | any bad_binder bs = expandTypeSynonyms ty
135 | otherwise = ty -- Note [Existential variables and silly type synonyms]
136 where
137 ty = exprType rhs
138 free_tvs = tyCoVarsOfType ty
139 bad_binder b = b `elemVarSet` free_tvs
140
141 coreAltsType :: [CoreAlt] -> Type
142 -- ^ Returns the type of the first alternative, which should be the same as for all alternatives
143 coreAltsType (alt:_) = coreAltType alt
144 coreAltsType [] = panic "corAltsType"
145
146 -- | Is this expression levity polymorphic? This should be the
147 -- same as saying (isKindLevPoly . typeKind . exprType) but
148 -- much faster.
149 isExprLevPoly :: CoreExpr -> Bool
150 isExprLevPoly = go
151 where
152 go (Var _) = False -- no levity-polymorphic binders
153 go (Lit _) = False -- no levity-polymorphic literals
154 go e@(App f _) | not (go_app f) = False
155 | otherwise = check_type e
156 go (Lam _ _) = False
157 go (Let _ e) = go e
158 go e@(Case {}) = check_type e -- checking type is fast
159 go e@(Cast {}) = check_type e
160 go (Tick _ e) = go e
161 go e@(Type {}) = pprPanic "isExprLevPoly ty" (ppr e)
162 go (Coercion {}) = False -- this case can happen in SetLevels
163
164 check_type = isTypeLevPoly . exprType -- slow approach
165
166 -- if the function is a variable (common case), check its
167 -- levityInfo. This might mean we don't need to look up and compute
168 -- on the type. Spec of these functions: return False if there is
169 -- no possibility, ever, of this expression becoming levity polymorphic,
170 -- no matter what it's applied to; return True otherwise.
171 -- returning True is always safe. See also Note [Levity info] in
172 -- IdInfo
173 go_app (Var id) = not (isNeverLevPolyId id)
174 go_app (Lit _) = False
175 go_app (App f _) = go_app f
176 go_app (Lam _ e) = go_app e
177 go_app (Let _ e) = go_app e
178 go_app (Case _ _ ty _) = resultIsLevPoly ty
179 go_app (Cast _ co) = resultIsLevPoly (pSnd $ coercionKind co)
180 go_app (Tick _ e) = go_app e
181 go_app e@(Type {}) = pprPanic "isExprLevPoly app ty" (ppr e)
182 go_app e@(Coercion {}) = pprPanic "isExprLevPoly app co" (ppr e)
183
184
185 {-
186 Note [Type bindings]
187 ~~~~~~~~~~~~~~~~~~~~
188 Core does allow type bindings, although such bindings are
189 not much used, except in the output of the desugarer.
190 Example:
191 let a = Int in (\x:a. x)
192 Given this, exprType must be careful to substitute 'a' in the
193 result type (Trac #8522).
194
195 Note [Existential variables and silly type synonyms]
196 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
197 Consider
198 data T = forall a. T (Funny a)
199 type Funny a = Bool
200 f :: T -> Bool
201 f (T x) = x
202
203 Now, the type of 'x' is (Funny a), where 'a' is existentially quantified.
204 That means that 'exprType' and 'coreAltsType' may give a result that *appears*
205 to mention an out-of-scope type variable. See Trac #3409 for a more real-world
206 example.
207
208 Various possibilities suggest themselves:
209
210 - Ignore the problem, and make Lint not complain about such variables
211
212 - Expand all type synonyms (or at least all those that discard arguments)
213 This is tricky, because at least for top-level things we want to
214 retain the type the user originally specified.
215
216 - Expand synonyms on the fly, when the problem arises. That is what
217 we are doing here. It's not too expensive, I think.
218
219 Note that there might be existentially quantified coercion variables, too.
220 -}
221
222 -- Not defined with applyTypeToArg because you can't print from CoreSyn.
223 applyTypeToArgs :: CoreExpr -> Type -> [CoreExpr] -> Type
224 -- ^ A more efficient version of 'applyTypeToArg' when we have several arguments.
225 -- The first argument is just for debugging, and gives some context
226 applyTypeToArgs e op_ty args
227 = go op_ty args
228 where
229 go op_ty [] = op_ty
230 go op_ty (Type ty : args) = go_ty_args op_ty [ty] args
231 go op_ty (Coercion co : args) = go_ty_args op_ty [mkCoercionTy co] args
232 go op_ty (_ : args) | Just (_, res_ty) <- splitFunTy_maybe op_ty
233 = go res_ty args
234 go _ _ = pprPanic "applyTypeToArgs" panic_msg
235
236 -- go_ty_args: accumulate type arguments so we can
237 -- instantiate all at once with piResultTys
238 go_ty_args op_ty rev_tys (Type ty : args)
239 = go_ty_args op_ty (ty:rev_tys) args
240 go_ty_args op_ty rev_tys (Coercion co : args)
241 = go_ty_args op_ty (mkCoercionTy co : rev_tys) args
242 go_ty_args op_ty rev_tys args
243 = go (piResultTys op_ty (reverse rev_tys)) args
244
245 panic_msg = vcat [ text "Expression:" <+> pprCoreExpr e
246 , text "Type:" <+> ppr op_ty
247 , text "Args:" <+> ppr args ]
248
249
250 {-
251 ************************************************************************
252 * *
253 \subsection{Attaching notes}
254 * *
255 ************************************************************************
256 -}
257
258 -- | Wrap the given expression in the coercion safely, dropping
259 -- identity coercions and coalescing nested coercions
260 mkCast :: CoreExpr -> CoercionR -> CoreExpr
261 mkCast e co
262 | ASSERT2( coercionRole co == Representational
263 , text "coercion" <+> ppr co <+> ptext (sLit "passed to mkCast")
264 <+> ppr e <+> text "has wrong role" <+> ppr (coercionRole co) )
265 isReflCo co
266 = e
267
268 mkCast (Coercion e_co) co
269 | isCoercionType (pSnd (coercionKind co))
270 -- The guard here checks that g has a (~#) on both sides,
271 -- otherwise decomposeCo fails. Can in principle happen
272 -- with unsafeCoerce
273 = Coercion (mkCoCast e_co co)
274
275 mkCast (Cast expr co2) co
276 = WARN(let { Pair from_ty _to_ty = coercionKind co;
277 Pair _from_ty2 to_ty2 = coercionKind co2} in
278 not (from_ty `eqType` to_ty2),
279 vcat ([ text "expr:" <+> ppr expr
280 , text "co2:" <+> ppr co2
281 , text "co:" <+> ppr co ]) )
282 mkCast expr (mkTransCo co2 co)
283
284 mkCast (Tick t expr) co
285 = Tick t (mkCast expr co)
286
287 mkCast expr co
288 = let Pair from_ty _to_ty = coercionKind co in
289 WARN( not (from_ty `eqType` exprType expr),
290 text "Trying to coerce" <+> text "(" <> ppr expr
291 $$ text "::" <+> ppr (exprType expr) <> text ")"
292 $$ ppr co $$ ppr (coercionType co) )
293 (Cast expr co)
294
295 -- | Wraps the given expression in the source annotation, dropping the
296 -- annotation if possible.
297 mkTick :: Tickish Id -> CoreExpr -> CoreExpr
298 mkTick t orig_expr = mkTick' id id orig_expr
299 where
300 -- Some ticks (cost-centres) can be split in two, with the
301 -- non-counting part having laxer placement properties.
302 canSplit = tickishCanSplit t && tickishPlace (mkNoCount t) /= tickishPlace t
303
304 mkTick' :: (CoreExpr -> CoreExpr) -- ^ apply after adding tick (float through)
305 -> (CoreExpr -> CoreExpr) -- ^ apply before adding tick (float with)
306 -> CoreExpr -- ^ current expression
307 -> CoreExpr
308 mkTick' top rest expr = case expr of
309
310 -- Cost centre ticks should never be reordered relative to each
311 -- other. Therefore we can stop whenever two collide.
312 Tick t2 e
313 | ProfNote{} <- t2, ProfNote{} <- t -> top $ Tick t $ rest expr
314
315 -- Otherwise we assume that ticks of different placements float
316 -- through each other.
317 | tickishPlace t2 /= tickishPlace t -> mkTick' (top . Tick t2) rest e
318
319 -- For annotations this is where we make sure to not introduce
320 -- redundant ticks.
321 | tickishContains t t2 -> mkTick' top rest e
322 | tickishContains t2 t -> orig_expr
323 | otherwise -> mkTick' top (rest . Tick t2) e
324
325 -- Ticks don't care about types, so we just float all ticks
326 -- through them. Note that it's not enough to check for these
327 -- cases top-level. While mkTick will never produce Core with type
328 -- expressions below ticks, such constructs can be the result of
329 -- unfoldings. We therefore make an effort to put everything into
330 -- the right place no matter what we start with.
331 Cast e co -> mkTick' (top . flip Cast co) rest e
332 Coercion co -> Coercion co
333
334 Lam x e
335 -- Always float through type lambdas. Even for non-type lambdas,
336 -- floating is allowed for all but the most strict placement rule.
337 | not (isRuntimeVar x) || tickishPlace t /= PlaceRuntime
338 -> mkTick' (top . Lam x) rest e
339
340 -- If it is both counting and scoped, we split the tick into its
341 -- two components, often allowing us to keep the counting tick on
342 -- the outside of the lambda and push the scoped tick inside.
343 -- The point of this is that the counting tick can probably be
344 -- floated, and the lambda may then be in a position to be
345 -- beta-reduced.
346 | canSplit
347 -> top $ Tick (mkNoScope t) $ rest $ Lam x $ mkTick (mkNoCount t) e
348
349 App f arg
350 -- Always float through type applications.
351 | not (isRuntimeArg arg)
352 -> mkTick' (top . flip App arg) rest f
353
354 -- We can also float through constructor applications, placement
355 -- permitting. Again we can split.
356 | isSaturatedConApp expr && (tickishPlace t==PlaceCostCentre || canSplit)
357 -> if tickishPlace t == PlaceCostCentre
358 then top $ rest $ tickHNFArgs t expr
359 else top $ Tick (mkNoScope t) $ rest $ tickHNFArgs (mkNoCount t) expr
360
361 Var x
362 | notFunction && tickishPlace t == PlaceCostCentre
363 -> orig_expr
364 | notFunction && canSplit
365 -> top $ Tick (mkNoScope t) $ rest expr
366 where
367 -- SCCs can be eliminated on variables provided the variable
368 -- is not a function. In these cases the SCC makes no difference:
369 -- the cost of evaluating the variable will be attributed to its
370 -- definition site. When the variable refers to a function, however,
371 -- an SCC annotation on the variable affects the cost-centre stack
372 -- when the function is called, so we must retain those.
373 notFunction = not (isFunTy (idType x))
374
375 Lit{}
376 | tickishPlace t == PlaceCostCentre
377 -> orig_expr
378
379 -- Catch-all: Annotate where we stand
380 _any -> top $ Tick t $ rest expr
381
382 mkTicks :: [Tickish Id] -> CoreExpr -> CoreExpr
383 mkTicks ticks expr = foldr mkTick expr ticks
384
385 isSaturatedConApp :: CoreExpr -> Bool
386 isSaturatedConApp e = go e []
387 where go (App f a) as = go f (a:as)
388 go (Var fun) args
389 = isConLikeId fun && idArity fun == valArgCount args
390 go (Cast f _) as = go f as
391 go _ _ = False
392
393 mkTickNoHNF :: Tickish Id -> CoreExpr -> CoreExpr
394 mkTickNoHNF t e
395 | exprIsHNF e = tickHNFArgs t e
396 | otherwise = mkTick t e
397
398 -- push a tick into the arguments of a HNF (call or constructor app)
399 tickHNFArgs :: Tickish Id -> CoreExpr -> CoreExpr
400 tickHNFArgs t e = push t e
401 where
402 push t (App f (Type u)) = App (push t f) (Type u)
403 push t (App f arg) = App (push t f) (mkTick t arg)
404 push _t e = e
405
406 -- | Strip ticks satisfying a predicate from top of an expression
407 stripTicksTop :: (Tickish Id -> Bool) -> Expr b -> ([Tickish Id], Expr b)
408 stripTicksTop p = go []
409 where go ts (Tick t e) | p t = go (t:ts) e
410 go ts other = (reverse ts, other)
411
412 -- | Strip ticks satisfying a predicate from top of an expression,
413 -- returning the remaining expression
414 stripTicksTopE :: (Tickish Id -> Bool) -> Expr b -> Expr b
415 stripTicksTopE p = go
416 where go (Tick t e) | p t = go e
417 go other = other
418
419 -- | Strip ticks satisfying a predicate from top of an expression,
420 -- returning the ticks
421 stripTicksTopT :: (Tickish Id -> Bool) -> Expr b -> [Tickish Id]
422 stripTicksTopT p = go []
423 where go ts (Tick t e) | p t = go (t:ts) e
424 go ts _ = ts
425
426 -- | Completely strip ticks satisfying a predicate from an
427 -- expression. Note this is O(n) in the size of the expression!
428 stripTicksE :: (Tickish Id -> Bool) -> Expr b -> Expr b
429 stripTicksE p expr = go expr
430 where go (App e a) = App (go e) (go a)
431 go (Lam b e) = Lam b (go e)
432 go (Let b e) = Let (go_bs b) (go e)
433 go (Case e b t as) = Case (go e) b t (map go_a as)
434 go (Cast e c) = Cast (go e) c
435 go (Tick t e)
436 | p t = go e
437 | otherwise = Tick t (go e)
438 go other = other
439 go_bs (NonRec b e) = NonRec b (go e)
440 go_bs (Rec bs) = Rec (map go_b bs)
441 go_b (b, e) = (b, go e)
442 go_a (c,bs,e) = (c,bs, go e)
443
444 stripTicksT :: (Tickish Id -> Bool) -> Expr b -> [Tickish Id]
445 stripTicksT p expr = fromOL $ go expr
446 where go (App e a) = go e `appOL` go a
447 go (Lam _ e) = go e
448 go (Let b e) = go_bs b `appOL` go e
449 go (Case e _ _ as) = go e `appOL` concatOL (map go_a as)
450 go (Cast e _) = go e
451 go (Tick t e)
452 | p t = t `consOL` go e
453 | otherwise = go e
454 go _ = nilOL
455 go_bs (NonRec _ e) = go e
456 go_bs (Rec bs) = concatOL (map go_b bs)
457 go_b (_, e) = go e
458 go_a (_, _, e) = go e
459
460 {-
461 ************************************************************************
462 * *
463 \subsection{Other expression construction}
464 * *
465 ************************************************************************
466 -}
467
468 bindNonRec :: Id -> CoreExpr -> CoreExpr -> CoreExpr
469 -- ^ @bindNonRec x r b@ produces either:
470 --
471 -- > let x = r in b
472 --
473 -- or:
474 --
475 -- > case r of x { _DEFAULT_ -> b }
476 --
477 -- depending on whether we have to use a @case@ or @let@
478 -- binding for the expression (see 'needsCaseBinding').
479 -- It's used by the desugarer to avoid building bindings
480 -- that give Core Lint a heart attack, although actually
481 -- the simplifier deals with them perfectly well. See
482 -- also 'MkCore.mkCoreLet'
483 bindNonRec bndr rhs body
484 | needsCaseBinding (idType bndr) rhs = Case rhs bndr (exprType body) [(DEFAULT, [], body)]
485 | otherwise = Let (NonRec bndr rhs) body
486
487 -- | Tests whether we have to use a @case@ rather than @let@ binding for this expression
488 -- as per the invariants of 'CoreExpr': see "CoreSyn#let_app_invariant"
489 needsCaseBinding :: Type -> CoreExpr -> Bool
490 needsCaseBinding ty rhs = isUnliftedType ty && not (exprOkForSpeculation rhs)
491 -- Make a case expression instead of a let
492 -- These can arise either from the desugarer,
493 -- or from beta reductions: (\x.e) (x +# y)
494
495 mkAltExpr :: AltCon -- ^ Case alternative constructor
496 -> [CoreBndr] -- ^ Things bound by the pattern match
497 -> [Type] -- ^ The type arguments to the case alternative
498 -> CoreExpr
499 -- ^ This guy constructs the value that the scrutinee must have
500 -- given that you are in one particular branch of a case
501 mkAltExpr (DataAlt con) args inst_tys
502 = mkConApp con (map Type inst_tys ++ varsToCoreExprs args)
503 mkAltExpr (LitAlt lit) [] []
504 = Lit lit
505 mkAltExpr (LitAlt _) _ _ = panic "mkAltExpr LitAlt"
506 mkAltExpr DEFAULT _ _ = panic "mkAltExpr DEFAULT"
507
508 {-
509 ************************************************************************
510 * *
511 Operations oer case alternatives
512 * *
513 ************************************************************************
514
515 The default alternative must be first, if it exists at all.
516 This makes it easy to find, though it makes matching marginally harder.
517 -}
518
519 -- | Extract the default case alternative
520 findDefault :: [(AltCon, [a], b)] -> ([(AltCon, [a], b)], Maybe b)
521 findDefault ((DEFAULT,args,rhs) : alts) = ASSERT( null args ) (alts, Just rhs)
522 findDefault alts = (alts, Nothing)
523
524 addDefault :: [(AltCon, [a], b)] -> Maybe b -> [(AltCon, [a], b)]
525 addDefault alts Nothing = alts
526 addDefault alts (Just rhs) = (DEFAULT, [], rhs) : alts
527
528 isDefaultAlt :: (AltCon, a, b) -> Bool
529 isDefaultAlt (DEFAULT, _, _) = True
530 isDefaultAlt _ = False
531
532 -- | Find the case alternative corresponding to a particular
533 -- constructor: panics if no such constructor exists
534 findAlt :: AltCon -> [(AltCon, a, b)] -> Maybe (AltCon, a, b)
535 -- A "Nothing" result *is* legitmiate
536 -- See Note [Unreachable code]
537 findAlt con alts
538 = case alts of
539 (deflt@(DEFAULT,_,_):alts) -> go alts (Just deflt)
540 _ -> go alts Nothing
541 where
542 go [] deflt = deflt
543 go (alt@(con1,_,_) : alts) deflt
544 = case con `cmpAltCon` con1 of
545 LT -> deflt -- Missed it already; the alts are in increasing order
546 EQ -> Just alt
547 GT -> ASSERT( not (con1 == DEFAULT) ) go alts deflt
548
549 {- Note [Unreachable code]
550 ~~~~~~~~~~~~~~~~~~~~~~~~~~
551 It is possible (although unusual) for GHC to find a case expression
552 that cannot match. For example:
553
554 data Col = Red | Green | Blue
555 x = Red
556 f v = case x of
557 Red -> ...
558 _ -> ...(case x of { Green -> e1; Blue -> e2 })...
559
560 Suppose that for some silly reason, x isn't substituted in the case
561 expression. (Perhaps there's a NOINLINE on it, or profiling SCC stuff
562 gets in the way; cf Trac #3118.) Then the full-lazines pass might produce
563 this
564
565 x = Red
566 lvl = case x of { Green -> e1; Blue -> e2 })
567 f v = case x of
568 Red -> ...
569 _ -> ...lvl...
570
571 Now if x gets inlined, we won't be able to find a matching alternative
572 for 'Red'. That's because 'lvl' is unreachable. So rather than crashing
573 we generate (error "Inaccessible alternative").
574
575 Similar things can happen (augmented by GADTs) when the Simplifier
576 filters down the matching alternatives in Simplify.rebuildCase.
577 -}
578
579 ---------------------------------
580 mergeAlts :: [(AltCon, a, b)] -> [(AltCon, a, b)] -> [(AltCon, a, b)]
581 -- ^ Merge alternatives preserving order; alternatives in
582 -- the first argument shadow ones in the second
583 mergeAlts [] as2 = as2
584 mergeAlts as1 [] = as1
585 mergeAlts (a1:as1) (a2:as2)
586 = case a1 `cmpAlt` a2 of
587 LT -> a1 : mergeAlts as1 (a2:as2)
588 EQ -> a1 : mergeAlts as1 as2 -- Discard a2
589 GT -> a2 : mergeAlts (a1:as1) as2
590
591
592 ---------------------------------
593 trimConArgs :: AltCon -> [CoreArg] -> [CoreArg]
594 -- ^ Given:
595 --
596 -- > case (C a b x y) of
597 -- > C b x y -> ...
598 --
599 -- We want to drop the leading type argument of the scrutinee
600 -- leaving the arguments to match against the pattern
601
602 trimConArgs DEFAULT args = ASSERT( null args ) []
603 trimConArgs (LitAlt _) args = ASSERT( null args ) []
604 trimConArgs (DataAlt dc) args = dropList (dataConUnivTyVars dc) args
605
606 filterAlts :: TyCon -- ^ Type constructor of scrutinee's type (used to prune possibilities)
607 -> [Type] -- ^ And its type arguments
608 -> [AltCon] -- ^ 'imposs_cons': constructors known to be impossible due to the form of the scrutinee
609 -> [(AltCon, [Var], a)] -- ^ Alternatives
610 -> ([AltCon], [(AltCon, [Var], a)])
611 -- Returns:
612 -- 1. Constructors that will never be encountered by the
613 -- *default* case (if any). A superset of imposs_cons
614 -- 2. The new alternatives, trimmed by
615 -- a) remove imposs_cons
616 -- b) remove constructors which can't match because of GADTs
617 -- and with the DEFAULT expanded to a DataAlt if there is exactly
618 -- remaining constructor that can match
619 --
620 -- NB: the final list of alternatives may be empty:
621 -- This is a tricky corner case. If the data type has no constructors,
622 -- which GHC allows, or if the imposs_cons covers all constructors (after taking
623 -- account of GADTs), then no alternatives can match.
624 --
625 -- If callers need to preserve the invariant that there is always at least one branch
626 -- in a "case" statement then they will need to manually add a dummy case branch that just
627 -- calls "error" or similar.
628 filterAlts _tycon inst_tys imposs_cons alts
629 = (imposs_deflt_cons, addDefault trimmed_alts maybe_deflt)
630 where
631 (alts_wo_default, maybe_deflt) = findDefault alts
632 alt_cons = [con | (con,_,_) <- alts_wo_default]
633
634 trimmed_alts = filterOut (impossible_alt inst_tys) alts_wo_default
635
636 imposs_cons_set = Set.fromList imposs_cons
637 imposs_deflt_cons =
638 imposs_cons ++ filterOut (`Set.member` imposs_cons_set) alt_cons
639 -- "imposs_deflt_cons" are handled
640 -- EITHER by the context,
641 -- OR by a non-DEFAULT branch in this case expression.
642
643 impossible_alt :: [Type] -> (AltCon, a, b) -> Bool
644 impossible_alt _ (con, _, _) | con `Set.member` imposs_cons_set = True
645 impossible_alt inst_tys (DataAlt con, _, _) = dataConCannotMatch inst_tys con
646 impossible_alt _ _ = False
647
648 refineDefaultAlt :: [Unique] -> TyCon -> [Type]
649 -> [AltCon] -- Constructors that cannot match the DEFAULT (if any)
650 -> [CoreAlt]
651 -> (Bool, [CoreAlt])
652 -- Refine the default alternative to a DataAlt,
653 -- if there is a unique way to do so
654 refineDefaultAlt us tycon tys imposs_deflt_cons all_alts
655 | (DEFAULT,_,rhs) : rest_alts <- all_alts
656 , isAlgTyCon tycon -- It's a data type, tuple, or unboxed tuples.
657 , not (isNewTyCon tycon) -- We can have a newtype, if we are just doing an eval:
658 -- case x of { DEFAULT -> e }
659 -- and we don't want to fill in a default for them!
660 , Just all_cons <- tyConDataCons_maybe tycon
661 , let imposs_data_cons = mkUniqSet [con | DataAlt con <- imposs_deflt_cons]
662 -- We now know it's a data type, so we can use
663 -- UniqSet rather than Set (more efficient)
664 impossible con = con `elementOfUniqSet` imposs_data_cons
665 || dataConCannotMatch tys con
666 = case filterOut impossible all_cons of
667 -- Eliminate the default alternative
668 -- altogether if it can't match:
669 [] -> (False, rest_alts)
670
671 -- It matches exactly one constructor, so fill it in:
672 [con] -> (True, mergeAlts rest_alts [(DataAlt con, ex_tvs ++ arg_ids, rhs)])
673 -- We need the mergeAlts to keep the alternatives in the right order
674 where
675 (ex_tvs, arg_ids) = dataConRepInstPat us con tys
676
677 -- It matches more than one, so do nothing
678 _ -> (False, all_alts)
679
680 | debugIsOn, isAlgTyCon tycon, null (tyConDataCons tycon)
681 , not (isFamilyTyCon tycon || isAbstractTyCon tycon)
682 -- Check for no data constructors
683 -- This can legitimately happen for abstract types and type families,
684 -- so don't report that
685 = (False, all_alts)
686
687 | otherwise -- The common case
688 = (False, all_alts)
689
690 {- Note [Combine identical alternatives]
691 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
692 If several alternatives are identical, merge them into a single
693 DEFAULT alternative. I've occasionally seen this making a big
694 difference:
695
696 case e of =====> case e of
697 C _ -> f x D v -> ....v....
698 D v -> ....v.... DEFAULT -> f x
699 DEFAULT -> f x
700
701 The point is that we merge common RHSs, at least for the DEFAULT case.
702 [One could do something more elaborate but I've never seen it needed.]
703 To avoid an expensive test, we just merge branches equal to the *first*
704 alternative; this picks up the common cases
705 a) all branches equal
706 b) some branches equal to the DEFAULT (which occurs first)
707
708 The case where Combine Identical Alternatives transformation showed up
709 was like this (base/Foreign/C/Err/Error.hs):
710
711 x | p `is` 1 -> e1
712 | p `is` 2 -> e2
713 ...etc...
714
715 where @is@ was something like
716
717 p `is` n = p /= (-1) && p == n
718
719 This gave rise to a horrible sequence of cases
720
721 case p of
722 (-1) -> $j p
723 1 -> e1
724 DEFAULT -> $j p
725
726 and similarly in cascade for all the join points!
727
728 NB: it's important that all this is done in [InAlt], *before* we work
729 on the alternatives themselves, because Simplify.simplAlt may zap the
730 occurrence info on the binders in the alternatives, which in turn
731 defeats combineIdenticalAlts (see Trac #7360).
732
733 Note [Care with impossible-constructors when combining alternatives]
734 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
735 Suppose we have (Trac #10538)
736 data T = A | B | C | D
737
738 case x::T of (Imposs-default-cons {A,B})
739 DEFAULT -> e1
740 A -> e2
741 B -> e1
742
743 When calling combineIdentialAlts, we'll have computed that the
744 "impossible constructors" for the DEFAULT alt is {A,B}, since if x is
745 A or B we'll take the other alternatives. But suppose we combine B
746 into the DEFAULT, to get
747
748 case x::T of (Imposs-default-cons {A})
749 DEFAULT -> e1
750 A -> e2
751
752 Then we must be careful to trim the impossible constructors to just {A},
753 else we risk compiling 'e1' wrong!
754
755 Not only that, but we take care when there is no DEFAULT beforehand,
756 because we are introducing one. Consider
757
758 case x of (Imposs-default-cons {A,B,C})
759 A -> e1
760 B -> e2
761 C -> e1
762
763 Then when combining the A and C alternatives we get
764
765 case x of (Imposs-default-cons {B})
766 DEFAULT -> e1
767 B -> e2
768
769 Note that we have a new DEFAULT branch that we didn't have before. So
770 we need delete from the "impossible-default-constructors" all the
771 known-con alternatives that we have eliminated. (In Trac #11172 we
772 missed the first one.)
773
774 -}
775
776 combineIdenticalAlts :: [AltCon] -- Constructors that cannot match DEFAULT
777 -> [CoreAlt]
778 -> (Bool, -- True <=> something happened
779 [AltCon], -- New constructors that cannot match DEFAULT
780 [CoreAlt]) -- New alternatives
781 -- See Note [Combine identical alternatives]
782 -- True <=> we did some combining, result is a single DEFAULT alternative
783 combineIdenticalAlts imposs_deflt_cons ((con1,bndrs1,rhs1) : rest_alts)
784 | all isDeadBinder bndrs1 -- Remember the default
785 , not (null elim_rest) -- alternative comes first
786 = (True, imposs_deflt_cons', deflt_alt : filtered_rest)
787 where
788 (elim_rest, filtered_rest) = partition identical_to_alt1 rest_alts
789 deflt_alt = (DEFAULT, [], mkTicks (concat tickss) rhs1)
790
791 -- See Note [Care with impossible-constructors when combining alternatives]
792 imposs_deflt_cons' = imposs_deflt_cons `minusList` elim_cons
793 elim_cons = elim_con1 ++ map fstOf3 elim_rest
794 elim_con1 = case con1 of -- Don't forget con1!
795 DEFAULT -> [] -- See Note [
796 _ -> [con1]
797
798 cheapEqTicked e1 e2 = cheapEqExpr' tickishFloatable e1 e2
799 identical_to_alt1 (_con,bndrs,rhs)
800 = all isDeadBinder bndrs && rhs `cheapEqTicked` rhs1
801 tickss = map (stripTicksT tickishFloatable . thdOf3) elim_rest
802
803 combineIdenticalAlts imposs_cons alts
804 = (False, imposs_cons, alts)
805
806 {- *********************************************************************
807 * *
808 exprIsTrivial
809 * *
810 ************************************************************************
811
812 Note [exprIsTrivial]
813 ~~~~~~~~~~~~~~~~~~~~
814 @exprIsTrivial@ is true of expressions we are unconditionally happy to
815 duplicate; simple variables and constants, and type
816 applications. Note that primop Ids aren't considered
817 trivial unless
818
819 Note [Variables are trivial]
820 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
821 There used to be a gruesome test for (hasNoBinding v) in the
822 Var case:
823 exprIsTrivial (Var v) | hasNoBinding v = idArity v == 0
824 The idea here is that a constructor worker, like \$wJust, is
825 really short for (\x -> \$wJust x), because \$wJust has no binding.
826 So it should be treated like a lambda. Ditto unsaturated primops.
827 But now constructor workers are not "have-no-binding" Ids. And
828 completely un-applied primops and foreign-call Ids are sufficiently
829 rare that I plan to allow them to be duplicated and put up with
830 saturating them.
831
832 Note [Tick trivial]
833 ~~~~~~~~~~~~~~~~~~~
834 Ticks are only trivial if they are pure annotations. If we treat
835 "tick<n> x" as trivial, it will be inlined inside lambdas and the
836 entry count will be skewed, for example. Furthermore "scc<n> x" will
837 turn into just "x" in mkTick.
838
839 Note [Empty case is trivial]
840 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
841 The expression (case (x::Int) Bool of {}) is just a type-changing
842 case used when we are sure that 'x' will not return. See
843 Note [Empty case alternatives] in CoreSyn.
844
845 If the scrutinee is trivial, then so is the whole expression; and the
846 CoreToSTG pass in fact drops the case expression leaving only the
847 scrutinee.
848
849 Having more trivial expressions is good. Moreover, if we don't treat
850 it as trivial we may land up with let-bindings like
851 let v = case x of {} in ...
852 and after CoreToSTG that gives
853 let v = x in ...
854 and that confuses the code generator (Trac #11155). So best to kill
855 it off at source.
856 -}
857
858 exprIsTrivial :: CoreExpr -> Bool
859 exprIsTrivial (Var _) = True -- See Note [Variables are trivial]
860 exprIsTrivial (Type _) = True
861 exprIsTrivial (Coercion _) = True
862 exprIsTrivial (Lit lit) = litIsTrivial lit
863 exprIsTrivial (App e arg) = not (isRuntimeArg arg) && exprIsTrivial e
864 exprIsTrivial (Lam b e) = not (isRuntimeVar b) && exprIsTrivial e
865 exprIsTrivial (Tick t e) = not (tickishIsCode t) && exprIsTrivial e
866 -- See Note [Tick trivial]
867 exprIsTrivial (Cast e _) = exprIsTrivial e
868 exprIsTrivial (Case e _ _ []) = exprIsTrivial e -- See Note [Empty case is trivial]
869 exprIsTrivial _ = False
870
871 {-
872 Note [getIdFromTrivialExpr]
873 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
874 When substituting in a breakpoint we need to strip away the type cruft
875 from a trivial expression and get back to the Id. The invariant is
876 that the expression we're substituting was originally trivial
877 according to exprIsTrivial, AND the expression is not a literal.
878 See Note [substTickish] for how breakpoint substitution preserves
879 this extra invariant.
880
881 We also need this functionality in CorePrep to extract out Id of a
882 function which we are saturating. However, in this case we don't know
883 if the variable actually refers to a literal; thus we use
884 'getIdFromTrivialExpr_maybe' to handle this case. See test
885 T12076lit for an example where this matters.
886 -}
887
888 getIdFromTrivialExpr :: CoreExpr -> Id
889 getIdFromTrivialExpr e
890 = fromMaybe (pprPanic "getIdFromTrivialExpr" (ppr e))
891 (getIdFromTrivialExpr_maybe e)
892
893 getIdFromTrivialExpr_maybe :: CoreExpr -> Maybe Id
894 -- See Note [getIdFromTrivialExpr]
895 getIdFromTrivialExpr_maybe e = go e
896 where go (Var v) = Just v
897 go (App f t) | not (isRuntimeArg t) = go f
898 go (Tick t e) | not (tickishIsCode t) = go e
899 go (Cast e _) = go e
900 go (Lam b e) | not (isRuntimeVar b) = go e
901 go _ = Nothing
902
903 {-
904 exprIsBottom is a very cheap and cheerful function; it may return
905 False for bottoming expressions, but it never costs much to ask. See
906 also CoreArity.exprBotStrictness_maybe, but that's a bit more
907 expensive.
908 -}
909
910 exprIsBottom :: CoreExpr -> Bool
911 -- See Note [Bottoming expressions]
912 exprIsBottom e
913 | isEmptyTy (exprType e)
914 = True
915 | otherwise
916 = go 0 e
917 where
918 go n (Var v) = isBottomingId v && n >= idArity v
919 go n (App e a) | isTypeArg a = go n e
920 | otherwise = go (n+1) e
921 go n (Tick _ e) = go n e
922 go n (Cast e _) = go n e
923 go n (Let _ e) = go n e
924 go n (Lam v e) | isTyVar v = go n e
925 go _ (Case _ _ _ alts) = null alts
926 -- See Note [Empty case alternatives] in CoreSyn
927 go _ _ = False
928
929 {- Note [Bottoming expressions]
930 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
931 A bottoming expression is guaranteed to diverge, or raise an
932 exception. We can test for it in two different ways, and exprIsBottom
933 checks for both of these situations:
934
935 * Visibly-bottom computations. For example
936 (error Int "Hello")
937 is visibly bottom. The strictness analyser also finds out if
938 a function diverges or raises an exception, and puts that info
939 in its strictness signature.
940
941 * Empty types. If a type is empty, its only inhabitant is bottom.
942 For example:
943 data T
944 f :: T -> Bool
945 f = \(x:t). case x of Bool {}
946 Since T has no data constructors, the case alternatives are of course
947 empty. However note that 'x' is not bound to a visibly-bottom value;
948 it's the *type* that tells us it's going to diverge.
949
950 A GADT may also be empty even though it has constructors:
951 data T a where
952 T1 :: a -> T Bool
953 T2 :: T Int
954 ...(case (x::T Char) of {})...
955 Here (T Char) is uninhabited. A more realistic case is (Int ~ Bool),
956 which is likewise uninhabited.
957
958
959 ************************************************************************
960 * *
961 exprIsDupable
962 * *
963 ************************************************************************
964
965 Note [exprIsDupable]
966 ~~~~~~~~~~~~~~~~~~~~
967 @exprIsDupable@ is true of expressions that can be duplicated at a modest
968 cost in code size. This will only happen in different case
969 branches, so there's no issue about duplicating work.
970
971 That is, exprIsDupable returns True of (f x) even if
972 f is very very expensive to call.
973
974 Its only purpose is to avoid fruitless let-binding
975 and then inlining of case join points
976 -}
977
978 exprIsDupable :: DynFlags -> CoreExpr -> Bool
979 exprIsDupable dflags e
980 = isJust (go dupAppSize e)
981 where
982 go :: Int -> CoreExpr -> Maybe Int
983 go n (Type {}) = Just n
984 go n (Coercion {}) = Just n
985 go n (Var {}) = decrement n
986 go n (Tick _ e) = go n e
987 go n (Cast e _) = go n e
988 go n (App f a) | Just n' <- go n a = go n' f
989 go n (Lit lit) | litIsDupable dflags lit = decrement n
990 go _ _ = Nothing
991
992 decrement :: Int -> Maybe Int
993 decrement 0 = Nothing
994 decrement n = Just (n-1)
995
996 dupAppSize :: Int
997 dupAppSize = 8 -- Size of term we are prepared to duplicate
998 -- This is *just* big enough to make test MethSharing
999 -- inline enough join points. Really it should be
1000 -- smaller, and could be if we fixed Trac #4960.
1001
1002 {-
1003 ************************************************************************
1004 * *
1005 exprIsCheap, exprIsExpandable
1006 * *
1007 ************************************************************************
1008
1009 Note [exprIsWorkFree]
1010 ~~~~~~~~~~~~~~~~~~~~~
1011 exprIsWorkFree is used when deciding whether to inline something; we
1012 don't inline it if doing so might duplicate work, by peeling off a
1013 complete copy of the expression. Here we do not want even to
1014 duplicate a primop (Trac #5623):
1015 eg let x = a #+ b in x +# x
1016 we do not want to inline/duplicate x
1017
1018 Previously we were a bit more liberal, which led to the primop-duplicating
1019 problem. However, being more conservative did lead to a big regression in
1020 one nofib benchmark, wheel-sieve1. The situation looks like this:
1021
1022 let noFactor_sZ3 :: GHC.Types.Int -> GHC.Types.Bool
1023 noFactor_sZ3 = case s_adJ of _ { GHC.Types.I# x_aRs ->
1024 case GHC.Prim.<=# x_aRs 2 of _ {
1025 GHC.Types.False -> notDivBy ps_adM qs_adN;
1026 GHC.Types.True -> lvl_r2Eb }}
1027 go = \x. ...(noFactor (I# y))....(go x')...
1028
1029 The function 'noFactor' is heap-allocated and then called. Turns out
1030 that 'notDivBy' is strict in its THIRD arg, but that is invisible to
1031 the caller of noFactor, which therefore cannot do w/w and
1032 heap-allocates noFactor's argument. At the moment (May 12) we are just
1033 going to put up with this, because the previous more aggressive inlining
1034 (which treated 'noFactor' as work-free) was duplicating primops, which
1035 in turn was making inner loops of array calculations runs slow (#5623)
1036
1037 Note [Case expressions are work-free]
1038 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1039 Are case-expressions work-free? Consider
1040 let v = case x of (p,q) -> p
1041 go = \y -> ...case v of ...
1042 Should we inline 'v' at its use site inside the loop? At the moment
1043 we do. I experimented with saying that case are *not* work-free, but
1044 that increased allocation slightly. It's a fairly small effect, and at
1045 the moment we go for the slightly more aggressive version which treats
1046 (case x of ....) as work-free if the alternatives are.
1047
1048 Moreover it improves arities of overloaded functions where
1049 there is only dictionary selection (no construction) involved
1050
1051 Note [exprIsCheap] See also Note [Interaction of exprIsCheap and lone variables]
1052 ~~~~~~~~~~~~~~~~~~ in CoreUnfold.hs
1053 @exprIsCheap@ looks at a Core expression and returns \tr{True} if
1054 it is obviously in weak head normal form, or is cheap to get to WHNF.
1055 [Note that that's not the same as exprIsDupable; an expression might be
1056 big, and hence not dupable, but still cheap.]
1057
1058 By ``cheap'' we mean a computation we're willing to:
1059 push inside a lambda, or
1060 inline at more than one place
1061 That might mean it gets evaluated more than once, instead of being
1062 shared. The main examples of things which aren't WHNF but are
1063 ``cheap'' are:
1064
1065 * case e of
1066 pi -> ei
1067 (where e, and all the ei are cheap)
1068
1069 * let x = e in b
1070 (where e and b are cheap)
1071
1072 * op x1 ... xn
1073 (where op is a cheap primitive operator)
1074
1075 * error "foo"
1076 (because we are happy to substitute it inside a lambda)
1077
1078 Notice that a variable is considered 'cheap': we can push it inside a lambda,
1079 because sharing will make sure it is only evaluated once.
1080
1081 Note [exprIsCheap and exprIsHNF]
1082 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1083 Note that exprIsHNF does not imply exprIsCheap. Eg
1084 let x = fac 20 in Just x
1085 This responds True to exprIsHNF (you can discard a seq), but
1086 False to exprIsCheap.
1087
1088 Note [Arguments and let-bindings exprIsCheapX]
1089 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1090 What predicate should we apply to the argument of an application, or the
1091 RHS of a let-binding?
1092
1093 We used to say "exprIsTrivial arg" due to concerns about duplicating
1094 nested constructor applications, but see #4978. So now we just recursively
1095 use exprIsCheapX.
1096
1097 We definitely want to treat let and app the same. The principle here is
1098 that
1099 let x = blah in f x
1100 should behave equivalently to
1101 f blah
1102
1103 This in turn means that the 'letrec g' does not prevent eta expansion
1104 in this (which it previously was):
1105 f = \x. let v = case x of
1106 True -> letrec g = \w. blah
1107 in g
1108 False -> \x. x
1109 in \w. v True
1110 -}
1111
1112 --------------------
1113 exprIsWorkFree :: CoreExpr -> Bool -- See Note [exprIsWorkFree]
1114 exprIsWorkFree = exprIsCheapX isWorkFreeApp
1115
1116 exprIsCheap :: CoreExpr -> Bool
1117 exprIsCheap = exprIsCheapX isCheapApp
1118
1119 exprIsCheapX :: CheapAppFun -> CoreExpr -> Bool
1120 exprIsCheapX ok_app e
1121 = ok e
1122 where
1123 ok e = go 0 e
1124
1125 -- n is the number of value arguments
1126 go n (Var v) = ok_app v n
1127 go _ (Lit {}) = True
1128 go _ (Type {}) = True
1129 go _ (Coercion {}) = True
1130 go n (Cast e _) = go n e
1131 go n (Case scrut _ _ alts) = ok scrut &&
1132 and [ go n rhs | (_,_,rhs) <- alts ]
1133 go n (Tick t e) | tickishCounts t = False
1134 | otherwise = go n e
1135 go n (Lam x e) | isRuntimeVar x = n==0 || go (n-1) e
1136 | otherwise = go n e
1137 go n (App f e) | isRuntimeArg e = go (n+1) f && ok e
1138 | otherwise = go n f
1139 go n (Let (NonRec _ r) e) = go n e && ok r
1140 go n (Let (Rec prs) e) = go n e && all (ok . snd) prs
1141
1142 -- Case: see Note [Case expressions are work-free]
1143 -- App, Let: see Note [Arguments and let-bindings exprIsCheapX]
1144
1145
1146 {- Note [exprIsExpandable]
1147 ~~~~~~~~~~~~~~~~~~~~~~~~~~
1148 An expression is "expandable" if we are willing to duplicate it, if doing
1149 so might make a RULE or case-of-constructor fire. Consider
1150 let x = (a,b)
1151 y = build g
1152 in ....(case x of (p,q) -> rhs)....(foldr k z y)....
1153
1154 We don't inline 'x' or 'y' (see Note [Lone variables] in CoreUnfold),
1155 but we do want
1156
1157 * the case-expression to simplify
1158 (via exprIsConApp_maybe, exprIsLiteral_maybe)
1159
1160 * the foldr/build RULE to fire
1161 (by expanding the unfolding during rule matching)
1162
1163 So we classify the unfolding of a let-binding as "expandable" (via the
1164 uf_expandable field) if we want to do this kind of on-the-fly
1165 expansion. Specifically:
1166
1167 * True of constructor applications (K a b)
1168
1169 * True of applications of a "CONLIKE" Id; see Note [CONLIKE pragma] in BasicTypes.
1170 (NB: exprIsCheap might not be true of this)
1171
1172 * False of case-expressions. If we have
1173 let x = case ... in ...(case x of ...)...
1174 we won't simplify. We have to inline x. See Trac #14688.
1175
1176 * False of let-expressions (same reason); and in any case we
1177 float lets out of an RHS if doing so will reveal an expandable
1178 application (see SimplEnv.doFloatFromRhs).
1179
1180 * Take care: exprIsExpandable should /not/ be true of primops. I
1181 found this in test T5623a:
1182 let q = /\a. Ptr a (a +# b)
1183 in case q @ Float of Ptr v -> ...q...
1184
1185 q's inlining should not be expandable, else exprIsConApp_maybe will
1186 say that (q @ Float) expands to (Ptr a (a +# b)), and that will
1187 duplicate the (a +# b) primop, which we should not do lightly.
1188 (It's quite hard to trigger this bug, but T13155 does so for GHC 8.0.)
1189 -}
1190
1191 -------------------------------------
1192 exprIsExpandable :: CoreExpr -> Bool
1193 -- See Note [exprIsExpandable]
1194 exprIsExpandable e
1195 = ok e
1196 where
1197 ok e = go 0 e
1198
1199 -- n is the number of value arguments
1200 go n (Var v) = isExpandableApp v n
1201 go _ (Lit {}) = True
1202 go _ (Type {}) = True
1203 go _ (Coercion {}) = True
1204 go n (Cast e _) = go n e
1205 go n (Tick t e) | tickishCounts t = False
1206 | otherwise = go n e
1207 go n (Lam x e) | isRuntimeVar x = n==0 || go (n-1) e
1208 | otherwise = go n e
1209 go n (App f e) | isRuntimeArg e = go (n+1) f && ok e
1210 | otherwise = go n f
1211 go _ (Case {}) = False
1212 go _ (Let {}) = False
1213
1214
1215 -------------------------------------
1216 type CheapAppFun = Id -> Arity -> Bool
1217 -- Is an application of this function to n *value* args
1218 -- always cheap, assuming the arguments are cheap?
1219 -- True mainly of data constructors, partial applications;
1220 -- but with minor variations:
1221 -- isWorkFreeApp
1222 -- isCheapApp
1223 -- isExpandableApp
1224
1225 isWorkFreeApp :: CheapAppFun
1226 isWorkFreeApp fn n_val_args
1227 | n_val_args == 0 -- No value args
1228 = True
1229 | n_val_args < idArity fn -- Partial application
1230 = True
1231 | otherwise
1232 = case idDetails fn of
1233 DataConWorkId {} -> True
1234 _ -> False
1235
1236 isCheapApp :: CheapAppFun
1237 isCheapApp fn n_val_args
1238 | isWorkFreeApp fn n_val_args = True
1239 | isBottomingId fn = True -- See Note [isCheapApp: bottoming functions]
1240 | otherwise
1241 = case idDetails fn of
1242 DataConWorkId {} -> True -- Actually handled by isWorkFreeApp
1243 RecSelId {} -> n_val_args == 1 -- See Note [Record selection]
1244 ClassOpId {} -> n_val_args == 1
1245 PrimOpId op -> primOpIsCheap op
1246 _ -> False
1247 -- In principle we should worry about primops
1248 -- that return a type variable, since the result
1249 -- might be applied to something, but I'm not going
1250 -- to bother to check the number of args
1251
1252 isExpandableApp :: CheapAppFun
1253 isExpandableApp fn n_val_args
1254 | isWorkFreeApp fn n_val_args = True
1255 | otherwise
1256 = case idDetails fn of
1257 DataConWorkId {} -> True -- Actually handled by isWorkFreeApp
1258 RecSelId {} -> n_val_args == 1 -- See Note [Record selection]
1259 ClassOpId {} -> n_val_args == 1
1260 PrimOpId {} -> False
1261 _ | isBottomingId fn -> False
1262 -- See Note [isExpandableApp: bottoming functions]
1263 | isConLike (idRuleMatchInfo fn) -> True
1264 | all_args_are_preds -> True
1265 | otherwise -> False
1266
1267 where
1268 -- See if all the arguments are PredTys (implicit params or classes)
1269 -- If so we'll regard it as expandable; see Note [Expandable overloadings]
1270 all_args_are_preds = all_pred_args n_val_args (idType fn)
1271
1272 all_pred_args n_val_args ty
1273 | n_val_args == 0
1274 = True
1275
1276 | Just (bndr, ty) <- splitPiTy_maybe ty
1277 = caseBinder bndr
1278 (\_tv -> all_pred_args n_val_args ty)
1279 (\bndr_ty -> isPredTy bndr_ty && all_pred_args (n_val_args-1) ty)
1280
1281 | otherwise
1282 = False
1283
1284 {- Note [isCheapApp: bottoming functions]
1285 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1286 I'm not sure why we have a special case for bottoming
1287 functions in isCheapApp. Maybe we don't need it.
1288
1289 Note [isExpandableApp: bottoming functions]
1290 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1291 It's important that isExpandableApp does not respond True to bottoming
1292 functions. Recall undefined :: HasCallStack => a
1293 Suppose isExpandableApp responded True to (undefined d), and we had:
1294
1295 x = undefined <dict-expr>
1296
1297 Then Simplify.prepareRhs would ANF the RHS:
1298
1299 d = <dict-expr>
1300 x = undefined d
1301
1302 This is already bad: we gain nothing from having x bound to (undefined
1303 var), unlike the case for data constructors. Worse, we get the
1304 simplifier loop described in OccurAnal Note [Cascading inlines].
1305 Suppose x occurs just once; OccurAnal.occAnalNonRecRhs decides x will
1306 certainly_inline; so we end up inlining d right back into x; but in
1307 the end x doesn't inline because it is bottom (preInlineUnconditionally);
1308 so the process repeats.. We could elaborate the certainly_inline logic
1309 some more, but it's better just to treat bottoming bindings as
1310 non-expandable, because ANFing them is a bad idea in the first place.
1311
1312 Note [Record selection]
1313 ~~~~~~~~~~~~~~~~~~~~~~~~~~
1314 I'm experimenting with making record selection
1315 look cheap, so we will substitute it inside a
1316 lambda. Particularly for dictionary field selection.
1317
1318 BUT: Take care with (sel d x)! The (sel d) might be cheap, but
1319 there's no guarantee that (sel d x) will be too. Hence (n_val_args == 1)
1320
1321 Note [Expandable overloadings]
1322 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1323 Suppose the user wrote this
1324 {-# RULE forall x. foo (negate x) = h x #-}
1325 f x = ....(foo (negate x))....
1326 He'd expect the rule to fire. But since negate is overloaded, we might
1327 get this:
1328 f = \d -> let n = negate d in \x -> ...foo (n x)...
1329 So we treat the application of a function (negate in this case) to a
1330 *dictionary* as expandable. In effect, every function is CONLIKE when
1331 it's applied only to dictionaries.
1332
1333
1334 ************************************************************************
1335 * *
1336 exprOkForSpeculation
1337 * *
1338 ************************************************************************
1339 -}
1340
1341 -----------------------------
1342 -- | 'exprOkForSpeculation' returns True of an expression that is:
1343 --
1344 -- * Safe to evaluate even if normal order eval might not
1345 -- evaluate the expression at all, or
1346 --
1347 -- * Safe /not/ to evaluate even if normal order would do so
1348 --
1349 -- It is usually called on arguments of unlifted type, but not always
1350 -- In particular, Simplify.rebuildCase calls it on lifted types
1351 -- when a 'case' is a plain 'seq'. See the example in
1352 -- Note [exprOkForSpeculation: case expressions] below
1353 --
1354 -- Precisely, it returns @True@ iff:
1355 -- a) The expression guarantees to terminate,
1356 -- b) soon,
1357 -- c) without causing a write side effect (e.g. writing a mutable variable)
1358 -- d) without throwing a Haskell exception
1359 -- e) without risking an unchecked runtime exception (array out of bounds,
1360 -- divide by zero)
1361 --
1362 -- For @exprOkForSideEffects@ the list is the same, but omitting (e).
1363 --
1364 -- Note that
1365 -- exprIsHNF implies exprOkForSpeculation
1366 -- exprOkForSpeculation implies exprOkForSideEffects
1367 --
1368 -- See Note [PrimOp can_fail and has_side_effects] in PrimOp
1369 -- and Note [Transformations affected by can_fail and has_side_effects]
1370 --
1371 -- As an example of the considerations in this test, consider:
1372 --
1373 -- > let x = case y# +# 1# of { r# -> I# r# }
1374 -- > in E
1375 --
1376 -- being translated to:
1377 --
1378 -- > case y# +# 1# of { r# ->
1379 -- > let x = I# r#
1380 -- > in E
1381 -- > }
1382 --
1383 -- We can only do this if the @y + 1@ is ok for speculation: it has no
1384 -- side effects, and can't diverge or raise an exception.
1385
1386 exprOkForSpeculation, exprOkForSideEffects :: CoreExpr -> Bool
1387 exprOkForSpeculation = expr_ok primOpOkForSpeculation
1388 exprOkForSideEffects = expr_ok primOpOkForSideEffects
1389
1390 expr_ok :: (PrimOp -> Bool) -> CoreExpr -> Bool
1391 expr_ok _ (Lit _) = True
1392 expr_ok _ (Type _) = True
1393 expr_ok _ (Coercion _) = True
1394
1395 expr_ok primop_ok (Var v) = app_ok primop_ok v []
1396 expr_ok primop_ok (Cast e _) = expr_ok primop_ok e
1397 expr_ok primop_ok (Lam b e)
1398 | isTyVar b = expr_ok primop_ok e
1399 | otherwise = True
1400
1401
1402 -- Tick annotations that *tick* cannot be speculated, because these
1403 -- are meant to identify whether or not (and how often) the particular
1404 -- source expression was evaluated at runtime.
1405 expr_ok primop_ok (Tick tickish e)
1406 | tickishCounts tickish = False
1407 | otherwise = expr_ok primop_ok e
1408
1409 expr_ok _ (Let {}) = False
1410 -- Lets can be stacked deeply, so just give up.
1411 -- In any case, the argument of exprOkForSpeculation is
1412 -- usually in a strict context, so any lets will have been
1413 -- floated away.
1414
1415 expr_ok primop_ok (Case scrut bndr _ alts)
1416 = -- See Note [exprOkForSpeculation: case expressions]
1417 expr_ok primop_ok scrut
1418 && isUnliftedType (idType bndr)
1419 && all (\(_,_,rhs) -> expr_ok primop_ok rhs) alts
1420 && altsAreExhaustive alts
1421
1422 expr_ok primop_ok other_expr
1423 = case collectArgs other_expr of
1424 (expr, args) | Var f <- stripTicksTopE (not . tickishCounts) expr
1425 -> app_ok primop_ok f args
1426 _ -> False
1427
1428 -----------------------------
1429 app_ok :: (PrimOp -> Bool) -> Id -> [CoreExpr] -> Bool
1430 app_ok primop_ok fun args
1431 = case idDetails fun of
1432 DFunId new_type -> not new_type
1433 -- DFuns terminate, unless the dict is implemented
1434 -- with a newtype in which case they may not
1435
1436 DataConWorkId {} -> True
1437 -- The strictness of the constructor has already
1438 -- been expressed by its "wrapper", so we don't need
1439 -- to take the arguments into account
1440
1441 PrimOpId op
1442 | isDivOp op
1443 , [arg1, Lit lit] <- args
1444 -> not (isZeroLit lit) && expr_ok primop_ok arg1
1445 -- Special case for dividing operations that fail
1446 -- In general they are NOT ok-for-speculation
1447 -- (which primop_ok will catch), but they ARE OK
1448 -- if the divisor is definitely non-zero.
1449 -- Often there is a literal divisor, and this
1450 -- can get rid of a thunk in an inner loop
1451
1452 | SeqOp <- op -- See Note [seq# and expr_ok]
1453 -> all (expr_ok primop_ok) args
1454
1455 | otherwise
1456 -> primop_ok op -- Check the primop itself
1457 && and (zipWith arg_ok arg_tys args) -- Check the arguments
1458
1459 _other -> isUnliftedType (idType fun) -- c.f. the Var case of exprIsHNF
1460 || idArity fun > n_val_args -- Partial apps
1461 || (n_val_args == 0 &&
1462 isEvaldUnfolding (idUnfolding fun)) -- Let-bound values
1463 where
1464 n_val_args = valArgCount args
1465 where
1466 (arg_tys, _) = splitPiTys (idType fun)
1467
1468 arg_ok :: TyBinder -> CoreExpr -> Bool
1469 arg_ok (Named _) _ = True -- A type argument
1470 arg_ok (Anon ty) arg -- A term argument
1471 | isUnliftedType ty = expr_ok primop_ok arg
1472 | otherwise = True -- See Note [Primops with lifted arguments]
1473
1474 -----------------------------
1475 altsAreExhaustive :: [Alt b] -> Bool
1476 -- True <=> the case alternatives are definiely exhaustive
1477 -- False <=> they may or may not be
1478 altsAreExhaustive []
1479 = False -- Should not happen
1480 altsAreExhaustive ((con1,_,_) : alts)
1481 = case con1 of
1482 DEFAULT -> True
1483 LitAlt {} -> False
1484 DataAlt c -> alts `lengthIs` (tyConFamilySize (dataConTyCon c) - 1)
1485 -- It is possible to have an exhaustive case that does not
1486 -- enumerate all constructors, notably in a GADT match, but
1487 -- we behave conservatively here -- I don't think it's important
1488 -- enough to deserve special treatment
1489
1490 -- | True of dyadic operators that can fail only if the second arg is zero!
1491 isDivOp :: PrimOp -> Bool
1492 -- This function probably belongs in PrimOp, or even in
1493 -- an automagically generated file.. but it's such a
1494 -- special case I thought I'd leave it here for now.
1495 isDivOp IntQuotOp = True
1496 isDivOp IntRemOp = True
1497 isDivOp WordQuotOp = True
1498 isDivOp WordRemOp = True
1499 isDivOp FloatDivOp = True
1500 isDivOp DoubleDivOp = True
1501 isDivOp _ = False
1502
1503 {- Note [exprOkForSpeculation: case expressions]
1504 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1505 exprOkForSpeculation accepts very special case expressions.
1506 Reason: (a ==# b) is ok-for-speculation, but the litEq rules
1507 in PrelRules convert it (a ==# 3#) to
1508 case a of { DEAFULT -> 0#; 3# -> 1# }
1509 for excellent reasons described in
1510 PrelRules Note [The litEq rule: converting equality to case].
1511 So, annoyingly, we want that case expression to be
1512 ok-for-speculation too. Bother.
1513
1514 But we restrict it sharply:
1515
1516 * We restrict it to unlifted scrutinees. Consider this:
1517 case x of y {
1518 DEFAULT -> ... (let v::Int# = case y of { True -> e1
1519 ; False -> e2 }
1520 in ...) ...
1521
1522 Does the RHS of v satisfy the let/app invariant? Previously we said
1523 yes, on the grounds that y is evaluated. But the binder-swap done
1524 by SetLevels would transform the inner alternative to
1525 DEFAULT -> ... (let v::Int# = case x of { ... }
1526 in ...) ....
1527 which does /not/ satisfy the let/app invariant, because x is
1528 not evaluated. See Note [Binder-swap during float-out]
1529 in SetLevels. To avoid this awkwardness it seems simpler
1530 to stick to unlifted scrutinees where the issue does not
1531 arise.
1532
1533 * We restrict it to exhaustive alternatives. A non-exhaustive
1534 case manifestly isn't ok-for-speculation. Consider
1535 case e of x { DEAFULT ->
1536 ...(case x of y
1537 A -> ...
1538 _ -> ...(case (case x of { B -> p; C -> p }) of
1539 I# r -> blah)...
1540 If SetLevesls considers the inner nested case as ok-for-speculation
1541 it can do case-floating (see Note [Floating cases] in SetLevels).
1542 So we'd float to:
1543 case e of x { DEAFULT ->
1544 case (case x of { B -> p; C -> p }) of I# r ->
1545 ...(case x of y
1546 A -> ...
1547 _ -> ...blah...)...
1548 which is utterly bogus (seg fault); see Trac #5453.
1549
1550 Similarly, this is a valid program (albeit a slightly dodgy one)
1551 let v = case x of { B -> ...; C -> ... }
1552 in case x of
1553 A -> ...
1554 _ -> ...v...v....
1555 Should v be considered ok-for-speculation? Its scrutinee may be
1556 evaluated, but the alternatives are incomplete so we should not
1557 evaluate it strictly.
1558
1559 Now, all this is for lifted types, but it'd be the same for any
1560 finite unlifted type. We don't have many of them, but we might
1561 add unlifted algebraic types in due course.
1562
1563 ----- Historical note: Trac #3717: --------
1564 foo :: Int -> Int
1565 foo 0 = 0
1566 foo n = (if n < 5 then 1 else 2) `seq` foo (n-1)
1567
1568 In earlier GHCs, we got this:
1569 T.$wfoo =
1570 \ (ww :: GHC.Prim.Int#) ->
1571 case ww of ds {
1572 __DEFAULT -> case (case <# ds 5 of _ {
1573 GHC.Types.False -> lvl1;
1574 GHC.Types.True -> lvl})
1575 of _ { __DEFAULT ->
1576 T.$wfoo (GHC.Prim.-# ds_XkE 1) };
1577 0 -> 0 }
1578
1579 Before join-points etc we could only get rid of two cases (which are
1580 redundant) by recognising that th e(case <# ds 5 of { ... }) is
1581 ok-for-speculation, even though it has /lifted/ type. But now join
1582 points do the job nicely.
1583 ------- End of historical note ------------
1584
1585
1586 Note [Primops with lifted arguments]
1587 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1588 Is this ok-for-speculation (see Trac #13027)?
1589 reallyUnsafePtrEq# a b
1590 Well, yes. The primop accepts lifted arguments and does not
1591 evaluate them. Indeed, in general primops are, well, primitive
1592 and do not perform evaluation.
1593
1594 There is one primop, dataToTag#, which does /require/ a lifted
1595 argument to be evaluated. To ensure this, CorePrep adds an
1596 eval if it can't see the argument is definitely evaluated
1597 (see [dataToTag magic] in CorePrep).
1598
1599 We make no attempt to guarantee that dataToTag#'s argument is
1600 evaluated here. Main reason: it's very fragile to test for the
1601 evaluatedness of a lifted argument. Consider
1602 case x of y -> let v = dataToTag# y in ...
1603
1604 where x/y have type Int, say. 'y' looks evaluated (by the enclosing
1605 case) so all is well. Now the FloatOut pass does a binder-swap (for
1606 very good reasons), changing to
1607 case x of y -> let v = dataToTag# x in ...
1608
1609 See also Note [dataToTag#] in primops.txt.pp.
1610
1611 Bottom line:
1612 * in exprOkForSpeculation we simply ignore all lifted arguments.
1613 * except see Note [seq# and expr_ok] for an exception
1614
1615
1616 Note [seq# and expr_ok]
1617 ~~~~~~~~~~~~~~~~~~~~~~~
1618 Recall that
1619 seq# :: forall a s . a -> State# s -> (# State# s, a #)
1620 must always evaluate its first argument. So it's really a
1621 counter-example to Note [Primops with lifted arguments]. In
1622 the case of seq# we must check the argument to seq#. Remember
1623 item (d) of the specification of exprOkForSpeculation:
1624
1625 -- Precisely, it returns @True@ iff:
1626 -- a) The expression guarantees to terminate,
1627 ...
1628 -- d) without throwing a Haskell exception
1629
1630 The lack of this special case caused Trac #5129 to go bad again.
1631 See comment:24 and following
1632
1633
1634 ************************************************************************
1635 * *
1636 exprIsHNF, exprIsConLike
1637 * *
1638 ************************************************************************
1639 -}
1640
1641 -- Note [exprIsHNF] See also Note [exprIsCheap and exprIsHNF]
1642 -- ~~~~~~~~~~~~~~~~
1643 -- | exprIsHNF returns true for expressions that are certainly /already/
1644 -- evaluated to /head/ normal form. This is used to decide whether it's ok
1645 -- to change:
1646 --
1647 -- > case x of _ -> e
1648 --
1649 -- into:
1650 --
1651 -- > e
1652 --
1653 -- and to decide whether it's safe to discard a 'seq'.
1654 --
1655 -- So, it does /not/ treat variables as evaluated, unless they say they are.
1656 -- However, it /does/ treat partial applications and constructor applications
1657 -- as values, even if their arguments are non-trivial, provided the argument
1658 -- type is lifted. For example, both of these are values:
1659 --
1660 -- > (:) (f x) (map f xs)
1661 -- > map (...redex...)
1662 --
1663 -- because 'seq' on such things completes immediately.
1664 --
1665 -- For unlifted argument types, we have to be careful:
1666 --
1667 -- > C (f x :: Int#)
1668 --
1669 -- Suppose @f x@ diverges; then @C (f x)@ is not a value. However this can't
1670 -- happen: see "CoreSyn#let_app_invariant". This invariant states that arguments of
1671 -- unboxed type must be ok-for-speculation (or trivial).
1672 exprIsHNF :: CoreExpr -> Bool -- True => Value-lambda, constructor, PAP
1673 exprIsHNF = exprIsHNFlike isDataConWorkId isEvaldUnfolding
1674
1675 -- | Similar to 'exprIsHNF' but includes CONLIKE functions as well as
1676 -- data constructors. Conlike arguments are considered interesting by the
1677 -- inliner.
1678 exprIsConLike :: CoreExpr -> Bool -- True => lambda, conlike, PAP
1679 exprIsConLike = exprIsHNFlike isConLikeId isConLikeUnfolding
1680
1681 -- | Returns true for values or value-like expressions. These are lambdas,
1682 -- constructors / CONLIKE functions (as determined by the function argument)
1683 -- or PAPs.
1684 --
1685 exprIsHNFlike :: (Var -> Bool) -> (Unfolding -> Bool) -> CoreExpr -> Bool
1686 exprIsHNFlike is_con is_con_unf = is_hnf_like
1687 where
1688 is_hnf_like (Var v) -- NB: There are no value args at this point
1689 = id_app_is_value v 0 -- Catches nullary constructors,
1690 -- so that [] and () are values, for example
1691 -- and (e.g.) primops that don't have unfoldings
1692 || is_con_unf (idUnfolding v)
1693 -- Check the thing's unfolding; it might be bound to a value
1694 -- We don't look through loop breakers here, which is a bit conservative
1695 -- but otherwise I worry that if an Id's unfolding is just itself,
1696 -- we could get an infinite loop
1697
1698 is_hnf_like (Lit _) = True
1699 is_hnf_like (Type _) = True -- Types are honorary Values;
1700 -- we don't mind copying them
1701 is_hnf_like (Coercion _) = True -- Same for coercions
1702 is_hnf_like (Lam b e) = isRuntimeVar b || is_hnf_like e
1703 is_hnf_like (Tick tickish e) = not (tickishCounts tickish)
1704 && is_hnf_like e
1705 -- See Note [exprIsHNF Tick]
1706 is_hnf_like (Cast e _) = is_hnf_like e
1707 is_hnf_like (App e a)
1708 | isValArg a = app_is_value e 1
1709 | otherwise = is_hnf_like e
1710 is_hnf_like (Let _ e) = is_hnf_like e -- Lazy let(rec)s don't affect us
1711 is_hnf_like _ = False
1712
1713 -- There is at least one value argument
1714 -- 'n' is number of value args to which the expression is applied
1715 app_is_value :: CoreExpr -> Int -> Bool
1716 app_is_value (Var f) nva = id_app_is_value f nva
1717 app_is_value (Tick _ f) nva = app_is_value f nva
1718 app_is_value (Cast f _) nva = app_is_value f nva
1719 app_is_value (App f a) nva
1720 | isValArg a = app_is_value f (nva + 1)
1721 | otherwise = app_is_value f nva
1722 app_is_value _ _ = False
1723
1724 id_app_is_value id n_val_args
1725 = is_con id
1726 || idArity id > n_val_args
1727 || id `hasKey` absentErrorIdKey -- See Note [aBSENT_ERROR_ID] in MkCore
1728 -- absentError behaves like an honorary data constructor
1729
1730
1731 {-
1732 Note [exprIsHNF Tick]
1733
1734 We can discard source annotations on HNFs as long as they aren't
1735 tick-like:
1736
1737 scc c (\x . e) => \x . e
1738 scc c (C x1..xn) => C x1..xn
1739
1740 So we regard these as HNFs. Tick annotations that tick are not
1741 regarded as HNF if the expression they surround is HNF, because the
1742 tick is there to tell us that the expression was evaluated, so we
1743 don't want to discard a seq on it.
1744 -}
1745
1746 -- | Can we bind this 'CoreExpr' at the top level?
1747 exprIsTopLevelBindable :: CoreExpr -> Type -> Bool
1748 -- See Note [CoreSyn top-level string literals]
1749 -- Precondition: exprType expr = ty
1750 -- Top-level literal strings can't even be wrapped in ticks
1751 -- see Note [CoreSyn top-level string literals] in CoreSyn
1752 exprIsTopLevelBindable expr ty
1753 = not (isUnliftedType ty)
1754 || exprIsTickedString expr
1755
1756 -- | Check if the expression is zero or more Ticks wrapped around a literal
1757 -- string.
1758 exprIsTickedString :: CoreExpr -> Bool
1759 exprIsTickedString = isJust . exprIsTickedString_maybe
1760
1761 -- | Extract a literal string from an expression that is zero or more Ticks
1762 -- wrapped around a literal string. Returns Nothing if the expression has a
1763 -- different shape.
1764 -- Used to "look through" Ticks in places that need to handle literal strings.
1765 exprIsTickedString_maybe :: CoreExpr -> Maybe ByteString
1766 exprIsTickedString_maybe (Lit (MachStr bs)) = Just bs
1767 exprIsTickedString_maybe (Tick t e)
1768 -- we don't tick literals with CostCentre ticks, compare to mkTick
1769 | tickishPlace t == PlaceCostCentre = Nothing
1770 | otherwise = exprIsTickedString_maybe e
1771 exprIsTickedString_maybe _ = Nothing
1772
1773 {-
1774 ************************************************************************
1775 * *
1776 Instantiating data constructors
1777 * *
1778 ************************************************************************
1779
1780 These InstPat functions go here to avoid circularity between DataCon and Id
1781 -}
1782
1783 dataConRepInstPat :: [Unique] -> DataCon -> [Type] -> ([TyVar], [Id])
1784 dataConRepFSInstPat :: [FastString] -> [Unique] -> DataCon -> [Type] -> ([TyVar], [Id])
1785
1786 dataConRepInstPat = dataConInstPat (repeat ((fsLit "ipv")))
1787 dataConRepFSInstPat = dataConInstPat
1788
1789 dataConInstPat :: [FastString] -- A long enough list of FSs to use for names
1790 -> [Unique] -- An equally long list of uniques, at least one for each binder
1791 -> DataCon
1792 -> [Type] -- Types to instantiate the universally quantified tyvars
1793 -> ([TyVar], [Id]) -- Return instantiated variables
1794 -- dataConInstPat arg_fun fss us con inst_tys returns a tuple
1795 -- (ex_tvs, arg_ids),
1796 --
1797 -- ex_tvs are intended to be used as binders for existential type args
1798 --
1799 -- arg_ids are indended to be used as binders for value arguments,
1800 -- and their types have been instantiated with inst_tys and ex_tys
1801 -- The arg_ids include both evidence and
1802 -- programmer-specified arguments (both after rep-ing)
1803 --
1804 -- Example.
1805 -- The following constructor T1
1806 --
1807 -- data T a where
1808 -- T1 :: forall b. Int -> b -> T(a,b)
1809 -- ...
1810 --
1811 -- has representation type
1812 -- forall a. forall a1. forall b. (a ~ (a1,b)) =>
1813 -- Int -> b -> T a
1814 --
1815 -- dataConInstPat fss us T1 (a1',b') will return
1816 --
1817 -- ([a1'', b''], [c :: (a1', b')~(a1'', b''), x :: Int, y :: b''])
1818 --
1819 -- where the double-primed variables are created with the FastStrings and
1820 -- Uniques given as fss and us
1821 dataConInstPat fss uniqs con inst_tys
1822 = ASSERT( univ_tvs `equalLength` inst_tys )
1823 (ex_bndrs, arg_ids)
1824 where
1825 univ_tvs = dataConUnivTyVars con
1826 ex_tvs = dataConExTyVars con
1827 arg_tys = dataConRepArgTys con
1828 arg_strs = dataConRepStrictness con -- 1-1 with arg_tys
1829 n_ex = length ex_tvs
1830
1831 -- split the Uniques and FastStrings
1832 (ex_uniqs, id_uniqs) = splitAt n_ex uniqs
1833 (ex_fss, id_fss) = splitAt n_ex fss
1834
1835 -- Make the instantiating substitution for universals
1836 univ_subst = zipTvSubst univ_tvs inst_tys
1837
1838 -- Make existential type variables, applying and extending the substitution
1839 (full_subst, ex_bndrs) = mapAccumL mk_ex_var univ_subst
1840 (zip3 ex_tvs ex_fss ex_uniqs)
1841
1842 mk_ex_var :: TCvSubst -> (TyVar, FastString, Unique) -> (TCvSubst, TyVar)
1843 mk_ex_var subst (tv, fs, uniq) = (Type.extendTvSubstWithClone subst tv
1844 new_tv
1845 , new_tv)
1846 where
1847 new_tv = mkTyVar (mkSysTvName uniq fs) kind
1848 kind = Type.substTyUnchecked subst (tyVarKind tv)
1849
1850 -- Make value vars, instantiating types
1851 arg_ids = zipWith4 mk_id_var id_uniqs id_fss arg_tys arg_strs
1852 mk_id_var uniq fs ty str
1853 = setCaseBndrEvald str $ -- See Note [Mark evaluated arguments]
1854 mkLocalIdOrCoVar name (Type.substTy full_subst ty)
1855 where
1856 name = mkInternalName uniq (mkVarOccFS fs) noSrcSpan
1857
1858 {-
1859 Note [Mark evaluated arguments]
1860 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1861 When pattern matching on a constructor with strict fields, the binder
1862 can have an 'evaldUnfolding'. Moreover, it *should* have one, so that
1863 when loading an interface file unfolding like:
1864 data T = MkT !Int
1865 f x = case x of { MkT y -> let v::Int# = case y of I# n -> n+1
1866 in ... }
1867 we don't want Lint to complain. The 'y' is evaluated, so the
1868 case in the RHS of the binding for 'v' is fine. But only if we
1869 *know* that 'y' is evaluated.
1870
1871 c.f. add_evals in Simplify.simplAlt
1872
1873 ************************************************************************
1874 * *
1875 Equality
1876 * *
1877 ************************************************************************
1878 -}
1879
1880 -- | A cheap equality test which bales out fast!
1881 -- If it returns @True@ the arguments are definitely equal,
1882 -- otherwise, they may or may not be equal.
1883 --
1884 -- See also 'exprIsBig'
1885 cheapEqExpr :: Expr b -> Expr b -> Bool
1886 cheapEqExpr = cheapEqExpr' (const False)
1887
1888 -- | Cheap expression equality test, can ignore ticks by type.
1889 cheapEqExpr' :: (Tickish Id -> Bool) -> Expr b -> Expr b -> Bool
1890 cheapEqExpr' ignoreTick = go_s
1891 where go_s = go `on` stripTicksTopE ignoreTick
1892 go (Var v1) (Var v2) = v1 == v2
1893 go (Lit lit1) (Lit lit2) = lit1 == lit2
1894 go (Type t1) (Type t2) = t1 `eqType` t2
1895 go (Coercion c1) (Coercion c2) = c1 `eqCoercion` c2
1896
1897 go (App f1 a1) (App f2 a2)
1898 = f1 `go_s` f2 && a1 `go_s` a2
1899
1900 go (Cast e1 t1) (Cast e2 t2)
1901 = e1 `go_s` e2 && t1 `eqCoercion` t2
1902
1903 go (Tick t1 e1) (Tick t2 e2)
1904 = t1 == t2 && e1 `go_s` e2
1905
1906 go _ _ = False
1907 {-# INLINE go #-}
1908 {-# INLINE cheapEqExpr' #-}
1909
1910 exprIsBig :: Expr b -> Bool
1911 -- ^ Returns @True@ of expressions that are too big to be compared by 'cheapEqExpr'
1912 exprIsBig (Lit _) = False
1913 exprIsBig (Var _) = False
1914 exprIsBig (Type _) = False
1915 exprIsBig (Coercion _) = False
1916 exprIsBig (Lam _ e) = exprIsBig e
1917 exprIsBig (App f a) = exprIsBig f || exprIsBig a
1918 exprIsBig (Cast e _) = exprIsBig e -- Hopefully coercions are not too big!
1919 exprIsBig (Tick _ e) = exprIsBig e
1920 exprIsBig _ = True
1921
1922 eqExpr :: InScopeSet -> CoreExpr -> CoreExpr -> Bool
1923 -- Compares for equality, modulo alpha
1924 eqExpr in_scope e1 e2
1925 = go (mkRnEnv2 in_scope) e1 e2
1926 where
1927 go env (Var v1) (Var v2)
1928 | rnOccL env v1 == rnOccR env v2
1929 = True
1930
1931 go _ (Lit lit1) (Lit lit2) = lit1 == lit2
1932 go env (Type t1) (Type t2) = eqTypeX env t1 t2
1933 go env (Coercion co1) (Coercion co2) = eqCoercionX env co1 co2
1934 go env (Cast e1 co1) (Cast e2 co2) = eqCoercionX env co1 co2 && go env e1 e2
1935 go env (App f1 a1) (App f2 a2) = go env f1 f2 && go env a1 a2
1936 go env (Tick n1 e1) (Tick n2 e2) = eqTickish env n1 n2 && go env e1 e2
1937
1938 go env (Lam b1 e1) (Lam b2 e2)
1939 = eqTypeX env (varType b1) (varType b2) -- False for Id/TyVar combination
1940 && go (rnBndr2 env b1 b2) e1 e2
1941
1942 go env (Let (NonRec v1 r1) e1) (Let (NonRec v2 r2) e2)
1943 = go env r1 r2 -- No need to check binder types, since RHSs match
1944 && go (rnBndr2 env v1 v2) e1 e2
1945
1946 go env (Let (Rec ps1) e1) (Let (Rec ps2) e2)
1947 = equalLength ps1 ps2
1948 && all2 (go env') rs1 rs2 && go env' e1 e2
1949 where
1950 (bs1,rs1) = unzip ps1
1951 (bs2,rs2) = unzip ps2
1952 env' = rnBndrs2 env bs1 bs2
1953
1954 go env (Case e1 b1 t1 a1) (Case e2 b2 t2 a2)
1955 | null a1 -- See Note [Empty case alternatives] in TrieMap
1956 = null a2 && go env e1 e2 && eqTypeX env t1 t2
1957 | otherwise
1958 = go env e1 e2 && all2 (go_alt (rnBndr2 env b1 b2)) a1 a2
1959
1960 go _ _ _ = False
1961
1962 -----------
1963 go_alt env (c1, bs1, e1) (c2, bs2, e2)
1964 = c1 == c2 && go (rnBndrs2 env bs1 bs2) e1 e2
1965
1966 eqTickish :: RnEnv2 -> Tickish Id -> Tickish Id -> Bool
1967 eqTickish env (Breakpoint lid lids) (Breakpoint rid rids)
1968 = lid == rid && map (rnOccL env) lids == map (rnOccR env) rids
1969 eqTickish _ l r = l == r
1970
1971 -- | Finds differences between core expressions, modulo alpha and
1972 -- renaming. Setting @top@ means that the @IdInfo@ of bindings will be
1973 -- checked for differences as well.
1974 diffExpr :: Bool -> RnEnv2 -> CoreExpr -> CoreExpr -> [SDoc]
1975 diffExpr _ env (Var v1) (Var v2) | rnOccL env v1 == rnOccR env v2 = []
1976 diffExpr _ _ (Lit lit1) (Lit lit2) | lit1 == lit2 = []
1977 diffExpr _ env (Type t1) (Type t2) | eqTypeX env t1 t2 = []
1978 diffExpr _ env (Coercion co1) (Coercion co2)
1979 | eqCoercionX env co1 co2 = []
1980 diffExpr top env (Cast e1 co1) (Cast e2 co2)
1981 | eqCoercionX env co1 co2 = diffExpr top env e1 e2
1982 diffExpr top env (Tick n1 e1) e2
1983 | not (tickishIsCode n1) = diffExpr top env e1 e2
1984 diffExpr top env e1 (Tick n2 e2)
1985 | not (tickishIsCode n2) = diffExpr top env e1 e2
1986 diffExpr top env (Tick n1 e1) (Tick n2 e2)
1987 | eqTickish env n1 n2 = diffExpr top env e1 e2
1988 -- The error message of failed pattern matches will contain
1989 -- generated names, which are allowed to differ.
1990 diffExpr _ _ (App (App (Var absent) _) _)
1991 (App (App (Var absent2) _) _)
1992 | isBottomingId absent && isBottomingId absent2 = []
1993 diffExpr top env (App f1 a1) (App f2 a2)
1994 = diffExpr top env f1 f2 ++ diffExpr top env a1 a2
1995 diffExpr top env (Lam b1 e1) (Lam b2 e2)
1996 | eqTypeX env (varType b1) (varType b2) -- False for Id/TyVar combination
1997 = diffExpr top (rnBndr2 env b1 b2) e1 e2
1998 diffExpr top env (Let bs1 e1) (Let bs2 e2)
1999 = let (ds, env') = diffBinds top env (flattenBinds [bs1]) (flattenBinds [bs2])
2000 in ds ++ diffExpr top env' e1 e2
2001 diffExpr top env (Case e1 b1 t1 a1) (Case e2 b2 t2 a2)
2002 | equalLength a1 a2 && not (null a1) || eqTypeX env t1 t2
2003 -- See Note [Empty case alternatives] in TrieMap
2004 = diffExpr top env e1 e2 ++ concat (zipWith diffAlt a1 a2)
2005 where env' = rnBndr2 env b1 b2
2006 diffAlt (c1, bs1, e1) (c2, bs2, e2)
2007 | c1 /= c2 = [text "alt-cons " <> ppr c1 <> text " /= " <> ppr c2]
2008 | otherwise = diffExpr top (rnBndrs2 env' bs1 bs2) e1 e2
2009 diffExpr _ _ e1 e2
2010 = [fsep [ppr e1, text "/=", ppr e2]]
2011
2012 -- | Finds differences between core bindings, see @diffExpr@.
2013 --
2014 -- The main problem here is that while we expect the binds to have the
2015 -- same order in both lists, this is not guaranteed. To do this
2016 -- properly we'd either have to do some sort of unification or check
2017 -- all possible mappings, which would be seriously expensive. So
2018 -- instead we simply match single bindings as far as we can. This
2019 -- leaves us just with mutually recursive and/or mismatching bindings,
2020 -- which we then speculatively match by ordering them. It's by no means
2021 -- perfect, but gets the job done well enough.
2022 diffBinds :: Bool -> RnEnv2 -> [(Var, CoreExpr)] -> [(Var, CoreExpr)]
2023 -> ([SDoc], RnEnv2)
2024 diffBinds top env binds1 = go (length binds1) env binds1
2025 where go _ env [] []
2026 = ([], env)
2027 go fuel env binds1 binds2
2028 -- No binds left to compare? Bail out early.
2029 | null binds1 || null binds2
2030 = (warn env binds1 binds2, env)
2031 -- Iterated over all binds without finding a match? Then
2032 -- try speculatively matching binders by order.
2033 | fuel == 0
2034 = if not $ env `inRnEnvL` fst (head binds1)
2035 then let env' = uncurry (rnBndrs2 env) $ unzip $
2036 zip (sort $ map fst binds1) (sort $ map fst binds2)
2037 in go (length binds1) env' binds1 binds2
2038 -- If we have already tried that, give up
2039 else (warn env binds1 binds2, env)
2040 go fuel env ((bndr1,expr1):binds1) binds2
2041 | let matchExpr (bndr,expr) =
2042 (not top || null (diffIdInfo env bndr bndr1)) &&
2043 null (diffExpr top (rnBndr2 env bndr1 bndr) expr1 expr)
2044 , (binds2l, (bndr2,_):binds2r) <- break matchExpr binds2
2045 = go (length binds1) (rnBndr2 env bndr1 bndr2)
2046 binds1 (binds2l ++ binds2r)
2047 | otherwise -- No match, so push back (FIXME O(n^2))
2048 = go (fuel-1) env (binds1++[(bndr1,expr1)]) binds2
2049 go _ _ _ _ = panic "diffBinds: impossible" -- GHC isn't smart enough
2050
2051 -- We have tried everything, but couldn't find a good match. So
2052 -- now we just return the comparison results when we pair up
2053 -- the binds in a pseudo-random order.
2054 warn env binds1 binds2 =
2055 concatMap (uncurry (diffBind env)) (zip binds1' binds2') ++
2056 unmatched "unmatched left-hand:" (drop l binds1') ++
2057 unmatched "unmatched right-hand:" (drop l binds2')
2058 where binds1' = sortBy (comparing fst) binds1
2059 binds2' = sortBy (comparing fst) binds2
2060 l = min (length binds1') (length binds2')
2061 unmatched _ [] = []
2062 unmatched txt bs = [text txt $$ ppr (Rec bs)]
2063 diffBind env (bndr1,expr1) (bndr2,expr2)
2064 | ds@(_:_) <- diffExpr top env expr1 expr2
2065 = locBind "in binding" bndr1 bndr2 ds
2066 | otherwise
2067 = diffIdInfo env bndr1 bndr2
2068
2069 -- | Find differences in @IdInfo@. We will especially check whether
2070 -- the unfoldings match, if present (see @diffUnfold@).
2071 diffIdInfo :: RnEnv2 -> Var -> Var -> [SDoc]
2072 diffIdInfo env bndr1 bndr2
2073 | arityInfo info1 == arityInfo info2
2074 && cafInfo info1 == cafInfo info2
2075 && oneShotInfo info1 == oneShotInfo info2
2076 && inlinePragInfo info1 == inlinePragInfo info2
2077 && occInfo info1 == occInfo info2
2078 && demandInfo info1 == demandInfo info2
2079 && callArityInfo info1 == callArityInfo info2
2080 && levityInfo info1 == levityInfo info2
2081 = locBind "in unfolding of" bndr1 bndr2 $
2082 diffUnfold env (unfoldingInfo info1) (unfoldingInfo info2)
2083 | otherwise
2084 = locBind "in Id info of" bndr1 bndr2
2085 [fsep [pprBndr LetBind bndr1, text "/=", pprBndr LetBind bndr2]]
2086 where info1 = idInfo bndr1; info2 = idInfo bndr2
2087
2088 -- | Find differences in unfoldings. Note that we will not check for
2089 -- differences of @IdInfo@ in unfoldings, as this is generally
2090 -- redundant, and can lead to an exponential blow-up in complexity.
2091 diffUnfold :: RnEnv2 -> Unfolding -> Unfolding -> [SDoc]
2092 diffUnfold _ NoUnfolding NoUnfolding = []
2093 diffUnfold _ BootUnfolding BootUnfolding = []
2094 diffUnfold _ (OtherCon cs1) (OtherCon cs2) | cs1 == cs2 = []
2095 diffUnfold env (DFunUnfolding bs1 c1 a1)
2096 (DFunUnfolding bs2 c2 a2)
2097 | c1 == c2 && equalLength bs1 bs2
2098 = concatMap (uncurry (diffExpr False env')) (zip a1 a2)
2099 where env' = rnBndrs2 env bs1 bs2
2100 diffUnfold env (CoreUnfolding t1 _ _ v1 cl1 wf1 x1 g1)
2101 (CoreUnfolding t2 _ _ v2 cl2 wf2 x2 g2)
2102 | v1 == v2 && cl1 == cl2
2103 && wf1 == wf2 && x1 == x2 && g1 == g2
2104 = diffExpr False env t1 t2
2105 diffUnfold _ uf1 uf2
2106 = [fsep [ppr uf1, text "/=", ppr uf2]]
2107
2108 -- | Add location information to diff messages
2109 locBind :: String -> Var -> Var -> [SDoc] -> [SDoc]
2110 locBind loc b1 b2 diffs = map addLoc diffs
2111 where addLoc d = d $$ nest 2 (parens (text loc <+> bindLoc))
2112 bindLoc | b1 == b2 = ppr b1
2113 | otherwise = ppr b1 <> char '/' <> ppr b2
2114
2115 {-
2116 ************************************************************************
2117 * *
2118 Eta reduction
2119 * *
2120 ************************************************************************
2121
2122 Note [Eta reduction conditions]
2123 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2124 We try for eta reduction here, but *only* if we get all the way to an
2125 trivial expression. We don't want to remove extra lambdas unless we
2126 are going to avoid allocating this thing altogether.
2127
2128 There are some particularly delicate points here:
2129
2130 * We want to eta-reduce if doing so leaves a trivial expression,
2131 *including* a cast. For example
2132 \x. f |> co --> f |> co
2133 (provided co doesn't mention x)
2134
2135 * Eta reduction is not valid in general:
2136 \x. bot /= bot
2137 This matters, partly for old-fashioned correctness reasons but,
2138 worse, getting it wrong can yield a seg fault. Consider
2139 f = \x.f x
2140 h y = case (case y of { True -> f `seq` True; False -> False }) of
2141 True -> ...; False -> ...
2142
2143 If we (unsoundly) eta-reduce f to get f=f, the strictness analyser
2144 says f=bottom, and replaces the (f `seq` True) with just
2145 (f `cast` unsafe-co). BUT, as thing stand, 'f' got arity 1, and it
2146 *keeps* arity 1 (perhaps also wrongly). So CorePrep eta-expands
2147 the definition again, so that it does not termninate after all.
2148 Result: seg-fault because the boolean case actually gets a function value.
2149 See Trac #1947.
2150
2151 So it's important to do the right thing.
2152
2153 * Note [Arity care]: we need to be careful if we just look at f's
2154 arity. Currently (Dec07), f's arity is visible in its own RHS (see
2155 Note [Arity robustness] in SimplEnv) so we must *not* trust the
2156 arity when checking that 'f' is a value. Otherwise we will
2157 eta-reduce
2158 f = \x. f x
2159 to
2160 f = f
2161 Which might change a terminating program (think (f `seq` e)) to a
2162 non-terminating one. So we check for being a loop breaker first.
2163
2164 However for GlobalIds we can look at the arity; and for primops we
2165 must, since they have no unfolding.
2166
2167 * Regardless of whether 'f' is a value, we always want to
2168 reduce (/\a -> f a) to f
2169 This came up in a RULE: foldr (build (/\a -> g a))
2170 did not match foldr (build (/\b -> ...something complex...))
2171 The type checker can insert these eta-expanded versions,
2172 with both type and dictionary lambdas; hence the slightly
2173 ad-hoc isDictId
2174
2175 * Never *reduce* arity. For example
2176 f = \xy. g x y
2177 Then if h has arity 1 we don't want to eta-reduce because then
2178 f's arity would decrease, and that is bad
2179
2180 These delicacies are why we don't use exprIsTrivial and exprIsHNF here.
2181 Alas.
2182
2183 Note [Eta reduction with casted arguments]
2184 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2185 Consider
2186 (\(x:t3). f (x |> g)) :: t3 -> t2
2187 where
2188 f :: t1 -> t2
2189 g :: t3 ~ t1
2190 This should be eta-reduced to
2191
2192 f |> (sym g -> t2)
2193
2194 So we need to accumulate a coercion, pushing it inward (past
2195 variable arguments only) thus:
2196 f (x |> co_arg) |> co --> (f |> (sym co_arg -> co)) x
2197 f (x:t) |> co --> (f |> (t -> co)) x
2198 f @ a |> co --> (f |> (forall a.co)) @ a
2199 f @ (g:t1~t2) |> co --> (f |> (t1~t2 => co)) @ (g:t1~t2)
2200 These are the equations for ok_arg.
2201
2202 It's true that we could also hope to eta reduce these:
2203 (\xy. (f x |> g) y)
2204 (\xy. (f x y) |> g)
2205 But the simplifier pushes those casts outwards, so we don't
2206 need to address that here.
2207 -}
2208
2209 tryEtaReduce :: [Var] -> CoreExpr -> Maybe CoreExpr
2210 tryEtaReduce bndrs body
2211 = go (reverse bndrs) body (mkRepReflCo (exprType body))
2212 where
2213 incoming_arity = count isId bndrs
2214
2215 go :: [Var] -- Binders, innermost first, types [a3,a2,a1]
2216 -> CoreExpr -- Of type tr
2217 -> Coercion -- Of type tr ~ ts
2218 -> Maybe CoreExpr -- Of type a1 -> a2 -> a3 -> ts
2219 -- See Note [Eta reduction with casted arguments]
2220 -- for why we have an accumulating coercion
2221 go [] fun co
2222 | ok_fun fun
2223 , let used_vars = exprFreeVars fun `unionVarSet` tyCoVarsOfCo co
2224 , not (any (`elemVarSet` used_vars) bndrs)
2225 = Just (mkCast fun co) -- Check for any of the binders free in the result
2226 -- including the accumulated coercion
2227
2228 go bs (Tick t e) co
2229 | tickishFloatable t
2230 = fmap (Tick t) $ go bs e co
2231 -- Float app ticks: \x -> Tick t (e x) ==> Tick t e
2232
2233 go (b : bs) (App fun arg) co
2234 | Just (co', ticks) <- ok_arg b arg co
2235 = fmap (flip (foldr mkTick) ticks) $ go bs fun co'
2236 -- Float arg ticks: \x -> e (Tick t x) ==> Tick t e
2237
2238 go _ _ _ = Nothing -- Failure!
2239
2240 ---------------
2241 -- Note [Eta reduction conditions]
2242 ok_fun (App fun (Type {})) = ok_fun fun
2243 ok_fun (Cast fun _) = ok_fun fun
2244 ok_fun (Tick _ expr) = ok_fun expr
2245 ok_fun (Var fun_id) = ok_fun_id fun_id || all ok_lam bndrs
2246 ok_fun _fun = False
2247
2248 ---------------
2249 ok_fun_id fun = fun_arity fun >= incoming_arity
2250
2251 ---------------
2252 fun_arity fun -- See Note [Arity care]
2253 | isLocalId fun
2254 , isStrongLoopBreaker (idOccInfo fun) = 0
2255 | arity > 0 = arity
2256 | isEvaldUnfolding (idUnfolding fun) = 1
2257 -- See Note [Eta reduction of an eval'd function]
2258 | otherwise = 0
2259 where
2260 arity = idArity fun
2261
2262 ---------------
2263 ok_lam v = isTyVar v || isEvVar v
2264
2265 ---------------
2266 ok_arg :: Var -- Of type bndr_t
2267 -> CoreExpr -- Of type arg_t
2268 -> Coercion -- Of kind (t1~t2)
2269 -> Maybe (Coercion -- Of type (arg_t -> t1 ~ bndr_t -> t2)
2270 -- (and similarly for tyvars, coercion args)
2271 , [Tickish Var])
2272 -- See Note [Eta reduction with casted arguments]
2273 ok_arg bndr (Type ty) co
2274 | Just tv <- getTyVar_maybe ty
2275 , bndr == tv = Just (mkHomoForAllCos [tv] co, [])
2276 ok_arg bndr (Var v) co
2277 | bndr == v = let reflCo = mkRepReflCo (idType bndr)
2278 in Just (mkFunCo Representational reflCo co, [])
2279 ok_arg bndr (Cast e co_arg) co
2280 | (ticks, Var v) <- stripTicksTop tickishFloatable e
2281 , bndr == v
2282 = Just (mkFunCo Representational (mkSymCo co_arg) co, ticks)
2283 -- The simplifier combines multiple casts into one,
2284 -- so we can have a simple-minded pattern match here
2285 ok_arg bndr (Tick t arg) co
2286 | tickishFloatable t, Just (co', ticks) <- ok_arg bndr arg co
2287 = Just (co', t:ticks)
2288
2289 ok_arg _ _ _ = Nothing
2290
2291 {-
2292 Note [Eta reduction of an eval'd function]
2293 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2294 In Haskell it is not true that f = \x. f x
2295 because f might be bottom, and 'seq' can distinguish them.
2296
2297 But it *is* true that f = f `seq` \x. f x
2298 and we'd like to simplify the latter to the former. This amounts
2299 to the rule that
2300 * when there is just *one* value argument,
2301 * f is not bottom
2302 we can eta-reduce \x. f x ===> f
2303
2304 This turned up in Trac #7542.
2305
2306
2307 ************************************************************************
2308 * *
2309 \subsection{Determining non-updatable right-hand-sides}
2310 * *
2311 ************************************************************************
2312
2313 Top-level constructor applications can usually be allocated
2314 statically, but they can't if the constructor, or any of the
2315 arguments, come from another DLL (because we can't refer to static
2316 labels in other DLLs).
2317
2318 If this happens we simply make the RHS into an updatable thunk,
2319 and 'execute' it rather than allocating it statically.
2320 -}
2321
2322 -- | This function is called only on *top-level* right-hand sides.
2323 -- Returns @True@ if the RHS can be allocated statically in the output,
2324 -- with no thunks involved at all.
2325 rhsIsStatic :: Platform
2326 -> (Name -> Bool) -- Which names are dynamic
2327 -> (Integer -> CoreExpr) -- Desugaring for integer literals (disgusting)
2328 -- C.f. Note [Disgusting computation of CafRefs]
2329 -- in TidyPgm
2330 -> CoreExpr -> Bool
2331 -- It's called (i) in TidyPgm.hasCafRefs to decide if the rhs is, or
2332 -- refers to, CAFs; (ii) in CoreToStg to decide whether to put an
2333 -- update flag on it and (iii) in DsExpr to decide how to expand
2334 -- list literals
2335 --
2336 -- The basic idea is that rhsIsStatic returns True only if the RHS is
2337 -- (a) a value lambda
2338 -- (b) a saturated constructor application with static args
2339 --
2340 -- BUT watch out for
2341 -- (i) Any cross-DLL references kill static-ness completely
2342 -- because they must be 'executed' not statically allocated
2343 -- ("DLL" here really only refers to Windows DLLs, on other platforms,
2344 -- this is not necessary)
2345 --
2346 -- (ii) We treat partial applications as redexes, because in fact we
2347 -- make a thunk for them that runs and builds a PAP
2348 -- at run-time. The only applications that are treated as
2349 -- static are *saturated* applications of constructors.
2350
2351 -- We used to try to be clever with nested structures like this:
2352 -- ys = (:) w ((:) w [])
2353 -- on the grounds that CorePrep will flatten ANF-ise it later.
2354 -- But supporting this special case made the function much more
2355 -- complicated, because the special case only applies if there are no
2356 -- enclosing type lambdas:
2357 -- ys = /\ a -> Foo (Baz ([] a))
2358 -- Here the nested (Baz []) won't float out to top level in CorePrep.
2359 --
2360 -- But in fact, even without -O, nested structures at top level are
2361 -- flattened by the simplifier, so we don't need to be super-clever here.
2362 --
2363 -- Examples
2364 --
2365 -- f = \x::Int. x+7 TRUE
2366 -- p = (True,False) TRUE
2367 --
2368 -- d = (fst p, False) FALSE because there's a redex inside
2369 -- (this particular one doesn't happen but...)
2370 --
2371 -- h = D# (1.0## /## 2.0##) FALSE (redex again)
2372 -- n = /\a. Nil a TRUE
2373 --
2374 -- t = /\a. (:) (case w a of ...) (Nil a) FALSE (redex)
2375 --
2376 --
2377 -- This is a bit like CoreUtils.exprIsHNF, with the following differences:
2378 -- a) scc "foo" (\x -> ...) is updatable (so we catch the right SCC)
2379 --
2380 -- b) (C x xs), where C is a constructor is updatable if the application is
2381 -- dynamic
2382 --
2383 -- c) don't look through unfolding of f in (f x).
2384
2385 rhsIsStatic platform is_dynamic_name cvt_integer rhs = is_static False rhs
2386 where
2387 is_static :: Bool -- True <=> in a constructor argument; must be atomic
2388 -> CoreExpr -> Bool
2389
2390 is_static False (Lam b e) = isRuntimeVar b || is_static False e
2391 is_static in_arg (Tick n e) = not (tickishIsCode n)
2392 && is_static in_arg e
2393 is_static in_arg (Cast e _) = is_static in_arg e
2394 is_static _ (Coercion {}) = True -- Behaves just like a literal
2395 is_static in_arg (Lit (LitInteger i _)) = is_static in_arg (cvt_integer i)
2396 is_static _ (Lit (MachLabel {})) = False
2397 is_static _ (Lit _) = True
2398 -- A MachLabel (foreign import "&foo") in an argument
2399 -- prevents a constructor application from being static. The
2400 -- reason is that it might give rise to unresolvable symbols
2401 -- in the object file: under Linux, references to "weak"
2402 -- symbols from the data segment give rise to "unresolvable
2403 -- relocation" errors at link time This might be due to a bug
2404 -- in the linker, but we'll work around it here anyway.
2405 -- SDM 24/2/2004
2406
2407 is_static in_arg other_expr = go other_expr 0
2408 where
2409 go (Var f) n_val_args
2410 | (platformOS platform /= OSMinGW32) ||
2411 not (is_dynamic_name (idName f))
2412 = saturated_data_con f n_val_args
2413 || (in_arg && n_val_args == 0)
2414 -- A naked un-applied variable is *not* deemed a static RHS
2415 -- E.g. f = g
2416 -- Reason: better to update so that the indirection gets shorted
2417 -- out, and the true value will be seen
2418 -- NB: if you change this, you'll break the invariant that THUNK_STATICs
2419 -- are always updatable. If you do so, make sure that non-updatable
2420 -- ones have enough space for their static link field!
2421
2422 go (App f a) n_val_args
2423 | isTypeArg a = go f n_val_args
2424 | not in_arg && is_static True a = go f (n_val_args + 1)
2425 -- The (not in_arg) checks that we aren't in a constructor argument;
2426 -- if we are, we don't allow (value) applications of any sort
2427 --
2428 -- NB. In case you wonder, args are sometimes not atomic. eg.
2429 -- x = D# (1.0## /## 2.0##)
2430 -- can't float because /## can fail.
2431
2432 go (Tick n f) n_val_args = not (tickishIsCode n) && go f n_val_args
2433 go (Cast e _) n_val_args = go e n_val_args
2434 go _ _ = False
2435
2436 saturated_data_con f n_val_args
2437 = case isDataConWorkId_maybe f of
2438 Just dc -> n_val_args == dataConRepArity dc
2439 Nothing -> False
2440
2441 {-
2442 ************************************************************************
2443 * *
2444 \subsection{Type utilities}
2445 * *
2446 ************************************************************************
2447 -}
2448
2449 -- | True if the type has no non-bottom elements, e.g. when it is an empty
2450 -- datatype, or a GADT with non-satisfiable type parameters, e.g. Int :~: Bool.
2451 -- See Note [Bottoming expressions]
2452 --
2453 -- See Note [No alternatives lint check] for another use of this function.
2454 isEmptyTy :: Type -> Bool
2455 isEmptyTy ty
2456 -- Data types where, given the particular type parameters, no data
2457 -- constructor matches, are empty.
2458 -- This includes data types with no constructors, e.g. Data.Void.Void.
2459 | Just (tc, inst_tys) <- splitTyConApp_maybe ty
2460 , Just dcs <- tyConDataCons_maybe tc
2461 , all (dataConCannotMatch inst_tys) dcs
2462 = True
2463 | otherwise
2464 = False
2465
2466 {-
2467 *****************************************************
2468 *
2469 * StaticPtr
2470 *
2471 *****************************************************
2472 -}
2473
2474 -- | @collectMakeStaticArgs (makeStatic t srcLoc e)@ yields
2475 -- @Just (makeStatic, t, srcLoc, e)@.
2476 --
2477 -- Returns @Nothing@ for every other expression.
2478 collectMakeStaticArgs
2479 :: CoreExpr -> Maybe (CoreExpr, Type, CoreExpr, CoreExpr)
2480 collectMakeStaticArgs e
2481 | (fun@(Var b), [Type t, loc, arg], _) <- collectArgsTicks (const True) e
2482 , idName b == makeStaticName = Just (fun, t, loc, arg)
2483 collectMakeStaticArgs _ = Nothing
2484
2485 {-
2486 ************************************************************************
2487 * *
2488 \subsection{Join points}
2489 * *
2490 ************************************************************************
2491 -}
2492
2493 -- | Does this binding bind a join point (or a recursive group of join points)?
2494 isJoinBind :: CoreBind -> Bool
2495 isJoinBind (NonRec b _) = isJoinId b
2496 isJoinBind (Rec ((b, _) : _)) = isJoinId b
2497 isJoinBind _ = False