Trim imports, remove a cycle
[packages/base.git] / GHC / IOBase.lhs
1 \begin{code}
2 {-# OPTIONS_GHC -fno-implicit-prelude #-}
3 -----------------------------------------------------------------------------
4 -- |
5 -- Module      :  GHC.IOBase
6 -- Copyright   :  (c) The University of Glasgow 1994-2002
7 -- License     :  see libraries/base/LICENSE
8 -- 
9 -- Maintainer  :  cvs-ghc@haskell.org
10 -- Stability   :  internal
11 -- Portability :  non-portable (GHC Extensions)
12 --
13 -- Definitions for the 'IO' monad and its friends.
14 --
15 -----------------------------------------------------------------------------
16
17 -- #hide
18 module GHC.IOBase(
19     IO(..), unIO, failIO, liftIO, bindIO, thenIO, returnIO, 
20     unsafePerformIO, unsafeInterleaveIO,
21     unsafeDupablePerformIO, unsafeDupableInterleaveIO,
22     noDuplicate,
23   
24         -- To and from from ST
25     stToIO, ioToST, unsafeIOToST, unsafeSTToIO,
26
27         -- References
28     IORef(..), newIORef, readIORef, writeIORef, 
29     IOArray(..), newIOArray, readIOArray, writeIOArray, unsafeReadIOArray, unsafeWriteIOArray,
30     MVar(..),
31
32         -- Handles, file descriptors,
33     FilePath,  
34     Handle(..), Handle__(..), HandleType(..), IOMode(..), FD, 
35     isReadableHandleType, isWritableHandleType, isReadWriteHandleType, showHandle,
36   
37         -- Buffers
38     Buffer(..), RawBuffer, BufferState(..), BufferList(..), BufferMode(..),
39     bufferIsWritable, bufferEmpty, bufferFull, 
40
41         -- Exceptions
42     Exception(..), ArithException(..), AsyncException(..), ArrayException(..),
43     stackOverflow, heapOverflow, throw, throwIO, ioException, 
44     IOError, IOException(..), IOErrorType(..), ioError, userError,
45     ExitCode(..) 
46   ) where
47         
48 import GHC.ST
49 import GHC.Arr  -- to derive Ix class
50 import GHC.Enum -- to derive Enum class
51 import GHC.STRef
52 import GHC.Base
53 --  import GHC.Num      -- To get fromInteger etc, needed because of -fno-implicit-prelude
54 import Data.Maybe  ( Maybe(..) )
55 import GHC.Show
56 import GHC.List
57 import GHC.Read
58 import Foreign.C.Types (CInt)
59
60 #ifndef __HADDOCK__
61 import {-# SOURCE #-} Data.Typeable     ( showsTypeRep )
62 import {-# SOURCE #-} Data.Dynamic      ( Dynamic, dynTypeRep )
63 #endif
64
65 -- ---------------------------------------------------------------------------
66 -- The IO Monad
67
68 {-
69 The IO Monad is just an instance of the ST monad, where the state is
70 the real world.  We use the exception mechanism (in GHC.Exception) to
71 implement IO exceptions.
72
73 NOTE: The IO representation is deeply wired in to various parts of the
74 system.  The following list may or may not be exhaustive:
75
76 Compiler  - types of various primitives in PrimOp.lhs
77
78 RTS       - forceIO (StgMiscClosures.hc)
79           - catchzh_fast, (un)?blockAsyncExceptionszh_fast, raisezh_fast 
80             (Exceptions.hc)
81           - raiseAsync (Schedule.c)
82
83 Prelude   - GHC.IOBase.lhs, and several other places including
84             GHC.Exception.lhs.
85
86 Libraries - parts of hslibs/lang.
87
88 --SDM
89 -}
90
91 {-|
92 A value of type @'IO' a@ is a computation which, when performed,
93 does some I\/O before returning a value of type @a@.  
94
95 There is really only one way to \"perform\" an I\/O action: bind it to
96 @Main.main@ in your program.  When your program is run, the I\/O will
97 be performed.  It isn't possible to perform I\/O from an arbitrary
98 function, unless that function is itself in the 'IO' monad and called
99 at some point, directly or indirectly, from @Main.main@.
100
101 'IO' is a monad, so 'IO' actions can be combined using either the do-notation
102 or the '>>' and '>>=' operations from the 'Monad' class.
103 -}
104 newtype IO a = IO (State# RealWorld -> (# State# RealWorld, a #))
105
106 unIO :: IO a -> (State# RealWorld -> (# State# RealWorld, a #))
107 unIO (IO a) = a
108
109 instance  Functor IO where
110    fmap f x = x >>= (return . f)
111
112 instance  Monad IO  where
113     {-# INLINE return #-}
114     {-# INLINE (>>)   #-}
115     {-# INLINE (>>=)  #-}
116     m >> k      =  m >>= \ _ -> k
117     return x    = returnIO x
118
119     m >>= k     = bindIO m k
120     fail s      = failIO s
121
122 failIO :: String -> IO a
123 failIO s = ioError (userError s)
124
125 liftIO :: IO a -> State# RealWorld -> STret RealWorld a
126 liftIO (IO m) = \s -> case m s of (# s', r #) -> STret s' r
127
128 bindIO :: IO a -> (a -> IO b) -> IO b
129 bindIO (IO m) k = IO ( \ s ->
130   case m s of 
131     (# new_s, a #) -> unIO (k a) new_s
132   )
133
134 thenIO :: IO a -> IO b -> IO b
135 thenIO (IO m) k = IO ( \ s ->
136   case m s of 
137     (# new_s, a #) -> unIO k new_s
138   )
139
140 returnIO :: a -> IO a
141 returnIO x = IO (\ s -> (# s, x #))
142
143 -- ---------------------------------------------------------------------------
144 -- Coercions between IO and ST
145
146 -- | A monad transformer embedding strict state transformers in the 'IO'
147 -- monad.  The 'RealWorld' parameter indicates that the internal state
148 -- used by the 'ST' computation is a special one supplied by the 'IO'
149 -- monad, and thus distinct from those used by invocations of 'runST'.
150 stToIO        :: ST RealWorld a -> IO a
151 stToIO (ST m) = IO m
152
153 ioToST        :: IO a -> ST RealWorld a
154 ioToST (IO m) = (ST m)
155
156 -- This relies on IO and ST having the same representation modulo the
157 -- constraint on the type of the state
158 --
159 unsafeIOToST        :: IO a -> ST s a
160 unsafeIOToST (IO io) = ST $ \ s -> (unsafeCoerce# io) s
161
162 unsafeSTToIO :: ST s a -> IO a
163 unsafeSTToIO (ST m) = IO (unsafeCoerce# m)
164
165 -- ---------------------------------------------------------------------------
166 -- Unsafe IO operations
167
168 {-|
169 This is the \"back door\" into the 'IO' monad, allowing
170 'IO' computation to be performed at any time.  For
171 this to be safe, the 'IO' computation should be
172 free of side effects and independent of its environment.
173
174 If the I\/O computation wrapped in 'unsafePerformIO'
175 performs side effects, then the relative order in which those side
176 effects take place (relative to the main I\/O trunk, or other calls to
177 'unsafePerformIO') is indeterminate.  You have to be careful when 
178 writing and compiling modules that use 'unsafePerformIO':
179
180   * Use @{\-\# NOINLINE foo \#-\}@ as a pragma on any function @foo@
181         that calls 'unsafePerformIO'.  If the call is inlined,
182         the I\/O may be performed more than once.
183
184   * Use the compiler flag @-fno-cse@ to prevent common sub-expression
185         elimination being performed on the module, which might combine
186         two side effects that were meant to be separate.  A good example
187         is using multiple global variables (like @test@ in the example below).
188
189   * Make sure that the either you switch off let-floating, or that the 
190         call to 'unsafePerformIO' cannot float outside a lambda.  For example, 
191         if you say:
192         @
193            f x = unsafePerformIO (newIORef [])
194         @
195         you may get only one reference cell shared between all calls to @f@.
196         Better would be
197         @
198            f x = unsafePerformIO (newIORef [x])
199         @
200         because now it can't float outside the lambda.
201
202 It is less well known that
203 'unsafePerformIO' is not type safe.  For example:
204
205 >     test :: IORef [a]
206 >     test = unsafePerformIO $ newIORef []
207 >     
208 >     main = do
209 >             writeIORef test [42]
210 >             bang <- readIORef test
211 >             print (bang :: [Char])
212
213 This program will core dump.  This problem with polymorphic references
214 is well known in the ML community, and does not arise with normal
215 monadic use of references.  There is no easy way to make it impossible
216 once you use 'unsafePerformIO'.  Indeed, it is
217 possible to write @coerce :: a -> b@ with the
218 help of 'unsafePerformIO'.  So be careful!
219 -}
220 unsafePerformIO :: IO a -> a
221 unsafePerformIO m = unsafeDupablePerformIO (noDuplicate >> m)
222
223 {-| 
224 This version of 'unsafePerformIO' is slightly more efficient,
225 because it omits the check that the IO is only being performed by a
226 single thread.  Hence, when you write 'unsafeDupablePerformIO',
227 there is a possibility that the IO action may be performed multiple
228 times (on a multiprocessor), and you should therefore ensure that
229 it gives the same results each time.
230 -}
231 {-# NOINLINE unsafeDupablePerformIO #-}
232 unsafeDupablePerformIO  :: IO a -> a
233 unsafeDupablePerformIO (IO m) = lazy (case m realWorld# of (# _, r #) -> r)
234
235 -- Why do we NOINLINE unsafeDupablePerformIO?  See the comment with
236 -- GHC.ST.runST.  Essentially the issue is that the IO computation
237 -- inside unsafePerformIO must be atomic: it must either all run, or
238 -- not at all.  If we let the compiler see the application of the IO
239 -- to realWorld#, it might float out part of the IO.
240
241 -- Why is there a call to 'lazy' in unsafeDupablePerformIO?
242 -- If we don't have it, the demand analyser discovers the following strictness
243 -- for unsafeDupablePerformIO:  C(U(AV))
244 -- But then consider
245 --      unsafeDupablePerformIO (\s -> let r = f x in 
246 --                             case writeIORef v r s of (# s1, _ #) ->
247 --                             (# s1, r #)
248 -- The strictness analyser will find that the binding for r is strict,
249 -- (becuase of uPIO's strictness sig), and so it'll evaluate it before 
250 -- doing the writeIORef.  This actually makes tests/lib/should_run/memo002
251 -- get a deadlock!  
252 --
253 -- Solution: don't expose the strictness of unsafeDupablePerformIO,
254 --           by hiding it with 'lazy'
255
256 {-|
257 'unsafeInterleaveIO' allows 'IO' computation to be deferred lazily.
258 When passed a value of type @IO a@, the 'IO' will only be performed
259 when the value of the @a@ is demanded.  This is used to implement lazy
260 file reading, see 'System.IO.hGetContents'.
261 -}
262 {-# INLINE unsafeInterleaveIO #-}
263 unsafeInterleaveIO :: IO a -> IO a
264 unsafeInterleaveIO m = unsafeDupableInterleaveIO (noDuplicate >> m)
265
266 -- We believe that INLINE on unsafeInterleaveIO is safe, because the
267 -- state from this IO thread is passed explicitly to the interleaved
268 -- IO, so it cannot be floated out and shared.
269
270 {-# INLINE unsafeDupableInterleaveIO #-}
271 unsafeDupableInterleaveIO :: IO a -> IO a
272 unsafeDupableInterleaveIO (IO m)
273   = IO ( \ s -> let
274                    r = case m s of (# _, res #) -> res
275                 in
276                 (# s, r #))
277
278 {-| 
279 Ensures that the suspensions under evaluation by the current thread
280 are unique; that is, the current thread is not evaluating anything
281 that is also under evaluation by another thread that has also executed
282 'noDuplicate'.
283
284 This operation is used in the definition of 'unsafePerformIO' to
285 prevent the IO action from being executed multiple times, which is usually
286 undesirable.
287 -}
288 noDuplicate :: IO ()
289 noDuplicate = IO $ \s -> case noDuplicate# s of s' -> (# s', () #)
290
291 -- ---------------------------------------------------------------------------
292 -- Handle type
293
294 data MVar a = MVar (MVar# RealWorld a)
295 {- ^
296 An 'MVar' (pronounced \"em-var\") is a synchronising variable, used
297 for communication between concurrent threads.  It can be thought of
298 as a a box, which may be empty or full.
299 -}
300
301 -- pull in Eq (Mvar a) too, to avoid GHC.Conc being an orphan-instance module
302 instance Eq (MVar a) where
303         (MVar mvar1#) == (MVar mvar2#) = sameMVar# mvar1# mvar2#
304
305 --  A Handle is represented by (a reference to) a record 
306 --  containing the state of the I/O port/device. We record
307 --  the following pieces of info:
308
309 --    * type (read,write,closed etc.)
310 --    * the underlying file descriptor
311 --    * buffering mode 
312 --    * buffer, and spare buffers
313 --    * user-friendly name (usually the
314 --      FilePath used when IO.openFile was called)
315
316 -- Note: when a Handle is garbage collected, we want to flush its buffer
317 -- and close the OS file handle, so as to free up a (precious) resource.
318
319 -- | Haskell defines operations to read and write characters from and to files,
320 -- represented by values of type @Handle@.  Each value of this type is a
321 -- /handle/: a record used by the Haskell run-time system to /manage/ I\/O
322 -- with file system objects.  A handle has at least the following properties:
323 -- 
324 --  * whether it manages input or output or both;
325 --
326 --  * whether it is /open/, /closed/ or /semi-closed/;
327 --
328 --  * whether the object is seekable;
329 --
330 --  * whether buffering is disabled, or enabled on a line or block basis;
331 --
332 --  * a buffer (whose length may be zero).
333 --
334 -- Most handles will also have a current I\/O position indicating where the next
335 -- input or output operation will occur.  A handle is /readable/ if it
336 -- manages only input or both input and output; likewise, it is /writable/ if
337 -- it manages only output or both input and output.  A handle is /open/ when
338 -- first allocated.
339 -- Once it is closed it can no longer be used for either input or output,
340 -- though an implementation cannot re-use its storage while references
341 -- remain to it.  Handles are in the 'Show' and 'Eq' classes.  The string
342 -- produced by showing a handle is system dependent; it should include
343 -- enough information to identify the handle for debugging.  A handle is
344 -- equal according to '==' only to itself; no attempt
345 -- is made to compare the internal state of different handles for equality.
346 --
347 -- GHC note: a 'Handle' will be automatically closed when the garbage
348 -- collector detects that it has become unreferenced by the program.
349 -- However, relying on this behaviour is not generally recommended:
350 -- the garbage collector is unpredictable.  If possible, use explicit
351 -- an explicit 'hClose' to close 'Handle's when they are no longer
352 -- required.  GHC does not currently attempt to free up file
353 -- descriptors when they have run out, it is your responsibility to
354 -- ensure that this doesn't happen.
355
356 data Handle 
357   = FileHandle                          -- A normal handle to a file
358         FilePath                        -- the file (invariant)
359         !(MVar Handle__)
360
361   | DuplexHandle                        -- A handle to a read/write stream
362         FilePath                        -- file for a FIFO, otherwise some
363                                         --   descriptive string.
364         !(MVar Handle__)                -- The read side
365         !(MVar Handle__)                -- The write side
366
367 -- NOTES:
368 --    * A 'FileHandle' is seekable.  A 'DuplexHandle' may or may not be
369 --      seekable.
370
371 instance Eq Handle where
372  (FileHandle _ h1)     == (FileHandle _ h2)     = h1 == h2
373  (DuplexHandle _ h1 _) == (DuplexHandle _ h2 _) = h1 == h2
374  _ == _ = False 
375
376 type FD = CInt
377
378 data Handle__
379   = Handle__ {
380       haFD          :: !FD,                  -- file descriptor
381       haType        :: HandleType,           -- type (read/write/append etc.)
382       haIsBin       :: Bool,                 -- binary mode?
383       haIsStream    :: Bool,                 -- is this a stream handle?
384       haBufferMode  :: BufferMode,           -- buffer contains read/write data?
385       haBuffer      :: !(IORef Buffer),      -- the current buffer
386       haBuffers     :: !(IORef BufferList),  -- spare buffers
387       haOtherSide   :: Maybe (MVar Handle__) -- ptr to the write side of a 
388                                              -- duplex handle.
389     }
390
391 -- ---------------------------------------------------------------------------
392 -- Buffers
393
394 -- The buffer is represented by a mutable variable containing a
395 -- record, where the record contains the raw buffer and the start/end
396 -- points of the filled portion.  We use a mutable variable so that
397 -- the common operation of writing (or reading) some data from (to)
398 -- the buffer doesn't need to modify, and hence copy, the handle
399 -- itself, it just updates the buffer.  
400
401 -- There will be some allocation involved in a simple hPutChar in
402 -- order to create the new Buffer structure (below), but this is
403 -- relatively small, and this only has to be done once per write
404 -- operation.
405
406 -- The buffer contains its size - we could also get the size by
407 -- calling sizeOfMutableByteArray# on the raw buffer, but that tends
408 -- to be rounded up to the nearest Word.
409
410 type RawBuffer = MutableByteArray# RealWorld
411
412 -- INVARIANTS on a Buffer:
413 --
414 --   * A handle *always* has a buffer, even if it is only 1 character long
415 --     (an unbuffered handle needs a 1 character buffer in order to support
416 --      hLookAhead and hIsEOF).
417 --   * r <= w
418 --   * if r == w, then r == 0 && w == 0
419 --   * if state == WriteBuffer, then r == 0
420 --   * a write buffer is never full.  If an operation
421 --     fills up the buffer, it will always flush it before 
422 --     returning.
423 --   * a read buffer may be full as a result of hLookAhead.  In normal
424 --     operation, a read buffer always has at least one character of space.
425
426 data Buffer 
427   = Buffer {
428         bufBuf   :: RawBuffer,
429         bufRPtr  :: !Int,
430         bufWPtr  :: !Int,
431         bufSize  :: !Int,
432         bufState :: BufferState
433   }
434
435 data BufferState = ReadBuffer | WriteBuffer deriving (Eq)
436
437 -- we keep a few spare buffers around in a handle to avoid allocating
438 -- a new one for each hPutStr.  These buffers are *guaranteed* to be the
439 -- same size as the main buffer.
440 data BufferList 
441   = BufferListNil 
442   | BufferListCons RawBuffer BufferList
443
444
445 bufferIsWritable :: Buffer -> Bool
446 bufferIsWritable Buffer{ bufState=WriteBuffer } = True
447 bufferIsWritable _other = False
448
449 bufferEmpty :: Buffer -> Bool
450 bufferEmpty Buffer{ bufRPtr=r, bufWPtr=w } = r == w
451
452 -- only makes sense for a write buffer
453 bufferFull :: Buffer -> Bool
454 bufferFull b@Buffer{ bufWPtr=w } = w >= bufSize b
455
456 --  Internally, we classify handles as being one
457 --  of the following:
458
459 data HandleType
460  = ClosedHandle
461  | SemiClosedHandle
462  | ReadHandle
463  | WriteHandle
464  | AppendHandle
465  | ReadWriteHandle
466
467 isReadableHandleType ReadHandle         = True
468 isReadableHandleType ReadWriteHandle    = True
469 isReadableHandleType _                  = False
470
471 isWritableHandleType AppendHandle    = True
472 isWritableHandleType WriteHandle     = True
473 isWritableHandleType ReadWriteHandle = True
474 isWritableHandleType _               = False
475
476 isReadWriteHandleType ReadWriteHandle{} = True
477 isReadWriteHandleType _                 = False
478
479 -- | File and directory names are values of type 'String', whose precise
480 -- meaning is operating system dependent. Files can be opened, yielding a
481 -- handle which can then be used to operate on the contents of that file.
482
483 type FilePath = String
484
485 -- ---------------------------------------------------------------------------
486 -- Buffering modes
487
488 -- | Three kinds of buffering are supported: line-buffering, 
489 -- block-buffering or no-buffering.  These modes have the following
490 -- effects. For output, items are written out, or /flushed/,
491 -- from the internal buffer according to the buffer mode:
492 --
493 --  * /line-buffering/: the entire output buffer is flushed
494 --    whenever a newline is output, the buffer overflows, 
495 --    a 'System.IO.hFlush' is issued, or the handle is closed.
496 --
497 --  * /block-buffering/: the entire buffer is written out whenever it
498 --    overflows, a 'System.IO.hFlush' is issued, or the handle is closed.
499 --
500 --  * /no-buffering/: output is written immediately, and never stored
501 --    in the buffer.
502 --
503 -- An implementation is free to flush the buffer more frequently,
504 -- but not less frequently, than specified above.
505 -- The output buffer is emptied as soon as it has been written out.
506 --
507 -- Similarly, input occurs according to the buffer mode for the handle:
508 --
509 --  * /line-buffering/: when the buffer for the handle is not empty,
510 --    the next item is obtained from the buffer; otherwise, when the
511 --    buffer is empty, characters up to and including the next newline
512 --    character are read into the buffer.  No characters are available
513 --    until the newline character is available or the buffer is full.
514 --
515 --  * /block-buffering/: when the buffer for the handle becomes empty,
516 --    the next block of data is read into the buffer.
517 --
518 --  * /no-buffering/: the next input item is read and returned.
519 --    The 'System.IO.hLookAhead' operation implies that even a no-buffered
520 --    handle may require a one-character buffer.
521 --
522 -- The default buffering mode when a handle is opened is
523 -- implementation-dependent and may depend on the file system object
524 -- which is attached to that handle.
525 -- For most implementations, physical files will normally be block-buffered 
526 -- and terminals will normally be line-buffered.
527
528 data BufferMode  
529  = NoBuffering  -- ^ buffering is disabled if possible.
530  | LineBuffering
531                 -- ^ line-buffering should be enabled if possible.
532  | BlockBuffering (Maybe Int)
533                 -- ^ block-buffering should be enabled if possible.
534                 -- The size of the buffer is @n@ items if the argument
535                 -- is 'Just' @n@ and is otherwise implementation-dependent.
536    deriving (Eq, Ord, Read, Show)
537
538 -- ---------------------------------------------------------------------------
539 -- IORefs
540
541 -- |A mutable variable in the 'IO' monad
542 newtype IORef a = IORef (STRef RealWorld a)
543
544 -- explicit instance because Haddock can't figure out a derived one
545 instance Eq (IORef a) where
546   IORef x == IORef y = x == y
547
548 -- |Build a new 'IORef'
549 newIORef    :: a -> IO (IORef a)
550 newIORef v = stToIO (newSTRef v) >>= \ var -> return (IORef var)
551
552 -- |Read the value of an 'IORef'
553 readIORef   :: IORef a -> IO a
554 readIORef  (IORef var) = stToIO (readSTRef var)
555
556 -- |Write a new value into an 'IORef'
557 writeIORef  :: IORef a -> a -> IO ()
558 writeIORef (IORef var) v = stToIO (writeSTRef var v)
559
560 -- ---------------------------------------------------------------------------
561 -- | An 'IOArray' is a mutable, boxed, non-strict array in the 'IO' monad.  
562 -- The type arguments are as follows:
563 --
564 --  * @i@: the index type of the array (should be an instance of 'Ix')
565 --
566 --  * @e@: the element type of the array.
567 --
568 -- 
569
570 newtype IOArray i e = IOArray (STArray RealWorld i e)
571
572 -- explicit instance because Haddock can't figure out a derived one
573 instance Eq (IOArray i e) where
574   IOArray x == IOArray y = x == y
575
576 -- |Build a new 'IOArray'
577 newIOArray :: Ix i => (i,i) -> e -> IO (IOArray i e)
578 {-# INLINE newIOArray #-}
579 newIOArray lu init  = stToIO $ do {marr <- newSTArray lu init; return (IOArray marr)}
580
581 -- | Read a value from an 'IOArray'
582 unsafeReadIOArray  :: Ix i => IOArray i e -> Int -> IO e
583 {-# INLINE unsafeReadIOArray #-}
584 unsafeReadIOArray (IOArray marr) i = stToIO (unsafeReadSTArray marr i)
585
586 -- | Write a new value into an 'IOArray'
587 unsafeWriteIOArray :: Ix i => IOArray i e -> Int -> e -> IO ()
588 {-# INLINE unsafeWriteIOArray #-}
589 unsafeWriteIOArray (IOArray marr) i e = stToIO (unsafeWriteSTArray marr i e)
590
591 -- | Read a value from an 'IOArray'
592 readIOArray  :: Ix i => IOArray i e -> i -> IO e
593 readIOArray (IOArray marr) i = stToIO (readSTArray marr i)
594
595 -- | Write a new value into an 'IOArray'
596 writeIOArray :: Ix i => IOArray i e -> i -> e -> IO ()
597 writeIOArray (IOArray marr) i e = stToIO (writeSTArray marr i e)
598
599
600 -- ---------------------------------------------------------------------------
601 -- Show instance for Handles
602
603 -- handle types are 'show'n when printing error msgs, so
604 -- we provide a more user-friendly Show instance for it
605 -- than the derived one.
606
607 instance Show HandleType where
608   showsPrec p t =
609     case t of
610       ClosedHandle      -> showString "closed"
611       SemiClosedHandle  -> showString "semi-closed"
612       ReadHandle        -> showString "readable"
613       WriteHandle       -> showString "writable"
614       AppendHandle      -> showString "writable (append)"
615       ReadWriteHandle   -> showString "read-writable"
616
617 instance Show Handle where 
618   showsPrec p (FileHandle   file _)   = showHandle file
619   showsPrec p (DuplexHandle file _ _) = showHandle file
620
621 showHandle file = showString "{handle: " . showString file . showString "}"
622
623 -- ------------------------------------------------------------------------
624 -- Exception datatype and operations
625
626 -- |The type of exceptions.  Every kind of system-generated exception
627 -- has a constructor in the 'Exception' type, and values of other
628 -- types may be injected into 'Exception' by coercing them to
629 -- 'Data.Dynamic.Dynamic' (see the section on Dynamic Exceptions:
630 -- "Control.Exception\#DynamicExceptions").
631 data Exception
632   = ArithException      ArithException
633         -- ^Exceptions raised by arithmetic
634         -- operations.  (NOTE: GHC currently does not throw
635         -- 'ArithException's except for 'DivideByZero').
636   | ArrayException      ArrayException
637         -- ^Exceptions raised by array-related
638         -- operations.  (NOTE: GHC currently does not throw
639         -- 'ArrayException's).
640   | AssertionFailed     String
641         -- ^This exception is thrown by the
642         -- 'assert' operation when the condition
643         -- fails.  The 'String' argument contains the
644         -- location of the assertion in the source program.
645   | AsyncException      AsyncException
646         -- ^Asynchronous exceptions (see section on Asynchronous Exceptions: "Control.Exception\#AsynchronousExceptions").
647   | BlockedOnDeadMVar
648         -- ^The current thread was executing a call to
649         -- 'Control.Concurrent.MVar.takeMVar' that could never return,
650         -- because there are no other references to this 'MVar'.
651   | BlockedIndefinitely
652         -- ^The current thread was waiting to retry an atomic memory transaction
653         -- that could never become possible to complete because there are no other
654         -- threads referring to any of teh TVars involved.
655   | NestedAtomically
656         -- ^The runtime detected an attempt to nest one STM transaction
657         -- inside another one, presumably due to the use of 
658         -- 'unsafePeformIO' with 'atomically'.
659   | Deadlock
660         -- ^There are no runnable threads, so the program is
661         -- deadlocked.  The 'Deadlock' exception is
662         -- raised in the main thread only (see also: "Control.Concurrent").
663   | DynException        Dynamic
664         -- ^Dynamically typed exceptions (see section on Dynamic Exceptions: "Control.Exception\#DynamicExceptions").
665   | ErrorCall           String
666         -- ^The 'ErrorCall' exception is thrown by 'error'.  The 'String'
667         -- argument of 'ErrorCall' is the string passed to 'error' when it was
668         -- called.
669   | ExitException       ExitCode
670         -- ^The 'ExitException' exception is thrown by 'System.Exit.exitWith' (and
671         -- 'System.Exit.exitFailure').  The 'ExitCode' argument is the value passed 
672         -- to 'System.Exit.exitWith'.  An unhandled 'ExitException' exception in the
673         -- main thread will cause the program to be terminated with the given 
674         -- exit code.
675   | IOException         IOException
676         -- ^These are the standard IO exceptions generated by
677         -- Haskell\'s @IO@ operations.  See also "System.IO.Error".
678   | NoMethodError       String
679         -- ^An attempt was made to invoke a class method which has
680         -- no definition in this instance, and there was no default
681         -- definition given in the class declaration.  GHC issues a
682         -- warning when you compile an instance which has missing
683         -- methods.
684   | NonTermination
685         -- ^The current thread is stuck in an infinite loop.  This
686         -- exception may or may not be thrown when the program is
687         -- non-terminating.
688   | PatternMatchFail    String
689         -- ^A pattern matching failure.  The 'String' argument should contain a
690         -- descriptive message including the function name, source file
691         -- and line number.
692   | RecConError         String
693         -- ^An attempt was made to evaluate a field of a record
694         -- for which no value was given at construction time.  The
695         -- 'String' argument gives the location of the
696         -- record construction in the source program.
697   | RecSelError         String
698         -- ^A field selection was attempted on a constructor that
699         -- doesn\'t have the requested field.  This can happen with
700         -- multi-constructor records when one or more fields are
701         -- missing from some of the constructors.  The
702         -- 'String' argument gives the location of the
703         -- record selection in the source program.
704   | RecUpdError         String
705         -- ^An attempt was made to update a field in a record,
706         -- where the record doesn\'t have the requested field.  This can
707         -- only occur with multi-constructor records, when one or more
708         -- fields are missing from some of the constructors.  The
709         -- 'String' argument gives the location of the
710         -- record update in the source program.
711
712 -- |The type of arithmetic exceptions
713 data ArithException
714   = Overflow
715   | Underflow
716   | LossOfPrecision
717   | DivideByZero
718   | Denormal
719   deriving (Eq, Ord)
720
721
722 -- |Asynchronous exceptions
723 data AsyncException
724   = StackOverflow
725         -- ^The current thread\'s stack exceeded its limit.
726         -- Since an exception has been raised, the thread\'s stack
727         -- will certainly be below its limit again, but the
728         -- programmer should take remedial action
729         -- immediately.
730   | HeapOverflow
731         -- ^The program\'s heap is reaching its limit, and
732         -- the program should take action to reduce the amount of
733         -- live data it has. Notes:
734         --
735         --      * It is undefined which thread receives this exception.
736         --
737         --      * GHC currently does not throw 'HeapOverflow' exceptions.
738   | ThreadKilled
739         -- ^This exception is raised by another thread
740         -- calling 'Control.Concurrent.killThread', or by the system
741         -- if it needs to terminate the thread for some
742         -- reason.
743   deriving (Eq, Ord)
744
745 -- | Exceptions generated by array operations
746 data ArrayException
747   = IndexOutOfBounds    String
748         -- ^An attempt was made to index an array outside
749         -- its declared bounds.
750   | UndefinedElement    String
751         -- ^An attempt was made to evaluate an element of an
752         -- array that had not been initialized.
753   deriving (Eq, Ord)
754
755 stackOverflow, heapOverflow :: Exception -- for the RTS
756 stackOverflow = AsyncException StackOverflow
757 heapOverflow  = AsyncException HeapOverflow
758
759 instance Show ArithException where
760   showsPrec _ Overflow        = showString "arithmetic overflow"
761   showsPrec _ Underflow       = showString "arithmetic underflow"
762   showsPrec _ LossOfPrecision = showString "loss of precision"
763   showsPrec _ DivideByZero    = showString "divide by zero"
764   showsPrec _ Denormal        = showString "denormal"
765
766 instance Show AsyncException where
767   showsPrec _ StackOverflow   = showString "stack overflow"
768   showsPrec _ HeapOverflow    = showString "heap overflow"
769   showsPrec _ ThreadKilled    = showString "thread killed"
770
771 instance Show ArrayException where
772   showsPrec _ (IndexOutOfBounds s)
773         = showString "array index out of range"
774         . (if not (null s) then showString ": " . showString s
775                            else id)
776   showsPrec _ (UndefinedElement s)
777         = showString "undefined array element"
778         . (if not (null s) then showString ": " . showString s
779                            else id)
780
781 instance Show Exception where
782   showsPrec _ (IOException err)          = shows err
783   showsPrec _ (ArithException err)       = shows err
784   showsPrec _ (ArrayException err)       = shows err
785   showsPrec _ (ErrorCall err)            = showString err
786   showsPrec _ (ExitException err)        = showString "exit: " . shows err
787   showsPrec _ (NoMethodError err)        = showString err
788   showsPrec _ (PatternMatchFail err)     = showString err
789   showsPrec _ (RecSelError err)          = showString err
790   showsPrec _ (RecConError err)          = showString err
791   showsPrec _ (RecUpdError err)          = showString err
792   showsPrec _ (AssertionFailed err)      = showString err
793   showsPrec _ (DynException err)         = showString "exception :: " . showsTypeRep (dynTypeRep err)
794   showsPrec _ (AsyncException e)         = shows e
795   showsPrec _ (BlockedOnDeadMVar)        = showString "thread blocked indefinitely"
796   showsPrec _ (BlockedIndefinitely)      = showString "thread blocked indefinitely"
797   showsPrec _ (NestedAtomically)         = showString "Control.Concurrent.STM.atomically was nested"
798   showsPrec _ (NonTermination)           = showString "<<loop>>"
799   showsPrec _ (Deadlock)                 = showString "<<deadlock>>"
800
801 instance Eq Exception where
802   IOException e1      == IOException e2      = e1 == e2
803   ArithException e1   == ArithException e2   = e1 == e2
804   ArrayException e1   == ArrayException e2   = e1 == e2
805   ErrorCall e1        == ErrorCall e2        = e1 == e2
806   ExitException e1    == ExitException e2    = e1 == e2
807   NoMethodError e1    == NoMethodError e2    = e1 == e2
808   PatternMatchFail e1 == PatternMatchFail e2 = e1 == e2
809   RecSelError e1      == RecSelError e2      = e1 == e2
810   RecConError e1      == RecConError e2      = e1 == e2
811   RecUpdError e1      == RecUpdError e2      = e1 == e2
812   AssertionFailed e1  == AssertionFailed e2  = e1 == e2
813   DynException _      == DynException _      = False -- incomparable
814   AsyncException e1   == AsyncException e2   = e1 == e2
815   BlockedOnDeadMVar   == BlockedOnDeadMVar   = True
816   NonTermination      == NonTermination      = True
817   NestedAtomically    == NestedAtomically    = True
818   Deadlock            == Deadlock            = True
819   _                   == _                   = False
820
821 -- -----------------------------------------------------------------------------
822 -- The ExitCode type
823
824 -- We need it here because it is used in ExitException in the
825 -- Exception datatype (above).
826
827 data ExitCode
828   = ExitSuccess -- ^ indicates successful termination;
829   | ExitFailure Int
830                 -- ^ indicates program failure with an exit code.
831                 -- The exact interpretation of the code is
832                 -- operating-system dependent.  In particular, some values
833                 -- may be prohibited (e.g. 0 on a POSIX-compliant system).
834   deriving (Eq, Ord, Read, Show)
835
836 -- --------------------------------------------------------------------------
837 -- Primitive throw
838
839 -- | Throw an exception.  Exceptions may be thrown from purely
840 -- functional code, but may only be caught within the 'IO' monad.
841 throw :: Exception -> a
842 throw exception = raise# exception
843
844 -- | A variant of 'throw' that can be used within the 'IO' monad.
845 --
846 -- Although 'throwIO' has a type that is an instance of the type of 'throw', the
847 -- two functions are subtly different:
848 --
849 -- > throw e   `seq` x  ===> throw e
850 -- > throwIO e `seq` x  ===> x
851 --
852 -- The first example will cause the exception @e@ to be raised,
853 -- whereas the second one won\'t.  In fact, 'throwIO' will only cause
854 -- an exception to be raised when it is used within the 'IO' monad.
855 -- The 'throwIO' variant should be used in preference to 'throw' to
856 -- raise an exception within the 'IO' monad because it guarantees
857 -- ordering with respect to other 'IO' operations, whereas 'throw'
858 -- does not.
859 throwIO         :: Exception -> IO a
860 throwIO err     =  IO $ raiseIO# err
861
862 ioException     :: IOException -> IO a
863 ioException err =  IO $ raiseIO# (IOException err)
864
865 -- | Raise an 'IOError' in the 'IO' monad.
866 ioError         :: IOError -> IO a 
867 ioError         =  ioException
868
869 -- ---------------------------------------------------------------------------
870 -- IOError type
871
872 -- | The Haskell 98 type for exceptions in the 'IO' monad.
873 -- Any I\/O operation may raise an 'IOError' instead of returning a result.
874 -- For a more general type of exception, including also those that arise
875 -- in pure code, see 'Control.Exception.Exception'.
876 --
877 -- In Haskell 98, this is an opaque type.
878 type IOError = IOException
879
880 -- |Exceptions that occur in the @IO@ monad.
881 -- An @IOException@ records a more specific error type, a descriptive
882 -- string and maybe the handle that was used when the error was
883 -- flagged.
884 data IOException
885  = IOError {
886      ioe_handle   :: Maybe Handle,   -- the handle used by the action flagging 
887                                      -- the error.
888      ioe_type     :: IOErrorType,    -- what it was.
889      ioe_location :: String,         -- location.
890      ioe_description :: String,      -- error type specific information.
891      ioe_filename :: Maybe FilePath  -- filename the error is related to.
892    }
893
894 instance Eq IOException where
895   (IOError h1 e1 loc1 str1 fn1) == (IOError h2 e2 loc2 str2 fn2) = 
896     e1==e2 && str1==str2 && h1==h2 && loc1==loc2 && fn1==fn2
897
898 -- | An abstract type that contains a value for each variant of 'IOError'.
899 data IOErrorType
900   -- Haskell 98:
901   = AlreadyExists
902   | NoSuchThing
903   | ResourceBusy
904   | ResourceExhausted
905   | EOF
906   | IllegalOperation
907   | PermissionDenied
908   | UserError
909   -- GHC only:
910   | UnsatisfiedConstraints
911   | SystemError
912   | ProtocolError
913   | OtherError
914   | InvalidArgument
915   | InappropriateType
916   | HardwareFault
917   | UnsupportedOperation
918   | TimeExpired
919   | ResourceVanished
920   | Interrupted
921   | DynIOError Dynamic -- cheap&cheerful extensible IO error type.
922
923 instance Eq IOErrorType where
924    x == y = 
925      case x of
926        DynIOError{} -> False -- from a strictness POV, compatible with a derived Eq inst?
927        _ -> getTag x ==# getTag y
928  
929 instance Show IOErrorType where
930   showsPrec _ e =
931     showString $
932     case e of
933       AlreadyExists     -> "already exists"
934       NoSuchThing       -> "does not exist"
935       ResourceBusy      -> "resource busy"
936       ResourceExhausted -> "resource exhausted"
937       EOF               -> "end of file"
938       IllegalOperation  -> "illegal operation"
939       PermissionDenied  -> "permission denied"
940       UserError         -> "user error"
941       HardwareFault     -> "hardware fault"
942       InappropriateType -> "inappropriate type"
943       Interrupted       -> "interrupted"
944       InvalidArgument   -> "invalid argument"
945       OtherError        -> "failed"
946       ProtocolError     -> "protocol error"
947       ResourceVanished  -> "resource vanished"
948       SystemError       -> "system error"
949       TimeExpired       -> "timeout"
950       UnsatisfiedConstraints -> "unsatisified constraints" -- ultra-precise!
951       UnsupportedOperation -> "unsupported operation"
952       DynIOError{}      -> "unknown IO error"
953
954 -- | Construct an 'IOError' value with a string describing the error.
955 -- The 'fail' method of the 'IO' instance of the 'Monad' class raises a
956 -- 'userError', thus:
957 --
958 -- > instance Monad IO where 
959 -- >   ...
960 -- >   fail s = ioError (userError s)
961 --
962 userError       :: String  -> IOError
963 userError str   =  IOError Nothing UserError "" str Nothing
964
965 -- ---------------------------------------------------------------------------
966 -- Showing IOErrors
967
968 instance Show IOException where
969     showsPrec p (IOError hdl iot loc s fn) =
970       (case fn of
971          Nothing -> case hdl of
972                         Nothing -> id
973                         Just h  -> showsPrec p h . showString ": "
974          Just name -> showString name . showString ": ") .
975       (case loc of
976          "" -> id
977          _  -> showString loc . showString ": ") .
978       showsPrec p iot . 
979       (case s of
980          "" -> id
981          _  -> showString " (" . showString s . showString ")")
982
983 -- -----------------------------------------------------------------------------
984 -- IOMode type
985
986 data IOMode      =  ReadMode | WriteMode | AppendMode | ReadWriteMode
987                     deriving (Eq, Ord, Ix, Enum, Read, Show)
988 \end{code}