untabify
[packages/base.git] / aclocal.m4
1 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
2 # --------------------------------------------------------
3 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
4 # compilation. Execute IF-FAILS when unable to determine the value. Works for
5 # cross-compilation, too.
6 #
7 # Implementation note: We are lazy and use an internal autoconf macro, but it
8 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
9 # little risk.
10 AC_DEFUN([FP_COMPUTE_INT],
11 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
12 ])# FP_COMPUTE_INT
13
14
15 # FP_CHECK_CONST(EXPRESSION, [INCLUDES = DEFAULT-INCLUDES], [VALUE-IF-FAIL = -1])
16 # -------------------------------------------------------------------------------
17 # Defines CONST_EXPRESSION to the value of the compile-time EXPRESSION, using
18 # INCLUDES. If the value cannot be determined, use VALUE-IF-FAIL.
19 AC_DEFUN([FP_CHECK_CONST],
20 [AS_VAR_PUSHDEF([fp_Cache], [fp_cv_const_$1])[]dnl
21 AC_CACHE_CHECK([value of $1], fp_Cache,
22 [FP_COMPUTE_INT([$1], fp_check_const_result, [AC_INCLUDES_DEFAULT([$2])],
23                 [fp_check_const_result=m4_default([$3], ['-1'])])
24 AS_VAR_SET(fp_Cache, [$fp_check_const_result])])[]dnl
25 AC_DEFINE_UNQUOTED(AS_TR_CPP([CONST_$1]), AS_VAR_GET(fp_Cache), [The value of $1.])[]dnl
26 AS_VAR_POPDEF([fp_Cache])[]dnl
27 ])# FP_CHECK_CONST
28
29
30 # FP_CHECK_CONSTS_TEMPLATE(EXPRESSION...)
31 # ---------------------------------------
32 # autoheader helper for FP_CHECK_CONSTS
33 m4_define([FP_CHECK_CONSTS_TEMPLATE],
34 [AC_FOREACH([fp_Const], [$1],
35   [AH_TEMPLATE(AS_TR_CPP(CONST_[]fp_Const),
36                [The value of ]fp_Const[.])])[]dnl
37 ])# FP_CHECK_CONSTS_TEMPLATE
38
39
40 # FP_CHECK_CONSTS(EXPRESSION..., [INCLUDES = DEFAULT-INCLUDES], [VALUE-IF-FAIL = -1])
41 # -----------------------------------------------------------------------------------
42 # List version of FP_CHECK_CONST
43 AC_DEFUN([FP_CHECK_CONSTS],
44 [FP_CHECK_CONSTS_TEMPLATE([$1])dnl
45 for fp_const_name in $1
46 do
47 FP_CHECK_CONST([$fp_const_name], [$2], [$3])
48 done
49 ])# FP_CHECK_CONSTS
50
51
52 dnl ** Map an arithmetic C type to a Haskell type.
53 dnl    Based on autconf's AC_CHECK_SIZEOF.
54
55 dnl FPTOOLS_CHECK_HTYPE(TYPE [, DEFAULT_VALUE, [, VALUE-FOR-CROSS-COMPILATION])
56 AC_DEFUN([FPTOOLS_CHECK_HTYPE],
57 [changequote(<<, >>)dnl
58 dnl The name to #define.
59 define(<<AC_TYPE_NAME>>, translit(htype_$1, [a-z *], [A-Z_P]))dnl
60 dnl The cache variable name.
61 define(<<AC_CV_NAME>>, translit(fptools_cv_htype_$1, [ *], [_p]))dnl
62 define(<<AC_CV_NAME_supported>>, translit(fptools_cv_htype_sup_$1, [ *], [_p]))dnl
63 changequote([, ])dnl
64 AC_MSG_CHECKING(Haskell type for $1)
65 AC_CACHE_VAL(AC_CV_NAME,
66 [AC_CV_NAME_supported=yes
67 fp_check_htype_save_cppflags="$CPPFLAGS"
68 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
69 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdio.h>
70 #include <stddef.h>
71
72 #if HAVE_SYS_TYPES_H
73 # include <sys/types.h>
74 #endif
75
76 #if HAVE_UNISTD_H
77 # include <unistd.h>
78 #endif
79
80 #if HAVE_SYS_STAT_H
81 # include <sys/stat.h>
82 #endif
83
84 #if HAVE_FCNTL_H
85 # include <fcntl.h>
86 #endif
87
88 #if HAVE_SIGNAL_H
89 # include <signal.h>
90 #endif
91
92 #if HAVE_TIME_H
93 # include <time.h>
94 #endif
95
96 #if HAVE_TERMIOS_H
97 # include <termios.h>
98 #endif
99
100 #if HAVE_STRING_H
101 # include <string.h>
102 #endif
103
104 #if HAVE_CTYPE_H
105 # include <ctype.h>
106 #endif
107
108 #if HAVE_INTTYPES_H
109 # include <inttypes.h>
110 #else
111 # if HAVE_STDINT_H
112 #  include <stdint.h>
113 # endif
114 #endif
115
116 #if defined(HAVE_GL_GL_H)
117 # include <GL/gl.h>
118 #elif defined(HAVE_OPENGL_GL_H)
119 # include <OpenGL/gl.h>
120 #endif
121
122 #if defined(HAVE_AL_AL_H)
123 # include <AL/al.h>
124 #elif defined(HAVE_OPENAL_AL_H)
125 # include <OpenAL/al.h>
126 #endif
127
128 #if defined(HAVE_AL_ALC_H)
129 # include <AL/alc.h>
130 #elif defined(HAVE_OPENAL_ALC_H)
131 # include <OpenAL/alc.h>
132 #endif
133
134 #if HAVE_SYS_RESOURCE_H
135 # include <sys/resource.h>
136 #endif
137
138 typedef $1 testing;
139
140 main() {
141   FILE *f=fopen("conftestval", "w");
142   if (!f) exit(1);
143   if (((testing)((int)((testing)1.4))) == ((testing)1.4)) {
144     fprintf(f, "%s%d\n",
145            ((testing)(-1) < (testing)0) ? "Int" : "Word",
146            sizeof(testing)*8);
147   } else {
148     fprintf(f,"%s\n",
149            (sizeof(testing) >  sizeof(double)) ? "LDouble" :
150            (sizeof(testing) == sizeof(double)) ? "Double"  : "Float");
151   }
152   fclose(f);
153   exit(0);
154 }]])],[AC_CV_NAME=`cat conftestval`],
155 [ifelse([$2], , [AC_CV_NAME=NotReallyAType; AC_CV_NAME_supported=no], [AC_CV_NAME=$2])],
156 [ifelse([$3], , [AC_CV_NAME=NotReallyATypeCross; AC_CV_NAME_supported=no], [AC_CV_NAME=$3])])
157 CPPFLAGS="$fp_check_htype_save_cppflags"]) dnl
158 if test "$AC_CV_NAME_supported" = yes; then
159   AC_MSG_RESULT($AC_CV_NAME)
160   AC_DEFINE_UNQUOTED(AC_TYPE_NAME, $AC_CV_NAME, [Define to Haskell type for $1])
161 else
162   AC_MSG_RESULT([not supported])
163 fi
164 undefine([AC_TYPE_NAME])dnl
165 undefine([AC_CV_NAME])dnl
166 undefine([AC_CV_NAME_supported])dnl
167 ])
168
169
170 # FP_READDIR_EOF_ERRNO
171 # --------------------
172 # Defines READDIR_ERRNO_EOF to what readdir() sets 'errno' to upon reaching end
173 # of directory (not set => 0); not setting it is the correct thing to do, but
174 # MinGW based versions have set it to ENOENT until recently (summer 2004).
175 AC_DEFUN([FP_READDIR_EOF_ERRNO],
176 [AC_CACHE_CHECK([what readdir sets errno to upon EOF], [fptools_cv_readdir_eof_errno],
177 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <dirent.h>
178 #include <stdio.h>
179 #include <errno.h>
180 int
181 main(argc, argv)
182 int argc;
183 char **argv;
184 {
185   FILE *f=fopen("conftestval", "w");
186 #if defined(__MINGW32__)
187   int fd = mkdir("testdir");
188 #else
189   int fd = mkdir("testdir", 0666);
190 #endif
191   DIR* dp;
192   struct dirent* de;
193   int err = 0;
194
195   if (!f) return 1;
196   if (fd == -1) { 
197      fprintf(stderr,"unable to create directory; quitting.\n");
198      return 1;
199   }
200   close(fd);
201   dp = opendir("testdir");
202   if (!dp) { 
203      fprintf(stderr,"unable to browse directory; quitting.\n");
204      rmdir("testdir");
205      return 1;
206   }
207
208   /* the assumption here is that readdir() will only return NULL
209    * due to reaching the end of the directory.
210    */
211   while (de = readdir(dp)) {
212         ;
213   }
214   err = errno;
215   fprintf(f,"%d", err);
216   fclose(f);
217   closedir(dp);
218   rmdir("testdir");
219   return 0;
220 }]])],
221 [fptools_cv_readdir_eof_errno=`cat conftestval`],
222 [AC_MSG_WARN([failed to determine the errno value])
223  fptools_cv_readdir_eof_errno=0],
224 [fptools_cv_readdir_eof_errno=0])])
225 AC_DEFINE_UNQUOTED([READDIR_ERRNO_EOF], [$fptools_cv_readdir_eof_errno], [readdir() sets errno to this upon EOF])
226 ])# FP_READDIR_EOF_ERRNO