239ab163451c9897841ace18cd5f47370013bfb9
[packages/old-time.git] / GHC / Real.lhs
1 \begin{code}
2 {-# OPTIONS -fno-implicit-prelude #-}
3 -----------------------------------------------------------------------------
4 -- |
5 -- Module      :  GHC.Real
6 -- Copyright   :  (c) The FFI Task Force, 1994-2002
7 -- License     :  see libraries/base/LICENSE
8 -- 
9 -- Maintainer  :  cvs-ghc@haskell.org
10 -- Stability   :  internal
11 -- Portability :  non-portable (GHC Extensions)
12 --
13 -- The types 'Ratio' and 'Rational', and the classes 'Real', 'Fractional',
14 -- 'Integral', and 'RealFrac'.
15 --
16 -----------------------------------------------------------------------------
17
18 module GHC.Real where
19
20 import {-# SOURCE #-} GHC.Err
21 import GHC.Base
22 import GHC.Num
23 import GHC.List
24 import GHC.Enum
25 import GHC.Show
26
27 infixr 8  ^, ^^
28 infixl 7  /, `quot`, `rem`, `div`, `mod`
29 infixl 7  %
30
31 default ()              -- Double isn't available yet, 
32                         -- and we shouldn't be using defaults anyway
33 \end{code}
34
35
36 %*********************************************************
37 %*                                                      *
38 \subsection{The @Ratio@ and @Rational@ types}
39 %*                                                      *
40 %*********************************************************
41
42 \begin{code}
43 data  (Integral a)      => Ratio a = !a :% !a  deriving (Eq)
44
45 -- | Arbitrary-precision rational numbers, represented as a ratio of
46 -- two 'Integer' values.  A rational number may be constructed using
47 -- the '%' operator.
48 type  Rational          =  Ratio Integer
49
50 ratioPrec, ratioPrec1 :: Int
51 ratioPrec  = 7  -- Precedence of ':%' constructor
52 ratioPrec1 = ratioPrec + 1
53
54 infinity, notANumber :: Rational
55 infinity   = 1 :% 0
56 notANumber = 0 :% 0
57
58 -- Use :%, not % for Inf/NaN; the latter would 
59 -- immediately lead to a runtime error, because it normalises. 
60 \end{code}
61
62
63 \begin{code}
64 {-# SPECIALISE (%) :: Integer -> Integer -> Rational #-}
65 (%)                     :: (Integral a) => a -> a -> Ratio a
66 numerator, denominator  :: (Integral a) => Ratio a -> a
67 \end{code}
68
69 \tr{reduce} is a subsidiary function used only in this module .
70 It normalises a ratio by dividing both numerator and denominator by
71 their greatest common divisor.
72
73 \begin{code}
74 reduce ::  (Integral a) => a -> a -> Ratio a
75 {-# SPECIALISE reduce :: Integer -> Integer -> Rational #-}
76 reduce _ 0              =  error "Ratio.%: zero denominator"
77 reduce x y              =  (x `quot` d) :% (y `quot` d)
78                            where d = gcd x y
79 \end{code}
80
81 \begin{code}
82 x % y                   =  reduce (x * signum y) (abs y)
83
84 numerator   (x :% _)    =  x
85 denominator (_ :% y)    =  y
86 \end{code}
87
88
89 %*********************************************************
90 %*                                                      *
91 \subsection{Standard numeric classes}
92 %*                                                      *
93 %*********************************************************
94
95 \begin{code}
96 class  (Num a, Ord a) => Real a  where
97     toRational          ::  a -> Rational
98
99 class  (Real a, Enum a) => Integral a  where
100     quot, rem, div, mod :: a -> a -> a
101     quotRem, divMod     :: a -> a -> (a,a)
102     toInteger           :: a -> Integer
103
104     n `quot` d          =  q  where (q,_) = quotRem n d
105     n `rem` d           =  r  where (_,r) = quotRem n d
106     n `div` d           =  q  where (q,_) = divMod n d
107     n `mod` d           =  r  where (_,r) = divMod n d
108     divMod n d          =  if signum r == negate (signum d) then (q-1, r+d) else qr
109                            where qr@(q,r) = quotRem n d
110
111 class  (Num a) => Fractional a  where
112     (/)                 :: a -> a -> a
113     recip               :: a -> a
114     fromRational        :: Rational -> a
115
116     recip x             =  1 / x
117     x / y               = x * recip y
118
119 class  (Real a, Fractional a) => RealFrac a  where
120     properFraction      :: (Integral b) => a -> (b,a)
121     truncate, round     :: (Integral b) => a -> b
122     ceiling, floor      :: (Integral b) => a -> b
123
124     truncate x          =  m  where (m,_) = properFraction x
125     
126     round x             =  let (n,r) = properFraction x
127                                m     = if r < 0 then n - 1 else n + 1
128                            in case signum (abs r - 0.5) of
129                                 -1 -> n
130                                 0  -> if even n then n else m
131                                 1  -> m
132     
133     ceiling x           =  if r > 0 then n + 1 else n
134                            where (n,r) = properFraction x
135     
136     floor x             =  if r < 0 then n - 1 else n
137                            where (n,r) = properFraction x
138 \end{code}
139
140
141 These 'numeric' enumerations come straight from the Report
142
143 \begin{code}
144 numericEnumFrom         :: (Fractional a) => a -> [a]
145 numericEnumFrom         =  iterate (+1)
146
147 numericEnumFromThen     :: (Fractional a) => a -> a -> [a]
148 numericEnumFromThen n m =  iterate (+(m-n)) n
149
150 numericEnumFromTo       :: (Ord a, Fractional a) => a -> a -> [a]
151 numericEnumFromTo n m   = takeWhile (<= m + 1/2) (numericEnumFrom n)
152
153 numericEnumFromThenTo   :: (Ord a, Fractional a) => a -> a -> a -> [a]
154 numericEnumFromThenTo e1 e2 e3 = takeWhile pred (numericEnumFromThen e1 e2)
155                                 where
156                                  mid = (e2 - e1) / 2
157                                  pred | e2 > e1   = (<= e3 + mid)
158                                       | otherwise = (>= e3 + mid)
159 \end{code}
160
161
162 %*********************************************************
163 %*                                                      *
164 \subsection{Instances for @Int@}
165 %*                                                      *
166 %*********************************************************
167
168 \begin{code}
169 instance  Real Int  where
170     toRational x        =  toInteger x % 1
171
172 instance  Integral Int  where
173     toInteger i = int2Integer i  -- give back a full-blown Integer
174
175     a `quot` 0   = divZeroError
176     a `quot` b  =  a `quotInt` b
177
178     a `rem` 0   = divZeroError
179     a `rem` b   = a `remInt` b
180
181     a `div` 0   = divZeroError
182     a `div` b   = a `divInt` b
183
184     a `mod` 0   = divZeroError
185     a `mod` b   = a `modInt` b
186
187     a `quotRem` 0 = divZeroError
188     a `quotRem` b = a `quotRemInt` b
189
190     a `divMod`  0 = divZeroError
191     a `divMod`  b = a `divModInt`  b
192 \end{code}
193
194
195 %*********************************************************
196 %*                                                      *
197 \subsection{Instances for @Integer@}
198 %*                                                      *
199 %*********************************************************
200
201 \begin{code}
202 instance  Real Integer  where
203     toRational x        =  x % 1
204
205 instance  Integral Integer where
206     toInteger n      = n
207
208     a `quot` 0 = divZeroError
209     n `quot` d = n `quotInteger` d
210
211     a `rem` 0 = divZeroError
212     n `rem`  d = n `remInteger`  d
213
214     a `divMod` 0 = divZeroError
215     a `divMod` b = a `divModInteger` b
216
217     a `quotRem` 0 = divZeroError
218     a `quotRem` b = a `quotRemInteger` b
219
220     -- use the defaults for div & mod
221 \end{code}
222
223
224 %*********************************************************
225 %*                                                      *
226 \subsection{Instances for @Ratio@}
227 %*                                                      *
228 %*********************************************************
229
230 \begin{code}
231 instance  (Integral a)  => Ord (Ratio a)  where
232     {-# SPECIALIZE instance Ord Rational #-}
233     (x:%y) <= (x':%y')  =  x * y' <= x' * y
234     (x:%y) <  (x':%y')  =  x * y' <  x' * y
235
236 instance  (Integral a)  => Num (Ratio a)  where
237     {-# SPECIALIZE instance Num Rational #-}
238     (x:%y) + (x':%y')   =  reduce (x*y' + x'*y) (y*y')
239     (x:%y) - (x':%y')   =  reduce (x*y' - x'*y) (y*y')
240     (x:%y) * (x':%y')   =  reduce (x * x') (y * y')
241     negate (x:%y)       =  (-x) :% y
242     abs (x:%y)          =  abs x :% y
243     signum (x:%_)       =  signum x :% 1
244     fromInteger x       =  fromInteger x :% 1
245
246 instance  (Integral a)  => Fractional (Ratio a)  where
247     {-# SPECIALIZE instance Fractional Rational #-}
248     (x:%y) / (x':%y')   =  (x*y') % (y*x')
249     recip (x:%y)        =  y % x
250     fromRational (x:%y) =  fromInteger x :% fromInteger y
251
252 instance  (Integral a)  => Real (Ratio a)  where
253     {-# SPECIALIZE instance Real Rational #-}
254     toRational (x:%y)   =  toInteger x :% toInteger y
255
256 instance  (Integral a)  => RealFrac (Ratio a)  where
257     {-# SPECIALIZE instance RealFrac Rational #-}
258     properFraction (x:%y) = (fromInteger (toInteger q), r:%y)
259                           where (q,r) = quotRem x y
260
261 instance  (Integral a)  => Show (Ratio a)  where
262     {-# SPECIALIZE instance Show Rational #-}
263     showsPrec p (x:%y)  =  showParen (p > ratioPrec) $
264                            showsPrec ratioPrec1 x . 
265                            showString " % " . 
266                            showsPrec ratioPrec1 y
267
268 instance  (Integral a)  => Enum (Ratio a)  where
269     {-# SPECIALIZE instance Enum Rational #-}
270     succ x              =  x + 1
271     pred x              =  x - 1
272
273     toEnum n            =  fromInteger (int2Integer n) :% 1
274     fromEnum            =  fromInteger . truncate
275
276     enumFrom            =  numericEnumFrom
277     enumFromThen        =  numericEnumFromThen
278     enumFromTo          =  numericEnumFromTo
279     enumFromThenTo      =  numericEnumFromThenTo
280 \end{code}
281
282
283 %*********************************************************
284 %*                                                      *
285 \subsection{Coercions}
286 %*                                                      *
287 %*********************************************************
288
289 \begin{code}
290 fromIntegral :: (Integral a, Num b) => a -> b
291 fromIntegral = fromInteger . toInteger
292
293 {-# RULES
294 "fromIntegral/Int->Int" fromIntegral = id :: Int -> Int
295     #-}
296
297 realToFrac :: (Real a, Fractional b) => a -> b
298 realToFrac = fromRational . toRational
299
300 {-# RULES
301 "realToFrac/Int->Int" realToFrac = id :: Int -> Int
302     #-}
303 \end{code}
304
305 %*********************************************************
306 %*                                                      *
307 \subsection{Overloaded numeric functions}
308 %*                                                      *
309 %*********************************************************
310
311 \begin{code}
312 showSigned :: (Real a) => (a -> ShowS) -> Int -> a -> ShowS
313 showSigned showPos p x 
314    | x < 0     = showParen (p > 6) (showChar '-' . showPos (-x))
315    | otherwise = showPos x
316
317 even, odd       :: (Integral a) => a -> Bool
318 even n          =  n `rem` 2 == 0
319 odd             =  not . even
320
321 -------------------------------------------------------
322 {-# SPECIALISE (^) ::
323         Integer -> Integer -> Integer,
324         Integer -> Int -> Integer,
325         Int -> Int -> Int #-}
326 (^)             :: (Num a, Integral b) => a -> b -> a
327 _ ^ 0           =  1
328 x ^ n | n > 0   =  f x (n-1) x
329                    where f _ 0 y = y
330                          f a d y = g a d  where
331                                    g b i | even i  = g (b*b) (i `quot` 2)
332                                          | otherwise = f b (i-1) (b*y)
333 _ ^ _           = error "Prelude.^: negative exponent"
334
335 {-# SPECIALISE (^^) ::
336         Rational -> Int -> Rational #-}
337 (^^)            :: (Fractional a, Integral b) => a -> b -> a
338 x ^^ n          =  if n >= 0 then x^n else recip (x^(negate n))
339
340
341 -------------------------------------------------------
342 gcd             :: (Integral a) => a -> a -> a
343 gcd 0 0         =  error "Prelude.gcd: gcd 0 0 is undefined"
344 gcd x y         =  gcd' (abs x) (abs y)
345                    where gcd' a 0  =  a
346                          gcd' a b  =  gcd' b (a `rem` b)
347
348 lcm             :: (Integral a) => a -> a -> a
349 {-# SPECIALISE lcm :: Int -> Int -> Int #-}
350 lcm _ 0         =  0
351 lcm 0 _         =  0
352 lcm x y         =  abs ((x `quot` (gcd x y)) * y)
353
354
355 {-# RULES
356 "gcd/Int->Int->Int"             gcd = gcdInt
357 "gcd/Integer->Integer->Integer" gcd = gcdInteger
358 "lcm/Integer->Integer->Integer" lcm = lcmInteger
359  #-}
360
361 integralEnumFrom :: (Integral a, Bounded a) => a -> [a]
362 integralEnumFrom n = map fromInteger [toInteger n .. toInteger (maxBound `asTypeOf` n)]
363
364 integralEnumFromThen :: (Integral a, Bounded a) => a -> a -> [a]
365 integralEnumFromThen n1 n2
366   | i_n2 >= i_n1  = map fromInteger [i_n1, i_n2 .. toInteger (maxBound `asTypeOf` n1)]
367   | otherwise     = map fromInteger [i_n1, i_n2 .. toInteger (minBound `asTypeOf` n1)]
368   where
369     i_n1 = toInteger n1
370     i_n2 = toInteger n2
371
372 integralEnumFromTo :: Integral a => a -> a -> [a]
373 integralEnumFromTo n m = map fromInteger [toInteger n .. toInteger m]
374
375 integralEnumFromThenTo :: Integral a => a -> a -> a -> [a]
376 integralEnumFromThenTo n1 n2 m
377   = map fromInteger [toInteger n1, toInteger n2 .. toInteger m]
378 \end{code}