1fca981077bae5071e50d79ba03b8b42edf726c3
[packages/random.git] / Control / Concurrent / Chan.hs
1 -----------------------------------------------------------------------------
2 -- |
3 -- Module : Control.Concurrent.Chan
4 -- Copyright : (c) The University of Glasgow 2001
5 -- License : BSD-style (see the file libraries/base/LICENSE)
6 --
7 -- Maintainer : libraries@haskell.org
8 -- Stability : experimental
9 -- Portability : non-portable (concurrency)
10 --
11 -- Unbounded channels.
12 --
13 -----------------------------------------------------------------------------
14
15 module Control.Concurrent.Chan
16 (
17 -- * The 'Chan' type
18 Chan, -- abstract
19
20 -- * Operations
21 newChan, -- :: IO (Chan a)
22 writeChan, -- :: Chan a -> a -> IO ()
23 readChan, -- :: Chan a -> IO a
24 dupChan, -- :: Chan a -> IO (Chan a)
25 unGetChan, -- :: Chan a -> a -> IO ()
26 isEmptyChan, -- :: Chan a -> IO Bool
27
28 -- * Stream interface
29 getChanContents, -- :: Chan a -> IO [a]
30 writeList2Chan, -- :: Chan a -> [a] -> IO ()
31 ) where
32
33 import Prelude
34
35 import System.IO.Unsafe ( unsafeInterleaveIO )
36 import Control.Concurrent.MVar
37 import Data.Typeable
38
39 #include "Typeable.h"
40
41 -- A channel is represented by two @MVar@s keeping track of the two ends
42 -- of the channel contents,i.e., the read- and write ends. Empty @MVar@s
43 -- are used to handle consumers trying to read from an empty channel.
44
45 -- |'Chan' is an abstract type representing an unbounded FIFO channel.
46 data Chan a
47 = Chan (MVar (Stream a))
48 (MVar (Stream a))
49
50 INSTANCE_TYPEABLE1(Chan,chanTc,"Chan")
51
52 type Stream a = MVar (ChItem a)
53
54 data ChItem a = ChItem a (Stream a)
55
56 -- See the Concurrent Haskell paper for a diagram explaining the
57 -- how the different channel operations proceed.
58
59 -- @newChan@ sets up the read and write end of a channel by initialising
60 -- these two @MVar@s with an empty @MVar@.
61
62 -- |Build and returns a new instance of 'Chan'.
63 newChan :: IO (Chan a)
64 newChan = do
65 hole <- newEmptyMVar
66 read <- newMVar hole
67 write <- newMVar hole
68 return (Chan read write)
69
70 -- To put an element on a channel, a new hole at the write end is created.
71 -- What was previously the empty @MVar@ at the back of the channel is then
72 -- filled in with a new stream element holding the entered value and the
73 -- new hole.
74
75 -- |Write a value to a 'Chan'.
76 writeChan :: Chan a -> a -> IO ()
77 writeChan (Chan _read write) val = do
78 new_hole <- newEmptyMVar
79 modifyMVar_ write $ \old_hole -> do
80 putMVar old_hole (ChItem val new_hole)
81 return new_hole
82
83 -- |Read the next value from the 'Chan'.
84 readChan :: Chan a -> IO a
85 readChan (Chan read _write) = do
86 modifyMVar read $ \read_end -> do
87 (ChItem val new_read_end) <- readMVar read_end
88 -- Use readMVar here, not takeMVar,
89 -- else dupChan doesn't work
90 return (new_read_end, val)
91
92 -- |Duplicate a 'Chan': the duplicate channel begins empty, but data written to
93 -- either channel from then on will be available from both. Hence this creates
94 -- a kind of broadcast channel, where data written by anyone is seen by
95 -- everyone else.
96 dupChan :: Chan a -> IO (Chan a)
97 dupChan (Chan _read write) = do
98 hole <- readMVar write
99 new_read <- newMVar hole
100 return (Chan new_read write)
101
102 -- |Put a data item back onto a channel, where it will be the next item read.
103 unGetChan :: Chan a -> a -> IO ()
104 unGetChan (Chan read _write) val = do
105 new_read_end <- newEmptyMVar
106 modifyMVar_ read $ \read_end -> do
107 putMVar new_read_end (ChItem val read_end)
108 return new_read_end
109
110 -- |Returns 'True' if the supplied 'Chan' is empty.
111 isEmptyChan :: Chan a -> IO Bool
112 isEmptyChan (Chan read write) = do
113 withMVar read $ \r -> do
114 w <- readMVar write
115 let eq = r == w
116 eq `seq` return eq
117
118 -- Operators for interfacing with functional streams.
119
120 -- |Return a lazy list representing the contents of the supplied
121 -- 'Chan', much like 'System.IO.hGetContents'.
122 getChanContents :: Chan a -> IO [a]
123 getChanContents ch
124 = unsafeInterleaveIO (do
125 x <- readChan ch
126 xs <- getChanContents ch
127 return (x:xs)
128 )
129
130 -- |Write an entire list of items to a 'Chan'.
131 writeList2Chan :: Chan a -> [a] -> IO ()
132 writeList2Chan ch ls = sequence_ (map (writeChan ch) ls)