Refactor to eliminate FamTyConShape
[ghc.git] / compiler / types / Type.hs
1 -- (c) The University of Glasgow 2006
2 -- (c) The GRASP/AQUA Project, Glasgow University, 1998
3 --
4 -- Type - public interface
5
6 {-# LANGUAGE CPP, FlexibleContexts #-}
7 {-# OPTIONS_GHC -fno-warn-orphans #-}
8
9 -- | Main functions for manipulating types and type-related things
10 module Type (
11 -- Note some of this is just re-exports from TyCon..
12
13 -- * Main data types representing Types
14 -- $type_classification
15
16 -- $representation_types
17 TyThing(..), Type, ArgFlag(..), KindOrType, PredType, ThetaType,
18 Var, TyVar, isTyVar, TyCoVar, TyBinder, TyVarBinder,
19
20 -- ** Constructing and deconstructing types
21 mkTyVarTy, mkTyVarTys, getTyVar, getTyVar_maybe, repGetTyVar_maybe,
22 getCastedTyVar_maybe, tyVarKind,
23
24 mkAppTy, mkAppTys, splitAppTy, splitAppTys, repSplitAppTys,
25 splitAppTy_maybe, repSplitAppTy_maybe, tcRepSplitAppTy_maybe,
26
27 mkFunTy, mkFunTys, splitFunTy, splitFunTy_maybe,
28 splitFunTys, funResultTy, funArgTy,
29
30 mkTyConApp, mkTyConTy,
31 tyConAppTyCon_maybe, tyConAppTyConPicky_maybe,
32 tyConAppArgs_maybe, tyConAppTyCon, tyConAppArgs,
33 splitTyConApp_maybe, splitTyConApp, tyConAppArgN, nextRole,
34 tcRepSplitTyConApp_maybe, tcSplitTyConApp_maybe,
35 splitListTyConApp_maybe,
36 repSplitTyConApp_maybe,
37
38 mkForAllTy, mkForAllTys, mkInvForAllTys, mkSpecForAllTys,
39 mkVisForAllTys, mkInvForAllTy,
40 splitForAllTys, splitForAllTyVarBndrs,
41 splitForAllTy_maybe, splitForAllTy,
42 splitPiTy_maybe, splitPiTy, splitPiTys,
43 mkPiTy, mkPiTys, mkTyConBindersPreferAnon,
44 mkLamType, mkLamTypes,
45 piResultTy, piResultTys,
46 applyTysX, dropForAlls,
47
48 mkNumLitTy, isNumLitTy,
49 mkStrLitTy, isStrLitTy,
50
51 getRuntimeRep_maybe, getRuntimeRepFromKind_maybe,
52
53 mkCastTy, mkCoercionTy, splitCastTy_maybe,
54
55 userTypeError_maybe, pprUserTypeErrorTy,
56
57 coAxNthLHS,
58 stripCoercionTy, splitCoercionType_maybe,
59
60 splitPiTysInvisible, filterOutInvisibleTypes,
61 partitionInvisibles,
62 synTyConResKind,
63
64 modifyJoinResTy, setJoinResTy,
65
66 -- Analyzing types
67 TyCoMapper(..), mapType, mapCoercion,
68
69 -- (Newtypes)
70 newTyConInstRhs,
71
72 -- Pred types
73 mkFamilyTyConApp,
74 isDictLikeTy,
75 mkPrimEqPred, mkReprPrimEqPred, mkPrimEqPredRole,
76 equalityTyCon,
77 mkHeteroPrimEqPred, mkHeteroReprPrimEqPred,
78 mkClassPred,
79 isClassPred, isEqPred, isNomEqPred,
80 isIPPred, isIPPred_maybe, isIPTyCon, isIPClass,
81 isCTupleClass,
82
83 -- Deconstructing predicate types
84 PredTree(..), EqRel(..), eqRelRole, classifyPredType,
85 getClassPredTys, getClassPredTys_maybe,
86 getEqPredTys, getEqPredTys_maybe, getEqPredRole,
87 predTypeEqRel,
88
89 -- ** Binders
90 sameVis,
91 mkTyVarBinder, mkTyVarBinders,
92 mkAnonBinder,
93 isAnonTyBinder, isNamedTyBinder,
94 binderVar, binderVars, binderKind, binderArgFlag,
95 tyBinderType,
96 binderRelevantType_maybe, caseBinder,
97 isVisibleArgFlag, isInvisibleArgFlag, isVisibleBinder, isInvisibleBinder,
98 tyConBindersTyBinders,
99 mkTyBinderTyConBinder,
100
101 -- ** Common type constructors
102 funTyCon,
103
104 -- ** Predicates on types
105 isTyVarTy, isFunTy, isDictTy, isPredTy, isCoercionTy,
106 isCoercionTy_maybe, isCoercionType, isForAllTy,
107 isPiTy, isTauTy, isFamFreeTy,
108
109 isValidJoinPointType,
110
111 -- (Lifting and boxity)
112 isLiftedType_maybe, isUnliftedType, isUnboxedTupleType, isUnboxedSumType,
113 isAlgType, isDataFamilyAppType,
114 isPrimitiveType, isStrictType,
115 isRuntimeRepTy, isRuntimeRepVar, isRuntimeRepKindedTy,
116 dropRuntimeRepArgs,
117 getRuntimeRep, getRuntimeRepFromKind,
118
119 -- * Main data types representing Kinds
120 Kind,
121
122 -- ** Finding the kind of a type
123 typeKind, isTypeLevPoly, resultIsLevPoly,
124
125 -- ** Common Kind
126 liftedTypeKind,
127
128 -- * Type free variables
129 tyCoFVsOfType, tyCoFVsBndr,
130 tyCoVarsOfType, tyCoVarsOfTypes,
131 tyCoVarsOfTypeDSet,
132 coVarsOfType,
133 coVarsOfTypes, closeOverKinds, closeOverKindsList,
134 noFreeVarsOfType,
135 splitVisVarsOfType, splitVisVarsOfTypes,
136 expandTypeSynonyms,
137 typeSize,
138
139 -- * Well-scoped lists of variables
140 dVarSetElemsWellScoped, toposortTyVars, tyCoVarsOfTypeWellScoped,
141 tyCoVarsOfTypesWellScoped,
142
143 -- * Type comparison
144 eqType, eqTypeX, eqTypes, nonDetCmpType, nonDetCmpTypes, nonDetCmpTypeX,
145 nonDetCmpTypesX, nonDetCmpTc,
146 eqVarBndrs,
147
148 -- * Forcing evaluation of types
149 seqType, seqTypes,
150
151 -- * Other views onto Types
152 coreView, tcView,
153
154 tyConsOfType,
155
156 -- * Main type substitution data types
157 TvSubstEnv, -- Representation widely visible
158 TCvSubst(..), -- Representation visible to a few friends
159
160 -- ** Manipulating type substitutions
161 emptyTvSubstEnv, emptyTCvSubst, mkEmptyTCvSubst,
162
163 mkTCvSubst, zipTvSubst, mkTvSubstPrs,
164 notElemTCvSubst,
165 getTvSubstEnv, setTvSubstEnv,
166 zapTCvSubst, getTCvInScope, getTCvSubstRangeFVs,
167 extendTCvInScope, extendTCvInScopeList, extendTCvInScopeSet,
168 extendTCvSubst, extendCvSubst,
169 extendTvSubst, extendTvSubstBinderAndInScope,
170 extendTvSubstList, extendTvSubstAndInScope,
171 extendTvSubstWithClone,
172 isInScope, composeTCvSubstEnv, composeTCvSubst, zipTyEnv, zipCoEnv,
173 isEmptyTCvSubst, unionTCvSubst,
174
175 -- ** Performing substitution on types and kinds
176 substTy, substTys, substTyWith, substTysWith, substTheta,
177 substTyAddInScope,
178 substTyUnchecked, substTysUnchecked, substThetaUnchecked,
179 substTyWithUnchecked,
180 substCoUnchecked, substCoWithUnchecked,
181 substTyVarBndr, substTyVar, substTyVars,
182 cloneTyVarBndr, cloneTyVarBndrs, lookupTyVar,
183
184 -- * Pretty-printing
185 pprType, pprParendType, pprPrecType,
186 pprTypeApp, pprTyThingCategory, pprShortTyThing,
187 pprTvBndr, pprTvBndrs, pprForAll, pprUserForAll,
188 pprSigmaType, ppSuggestExplicitKinds,
189 pprTheta, pprThetaArrowTy, pprClassPred,
190 pprKind, pprParendKind, pprSourceTyCon,
191 TyPrec(..), maybeParen,
192 pprTyVar, pprTyVars, pprPrefixApp, pprArrowChain,
193
194 -- * Tidying type related things up for printing
195 tidyType, tidyTypes,
196 tidyOpenType, tidyOpenTypes,
197 tidyOpenKind,
198 tidyTyCoVarBndr, tidyTyCoVarBndrs, tidyFreeTyCoVars,
199 tidyOpenTyCoVar, tidyOpenTyCoVars,
200 tidyTyVarOcc,
201 tidyTopType,
202 tidyKind,
203 tidyTyVarBinder, tidyTyVarBinders
204 ) where
205
206 #include "HsVersions.h"
207
208 import BasicTypes
209
210 -- We import the representation and primitive functions from TyCoRep.
211 -- Many things are reexported, but not the representation!
212
213 import Kind
214 import TyCoRep
215
216 -- friends:
217 import Var
218 import VarEnv
219 import VarSet
220 import UniqSet
221
222 import Class
223 import TyCon
224 import TysPrim
225 import {-# SOURCE #-} TysWiredIn ( listTyCon, typeNatKind
226 , typeSymbolKind, liftedTypeKind )
227 import PrelNames
228 import CoAxiom
229 import {-# SOURCE #-} Coercion
230
231 -- others
232 import Util
233 import Outputable
234 import FastString
235 import Pair
236 import ListSetOps
237 import Digraph
238 import Unique ( nonDetCmpUnique )
239 import SrcLoc ( SrcSpan )
240 import OccName ( OccName )
241 import Name ( mkInternalName )
242
243 import Maybes ( orElse )
244 import Data.Maybe ( isJust, mapMaybe )
245 import Control.Monad ( guard )
246 import Control.Arrow ( first, second )
247
248 -- $type_classification
249 -- #type_classification#
250 --
251 -- Types are one of:
252 --
253 -- [Unboxed] Iff its representation is other than a pointer
254 -- Unboxed types are also unlifted.
255 --
256 -- [Lifted] Iff it has bottom as an element.
257 -- Closures always have lifted types: i.e. any
258 -- let-bound identifier in Core must have a lifted
259 -- type. Operationally, a lifted object is one that
260 -- can be entered.
261 -- Only lifted types may be unified with a type variable.
262 --
263 -- [Algebraic] Iff it is a type with one or more constructors, whether
264 -- declared with @data@ or @newtype@.
265 -- An algebraic type is one that can be deconstructed
266 -- with a case expression. This is /not/ the same as
267 -- lifted types, because we also include unboxed
268 -- tuples in this classification.
269 --
270 -- [Data] Iff it is a type declared with @data@, or a boxed tuple.
271 --
272 -- [Primitive] Iff it is a built-in type that can't be expressed in Haskell.
273 --
274 -- Currently, all primitive types are unlifted, but that's not necessarily
275 -- the case: for example, @Int@ could be primitive.
276 --
277 -- Some primitive types are unboxed, such as @Int#@, whereas some are boxed
278 -- but unlifted (such as @ByteArray#@). The only primitive types that we
279 -- classify as algebraic are the unboxed tuples.
280 --
281 -- Some examples of type classifications that may make this a bit clearer are:
282 --
283 -- @
284 -- Type primitive boxed lifted algebraic
285 -- -----------------------------------------------------------------------------
286 -- Int# Yes No No No
287 -- ByteArray# Yes Yes No No
288 -- (\# a, b \#) Yes No No Yes
289 -- (\# a | b \#) Yes No No Yes
290 -- ( a, b ) No Yes Yes Yes
291 -- [a] No Yes Yes Yes
292 -- @
293
294 -- $representation_types
295 -- A /source type/ is a type that is a separate type as far as the type checker is
296 -- concerned, but which has a more low-level representation as far as Core-to-Core
297 -- passes and the rest of the back end is concerned.
298 --
299 -- You don't normally have to worry about this, as the utility functions in
300 -- this module will automatically convert a source into a representation type
301 -- if they are spotted, to the best of it's abilities. If you don't want this
302 -- to happen, use the equivalent functions from the "TcType" module.
303
304 {-
305 ************************************************************************
306 * *
307 Type representation
308 * *
309 ************************************************************************
310
311 Note [coreView vs tcView]
312 ~~~~~~~~~~~~~~~~~~~~~~~~~
313 So far as the typechecker is concerned, 'Constraint' and 'TYPE LiftedRep' are distinct kinds.
314
315 But in Core these two are treated as identical.
316
317 We implement this by making 'coreView' convert 'Constraint' to 'TYPE LiftedRep' on the fly.
318 The function tcView (used in the type checker) does not do this.
319
320 See also Trac #11715, which tracks removing this inconsistency.
321
322 -}
323
324 {-# INLINE coreView #-}
325 coreView :: Type -> Maybe Type
326 -- ^ This function Strips off the /top layer only/ of a type synonym
327 -- application (if any) its underlying representation type.
328 -- Returns Nothing if there is nothing to look through.
329 -- This function considers 'Constraint' to be a synonym of @TYPE LiftedRep@.
330 --
331 -- By being non-recursive and inlined, this case analysis gets efficiently
332 -- joined onto the case analysis that the caller is already doing
333 coreView (TyConApp tc tys) | Just (tenv, rhs, tys') <- expandSynTyCon_maybe tc tys
334 = Just (mkAppTys (substTy (mkTvSubstPrs tenv) rhs) tys')
335 -- The free vars of 'rhs' should all be bound by 'tenv', so it's
336 -- ok to use 'substTy' here.
337 -- See also Note [The substitution invariant] in TyCoRep.
338 -- Its important to use mkAppTys, rather than (foldl AppTy),
339 -- because the function part might well return a
340 -- partially-applied type constructor; indeed, usually will!
341 coreView (TyConApp tc [])
342 | isStarKindSynonymTyCon tc
343 = Just liftedTypeKind
344
345 coreView _ = Nothing
346
347 -- | Gives the typechecker view of a type. This unwraps synonyms but
348 -- leaves 'Constraint' alone. c.f. coreView, which turns Constraint into
349 -- TYPE LiftedRep. Returns Nothing if no unwrapping happens.
350 -- See also Note [coreView vs tcView] in Type.
351 {-# INLINE tcView #-}
352 tcView :: Type -> Maybe Type
353 tcView (TyConApp tc tys) | Just (tenv, rhs, tys') <- expandSynTyCon_maybe tc tys
354 = Just (mkAppTys (substTy (mkTvSubstPrs tenv) rhs) tys')
355 -- The free vars of 'rhs' should all be bound by 'tenv', so it's
356 -- ok to use 'substTy' here.
357 -- See also Note [The substitution invariant] in TyCoRep.
358 -- Its important to use mkAppTys, rather than (foldl AppTy),
359 -- because the function part might well return a
360 -- partially-applied type constructor; indeed, usually will!
361 tcView _ = Nothing
362
363 -----------------------------------------------
364 expandTypeSynonyms :: Type -> Type
365 -- ^ Expand out all type synonyms. Actually, it'd suffice to expand out
366 -- just the ones that discard type variables (e.g. type Funny a = Int)
367 -- But we don't know which those are currently, so we just expand all.
368 --
369 -- 'expandTypeSynonyms' only expands out type synonyms mentioned in the type,
370 -- not in the kinds of any TyCon or TyVar mentioned in the type.
371 --
372 -- Keep this synchronized with 'synonymTyConsOfType'
373 expandTypeSynonyms ty
374 = go (mkEmptyTCvSubst in_scope) ty
375 where
376 in_scope = mkInScopeSet (tyCoVarsOfType ty)
377
378 go subst (TyConApp tc tys)
379 | Just (tenv, rhs, tys') <- expandSynTyCon_maybe tc expanded_tys
380 = let subst' = mkTvSubst in_scope (mkVarEnv tenv)
381 -- Make a fresh substitution; rhs has nothing to
382 -- do with anything that has happened so far
383 -- NB: if you make changes here, be sure to build an
384 -- /idempotent/ substitution, even in the nested case
385 -- type T a b = a -> b
386 -- type S x y = T y x
387 -- (Trac #11665)
388 in mkAppTys (go subst' rhs) tys'
389 | otherwise
390 = TyConApp tc expanded_tys
391 where
392 expanded_tys = (map (go subst) tys)
393
394 go _ (LitTy l) = LitTy l
395 go subst (TyVarTy tv) = substTyVar subst tv
396 go subst (AppTy t1 t2) = mkAppTy (go subst t1) (go subst t2)
397 go subst (FunTy arg res)
398 = mkFunTy (go subst arg) (go subst res)
399 go subst (ForAllTy (TvBndr tv vis) t)
400 = let (subst', tv') = substTyVarBndrCallback go subst tv in
401 ForAllTy (TvBndr tv' vis) (go subst' t)
402 go subst (CastTy ty co) = mkCastTy (go subst ty) (go_co subst co)
403 go subst (CoercionTy co) = mkCoercionTy (go_co subst co)
404
405 go_co subst (Refl r ty)
406 = mkReflCo r (go subst ty)
407 -- NB: coercions are always expanded upon creation
408 go_co subst (TyConAppCo r tc args)
409 = mkTyConAppCo r tc (map (go_co subst) args)
410 go_co subst (AppCo co arg)
411 = mkAppCo (go_co subst co) (go_co subst arg)
412 go_co subst (ForAllCo tv kind_co co)
413 = let (subst', tv', kind_co') = go_cobndr subst tv kind_co in
414 mkForAllCo tv' kind_co' (go_co subst' co)
415 go_co subst (FunCo r co1 co2)
416 = mkFunCo r (go_co subst co1) (go_co subst co2)
417 go_co subst (CoVarCo cv)
418 = substCoVar subst cv
419 go_co subst (AxiomInstCo ax ind args)
420 = mkAxiomInstCo ax ind (map (go_co subst) args)
421 go_co subst (UnivCo p r t1 t2)
422 = mkUnivCo (go_prov subst p) r (go subst t1) (go subst t2)
423 go_co subst (SymCo co)
424 = mkSymCo (go_co subst co)
425 go_co subst (TransCo co1 co2)
426 = mkTransCo (go_co subst co1) (go_co subst co2)
427 go_co subst (NthCo n co)
428 = mkNthCo n (go_co subst co)
429 go_co subst (LRCo lr co)
430 = mkLRCo lr (go_co subst co)
431 go_co subst (InstCo co arg)
432 = mkInstCo (go_co subst co) (go_co subst arg)
433 go_co subst (CoherenceCo co1 co2)
434 = mkCoherenceCo (go_co subst co1) (go_co subst co2)
435 go_co subst (KindCo co)
436 = mkKindCo (go_co subst co)
437 go_co subst (SubCo co)
438 = mkSubCo (go_co subst co)
439 go_co subst (AxiomRuleCo ax cs) = AxiomRuleCo ax (map (go_co subst) cs)
440
441 go_prov _ UnsafeCoerceProv = UnsafeCoerceProv
442 go_prov subst (PhantomProv co) = PhantomProv (go_co subst co)
443 go_prov subst (ProofIrrelProv co) = ProofIrrelProv (go_co subst co)
444 go_prov _ p@(PluginProv _) = p
445 go_prov _ (HoleProv h) = pprPanic "expandTypeSynonyms hit a hole" (ppr h)
446
447 -- the "False" and "const" are to accommodate the type of
448 -- substForAllCoBndrCallback, which is general enough to
449 -- handle coercion optimization (which sometimes swaps the
450 -- order of a coercion)
451 go_cobndr subst = substForAllCoBndrCallback False (go_co subst) subst
452
453 {-
454 ************************************************************************
455 * *
456 Analyzing types
457 * *
458 ************************************************************************
459
460 These functions do a map-like operation over types, performing some operation
461 on all variables and binding sites. Primarily used for zonking.
462
463 Note [Efficiency for mapCoercion ForAllCo case]
464 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
465 As noted in Note [Forall coercions] in TyCoRep, a ForAllCo is a bit redundant.
466 It stores a TyVar and a Coercion, where the kind of the TyVar always matches
467 the left-hand kind of the coercion. This is convenient lots of the time, but
468 not when mapping a function over a coercion.
469
470 The problem is that tcm_tybinder will affect the TyVar's kind and
471 mapCoercion will affect the Coercion, and we hope that the results will be
472 the same. Even if they are the same (which should generally happen with
473 correct algorithms), then there is an efficiency issue. In particular,
474 this problem seems to make what should be a linear algorithm into a potentially
475 exponential one. But it's only going to be bad in the case where there's
476 lots of foralls in the kinds of other foralls. Like this:
477
478 forall a : (forall b : (forall c : ...). ...). ...
479
480 This construction seems unlikely. So we'll do the inefficient, easy way
481 for now.
482
483 Note [Specialising mappers]
484 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
485 These INLINABLE pragmas are indispensable. mapType/mapCoercion are used
486 to implement zonking, and it's vital that they get specialised to the TcM
487 monad. This specialisation happens automatically (that is, without a
488 SPECIALISE pragma) as long as the definitions are INLINABLE. For example,
489 this one change made a 20% allocation difference in perf/compiler/T5030.
490
491 -}
492
493 -- | This describes how a "map" operation over a type/coercion should behave
494 data TyCoMapper env m
495 = TyCoMapper
496 { tcm_smart :: Bool -- ^ Should the new type be created with smart
497 -- constructors?
498 , tcm_tyvar :: env -> TyVar -> m Type
499 , tcm_covar :: env -> CoVar -> m Coercion
500 , tcm_hole :: env -> CoercionHole -> Role
501 -> Type -> Type -> m Coercion
502 -- ^ What to do with coercion holes. See Note [Coercion holes] in
503 -- TyCoRep.
504
505 , tcm_tybinder :: env -> TyVar -> ArgFlag -> m (env, TyVar)
506 -- ^ The returned env is used in the extended scope
507 }
508
509 {-# INLINABLE mapType #-} -- See Note [Specialising mappers]
510 mapType :: Monad m => TyCoMapper env m -> env -> Type -> m Type
511 mapType mapper@(TyCoMapper { tcm_smart = smart, tcm_tyvar = tyvar
512 , tcm_tybinder = tybinder })
513 env ty
514 = go ty
515 where
516 go (TyVarTy tv) = tyvar env tv
517 go (AppTy t1 t2) = mkappty <$> go t1 <*> go t2
518 go t@(TyConApp _ []) = return t -- avoid allocation in this exceedingly
519 -- common case (mostly, for *)
520 go (TyConApp tc tys) = mktyconapp tc <$> mapM go tys
521 go (FunTy arg res) = FunTy <$> go arg <*> go res
522 go (ForAllTy (TvBndr tv vis) inner)
523 = do { (env', tv') <- tybinder env tv vis
524 ; inner' <- mapType mapper env' inner
525 ; return $ ForAllTy (TvBndr tv' vis) inner' }
526 go ty@(LitTy {}) = return ty
527 go (CastTy ty co) = mkcastty <$> go ty <*> mapCoercion mapper env co
528 go (CoercionTy co) = CoercionTy <$> mapCoercion mapper env co
529
530 (mktyconapp, mkappty, mkcastty)
531 | smart = (mkTyConApp, mkAppTy, mkCastTy)
532 | otherwise = (TyConApp, AppTy, CastTy)
533
534 {-# INLINABLE mapCoercion #-} -- See Note [Specialising mappers]
535 mapCoercion :: Monad m
536 => TyCoMapper env m -> env -> Coercion -> m Coercion
537 mapCoercion mapper@(TyCoMapper { tcm_smart = smart, tcm_covar = covar
538 , tcm_hole = cohole, tcm_tybinder = tybinder })
539 env co
540 = go co
541 where
542 go (Refl r ty) = Refl r <$> mapType mapper env ty
543 go (TyConAppCo r tc args)
544 = mktyconappco r tc <$> mapM go args
545 go (AppCo c1 c2) = mkappco <$> go c1 <*> go c2
546 go (ForAllCo tv kind_co co)
547 = do { kind_co' <- go kind_co
548 ; (env', tv') <- tybinder env tv Inferred
549 ; co' <- mapCoercion mapper env' co
550 ; return $ mkforallco tv' kind_co' co' }
551 -- See Note [Efficiency for mapCoercion ForAllCo case]
552 go (FunCo r c1 c2) = mkFunCo r <$> go c1 <*> go c2
553 go (CoVarCo cv) = covar env cv
554 go (AxiomInstCo ax i args)
555 = mkaxiominstco ax i <$> mapM go args
556 go (UnivCo (HoleProv hole) r t1 t2)
557 = cohole env hole r t1 t2
558 go (UnivCo p r t1 t2)
559 = mkunivco <$> go_prov p <*> pure r
560 <*> mapType mapper env t1 <*> mapType mapper env t2
561 go (SymCo co) = mksymco <$> go co
562 go (TransCo c1 c2) = mktransco <$> go c1 <*> go c2
563 go (AxiomRuleCo r cos) = AxiomRuleCo r <$> mapM go cos
564 go (NthCo i co) = mknthco i <$> go co
565 go (LRCo lr co) = mklrco lr <$> go co
566 go (InstCo co arg) = mkinstco <$> go co <*> go arg
567 go (CoherenceCo c1 c2) = mkcoherenceco <$> go c1 <*> go c2
568 go (KindCo co) = mkkindco <$> go co
569 go (SubCo co) = mksubco <$> go co
570
571 go_prov UnsafeCoerceProv = return UnsafeCoerceProv
572 go_prov (PhantomProv co) = PhantomProv <$> go co
573 go_prov (ProofIrrelProv co) = ProofIrrelProv <$> go co
574 go_prov p@(PluginProv _) = return p
575 go_prov (HoleProv _) = panic "mapCoercion"
576
577 ( mktyconappco, mkappco, mkaxiominstco, mkunivco
578 , mksymco, mktransco, mknthco, mklrco, mkinstco, mkcoherenceco
579 , mkkindco, mksubco, mkforallco)
580 | smart
581 = ( mkTyConAppCo, mkAppCo, mkAxiomInstCo, mkUnivCo
582 , mkSymCo, mkTransCo, mkNthCo, mkLRCo, mkInstCo, mkCoherenceCo
583 , mkKindCo, mkSubCo, mkForAllCo )
584 | otherwise
585 = ( TyConAppCo, AppCo, AxiomInstCo, UnivCo
586 , SymCo, TransCo, NthCo, LRCo, InstCo, CoherenceCo
587 , KindCo, SubCo, ForAllCo )
588
589 {-
590 ************************************************************************
591 * *
592 \subsection{Constructor-specific functions}
593 * *
594 ************************************************************************
595
596
597 ---------------------------------------------------------------------
598 TyVarTy
599 ~~~~~~~
600 -}
601
602 -- | Attempts to obtain the type variable underlying a 'Type', and panics with the
603 -- given message if this is not a type variable type. See also 'getTyVar_maybe'
604 getTyVar :: String -> Type -> TyVar
605 getTyVar msg ty = case getTyVar_maybe ty of
606 Just tv -> tv
607 Nothing -> panic ("getTyVar: " ++ msg)
608
609 isTyVarTy :: Type -> Bool
610 isTyVarTy ty = isJust (getTyVar_maybe ty)
611
612 -- | Attempts to obtain the type variable underlying a 'Type'
613 getTyVar_maybe :: Type -> Maybe TyVar
614 getTyVar_maybe ty | Just ty' <- coreView ty = getTyVar_maybe ty'
615 | otherwise = repGetTyVar_maybe ty
616
617 -- | If the type is a tyvar, possibly under a cast, returns it, along
618 -- with the coercion. Thus, the co is :: kind tv ~N kind type
619 getCastedTyVar_maybe :: Type -> Maybe (TyVar, CoercionN)
620 getCastedTyVar_maybe ty | Just ty' <- coreView ty = getCastedTyVar_maybe ty'
621 getCastedTyVar_maybe (CastTy (TyVarTy tv) co) = Just (tv, co)
622 getCastedTyVar_maybe (TyVarTy tv)
623 = Just (tv, mkReflCo Nominal (tyVarKind tv))
624 getCastedTyVar_maybe _ = Nothing
625
626 -- | Attempts to obtain the type variable underlying a 'Type', without
627 -- any expansion
628 repGetTyVar_maybe :: Type -> Maybe TyVar
629 repGetTyVar_maybe (TyVarTy tv) = Just tv
630 repGetTyVar_maybe _ = Nothing
631
632 {-
633 ---------------------------------------------------------------------
634 AppTy
635 ~~~~~
636 We need to be pretty careful with AppTy to make sure we obey the
637 invariant that a TyConApp is always visibly so. mkAppTy maintains the
638 invariant: use it.
639
640 Note [Decomposing fat arrow c=>t]
641 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
642 Can we unify (a b) with (Eq a => ty)? If we do so, we end up with
643 a partial application like ((=>) Eq a) which doesn't make sense in
644 source Haskell. In contrast, we *can* unify (a b) with (t1 -> t2).
645 Here's an example (Trac #9858) of how you might do it:
646 i :: (Typeable a, Typeable b) => Proxy (a b) -> TypeRep
647 i p = typeRep p
648
649 j = i (Proxy :: Proxy (Eq Int => Int))
650 The type (Proxy (Eq Int => Int)) is only accepted with -XImpredicativeTypes,
651 but suppose we want that. But then in the call to 'i', we end
652 up decomposing (Eq Int => Int), and we definitely don't want that.
653
654 This really only applies to the type checker; in Core, '=>' and '->'
655 are the same, as are 'Constraint' and '*'. But for now I've put
656 the test in repSplitAppTy_maybe, which applies throughout, because
657 the other calls to splitAppTy are in Unify, which is also used by
658 the type checker (e.g. when matching type-function equations).
659
660 -}
661
662 -- | Applies a type to another, as in e.g. @k a@
663 mkAppTy :: Type -> Type -> Type
664 mkAppTy (TyConApp tc tys) ty2 = mkTyConApp tc (tys ++ [ty2])
665 mkAppTy ty1 ty2 = AppTy ty1 ty2
666 -- Note that the TyConApp could be an
667 -- under-saturated type synonym. GHC allows that; e.g.
668 -- type Foo k = k a -> k a
669 -- type Id x = x
670 -- foo :: Foo Id -> Foo Id
671 --
672 -- Here Id is partially applied in the type sig for Foo,
673 -- but once the type synonyms are expanded all is well
674
675 mkAppTys :: Type -> [Type] -> Type
676 mkAppTys ty1 [] = ty1
677 mkAppTys (TyConApp tc tys1) tys2 = mkTyConApp tc (tys1 ++ tys2)
678 mkAppTys ty1 tys2 = foldl AppTy ty1 tys2
679
680 -------------
681 splitAppTy_maybe :: Type -> Maybe (Type, Type)
682 -- ^ Attempt to take a type application apart, whether it is a
683 -- function, type constructor, or plain type application. Note
684 -- that type family applications are NEVER unsaturated by this!
685 splitAppTy_maybe ty | Just ty' <- coreView ty
686 = splitAppTy_maybe ty'
687 splitAppTy_maybe ty = repSplitAppTy_maybe ty
688
689 -------------
690 repSplitAppTy_maybe :: HasDebugCallStack => Type -> Maybe (Type,Type)
691 -- ^ Does the AppTy split as in 'splitAppTy_maybe', but assumes that
692 -- any Core view stuff is already done
693 repSplitAppTy_maybe (FunTy ty1 ty2)
694 = Just (TyConApp funTyCon [rep1, rep2, ty1], ty2)
695 where
696 rep1 = getRuntimeRep ty1
697 rep2 = getRuntimeRep ty2
698
699 repSplitAppTy_maybe (AppTy ty1 ty2)
700 = Just (ty1, ty2)
701
702 repSplitAppTy_maybe (TyConApp tc tys)
703 | mightBeUnsaturatedTyCon tc || tys `lengthExceeds` tyConArity tc
704 , Just (tys', ty') <- snocView tys
705 = Just (TyConApp tc tys', ty') -- Never create unsaturated type family apps!
706
707 repSplitAppTy_maybe _other = Nothing
708
709 -- this one doesn't braek apart (c => t).
710 -- See Note [Decomposing fat arrow c=>t]
711 -- Defined here to avoid module loops between Unify and TcType.
712 tcRepSplitAppTy_maybe :: Type -> Maybe (Type,Type)
713 -- ^ Does the AppTy split as in 'tcSplitAppTy_maybe', but assumes that
714 -- any coreView stuff is already done. Refuses to look through (c => t)
715 tcRepSplitAppTy_maybe (FunTy ty1 ty2)
716 | isConstraintKind (typeKind ty1)
717 = Nothing -- See Note [Decomposing fat arrow c=>t]
718
719 | otherwise
720 = Just (TyConApp funTyCon [rep1, rep2, ty1], ty2)
721 where
722 rep1 = getRuntimeRep ty1
723 rep2 = getRuntimeRep ty2
724
725 tcRepSplitAppTy_maybe (AppTy ty1 ty2) = Just (ty1, ty2)
726 tcRepSplitAppTy_maybe (TyConApp tc tys)
727 | mightBeUnsaturatedTyCon tc || tys `lengthExceeds` tyConArity tc
728 , Just (tys', ty') <- snocView tys
729 = Just (TyConApp tc tys', ty') -- Never create unsaturated type family apps!
730 tcRepSplitAppTy_maybe _other = Nothing
731
732 -- | Split a type constructor application into its type constructor and
733 -- applied types. Note that this may fail in the case of a 'FunTy' with an
734 -- argument of unknown kind 'FunTy' (e.g. @FunTy (a :: k) Int@. since the kind
735 -- of @a@ isn't of the form @TYPE rep@). Consequently, you may need to zonk your
736 -- type before using this function.
737 --
738 -- If you only need the 'TyCon', consider using 'tcTyConAppTyCon_maybe'.
739 tcSplitTyConApp_maybe :: HasCallStack => Type -> Maybe (TyCon, [Type])
740 -- Defined here to avoid module loops between Unify and TcType.
741 tcSplitTyConApp_maybe ty | Just ty' <- tcView ty = tcSplitTyConApp_maybe ty'
742 tcSplitTyConApp_maybe ty = tcRepSplitTyConApp_maybe ty
743
744 -- | Like 'tcSplitTyConApp_maybe' but doesn't look through type synonyms.
745 tcRepSplitTyConApp_maybe :: HasCallStack => Type -> Maybe (TyCon, [Type])
746 -- Defined here to avoid module loops between Unify and TcType.
747 tcRepSplitTyConApp_maybe (TyConApp tc tys)
748 = Just (tc, tys)
749
750 tcRepSplitTyConApp_maybe (FunTy arg res)
751 = Just (funTyCon, [arg_rep, res_rep, arg, res])
752 where
753 arg_rep = getRuntimeRep arg
754 res_rep = getRuntimeRep res
755
756 tcRepSplitTyConApp_maybe _
757 = Nothing
758
759 -------------
760 splitAppTy :: Type -> (Type, Type)
761 -- ^ Attempts to take a type application apart, as in 'splitAppTy_maybe',
762 -- and panics if this is not possible
763 splitAppTy ty = case splitAppTy_maybe ty of
764 Just pr -> pr
765 Nothing -> panic "splitAppTy"
766
767 -------------
768 splitAppTys :: Type -> (Type, [Type])
769 -- ^ Recursively splits a type as far as is possible, leaving a residual
770 -- type being applied to and the type arguments applied to it. Never fails,
771 -- even if that means returning an empty list of type applications.
772 splitAppTys ty = split ty ty []
773 where
774 split orig_ty ty args | Just ty' <- coreView ty = split orig_ty ty' args
775 split _ (AppTy ty arg) args = split ty ty (arg:args)
776 split _ (TyConApp tc tc_args) args
777 = let -- keep type families saturated
778 n | mightBeUnsaturatedTyCon tc = 0
779 | otherwise = tyConArity tc
780 (tc_args1, tc_args2) = splitAt n tc_args
781 in
782 (TyConApp tc tc_args1, tc_args2 ++ args)
783 split _ (FunTy ty1 ty2) args
784 = ASSERT( null args )
785 (TyConApp funTyCon [], [rep1, rep2, ty1, ty2])
786 where
787 rep1 = getRuntimeRep ty1
788 rep2 = getRuntimeRep ty2
789
790 split orig_ty _ args = (orig_ty, args)
791
792 -- | Like 'splitAppTys', but doesn't look through type synonyms
793 repSplitAppTys :: HasDebugCallStack => Type -> (Type, [Type])
794 repSplitAppTys ty = split ty []
795 where
796 split (AppTy ty arg) args = split ty (arg:args)
797 split (TyConApp tc tc_args) args
798 = let n | mightBeUnsaturatedTyCon tc = 0
799 | otherwise = tyConArity tc
800 (tc_args1, tc_args2) = splitAt n tc_args
801 in
802 (TyConApp tc tc_args1, tc_args2 ++ args)
803 split (FunTy ty1 ty2) args
804 = ASSERT( null args )
805 (TyConApp funTyCon [], [rep1, rep2, ty1, ty2])
806 where
807 rep1 = getRuntimeRep ty1
808 rep2 = getRuntimeRep ty2
809
810 split ty args = (ty, args)
811
812 {-
813 LitTy
814 ~~~~~
815 -}
816
817 mkNumLitTy :: Integer -> Type
818 mkNumLitTy n = LitTy (NumTyLit n)
819
820 -- | Is this a numeric literal. We also look through type synonyms.
821 isNumLitTy :: Type -> Maybe Integer
822 isNumLitTy ty | Just ty1 <- coreView ty = isNumLitTy ty1
823 isNumLitTy (LitTy (NumTyLit n)) = Just n
824 isNumLitTy _ = Nothing
825
826 mkStrLitTy :: FastString -> Type
827 mkStrLitTy s = LitTy (StrTyLit s)
828
829 -- | Is this a symbol literal. We also look through type synonyms.
830 isStrLitTy :: Type -> Maybe FastString
831 isStrLitTy ty | Just ty1 <- coreView ty = isStrLitTy ty1
832 isStrLitTy (LitTy (StrTyLit s)) = Just s
833 isStrLitTy _ = Nothing
834
835
836 -- | Is this type a custom user error?
837 -- If so, give us the kind and the error message.
838 userTypeError_maybe :: Type -> Maybe Type
839 userTypeError_maybe t
840 = do { (tc, _kind : msg : _) <- splitTyConApp_maybe t
841 -- There may be more than 2 arguments, if the type error is
842 -- used as a type constructor (e.g. at kind `Type -> Type`).
843
844 ; guard (tyConName tc == errorMessageTypeErrorFamName)
845 ; return msg }
846
847 -- | Render a type corresponding to a user type error into a SDoc.
848 pprUserTypeErrorTy :: Type -> SDoc
849 pprUserTypeErrorTy ty =
850 case splitTyConApp_maybe ty of
851
852 -- Text "Something"
853 Just (tc,[txt])
854 | tyConName tc == typeErrorTextDataConName
855 , Just str <- isStrLitTy txt -> ftext str
856
857 -- ShowType t
858 Just (tc,[_k,t])
859 | tyConName tc == typeErrorShowTypeDataConName -> ppr t
860
861 -- t1 :<>: t2
862 Just (tc,[t1,t2])
863 | tyConName tc == typeErrorAppendDataConName ->
864 pprUserTypeErrorTy t1 <> pprUserTypeErrorTy t2
865
866 -- t1 :$$: t2
867 Just (tc,[t1,t2])
868 | tyConName tc == typeErrorVAppendDataConName ->
869 pprUserTypeErrorTy t1 $$ pprUserTypeErrorTy t2
870
871 -- An unevaluated type function
872 _ -> ppr ty
873
874
875
876
877 {-
878 ---------------------------------------------------------------------
879 FunTy
880 ~~~~~
881
882 Note [Representation of function types]
883 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
884
885 Functions (e.g. Int -> Char) are can be thought of as being applications
886 of funTyCon (known in Haskell surface syntax as (->)),
887
888 (->) :: forall (r1 :: RuntimeRep) (r2 :: RuntimeRep)
889 (a :: TYPE r1) (b :: TYPE r2).
890 a -> b -> Type
891
892 However, for efficiency's sake we represent saturated applications of (->)
893 with FunTy. For instance, the type,
894
895 (->) r1 r2 a b
896
897 is equivalent to,
898
899 FunTy (Anon a) b
900
901 Note how the RuntimeReps are implied in the FunTy representation. For this
902 reason we must be careful when recontructing the TyConApp representation (see,
903 for instance, splitTyConApp_maybe).
904
905 In the compiler we maintain the invariant that all saturated applications of
906 (->) are represented with FunTy.
907
908 See #11714.
909 -}
910
911 isFunTy :: Type -> Bool
912 isFunTy ty = isJust (splitFunTy_maybe ty)
913
914 splitFunTy :: Type -> (Type, Type)
915 -- ^ Attempts to extract the argument and result types from a type, and
916 -- panics if that is not possible. See also 'splitFunTy_maybe'
917 splitFunTy ty | Just ty' <- coreView ty = splitFunTy ty'
918 splitFunTy (FunTy arg res) = (arg, res)
919 splitFunTy other = pprPanic "splitFunTy" (ppr other)
920
921 splitFunTy_maybe :: Type -> Maybe (Type, Type)
922 -- ^ Attempts to extract the argument and result types from a type
923 splitFunTy_maybe ty | Just ty' <- coreView ty = splitFunTy_maybe ty'
924 splitFunTy_maybe (FunTy arg res) = Just (arg, res)
925 splitFunTy_maybe _ = Nothing
926
927 splitFunTys :: Type -> ([Type], Type)
928 splitFunTys ty = split [] ty ty
929 where
930 split args orig_ty ty | Just ty' <- coreView ty = split args orig_ty ty'
931 split args _ (FunTy arg res) = split (arg:args) res res
932 split args orig_ty _ = (reverse args, orig_ty)
933
934 funResultTy :: Type -> Type
935 -- ^ Extract the function result type and panic if that is not possible
936 funResultTy ty | Just ty' <- coreView ty = funResultTy ty'
937 funResultTy (FunTy _ res) = res
938 funResultTy ty = pprPanic "funResultTy" (ppr ty)
939
940 funArgTy :: Type -> Type
941 -- ^ Extract the function argument type and panic if that is not possible
942 funArgTy ty | Just ty' <- coreView ty = funArgTy ty'
943 funArgTy (FunTy arg _res) = arg
944 funArgTy ty = pprPanic "funArgTy" (ppr ty)
945
946 piResultTy :: HasDebugCallStack => Type -> Type -> Type
947 piResultTy ty arg = case piResultTy_maybe ty arg of
948 Just res -> res
949 Nothing -> pprPanic "piResultTy" (ppr ty $$ ppr arg)
950
951 piResultTy_maybe :: Type -> Type -> Maybe Type
952
953 -- ^ Just like 'piResultTys' but for a single argument
954 -- Try not to iterate 'piResultTy', because it's inefficient to substitute
955 -- one variable at a time; instead use 'piResultTys"
956 piResultTy_maybe ty arg
957 | Just ty' <- coreView ty = piResultTy_maybe ty' arg
958
959 | FunTy _ res <- ty
960 = Just res
961
962 | ForAllTy (TvBndr tv _) res <- ty
963 = let empty_subst = mkEmptyTCvSubst $ mkInScopeSet $
964 tyCoVarsOfTypes [arg,res]
965 in Just (substTy (extendTvSubst empty_subst tv arg) res)
966
967 | otherwise
968 = Nothing
969
970 -- | (piResultTys f_ty [ty1, .., tyn]) gives the type of (f ty1 .. tyn)
971 -- where f :: f_ty
972 -- 'piResultTys' is interesting because:
973 -- 1. 'f_ty' may have more for-alls than there are args
974 -- 2. Less obviously, it may have fewer for-alls
975 -- For case 2. think of:
976 -- piResultTys (forall a.a) [forall b.b, Int]
977 -- This really can happen, but only (I think) in situations involving
978 -- undefined. For example:
979 -- undefined :: forall a. a
980 -- Term: undefined @(forall b. b->b) @Int
981 -- This term should have type (Int -> Int), but notice that
982 -- there are more type args than foralls in 'undefined's type.
983
984 -- If you edit this function, you may need to update the GHC formalism
985 -- See Note [GHC Formalism] in coreSyn/CoreLint.hs
986
987 -- This is a heavily used function (e.g. from typeKind),
988 -- so we pay attention to efficiency, especially in the special case
989 -- where there are no for-alls so we are just dropping arrows from
990 -- a function type/kind.
991 piResultTys :: HasDebugCallStack => Type -> [Type] -> Type
992 piResultTys ty [] = ty
993 piResultTys ty orig_args@(arg:args)
994 | Just ty' <- coreView ty
995 = piResultTys ty' orig_args
996
997 | FunTy _ res <- ty
998 = piResultTys res args
999
1000 | ForAllTy (TvBndr tv _) res <- ty
1001 = go (extendVarEnv emptyTvSubstEnv tv arg) res args
1002
1003 | otherwise
1004 = pprPanic "piResultTys1" (ppr ty $$ ppr orig_args)
1005 where
1006 in_scope = mkInScopeSet (tyCoVarsOfTypes (ty:orig_args))
1007
1008 go :: TvSubstEnv -> Type -> [Type] -> Type
1009 go tv_env ty [] = substTy (mkTvSubst in_scope tv_env) ty
1010
1011 go tv_env ty all_args@(arg:args)
1012 | Just ty' <- coreView ty
1013 = go tv_env ty' all_args
1014
1015 | FunTy _ res <- ty
1016 = go tv_env res args
1017
1018 | ForAllTy (TvBndr tv _) res <- ty
1019 = go (extendVarEnv tv_env tv arg) res args
1020
1021 | TyVarTy tv <- ty
1022 , Just ty' <- lookupVarEnv tv_env tv
1023 -- Deals with piResultTys (forall a. a) [forall b.b, Int]
1024 = piResultTys ty' all_args
1025
1026 | otherwise
1027 = pprPanic "piResultTys2" (ppr ty $$ ppr orig_args $$ ppr all_args)
1028
1029 applyTysX :: [TyVar] -> Type -> [Type] -> Type
1030 -- applyTyxX beta-reduces (/\tvs. body_ty) arg_tys
1031 -- Assumes that (/\tvs. body_ty) is closed
1032 applyTysX tvs body_ty arg_tys
1033 = ASSERT2( arg_tys `lengthAtLeast` n_tvs, pp_stuff )
1034 ASSERT2( tyCoVarsOfType body_ty `subVarSet` mkVarSet tvs, pp_stuff )
1035 mkAppTys (substTyWith tvs (take n_tvs arg_tys) body_ty)
1036 (drop n_tvs arg_tys)
1037 where
1038 pp_stuff = vcat [ppr tvs, ppr body_ty, ppr arg_tys]
1039 n_tvs = length tvs
1040
1041 {-
1042 ---------------------------------------------------------------------
1043 TyConApp
1044 ~~~~~~~~
1045 -}
1046
1047 -- | A key function: builds a 'TyConApp' or 'FunTy' as appropriate to
1048 -- its arguments. Applies its arguments to the constructor from left to right.
1049 mkTyConApp :: TyCon -> [Type] -> Type
1050 mkTyConApp tycon tys
1051 | isFunTyCon tycon
1052 , [_rep1,_rep2,ty1,ty2] <- tys
1053 = FunTy ty1 ty2
1054
1055 | otherwise
1056 = TyConApp tycon tys
1057
1058 -- splitTyConApp "looks through" synonyms, because they don't
1059 -- mean a distinct type, but all other type-constructor applications
1060 -- including functions are returned as Just ..
1061
1062 -- | Retrieve the tycon heading this type, if there is one. Does /not/
1063 -- look through synonyms.
1064 tyConAppTyConPicky_maybe :: Type -> Maybe TyCon
1065 tyConAppTyConPicky_maybe (TyConApp tc _) = Just tc
1066 tyConAppTyConPicky_maybe (FunTy {}) = Just funTyCon
1067 tyConAppTyConPicky_maybe _ = Nothing
1068
1069
1070 -- | The same as @fst . splitTyConApp@
1071 tyConAppTyCon_maybe :: Type -> Maybe TyCon
1072 tyConAppTyCon_maybe ty | Just ty' <- coreView ty = tyConAppTyCon_maybe ty'
1073 tyConAppTyCon_maybe (TyConApp tc _) = Just tc
1074 tyConAppTyCon_maybe (FunTy {}) = Just funTyCon
1075 tyConAppTyCon_maybe _ = Nothing
1076
1077 tyConAppTyCon :: Type -> TyCon
1078 tyConAppTyCon ty = tyConAppTyCon_maybe ty `orElse` pprPanic "tyConAppTyCon" (ppr ty)
1079
1080 -- | The same as @snd . splitTyConApp@
1081 tyConAppArgs_maybe :: Type -> Maybe [Type]
1082 tyConAppArgs_maybe ty | Just ty' <- coreView ty = tyConAppArgs_maybe ty'
1083 tyConAppArgs_maybe (TyConApp _ tys) = Just tys
1084 tyConAppArgs_maybe (FunTy arg res)
1085 | Just rep1 <- getRuntimeRep_maybe arg
1086 , Just rep2 <- getRuntimeRep_maybe res
1087 = Just [rep1, rep2, arg, res]
1088 tyConAppArgs_maybe _ = Nothing
1089
1090 tyConAppArgs :: Type -> [Type]
1091 tyConAppArgs ty = tyConAppArgs_maybe ty `orElse` pprPanic "tyConAppArgs" (ppr ty)
1092
1093 tyConAppArgN :: Int -> Type -> Type
1094 -- Executing Nth
1095 tyConAppArgN n ty
1096 = case tyConAppArgs_maybe ty of
1097 Just tys -> ASSERT2( tys `lengthExceeds` n, ppr n <+> ppr tys ) tys `getNth` n
1098 Nothing -> pprPanic "tyConAppArgN" (ppr n <+> ppr ty)
1099
1100 -- | Attempts to tease a type apart into a type constructor and the application
1101 -- of a number of arguments to that constructor. Panics if that is not possible.
1102 -- See also 'splitTyConApp_maybe'
1103 splitTyConApp :: Type -> (TyCon, [Type])
1104 splitTyConApp ty = case splitTyConApp_maybe ty of
1105 Just stuff -> stuff
1106 Nothing -> pprPanic "splitTyConApp" (ppr ty)
1107
1108 -- | Attempts to tease a type apart into a type constructor and the application
1109 -- of a number of arguments to that constructor
1110 splitTyConApp_maybe :: HasDebugCallStack => Type -> Maybe (TyCon, [Type])
1111 splitTyConApp_maybe ty | Just ty' <- coreView ty = splitTyConApp_maybe ty'
1112 splitTyConApp_maybe ty = repSplitTyConApp_maybe ty
1113
1114 -- | Like 'splitTyConApp_maybe', but doesn't look through synonyms. This
1115 -- assumes the synonyms have already been dealt with.
1116 repSplitTyConApp_maybe :: HasDebugCallStack => Type -> Maybe (TyCon, [Type])
1117 repSplitTyConApp_maybe (TyConApp tc tys) = Just (tc, tys)
1118 repSplitTyConApp_maybe (FunTy arg res)
1119 | Just arg_rep <- getRuntimeRep_maybe arg
1120 , Just res_rep <- getRuntimeRep_maybe res
1121 = Just (funTyCon, [arg_rep, res_rep, arg, res])
1122 repSplitTyConApp_maybe _ = Nothing
1123
1124 -- | Attempts to tease a list type apart and gives the type of the elements if
1125 -- successful (looks through type synonyms)
1126 splitListTyConApp_maybe :: Type -> Maybe Type
1127 splitListTyConApp_maybe ty = case splitTyConApp_maybe ty of
1128 Just (tc,[e]) | tc == listTyCon -> Just e
1129 _other -> Nothing
1130
1131 -- | What is the role assigned to the next parameter of this type? Usually,
1132 -- this will be 'Nominal', but if the type is a 'TyConApp', we may be able to
1133 -- do better. The type does *not* have to be well-kinded when applied for this
1134 -- to work!
1135 nextRole :: Type -> Role
1136 nextRole ty
1137 | Just (tc, tys) <- splitTyConApp_maybe ty
1138 , let num_tys = length tys
1139 , num_tys < tyConArity tc
1140 = tyConRoles tc `getNth` num_tys
1141
1142 | otherwise
1143 = Nominal
1144
1145 newTyConInstRhs :: TyCon -> [Type] -> Type
1146 -- ^ Unwrap one 'layer' of newtype on a type constructor and its
1147 -- arguments, using an eta-reduced version of the @newtype@ if possible.
1148 -- This requires tys to have at least @newTyConInstArity tycon@ elements.
1149 newTyConInstRhs tycon tys
1150 = ASSERT2( tvs `leLength` tys, ppr tycon $$ ppr tys $$ ppr tvs )
1151 applyTysX tvs rhs tys
1152 where
1153 (tvs, rhs) = newTyConEtadRhs tycon
1154
1155 {-
1156 ---------------------------------------------------------------------
1157 CastTy
1158 ~~~~~~
1159 A casted type has its *kind* casted into something new.
1160
1161 Note [No reflexive casts in types]
1162 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1163 As far as possible, we would like to maintain the following property:
1164
1165 (*) If (t1 `eqType` t2), then t1 and t2 are treated identically within GHC.
1166
1167 The (*) property is very useful, because we have a tendency to compare two
1168 types to see if they're equal, and then arbitrarily choose one. We don't
1169 want this arbitrary choice to then matter later on. Maintaining (*) means
1170 that every function that looks at a structure of a type must think about
1171 casts. In places where we directly pattern-match, this consideration is
1172 forced by consideration of the CastTy constructor.
1173
1174 But, when we call a splitXXX function, it's easy to ignore the possibility
1175 of casts. In particular, splitTyConApp is used extensively, and we don't
1176 want it to fail on (T a b c |> co). Happily, if we have
1177 (T a b c |> co) `eqType` (T d e f)
1178 then co must be reflexive. Why? eqType checks that the kinds are equal, as
1179 well as checking that (a `eqType` d), (b `eqType` e), and (c `eqType` f).
1180 By the kind check, we know that (T a b c |> co) and (T d e f) have the same
1181 kind. So the only way that co could be non-reflexive is for (T a b c) to have
1182 a different kind than (T d e f). But because T's kind is closed (all tycon kinds
1183 are closed), the only way for this to happen is that one of the arguments has
1184 to differ, leading to a contradiction. Thus, co is reflexive.
1185
1186 Accordingly, by eliminating reflexive casts, splitTyConApp need not worry
1187 about outermost casts to uphold (*).
1188
1189 Unfortunately, that's not the end of the story. Consider comparing
1190 (T a b c) =? (T a b |> (co -> <Type>)) (c |> sym co)
1191 These two types have the same kind (Type), but the left type is a TyConApp
1192 while the right type is not. To handle this case, we will have to implement
1193 some variant of the dreaded KPush algorithm (c.f. CoreOpt.pushCoDataCon).
1194 This stone is left unturned for now, meaning that we don't yet uphold (*).
1195
1196 The other place where (*) will be hard to guarantee is in splitAppTy, because
1197 I (Richard E) can't think of a way to push coercions into AppTys. The good
1198 news here is that splitAppTy is not used all that much, and so all clients of
1199 that function can simply be told to use splitCastTy as well, in order to
1200 uphold (*). This, too, is left undone, for now.
1201
1202 -}
1203
1204 splitCastTy_maybe :: Type -> Maybe (Type, Coercion)
1205 splitCastTy_maybe ty | Just ty' <- coreView ty = splitCastTy_maybe ty'
1206 splitCastTy_maybe (CastTy ty co) = Just (ty, co)
1207 splitCastTy_maybe _ = Nothing
1208
1209 -- | Make a 'CastTy'. The Coercion must be nominal. Checks the
1210 -- Coercion for reflexivity, dropping it if it's reflexive.
1211 -- See Note [No reflexive casts in types]
1212 mkCastTy :: Type -> Coercion -> Type
1213 mkCastTy ty co | isReflexiveCo co = ty
1214 -- NB: Do the slow check here. This is important to keep the splitXXX
1215 -- functions working properly. Otherwise, we may end up with something
1216 -- like (((->) |> something_reflexive_but_not_obviously_so) biz baz)
1217 -- fails under splitFunTy_maybe. This happened with the cheaper check
1218 -- in test dependent/should_compile/dynamic-paper.
1219
1220 mkCastTy (CastTy ty co1) co2 = mkCastTy ty (co1 `mkTransCo` co2)
1221 mkCastTy ty co = CastTy ty co
1222
1223 tyConBindersTyBinders :: [TyConBinder] -> [TyBinder]
1224 -- Return the tyConBinders in TyBinder form
1225 tyConBindersTyBinders = map to_tyb
1226 where
1227 to_tyb (TvBndr tv (NamedTCB vis)) = Named (TvBndr tv vis)
1228 to_tyb (TvBndr tv AnonTCB) = Anon (tyVarKind tv)
1229
1230 {-
1231 --------------------------------------------------------------------
1232 CoercionTy
1233 ~~~~~~~~~~
1234 CoercionTy allows us to inject coercions into types. A CoercionTy
1235 should appear only in the right-hand side of an application.
1236 -}
1237
1238 mkCoercionTy :: Coercion -> Type
1239 mkCoercionTy = CoercionTy
1240
1241 isCoercionTy :: Type -> Bool
1242 isCoercionTy (CoercionTy _) = True
1243 isCoercionTy _ = False
1244
1245 isCoercionTy_maybe :: Type -> Maybe Coercion
1246 isCoercionTy_maybe (CoercionTy co) = Just co
1247 isCoercionTy_maybe _ = Nothing
1248
1249 stripCoercionTy :: Type -> Coercion
1250 stripCoercionTy (CoercionTy co) = co
1251 stripCoercionTy ty = pprPanic "stripCoercionTy" (ppr ty)
1252
1253 {-
1254 ---------------------------------------------------------------------
1255 SynTy
1256 ~~~~~
1257
1258 Notes on type synonyms
1259 ~~~~~~~~~~~~~~~~~~~~~~
1260 The various "split" functions (splitFunTy, splitRhoTy, splitForAllTy) try
1261 to return type synonyms wherever possible. Thus
1262
1263 type Foo a = a -> a
1264
1265 we want
1266 splitFunTys (a -> Foo a) = ([a], Foo a)
1267 not ([a], a -> a)
1268
1269 The reason is that we then get better (shorter) type signatures in
1270 interfaces. Notably this plays a role in tcTySigs in TcBinds.hs.
1271
1272
1273 ---------------------------------------------------------------------
1274 ForAllTy
1275 ~~~~~~~~
1276 -}
1277
1278 -- | Make a dependent forall over an Inferred (as opposed to Specified)
1279 -- variable
1280 mkInvForAllTy :: TyVar -> Type -> Type
1281 mkInvForAllTy tv ty = ASSERT( isTyVar tv )
1282 ForAllTy (TvBndr tv Inferred) ty
1283
1284 -- | Like mkForAllTys, but assumes all variables are dependent and Inferred,
1285 -- a common case
1286 mkInvForAllTys :: [TyVar] -> Type -> Type
1287 mkInvForAllTys tvs ty = ASSERT( all isTyVar tvs )
1288 foldr mkInvForAllTy ty tvs
1289
1290 -- | Like mkForAllTys, but assumes all variables are dependent and specified,
1291 -- a common case
1292 mkSpecForAllTys :: [TyVar] -> Type -> Type
1293 mkSpecForAllTys tvs = ASSERT( all isTyVar tvs )
1294 mkForAllTys [ TvBndr tv Specified | tv <- tvs ]
1295
1296 -- | Like mkForAllTys, but assumes all variables are dependent and visible
1297 mkVisForAllTys :: [TyVar] -> Type -> Type
1298 mkVisForAllTys tvs = ASSERT( all isTyVar tvs )
1299 mkForAllTys [ TvBndr tv Required | tv <- tvs ]
1300
1301 mkLamType :: Var -> Type -> Type
1302 -- ^ Makes a @(->)@ type or an implicit forall type, depending
1303 -- on whether it is given a type variable or a term variable.
1304 -- This is used, for example, when producing the type of a lambda.
1305 -- Always uses Inferred binders.
1306 mkLamTypes :: [Var] -> Type -> Type
1307 -- ^ 'mkLamType' for multiple type or value arguments
1308
1309 mkLamType v ty
1310 | isTyVar v = ForAllTy (TvBndr v Inferred) ty
1311 | otherwise = FunTy (varType v) ty
1312
1313 mkLamTypes vs ty = foldr mkLamType ty vs
1314
1315 -- | Given a list of type-level vars and a result kind,
1316 -- makes TyBinders, preferring anonymous binders
1317 -- if the variable is, in fact, not dependent.
1318 -- e.g. mkTyConBindersPreferAnon [(k:*),(b:k),(c:k)] (k->k)
1319 -- We want (k:*) Named, (a;k) Anon, (c:k) Anon
1320 --
1321 -- All binders are /visible/.
1322 mkTyConBindersPreferAnon :: [TyVar] -> Type -> [TyConBinder]
1323 mkTyConBindersPreferAnon vars inner_ty = fst (go vars)
1324 where
1325 go :: [TyVar] -> ([TyConBinder], VarSet) -- also returns the free vars
1326 go [] = ([], tyCoVarsOfType inner_ty)
1327 go (v:vs) | v `elemVarSet` fvs
1328 = ( TvBndr v (NamedTCB Required) : binders
1329 , fvs `delVarSet` v `unionVarSet` kind_vars )
1330 | otherwise
1331 = ( TvBndr v AnonTCB : binders
1332 , fvs `unionVarSet` kind_vars )
1333 where
1334 (binders, fvs) = go vs
1335 kind_vars = tyCoVarsOfType $ tyVarKind v
1336
1337 -- | Take a ForAllTy apart, returning the list of tyvars and the result type.
1338 -- This always succeeds, even if it returns only an empty list. Note that the
1339 -- result type returned may have free variables that were bound by a forall.
1340 splitForAllTys :: Type -> ([TyVar], Type)
1341 splitForAllTys ty = split ty ty []
1342 where
1343 split orig_ty ty tvs | Just ty' <- coreView ty = split orig_ty ty' tvs
1344 split _ (ForAllTy (TvBndr tv _) ty) tvs = split ty ty (tv:tvs)
1345 split orig_ty _ tvs = (reverse tvs, orig_ty)
1346
1347 -- | Like 'splitPiTys' but split off only /named/ binders.
1348 splitForAllTyVarBndrs :: Type -> ([TyVarBinder], Type)
1349 splitForAllTyVarBndrs ty = split ty ty []
1350 where
1351 split orig_ty ty bs | Just ty' <- coreView ty = split orig_ty ty' bs
1352 split _ (ForAllTy b res) bs = split res res (b:bs)
1353 split orig_ty _ bs = (reverse bs, orig_ty)
1354
1355 -- | Checks whether this is a proper forall (with a named binder)
1356 isForAllTy :: Type -> Bool
1357 isForAllTy ty | Just ty' <- coreView ty = isForAllTy ty'
1358 isForAllTy (ForAllTy {}) = True
1359 isForAllTy _ = False
1360
1361 -- | Is this a function or forall?
1362 isPiTy :: Type -> Bool
1363 isPiTy ty | Just ty' <- coreView ty = isForAllTy ty'
1364 isPiTy (ForAllTy {}) = True
1365 isPiTy (FunTy {}) = True
1366 isPiTy _ = False
1367
1368 -- | Take a forall type apart, or panics if that is not possible.
1369 splitForAllTy :: Type -> (TyVar, Type)
1370 splitForAllTy ty
1371 | Just answer <- splitForAllTy_maybe ty = answer
1372 | otherwise = pprPanic "splitForAllTy" (ppr ty)
1373
1374 -- | Drops all ForAllTys
1375 dropForAlls :: Type -> Type
1376 dropForAlls ty = go ty
1377 where
1378 go ty | Just ty' <- coreView ty = go ty'
1379 go (ForAllTy _ res) = go res
1380 go res = res
1381
1382 -- | Attempts to take a forall type apart, but only if it's a proper forall,
1383 -- with a named binder
1384 splitForAllTy_maybe :: Type -> Maybe (TyVar, Type)
1385 splitForAllTy_maybe ty = go ty
1386 where
1387 go ty | Just ty' <- coreView ty = go ty'
1388 go (ForAllTy (TvBndr tv _) ty) = Just (tv, ty)
1389 go _ = Nothing
1390
1391 -- | Attempts to take a forall type apart; works with proper foralls and
1392 -- functions
1393 splitPiTy_maybe :: Type -> Maybe (TyBinder, Type)
1394 splitPiTy_maybe ty = go ty
1395 where
1396 go ty | Just ty' <- coreView ty = go ty'
1397 go (ForAllTy bndr ty) = Just (Named bndr, ty)
1398 go (FunTy arg res) = Just (Anon arg, res)
1399 go _ = Nothing
1400
1401 -- | Takes a forall type apart, or panics
1402 splitPiTy :: Type -> (TyBinder, Type)
1403 splitPiTy ty
1404 | Just answer <- splitPiTy_maybe ty = answer
1405 | otherwise = pprPanic "splitPiTy" (ppr ty)
1406
1407 -- | Split off all TyBinders to a type, splitting both proper foralls
1408 -- and functions
1409 splitPiTys :: Type -> ([TyBinder], Type)
1410 splitPiTys ty = split ty ty []
1411 where
1412 split orig_ty ty bs | Just ty' <- coreView ty = split orig_ty ty' bs
1413 split _ (ForAllTy b res) bs = split res res (Named b : bs)
1414 split _ (FunTy arg res) bs = split res res (Anon arg : bs)
1415 split orig_ty _ bs = (reverse bs, orig_ty)
1416
1417 -- Like splitPiTys, but returns only *invisible* binders, including constraints
1418 -- Stops at the first visible binder
1419 splitPiTysInvisible :: Type -> ([TyBinder], Type)
1420 splitPiTysInvisible ty = split ty ty []
1421 where
1422 split orig_ty ty bs | Just ty' <- coreView ty = split orig_ty ty' bs
1423 split _ (ForAllTy b@(TvBndr _ vis) res) bs
1424 | isInvisibleArgFlag vis = split res res (Named b : bs)
1425 split _ (FunTy arg res) bs
1426 | isPredTy arg = split res res (Anon arg : bs)
1427 split orig_ty _ bs = (reverse bs, orig_ty)
1428
1429 -- | Given a tycon and its arguments, filters out any invisible arguments
1430 filterOutInvisibleTypes :: TyCon -> [Type] -> [Type]
1431 filterOutInvisibleTypes tc tys = snd $ partitionInvisibles tc id tys
1432
1433 -- | Given a tycon and a list of things (which correspond to arguments),
1434 -- partitions the things into
1435 -- Inferred or Specified ones and
1436 -- Required ones
1437 -- The callback function is necessary for this scenario:
1438 --
1439 -- > T :: forall k. k -> k
1440 -- > partitionInvisibles T [forall m. m -> m -> m, S, R, Q]
1441 --
1442 -- After substituting, we get
1443 --
1444 -- > T (forall m. m -> m -> m) :: (forall m. m -> m -> m) -> forall n. n -> n -> n
1445 --
1446 -- Thus, the first argument is invisible, @S@ is visible, @R@ is invisible again,
1447 -- and @Q@ is visible.
1448 --
1449 -- If you're absolutely sure that your tycon's kind doesn't end in a variable,
1450 -- it's OK if the callback function panics, as that's the only time it's
1451 -- consulted.
1452 partitionInvisibles :: TyCon -> (a -> Type) -> [a] -> ([a], [a])
1453 partitionInvisibles tc get_ty = go emptyTCvSubst (tyConKind tc)
1454 where
1455 go _ _ [] = ([], [])
1456 go subst (ForAllTy (TvBndr tv vis) res_ki) (x:xs)
1457 | isVisibleArgFlag vis = second (x :) (go subst' res_ki xs)
1458 | otherwise = first (x :) (go subst' res_ki xs)
1459 where
1460 subst' = extendTvSubst subst tv (get_ty x)
1461 go subst (TyVarTy tv) xs
1462 | Just ki <- lookupTyVar subst tv = go subst ki xs
1463 go _ _ xs = ([], xs) -- something is ill-kinded. But this can happen
1464 -- when printing errors. Assume everything is visible.
1465
1466 -- @isTauTy@ tests if a type has no foralls
1467 isTauTy :: Type -> Bool
1468 isTauTy ty | Just ty' <- coreView ty = isTauTy ty'
1469 isTauTy (TyVarTy _) = True
1470 isTauTy (LitTy {}) = True
1471 isTauTy (TyConApp tc tys) = all isTauTy tys && isTauTyCon tc
1472 isTauTy (AppTy a b) = isTauTy a && isTauTy b
1473 isTauTy (FunTy a b) = isTauTy a && isTauTy b
1474 isTauTy (ForAllTy {}) = False
1475 isTauTy (CastTy ty _) = isTauTy ty
1476 isTauTy (CoercionTy _) = False -- Not sure about this
1477
1478 {-
1479 %************************************************************************
1480 %* *
1481 TyBinders
1482 %* *
1483 %************************************************************************
1484 -}
1485
1486 -- | Make an anonymous binder
1487 mkAnonBinder :: Type -> TyBinder
1488 mkAnonBinder = Anon
1489
1490 -- | Does this binder bind a variable that is /not/ erased? Returns
1491 -- 'True' for anonymous binders.
1492 isAnonTyBinder :: TyBinder -> Bool
1493 isAnonTyBinder (Named {}) = False
1494 isAnonTyBinder (Anon {}) = True
1495
1496 isNamedTyBinder :: TyBinder -> Bool
1497 isNamedTyBinder (Named {}) = True
1498 isNamedTyBinder (Anon {}) = False
1499
1500 tyBinderType :: TyBinder -> Type
1501 -- Barely used
1502 tyBinderType (Named tvb) = binderKind tvb
1503 tyBinderType (Anon ty) = ty
1504
1505 -- | Extract a relevant type, if there is one.
1506 binderRelevantType_maybe :: TyBinder -> Maybe Type
1507 binderRelevantType_maybe (Named {}) = Nothing
1508 binderRelevantType_maybe (Anon ty) = Just ty
1509
1510 -- | Like 'maybe', but for binders.
1511 caseBinder :: TyBinder -- ^ binder to scrutinize
1512 -> (TyVarBinder -> a) -- ^ named case
1513 -> (Type -> a) -- ^ anonymous case
1514 -> a
1515 caseBinder (Named v) f _ = f v
1516 caseBinder (Anon t) _ d = d t
1517
1518 -- | Manufacture a new 'TyConBinder' from a 'TyBinder'. Anonymous
1519 -- 'TyBinder's are still assigned names as 'TyConBinder's, so we need
1520 -- the extra gunk with which to construct a 'Name'. Used when producing
1521 -- tyConTyVars from a datatype kind signature. Defined here to avoid module
1522 -- loops.
1523 mkTyBinderTyConBinder :: TyBinder -> SrcSpan -> Unique -> OccName -> TyConBinder
1524 mkTyBinderTyConBinder (Named (TvBndr tv argf)) _ _ _ = TvBndr tv (NamedTCB argf)
1525 mkTyBinderTyConBinder (Anon kind) loc uniq occ
1526 = TvBndr (mkTyVar (mkInternalName uniq occ loc) kind) AnonTCB
1527
1528 {-
1529 %************************************************************************
1530 %* *
1531 Pred
1532 * *
1533 ************************************************************************
1534
1535 Predicates on PredType
1536
1537 Note [isPredTy complications]
1538 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1539 You would think that we could define
1540 isPredTy ty = isConstraintKind (typeKind ty)
1541 But there are a number of complications:
1542
1543 * isPredTy is used when printing types, which can happen in debug
1544 printing during type checking of not-fully-zonked types. So it's
1545 not cool to say isConstraintKind (typeKind ty) because, absent
1546 zonking, the type might be ill-kinded, and typeKind crashes. Hence the
1547 rather tiresome story here
1548
1549 * isPredTy must return "True" to *unlifted* coercions, such as (t1 ~# t2)
1550 and (t1 ~R# t2), which are not of kind Constraint! Currently they are
1551 of kind #.
1552
1553 * If we do form the type '(C a => C [a]) => blah', then we'd like to
1554 print it as such. But that means that isPredTy must return True for
1555 (C a => C [a]). Admittedly that type is illegal in Haskell, but we
1556 want to print it nicely in error messages.
1557 -}
1558
1559 -- | Is the type suitable to classify a given/wanted in the typechecker?
1560 isPredTy :: Type -> Bool
1561 -- See Note [isPredTy complications]
1562 isPredTy ty = go ty []
1563 where
1564 go :: Type -> [KindOrType] -> Bool
1565 go (AppTy ty1 ty2) args = go ty1 (ty2 : args)
1566 go (TyVarTy tv) args = go_k (tyVarKind tv) args
1567 go (TyConApp tc tys) args = ASSERT( null args ) -- TyConApp invariant
1568 go_tc tc tys
1569 go (FunTy arg res) []
1570 | isPredTy arg = isPredTy res -- (Eq a => C a)
1571 | otherwise = False -- (Int -> Bool)
1572 go (ForAllTy _ ty) [] = go ty []
1573 go (CastTy _ co) args = go_k (pSnd (coercionKind co)) args
1574 go _ _ = False
1575
1576 go_tc :: TyCon -> [KindOrType] -> Bool
1577 go_tc tc args
1578 | tc `hasKey` eqPrimTyConKey || tc `hasKey` eqReprPrimTyConKey
1579 = args `lengthIs` 4 -- ~# and ~R# sadly have result kind #
1580 -- not Constraint; but we still want
1581 -- isPredTy to reply True.
1582 | otherwise = go_k (tyConKind tc) args
1583
1584 go_k :: Kind -> [KindOrType] -> Bool
1585 -- True <=> ('k' applied to 'kts') = Constraint
1586 go_k k [] = isConstraintKind k
1587 go_k k (arg:args) = case piResultTy_maybe k arg of
1588 Just k' -> go_k k' args
1589 Nothing -> WARN( True, text "isPredTy" <+> ppr ty )
1590 False
1591 -- This last case shouldn't happen under most circumstances. It can
1592 -- occur if we call isPredTy during kind checking, especially if one
1593 -- of the following happens:
1594 --
1595 -- 1. There is actually a kind error. Example in which this showed up:
1596 -- polykinds/T11399
1597 --
1598 -- 2. A type constructor application appears to be oversaturated. An
1599 -- example of this occurred in GHC Trac #13187:
1600 --
1601 -- {-# LANGUAGE PolyKinds #-}
1602 -- type Const a b = b
1603 -- f :: Const Int (,) Bool Char -> Char
1604 --
1605 -- We call isPredTy (Const k1 k2 Int (,) Bool Char
1606 -- where k1,k2 are unification variables that have been
1607 -- unified to *, and (*->*->*) resp, /but not zonked/.
1608 -- This shows that isPredTy can report a false negative
1609 -- if a constraint is similarly oversaturated, but
1610 -- it's hard to do better than isPredTy currently does without
1611 -- zonking, so we punt on such cases for now. This only happens
1612 -- during debug-printing, so it doesn't matter.
1613
1614 isClassPred, isEqPred, isNomEqPred, isIPPred :: PredType -> Bool
1615 isClassPred ty = case tyConAppTyCon_maybe ty of
1616 Just tyCon | isClassTyCon tyCon -> True
1617 _ -> False
1618 isEqPred ty = case tyConAppTyCon_maybe ty of
1619 Just tyCon -> tyCon `hasKey` eqPrimTyConKey
1620 || tyCon `hasKey` eqReprPrimTyConKey
1621 _ -> False
1622
1623 isNomEqPred ty = case tyConAppTyCon_maybe ty of
1624 Just tyCon -> tyCon `hasKey` eqPrimTyConKey
1625 _ -> False
1626
1627 isIPPred ty = case tyConAppTyCon_maybe ty of
1628 Just tc -> isIPTyCon tc
1629 _ -> False
1630
1631 isIPTyCon :: TyCon -> Bool
1632 isIPTyCon tc = tc `hasKey` ipClassKey
1633 -- Class and its corresponding TyCon have the same Unique
1634
1635 isIPClass :: Class -> Bool
1636 isIPClass cls = cls `hasKey` ipClassKey
1637
1638 isCTupleClass :: Class -> Bool
1639 isCTupleClass cls = isTupleTyCon (classTyCon cls)
1640
1641 isIPPred_maybe :: Type -> Maybe (FastString, Type)
1642 isIPPred_maybe ty =
1643 do (tc,[t1,t2]) <- splitTyConApp_maybe ty
1644 guard (isIPTyCon tc)
1645 x <- isStrLitTy t1
1646 return (x,t2)
1647
1648 {-
1649 Make PredTypes
1650
1651 --------------------- Equality types ---------------------------------
1652 -}
1653
1654 -- | Makes a lifted equality predicate at the given role
1655 mkPrimEqPredRole :: Role -> Type -> Type -> PredType
1656 mkPrimEqPredRole Nominal = mkPrimEqPred
1657 mkPrimEqPredRole Representational = mkReprPrimEqPred
1658 mkPrimEqPredRole Phantom = panic "mkPrimEqPredRole phantom"
1659
1660 -- | Creates a primitive type equality predicate.
1661 -- Invariant: the types are not Coercions
1662 mkPrimEqPred :: Type -> Type -> Type
1663 mkPrimEqPred ty1 ty2
1664 = TyConApp eqPrimTyCon [k1, k2, ty1, ty2]
1665 where
1666 k1 = typeKind ty1
1667 k2 = typeKind ty2
1668
1669 -- | Creates a primite type equality predicate with explicit kinds
1670 mkHeteroPrimEqPred :: Kind -> Kind -> Type -> Type -> Type
1671 mkHeteroPrimEqPred k1 k2 ty1 ty2 = TyConApp eqPrimTyCon [k1, k2, ty1, ty2]
1672
1673 -- | Creates a primitive representational type equality predicate
1674 -- with explicit kinds
1675 mkHeteroReprPrimEqPred :: Kind -> Kind -> Type -> Type -> Type
1676 mkHeteroReprPrimEqPred k1 k2 ty1 ty2
1677 = TyConApp eqReprPrimTyCon [k1, k2, ty1, ty2]
1678
1679 -- | Try to split up a coercion type into the types that it coerces
1680 splitCoercionType_maybe :: Type -> Maybe (Type, Type)
1681 splitCoercionType_maybe ty
1682 = do { (tc, [_, _, ty1, ty2]) <- splitTyConApp_maybe ty
1683 ; guard $ tc `hasKey` eqPrimTyConKey || tc `hasKey` eqReprPrimTyConKey
1684 ; return (ty1, ty2) }
1685
1686 mkReprPrimEqPred :: Type -> Type -> Type
1687 mkReprPrimEqPred ty1 ty2
1688 = TyConApp eqReprPrimTyCon [k1, k2, ty1, ty2]
1689 where
1690 k1 = typeKind ty1
1691 k2 = typeKind ty2
1692
1693 equalityTyCon :: Role -> TyCon
1694 equalityTyCon Nominal = eqPrimTyCon
1695 equalityTyCon Representational = eqReprPrimTyCon
1696 equalityTyCon Phantom = eqPhantPrimTyCon
1697
1698 -- --------------------- Dictionary types ---------------------------------
1699
1700 mkClassPred :: Class -> [Type] -> PredType
1701 mkClassPred clas tys = TyConApp (classTyCon clas) tys
1702
1703 isDictTy :: Type -> Bool
1704 isDictTy = isClassPred
1705
1706 isDictLikeTy :: Type -> Bool
1707 -- Note [Dictionary-like types]
1708 isDictLikeTy ty | Just ty' <- coreView ty = isDictLikeTy ty'
1709 isDictLikeTy ty = case splitTyConApp_maybe ty of
1710 Just (tc, tys) | isClassTyCon tc -> True
1711 | isTupleTyCon tc -> all isDictLikeTy tys
1712 _other -> False
1713
1714 {-
1715 Note [Dictionary-like types]
1716 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1717 Being "dictionary-like" means either a dictionary type or a tuple thereof.
1718 In GHC 6.10 we build implication constraints which construct such tuples,
1719 and if we land up with a binding
1720 t :: (C [a], Eq [a])
1721 t = blah
1722 then we want to treat t as cheap under "-fdicts-cheap" for example.
1723 (Implication constraints are normally inlined, but sadly not if the
1724 occurrence is itself inside an INLINE function! Until we revise the
1725 handling of implication constraints, that is.) This turned out to
1726 be important in getting good arities in DPH code. Example:
1727
1728 class C a
1729 class D a where { foo :: a -> a }
1730 instance C a => D (Maybe a) where { foo x = x }
1731
1732 bar :: (C a, C b) => a -> b -> (Maybe a, Maybe b)
1733 {-# INLINE bar #-}
1734 bar x y = (foo (Just x), foo (Just y))
1735
1736 Then 'bar' should jolly well have arity 4 (two dicts, two args), but
1737 we ended up with something like
1738 bar = __inline_me__ (\d1,d2. let t :: (D (Maybe a), D (Maybe b)) = ...
1739 in \x,y. <blah>)
1740
1741 This is all a bit ad-hoc; eg it relies on knowing that implication
1742 constraints build tuples.
1743
1744
1745 Decomposing PredType
1746 -}
1747
1748 -- | A choice of equality relation. This is separate from the type 'Role'
1749 -- because 'Phantom' does not define a (non-trivial) equality relation.
1750 data EqRel = NomEq | ReprEq
1751 deriving (Eq, Ord)
1752
1753 instance Outputable EqRel where
1754 ppr NomEq = text "nominal equality"
1755 ppr ReprEq = text "representational equality"
1756
1757 eqRelRole :: EqRel -> Role
1758 eqRelRole NomEq = Nominal
1759 eqRelRole ReprEq = Representational
1760
1761 data PredTree = ClassPred Class [Type]
1762 | EqPred EqRel Type Type
1763 | IrredPred PredType
1764
1765 classifyPredType :: PredType -> PredTree
1766 classifyPredType ev_ty = case splitTyConApp_maybe ev_ty of
1767 Just (tc, [_, _, ty1, ty2])
1768 | tc `hasKey` eqReprPrimTyConKey -> EqPred ReprEq ty1 ty2
1769 | tc `hasKey` eqPrimTyConKey -> EqPred NomEq ty1 ty2
1770 Just (tc, tys)
1771 | Just clas <- tyConClass_maybe tc -> ClassPred clas tys
1772 _ -> IrredPred ev_ty
1773
1774 getClassPredTys :: PredType -> (Class, [Type])
1775 getClassPredTys ty = case getClassPredTys_maybe ty of
1776 Just (clas, tys) -> (clas, tys)
1777 Nothing -> pprPanic "getClassPredTys" (ppr ty)
1778
1779 getClassPredTys_maybe :: PredType -> Maybe (Class, [Type])
1780 getClassPredTys_maybe ty = case splitTyConApp_maybe ty of
1781 Just (tc, tys) | Just clas <- tyConClass_maybe tc -> Just (clas, tys)
1782 _ -> Nothing
1783
1784 getEqPredTys :: PredType -> (Type, Type)
1785 getEqPredTys ty
1786 = case splitTyConApp_maybe ty of
1787 Just (tc, [_, _, ty1, ty2])
1788 | tc `hasKey` eqPrimTyConKey
1789 || tc `hasKey` eqReprPrimTyConKey
1790 -> (ty1, ty2)
1791 _ -> pprPanic "getEqPredTys" (ppr ty)
1792
1793 getEqPredTys_maybe :: PredType -> Maybe (Role, Type, Type)
1794 getEqPredTys_maybe ty
1795 = case splitTyConApp_maybe ty of
1796 Just (tc, [_, _, ty1, ty2])
1797 | tc `hasKey` eqPrimTyConKey -> Just (Nominal, ty1, ty2)
1798 | tc `hasKey` eqReprPrimTyConKey -> Just (Representational, ty1, ty2)
1799 _ -> Nothing
1800
1801 getEqPredRole :: PredType -> Role
1802 getEqPredRole ty = eqRelRole (predTypeEqRel ty)
1803
1804 -- | Get the equality relation relevant for a pred type.
1805 predTypeEqRel :: PredType -> EqRel
1806 predTypeEqRel ty
1807 | Just (tc, _) <- splitTyConApp_maybe ty
1808 , tc `hasKey` eqReprPrimTyConKey
1809 = ReprEq
1810 | otherwise
1811 = NomEq
1812
1813 {-
1814 %************************************************************************
1815 %* *
1816 Well-scoped tyvars
1817 * *
1818 ************************************************************************
1819 -}
1820
1821 -- | Do a topological sort on a list of tyvars,
1822 -- so that binders occur before occurrences
1823 -- E.g. given [ a::k, k::*, b::k ]
1824 -- it'll return a well-scoped list [ k::*, a::k, b::k ]
1825 --
1826 -- This is a deterministic sorting operation
1827 -- (that is, doesn't depend on Uniques).
1828 toposortTyVars :: [TyCoVar] -> [TyCoVar]
1829 toposortTyVars tvs = reverse $
1830 [ node_payload node | node <- topologicalSortG $
1831 graphFromEdgedVerticesOrd nodes ]
1832 where
1833 var_ids :: VarEnv Int
1834 var_ids = mkVarEnv (zip tvs [1..])
1835
1836 nodes :: [ Node Int TyVar ]
1837 nodes = [ DigraphNode
1838 tv
1839 (lookupVarEnv_NF var_ids tv)
1840 (mapMaybe (lookupVarEnv var_ids)
1841 (tyCoVarsOfTypeList (tyVarKind tv)))
1842 | tv <- tvs ]
1843
1844 -- | Extract a well-scoped list of variables from a deterministic set of
1845 -- variables. The result is deterministic.
1846 -- NB: There used to exist varSetElemsWellScoped :: VarSet -> [Var] which
1847 -- took a non-deterministic set and produced a non-deterministic
1848 -- well-scoped list. If you care about the list being well-scoped you also
1849 -- most likely care about it being in deterministic order.
1850 dVarSetElemsWellScoped :: DVarSet -> [Var]
1851 dVarSetElemsWellScoped = toposortTyVars . dVarSetElems
1852
1853 -- | Get the free vars of a type in scoped order
1854 tyCoVarsOfTypeWellScoped :: Type -> [TyVar]
1855 tyCoVarsOfTypeWellScoped = toposortTyVars . tyCoVarsOfTypeList
1856
1857 -- | Get the free vars of types in scoped order
1858 tyCoVarsOfTypesWellScoped :: [Type] -> [TyVar]
1859 tyCoVarsOfTypesWellScoped = toposortTyVars . tyCoVarsOfTypesList
1860
1861 {-
1862 ************************************************************************
1863 * *
1864 \subsection{Type families}
1865 * *
1866 ************************************************************************
1867 -}
1868
1869 mkFamilyTyConApp :: TyCon -> [Type] -> Type
1870 -- ^ Given a family instance TyCon and its arg types, return the
1871 -- corresponding family type. E.g:
1872 --
1873 -- > data family T a
1874 -- > data instance T (Maybe b) = MkT b
1875 --
1876 -- Where the instance tycon is :RTL, so:
1877 --
1878 -- > mkFamilyTyConApp :RTL Int = T (Maybe Int)
1879 mkFamilyTyConApp tc tys
1880 | Just (fam_tc, fam_tys) <- tyConFamInst_maybe tc
1881 , let tvs = tyConTyVars tc
1882 fam_subst = ASSERT2( tvs `equalLength` tys, ppr tc <+> ppr tys )
1883 zipTvSubst tvs tys
1884 = mkTyConApp fam_tc (substTys fam_subst fam_tys)
1885 | otherwise
1886 = mkTyConApp tc tys
1887
1888 -- | Get the type on the LHS of a coercion induced by a type/data
1889 -- family instance.
1890 coAxNthLHS :: CoAxiom br -> Int -> Type
1891 coAxNthLHS ax ind =
1892 mkTyConApp (coAxiomTyCon ax) (coAxBranchLHS (coAxiomNthBranch ax ind))
1893
1894 -- | Pretty prints a 'TyCon', using the family instance in case of a
1895 -- representation tycon. For example:
1896 --
1897 -- > data T [a] = ...
1898 --
1899 -- In that case we want to print @T [a]@, where @T@ is the family 'TyCon'
1900 pprSourceTyCon :: TyCon -> SDoc
1901 pprSourceTyCon tycon
1902 | Just (fam_tc, tys) <- tyConFamInst_maybe tycon
1903 = ppr $ fam_tc `TyConApp` tys -- can't be FunTyCon
1904 | otherwise
1905 = ppr tycon
1906
1907 -- @isTauTy@ tests if a type has no foralls
1908 isFamFreeTy :: Type -> Bool
1909 isFamFreeTy ty | Just ty' <- coreView ty = isFamFreeTy ty'
1910 isFamFreeTy (TyVarTy _) = True
1911 isFamFreeTy (LitTy {}) = True
1912 isFamFreeTy (TyConApp tc tys) = all isFamFreeTy tys && isFamFreeTyCon tc
1913 isFamFreeTy (AppTy a b) = isFamFreeTy a && isFamFreeTy b
1914 isFamFreeTy (FunTy a b) = isFamFreeTy a && isFamFreeTy b
1915 isFamFreeTy (ForAllTy _ ty) = isFamFreeTy ty
1916 isFamFreeTy (CastTy ty _) = isFamFreeTy ty
1917 isFamFreeTy (CoercionTy _) = False -- Not sure about this
1918
1919 {-
1920 ************************************************************************
1921 * *
1922 \subsection{Liftedness}
1923 * *
1924 ************************************************************************
1925 -}
1926
1927 -- | Returns Just True if this type is surely lifted, Just False
1928 -- if it is surely unlifted, Nothing if we can't be sure (i.e., it is
1929 -- levity polymorphic), and panics if the kind does not have the shape
1930 -- TYPE r.
1931 isLiftedType_maybe :: HasDebugCallStack => Type -> Maybe Bool
1932 isLiftedType_maybe ty = go (getRuntimeRep ty)
1933 where
1934 go rr | Just rr' <- coreView rr = go rr'
1935 go (TyConApp lifted_rep [])
1936 | lifted_rep `hasKey` liftedRepDataConKey = Just True
1937 go (TyConApp {}) = Just False -- everything else is unlifted
1938 go _ = Nothing -- levity polymorphic
1939
1940 -- | See "Type#type_classification" for what an unlifted type is.
1941 -- Panics on levity polymorphic types.
1942 isUnliftedType :: HasDebugCallStack => Type -> Bool
1943 -- isUnliftedType returns True for forall'd unlifted types:
1944 -- x :: forall a. Int#
1945 -- I found bindings like these were getting floated to the top level.
1946 -- They are pretty bogus types, mind you. It would be better never to
1947 -- construct them
1948 isUnliftedType ty
1949 = not (isLiftedType_maybe ty `orElse`
1950 pprPanic "isUnliftedType" (ppr ty <+> dcolon <+> ppr (typeKind ty)))
1951
1952 -- | Is this a type of kind RuntimeRep? (e.g. LiftedRep)
1953 isRuntimeRepKindedTy :: Type -> Bool
1954 isRuntimeRepKindedTy = isRuntimeRepTy . typeKind
1955
1956 -- | Drops prefix of RuntimeRep constructors in 'TyConApp's. Useful for e.g.
1957 -- dropping 'LiftedRep arguments of unboxed tuple TyCon applications:
1958 --
1959 -- dropRuntimeRepArgs [ 'LiftedRep, 'IntRep
1960 -- , String, Int# ] == [String, Int#]
1961 --
1962 dropRuntimeRepArgs :: [Type] -> [Type]
1963 dropRuntimeRepArgs = dropWhile isRuntimeRepKindedTy
1964
1965 -- | Extract the RuntimeRep classifier of a type. For instance,
1966 -- @getRuntimeRep_maybe Int = LiftedRep@. Returns 'Nothing' if this is not
1967 -- possible.
1968 getRuntimeRep_maybe :: HasDebugCallStack
1969 => Type -> Maybe Type
1970 getRuntimeRep_maybe = getRuntimeRepFromKind_maybe . typeKind
1971
1972 -- | Extract the RuntimeRep classifier of a type. For instance,
1973 -- @getRuntimeRep_maybe Int = LiftedRep@. Panics if this is not possible.
1974 getRuntimeRep :: HasDebugCallStack => Type -> Type
1975 getRuntimeRep ty
1976 = case getRuntimeRep_maybe ty of
1977 Just r -> r
1978 Nothing -> pprPanic "getRuntimeRep" (ppr ty <+> dcolon <+> ppr (typeKind ty))
1979
1980 -- | Extract the RuntimeRep classifier of a type from its kind. For example,
1981 -- @getRuntimeRepFromKind * = LiftedRep@; Panics if this is not possible.
1982 getRuntimeRepFromKind :: HasDebugCallStack
1983 => Type -> Type
1984 getRuntimeRepFromKind k =
1985 case getRuntimeRepFromKind_maybe k of
1986 Just r -> r
1987 Nothing -> pprPanic "getRuntimeRepFromKind"
1988 (ppr k <+> dcolon <+> ppr (typeKind k))
1989
1990 -- | Extract the RuntimeRep classifier of a type from its kind. For example,
1991 -- @getRuntimeRepFromKind * = LiftedRep@; Returns 'Nothing' if this is not
1992 -- possible.
1993 getRuntimeRepFromKind_maybe :: HasDebugCallStack
1994 => Type -> Maybe Type
1995 getRuntimeRepFromKind_maybe = go
1996 where
1997 go k | Just k' <- coreView k = go k'
1998 go k
1999 | Just (_tc, [arg]) <- splitTyConApp_maybe k
2000 = ASSERT2( _tc `hasKey` tYPETyConKey, ppr k )
2001 Just arg
2002 go _ = Nothing
2003
2004 isUnboxedTupleType :: Type -> Bool
2005 isUnboxedTupleType ty
2006 = tyConAppTyCon (getRuntimeRep ty) `hasKey` tupleRepDataConKey
2007 -- NB: Do not use typePrimRep, as that can't tell the difference between
2008 -- unboxed tuples and unboxed sums
2009
2010
2011 isUnboxedSumType :: Type -> Bool
2012 isUnboxedSumType ty
2013 = tyConAppTyCon (getRuntimeRep ty) `hasKey` sumRepDataConKey
2014
2015 -- | See "Type#type_classification" for what an algebraic type is.
2016 -- Should only be applied to /types/, as opposed to e.g. partially
2017 -- saturated type constructors
2018 isAlgType :: Type -> Bool
2019 isAlgType ty
2020 = case splitTyConApp_maybe ty of
2021 Just (tc, ty_args) -> ASSERT( ty_args `lengthIs` tyConArity tc )
2022 isAlgTyCon tc
2023 _other -> False
2024
2025 -- | Check whether a type is a data family type
2026 isDataFamilyAppType :: Type -> Bool
2027 isDataFamilyAppType ty = case tyConAppTyCon_maybe ty of
2028 Just tc -> isDataFamilyTyCon tc
2029 _ -> False
2030
2031 -- | Computes whether an argument (or let right hand side) should
2032 -- be computed strictly or lazily, based only on its type.
2033 -- Currently, it's just 'isUnliftedType'. Panics on levity-polymorphic types.
2034 isStrictType :: HasDebugCallStack => Type -> Bool
2035 isStrictType = isUnliftedType
2036
2037 isPrimitiveType :: Type -> Bool
2038 -- ^ Returns true of types that are opaque to Haskell.
2039 isPrimitiveType ty = case splitTyConApp_maybe ty of
2040 Just (tc, ty_args) -> ASSERT( ty_args `lengthIs` tyConArity tc )
2041 isPrimTyCon tc
2042 _ -> False
2043
2044 {-
2045 ************************************************************************
2046 * *
2047 \subsection{Join points}
2048 * *
2049 ************************************************************************
2050 -}
2051
2052 -- | Determine whether a type could be the type of a join point of given total
2053 -- arity, according to the polymorphism rule. A join point cannot be polymorphic
2054 -- in its return type, since given
2055 -- join j @a @b x y z = e1 in e2,
2056 -- the types of e1 and e2 must be the same, and a and b are not in scope for e2.
2057 -- (See Note [The polymorphism rule of join points] in CoreSyn.) Returns False
2058 -- also if the type simply doesn't have enough arguments.
2059 --
2060 -- Note that we need to know how many arguments (type *and* value) the putative
2061 -- join point takes; for instance, if
2062 -- j :: forall a. a -> Int
2063 -- then j could be a binary join point returning an Int, but it could *not* be a
2064 -- unary join point returning a -> Int.
2065 --
2066 -- TODO: See Note [Excess polymorphism and join points]
2067 isValidJoinPointType :: JoinArity -> Type -> Bool
2068 isValidJoinPointType arity ty
2069 = valid_under emptyVarSet arity ty
2070 where
2071 valid_under tvs arity ty
2072 | arity == 0
2073 = isEmptyVarSet (tvs `intersectVarSet` tyCoVarsOfType ty)
2074 | Just (t, ty') <- splitForAllTy_maybe ty
2075 = valid_under (tvs `extendVarSet` t) (arity-1) ty'
2076 | Just (_, res_ty) <- splitFunTy_maybe ty
2077 = valid_under tvs (arity-1) res_ty
2078 | otherwise
2079 = False
2080
2081 {-
2082 ************************************************************************
2083 * *
2084 \subsection{Sequencing on types}
2085 * *
2086 ************************************************************************
2087 -}
2088
2089 seqType :: Type -> ()
2090 seqType (LitTy n) = n `seq` ()
2091 seqType (TyVarTy tv) = tv `seq` ()
2092 seqType (AppTy t1 t2) = seqType t1 `seq` seqType t2
2093 seqType (FunTy t1 t2) = seqType t1 `seq` seqType t2
2094 seqType (TyConApp tc tys) = tc `seq` seqTypes tys
2095 seqType (ForAllTy (TvBndr tv _) ty) = seqType (tyVarKind tv) `seq` seqType ty
2096 seqType (CastTy ty co) = seqType ty `seq` seqCo co
2097 seqType (CoercionTy co) = seqCo co
2098
2099 seqTypes :: [Type] -> ()
2100 seqTypes [] = ()
2101 seqTypes (ty:tys) = seqType ty `seq` seqTypes tys
2102
2103 {-
2104 ************************************************************************
2105 * *
2106 Comparison for types
2107 (We don't use instances so that we know where it happens)
2108 * *
2109 ************************************************************************
2110
2111 Note [Equality on AppTys]
2112 ~~~~~~~~~~~~~~~~~~~~~~~~~
2113 In our cast-ignoring equality, we want to say that the following two
2114 are equal:
2115
2116 (Maybe |> co) (Int |> co') ~? Maybe Int
2117
2118 But the left is an AppTy while the right is a TyConApp. The solution is
2119 to use repSplitAppTy_maybe to break up the TyConApp into its pieces and
2120 then continue. Easy to do, but also easy to forget to do.
2121
2122 -}
2123
2124 eqType :: Type -> Type -> Bool
2125 -- ^ Type equality on source types. Does not look through @newtypes@ or
2126 -- 'PredType's, but it does look through type synonyms.
2127 -- This first checks that the kinds of the types are equal and then
2128 -- checks whether the types are equal, ignoring casts and coercions.
2129 -- (The kind check is a recursive call, but since all kinds have type
2130 -- @Type@, there is no need to check the types of kinds.)
2131 -- See also Note [Non-trivial definitional equality] in TyCoRep.
2132 eqType t1 t2 = isEqual $ nonDetCmpType t1 t2
2133 -- It's OK to use nonDetCmpType here and eqType is deterministic,
2134 -- nonDetCmpType does equality deterministically
2135
2136 -- | Compare types with respect to a (presumably) non-empty 'RnEnv2'.
2137 eqTypeX :: RnEnv2 -> Type -> Type -> Bool
2138 eqTypeX env t1 t2 = isEqual $ nonDetCmpTypeX env t1 t2
2139 -- It's OK to use nonDetCmpType here and eqTypeX is deterministic,
2140 -- nonDetCmpTypeX does equality deterministically
2141
2142 -- | Type equality on lists of types, looking through type synonyms
2143 -- but not newtypes.
2144 eqTypes :: [Type] -> [Type] -> Bool
2145 eqTypes tys1 tys2 = isEqual $ nonDetCmpTypes tys1 tys2
2146 -- It's OK to use nonDetCmpType here and eqTypes is deterministic,
2147 -- nonDetCmpTypes does equality deterministically
2148
2149 eqVarBndrs :: RnEnv2 -> [Var] -> [Var] -> Maybe RnEnv2
2150 -- Check that the var lists are the same length
2151 -- and have matching kinds; if so, extend the RnEnv2
2152 -- Returns Nothing if they don't match
2153 eqVarBndrs env [] []
2154 = Just env
2155 eqVarBndrs env (tv1:tvs1) (tv2:tvs2)
2156 | eqTypeX env (tyVarKind tv1) (tyVarKind tv2)
2157 = eqVarBndrs (rnBndr2 env tv1 tv2) tvs1 tvs2
2158 eqVarBndrs _ _ _= Nothing
2159
2160 -- Now here comes the real worker
2161
2162 {-
2163 Note [nonDetCmpType nondeterminism]
2164 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2165 nonDetCmpType is implemented in terms of nonDetCmpTypeX. nonDetCmpTypeX
2166 uses nonDetCmpTc which compares TyCons by their Unique value. Using Uniques for
2167 ordering leads to nondeterminism. We hit the same problem in the TyVarTy case,
2168 comparing type variables is nondeterministic, note the call to nonDetCmpVar in
2169 nonDetCmpTypeX.
2170 See Note [Unique Determinism] for more details.
2171 -}
2172
2173 nonDetCmpType :: Type -> Type -> Ordering
2174 nonDetCmpType t1 t2
2175 -- we know k1 and k2 have the same kind, because they both have kind *.
2176 = nonDetCmpTypeX rn_env t1 t2
2177 where
2178 rn_env = mkRnEnv2 (mkInScopeSet (tyCoVarsOfTypes [t1, t2]))
2179
2180 nonDetCmpTypes :: [Type] -> [Type] -> Ordering
2181 nonDetCmpTypes ts1 ts2 = nonDetCmpTypesX rn_env ts1 ts2
2182 where
2183 rn_env = mkRnEnv2 (mkInScopeSet (tyCoVarsOfTypes (ts1 ++ ts2)))
2184
2185 -- | An ordering relation between two 'Type's (known below as @t1 :: k1@
2186 -- and @t2 :: k2@)
2187 data TypeOrdering = TLT -- ^ @t1 < t2@
2188 | TEQ -- ^ @t1 ~ t2@ and there are no casts in either,
2189 -- therefore we can conclude @k1 ~ k2@
2190 | TEQX -- ^ @t1 ~ t2@ yet one of the types contains a cast so
2191 -- they may differ in kind.
2192 | TGT -- ^ @t1 > t2@
2193 deriving (Eq, Ord, Enum, Bounded)
2194
2195 nonDetCmpTypeX :: RnEnv2 -> Type -> Type -> Ordering -- Main workhorse
2196 -- See Note [Non-trivial definitional equality] in TyCoRep
2197 nonDetCmpTypeX env orig_t1 orig_t2 =
2198 case go env orig_t1 orig_t2 of
2199 -- If there are casts then we also need to do a comparison of the kinds of
2200 -- the types being compared
2201 TEQX -> toOrdering $ go env k1 k2
2202 ty_ordering -> toOrdering ty_ordering
2203 where
2204 k1 = typeKind orig_t1
2205 k2 = typeKind orig_t2
2206
2207 toOrdering :: TypeOrdering -> Ordering
2208 toOrdering TLT = LT
2209 toOrdering TEQ = EQ
2210 toOrdering TEQX = EQ
2211 toOrdering TGT = GT
2212
2213 liftOrdering :: Ordering -> TypeOrdering
2214 liftOrdering LT = TLT
2215 liftOrdering EQ = TEQ
2216 liftOrdering GT = TGT
2217
2218 thenCmpTy :: TypeOrdering -> TypeOrdering -> TypeOrdering
2219 thenCmpTy TEQ rel = rel
2220 thenCmpTy TEQX rel = hasCast rel
2221 thenCmpTy rel _ = rel
2222
2223 hasCast :: TypeOrdering -> TypeOrdering
2224 hasCast TEQ = TEQX
2225 hasCast rel = rel
2226
2227 -- Returns both the resulting ordering relation between the two types
2228 -- and whether either contains a cast.
2229 go :: RnEnv2 -> Type -> Type -> TypeOrdering
2230 go env t1 t2
2231 | Just t1' <- coreView t1 = go env t1' t2
2232 | Just t2' <- coreView t2 = go env t1 t2'
2233
2234 go env (TyVarTy tv1) (TyVarTy tv2)
2235 = liftOrdering $ rnOccL env tv1 `nonDetCmpVar` rnOccR env tv2
2236 go env (ForAllTy (TvBndr tv1 _) t1) (ForAllTy (TvBndr tv2 _) t2)
2237 = go env (tyVarKind tv1) (tyVarKind tv2)
2238 `thenCmpTy` go (rnBndr2 env tv1 tv2) t1 t2
2239 -- See Note [Equality on AppTys]
2240 go env (AppTy s1 t1) ty2
2241 | Just (s2, t2) <- repSplitAppTy_maybe ty2
2242 = go env s1 s2 `thenCmpTy` go env t1 t2
2243 go env ty1 (AppTy s2 t2)
2244 | Just (s1, t1) <- repSplitAppTy_maybe ty1
2245 = go env s1 s2 `thenCmpTy` go env t1 t2
2246 go env (FunTy s1 t1) (FunTy s2 t2)
2247 = go env s1 s2 `thenCmpTy` go env t1 t2
2248 go env (TyConApp tc1 tys1) (TyConApp tc2 tys2)
2249 = liftOrdering (tc1 `nonDetCmpTc` tc2) `thenCmpTy` gos env tys1 tys2
2250 go _ (LitTy l1) (LitTy l2) = liftOrdering (compare l1 l2)
2251 go env (CastTy t1 _) t2 = hasCast $ go env t1 t2
2252 go env t1 (CastTy t2 _) = hasCast $ go env t1 t2
2253
2254 go _ (CoercionTy {}) (CoercionTy {}) = TEQ
2255
2256 -- Deal with the rest: TyVarTy < CoercionTy < AppTy < LitTy < TyConApp < ForAllTy
2257 go _ ty1 ty2
2258 = liftOrdering $ (get_rank ty1) `compare` (get_rank ty2)
2259 where get_rank :: Type -> Int
2260 get_rank (CastTy {})
2261 = pprPanic "nonDetCmpTypeX.get_rank" (ppr [ty1,ty2])
2262 get_rank (TyVarTy {}) = 0
2263 get_rank (CoercionTy {}) = 1
2264 get_rank (AppTy {}) = 3
2265 get_rank (LitTy {}) = 4
2266 get_rank (TyConApp {}) = 5
2267 get_rank (FunTy {}) = 6
2268 get_rank (ForAllTy {}) = 7
2269
2270 gos :: RnEnv2 -> [Type] -> [Type] -> TypeOrdering
2271 gos _ [] [] = TEQ
2272 gos _ [] _ = TLT
2273 gos _ _ [] = TGT
2274 gos env (ty1:tys1) (ty2:tys2) = go env ty1 ty2 `thenCmpTy` gos env tys1 tys2
2275
2276 -------------
2277 nonDetCmpTypesX :: RnEnv2 -> [Type] -> [Type] -> Ordering
2278 nonDetCmpTypesX _ [] [] = EQ
2279 nonDetCmpTypesX env (t1:tys1) (t2:tys2) = nonDetCmpTypeX env t1 t2
2280 `thenCmp` nonDetCmpTypesX env tys1 tys2
2281 nonDetCmpTypesX _ [] _ = LT
2282 nonDetCmpTypesX _ _ [] = GT
2283
2284 -------------
2285 -- | Compare two 'TyCon's. NB: This should /never/ see the "star synonyms",
2286 -- as recognized by Kind.isStarKindSynonymTyCon. See Note
2287 -- [Kind Constraint and kind *] in Kind.
2288 -- See Note [nonDetCmpType nondeterminism]
2289 nonDetCmpTc :: TyCon -> TyCon -> Ordering
2290 nonDetCmpTc tc1 tc2
2291 = ASSERT( not (isStarKindSynonymTyCon tc1) && not (isStarKindSynonymTyCon tc2) )
2292 u1 `nonDetCmpUnique` u2
2293 where
2294 u1 = tyConUnique tc1
2295 u2 = tyConUnique tc2
2296
2297 {-
2298 ************************************************************************
2299 * *
2300 The kind of a type
2301 * *
2302 ************************************************************************
2303 -}
2304
2305 typeKind :: HasDebugCallStack => Type -> Kind
2306 typeKind (TyConApp tc tys) = piResultTys (tyConKind tc) tys
2307 typeKind (AppTy fun arg) = piResultTy (typeKind fun) arg
2308 typeKind (LitTy l) = typeLiteralKind l
2309 typeKind (FunTy {}) = liftedTypeKind
2310 typeKind (ForAllTy _ ty) = typeKind ty
2311 typeKind (TyVarTy tyvar) = tyVarKind tyvar
2312 typeKind (CastTy _ty co) = pSnd $ coercionKind co
2313 typeKind (CoercionTy co) = coercionType co
2314
2315 typeLiteralKind :: TyLit -> Kind
2316 typeLiteralKind l =
2317 case l of
2318 NumTyLit _ -> typeNatKind
2319 StrTyLit _ -> typeSymbolKind
2320
2321 -- | Returns True if a type is levity polymorphic. Should be the same
2322 -- as (isKindLevPoly . typeKind) but much faster.
2323 -- Precondition: The type has kind (TYPE blah)
2324 isTypeLevPoly :: Type -> Bool
2325 isTypeLevPoly = go
2326 where
2327 go ty@(TyVarTy {}) = check_kind ty
2328 go ty@(AppTy {}) = check_kind ty
2329 go ty@(TyConApp tc _) | not (isTcLevPoly tc) = False
2330 | otherwise = check_kind ty
2331 go (ForAllTy _ ty) = go ty
2332 go (FunTy {}) = False
2333 go (LitTy {}) = False
2334 go ty@(CastTy {}) = check_kind ty
2335 go ty@(CoercionTy {}) = pprPanic "isTypeLevPoly co" (ppr ty)
2336
2337 check_kind = isKindLevPoly . typeKind
2338
2339 -- | Looking past all pi-types, is the end result potentially levity polymorphic?
2340 -- Example: True for (forall r (a :: TYPE r). String -> a)
2341 -- Example: False for (forall r1 r2 (a :: TYPE r1) (b :: TYPE r2). a -> b -> Type)
2342 resultIsLevPoly :: Type -> Bool
2343 resultIsLevPoly = isTypeLevPoly . snd . splitPiTys
2344
2345 {-
2346 %************************************************************************
2347 %* *
2348 Miscellaneous functions
2349 %* *
2350 %************************************************************************
2351
2352 -}
2353 -- | All type constructors occurring in the type; looking through type
2354 -- synonyms, but not newtypes.
2355 -- When it finds a Class, it returns the class TyCon.
2356 tyConsOfType :: Type -> UniqSet TyCon
2357 tyConsOfType ty
2358 = go ty
2359 where
2360 go :: Type -> UniqSet TyCon -- The UniqSet does duplicate elim
2361 go ty | Just ty' <- coreView ty = go ty'
2362 go (TyVarTy {}) = emptyUniqSet
2363 go (LitTy {}) = emptyUniqSet
2364 go (TyConApp tc tys) = go_tc tc `unionUniqSets` go_s tys
2365 go (AppTy a b) = go a `unionUniqSets` go b
2366 go (FunTy a b) = go a `unionUniqSets` go b `unionUniqSets` go_tc funTyCon
2367 go (ForAllTy (TvBndr tv _) ty) = go ty `unionUniqSets` go (tyVarKind tv)
2368 go (CastTy ty co) = go ty `unionUniqSets` go_co co
2369 go (CoercionTy co) = go_co co
2370
2371 go_co (Refl _ ty) = go ty
2372 go_co (TyConAppCo _ tc args) = go_tc tc `unionUniqSets` go_cos args
2373 go_co (AppCo co arg) = go_co co `unionUniqSets` go_co arg
2374 go_co (ForAllCo _ kind_co co) = go_co kind_co `unionUniqSets` go_co co
2375 go_co (FunCo _ co1 co2) = go_co co1 `unionUniqSets` go_co co2
2376 go_co (AxiomInstCo ax _ args) = go_ax ax `unionUniqSets` go_cos args
2377 go_co (UnivCo p _ t1 t2) = go_prov p `unionUniqSets` go t1 `unionUniqSets` go t2
2378 go_co (CoVarCo {}) = emptyUniqSet
2379 go_co (SymCo co) = go_co co
2380 go_co (TransCo co1 co2) = go_co co1 `unionUniqSets` go_co co2
2381 go_co (NthCo _ co) = go_co co
2382 go_co (LRCo _ co) = go_co co
2383 go_co (InstCo co arg) = go_co co `unionUniqSets` go_co arg
2384 go_co (CoherenceCo co1 co2) = go_co co1 `unionUniqSets` go_co co2
2385 go_co (KindCo co) = go_co co
2386 go_co (SubCo co) = go_co co
2387 go_co (AxiomRuleCo _ cs) = go_cos cs
2388
2389 go_prov UnsafeCoerceProv = emptyUniqSet
2390 go_prov (PhantomProv co) = go_co co
2391 go_prov (ProofIrrelProv co) = go_co co
2392 go_prov (PluginProv _) = emptyUniqSet
2393 go_prov (HoleProv _) = emptyUniqSet
2394 -- this last case can happen from the tyConsOfType used from
2395 -- checkTauTvUpdate
2396
2397 go_s tys = foldr (unionUniqSets . go) emptyUniqSet tys
2398 go_cos cos = foldr (unionUniqSets . go_co) emptyUniqSet cos
2399
2400 go_tc tc = unitUniqSet tc
2401 go_ax ax = go_tc $ coAxiomTyCon ax
2402
2403 -- | Find the result 'Kind' of a type synonym,
2404 -- after applying it to its 'arity' number of type variables
2405 -- Actually this function works fine on data types too,
2406 -- but they'd always return '*', so we never need to ask
2407 synTyConResKind :: TyCon -> Kind
2408 synTyConResKind tycon = piResultTys (tyConKind tycon) (mkTyVarTys (tyConTyVars tycon))
2409
2410 -- | Retrieve the free variables in this type, splitting them based
2411 -- on whether they are used visibly or invisibly. Invisible ones come
2412 -- first.
2413 splitVisVarsOfType :: Type -> Pair TyCoVarSet
2414 splitVisVarsOfType orig_ty = Pair invis_vars vis_vars
2415 where
2416 Pair invis_vars1 vis_vars = go orig_ty
2417 invis_vars = invis_vars1 `minusVarSet` vis_vars
2418
2419 go (TyVarTy tv) = Pair (tyCoVarsOfType $ tyVarKind tv) (unitVarSet tv)
2420 go (AppTy t1 t2) = go t1 `mappend` go t2
2421 go (TyConApp tc tys) = go_tc tc tys
2422 go (FunTy t1 t2) = go t1 `mappend` go t2
2423 go (ForAllTy (TvBndr tv _) ty)
2424 = ((`delVarSet` tv) <$> go ty) `mappend`
2425 (invisible (tyCoVarsOfType $ tyVarKind tv))
2426 go (LitTy {}) = mempty
2427 go (CastTy ty co) = go ty `mappend` invisible (tyCoVarsOfCo co)
2428 go (CoercionTy co) = invisible $ tyCoVarsOfCo co
2429
2430 invisible vs = Pair vs emptyVarSet
2431
2432 go_tc tc tys = let (invis, vis) = partitionInvisibles tc id tys in
2433 invisible (tyCoVarsOfTypes invis) `mappend` foldMap go vis
2434
2435 splitVisVarsOfTypes :: [Type] -> Pair TyCoVarSet
2436 splitVisVarsOfTypes = foldMap splitVisVarsOfType
2437
2438 modifyJoinResTy :: Int -- Number of binders to skip
2439 -> (Type -> Type) -- Function to apply to result type
2440 -> Type -- Type of join point
2441 -> Type -- New type
2442 -- INVARIANT: If any of the first n binders are foralls, those tyvars cannot
2443 -- appear in the original result type. See isValidJoinPointType.
2444 modifyJoinResTy orig_ar f orig_ty
2445 = go orig_ar orig_ty
2446 where
2447 go 0 ty = f ty
2448 go n ty | Just (arg_bndr, res_ty) <- splitPiTy_maybe ty
2449 = mkPiTy arg_bndr (go (n-1) res_ty)
2450 | otherwise
2451 = pprPanic "modifyJoinResTy" (ppr orig_ar <+> ppr orig_ty)
2452
2453 setJoinResTy :: Int -- Number of binders to skip
2454 -> Type -- New result type
2455 -> Type -- Type of join point
2456 -> Type -- New type
2457 -- INVARIANT: Same as for modifyJoinResTy
2458 setJoinResTy ar new_res_ty ty
2459 = modifyJoinResTy ar (const new_res_ty) ty