Change a use of atomicModifyIORef to atomicModifyIORef'
[packages/base.git] / configure.ac
1 AC_INIT([Haskell base package], [1.0], [libraries@haskell.org], [base])
2
3 # Safety check: Ensure that we are in the correct source directory.
4 AC_CONFIG_SRCDIR([include/HsBase.h])
5
6 AC_CONFIG_HEADERS([include/HsBaseConfig.h include/EventConfig.h])
7
8 AC_CANONICAL_BUILD
9 AC_CANONICAL_HOST
10 AC_CANONICAL_TARGET
11
12 AC_ARG_WITH([cc],
13             [C compiler],
14             [CC=$withval])
15 AC_PROG_CC()
16
17 AC_MSG_CHECKING(for WINDOWS platform)
18 case $host in
19     *mingw32*|*cygwin*)
20         WINDOWS=YES;;
21     *)
22         WINDOWS=NO;;
23 esac
24 AC_MSG_RESULT($WINDOWS)
25
26 # do we have long longs?
27 AC_CHECK_TYPES([long long])
28
29 dnl ** check for full ANSI header (.h) files
30 AC_HEADER_STDC
31
32 # check for specific header (.h) files that we are interested in
33 AC_CHECK_HEADERS([ctype.h errno.h fcntl.h inttypes.h limits.h signal.h sys/resource.h sys/select.h sys/stat.h sys/syscall.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/types.h sys/utsname.h sys/wait.h termios.h time.h unistd.h utime.h windows.h winsock.h langinfo.h poll.h sys/epoll.h sys/event.h sys/eventfd.h])
34
35 # Enable large file support. Do this before testing the types ino_t, off_t, and
36 # rlim_t, because it will affect the result of that test.
37 AC_SYS_LARGEFILE
38
39 dnl ** check for wide-char classifications
40 dnl FreeBSD has an emtpy wctype.h, so test one of the affected
41 dnl functions if it's really there.
42 AC_CHECK_HEADERS([wctype.h], [AC_CHECK_FUNCS(iswspace)])
43
44 AC_CHECK_FUNCS([lstat])
45 AC_CHECK_LIB([rt], [clock_gettime])
46 AC_CHECK_FUNCS([clock_gettime])
47 AC_CHECK_FUNCS([getclock getrusage times])
48 AC_CHECK_FUNCS([_chsize ftruncate])
49
50 AC_CHECK_FUNCS([epoll_ctl eventfd kevent kevent64 kqueue poll])
51
52 # event-related fun
53
54 if test "$ac_cv_header_sys_epoll_h" = yes -a "$ac_cv_func_epoll_ctl" = yes; then
55   AC_DEFINE([HAVE_EPOLL], [1], [Define if you have epoll support.])
56 fi
57
58 if test "$ac_cv_header_sys_event_h" = yes -a "$ac_cv_func_kqueue" = yes; then
59   AC_DEFINE([HAVE_KQUEUE], [1], [Define if you have kqueue support.])
60
61   AC_CHECK_SIZEOF([kev.filter], [], [#include <sys/event.h>
62 struct kevent kev;])
63
64   AC_CHECK_SIZEOF([kev.flags], [], [#include <sys/event.h>
65 struct kevent kev;])
66 fi
67
68 if test "$ac_cv_header_poll_h" = yes -a "$ac_cv_func_poll" = yes; then
69   AC_DEFINE([HAVE_POLL], [1], [Define if you have poll support.])
70 fi
71
72 dnl--------------------------------------------------------------------
73 dnl * Deal with arguments telling us iconv is somewhere odd
74 dnl--------------------------------------------------------------------
75
76 AC_ARG_WITH([iconv-includes],
77   [AC_HELP_STRING([--with-iconv-includes],
78     [directory containing iconv.h])],
79     [ICONV_INCLUDE_DIRS=$withval; CPPFLAGS="-I$withval"],
80     [ICONV_INCLUDE_DIRS=])
81
82 AC_ARG_WITH([iconv-libraries],
83   [AC_HELP_STRING([--with-iconv-libraries],
84     [directory containing iconv library])],
85     [ICONV_LIB_DIRS=$withval; LDFLAGS="-L$withval"],
86     [ICONV_LIB_DIRS=])
87
88 AC_SUBST(ICONV_INCLUDE_DIRS)
89 AC_SUBST(ICONV_LIB_DIRS)
90
91 # map standard C types and ISO types to Haskell types
92 FPTOOLS_CHECK_HTYPE(char)
93 FPTOOLS_CHECK_HTYPE(signed char)
94 FPTOOLS_CHECK_HTYPE(unsigned char)
95 FPTOOLS_CHECK_HTYPE(short)
96 FPTOOLS_CHECK_HTYPE(unsigned short)
97 FPTOOLS_CHECK_HTYPE(int)
98 FPTOOLS_CHECK_HTYPE(unsigned int)
99 FPTOOLS_CHECK_HTYPE(long)
100 FPTOOLS_CHECK_HTYPE(unsigned long)
101 if test "$ac_cv_type_long_long" = yes; then
102 FPTOOLS_CHECK_HTYPE(long long)
103 FPTOOLS_CHECK_HTYPE(unsigned long long)
104 fi
105 FPTOOLS_CHECK_HTYPE(float)
106 FPTOOLS_CHECK_HTYPE(double)
107 FPTOOLS_CHECK_HTYPE(ptrdiff_t)
108 FPTOOLS_CHECK_HTYPE(size_t)
109 FPTOOLS_CHECK_HTYPE(wchar_t)
110 FPTOOLS_CHECK_HTYPE(sig_atomic_t)
111 FPTOOLS_CHECK_HTYPE(clock_t)
112 FPTOOLS_CHECK_HTYPE(time_t)
113 FPTOOLS_CHECK_HTYPE(useconds_t)
114 FPTOOLS_CHECK_HTYPE_ELSE(suseconds_t,
115                          [if test "$WINDOWS" = "YES"
116                           then
117                               AC_CV_NAME=Int32
118                               AC_CV_NAME_supported=yes
119                           else
120                               AC_MSG_ERROR([type not found])
121                           fi])
122 FPTOOLS_CHECK_HTYPE(dev_t)
123 FPTOOLS_CHECK_HTYPE(ino_t)
124 FPTOOLS_CHECK_HTYPE(mode_t)
125 FPTOOLS_CHECK_HTYPE(off_t)
126 FPTOOLS_CHECK_HTYPE(pid_t)
127 FPTOOLS_CHECK_HTYPE(gid_t)
128 FPTOOLS_CHECK_HTYPE(uid_t)
129 FPTOOLS_CHECK_HTYPE(cc_t)
130 FPTOOLS_CHECK_HTYPE(speed_t)
131 FPTOOLS_CHECK_HTYPE(tcflag_t)
132 FPTOOLS_CHECK_HTYPE(nlink_t)
133 FPTOOLS_CHECK_HTYPE(ssize_t)
134 FPTOOLS_CHECK_HTYPE(rlim_t)
135
136 FPTOOLS_CHECK_HTYPE(intptr_t)
137 FPTOOLS_CHECK_HTYPE(uintptr_t)
138 FPTOOLS_CHECK_HTYPE(intmax_t)
139 FPTOOLS_CHECK_HTYPE(uintmax_t)
140
141 # test errno values
142 FP_CHECK_CONSTS([E2BIG EACCES EADDRINUSE EADDRNOTAVAIL EADV EAFNOSUPPORT EAGAIN EALREADY EBADF EBADMSG EBADRPC EBUSY ECHILD ECOMM ECONNABORTED ECONNREFUSED ECONNRESET EDEADLK EDESTADDRREQ EDIRTY EDOM EDQUOT EEXIST EFAULT EFBIG EFTYPE EHOSTDOWN EHOSTUNREACH EIDRM EILSEQ EINPROGRESS EINTR EINVAL EIO EISCONN EISDIR ELOOP EMFILE EMLINK EMSGSIZE EMULTIHOP ENAMETOOLONG ENETDOWN ENETRESET ENETUNREACH ENFILE ENOBUFS ENODATA ENODEV ENOENT ENOEXEC ENOLCK ENOLINK ENOMEM ENOMSG ENONET ENOPROTOOPT ENOSPC ENOSR ENOSTR ENOSYS ENOTBLK ENOTCONN ENOTDIR ENOTEMPTY ENOTSOCK ENOTTY ENXIO EOPNOTSUPP EPERM EPFNOSUPPORT EPIPE EPROCLIM EPROCUNAVAIL EPROGMISMATCH EPROGUNAVAIL EPROTO EPROTONOSUPPORT EPROTOTYPE ERANGE EREMCHG EREMOTE EROFS ERPCMISMATCH ERREMOTE ESHUTDOWN ESOCKTNOSUPPORT ESPIPE ESRCH ESRMNT ESTALE ETIME ETIMEDOUT ETOOMANYREFS ETXTBSY EUSERS EWOULDBLOCK EXDEV ENOCIGAR ENOTSUP], [#include <stdio.h>
143 #include <errno.h>])
144
145 # we need SIGINT in TopHandler.lhs
146 FP_CHECK_CONSTS([SIGINT], [
147 #if HAVE_SIGNAL_H
148 #include <signal.h>
149 #endif])
150
151 dnl ** can we open files in binary mode?
152 FP_CHECK_CONST([O_BINARY], [#include <fcntl.h>], [0])
153
154 # We don't use iconv or libcharset on Windows, but if configure finds
155 # them then it can cause problems. So we don't even try looking if
156 # we are on Windows.
157 # See http://www.haskell.org/pipermail/cvs-ghc/2011-September/065980.html
158 if test "$WINDOWS" = "NO"
159 then
160
161 # We can't just use AC_SEARCH_LIBS for this, as on OpenBSD the iconv.h
162 # header needs to be included as iconv_open is #define'd to something
163 # else. We therefore use our own FP_SEARCH_LIBS_PROTO, which allows us
164 # to give prototype text.
165 FP_SEARCH_LIBS_PROTO(iconv,
166                      [
167 #include <stddef.h>
168 #include <iconv.h>
169                       ],
170                      [iconv_t cd;
171                       cd = iconv_open("", "");
172                       iconv(cd,NULL,NULL,NULL,NULL);
173                       iconv_close(cd);],
174                      iconv,
175                      [EXTRA_LIBS="$EXTRA_LIBS $ac_lib"],
176                      [AC_MSG_ERROR([iconv is required on non-Windows platforms])])
177
178 # If possible, we use libcharset instead of nl_langinfo(CODESET) to
179 # determine the current locale's character encoding.
180 FP_SEARCH_LIBS_PROTO(
181     [locale_charset],
182     [#include <libcharset.h>],
183     [const char* charset = locale_charset();],
184     [charset],
185     [AC_DEFINE([HAVE_LIBCHARSET], [1], [Define to 1 if you have libcharset.])
186      EXTRA_LIBS="$EXTRA_LIBS $ac_lib"])
187
188 fi
189
190 # Hack - md5.h needs HsFFI.h.  Is there a better way to do this?
191 CFLAGS="-I../../includes $CFLAGS"
192 AC_CHECK_SIZEOF([struct MD5Context], ,[#include "include/md5.h"])
193
194 AC_SUBST(EXTRA_LIBS)
195 AC_CONFIG_FILES([base.buildinfo])
196
197 AC_OUTPUT