Remove Control.Parallel*, now in package parallel
[packages/random.git] / GHC / Base.lhs
1 \section[GHC.Base]{Module @GHC.Base@}
2
3 The overall structure of the GHC Prelude is a bit tricky.
4
5   a) We want to avoid "orphan modules", i.e. ones with instance
6         decls that don't belong either to a tycon or a class
7         defined in the same module
8
9   b) We want to avoid giant modules
10
11 So the rough structure is as follows, in (linearised) dependency order
12
13
14 GHC.Prim                Has no implementation.  It defines built-in things, and
15                 by importing it you bring them into scope.
16                 The source file is GHC.Prim.hi-boot, which is just
17                 copied to make GHC.Prim.hi
18
19 GHC.Base        Classes: Eq, Ord, Functor, Monad
20                 Types:   list, (), Int, Bool, Ordering, Char, String
21
22 Data.Tuple      Types: tuples, plus instances for GHC.Base classes
23
24 GHC.Show        Class: Show, plus instances for GHC.Base/GHC.Tup types
25
26 GHC.Enum        Class: Enum,  plus instances for GHC.Base/GHC.Tup types
27
28 Data.Maybe      Type: Maybe, plus instances for GHC.Base classes
29
30 GHC.List        List functions
31
32 GHC.Num         Class: Num, plus instances for Int
33                 Type:  Integer, plus instances for all classes so far (Eq, Ord, Num, Show)
34
35                 Integer is needed here because it is mentioned in the signature
36                 of 'fromInteger' in class Num
37
38 GHC.Real        Classes: Real, Integral, Fractional, RealFrac
39                          plus instances for Int, Integer
40                 Types:  Ratio, Rational
41                         plus intances for classes so far
42
43                 Rational is needed here because it is mentioned in the signature
44                 of 'toRational' in class Real
45
46 GHC.ST  The ST monad, instances and a few helper functions
47
48 Ix              Classes: Ix, plus instances for Int, Bool, Char, Integer, Ordering, tuples
49
50 GHC.Arr         Types: Array, MutableArray, MutableVar
51
52                 Arrays are used by a function in GHC.Float
53
54 GHC.Float       Classes: Floating, RealFloat
55                 Types:   Float, Double, plus instances of all classes so far
56
57                 This module contains everything to do with floating point.
58                 It is a big module (900 lines)
59                 With a bit of luck, many modules can be compiled without ever reading GHC.Float.hi
60
61
62 Other Prelude modules are much easier with fewer complex dependencies.
63
64 \begin{code}
65 {-# OPTIONS_GHC -fno-implicit-prelude #-}
66 -----------------------------------------------------------------------------
67 -- |
68 -- Module      :  GHC.Base
69 -- Copyright   :  (c) The University of Glasgow, 1992-2002
70 -- License     :  see libraries/base/LICENSE
71 -- 
72 -- Maintainer  :  cvs-ghc@haskell.org
73 -- Stability   :  internal
74 -- Portability :  non-portable (GHC extensions)
75 --
76 -- Basic data types and classes.
77 -- 
78 -----------------------------------------------------------------------------
79
80 #include "MachDeps.h"
81
82 -- #hide
83 module GHC.Base
84         (
85         module GHC.Base,
86         module GHC.Prim,        -- Re-export GHC.Prim and GHC.Err, to avoid lots
87         module GHC.Err          -- of people having to import it explicitly
88   ) 
89         where
90
91 import GHC.Prim
92 import {-# SOURCE #-} GHC.Err
93
94 infixr 9  .
95 infixr 5  ++, :
96 infix  4  ==, /=, <, <=, >=, >
97 infixr 3  &&
98 infixr 2  ||
99 infixl 1  >>, >>=
100 infixr 0  $
101
102 default ()              -- Double isn't available yet
103 \end{code}
104
105
106 %*********************************************************
107 %*                                                      *
108 \subsection{DEBUGGING STUFF}
109 %*  (for use when compiling GHC.Base itself doesn't work)
110 %*                                                      *
111 %*********************************************************
112
113 \begin{code}
114 {-
115 data  Bool  =  False | True
116 data Ordering = LT | EQ | GT 
117 data Char = C# Char#
118 type  String = [Char]
119 data Int = I# Int#
120 data  ()  =  ()
121 data [] a = MkNil
122
123 not True = False
124 (&&) True True = True
125 otherwise = True
126
127 build = error "urk"
128 foldr = error "urk"
129
130 unpackCString# :: Addr# -> [Char]
131 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a 
132 unpackAppendCString# :: Addr# -> [Char] -> [Char]
133 unpackCStringUtf8# :: Addr# -> [Char]
134 unpackCString# a = error "urk"
135 unpackFoldrCString# a = error "urk"
136 unpackAppendCString# a = error "urk"
137 unpackCStringUtf8# a = error "urk"
138 -}
139 \end{code}
140
141
142 %*********************************************************
143 %*                                                      *
144 \subsection{Standard classes @Eq@, @Ord@}
145 %*                                                      *
146 %*********************************************************
147
148 \begin{code}
149
150 -- | The 'Eq' class defines equality ('==') and inequality ('/=').
151 -- All the basic datatypes exported by the "Prelude" are instances of 'Eq',
152 -- and 'Eq' may be derived for any datatype whose constituents are also
153 -- instances of 'Eq'.
154 --
155 -- Minimal complete definition: either '==' or '/='.
156 --
157 class  Eq a  where
158     (==), (/=)           :: a -> a -> Bool
159
160     x /= y               = not (x == y)
161     x == y               = not (x /= y)
162
163 -- | The 'Ord' class is used for totally ordered datatypes.
164 --
165 -- Instances of 'Ord' can be derived for any user-defined
166 -- datatype whose constituent types are in 'Ord'.  The declared order
167 -- of the constructors in the data declaration determines the ordering
168 -- in derived 'Ord' instances.  The 'Ordering' datatype allows a single
169 -- comparison to determine the precise ordering of two objects.
170 --
171 -- Minimal complete definition: either 'compare' or '<='.
172 -- Using 'compare' can be more efficient for complex types.
173 --
174 class  (Eq a) => Ord a  where
175     compare              :: a -> a -> Ordering
176     (<), (<=), (>), (>=) :: a -> a -> Bool
177     max, min             :: a -> a -> a
178
179     compare x y
180         | x == y    = EQ
181         | x <= y    = LT        -- NB: must be '<=' not '<' to validate the
182                                 -- above claim about the minimal things that
183                                 -- can be defined for an instance of Ord
184         | otherwise = GT
185
186     x <  y = case compare x y of { LT -> True;  _other -> False }
187     x <= y = case compare x y of { GT -> False; _other -> True }
188     x >  y = case compare x y of { GT -> True;  _other -> False }
189     x >= y = case compare x y of { LT -> False; _other -> True }
190
191         -- These two default methods use '<=' rather than 'compare'
192         -- because the latter is often more expensive
193     max x y = if x <= y then y else x
194     min x y = if x <= y then x else y
195 \end{code}
196
197 %*********************************************************
198 %*                                                      *
199 \subsection{Monadic classes @Functor@, @Monad@ }
200 %*                                                      *
201 %*********************************************************
202
203 \begin{code}
204 {- | The 'Functor' class is used for types that can be mapped over.
205 Instances of 'Functor' should satisfy the following laws:
206
207 > fmap id  ==  id
208 > fmap (f . g)  ==  fmap f . fmap g
209
210 The instances of 'Functor' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
211 defined in the "Prelude" satisfy these laws.
212 -}
213
214 class  Functor f  where
215     fmap        :: (a -> b) -> f a -> f b
216
217 {- | The 'Monad' class defines the basic operations over a /monad/,
218 a concept from a branch of mathematics known as /category theory/.
219 From the perspective of a Haskell programmer, however, it is best to
220 think of a monad as an /abstract datatype/ of actions.
221 Haskell's @do@ expressions provide a convenient syntax for writing
222 monadic expressions.
223
224 Minimal complete definition: '>>=' and 'return'.
225
226 Instances of 'Monad' should satisfy the following laws:
227
228 > return a >>= k  ==  k a
229 > m >>= return  ==  m
230 > m >>= (\x -> k x >>= h)  ==  (m >>= k) >>= h
231
232 Instances of both 'Monad' and 'Functor' should additionally satisfy the law:
233
234 > fmap f xs  ==  xs >>= return . f
235
236 The instances of 'Monad' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
237 defined in the "Prelude" satisfy these laws.
238 -}
239
240 class  Monad m  where
241     -- | Sequentially compose two actions, passing any value produced
242     -- by the first as an argument to the second.
243     (>>=)       :: forall a b. m a -> (a -> m b) -> m b
244     -- | Sequentially compose two actions, discarding any value produced
245     -- by the first, like sequencing operators (such as the semicolon)
246     -- in imperative languages.
247     (>>)        :: forall a b. m a -> m b -> m b
248         -- Explicit for-alls so that we know what order to
249         -- give type arguments when desugaring
250
251     -- | Inject a value into the monadic type.
252     return      :: a -> m a
253     -- | Fail with a message.  This operation is not part of the
254     -- mathematical definition of a monad, but is invoked on pattern-match
255     -- failure in a @do@ expression.
256     fail        :: String -> m a
257
258     m >> k      = m >>= \_ -> k
259     fail s      = error s
260 \end{code}
261
262
263 %*********************************************************
264 %*                                                      *
265 \subsection{The list type}
266 %*                                                      *
267 %*********************************************************
268
269 \begin{code}
270 data [] a = [] | a : [a]  -- do explicitly: deriving (Eq, Ord)
271                           -- to avoid weird names like con2tag_[]#
272
273
274 instance (Eq a) => Eq [a] where
275     {-# SPECIALISE instance Eq [Char] #-}
276     []     == []     = True
277     (x:xs) == (y:ys) = x == y && xs == ys
278     _xs    == _ys    = False
279
280 instance (Ord a) => Ord [a] where
281     {-# SPECIALISE instance Ord [Char] #-}
282     compare []     []     = EQ
283     compare []     (_:_)  = LT
284     compare (_:_)  []     = GT
285     compare (x:xs) (y:ys) = case compare x y of
286                                 EQ    -> compare xs ys
287                                 other -> other
288
289 instance Functor [] where
290     fmap = map
291
292 instance  Monad []  where
293     m >>= k             = foldr ((++) . k) [] m
294     m >> k              = foldr ((++) . (\ _ -> k)) [] m
295     return x            = [x]
296     fail _              = []
297 \end{code}
298
299 A few list functions that appear here because they are used here.
300 The rest of the prelude list functions are in GHC.List.
301
302 ----------------------------------------------
303 --      foldr/build/augment
304 ----------------------------------------------
305   
306 \begin{code}
307 -- | 'foldr', applied to a binary operator, a starting value (typically
308 -- the right-identity of the operator), and a list, reduces the list
309 -- using the binary operator, from right to left:
310 --
311 -- > foldr f z [x1, x2, ..., xn] == x1 `f` (x2 `f` ... (xn `f` z)...)
312
313 foldr            :: (a -> b -> b) -> b -> [a] -> b
314 -- foldr _ z []     =  z
315 -- foldr f z (x:xs) =  f x (foldr f z xs)
316 {-# INLINE [0] foldr #-}
317 -- Inline only in the final stage, after the foldr/cons rule has had a chance
318 foldr k z xs = go xs
319              where
320                go []     = z
321                go (y:ys) = y `k` go ys
322
323 -- | A list producer that can be fused with 'foldr'.
324 -- This function is merely
325 --
326 -- >    build g = g (:) []
327 --
328 -- but GHC's simplifier will transform an expression of the form
329 -- @'foldr' k z ('build' g)@, which may arise after inlining, to @g k z@,
330 -- which avoids producing an intermediate list.
331
332 build   :: forall a. (forall b. (a -> b -> b) -> b -> b) -> [a]
333 {-# INLINE [1] build #-}
334         -- The INLINE is important, even though build is tiny,
335         -- because it prevents [] getting inlined in the version that
336         -- appears in the interface file.  If [] *is* inlined, it
337         -- won't match with [] appearing in rules in an importing module.
338         --
339         -- The "1" says to inline in phase 1
340
341 build g = g (:) []
342
343 -- | A list producer that can be fused with 'foldr'.
344 -- This function is merely
345 --
346 -- >    augment g xs = g (:) xs
347 --
348 -- but GHC's simplifier will transform an expression of the form
349 -- @'foldr' k z ('augment' g xs)@, which may arise after inlining, to
350 -- @g k ('foldr' k z xs)@, which avoids producing an intermediate list.
351
352 augment :: forall a. (forall b. (a->b->b) -> b -> b) -> [a] -> [a]
353 {-# INLINE [1] augment #-}
354 augment g xs = g (:) xs
355
356 {-# RULES
357 "fold/build"    forall k z (g::forall b. (a->b->b) -> b -> b) . 
358                 foldr k z (build g) = g k z
359
360 "foldr/augment" forall k z xs (g::forall b. (a->b->b) -> b -> b) . 
361                 foldr k z (augment g xs) = g k (foldr k z xs)
362
363 "foldr/id"                        foldr (:) [] = \x  -> x
364 "foldr/app"     [1] forall ys. foldr (:) ys = \xs -> xs ++ ys
365         -- Only activate this from phase 1, because that's
366         -- when we disable the rule that expands (++) into foldr
367
368 -- The foldr/cons rule looks nice, but it can give disastrously
369 -- bloated code when commpiling
370 --      array (a,b) [(1,2), (2,2), (3,2), ...very long list... ]
371 -- i.e. when there are very very long literal lists
372 -- So I've disabled it for now. We could have special cases
373 -- for short lists, I suppose.
374 -- "foldr/cons" forall k z x xs. foldr k z (x:xs) = k x (foldr k z xs)
375
376 "foldr/single"  forall k z x. foldr k z [x] = k x z
377 "foldr/nil"     forall k z.   foldr k z []  = z 
378
379 "augment/build" forall (g::forall b. (a->b->b) -> b -> b)
380                        (h::forall b. (a->b->b) -> b -> b) .
381                        augment g (build h) = build (\c n -> g c (h c n))
382 "augment/nil"   forall (g::forall b. (a->b->b) -> b -> b) .
383                         augment g [] = build g
384  #-}
385
386 -- This rule is true, but not (I think) useful:
387 --      augment g (augment h t) = augment (\cn -> g c (h c n)) t
388 \end{code}
389
390
391 ----------------------------------------------
392 --              map     
393 ----------------------------------------------
394
395 \begin{code}
396 -- | 'map' @f xs@ is the list obtained by applying @f@ to each element
397 -- of @xs@, i.e.,
398 --
399 -- > map f [x1, x2, ..., xn] == [f x1, f x2, ..., f xn]
400 -- > map f [x1, x2, ...] == [f x1, f x2, ...]
401
402 map :: (a -> b) -> [a] -> [b]
403 map _ []     = []
404 map f (x:xs) = f x : map f xs
405
406 -- Note eta expanded
407 mapFB ::  (elt -> lst -> lst) -> (a -> elt) -> a -> lst -> lst
408 {-# INLINE [0] mapFB #-}
409 mapFB c f x ys = c (f x) ys
410
411 -- The rules for map work like this.
412 -- 
413 -- Up to (but not including) phase 1, we use the "map" rule to
414 -- rewrite all saturated applications of map with its build/fold 
415 -- form, hoping for fusion to happen.
416 -- In phase 1 and 0, we switch off that rule, inline build, and
417 -- switch on the "mapList" rule, which rewrites the foldr/mapFB
418 -- thing back into plain map.  
419 --
420 -- It's important that these two rules aren't both active at once 
421 -- (along with build's unfolding) else we'd get an infinite loop 
422 -- in the rules.  Hence the activation control below.
423 --
424 -- The "mapFB" rule optimises compositions of map.
425 --
426 -- This same pattern is followed by many other functions: 
427 -- e.g. append, filter, iterate, repeat, etc.
428
429 {-# RULES
430 "map"       [~1] forall f xs.   map f xs                = build (\c n -> foldr (mapFB c f) n xs)
431 "mapList"   [1]  forall f.      foldr (mapFB (:) f) []  = map f
432 "mapFB"     forall c f g.       mapFB (mapFB c f) g     = mapFB c (f.g) 
433   #-}
434 \end{code}
435
436
437 ----------------------------------------------
438 --              append  
439 ----------------------------------------------
440 \begin{code}
441 -- | Append two lists, i.e.,
442 --
443 -- > [x1, ..., xm] ++ [y1, ..., yn] == [x1, ..., xm, y1, ..., yn]
444 -- > [x1, ..., xm] ++ [y1, ...] == [x1, ..., xm, y1, ...]
445 --
446 -- If the first list is not finite, the result is the first list.
447
448 (++) :: [a] -> [a] -> [a]
449 (++) []     ys = ys
450 (++) (x:xs) ys = x : xs ++ ys
451
452 {-# RULES
453 "++"    [~1] forall xs ys. xs ++ ys = augment (\c n -> foldr c n xs) ys
454   #-}
455
456 \end{code}
457
458
459 %*********************************************************
460 %*                                                      *
461 \subsection{Type @Bool@}
462 %*                                                      *
463 %*********************************************************
464
465 \begin{code}
466 -- |The 'Bool' type is an enumeration.  It is defined with 'False'
467 -- first so that the corresponding 'Prelude.Enum' instance will give
468 -- 'Prelude.fromEnum' 'False' the value zero, and
469 -- 'Prelude.fromEnum' 'True' the value 1.
470 data  Bool  =  False | True  deriving (Eq, Ord)
471         -- Read in GHC.Read, Show in GHC.Show
472
473 -- Boolean functions
474
475 -- | Boolean \"and\"
476 (&&)                    :: Bool -> Bool -> Bool
477 True  && x              =  x
478 False && _              =  False
479
480 -- | Boolean \"or\"
481 (||)                    :: Bool -> Bool -> Bool
482 True  || _              =  True
483 False || x              =  x
484
485 -- | Boolean \"not\"
486 not                     :: Bool -> Bool
487 not True                =  False
488 not False               =  True
489
490 -- |'otherwise' is defined as the value 'True'.  It helps to make
491 -- guards more readable.  eg.
492 --
493 -- >  f x | x < 0     = ...
494 -- >      | otherwise = ...
495 otherwise               :: Bool
496 otherwise               =  True
497 \end{code}
498
499 %*********************************************************
500 %*                                                      *
501 \subsection{The @()@ type}
502 %*                                                      *
503 %*********************************************************
504
505 The Unit type is here because virtually any program needs it (whereas
506 some programs may get away without consulting GHC.Tup).  Furthermore,
507 the renamer currently *always* asks for () to be in scope, so that
508 ccalls can use () as their default type; so when compiling GHC.Base we
509 need ().  (We could arrange suck in () only if -fglasgow-exts, but putting
510 it here seems more direct.)
511
512 \begin{code}
513 -- | The unit datatype @()@ has one non-undefined member, the nullary
514 -- constructor @()@.
515 data () = ()
516
517 instance Eq () where
518     () == () = True
519     () /= () = False
520
521 instance Ord () where
522     () <= () = True
523     () <  () = False
524     () >= () = True
525     () >  () = False
526     max () () = ()
527     min () () = ()
528     compare () () = EQ
529 \end{code}
530
531
532 %*********************************************************
533 %*                                                      *
534 \subsection{Type @Ordering@}
535 %*                                                      *
536 %*********************************************************
537
538 \begin{code}
539 -- | Represents an ordering relationship between two values: less
540 -- than, equal to, or greater than.  An 'Ordering' is returned by
541 -- 'compare'.
542 data Ordering = LT | EQ | GT deriving (Eq, Ord)
543         -- Read in GHC.Read, Show in GHC.Show
544 \end{code}
545
546
547 %*********************************************************
548 %*                                                      *
549 \subsection{Type @Char@ and @String@}
550 %*                                                      *
551 %*********************************************************
552
553 \begin{code}
554 -- | A 'String' is a list of characters.  String constants in Haskell are values
555 -- of type 'String'.
556 --
557 type String = [Char]
558
559 {-| The character type 'Char' is an enumeration whose values represent
560 Unicode (or equivalently ISO\/IEC 10646) characters
561 (see <http://www.unicode.org/> for details).
562 This set extends the ISO 8859-1 (Latin-1) character set
563 (the first 256 charachers), which is itself an extension of the ASCII
564 character set (the first 128 characters).
565 A character literal in Haskell has type 'Char'.
566
567 To convert a 'Char' to or from the corresponding 'Int' value defined
568 by Unicode, use 'Prelude.toEnum' and 'Prelude.fromEnum' from the
569 'Prelude.Enum' class respectively (or equivalently 'ord' and 'chr').
570 -}
571 data Char = C# Char#
572
573 -- We don't use deriving for Eq and Ord, because for Ord the derived
574 -- instance defines only compare, which takes two primops.  Then
575 -- '>' uses compare, and therefore takes two primops instead of one.
576
577 instance Eq Char where
578     (C# c1) == (C# c2) = c1 `eqChar#` c2
579     (C# c1) /= (C# c2) = c1 `neChar#` c2
580
581 instance Ord Char where
582     (C# c1) >  (C# c2) = c1 `gtChar#` c2
583     (C# c1) >= (C# c2) = c1 `geChar#` c2
584     (C# c1) <= (C# c2) = c1 `leChar#` c2
585     (C# c1) <  (C# c2) = c1 `ltChar#` c2
586
587 {-# RULES
588 "x# `eqChar#` x#" forall x#. x# `eqChar#` x# = True
589 "x# `neChar#` x#" forall x#. x# `neChar#` x# = False
590 "x# `gtChar#` x#" forall x#. x# `gtChar#` x# = False
591 "x# `geChar#` x#" forall x#. x# `geChar#` x# = True
592 "x# `leChar#` x#" forall x#. x# `leChar#` x# = True
593 "x# `ltChar#` x#" forall x#. x# `ltChar#` x# = False
594   #-}
595
596 -- | The 'Prelude.toEnum' method restricted to the type 'Data.Char.Char'.
597 chr :: Int -> Char
598 chr (I# i#) | int2Word# i# `leWord#` int2Word# 0x10FFFF# = C# (chr# i#)
599             | otherwise                                  = error "Prelude.chr: bad argument"
600
601 unsafeChr :: Int -> Char
602 unsafeChr (I# i#) = C# (chr# i#)
603
604 -- | The 'Prelude.fromEnum' method restricted to the type 'Data.Char.Char'.
605 ord :: Char -> Int
606 ord (C# c#) = I# (ord# c#)
607 \end{code}
608
609 String equality is used when desugaring pattern-matches against strings.
610
611 \begin{code}
612 eqString :: String -> String -> Bool
613 eqString []       []       = True
614 eqString (c1:cs1) (c2:cs2) = c1 == c2 && cs1 `eqString` cs2
615 eqString cs1      cs2      = False
616
617 {-# RULES "eqString" (==) = eqString #-}
618 -- eqString also has a BuiltInRule in PrelRules.lhs:
619 --      eqString (unpackCString# (Lit s1)) (unpackCString# (Lit s2) = s1==s2
620 \end{code}
621
622
623 %*********************************************************
624 %*                                                      *
625 \subsection{Type @Int@}
626 %*                                                      *
627 %*********************************************************
628
629 \begin{code}
630 data Int = I# Int#
631 -- ^A fixed-precision integer type with at least the range @[-2^29 .. 2^29-1]@.
632 -- The exact range for a given implementation can be determined by using
633 -- 'Prelude.minBound' and 'Prelude.maxBound' from the 'Prelude.Bounded' class.
634
635 zeroInt, oneInt, twoInt, maxInt, minInt :: Int
636 zeroInt = I# 0#
637 oneInt  = I# 1#
638 twoInt  = I# 2#
639
640 {- Seems clumsy. Should perhaps put minInt and MaxInt directly into MachDeps.h -}
641 #if WORD_SIZE_IN_BITS == 31
642 minInt  = I# (-0x40000000#)
643 maxInt  = I# 0x3FFFFFFF#
644 #elif WORD_SIZE_IN_BITS == 32
645 minInt  = I# (-0x80000000#)
646 maxInt  = I# 0x7FFFFFFF#
647 #else 
648 minInt  = I# (-0x8000000000000000#)
649 maxInt  = I# 0x7FFFFFFFFFFFFFFF#
650 #endif
651
652 instance Eq Int where
653     (==) = eqInt
654     (/=) = neInt
655
656 instance Ord Int where
657     compare = compareInt
658     (<)     = ltInt
659     (<=)    = leInt
660     (>=)    = geInt
661     (>)     = gtInt
662
663 compareInt :: Int -> Int -> Ordering
664 (I# x#) `compareInt` (I# y#) = compareInt# x# y#
665
666 compareInt# :: Int# -> Int# -> Ordering
667 compareInt# x# y#
668     | x# <#  y# = LT
669     | x# ==# y# = EQ
670     | otherwise = GT
671 \end{code}
672
673
674 %*********************************************************
675 %*                                                      *
676 \subsection{The function type}
677 %*                                                      *
678 %*********************************************************
679
680 \begin{code}
681 -- | Identity function.
682 id                      :: a -> a
683 id x                    =  x
684
685 -- | The call '(lazy e)' means the same as 'e', but 'lazy' has a 
686 -- magical strictness property: it is lazy in its first argument, 
687 -- even though its semantics is strict.
688 lazy :: a -> a
689 lazy x = x
690 -- Implementation note: its strictness and unfolding are over-ridden
691 -- by the definition in MkId.lhs; in both cases to nothing at all.
692 -- That way, 'lazy' does not get inlined, and the strictness analyser
693 -- sees it as lazy.  Then the worker/wrapper phase inlines it.
694 -- Result: happiness
695
696
697 -- | The call '(inline f)' reduces to 'f', but 'inline' has a BuiltInRule
698 -- that tries to inline 'f' (if it has an unfolding) unconditionally
699 -- The 'NOINLINE' pragma arranges that inline only gets inlined (and
700 -- hence eliminated) late in compilation, after the rule has had
701 -- a god chance to fire.
702 inline :: a -> a
703 {-# NOINLINE[0] inline #-}
704 inline x = x
705
706 -- Assertion function.  This simply ignores its boolean argument.
707 -- The compiler may rewrite it to @('assertError' line)@.
708
709 -- | If the first argument evaluates to 'True', then the result is the
710 -- second argument.  Otherwise an 'AssertionFailed' exception is raised,
711 -- containing a 'String' with the source file and line number of the
712 -- call to 'assert'.
713 --
714 -- Assertions can normally be turned on or off with a compiler flag
715 -- (for GHC, assertions are normally on unless optimisation is turned on 
716 -- with @-O@ or the @-fignore-asserts@
717 -- option is given).  When assertions are turned off, the first
718 -- argument to 'assert' is ignored, and the second argument is
719 -- returned as the result.
720
721 --      SLPJ: in 5.04 etc 'assert' is in GHC.Prim,
722 --      but from Template Haskell onwards it's simply
723 --      defined here in Base.lhs
724 assert :: Bool -> a -> a
725 assert pred r = r
726
727 breakpoint :: a -> a
728 breakpoint r = r
729
730 breakpointCond :: Bool -> a -> a
731 breakpointCond _ r = r
732
733 data Opaque = forall a. O a
734
735 -- | Constant function.
736 const                   :: a -> b -> a
737 const x _               =  x
738
739 -- | Function composition.
740 {-# INLINE (.) #-}
741 (.)       :: (b -> c) -> (a -> b) -> a -> c
742 (.) f g x = f (g x)
743
744 -- | @'flip' f@ takes its (first) two arguments in the reverse order of @f@.
745 flip                    :: (a -> b -> c) -> b -> a -> c
746 flip f x y              =  f y x
747
748 -- | Application operator.  This operator is redundant, since ordinary
749 -- application @(f x)@ means the same as @(f '$' x)@. However, '$' has
750 -- low, right-associative binding precedence, so it sometimes allows
751 -- parentheses to be omitted; for example:
752 --
753 -- >     f $ g $ h x  =  f (g (h x))
754 --
755 -- It is also useful in higher-order situations, such as @'map' ('$' 0) xs@,
756 -- or @'Data.List.zipWith' ('$') fs xs@.
757 {-# INLINE ($) #-}
758 ($)                     :: (a -> b) -> a -> b
759 f $ x                   =  f x
760
761 -- | @'until' p f@ yields the result of applying @f@ until @p@ holds.
762 until                   :: (a -> Bool) -> (a -> a) -> a -> a
763 until p f x | p x       =  x
764             | otherwise =  until p f (f x)
765
766 -- | 'asTypeOf' is a type-restricted version of 'const'.  It is usually
767 -- used as an infix operator, and its typing forces its first argument
768 -- (which is usually overloaded) to have the same type as the second.
769 asTypeOf                :: a -> a -> a
770 asTypeOf                =  const
771 \end{code}
772
773 %*********************************************************
774 %*                                                      *
775 \subsection{Generics}
776 %*                                                      *
777 %*********************************************************
778
779 \begin{code}
780 data Unit = Unit
781 #ifndef __HADDOCK__
782 data (:+:) a b = Inl a | Inr b
783 data (:*:) a b = a :*: b
784 #endif
785 \end{code}
786
787 %*********************************************************
788 %*                                                      *
789 \subsection{@getTag@}
790 %*                                                      *
791 %*********************************************************
792
793 Returns the 'tag' of a constructor application; this function is used
794 by the deriving code for Eq, Ord and Enum.
795
796 The primitive dataToTag# requires an evaluated constructor application
797 as its argument, so we provide getTag as a wrapper that performs the
798 evaluation before calling dataToTag#.  We could have dataToTag#
799 evaluate its argument, but we prefer to do it this way because (a)
800 dataToTag# can be an inline primop if it doesn't need to do any
801 evaluation, and (b) we want to expose the evaluation to the
802 simplifier, because it might be possible to eliminate the evaluation
803 in the case when the argument is already known to be evaluated.
804
805 \begin{code}
806 {-# INLINE getTag #-}
807 getTag :: a -> Int#
808 getTag x = x `seq` dataToTag# x
809 \end{code}
810
811 %*********************************************************
812 %*                                                      *
813 \subsection{Numeric primops}
814 %*                                                      *
815 %*********************************************************
816
817 \begin{code}
818 divInt# :: Int# -> Int# -> Int#
819 x# `divInt#` y#
820         -- Be careful NOT to overflow if we do any additional arithmetic
821         -- on the arguments...  the following  previous version of this
822         -- code has problems with overflow:
823 --    | (x# ># 0#) && (y# <# 0#) = ((x# -# y#) -# 1#) `quotInt#` y#
824 --    | (x# <# 0#) && (y# ># 0#) = ((x# -# y#) +# 1#) `quotInt#` y#
825     | (x# ># 0#) && (y# <# 0#) = ((x# -# 1#) `quotInt#` y#) -# 1#
826     | (x# <# 0#) && (y# ># 0#) = ((x# +# 1#) `quotInt#` y#) -# 1#
827     | otherwise                = x# `quotInt#` y#
828
829 modInt# :: Int# -> Int# -> Int#
830 x# `modInt#` y#
831     | (x# ># 0#) && (y# <# 0#) ||
832       (x# <# 0#) && (y# ># 0#)    = if r# /=# 0# then r# +# y# else 0#
833     | otherwise                   = r#
834     where
835     r# = x# `remInt#` y#
836 \end{code}
837
838 Definitions of the boxed PrimOps; these will be
839 used in the case of partial applications, etc.
840
841 \begin{code}
842 {-# INLINE eqInt #-}
843 {-# INLINE neInt #-}
844 {-# INLINE gtInt #-}
845 {-# INLINE geInt #-}
846 {-# INLINE ltInt #-}
847 {-# INLINE leInt #-}
848 {-# INLINE plusInt #-}
849 {-# INLINE minusInt #-}
850 {-# INLINE timesInt #-}
851 {-# INLINE quotInt #-}
852 {-# INLINE remInt #-}
853 {-# INLINE negateInt #-}
854
855 plusInt, minusInt, timesInt, quotInt, remInt, divInt, modInt, gcdInt :: Int -> Int -> Int
856 (I# x) `plusInt`  (I# y) = I# (x +# y)
857 (I# x) `minusInt` (I# y) = I# (x -# y)
858 (I# x) `timesInt` (I# y) = I# (x *# y)
859 (I# x) `quotInt`  (I# y) = I# (x `quotInt#` y)
860 (I# x) `remInt`   (I# y) = I# (x `remInt#`  y)
861 (I# x) `divInt`   (I# y) = I# (x `divInt#`  y)
862 (I# x) `modInt`   (I# y) = I# (x `modInt#`  y)
863
864 {-# RULES
865 "x# +# 0#" forall x#. x# +# 0# = x#
866 "0# +# x#" forall x#. 0# +# x# = x#
867 "x# -# 0#" forall x#. x# -# 0# = x#
868 "x# -# x#" forall x#. x# -# x# = 0#
869 "x# *# 0#" forall x#. x# *# 0# = 0#
870 "0# *# x#" forall x#. 0# *# x# = 0#
871 "x# *# 1#" forall x#. x# *# 1# = x#
872 "1# *# x#" forall x#. 1# *# x# = x#
873   #-}
874
875 gcdInt (I# a) (I# b) = g a b
876    where g 0# 0# = error "GHC.Base.gcdInt: gcd 0 0 is undefined"
877          g 0# _  = I# absB
878          g _  0# = I# absA
879          g _  _  = I# (gcdInt# absA absB)
880
881          absInt x = if x <# 0# then negateInt# x else x
882
883          absA     = absInt a
884          absB     = absInt b
885
886 negateInt :: Int -> Int
887 negateInt (I# x) = I# (negateInt# x)
888
889 gtInt, geInt, eqInt, neInt, ltInt, leInt :: Int -> Int -> Bool
890 (I# x) `gtInt` (I# y) = x >#  y
891 (I# x) `geInt` (I# y) = x >=# y
892 (I# x) `eqInt` (I# y) = x ==# y
893 (I# x) `neInt` (I# y) = x /=# y
894 (I# x) `ltInt` (I# y) = x <#  y
895 (I# x) `leInt` (I# y) = x <=# y
896
897 {-# RULES
898 "x# ># x#"  forall x#. x# >#  x# = False
899 "x# >=# x#" forall x#. x# >=# x# = True
900 "x# ==# x#" forall x#. x# ==# x# = True
901 "x# /=# x#" forall x#. x# /=# x# = False
902 "x# <# x#"  forall x#. x# <#  x# = False
903 "x# <=# x#" forall x#. x# <=# x# = True
904   #-}
905
906 {-# RULES
907 "plusFloat x 0.0"   forall x#. plusFloat#  x#   0.0# = x#
908 "plusFloat 0.0 x"   forall x#. plusFloat#  0.0# x#   = x#
909 "minusFloat x 0.0"  forall x#. minusFloat# x#   0.0# = x#
910 "minusFloat x x"    forall x#. minusFloat# x#   x#   = 0.0#
911 "timesFloat x 0.0"  forall x#. timesFloat# x#   0.0# = 0.0#
912 "timesFloat0.0 x"   forall x#. timesFloat# 0.0# x#   = 0.0#
913 "timesFloat x 1.0"  forall x#. timesFloat# x#   1.0# = x#
914 "timesFloat 1.0 x"  forall x#. timesFloat# 1.0# x#   = x#
915 "divideFloat x 1.0" forall x#. divideFloat# x#  1.0# = x#
916   #-}
917
918 {-# RULES
919 "plusDouble x 0.0"   forall x#. (+##) x#    0.0## = x#
920 "plusDouble 0.0 x"   forall x#. (+##) 0.0## x#    = x#
921 "minusDouble x 0.0"  forall x#. (-##) x#    0.0## = x#
922 "minusDouble x x"    forall x#. (-##) x#    x#    = 0.0##
923 "timesDouble x 0.0"  forall x#. (*##) x#    0.0## = 0.0##
924 "timesDouble 0.0 x"  forall x#. (*##) 0.0## x#    = 0.0##
925 "timesDouble x 1.0"  forall x#. (*##) x#    1.0## = x#
926 "timesDouble 1.0 x"  forall x#. (*##) 1.0## x#    = x#
927 "divideDouble x 1.0" forall x#. (/##) x#    1.0## = x#
928   #-}
929
930 -- Wrappers for the shift operations.  The uncheckedShift# family are
931 -- undefined when the amount being shifted by is greater than the size
932 -- in bits of Int#, so these wrappers perform a check and return
933 -- either zero or -1 appropriately.
934 --
935 -- Note that these wrappers still produce undefined results when the
936 -- second argument (the shift amount) is negative.
937
938 -- | Shift the argument left by the specified number of bits
939 -- (which must be non-negative).
940 shiftL# :: Word# -> Int# -> Word#
941 a `shiftL#` b   | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
942                 | otherwise                = a `uncheckedShiftL#` b
943
944 -- | Shift the argument right by the specified number of bits
945 -- (which must be non-negative).
946 shiftRL# :: Word# -> Int# -> Word#
947 a `shiftRL#` b  | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
948                 | otherwise                = a `uncheckedShiftRL#` b
949
950 -- | Shift the argument left by the specified number of bits
951 -- (which must be non-negative).
952 iShiftL# :: Int# -> Int# -> Int#
953 a `iShiftL#` b  | b >=# WORD_SIZE_IN_BITS# = 0#
954                 | otherwise                = a `uncheckedIShiftL#` b
955
956 -- | Shift the argument right (signed) by the specified number of bits
957 -- (which must be non-negative).
958 iShiftRA# :: Int# -> Int# -> Int#
959 a `iShiftRA#` b | b >=# WORD_SIZE_IN_BITS# = if a <# 0# then (-1#) else 0#
960                 | otherwise                = a `uncheckedIShiftRA#` b
961
962 -- | Shift the argument right (unsigned) by the specified number of bits
963 -- (which must be non-negative).
964 iShiftRL# :: Int# -> Int# -> Int#
965 a `iShiftRL#` b | b >=# WORD_SIZE_IN_BITS# = 0#
966                 | otherwise                = a `uncheckedIShiftRL#` b
967
968 #if WORD_SIZE_IN_BITS == 32
969 {-# RULES
970 "narrow32Int#"  forall x#. narrow32Int#   x# = x#
971 "narrow32Word#" forall x#. narrow32Word#   x# = x#
972    #-}
973 #endif
974
975 {-# RULES
976 "int2Word2Int"  forall x#. int2Word# (word2Int# x#) = x#
977 "word2Int2Word" forall x#. word2Int# (int2Word# x#) = x#
978   #-}
979 \end{code}
980
981
982 %********************************************************
983 %*                                                      *
984 \subsection{Unpacking C strings}
985 %*                                                      *
986 %********************************************************
987
988 This code is needed for virtually all programs, since it's used for
989 unpacking the strings of error messages.
990
991 \begin{code}
992 unpackCString# :: Addr# -> [Char]
993 {-# NOINLINE [1] unpackCString# #-}
994 unpackCString# addr 
995   = unpack 0#
996   where
997     unpack nh
998       | ch `eqChar#` '\0'# = []
999       | otherwise          = C# ch : unpack (nh +# 1#)
1000       where
1001         ch = indexCharOffAddr# addr nh
1002
1003 unpackAppendCString# :: Addr# -> [Char] -> [Char]
1004 unpackAppendCString# addr rest
1005   = unpack 0#
1006   where
1007     unpack nh
1008       | ch `eqChar#` '\0'# = rest
1009       | otherwise          = C# ch : unpack (nh +# 1#)
1010       where
1011         ch = indexCharOffAddr# addr nh
1012
1013 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a 
1014 {-# NOINLINE [0] unpackFoldrCString# #-}
1015 -- Don't inline till right at the end;
1016 -- usually the unpack-list rule turns it into unpackCStringList
1017 -- It also has a BuiltInRule in PrelRules.lhs:
1018 --      unpackFoldrCString# "foo" c (unpackFoldrCString# "baz" c n)
1019 --        =  unpackFoldrCString# "foobaz" c n
1020 unpackFoldrCString# addr f z 
1021   = unpack 0#
1022   where
1023     unpack nh
1024       | ch `eqChar#` '\0'# = z
1025       | otherwise          = C# ch `f` unpack (nh +# 1#)
1026       where
1027         ch = indexCharOffAddr# addr nh
1028
1029 unpackCStringUtf8# :: Addr# -> [Char]
1030 unpackCStringUtf8# addr 
1031   = unpack 0#
1032   where
1033     unpack nh
1034       | ch `eqChar#` '\0'#   = []
1035       | ch `leChar#` '\x7F'# = C# ch : unpack (nh +# 1#)
1036       | ch `leChar#` '\xDF'# =
1037           C# (chr# (((ord# ch                                  -# 0xC0#) `uncheckedIShiftL#`  6#) +#
1038                      (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#))) :
1039           unpack (nh +# 2#)
1040       | ch `leChar#` '\xEF'# =
1041           C# (chr# (((ord# ch                                  -# 0xE0#) `uncheckedIShiftL#` 12#) +#
1042                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
1043                      (ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#))) :
1044           unpack (nh +# 3#)
1045       | otherwise            =
1046           C# (chr# (((ord# ch                                  -# 0xF0#) `uncheckedIShiftL#` 18#) +#
1047                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#` 12#) +#
1048                     ((ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
1049                      (ord# (indexCharOffAddr# addr (nh +# 3#)) -# 0x80#))) :
1050           unpack (nh +# 4#)
1051       where
1052         ch = indexCharOffAddr# addr nh
1053
1054 unpackNBytes# :: Addr# -> Int# -> [Char]
1055 unpackNBytes# _addr 0#   = []
1056 unpackNBytes#  addr len# = unpack [] (len# -# 1#)
1057     where
1058      unpack acc i#
1059       | i# <# 0#  = acc
1060       | otherwise = 
1061          case indexCharOffAddr# addr i# of
1062             ch -> unpack (C# ch : acc) (i# -# 1#)
1063
1064 {-# RULES
1065 "unpack"       [~1] forall a   . unpackCString# a                  = build (unpackFoldrCString# a)
1066 "unpack-list"  [1]  forall a   . unpackFoldrCString# a (:) [] = unpackCString# a
1067 "unpack-append"     forall a n . unpackFoldrCString# a (:) n  = unpackAppendCString# a n
1068
1069 -- There's a built-in rule (in PrelRules.lhs) for
1070 --      unpackFoldr "foo" c (unpackFoldr "baz" c n)  =  unpackFoldr "foobaz" c n
1071
1072   #-}
1073 \end{code}
1074
1075 #ifdef __HADDOCK__
1076 \begin{code}
1077 -- | A special argument for the 'Control.Monad.ST.ST' type constructor,
1078 -- indexing a state embedded in the 'Prelude.IO' monad by
1079 -- 'Control.Monad.ST.stToIO'.
1080 data RealWorld
1081 \end{code}
1082 #endif