Fix build on OS X
[packages/base.git] / GHC / ST.lhs
1 \begin{code}
2 {-# LANGUAGE Unsafe #-}
3 {-# LANGUAGE NoImplicitPrelude, MagicHash, UnboxedTuples, RankNTypes #-}
4 {-# OPTIONS_HADDOCK hide #-}
5 -----------------------------------------------------------------------------
6 -- |
7 -- Module      :  GHC.ST
8 -- Copyright   :  (c) The University of Glasgow, 1992-2002
9 -- License     :  see libraries/base/LICENSE
10 -- 
11 -- Maintainer  :  cvs-ghc@haskell.org
12 -- Stability   :  internal
13 -- Portability :  non-portable (GHC Extensions)
14 --
15 -- The 'ST' Monad.
16 --
17 -----------------------------------------------------------------------------
18
19 -- #hide
20 module GHC.ST (
21         ST(..), STret(..), STRep,
22         fixST, runST, runSTRep,
23
24         -- * Unsafe functions
25         liftST, unsafeInterleaveST
26     ) where
27
28 import GHC.Base
29 import GHC.Show
30
31 default ()
32 \end{code}
33
34 %*********************************************************
35 %*                                                      *
36 \subsection{The @ST@ monad}
37 %*                                                      *
38 %*********************************************************
39
40 The state-transformer monad proper.  By default the monad is strict;
41 too many people got bitten by space leaks when it was lazy.
42
43 \begin{code}
44 -- | The strict state-transformer monad.
45 -- A computation of type @'ST' s a@ transforms an internal state indexed
46 -- by @s@, and returns a value of type @a@.
47 -- The @s@ parameter is either
48 --
49 -- * an uninstantiated type variable (inside invocations of 'runST'), or
50 --
51 -- * 'RealWorld' (inside invocations of 'Control.Monad.ST.stToIO').
52 --
53 -- It serves to keep the internal states of different invocations
54 -- of 'runST' separate from each other and from invocations of
55 -- 'Control.Monad.ST.stToIO'.
56 --
57 -- The '>>=' and '>>' operations are strict in the state (though not in
58 -- values stored in the state).  For example,
59 --
60 -- @'runST' (writeSTRef _|_ v >>= f) = _|_@
61 newtype ST s a = ST (STRep s a)
62 type STRep s a = State# s -> (# State# s, a #)
63
64 instance Functor (ST s) where
65     fmap f (ST m) = ST $ \ s ->
66       case (m s) of { (# new_s, r #) ->
67       (# new_s, f r #) }
68
69 instance Monad (ST s) where
70     {-# INLINE return #-}
71     {-# INLINE (>>)   #-}
72     {-# INLINE (>>=)  #-}
73     return x = ST (\ s -> (# s, x #))
74     m >> k   = m >>= \ _ -> k
75
76     (ST m) >>= k
77       = ST (\ s ->
78         case (m s) of { (# new_s, r #) ->
79         case (k r) of { ST k2 ->
80         (k2 new_s) }})
81
82 data STret s a = STret (State# s) a
83
84 -- liftST is useful when we want a lifted result from an ST computation.  See
85 -- fixST below.
86 liftST :: ST s a -> State# s -> STret s a
87 liftST (ST m) = \s -> case m s of (# s', r #) -> STret s' r
88
89 {-# NOINLINE unsafeInterleaveST #-}
90 unsafeInterleaveST :: ST s a -> ST s a
91 unsafeInterleaveST (ST m) = ST ( \ s ->
92     let
93         r = case m s of (# _, res #) -> res
94     in
95     (# s, r #)
96   )
97
98 -- | Allow the result of a state transformer computation to be used (lazily)
99 -- inside the computation.
100 -- Note that if @f@ is strict, @'fixST' f = _|_@.
101 fixST :: (a -> ST s a) -> ST s a
102 fixST k = ST $ \ s ->
103     let ans       = liftST (k r) s
104         STret _ r = ans
105     in
106     case ans of STret s' x -> (# s', x #)
107
108 instance  Show (ST s a)  where
109     showsPrec _ _  = showString "<<ST action>>"
110     showList       = showList__ (showsPrec 0)
111 \end{code}
112
113 Definition of runST
114 ~~~~~~~~~~~~~~~~~~~
115
116 SLPJ 95/04: Why @runST@ must not have an unfolding; consider:
117 \begin{verbatim}
118 f x =
119   runST ( \ s -> let
120                     (a, s')  = newArray# 100 [] s
121                     (_, s'') = fill_in_array_or_something a x s'
122                   in
123                   freezeArray# a s'' )
124 \end{verbatim}
125 If we inline @runST@, we'll get:
126 \begin{verbatim}
127 f x = let
128         (a, s')  = newArray# 100 [] realWorld#{-NB-}
129         (_, s'') = fill_in_array_or_something a x s'
130       in
131       freezeArray# a s''
132 \end{verbatim}
133 And now the @newArray#@ binding can be floated to become a CAF, which
134 is totally and utterly wrong:
135 \begin{verbatim}
136 f = let
137     (a, s')  = newArray# 100 [] realWorld#{-NB-} -- YIKES!!!
138     in
139     \ x ->
140         let (_, s'') = fill_in_array_or_something a x s' in
141         freezeArray# a s''
142 \end{verbatim}
143 All calls to @f@ will share a {\em single} array!  End SLPJ 95/04.
144
145 \begin{code}
146 {-# INLINE runST #-}
147 -- The INLINE prevents runSTRep getting inlined in *this* module
148 -- so that it is still visible when runST is inlined in an importing
149 -- module.  Regrettably delicate.  runST is behaving like a wrapper.
150
151 -- | Return the value computed by a state transformer computation.
152 -- The @forall@ ensures that the internal state used by the 'ST'
153 -- computation is inaccessible to the rest of the program.
154 runST :: (forall s. ST s a) -> a
155 runST st = runSTRep (case st of { ST st_rep -> st_rep })
156
157 -- I'm only letting runSTRep be inlined right at the end, in particular *after* full laziness
158 -- That's what the "INLINE [0]" says.
159 --              SLPJ Apr 99
160 -- {-# INLINE [0] runSTRep #-}
161
162 -- SDM: further to the above, inline phase 0 is run *before*
163 -- full-laziness at the moment, which means that the above comment is
164 -- invalid.  Inlining runSTRep doesn't make a huge amount of
165 -- difference, anyway.  Hence:
166
167 {-# NOINLINE runSTRep #-}
168 runSTRep :: (forall s. STRep s a) -> a
169 runSTRep st_rep = case st_rep realWorld# of
170                         (# _, r #) -> r
171 \end{code}