Update use of role annotations to new syntax.
[packages/base.git] / configure.ac
1 AC_INIT([Haskell base package], [1.0], [libraries@haskell.org], [base])
2
3 # Safety check: Ensure that we are in the correct source directory.
4 AC_CONFIG_SRCDIR([include/HsBase.h])
5
6 AC_CONFIG_HEADERS([include/HsBaseConfig.h include/EventConfig.h])
7
8 AC_CANONICAL_BUILD
9 AC_CANONICAL_HOST
10 AC_CANONICAL_TARGET
11
12 AC_ARG_WITH([cc],
13             [C compiler],
14             [CC=$withval])
15 AC_PROG_CC()
16
17 AC_MSG_CHECKING(for WINDOWS platform)
18 case $host in
19     *mingw32*|*cygwin*)
20         WINDOWS=YES;;
21     *)
22         WINDOWS=NO;;
23 esac
24 AC_MSG_RESULT($WINDOWS)
25
26 # do we have long longs?
27 AC_CHECK_TYPES([long long])
28
29 dnl ** check for full ANSI header (.h) files
30 AC_HEADER_STDC
31
32 # check for specific header (.h) files that we are interested in
33 AC_CHECK_HEADERS([ctype.h errno.h fcntl.h inttypes.h limits.h signal.h sys/resource.h sys/select.h sys/stat.h sys/syscall.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/types.h sys/utsname.h sys/wait.h termios.h time.h unistd.h utime.h windows.h winsock.h langinfo.h poll.h sys/epoll.h sys/event.h sys/eventfd.h])
34
35 # Enable large file support. Do this before testing the types ino_t, off_t, and
36 # rlim_t, because it will affect the result of that test.
37 AC_SYS_LARGEFILE
38
39 dnl ** check for wide-char classifications
40 dnl FreeBSD has an emtpy wctype.h, so test one of the affected
41 dnl functions if it's really there.
42 AC_CHECK_HEADERS([wctype.h], [AC_CHECK_FUNCS(iswspace)])
43
44 AC_CHECK_FUNCS([lstat])
45 AC_CHECK_LIB([rt], [clock_gettime])
46 AC_CHECK_FUNCS([clock_gettime])
47 AC_CHECK_FUNCS([getclock getrusage times])
48 AC_CHECK_FUNCS([_chsize ftruncate])
49
50 AC_CHECK_FUNCS([epoll_ctl eventfd kevent kevent64 kqueue poll])
51
52 # event-related fun
53
54 if test "$ac_cv_header_sys_epoll_h" = yes -a "$ac_cv_func_epoll_ctl" = yes; then
55   AC_DEFINE([HAVE_EPOLL], [1], [Define if you have epoll support.])
56 fi
57
58 if test "$ac_cv_header_sys_event_h" = yes -a "$ac_cv_func_kqueue" = yes; then
59   AC_DEFINE([HAVE_KQUEUE], [1], [Define if you have kqueue support.])
60
61   AC_CHECK_SIZEOF([kev.filter], [], [#include <sys/event.h>
62 struct kevent kev;])
63
64   AC_CHECK_SIZEOF([kev.flags], [], [#include <sys/event.h>
65 struct kevent kev;])
66 fi
67
68 if test "$ac_cv_header_poll_h" = yes -a "$ac_cv_func_poll" = yes; then
69   AC_DEFINE([HAVE_POLL], [1], [Define if you have poll support.])
70 fi
71
72 # unsetenv
73 AC_CHECK_FUNCS([unsetenv])
74
75 ###  POSIX.1003.1 unsetenv returns 0 or -1 (EINVAL), but older implementations
76 ###  in common use return void.
77 AC_CACHE_CHECK([return type of unsetenv], fptools_cv_func_unsetenv_return_type,
78   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+unsetenv>changequote([, ]),
79                    stdlib.h,
80                    [fptools_cv_func_unsetenv_return_type=void],
81                    [fptools_cv_func_unsetenv_return_type=int])])
82 case "$fptools_cv_func_unsetenv_return_type" in
83   "void" )
84     AC_DEFINE([UNSETENV_RETURNS_VOID], [1], [Define if stdlib.h declares unsetenv to return void.])
85   ;;
86 esac
87
88 dnl--------------------------------------------------------------------
89 dnl * Deal with arguments telling us iconv is somewhere odd
90 dnl--------------------------------------------------------------------
91
92 AC_ARG_WITH([iconv-includes],
93   [AC_HELP_STRING([--with-iconv-includes],
94     [directory containing iconv.h])],
95     [ICONV_INCLUDE_DIRS=$withval; CPPFLAGS="-I$withval"],
96     [ICONV_INCLUDE_DIRS=])
97
98 AC_ARG_WITH([iconv-libraries],
99   [AC_HELP_STRING([--with-iconv-libraries],
100     [directory containing iconv library])],
101     [ICONV_LIB_DIRS=$withval; LDFLAGS="-L$withval"],
102     [ICONV_LIB_DIRS=])
103
104 AC_SUBST(ICONV_INCLUDE_DIRS)
105 AC_SUBST(ICONV_LIB_DIRS)
106
107 # map standard C types and ISO types to Haskell types
108 FPTOOLS_CHECK_HTYPE(char)
109 FPTOOLS_CHECK_HTYPE(signed char)
110 FPTOOLS_CHECK_HTYPE(unsigned char)
111 FPTOOLS_CHECK_HTYPE(short)
112 FPTOOLS_CHECK_HTYPE(unsigned short)
113 FPTOOLS_CHECK_HTYPE(int)
114 FPTOOLS_CHECK_HTYPE(unsigned int)
115 FPTOOLS_CHECK_HTYPE(long)
116 FPTOOLS_CHECK_HTYPE(unsigned long)
117 if test "$ac_cv_type_long_long" = yes; then
118 FPTOOLS_CHECK_HTYPE(long long)
119 FPTOOLS_CHECK_HTYPE(unsigned long long)
120 fi
121 FPTOOLS_CHECK_HTYPE(float)
122 FPTOOLS_CHECK_HTYPE(double)
123 FPTOOLS_CHECK_HTYPE(ptrdiff_t)
124 FPTOOLS_CHECK_HTYPE(size_t)
125 FPTOOLS_CHECK_HTYPE(wchar_t)
126 FPTOOLS_CHECK_HTYPE(sig_atomic_t)
127 FPTOOLS_CHECK_HTYPE(clock_t)
128 FPTOOLS_CHECK_HTYPE(time_t)
129 FPTOOLS_CHECK_HTYPE(useconds_t)
130 FPTOOLS_CHECK_HTYPE_ELSE(suseconds_t,
131                          [if test "$WINDOWS" = "YES"
132                           then
133                               AC_CV_NAME=Int32
134                               AC_CV_NAME_supported=yes
135                           else
136                               AC_MSG_ERROR([type not found])
137                           fi])
138 FPTOOLS_CHECK_HTYPE(dev_t)
139 FPTOOLS_CHECK_HTYPE(ino_t)
140 FPTOOLS_CHECK_HTYPE(mode_t)
141 FPTOOLS_CHECK_HTYPE(off_t)
142 FPTOOLS_CHECK_HTYPE(pid_t)
143 FPTOOLS_CHECK_HTYPE(gid_t)
144 FPTOOLS_CHECK_HTYPE(uid_t)
145 FPTOOLS_CHECK_HTYPE(cc_t)
146 FPTOOLS_CHECK_HTYPE(speed_t)
147 FPTOOLS_CHECK_HTYPE(tcflag_t)
148 FPTOOLS_CHECK_HTYPE(nlink_t)
149 FPTOOLS_CHECK_HTYPE(ssize_t)
150 FPTOOLS_CHECK_HTYPE(rlim_t)
151
152 FPTOOLS_CHECK_HTYPE(intptr_t)
153 FPTOOLS_CHECK_HTYPE(uintptr_t)
154 FPTOOLS_CHECK_HTYPE(intmax_t)
155 FPTOOLS_CHECK_HTYPE(uintmax_t)
156
157 # test errno values
158 FP_CHECK_CONSTS([E2BIG EACCES EADDRINUSE EADDRNOTAVAIL EADV EAFNOSUPPORT EAGAIN EALREADY EBADF EBADMSG EBADRPC EBUSY ECHILD ECOMM ECONNABORTED ECONNREFUSED ECONNRESET EDEADLK EDESTADDRREQ EDIRTY EDOM EDQUOT EEXIST EFAULT EFBIG EFTYPE EHOSTDOWN EHOSTUNREACH EIDRM EILSEQ EINPROGRESS EINTR EINVAL EIO EISCONN EISDIR ELOOP EMFILE EMLINK EMSGSIZE EMULTIHOP ENAMETOOLONG ENETDOWN ENETRESET ENETUNREACH ENFILE ENOBUFS ENODATA ENODEV ENOENT ENOEXEC ENOLCK ENOLINK ENOMEM ENOMSG ENONET ENOPROTOOPT ENOSPC ENOSR ENOSTR ENOSYS ENOTBLK ENOTCONN ENOTDIR ENOTEMPTY ENOTSOCK ENOTTY ENXIO EOPNOTSUPP EPERM EPFNOSUPPORT EPIPE EPROCLIM EPROCUNAVAIL EPROGMISMATCH EPROGUNAVAIL EPROTO EPROTONOSUPPORT EPROTOTYPE ERANGE EREMCHG EREMOTE EROFS ERPCMISMATCH ERREMOTE ESHUTDOWN ESOCKTNOSUPPORT ESPIPE ESRCH ESRMNT ESTALE ETIME ETIMEDOUT ETOOMANYREFS ETXTBSY EUSERS EWOULDBLOCK EXDEV ENOCIGAR ENOTSUP], [#include <stdio.h>
159 #include <errno.h>])
160
161 # we need SIGINT in TopHandler.lhs
162 FP_CHECK_CONSTS([SIGINT], [
163 #if HAVE_SIGNAL_H
164 #include <signal.h>
165 #endif])
166
167 dnl ** can we open files in binary mode?
168 FP_CHECK_CONST([O_BINARY], [#include <fcntl.h>], [0])
169
170 # We don't use iconv or libcharset on Windows, but if configure finds
171 # them then it can cause problems. So we don't even try looking if
172 # we are on Windows.
173 # See http://www.haskell.org/pipermail/cvs-ghc/2011-September/065980.html
174 if test "$WINDOWS" = "NO"
175 then
176
177 # We can't just use AC_SEARCH_LIBS for this, as on OpenBSD the iconv.h
178 # header needs to be included as iconv_open is #define'd to something
179 # else. We therefore use our own FP_SEARCH_LIBS_PROTO, which allows us
180 # to give prototype text.
181 FP_SEARCH_LIBS_PROTO(iconv,
182                      [
183 #include <stddef.h>
184 #include <iconv.h>
185                       ],
186                      [iconv_t cd;
187                       cd = iconv_open("", "");
188                       iconv(cd,NULL,NULL,NULL,NULL);
189                       iconv_close(cd);],
190                      iconv,
191                      [EXTRA_LIBS="$EXTRA_LIBS $ac_lib"],
192                      [AC_MSG_ERROR([iconv is required on non-Windows platforms])])
193
194 # If possible, we use libcharset instead of nl_langinfo(CODESET) to
195 # determine the current locale's character encoding.
196 FP_SEARCH_LIBS_PROTO(
197     [locale_charset],
198     [#include <libcharset.h>],
199     [const char* charset = locale_charset();],
200     [charset],
201     [AC_DEFINE([HAVE_LIBCHARSET], [1], [Define to 1 if you have libcharset.])
202      EXTRA_LIBS="$EXTRA_LIBS $ac_lib"])
203
204 fi
205
206 # Hack - md5.h needs HsFFI.h.  Is there a better way to do this?
207 CFLAGS="-I../../includes $CFLAGS"
208 AC_CHECK_SIZEOF([struct MD5Context], ,[#include "include/md5.h"])
209
210 AC_SUBST(EXTRA_LIBS)
211 AC_CONFIG_FILES([base.buildinfo])
212
213 AC_OUTPUT