[project @ 2002-07-04 16:22:02 by simonmar]
[packages/base.git] / GHC / Num.lhs
1 \begin{code}
2 {-# OPTIONS -fno-implicit-prelude #-}
3 -----------------------------------------------------------------------------
4 -- |
5 -- Module      :  GHC.Num
6 -- Copyright   :  (c) The University of Glasgow 1994-2002
7 -- License     :  see libraries/base/LICENSE
8 -- 
9 -- Maintainer  :  cvs-ghc@haskell.org
10 -- Stability   :  internal
11 -- Portability :  non-portable (GHC Extensions)
12 --
13 -- The 'Num' class and the 'Integer' type.
14 --
15 -----------------------------------------------------------------------------
16
17 #include "MachDeps.h"
18 #if SIZEOF_HSWORD == 4
19 #define LEFTMOST_BIT 2147483648
20 #elif SIZEOF_HSWORD == 8
21 #define LEFTMOST_BIT 9223372036854775808
22 #else
23 #error Please define LEFTMOST_BIT to be 2^(SIZEOF_HSWORD*8-1)
24 #endif
25
26 module GHC.Num where
27
28 import {-# SOURCE #-} GHC.Err
29 import GHC.Base
30 import GHC.List
31 import GHC.Enum
32 import GHC.Show
33
34 infixl 7  *
35 infixl 6  +, -
36
37 default ()              -- Double isn't available yet, 
38                         -- and we shouldn't be using defaults anyway
39 \end{code}
40
41 %*********************************************************
42 %*                                                      *
43 \subsection{Standard numeric class}
44 %*                                                      *
45 %*********************************************************
46
47 \begin{code}
48 class  (Eq a, Show a) => Num a  where
49     (+), (-), (*)       :: a -> a -> a
50     negate              :: a -> a
51     abs, signum         :: a -> a
52     fromInteger         :: Integer -> a
53
54     x - y               = x + negate y
55     negate x            = 0 - x
56
57 {-# INLINE subtract #-}
58 subtract :: (Num a) => a -> a -> a
59 subtract x y = y - x
60 \end{code}
61
62
63 %*********************************************************
64 %*                                                      *
65 \subsection{Instances for @Int@}
66 %*                                                      *
67 %*********************************************************
68
69 \begin{code}
70 instance  Num Int  where
71     (+)    = plusInt
72     (-)    = minusInt
73     negate = negateInt
74     (*)    = timesInt
75     abs n  = if n `geInt` 0 then n else negateInt n
76
77     signum n | n `ltInt` 0 = negateInt 1
78              | n `eqInt` 0 = 0
79              | otherwise   = 1
80
81     fromInteger = integer2Int
82 \end{code}
83
84
85 \begin{code}
86 -- These can't go in GHC.Base with the defn of Int, because
87 -- we don't have pairs defined at that time!
88
89 quotRemInt :: Int -> Int -> (Int, Int)
90 a@(I# _) `quotRemInt` b@(I# _) = (a `quotInt` b, a `remInt` b)
91     -- OK, so I made it a little stricter.  Shoot me.  (WDP 94/10)
92
93 divModInt ::  Int -> Int -> (Int, Int)
94 divModInt x@(I# _) y@(I# _) = (x `divInt` y, x `modInt` y)
95     -- Stricter.  Sorry if you don't like it.  (WDP 94/10)
96 \end{code}
97
98
99 %*********************************************************
100 %*                                                      *
101 \subsection{The @Integer@ type}
102 %*                                                      *
103 %*********************************************************
104
105 \begin{code}
106 -- | Arbitrary-precision integers.
107 data Integer    
108    = S# Int#                            -- small integers
109 #ifndef ILX
110    | J# Int# ByteArray#                 -- large integers
111 #else
112    | J# Void BigInteger                 -- .NET big ints
113
114 foreign type dotnet "BigInteger" BigInteger
115 #endif
116 \end{code}
117
118 Convenient boxed Integer PrimOps. 
119
120 \begin{code}
121 zeroInteger :: Integer
122 zeroInteger = S# 0#
123
124 int2Integer :: Int -> Integer
125 {-# INLINE int2Integer #-}
126 int2Integer (I# i) = S# i
127
128 integer2Int :: Integer -> Int
129 integer2Int (S# i)   = I# i
130 integer2Int (J# s d) = case (integer2Int# s d) of { n# -> I# n# }
131
132 toBig (S# i)     = case int2Integer# i of { (# s, d #) -> J# s d }
133 toBig i@(J# _ _) = i
134 \end{code}
135
136
137 %*********************************************************
138 %*                                                      *
139 \subsection{Dividing @Integers@}
140 %*                                                      *
141 %*********************************************************
142
143 \begin{code}
144 quotRemInteger :: Integer -> Integer -> (Integer, Integer)
145 quotRemInteger a@(S# (-LEFTMOST_BIT#)) b = quotRemInteger (toBig a) b
146 quotRemInteger (S# i) (S# j)
147   = case quotRemInt (I# i) (I# j) of ( I# i, I# j ) -> ( S# i, S# j ) 
148 quotRemInteger i1@(J# _ _) i2@(S# _) = quotRemInteger i1 (toBig i2)
149 quotRemInteger i1@(S# _) i2@(J# _ _) = quotRemInteger (toBig i1) i2
150 quotRemInteger (J# s1 d1) (J# s2 d2)
151   = case (quotRemInteger# s1 d1 s2 d2) of
152           (# s3, d3, s4, d4 #)
153             -> (J# s3 d3, J# s4 d4)
154
155 divModInteger a@(S# (-LEFTMOST_BIT#)) b = divModInteger (toBig a) b
156 divModInteger (S# i) (S# j)
157   = case divModInt (I# i) (I# j) of ( I# i, I# j ) -> ( S# i, S# j) 
158 divModInteger i1@(J# _ _) i2@(S# _) = divModInteger i1 (toBig i2)
159 divModInteger i1@(S# _) i2@(J# _ _) = divModInteger (toBig i1) i2
160 divModInteger (J# s1 d1) (J# s2 d2)
161   = case (divModInteger# s1 d1 s2 d2) of
162           (# s3, d3, s4, d4 #)
163             -> (J# s3 d3, J# s4 d4)
164
165 remInteger :: Integer -> Integer -> Integer
166 remInteger ia 0
167   = error "Prelude.Integral.rem{Integer}: divide by 0"
168 remInteger a@(S# (-LEFTMOST_BIT#)) b = remInteger (toBig a) b
169 remInteger (S# a) (S# b) = S# (remInt# a b)
170 {- Special case doesn't work, because a 1-element J# has the range
171    -(2^32-1) -- 2^32-1, whereas S# has the range -2^31 -- (2^31-1)
172 remInteger ia@(S# a) (J# sb b)
173   | sb ==# 1#  = S# (remInt# a (word2Int# (integer2Word# sb b)))
174   | sb ==# -1# = S# (remInt# a (0# -# (word2Int# (integer2Word# sb b))))
175   | 0# <# sb   = ia
176   | otherwise  = S# (0# -# a)
177 -}
178 remInteger ia@(S# _) ib@(J# _ _) = remInteger (toBig ia) ib
179 remInteger (J# sa a) (S# b)
180   = case int2Integer# b of { (# sb, b #) ->
181     case remInteger# sa a sb b of { (# sr, r #) ->
182     S# (integer2Int# sr r) }}
183 remInteger (J# sa a) (J# sb b)
184   = case remInteger# sa a sb b of (# sr, r #) -> J# sr r
185
186 quotInteger :: Integer -> Integer -> Integer
187 quotInteger ia 0
188   = error "Prelude.Integral.quot{Integer}: divide by 0"
189 quotInteger a@(S# (-LEFTMOST_BIT#)) b = quotInteger (toBig a) b
190 quotInteger (S# a) (S# b) = S# (quotInt# a b)
191 {- Special case disabled, see remInteger above
192 quotInteger (S# a) (J# sb b)
193   | sb ==# 1#  = S# (quotInt# a (word2Int# (integer2Word# sb b)))
194   | sb ==# -1# = S# (quotInt# a (0# -# (word2Int# (integer2Word# sb b))))
195   | otherwise  = zeroInteger
196 -}
197 quotInteger ia@(S# _) ib@(J# _ _) = quotInteger (toBig ia) ib
198 quotInteger (J# sa a) (S# b)
199   = case int2Integer# b of { (# sb, b #) ->
200     case quotInteger# sa a sb b of (# sq, q #) -> J# sq q }
201 quotInteger (J# sa a) (J# sb b)
202   = case quotInteger# sa a sb b of (# sg, g #) -> J# sg g
203 \end{code}
204
205
206
207 \begin{code}
208 gcdInteger :: Integer -> Integer -> Integer
209 -- SUP: Do we really need the first two cases?
210 gcdInteger a@(S# (-LEFTMOST_BIT#)) b = gcdInteger (toBig a) b
211 gcdInteger a b@(S# (-LEFTMOST_BIT#)) = gcdInteger a (toBig b)
212 gcdInteger (S# a) (S# b) = case gcdInt (I# a) (I# b) of { I# c -> S# c }
213 gcdInteger ia@(S# 0#) ib@(J# 0# _) = error "GHC.Num.gcdInteger: gcd 0 0 is undefined"
214 gcdInteger ia@(S# a)  ib@(J# sb b)
215   | a  ==# 0#  = abs ib
216   | sb ==# 0#  = abs ia
217   | otherwise  = S# (gcdIntegerInt# absSb b absA)
218        where absA  = if a  <# 0# then negateInt# a  else a
219              absSb = if sb <# 0# then negateInt# sb else sb
220 gcdInteger ia@(J# _ _) ib@(S# _) = gcdInteger ib ia
221 gcdInteger (J# 0# _) (J# 0# _) = error "GHC.Num.gcdInteger: gcd 0 0 is undefined"
222 gcdInteger (J# sa a) (J# sb b)
223   = case gcdInteger# sa a sb b of (# sg, g #) -> J# sg g
224
225 lcmInteger :: Integer -> Integer -> Integer
226 lcmInteger a 0
227   = zeroInteger
228 lcmInteger 0 b
229   = zeroInteger
230 lcmInteger a b
231   = (divExact aa (gcdInteger aa ab)) * ab
232   where aa = abs a
233         ab = abs b
234
235 divExact :: Integer -> Integer -> Integer
236 divExact a@(S# (-LEFTMOST_BIT#)) b = divExact (toBig a) b
237 divExact (S# a) (S# b) = S# (quotInt# a b)
238 divExact (S# a) (J# sb b)
239   = S# (quotInt# a (integer2Int# sb b))
240 divExact (J# sa a) (S# b)
241   = case int2Integer# b of
242      (# sb, b #) -> case divExactInteger# sa a sb b of (# sd, d #) -> J# sd d
243 divExact (J# sa a) (J# sb b)
244   = case divExactInteger# sa a sb b of (# sd, d #) -> J# sd d
245 \end{code}
246
247
248 %*********************************************************
249 %*                                                      *
250 \subsection{The @Integer@ instances for @Eq@, @Ord@}
251 %*                                                      *
252 %*********************************************************
253
254 \begin{code}
255 instance  Eq Integer  where
256     (S# i)     ==  (S# j)     = i ==# j
257     (S# i)     ==  (J# s d)   = cmpIntegerInt# s d i ==# 0#
258     (J# s d)   ==  (S# i)     = cmpIntegerInt# s d i ==# 0#
259     (J# s1 d1) ==  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) ==# 0#
260
261     (S# i)     /=  (S# j)     = i /=# j
262     (S# i)     /=  (J# s d)   = cmpIntegerInt# s d i /=# 0#
263     (J# s d)   /=  (S# i)     = cmpIntegerInt# s d i /=# 0#
264     (J# s1 d1) /=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) /=# 0#
265
266 ------------------------------------------------------------------------
267 instance  Ord Integer  where
268     (S# i)     <=  (S# j)     = i <=# j
269     (J# s d)   <=  (S# i)     = cmpIntegerInt# s d i <=# 0#
270     (S# i)     <=  (J# s d)   = cmpIntegerInt# s d i >=# 0#
271     (J# s1 d1) <=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) <=# 0#
272
273     (S# i)     >   (S# j)     = i ># j
274     (J# s d)   >   (S# i)     = cmpIntegerInt# s d i ># 0#
275     (S# i)     >   (J# s d)   = cmpIntegerInt# s d i <# 0#
276     (J# s1 d1) >   (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) ># 0#
277
278     (S# i)     <   (S# j)     = i <# j
279     (J# s d)   <   (S# i)     = cmpIntegerInt# s d i <# 0#
280     (S# i)     <   (J# s d)   = cmpIntegerInt# s d i ># 0#
281     (J# s1 d1) <   (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) <# 0#
282
283     (S# i)     >=  (S# j)     = i >=# j
284     (J# s d)   >=  (S# i)     = cmpIntegerInt# s d i >=# 0#
285     (S# i)     >=  (J# s d)   = cmpIntegerInt# s d i <=# 0#
286     (J# s1 d1) >=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) >=# 0#
287
288     compare (S# i)  (S# j)
289        | i ==# j = EQ
290        | i <=# j = LT
291        | otherwise = GT
292     compare (J# s d) (S# i)
293        = case cmpIntegerInt# s d i of { res# ->
294          if res# <# 0# then LT else 
295          if res# ># 0# then GT else EQ
296          }
297     compare (S# i) (J# s d)
298        = case cmpIntegerInt# s d i of { res# ->
299          if res# ># 0# then LT else 
300          if res# <# 0# then GT else EQ
301          }
302     compare (J# s1 d1) (J# s2 d2)
303        = case cmpInteger# s1 d1 s2 d2 of { res# ->
304          if res# <# 0# then LT else 
305          if res# ># 0# then GT else EQ
306          }
307 \end{code}
308
309
310 %*********************************************************
311 %*                                                      *
312 \subsection{The @Integer@ instances for @Num@}
313 %*                                                      *
314 %*********************************************************
315
316 \begin{code}
317 instance  Num Integer  where
318     (+) = plusInteger
319     (-) = minusInteger
320     (*) = timesInteger
321     negate         = negateInteger
322     fromInteger x  =  x
323
324     -- ORIG: abs n = if n >= 0 then n else -n
325     abs (S# (-LEFTMOST_BIT#)) = LEFTMOST_BIT
326     abs (S# i) = case abs (I# i) of I# j -> S# j
327     abs n@(J# s d) = if (s >=# 0#) then n else J# (negateInt# s) d
328
329     signum (S# i) = case signum (I# i) of I# j -> S# j
330     signum (J# s d)
331       = let
332             cmp = cmpIntegerInt# s d 0#
333         in
334         if      cmp >#  0# then S# 1#
335         else if cmp ==# 0# then S# 0#
336         else                    S# (negateInt# 1#)
337
338 plusInteger i1@(S# i) i2@(S# j)  = case addIntC# i j of { (# r, c #) ->
339                                    if c ==# 0# then S# r
340                                    else toBig i1 + toBig i2 }
341 plusInteger i1@(J# _ _) i2@(S# _) = i1 + toBig i2
342 plusInteger i1@(S# _) i2@(J# _ _) = toBig i1 + i2
343 plusInteger (J# s1 d1) (J# s2 d2) = case plusInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
344
345 minusInteger i1@(S# i) i2@(S# j)   = case subIntC# i j of { (# r, c #) ->
346                                      if c ==# 0# then S# r
347                                      else toBig i1 - toBig i2 }
348 minusInteger i1@(J# _ _) i2@(S# _) = i1 - toBig i2
349 minusInteger i1@(S# _) i2@(J# _ _) = toBig i1 - i2
350 minusInteger (J# s1 d1) (J# s2 d2) = case minusInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
351
352 timesInteger i1@(S# i) i2@(S# j)   = if   mulIntMayOflo# i j ==# 0#
353                                      then S# (i *# j)
354                                      else toBig i1 * toBig i2 
355 timesInteger i1@(J# _ _) i2@(S# _) = i1 * toBig i2
356 timesInteger i1@(S# _) i2@(J# _ _) = toBig i1 * i2
357 timesInteger (J# s1 d1) (J# s2 d2) = case timesInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
358
359 negateInteger (S# (-LEFTMOST_BIT#)) = LEFTMOST_BIT
360 negateInteger (S# i)              = S# (negateInt# i)
361 negateInteger (J# s d)            = J# (negateInt# s) d
362 \end{code}
363
364
365 %*********************************************************
366 %*                                                      *
367 \subsection{The @Integer@ instance for @Enum@}
368 %*                                                      *
369 %*********************************************************
370
371 \begin{code}
372 instance  Enum Integer  where
373     succ x               = x + 1
374     pred x               = x - 1
375     toEnum n             = int2Integer n
376     fromEnum n           = integer2Int n
377
378     {-# INLINE enumFrom #-}
379     {-# INLINE enumFromThen #-}
380     {-# INLINE enumFromTo #-}
381     {-# INLINE enumFromThenTo #-}
382     enumFrom x             = enumDeltaInteger  x 1
383     enumFromThen x y       = enumDeltaInteger  x (y-x)
384     enumFromTo x lim       = enumDeltaToInteger x 1     lim
385     enumFromThenTo x y lim = enumDeltaToInteger x (y-x) lim
386
387 {-# RULES
388 "enumDeltaInteger"      [~1] forall x y.  enumDeltaInteger x y     = build (\c _ -> enumDeltaIntegerFB c x y)
389 "efdtInteger"           [~1] forall x y l.enumDeltaToInteger x y l = build (\c n -> enumDeltaToIntegerFB c n x y l)
390 "enumDeltaInteger"      [1] enumDeltaIntegerFB   (:)    = enumDeltaInteger
391 "enumDeltaToInteger"    [1] enumDeltaToIntegerFB (:) [] = enumDeltaToInteger
392  #-}
393
394 enumDeltaIntegerFB :: (Integer -> b -> b) -> Integer -> Integer -> b
395 enumDeltaIntegerFB c x d = x `c` enumDeltaIntegerFB c (x+d) d
396
397 enumDeltaInteger :: Integer -> Integer -> [Integer]
398 enumDeltaInteger x d = x : enumDeltaInteger (x+d) d
399
400 enumDeltaToIntegerFB c n x delta lim
401   | delta >= 0 = up_fb c n x delta lim
402   | otherwise  = dn_fb c n x delta lim
403
404 enumDeltaToInteger x delta lim
405   | delta >= 0 = up_list x delta lim
406   | otherwise  = dn_list x delta lim
407
408 up_fb c n x delta lim = go (x::Integer)
409                       where
410                         go x | x > lim   = n
411                              | otherwise = x `c` go (x+delta)
412 dn_fb c n x delta lim = go (x::Integer)
413                       where
414                         go x | x < lim   = n
415                              | otherwise = x `c` go (x+delta)
416
417 up_list x delta lim = go (x::Integer)
418                     where
419                         go x | x > lim   = []
420                              | otherwise = x : go (x+delta)
421 dn_list x delta lim = go (x::Integer)
422                     where
423                         go x | x < lim   = []
424                              | otherwise = x : go (x+delta)
425
426 \end{code}
427
428
429 %*********************************************************
430 %*                                                      *
431 \subsection{The @Integer@ instances for @Show@}
432 %*                                                      *
433 %*********************************************************
434
435 \begin{code}
436 instance Show Integer where
437     showsPrec p n r
438         | p > 6 && n < 0 = '(' : jtos n (')' : r)
439                 -- Minor point: testing p first gives better code 
440                 -- in the not-uncommon case where the p argument
441                 -- is a constant
442         | otherwise      = jtos n r
443     showList = showList__ (showsPrec 0)
444
445 jtos :: Integer -> String -> String
446 jtos n cs
447     | n < 0     = '-' : jtos' (-n) cs
448     | otherwise = jtos' n cs
449     where
450     jtos' :: Integer -> String -> String
451     jtos' n' cs'
452         | n' < 10    = case unsafeChr (ord '0' + fromInteger n') of
453             c@(C# _) -> c:cs'
454         | otherwise = case unsafeChr (ord '0' + fromInteger r) of
455             c@(C# _) -> jtos' q (c:cs')
456         where
457         (q,r) = n' `quotRemInteger` 10
458 \end{code}