Make sure the threaded threadDelay sleeps at least as long as it is asked to
[packages/old-time.git] / configure.ac
1 AC_INIT([Haskell base package], [1.0], [libraries@haskell.org], [base])
2
3 # Safety check: Ensure that we are in the correct source directory.
4 AC_CONFIG_SRCDIR([include/HsBase.h])
5
6 AC_CONFIG_HEADERS([include/HsBaseConfig.h])
7
8 # do we have long longs?
9 AC_CHECK_TYPES([long long])
10
11 dnl ** Working vfork?
12 AC_FUNC_FORK
13
14 dnl ** determine whether or not const works
15 AC_C_CONST
16
17 dnl ** check for full ANSI header (.h) files
18 AC_HEADER_STDC
19
20 # check for specific header (.h) files that we are interested in
21 AC_CHECK_HEADERS([ctype.h dirent.h errno.h fcntl.h limits.h signal.h sys/resource.h sys/select.h sys/syscall.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h])
22
23 # Enable large file support. Do this before testing the types ino_t, off_t, and
24 # rlim_t, because it will affect the result of that test.
25 AC_SYS_LARGEFILE
26
27 dnl ** check for wide-char classifications
28 dnl FreeBSD has an emtpy wctype.h, so test one of the affected
29 dnl functions if it's really there.
30 AC_CHECK_HEADERS([wctype.h], [AC_CHECK_FUNCS(iswspace)])
31
32 AC_CHECK_FUNCS([ftime gmtime_r localtime_r lstat readdir_r])
33 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer times])
34 AC_CHECK_FUNCS([_chsize ftruncate])
35
36 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
37 AC_HEADER_TIME
38
39 dnl ** how do we get a timezone name, and UTC offset ?
40 AC_STRUCT_TIMEZONE
41
42 dnl ** do we have altzone?
43 FP_DECL_ALTZONE
44
45 # map standard C types and ISO types to Haskell types
46 FPTOOLS_CHECK_HTYPE(char)
47 FPTOOLS_CHECK_HTYPE(signed char)
48 FPTOOLS_CHECK_HTYPE(unsigned char)
49 FPTOOLS_CHECK_HTYPE(short)
50 FPTOOLS_CHECK_HTYPE(unsigned short)
51 FPTOOLS_CHECK_HTYPE(int)
52 FPTOOLS_CHECK_HTYPE(unsigned int)
53 FPTOOLS_CHECK_HTYPE(long)
54 FPTOOLS_CHECK_HTYPE(unsigned long)
55 if test "$ac_cv_type_long_long" = yes; then
56 FPTOOLS_CHECK_HTYPE(long long)
57 FPTOOLS_CHECK_HTYPE(unsigned long long)
58 fi
59 FPTOOLS_CHECK_HTYPE(float)
60 FPTOOLS_CHECK_HTYPE(double)
61 FPTOOLS_CHECK_HTYPE(ptrdiff_t)
62 FPTOOLS_CHECK_HTYPE(size_t)
63 FPTOOLS_CHECK_HTYPE(wchar_t)
64 # Int32 is a HACK for non-ISO C compilers
65 FPTOOLS_CHECK_HTYPE(sig_atomic_t, Int32)
66 FPTOOLS_CHECK_HTYPE(clock_t)
67 FPTOOLS_CHECK_HTYPE(time_t)
68 FPTOOLS_CHECK_HTYPE(dev_t, Word32)
69 FPTOOLS_CHECK_HTYPE(ino_t)
70 FPTOOLS_CHECK_HTYPE(mode_t)
71 FPTOOLS_CHECK_HTYPE(off_t)
72 FPTOOLS_CHECK_HTYPE(pid_t)
73 FPTOOLS_CHECK_HTYPE(gid_t)
74 FPTOOLS_CHECK_HTYPE(uid_t)
75 FPTOOLS_CHECK_HTYPE(cc_t)
76 FPTOOLS_CHECK_HTYPE(speed_t)
77 FPTOOLS_CHECK_HTYPE(tcflag_t)
78 FPTOOLS_CHECK_HTYPE(nlink_t)
79 FPTOOLS_CHECK_HTYPE(ssize_t)
80 FPTOOLS_CHECK_HTYPE(rlim_t)
81 FPTOOLS_CHECK_HTYPE(wint_t)
82
83 FPTOOLS_CHECK_HTYPE(intptr_t)
84 FPTOOLS_CHECK_HTYPE(uintptr_t)
85 # Workaround for OSes that don't have intmax_t and uintmax_t, e.g. OpenBSD.
86 if test "$ac_cv_type_long_long" = yes; then
87   fptools_cv_default_htype_intmax=$fptools_cv_htype_long_long
88   fptools_cv_default_htype_uintmax=$fptools_cv_htype_unsigned_long_long
89 else
90   fptools_cv_default_htype_intmax=$fptools_cv_htype_long
91   fptools_cv_default_htype_uintmax=$fptools_cv_htype_unsigned_long
92 fi
93 FPTOOLS_CHECK_HTYPE(intmax_t, $fptools_cv_default_htype_intmax)
94 FPTOOLS_CHECK_HTYPE(uintmax_t, $fptools_cv_default_htype_uintmax)
95
96 # test errno values
97 FP_CHECK_CONSTS([E2BIG EACCES EADDRINUSE EADDRNOTAVAIL EADV EAFNOSUPPORT EAGAIN EALREADY EBADF EBADMSG EBADRPC EBUSY ECHILD ECOMM ECONNABORTED ECONNREFUSED ECONNRESET EDEADLK EDESTADDRREQ EDIRTY EDOM EDQUOT EEXIST EFAULT EFBIG EFTYPE EHOSTDOWN EHOSTUNREACH EIDRM EILSEQ EINPROGRESS EINTR EINVAL EIO EISCONN EISDIR ELOOP EMFILE EMLINK EMSGSIZE EMULTIHOP ENAMETOOLONG ENETDOWN ENETRESET ENETUNREACH ENFILE ENOBUFS ENODATA ENODEV ENOENT ENOEXEC ENOLCK ENOLINK ENOMEM ENOMSG ENONET ENOPROTOOPT ENOSPC ENOSR ENOSTR ENOSYS ENOTBLK ENOTCONN ENOTDIR ENOTEMPTY ENOTSOCK ENOTTY ENXIO EOPNOTSUPP EPERM EPFNOSUPPORT EPIPE EPROCLIM EPROCUNAVAIL EPROGMISMATCH EPROGUNAVAIL EPROTO EPROTONOSUPPORT EPROTOTYPE ERANGE EREMCHG EREMOTE EROFS ERPCMISMATCH ERREMOTE ESHUTDOWN ESOCKTNOSUPPORT ESPIPE ESRCH ESRMNT ESTALE ETIME ETIMEDOUT ETOOMANYREFS ETXTBSY EUSERS EWOULDBLOCK EXDEV ENOCIGAR], [#include <stdio.h>
98 #include <errno.h>])
99
100 FP_CHECK_CONSTS([SIGABRT SIGALRM SIGBUS SIGCHLD SIGCONT SIGFPE SIGHUP SIGILL SIGINT SIGKILL SIGPIPE SIGQUIT SIGSEGV SIGSTOP SIGTERM SIGTSTP SIGTTIN SIGTTOU SIGUSR1 SIGUSR2 SIGPOLL SIGPROF SIGSYS SIGTRAP SIGURG SIGVTALRM SIGXCPU SIGXFSZ SIG_BLOCK SIG_SETMASK SIG_UNBLOCK SIG_DFL SIG_IGN SIG_ERR], [
101 #if HAVE_SIGNAL_H
102 #include <signal.h>
103 #endif])
104
105 dnl ** can we open files in binary mode?
106 FP_CHECK_CONST([O_BINARY], [#include <fcntl.h>], [0])
107
108 # Check for idiosyncracies in some mingw impls of directory handling.
109 FP_READDIR_EOF_ERRNO
110
111 AC_OUTPUT