[project @ 2002-09-18 11:32:43 by simonmar]
[packages/base.git] / GHC / Num.lhs
1 \begin{code}
2 {-# OPTIONS -fno-implicit-prelude #-}
3 -----------------------------------------------------------------------------
4 -- |
5 -- Module      :  GHC.Num
6 -- Copyright   :  (c) The University of Glasgow 1994-2002
7 -- License     :  see libraries/base/LICENSE
8 -- 
9 -- Maintainer  :  cvs-ghc@haskell.org
10 -- Stability   :  internal
11 -- Portability :  non-portable (GHC Extensions)
12 --
13 -- The 'Num' class and the 'Integer' type.
14 --
15 -----------------------------------------------------------------------------
16
17 #include "MachDeps.h"
18 #if SIZEOF_HSWORD == 4
19 #define LEFTMOST_BIT 2147483648
20 #elif SIZEOF_HSWORD == 8
21 #define LEFTMOST_BIT 9223372036854775808
22 #else
23 #error Please define LEFTMOST_BIT to be 2^(SIZEOF_HSWORD*8-1)
24 #endif
25
26 module GHC.Num where
27
28 import {-# SOURCE #-} GHC.Err
29 import GHC.Base
30 import GHC.List
31 import GHC.Enum
32 import GHC.Show
33
34 infixl 7  *
35 infixl 6  +, -
36
37 default ()              -- Double isn't available yet, 
38                         -- and we shouldn't be using defaults anyway
39 \end{code}
40
41 %*********************************************************
42 %*                                                      *
43 \subsection{Standard numeric class}
44 %*                                                      *
45 %*********************************************************
46
47 \begin{code}
48 class  (Eq a, Show a) => Num a  where
49     (+), (-), (*)       :: a -> a -> a
50     negate              :: a -> a
51     abs, signum         :: a -> a
52     fromInteger         :: Integer -> a
53
54     x - y               = x + negate y
55     negate x            = 0 - x
56
57 {-# INLINE subtract #-}
58 subtract :: (Num a) => a -> a -> a
59 subtract x y = y - x
60 \end{code}
61
62
63 %*********************************************************
64 %*                                                      *
65 \subsection{Instances for @Int@}
66 %*                                                      *
67 %*********************************************************
68
69 \begin{code}
70 instance  Num Int  where
71     (+)    = plusInt
72     (-)    = minusInt
73     negate = negateInt
74     (*)    = timesInt
75     abs n  = if n `geInt` 0 then n else negateInt n
76
77     signum n | n `ltInt` 0 = negateInt 1
78              | n `eqInt` 0 = 0
79              | otherwise   = 1
80
81     fromInteger = integer2Int
82
83 quotRemInt :: Int -> Int -> (Int, Int)
84 quotRemInt a@(I# _) b@(I# _) = (a `quotInt` b, a `remInt` b)
85     -- OK, so I made it a little stricter.  Shoot me.  (WDP 94/10)
86
87 divModInt ::  Int -> Int -> (Int, Int)
88 divModInt x@(I# _) y@(I# _) = (x `divInt` y, x `modInt` y)
89     -- Stricter.  Sorry if you don't like it.  (WDP 94/10)
90 \end{code}
91
92 %*********************************************************
93 %*                                                      *
94 \subsection{The @Integer@ type}
95 %*                                                      *
96 %*********************************************************
97
98 \begin{code}
99 -- | Arbitrary-precision integers.
100 data Integer    
101    = S# Int#                            -- small integers
102 #ifndef ILX
103    | J# Int# ByteArray#                 -- large integers
104 #else
105    | J# Void BigInteger                 -- .NET big ints
106
107 foreign type dotnet "BigInteger" BigInteger
108 #endif
109 \end{code}
110
111 Convenient boxed Integer PrimOps. 
112
113 \begin{code}
114 zeroInteger :: Integer
115 zeroInteger = S# 0#
116
117 int2Integer :: Int -> Integer
118 {-# INLINE int2Integer #-}
119 int2Integer (I# i) = S# i
120
121 integer2Int :: Integer -> Int
122 integer2Int (S# i)   = I# i
123 integer2Int (J# s d) = case (integer2Int# s d) of { n# -> I# n# }
124
125 toBig (S# i)     = case int2Integer# i of { (# s, d #) -> J# s d }
126 toBig i@(J# _ _) = i
127 \end{code}
128
129
130 %*********************************************************
131 %*                                                      *
132 \subsection{Dividing @Integers@}
133 %*                                                      *
134 %*********************************************************
135
136 \begin{code}
137 quotRemInteger :: Integer -> Integer -> (Integer, Integer)
138 quotRemInteger a@(S# (-LEFTMOST_BIT#)) b = quotRemInteger (toBig a) b
139 quotRemInteger (S# i) (S# j)
140   = case quotRemInt (I# i) (I# j) of ( I# i, I# j ) -> ( S# i, S# j ) 
141 quotRemInteger i1@(J# _ _) i2@(S# _) = quotRemInteger i1 (toBig i2)
142 quotRemInteger i1@(S# _) i2@(J# _ _) = quotRemInteger (toBig i1) i2
143 quotRemInteger (J# s1 d1) (J# s2 d2)
144   = case (quotRemInteger# s1 d1 s2 d2) of
145           (# s3, d3, s4, d4 #)
146             -> (J# s3 d3, J# s4 d4)
147
148 divModInteger a@(S# (-LEFTMOST_BIT#)) b = divModInteger (toBig a) b
149 divModInteger (S# i) (S# j)
150   = case divModInt (I# i) (I# j) of ( I# i, I# j ) -> ( S# i, S# j) 
151 divModInteger i1@(J# _ _) i2@(S# _) = divModInteger i1 (toBig i2)
152 divModInteger i1@(S# _) i2@(J# _ _) = divModInteger (toBig i1) i2
153 divModInteger (J# s1 d1) (J# s2 d2)
154   = case (divModInteger# s1 d1 s2 d2) of
155           (# s3, d3, s4, d4 #)
156             -> (J# s3 d3, J# s4 d4)
157
158 remInteger :: Integer -> Integer -> Integer
159 remInteger ia 0
160   = error "Prelude.Integral.rem{Integer}: divide by 0"
161 remInteger a@(S# (-LEFTMOST_BIT#)) b = remInteger (toBig a) b
162 remInteger (S# a) (S# b) = S# (remInt# a b)
163 {- Special case doesn't work, because a 1-element J# has the range
164    -(2^32-1) -- 2^32-1, whereas S# has the range -2^31 -- (2^31-1)
165 remInteger ia@(S# a) (J# sb b)
166   | sb ==# 1#  = S# (remInt# a (word2Int# (integer2Word# sb b)))
167   | sb ==# -1# = S# (remInt# a (0# -# (word2Int# (integer2Word# sb b))))
168   | 0# <# sb   = ia
169   | otherwise  = S# (0# -# a)
170 -}
171 remInteger ia@(S# _) ib@(J# _ _) = remInteger (toBig ia) ib
172 remInteger (J# sa a) (S# b)
173   = case int2Integer# b of { (# sb, b #) ->
174     case remInteger# sa a sb b of { (# sr, r #) ->
175     S# (integer2Int# sr r) }}
176 remInteger (J# sa a) (J# sb b)
177   = case remInteger# sa a sb b of (# sr, r #) -> J# sr r
178
179 quotInteger :: Integer -> Integer -> Integer
180 quotInteger ia 0
181   = error "Prelude.Integral.quot{Integer}: divide by 0"
182 quotInteger a@(S# (-LEFTMOST_BIT#)) b = quotInteger (toBig a) b
183 quotInteger (S# a) (S# b) = S# (quotInt# a b)
184 {- Special case disabled, see remInteger above
185 quotInteger (S# a) (J# sb b)
186   | sb ==# 1#  = S# (quotInt# a (word2Int# (integer2Word# sb b)))
187   | sb ==# -1# = S# (quotInt# a (0# -# (word2Int# (integer2Word# sb b))))
188   | otherwise  = zeroInteger
189 -}
190 quotInteger ia@(S# _) ib@(J# _ _) = quotInteger (toBig ia) ib
191 quotInteger (J# sa a) (S# b)
192   = case int2Integer# b of { (# sb, b #) ->
193     case quotInteger# sa a sb b of (# sq, q #) -> J# sq q }
194 quotInteger (J# sa a) (J# sb b)
195   = case quotInteger# sa a sb b of (# sg, g #) -> J# sg g
196 \end{code}
197
198
199
200 \begin{code}
201 gcdInteger :: Integer -> Integer -> Integer
202 -- SUP: Do we really need the first two cases?
203 gcdInteger a@(S# (-LEFTMOST_BIT#)) b = gcdInteger (toBig a) b
204 gcdInteger a b@(S# (-LEFTMOST_BIT#)) = gcdInteger a (toBig b)
205 gcdInteger (S# a) (S# b) = case gcdInt (I# a) (I# b) of { I# c -> S# c }
206 gcdInteger ia@(S# 0#) ib@(J# 0# _) = error "GHC.Num.gcdInteger: gcd 0 0 is undefined"
207 gcdInteger ia@(S# a)  ib@(J# sb b)
208   | a  ==# 0#  = abs ib
209   | sb ==# 0#  = abs ia
210   | otherwise  = S# (gcdIntegerInt# absSb b absA)
211        where absA  = if a  <# 0# then negateInt# a  else a
212              absSb = if sb <# 0# then negateInt# sb else sb
213 gcdInteger ia@(J# _ _) ib@(S# _) = gcdInteger ib ia
214 gcdInteger (J# 0# _) (J# 0# _) = error "GHC.Num.gcdInteger: gcd 0 0 is undefined"
215 gcdInteger (J# sa a) (J# sb b)
216   = case gcdInteger# sa a sb b of (# sg, g #) -> J# sg g
217
218 lcmInteger :: Integer -> Integer -> Integer
219 lcmInteger a 0
220   = zeroInteger
221 lcmInteger 0 b
222   = zeroInteger
223 lcmInteger a b
224   = (divExact aa (gcdInteger aa ab)) * ab
225   where aa = abs a
226         ab = abs b
227
228 divExact :: Integer -> Integer -> Integer
229 divExact a@(S# (-LEFTMOST_BIT#)) b = divExact (toBig a) b
230 divExact (S# a) (S# b) = S# (quotInt# a b)
231 divExact (S# a) (J# sb b)
232   = S# (quotInt# a (integer2Int# sb b))
233 divExact (J# sa a) (S# b)
234   = case int2Integer# b of
235      (# sb, b #) -> case divExactInteger# sa a sb b of (# sd, d #) -> J# sd d
236 divExact (J# sa a) (J# sb b)
237   = case divExactInteger# sa a sb b of (# sd, d #) -> J# sd d
238 \end{code}
239
240
241 %*********************************************************
242 %*                                                      *
243 \subsection{The @Integer@ instances for @Eq@, @Ord@}
244 %*                                                      *
245 %*********************************************************
246
247 \begin{code}
248 instance  Eq Integer  where
249     (S# i)     ==  (S# j)     = i ==# j
250     (S# i)     ==  (J# s d)   = cmpIntegerInt# s d i ==# 0#
251     (J# s d)   ==  (S# i)     = cmpIntegerInt# s d i ==# 0#
252     (J# s1 d1) ==  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) ==# 0#
253
254     (S# i)     /=  (S# j)     = i /=# j
255     (S# i)     /=  (J# s d)   = cmpIntegerInt# s d i /=# 0#
256     (J# s d)   /=  (S# i)     = cmpIntegerInt# s d i /=# 0#
257     (J# s1 d1) /=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) /=# 0#
258
259 ------------------------------------------------------------------------
260 instance  Ord Integer  where
261     (S# i)     <=  (S# j)     = i <=# j
262     (J# s d)   <=  (S# i)     = cmpIntegerInt# s d i <=# 0#
263     (S# i)     <=  (J# s d)   = cmpIntegerInt# s d i >=# 0#
264     (J# s1 d1) <=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) <=# 0#
265
266     (S# i)     >   (S# j)     = i ># j
267     (J# s d)   >   (S# i)     = cmpIntegerInt# s d i ># 0#
268     (S# i)     >   (J# s d)   = cmpIntegerInt# s d i <# 0#
269     (J# s1 d1) >   (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) ># 0#
270
271     (S# i)     <   (S# j)     = i <# j
272     (J# s d)   <   (S# i)     = cmpIntegerInt# s d i <# 0#
273     (S# i)     <   (J# s d)   = cmpIntegerInt# s d i ># 0#
274     (J# s1 d1) <   (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) <# 0#
275
276     (S# i)     >=  (S# j)     = i >=# j
277     (J# s d)   >=  (S# i)     = cmpIntegerInt# s d i >=# 0#
278     (S# i)     >=  (J# s d)   = cmpIntegerInt# s d i <=# 0#
279     (J# s1 d1) >=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) >=# 0#
280
281     compare (S# i)  (S# j)
282        | i ==# j = EQ
283        | i <=# j = LT
284        | otherwise = GT
285     compare (J# s d) (S# i)
286        = case cmpIntegerInt# s d i of { res# ->
287          if res# <# 0# then LT else 
288          if res# ># 0# then GT else EQ
289          }
290     compare (S# i) (J# s d)
291        = case cmpIntegerInt# s d i of { res# ->
292          if res# ># 0# then LT else 
293          if res# <# 0# then GT else EQ
294          }
295     compare (J# s1 d1) (J# s2 d2)
296        = case cmpInteger# s1 d1 s2 d2 of { res# ->
297          if res# <# 0# then LT else 
298          if res# ># 0# then GT else EQ
299          }
300 \end{code}
301
302
303 %*********************************************************
304 %*                                                      *
305 \subsection{The @Integer@ instances for @Num@}
306 %*                                                      *
307 %*********************************************************
308
309 \begin{code}
310 instance  Num Integer  where
311     (+) = plusInteger
312     (-) = minusInteger
313     (*) = timesInteger
314     negate         = negateInteger
315     fromInteger x  =  x
316
317     -- ORIG: abs n = if n >= 0 then n else -n
318     abs (S# (-LEFTMOST_BIT#)) = LEFTMOST_BIT
319     abs (S# i) = case abs (I# i) of I# j -> S# j
320     abs n@(J# s d) = if (s >=# 0#) then n else J# (negateInt# s) d
321
322     signum (S# i) = case signum (I# i) of I# j -> S# j
323     signum (J# s d)
324       = let
325             cmp = cmpIntegerInt# s d 0#
326         in
327         if      cmp >#  0# then S# 1#
328         else if cmp ==# 0# then S# 0#
329         else                    S# (negateInt# 1#)
330
331 plusInteger i1@(S# i) i2@(S# j)  = case addIntC# i j of { (# r, c #) ->
332                                    if c ==# 0# then S# r
333                                    else toBig i1 + toBig i2 }
334 plusInteger i1@(J# _ _) i2@(S# _) = i1 + toBig i2
335 plusInteger i1@(S# _) i2@(J# _ _) = toBig i1 + i2
336 plusInteger (J# s1 d1) (J# s2 d2) = case plusInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
337
338 minusInteger i1@(S# i) i2@(S# j)   = case subIntC# i j of { (# r, c #) ->
339                                      if c ==# 0# then S# r
340                                      else toBig i1 - toBig i2 }
341 minusInteger i1@(J# _ _) i2@(S# _) = i1 - toBig i2
342 minusInteger i1@(S# _) i2@(J# _ _) = toBig i1 - i2
343 minusInteger (J# s1 d1) (J# s2 d2) = case minusInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
344
345 timesInteger i1@(S# i) i2@(S# j)   = if   mulIntMayOflo# i j ==# 0#
346                                      then S# (i *# j)
347                                      else toBig i1 * toBig i2 
348 timesInteger i1@(J# _ _) i2@(S# _) = i1 * toBig i2
349 timesInteger i1@(S# _) i2@(J# _ _) = toBig i1 * i2
350 timesInteger (J# s1 d1) (J# s2 d2) = case timesInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
351
352 negateInteger (S# (-LEFTMOST_BIT#)) = LEFTMOST_BIT
353 negateInteger (S# i)              = S# (negateInt# i)
354 negateInteger (J# s d)            = J# (negateInt# s) d
355 \end{code}
356
357
358 %*********************************************************
359 %*                                                      *
360 \subsection{The @Integer@ instance for @Enum@}
361 %*                                                      *
362 %*********************************************************
363
364 \begin{code}
365 instance  Enum Integer  where
366     succ x               = x + 1
367     pred x               = x - 1
368     toEnum n             = int2Integer n
369     fromEnum n           = integer2Int n
370
371     {-# INLINE enumFrom #-}
372     {-# INLINE enumFromThen #-}
373     {-# INLINE enumFromTo #-}
374     {-# INLINE enumFromThenTo #-}
375     enumFrom x             = enumDeltaInteger  x 1
376     enumFromThen x y       = enumDeltaInteger  x (y-x)
377     enumFromTo x lim       = enumDeltaToInteger x 1     lim
378     enumFromThenTo x y lim = enumDeltaToInteger x (y-x) lim
379
380 {-# RULES
381 "enumDeltaInteger"      [~1] forall x y.  enumDeltaInteger x y     = build (\c _ -> enumDeltaIntegerFB c x y)
382 "efdtInteger"           [~1] forall x y l.enumDeltaToInteger x y l = build (\c n -> enumDeltaToIntegerFB c n x y l)
383 "enumDeltaInteger"      [1] enumDeltaIntegerFB   (:)    = enumDeltaInteger
384 "enumDeltaToInteger"    [1] enumDeltaToIntegerFB (:) [] = enumDeltaToInteger
385  #-}
386
387 enumDeltaIntegerFB :: (Integer -> b -> b) -> Integer -> Integer -> b
388 enumDeltaIntegerFB c x d = x `c` enumDeltaIntegerFB c (x+d) d
389
390 enumDeltaInteger :: Integer -> Integer -> [Integer]
391 enumDeltaInteger x d = x : enumDeltaInteger (x+d) d
392
393 enumDeltaToIntegerFB c n x delta lim
394   | delta >= 0 = up_fb c n x delta lim
395   | otherwise  = dn_fb c n x delta lim
396
397 enumDeltaToInteger x delta lim
398   | delta >= 0 = up_list x delta lim
399   | otherwise  = dn_list x delta lim
400
401 up_fb c n x delta lim = go (x::Integer)
402                       where
403                         go x | x > lim   = n
404                              | otherwise = x `c` go (x+delta)
405 dn_fb c n x delta lim = go (x::Integer)
406                       where
407                         go x | x < lim   = n
408                              | otherwise = x `c` go (x+delta)
409
410 up_list x delta lim = go (x::Integer)
411                     where
412                         go x | x > lim   = []
413                              | otherwise = x : go (x+delta)
414 dn_list x delta lim = go (x::Integer)
415                     where
416                         go x | x < lim   = []
417                              | otherwise = x : go (x+delta)
418
419 \end{code}
420
421
422 %*********************************************************
423 %*                                                      *
424 \subsection{The @Integer@ instances for @Show@}
425 %*                                                      *
426 %*********************************************************
427
428 \begin{code}
429 instance Show Integer where
430     showsPrec p n r
431         | p > 6 && n < 0 = '(' : jtos n (')' : r)
432                 -- Minor point: testing p first gives better code 
433                 -- in the not-uncommon case where the p argument
434                 -- is a constant
435         | otherwise      = jtos n r
436     showList = showList__ (showsPrec 0)
437
438 jtos :: Integer -> String -> String
439 jtos n cs
440     | n < 0     = '-' : jtos' (-n) cs
441     | otherwise = jtos' n cs
442     where
443     jtos' :: Integer -> String -> String
444     jtos' n' cs'
445         | n' < 10    = case unsafeChr (ord '0' + fromInteger n') of
446             c@(C# _) -> c:cs'
447         | otherwise = case unsafeChr (ord '0' + fromInteger r) of
448             c@(C# _) -> jtos' q (c:cs')
449         where
450         (q,r) = n' `quotRemInteger` 10
451 \end{code}