8a5b55f1b333cb1b679aeff1a0b85b6717d1276a
[packages/random.git] / Data / Ratio.hs
1 -----------------------------------------------------------------------------
2 -- |
3 -- Module : Data.Ratio
4 -- Copyright : (c) The University of Glasgow 2001
5 -- License : BSD-style (see the file libraries/base/LICENSE)
6 --
7 -- Maintainer : libraries@haskell.org
8 -- Stability : provisional
9 -- Portability : portable
10 --
11 -- Standard functions on rational numbers
12 --
13 -----------------------------------------------------------------------------
14
15 module Data.Ratio
16 ( Ratio
17 , Rational
18 , (%) -- :: (Integral a) => a -> a -> Ratio a
19 , numerator -- :: (Integral a) => Ratio a -> a
20 , denominator -- :: (Integral a) => Ratio a -> a
21 , approxRational -- :: (RealFrac a) => a -> a -> Rational
22
23 -- Ratio instances:
24 -- (Integral a) => Eq (Ratio a)
25 -- (Integral a) => Ord (Ratio a)
26 -- (Integral a) => Num (Ratio a)
27 -- (Integral a) => Real (Ratio a)
28 -- (Integral a) => Fractional (Ratio a)
29 -- (Integral a) => RealFrac (Ratio a)
30 -- (Integral a) => Enum (Ratio a)
31 -- (Read a, Integral a) => Read (Ratio a)
32 -- (Integral a) => Show (Ratio a)
33
34 ) where
35
36 import Prelude
37
38 #ifdef __GLASGOW_HASKELL__
39 import GHC.Real -- The basic defns for Ratio
40 #endif
41
42 #ifdef __HUGS__
43 import Hugs.Prelude(Ratio(..), (%), numerator, denominator)
44 #endif
45
46 -- -----------------------------------------------------------------------------
47 -- approxRational
48
49 -- @approxRational@, applied to two real fractional numbers x and epsilon,
50 -- returns the simplest rational number within epsilon of x. A rational
51 -- number n%d in reduced form is said to be simpler than another n'%d' if
52 -- abs n <= abs n' && d <= d'. Any real interval contains a unique
53 -- simplest rational; here, for simplicity, we assume a closed rational
54 -- interval. If such an interval includes at least one whole number, then
55 -- the simplest rational is the absolutely least whole number. Otherwise,
56 -- the bounds are of the form q%1 + r%d and q%1 + r'%d', where abs r < d
57 -- and abs r' < d', and the simplest rational is q%1 + the reciprocal of
58 -- the simplest rational between d'%r' and d%r.
59
60 approxRational :: (RealFrac a) => a -> a -> Rational
61 approxRational rat eps = simplest (rat-eps) (rat+eps)
62 where simplest x y | y < x = simplest y x
63 | x == y = xr
64 | x > 0 = simplest' n d n' d'
65 | y < 0 = - simplest' (-n') d' (-n) d
66 | otherwise = 0 :% 1
67 where xr = toRational x
68 n = numerator xr
69 d = denominator xr
70 nd' = toRational y
71 n' = numerator nd'
72 d' = denominator nd'
73
74 simplest' n d n' d' -- assumes 0 < n%d < n'%d'
75 | r == 0 = q :% 1
76 | q /= q' = (q+1) :% 1
77 | otherwise = (q*n''+d'') :% n''
78 where (q,r) = quotRem n d
79 (q',r') = quotRem n' d'
80 nd'' = simplest' d' r' d r
81 n'' = numerator nd''
82 d'' = denominator nd''