Tighten Safe Haskell bounds, fixes new warning in GHC 7.10.
[packages/unix.git] / configure.ac
1 AC_INIT([Haskell unix package], [2.0], [libraries@haskell.org], [unix])
2
3 # Safety check: Ensure that we are in the correct source directory.
4 AC_CONFIG_SRCDIR([include/HsUnix.h])
5
6 AC_ARG_WITH([cc],
7             [C compiler],
8             [CC=$withval])
9 AC_PROG_CC()
10
11 AC_CONFIG_HEADERS([include/HsUnixConfig.h])
12
13 # Is this a Unix system?
14 AC_CHECK_HEADER([dlfcn.h], [BUILD_PACKAGE_BOOL=True], [BUILD_PACKAGE_BOOL=False])
15 AC_SUBST([BUILD_PACKAGE_BOOL])
16
17 AC_C_CONST
18
19 dnl ** Enable large file support.  NB. do this before testing the type of
20 dnl    off_t, because it will affect the result of that test.
21 dnl
22 dnl WARNING: It's essential this check agrees with HsBaseConfig.h as otherwise
23 dnl          the definitions of COff/coff_t don't line up
24 AC_SYS_LARGEFILE
25
26 AC_CHECK_HEADERS([dirent.h fcntl.h grp.h limits.h pwd.h signal.h string.h])
27 AC_CHECK_HEADERS([sys/resource.h sys/stat.h sys/times.h sys/time.h])
28 AC_CHECK_HEADERS([sys/utsname.h sys/wait.h])
29 AC_CHECK_HEADERS([bsd/libutil.h libutil.h pty.h utmp.h])
30 AC_CHECK_HEADERS([termios.h time.h unistd.h utime.h])
31
32 AC_CHECK_FUNCS([getgrgid_r getgrnam_r getpwnam_r getpwuid_r getpwnam getpwuid])
33 AC_CHECK_FUNCS([getpwent getgrent])
34 AC_CHECK_FUNCS([lchown setenv sysconf unsetenv clearenv])
35 AC_CHECK_FUNCS([nanosleep])
36 AC_CHECK_FUNCS([ptsname])
37 AC_CHECK_FUNCS([setitimer])
38 AC_CHECK_FUNCS([readdir_r])
39 dnl not available on android so check for it
40 AC_CHECK_FUNCS([telldir seekdir])
41
42 AC_CHECK_MEMBERS([struct stat.st_atim])
43 AC_CHECK_MEMBERS([struct stat.st_mtim])
44 AC_CHECK_MEMBERS([struct stat.st_ctim])
45 AC_CHECK_MEMBERS([struct stat.st_atimespec])
46 AC_CHECK_MEMBERS([struct stat.st_mtimespec])
47 AC_CHECK_MEMBERS([struct stat.st_ctimespec])
48 AC_CHECK_MEMBERS([struct stat.st_atimensec])
49 AC_CHECK_MEMBERS([struct stat.st_mtimensec])
50 AC_CHECK_MEMBERS([struct stat.st_ctimensec])
51 AC_CHECK_MEMBERS([struct stat.st_atime_n])
52 AC_CHECK_MEMBERS([struct stat.st_mtime_n])
53 AC_CHECK_MEMBERS([struct stat.st_ctime_n])
54 AC_CHECK_MEMBERS([struct stat.st_uatime])
55 AC_CHECK_MEMBERS([struct stat.st_umtime])
56 AC_CHECK_MEMBERS([struct stat.st_uctime])
57
58 AC_CHECK_MEMBER([struct passwd.pw_gecos], [], [AC_DEFINE([HAVE_NO_PASSWD_PW_GECOS],[],[Ignore the pw_gecos member of passwd where it does not exist])], [[#include <pwd.h>]])
59
60 # Functions for changing file timestamps
61 AC_CHECK_FUNCS([utimensat futimens])
62 AC_CHECK_FUNCS([lutimes futimes])
63
64 # Additional temp functions
65 AC_CHECK_FUNCS([mkstemps mkdtemp])
66
67 # Avoid adding rt if absent or unneeded
68 # shm_open needs -lrt on linux
69 AC_SEARCH_LIBS(shm_open, rt, [AC_CHECK_FUNCS([shm_open shm_unlink])])
70 AS_IF([test "x$ac_cv_search_shm_open" = x-lrt], [EXTRA_LIBS="$EXTRA_LIBS rt"])
71
72 FP_CHECK_CONSTS([SIGABRT SIGALRM SIGBUS SIGCHLD SIGCONT SIGFPE SIGHUP SIGILL SIGINT SIGKILL SIGPIPE SIGQUIT SIGSEGV SIGSTOP SIGTERM SIGTSTP SIGTTIN SIGTTOU SIGUSR1 SIGUSR2 SIGPOLL SIGPROF SIGSYS SIGTRAP SIGURG SIGVTALRM SIGXCPU SIGXFSZ SIG_BLOCK SIG_SETMASK SIG_UNBLOCK], [
73 #if HAVE_SIGNAL_H
74 #include <signal.h>
75 #endif])
76
77 AC_MSG_CHECKING([for _SC_GETGR_R_SIZE_MAX])
78 AC_EGREP_CPP(we_have_that_sysconf_thing,
79 [
80 #include <unistd.h>
81 #ifdef _SC_GETGR_R_SIZE_MAX
82 we_have_that_sysconf_thing
83 #endif
84 ],
85 [AC_MSG_RESULT([yes])
86 AC_DEFINE([HAVE_SC_GETGR_R_SIZE_MAX], [1], [Define to 1 if <unistd.h> defines _SC_GETGR_R_SIZE_MAX.])],
87 [AC_MSG_RESULT([no])])
88
89 AC_MSG_CHECKING([for _SC_GETPW_R_SIZE_MAX])
90 AC_EGREP_CPP(we_have_that_sysconf_thing,
91 [
92 #include <unistd.h>
93 #ifdef _SC_GETPW_R_SIZE_MAX
94 we_have_that_sysconf_thing
95 #endif
96 ],
97 [AC_MSG_RESULT([yes])
98 AC_DEFINE([HAVE_SC_GETPW_R_SIZE_MAX], [1], [Define to 1 if <unistd.h> defines _SC_GETPW_R_SIZE_MAX.])],
99 [AC_MSG_RESULT([no])])
100
101 dnl ---------- usleep ----------
102 dnl --- stolen from guile configure ---
103
104 ### On some systems usleep has no return value.  If it does have one,
105 ### we'd like to return it; otherwise, we'll fake it.
106 AC_CACHE_CHECK([return type of usleep], fptools_cv_func_usleep_return_type,
107   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
108                    unistd.h,
109                    [fptools_cv_func_usleep_return_type=void],
110                    [fptools_cv_func_usleep_return_type=int])])
111 case "$fptools_cv_func_usleep_return_type" in
112   "void" )
113     AC_DEFINE([USLEEP_RETURNS_VOID], [1], [Define if the system headers declare usleep to return void.])
114   ;;
115 esac
116
117 ###  POSIX.1003.1 unsetenv returns 0 or -1 (EINVAL), but older implementations
118 ###  in common use return void.
119 AC_CACHE_CHECK([return type of unsetenv], fptools_cv_func_unsetenv_return_type,
120   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+unsetenv>changequote([, ]),
121                    stdlib.h,
122                    [fptools_cv_func_unsetenv_return_type=void],
123                    [fptools_cv_func_unsetenv_return_type=int])])
124 case "$fptools_cv_func_unsetenv_return_type" in
125   "void" )
126     AC_DEFINE([UNSETENV_RETURNS_VOID], [1], [Define if stdlib.h declares unsetenv to return void.])
127   ;;
128 esac
129
130 dnl On some hosts (e.g. SuSe and Ubuntu Linux) RTLD_NEXT and RTLD_DEFAULT are
131 dnl not visible without setting _GNU_SOURCE, which we really don't want to.
132 dnl Also see comments in System/Posix/DynamicLinker/Prim.hsc.
133 AC_MSG_CHECKING(for RTLD_NEXT from dlfcn.h)
134 AC_EGREP_CPP(yes,
135 [
136  #include <dlfcn.h>
137  #ifdef RTLD_NEXT
138         yes
139  #endif
140 ], [
141   AC_MSG_RESULT(yes)
142   AC_DEFINE([HAVE_RTLDNEXT], [1], [Define to 1 if we can see RTLD_NEXT in dlfcn.h.])
143 ], [
144   AC_MSG_RESULT(no)
145   ])    
146
147 AC_MSG_CHECKING(for RTLD_DEFAULT from dlfcn.h)
148 AC_EGREP_CPP(yes,
149 [
150  #include <dlfcn.h>
151  #ifdef RTLD_DEFAULT
152         yes
153  #endif
154 ], [
155   AC_MSG_RESULT(yes)
156   AC_DEFINE([HAVE_RTLDDEFAULT], [1], [Define to 1 if RTLD_DEFAULT is available.])
157 ], [
158   AC_MSG_RESULT(no)
159   ])    
160
161 AC_CHECK_FUNCS(openpty,,
162    AC_CHECK_LIB(util,openpty,
163      [AC_DEFINE(HAVE_OPENPTY) EXTRA_LIBS="$EXTRA_LIBS util"],
164      AC_CHECK_LIB(bsd,openpty, [AC_DEFINE(HAVE_OPENPTY) EXTRA_LIBS="$EXTRA_LIBS bsd"])
165    )
166 )
167
168 AC_MSG_CHECKING(for /dev/ptmx)
169 if test -r /dev/ptmx
170 then
171   AC_MSG_RESULT(yes)
172   AC_DEFINE(HAVE_DEV_PTMX, 1,
173   [Define if we have /dev/ptmx.])
174 else
175   AC_MSG_RESULT(no)
176 fi
177
178 AC_MSG_CHECKING(for /dev/ptc)
179 if test -r /dev/ptc
180 then
181   AC_MSG_RESULT(yes)
182   AC_DEFINE(HAVE_DEV_PTC, 1,
183   [Define if we have /dev/ptc.])
184 else
185   AC_MSG_RESULT(no)
186 fi
187
188 # Avoid adding dl if absent or unneeded
189 AC_CHECK_LIB(dl, dlopen, [EXTRA_LIBS="$EXTRA_LIBS dl"])
190
191 # -{l,}pthread goo
192 AC_CANONICAL_TARGET
193
194 AC_SEARCH_LIBS(sem_close, pthread,
195     [EXTRA_LIBS="$EXTRA_LIBS $ac_lib"],
196     [AC_MSG_NOTICE([Not found])])
197
198 AC_SUBST([EXTRA_LIBS])
199 AC_CONFIG_FILES([unix.buildinfo])
200
201 AC_OUTPUT