[project @ 2005-01-27 10:45:47 by simonpj]
[packages/base.git] / GHC / Num.lhs
1 \begin{code}
2 {-# OPTIONS_GHC -fno-implicit-prelude #-}
3 -----------------------------------------------------------------------------
4 -- |
5 -- Module      :  GHC.Num
6 -- Copyright   :  (c) The University of Glasgow 1994-2002
7 -- License     :  see libraries/base/LICENSE
8 -- 
9 -- Maintainer  :  cvs-ghc@haskell.org
10 -- Stability   :  internal
11 -- Portability :  non-portable (GHC Extensions)
12 --
13 -- The 'Num' class and the 'Integer' type.
14 --
15 -----------------------------------------------------------------------------
16
17 #include "MachDeps.h"
18 #if SIZEOF_HSWORD == 4
19 #define LEFTMOST_BIT 2147483648
20 #elif SIZEOF_HSWORD == 8
21 #define LEFTMOST_BIT 9223372036854775808
22 #else
23 #error Please define LEFTMOST_BIT to be 2^(SIZEOF_HSWORD*8-1)
24 #endif
25
26 module GHC.Num where
27
28 import {-# SOURCE #-} GHC.Err
29 import GHC.Base
30 import GHC.Enum
31 import GHC.Show
32
33 infixl 7  *
34 infixl 6  +, -
35
36 default ()              -- Double isn't available yet, 
37                         -- and we shouldn't be using defaults anyway
38 \end{code}
39
40 %*********************************************************
41 %*                                                      *
42 \subsection{Standard numeric class}
43 %*                                                      *
44 %*********************************************************
45
46 \begin{code}
47 -- | Basic numeric class.
48 --
49 -- Minimal complete definition: all except 'negate' or @(-)@
50 class  (Eq a, Show a) => Num a  where
51     (+), (-), (*)       :: a -> a -> a
52     -- | Unary negation.
53     negate              :: a -> a
54     -- | Absolute value.
55     abs                 :: a -> a
56     -- | Sign of a number.
57     -- The functions 'abs' and 'signum' should satisfy the law: 
58     --
59     -- > abs x * signum x == x
60     --
61     -- For real numbers, the 'signum' is either @-1@ (negative), @0@ (zero)
62     -- or @1@ (positive).
63     signum              :: a -> a
64     -- | Conversion from an 'Integer'.
65     -- An integer literal represents the application of the function
66     -- 'fromInteger' to the appropriate value of type 'Integer',
67     -- so such literals have type @('Num' a) => a@.
68     fromInteger         :: Integer -> a
69
70     x - y               = x + negate y
71     negate x            = 0 - x
72
73 -- | the same as @'flip' ('-')@.
74 --
75 -- Because @-@ is treated specially in the Haskell grammar,
76 -- @(-@ /e/@)@ is not a section, but an application of prefix negation.
77 -- However, @('subtract'@ /exp/@)@ is equivalent to the disallowed section.
78 {-# INLINE subtract #-}
79 subtract :: (Num a) => a -> a -> a
80 subtract x y = y - x
81 \end{code}
82
83
84 %*********************************************************
85 %*                                                      *
86 \subsection{Instances for @Int@}
87 %*                                                      *
88 %*********************************************************
89
90 \begin{code}
91 instance  Num Int  where
92     (+)    = plusInt
93     (-)    = minusInt
94     negate = negateInt
95     (*)    = timesInt
96     abs n  = if n `geInt` 0 then n else negateInt n
97
98     signum n | n `ltInt` 0 = negateInt 1
99              | n `eqInt` 0 = 0
100              | otherwise   = 1
101
102     fromInteger = integer2Int
103
104 quotRemInt :: Int -> Int -> (Int, Int)
105 quotRemInt a@(I# _) b@(I# _) = (a `quotInt` b, a `remInt` b)
106     -- OK, so I made it a little stricter.  Shoot me.  (WDP 94/10)
107
108 divModInt ::  Int -> Int -> (Int, Int)
109 divModInt x@(I# _) y@(I# _) = (x `divInt` y, x `modInt` y)
110     -- Stricter.  Sorry if you don't like it.  (WDP 94/10)
111 \end{code}
112
113 %*********************************************************
114 %*                                                      *
115 \subsection{The @Integer@ type}
116 %*                                                      *
117 %*********************************************************
118
119 \begin{code}
120 -- | Arbitrary-precision integers.
121 data Integer    
122    = S# Int#                            -- small integers
123 #ifndef ILX
124    | J# Int# ByteArray#                 -- large integers
125 #else
126    | J# Void BigInteger                 -- .NET big ints
127
128 foreign type dotnet "BigInteger" BigInteger
129 #endif
130 \end{code}
131
132 Convenient boxed Integer PrimOps. 
133
134 \begin{code}
135 zeroInteger :: Integer
136 zeroInteger = S# 0#
137
138 int2Integer :: Int -> Integer
139 {-# INLINE int2Integer #-}
140 int2Integer (I# i) = S# i
141
142 integer2Int :: Integer -> Int
143 integer2Int (S# i)   = I# i
144 integer2Int (J# s d) = case (integer2Int# s d) of { n# -> I# n# }
145
146 toBig (S# i)     = case int2Integer# i of { (# s, d #) -> J# s d }
147 toBig i@(J# _ _) = i
148 \end{code}
149
150
151 %*********************************************************
152 %*                                                      *
153 \subsection{Dividing @Integers@}
154 %*                                                      *
155 %*********************************************************
156
157 \begin{code}
158 quotRemInteger :: Integer -> Integer -> (Integer, Integer)
159 quotRemInteger a@(S# (-LEFTMOST_BIT#)) b = quotRemInteger (toBig a) b
160 quotRemInteger (S# i) (S# j)
161   = case quotRemInt (I# i) (I# j) of ( I# i, I# j ) -> ( S# i, S# j ) 
162 quotRemInteger i1@(J# _ _) i2@(S# _) = quotRemInteger i1 (toBig i2)
163 quotRemInteger i1@(S# _) i2@(J# _ _) = quotRemInteger (toBig i1) i2
164 quotRemInteger (J# s1 d1) (J# s2 d2)
165   = case (quotRemInteger# s1 d1 s2 d2) of
166           (# s3, d3, s4, d4 #)
167             -> (J# s3 d3, J# s4 d4)
168
169 divModInteger a@(S# (-LEFTMOST_BIT#)) b = divModInteger (toBig a) b
170 divModInteger (S# i) (S# j)
171   = case divModInt (I# i) (I# j) of ( I# i, I# j ) -> ( S# i, S# j) 
172 divModInteger i1@(J# _ _) i2@(S# _) = divModInteger i1 (toBig i2)
173 divModInteger i1@(S# _) i2@(J# _ _) = divModInteger (toBig i1) i2
174 divModInteger (J# s1 d1) (J# s2 d2)
175   = case (divModInteger# s1 d1 s2 d2) of
176           (# s3, d3, s4, d4 #)
177             -> (J# s3 d3, J# s4 d4)
178
179 remInteger :: Integer -> Integer -> Integer
180 remInteger ia 0
181   = error "Prelude.Integral.rem{Integer}: divide by 0"
182 remInteger a@(S# (-LEFTMOST_BIT#)) b = remInteger (toBig a) b
183 remInteger (S# a) (S# b) = S# (remInt# a b)
184 {- Special case doesn't work, because a 1-element J# has the range
185    -(2^32-1) -- 2^32-1, whereas S# has the range -2^31 -- (2^31-1)
186 remInteger ia@(S# a) (J# sb b)
187   | sb ==# 1#  = S# (remInt# a (word2Int# (integer2Word# sb b)))
188   | sb ==# -1# = S# (remInt# a (0# -# (word2Int# (integer2Word# sb b))))
189   | 0# <# sb   = ia
190   | otherwise  = S# (0# -# a)
191 -}
192 remInteger ia@(S# _) ib@(J# _ _) = remInteger (toBig ia) ib
193 remInteger (J# sa a) (S# b)
194   = case int2Integer# b of { (# sb, b #) ->
195     case remInteger# sa a sb b of { (# sr, r #) ->
196     S# (integer2Int# sr r) }}
197 remInteger (J# sa a) (J# sb b)
198   = case remInteger# sa a sb b of (# sr, r #) -> J# sr r
199
200 quotInteger :: Integer -> Integer -> Integer
201 quotInteger ia 0
202   = error "Prelude.Integral.quot{Integer}: divide by 0"
203 quotInteger a@(S# (-LEFTMOST_BIT#)) b = quotInteger (toBig a) b
204 quotInteger (S# a) (S# b) = S# (quotInt# a b)
205 {- Special case disabled, see remInteger above
206 quotInteger (S# a) (J# sb b)
207   | sb ==# 1#  = S# (quotInt# a (word2Int# (integer2Word# sb b)))
208   | sb ==# -1# = S# (quotInt# a (0# -# (word2Int# (integer2Word# sb b))))
209   | otherwise  = zeroInteger
210 -}
211 quotInteger ia@(S# _) ib@(J# _ _) = quotInteger (toBig ia) ib
212 quotInteger (J# sa a) (S# b)
213   = case int2Integer# b of { (# sb, b #) ->
214     case quotInteger# sa a sb b of (# sq, q #) -> J# sq q }
215 quotInteger (J# sa a) (J# sb b)
216   = case quotInteger# sa a sb b of (# sg, g #) -> J# sg g
217 \end{code}
218
219
220
221 \begin{code}
222 gcdInteger :: Integer -> Integer -> Integer
223 -- SUP: Do we really need the first two cases?
224 gcdInteger a@(S# (-LEFTMOST_BIT#)) b = gcdInteger (toBig a) b
225 gcdInteger a b@(S# (-LEFTMOST_BIT#)) = gcdInteger a (toBig b)
226 gcdInteger (S# a) (S# b) = case gcdInt (I# a) (I# b) of { I# c -> S# c }
227 gcdInteger ia@(S# 0#) ib@(J# 0# _) = error "GHC.Num.gcdInteger: gcd 0 0 is undefined"
228 gcdInteger ia@(S# a)  ib@(J# sb b)
229   | a  ==# 0#  = abs ib
230   | sb ==# 0#  = abs ia
231   | otherwise  = S# (gcdIntegerInt# absSb b absA)
232        where absA  = if a  <# 0# then negateInt# a  else a
233              absSb = if sb <# 0# then negateInt# sb else sb
234 gcdInteger ia@(J# _ _) ib@(S# _) = gcdInteger ib ia
235 gcdInteger (J# 0# _) (J# 0# _) = error "GHC.Num.gcdInteger: gcd 0 0 is undefined"
236 gcdInteger (J# sa a) (J# sb b)
237   = case gcdInteger# sa a sb b of (# sg, g #) -> J# sg g
238
239 lcmInteger :: Integer -> Integer -> Integer
240 lcmInteger a 0
241   = zeroInteger
242 lcmInteger 0 b
243   = zeroInteger
244 lcmInteger a b
245   = (divExact aa (gcdInteger aa ab)) * ab
246   where aa = abs a
247         ab = abs b
248
249 divExact :: Integer -> Integer -> Integer
250 divExact a@(S# (-LEFTMOST_BIT#)) b = divExact (toBig a) b
251 divExact (S# a) (S# b) = S# (quotInt# a b)
252 divExact (S# a) (J# sb b)
253   = S# (quotInt# a (integer2Int# sb b))
254 divExact (J# sa a) (S# b)
255   = case int2Integer# b of
256      (# sb, b #) -> case divExactInteger# sa a sb b of (# sd, d #) -> J# sd d
257 divExact (J# sa a) (J# sb b)
258   = case divExactInteger# sa a sb b of (# sd, d #) -> J# sd d
259 \end{code}
260
261
262 %*********************************************************
263 %*                                                      *
264 \subsection{The @Integer@ instances for @Eq@, @Ord@}
265 %*                                                      *
266 %*********************************************************
267
268 \begin{code}
269 instance  Eq Integer  where
270     (S# i)     ==  (S# j)     = i ==# j
271     (S# i)     ==  (J# s d)   = cmpIntegerInt# s d i ==# 0#
272     (J# s d)   ==  (S# i)     = cmpIntegerInt# s d i ==# 0#
273     (J# s1 d1) ==  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) ==# 0#
274
275     (S# i)     /=  (S# j)     = i /=# j
276     (S# i)     /=  (J# s d)   = cmpIntegerInt# s d i /=# 0#
277     (J# s d)   /=  (S# i)     = cmpIntegerInt# s d i /=# 0#
278     (J# s1 d1) /=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) /=# 0#
279
280 ------------------------------------------------------------------------
281 instance  Ord Integer  where
282     (S# i)     <=  (S# j)     = i <=# j
283     (J# s d)   <=  (S# i)     = cmpIntegerInt# s d i <=# 0#
284     (S# i)     <=  (J# s d)   = cmpIntegerInt# s d i >=# 0#
285     (J# s1 d1) <=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) <=# 0#
286
287     (S# i)     >   (S# j)     = i ># j
288     (J# s d)   >   (S# i)     = cmpIntegerInt# s d i ># 0#
289     (S# i)     >   (J# s d)   = cmpIntegerInt# s d i <# 0#
290     (J# s1 d1) >   (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) ># 0#
291
292     (S# i)     <   (S# j)     = i <# j
293     (J# s d)   <   (S# i)     = cmpIntegerInt# s d i <# 0#
294     (S# i)     <   (J# s d)   = cmpIntegerInt# s d i ># 0#
295     (J# s1 d1) <   (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) <# 0#
296
297     (S# i)     >=  (S# j)     = i >=# j
298     (J# s d)   >=  (S# i)     = cmpIntegerInt# s d i >=# 0#
299     (S# i)     >=  (J# s d)   = cmpIntegerInt# s d i <=# 0#
300     (J# s1 d1) >=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) >=# 0#
301
302     compare (S# i)  (S# j)
303        | i ==# j = EQ
304        | i <=# j = LT
305        | otherwise = GT
306     compare (J# s d) (S# i)
307        = case cmpIntegerInt# s d i of { res# ->
308          if res# <# 0# then LT else 
309          if res# ># 0# then GT else EQ
310          }
311     compare (S# i) (J# s d)
312        = case cmpIntegerInt# s d i of { res# ->
313          if res# ># 0# then LT else 
314          if res# <# 0# then GT else EQ
315          }
316     compare (J# s1 d1) (J# s2 d2)
317        = case cmpInteger# s1 d1 s2 d2 of { res# ->
318          if res# <# 0# then LT else 
319          if res# ># 0# then GT else EQ
320          }
321 \end{code}
322
323
324 %*********************************************************
325 %*                                                      *
326 \subsection{The @Integer@ instances for @Num@}
327 %*                                                      *
328 %*********************************************************
329
330 \begin{code}
331 instance  Num Integer  where
332     (+) = plusInteger
333     (-) = minusInteger
334     (*) = timesInteger
335     negate         = negateInteger
336     fromInteger x  =  x
337
338     -- ORIG: abs n = if n >= 0 then n else -n
339     abs (S# (-LEFTMOST_BIT#)) = LEFTMOST_BIT
340     abs (S# i) = case abs (I# i) of I# j -> S# j
341     abs n@(J# s d) = if (s >=# 0#) then n else J# (negateInt# s) d
342
343     signum (S# i) = case signum (I# i) of I# j -> S# j
344     signum (J# s d)
345       = let
346             cmp = cmpIntegerInt# s d 0#
347         in
348         if      cmp >#  0# then S# 1#
349         else if cmp ==# 0# then S# 0#
350         else                    S# (negateInt# 1#)
351
352 plusInteger i1@(S# i) i2@(S# j)  = case addIntC# i j of { (# r, c #) ->
353                                    if c ==# 0# then S# r
354                                    else toBig i1 + toBig i2 }
355 plusInteger i1@(J# _ _) i2@(S# _) = i1 + toBig i2
356 plusInteger i1@(S# _) i2@(J# _ _) = toBig i1 + i2
357 plusInteger (J# s1 d1) (J# s2 d2) = case plusInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
358
359 minusInteger i1@(S# i) i2@(S# j)   = case subIntC# i j of { (# r, c #) ->
360                                      if c ==# 0# then S# r
361                                      else toBig i1 - toBig i2 }
362 minusInteger i1@(J# _ _) i2@(S# _) = i1 - toBig i2
363 minusInteger i1@(S# _) i2@(J# _ _) = toBig i1 - i2
364 minusInteger (J# s1 d1) (J# s2 d2) = case minusInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
365
366 timesInteger i1@(S# i) i2@(S# j)   = if   mulIntMayOflo# i j ==# 0#
367                                      then S# (i *# j)
368                                      else toBig i1 * toBig i2 
369 timesInteger i1@(J# _ _) i2@(S# _) = i1 * toBig i2
370 timesInteger i1@(S# _) i2@(J# _ _) = toBig i1 * i2
371 timesInteger (J# s1 d1) (J# s2 d2) = case timesInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
372
373 negateInteger (S# (-LEFTMOST_BIT#)) = LEFTMOST_BIT
374 negateInteger (S# i)              = S# (negateInt# i)
375 negateInteger (J# s d)            = J# (negateInt# s) d
376 \end{code}
377
378
379 %*********************************************************
380 %*                                                      *
381 \subsection{The @Integer@ instance for @Enum@}
382 %*                                                      *
383 %*********************************************************
384
385 \begin{code}
386 instance  Enum Integer  where
387     succ x               = x + 1
388     pred x               = x - 1
389     toEnum n             = int2Integer n
390     fromEnum n           = integer2Int n
391
392     {-# INLINE enumFrom #-}
393     {-# INLINE enumFromThen #-}
394     {-# INLINE enumFromTo #-}
395     {-# INLINE enumFromThenTo #-}
396     enumFrom x             = enumDeltaInteger  x 1
397     enumFromThen x y       = enumDeltaInteger  x (y-x)
398     enumFromTo x lim       = enumDeltaToInteger x 1     lim
399     enumFromThenTo x y lim = enumDeltaToInteger x (y-x) lim
400
401 {-# RULES
402 "enumDeltaInteger"      [~1] forall x y.  enumDeltaInteger x y     = build (\c _ -> enumDeltaIntegerFB c x y)
403 "efdtInteger"           [~1] forall x y l.enumDeltaToInteger x y l = build (\c n -> enumDeltaToIntegerFB c n x y l)
404 "enumDeltaInteger"      [1] enumDeltaIntegerFB   (:)    = enumDeltaInteger
405 "enumDeltaToInteger"    [1] enumDeltaToIntegerFB (:) [] = enumDeltaToInteger
406  #-}
407
408 enumDeltaIntegerFB :: (Integer -> b -> b) -> Integer -> Integer -> b
409 enumDeltaIntegerFB c x d = x `c` enumDeltaIntegerFB c (x+d) d
410
411 enumDeltaInteger :: Integer -> Integer -> [Integer]
412 enumDeltaInteger x d = x : enumDeltaInteger (x+d) d
413
414 enumDeltaToIntegerFB c n x delta lim
415   | delta >= 0 = up_fb c n x delta lim
416   | otherwise  = dn_fb c n x delta lim
417
418 enumDeltaToInteger x delta lim
419   | delta >= 0 = up_list x delta lim
420   | otherwise  = dn_list x delta lim
421
422 up_fb c n x delta lim = go (x::Integer)
423                       where
424                         go x | x > lim   = n
425                              | otherwise = x `c` go (x+delta)
426 dn_fb c n x delta lim = go (x::Integer)
427                       where
428                         go x | x < lim   = n
429                              | otherwise = x `c` go (x+delta)
430
431 up_list x delta lim = go (x::Integer)
432                     where
433                         go x | x > lim   = []
434                              | otherwise = x : go (x+delta)
435 dn_list x delta lim = go (x::Integer)
436                     where
437                         go x | x < lim   = []
438                              | otherwise = x : go (x+delta)
439
440 \end{code}
441
442
443 %*********************************************************
444 %*                                                      *
445 \subsection{The @Integer@ instances for @Show@}
446 %*                                                      *
447 %*********************************************************
448
449 \begin{code}
450 instance Show Integer where
451     showsPrec p n r
452         | p > 6 && n < 0 = '(' : jtos n (')' : r)
453                 -- Minor point: testing p first gives better code 
454                 -- in the not-uncommon case where the p argument
455                 -- is a constant
456         | otherwise      = jtos n r
457     showList = showList__ (showsPrec 0)
458
459 jtos :: Integer -> String -> String
460 jtos n cs
461     | n < 0     = '-' : jtos' (-n) cs
462     | otherwise = jtos' n cs
463     where
464     jtos' :: Integer -> String -> String
465     jtos' n' cs'
466         | n' < 10    = case unsafeChr (ord '0' + fromInteger n') of
467             c@(C# _) -> c:cs'
468         | otherwise = case unsafeChr (ord '0' + fromInteger r) of
469             c@(C# _) -> jtos' q (c:cs')
470         where
471         (q,r) = n' `quotRemInteger` 10
472 \end{code}