SafeHaskell: Added SafeHaskell to base
[packages/base.git] / GHC / List.lhs
1 \begin{code}
2 {-# LANGUAGE Trustworthy #-}
3 {-# LANGUAGE CPP, NoImplicitPrelude, MagicHash #-}
4 {-# OPTIONS_HADDOCK hide #-}
5
6 -----------------------------------------------------------------------------
7 -- |
8 -- Module      :  GHC.List
9 -- Copyright   :  (c) The University of Glasgow 1994-2002
10 -- License     :  see libraries/base/LICENSE
11 -- 
12 -- Maintainer  :  cvs-ghc@haskell.org
13 -- Stability   :  internal
14 -- Portability :  non-portable (GHC Extensions)
15 --
16 -- The List data type and its operations
17 --
18 -----------------------------------------------------------------------------
19
20 -- #hide
21 module GHC.List (
22    -- [] (..),          -- Not Haskell 98; built in syntax
23
24    map, (++), filter, concat,
25    head, last, tail, init, null, length, (!!),
26    foldl, scanl, scanl1, foldr, foldr1, scanr, scanr1,
27    iterate, repeat, replicate, cycle,
28    take, drop, splitAt, takeWhile, dropWhile, span, break,
29    reverse, and, or,
30    any, all, elem, notElem, lookup,
31    concatMap,
32    zip, zip3, zipWith, zipWith3, unzip, unzip3,
33    errorEmptyList,
34
35 #ifndef USE_REPORT_PRELUDE
36    -- non-standard, but hidden when creating the Prelude
37    -- export list.
38    takeUInt_append
39 #endif
40
41  ) where
42
43 import Data.Maybe
44 import GHC.Base
45
46 infixl 9  !!
47 infix  4 `elem`, `notElem`
48 \end{code}
49
50 %*********************************************************
51 %*                                                      *
52 \subsection{List-manipulation functions}
53 %*                                                      *
54 %*********************************************************
55
56 \begin{code}
57 -- | Extract the first element of a list, which must be non-empty.
58 head                    :: [a] -> a
59 head (x:_)              =  x
60 head []                 =  badHead
61
62 badHead :: a
63 badHead = errorEmptyList "head"
64
65 -- This rule is useful in cases like 
66 --      head [y | (x,y) <- ps, x==t]
67 {-# RULES
68 "head/build"    forall (g::forall b.(a->b->b)->b->b) .
69                 head (build g) = g (\x _ -> x) badHead
70 "head/augment"  forall xs (g::forall b. (a->b->b) -> b -> b) . 
71                 head (augment g xs) = g (\x _ -> x) (head xs)
72  #-}
73
74 -- | Extract the elements after the head of a list, which must be non-empty.
75 tail                    :: [a] -> [a]
76 tail (_:xs)             =  xs
77 tail []                 =  errorEmptyList "tail"
78
79 -- | Extract the last element of a list, which must be finite and non-empty.
80 last                    :: [a] -> a
81 #ifdef USE_REPORT_PRELUDE
82 last [x]                =  x
83 last (_:xs)             =  last xs
84 last []                 =  errorEmptyList "last"
85 #else
86 -- eliminate repeated cases
87 last []                 =  errorEmptyList "last"
88 last (x:xs)             =  last' x xs
89   where last' y []     = y
90         last' _ (y:ys) = last' y ys
91 #endif
92
93 -- | Return all the elements of a list except the last one.
94 -- The list must be non-empty.
95 init                    :: [a] -> [a]
96 #ifdef USE_REPORT_PRELUDE
97 init [x]                =  []
98 init (x:xs)             =  x : init xs
99 init []                 =  errorEmptyList "init"
100 #else
101 -- eliminate repeated cases
102 init []                 =  errorEmptyList "init"
103 init (x:xs)             =  init' x xs
104   where init' _ []     = []
105         init' y (z:zs) = y : init' z zs
106 #endif
107
108 -- | Test whether a list is empty.
109 null                    :: [a] -> Bool
110 null []                 =  True
111 null (_:_)              =  False
112
113 -- | /O(n)/. 'length' returns the length of a finite list as an 'Int'.
114 -- It is an instance of the more general 'Data.List.genericLength',
115 -- the result type of which may be any kind of number.
116 length                  :: [a] -> Int
117 length l                =  len l 0#
118   where
119     len :: [a] -> Int# -> Int
120     len []     a# = I# a#
121     len (_:xs) a# = len xs (a# +# 1#)
122
123 -- | 'filter', applied to a predicate and a list, returns the list of
124 -- those elements that satisfy the predicate; i.e.,
125 --
126 -- > filter p xs = [ x | x <- xs, p x]
127
128 filter :: (a -> Bool) -> [a] -> [a]
129 filter _pred []    = []
130 filter pred (x:xs)
131   | pred x         = x : filter pred xs
132   | otherwise      = filter pred xs
133
134 {-# NOINLINE [0] filterFB #-}
135 filterFB :: (a -> b -> b) -> (a -> Bool) -> a -> b -> b
136 filterFB c p x r | p x       = x `c` r
137                  | otherwise = r
138
139 {-# RULES
140 "filter"     [~1] forall p xs.  filter p xs = build (\c n -> foldr (filterFB c p) n xs)
141 "filterList" [1]  forall p.     foldr (filterFB (:) p) [] = filter p
142 "filterFB"        forall c p q. filterFB (filterFB c p) q = filterFB c (\x -> q x && p x)
143  #-}
144
145 -- Note the filterFB rule, which has p and q the "wrong way round" in the RHS.
146 --     filterFB (filterFB c p) q a b
147 --   = if q a then filterFB c p a b else b
148 --   = if q a then (if p a then c a b else b) else b
149 --   = if q a && p a then c a b else b
150 --   = filterFB c (\x -> q x && p x) a b
151 -- I originally wrote (\x -> p x && q x), which is wrong, and actually
152 -- gave rise to a live bug report.  SLPJ.
153
154
155 -- | 'foldl', applied to a binary operator, a starting value (typically
156 -- the left-identity of the operator), and a list, reduces the list
157 -- using the binary operator, from left to right:
158 --
159 -- > foldl f z [x1, x2, ..., xn] == (...((z `f` x1) `f` x2) `f`...) `f` xn
160 --
161 -- The list must be finite.
162
163 -- We write foldl as a non-recursive thing, so that it
164 -- can be inlined, and then (often) strictness-analysed,
165 -- and hence the classic space leak on foldl (+) 0 xs
166
167 foldl        :: (a -> b -> a) -> a -> [b] -> a
168 foldl f z0 xs0 = lgo z0 xs0
169              where
170                 lgo z []     =  z
171                 lgo z (x:xs) = lgo (f z x) xs
172
173 -- | 'scanl' is similar to 'foldl', but returns a list of successive
174 -- reduced values from the left:
175 --
176 -- > scanl f z [x1, x2, ...] == [z, z `f` x1, (z `f` x1) `f` x2, ...]
177 --
178 -- Note that
179 --
180 -- > last (scanl f z xs) == foldl f z xs.
181
182 scanl                   :: (a -> b -> a) -> a -> [b] -> [a]
183 scanl f q ls            =  q : (case ls of
184                                 []   -> []
185                                 x:xs -> scanl f (f q x) xs)
186
187 -- | 'scanl1' is a variant of 'scanl' that has no starting value argument:
188 --
189 -- > scanl1 f [x1, x2, ...] == [x1, x1 `f` x2, ...]
190
191 scanl1                  :: (a -> a -> a) -> [a] -> [a]
192 scanl1 f (x:xs)         =  scanl f x xs
193 scanl1 _ []             =  []
194
195 -- foldr, foldr1, scanr, and scanr1 are the right-to-left duals of the
196 -- above functions.
197
198 -- | 'foldr1' is a variant of 'foldr' that has no starting value argument,
199 -- and thus must be applied to non-empty lists.
200
201 foldr1                  :: (a -> a -> a) -> [a] -> a
202 foldr1 _ [x]            =  x
203 foldr1 f (x:xs)         =  f x (foldr1 f xs)
204 foldr1 _ []             =  errorEmptyList "foldr1"
205
206 -- | 'scanr' is the right-to-left dual of 'scanl'.
207 -- Note that
208 --
209 -- > head (scanr f z xs) == foldr f z xs.
210
211 scanr                   :: (a -> b -> b) -> b -> [a] -> [b]
212 scanr _ q0 []           =  [q0]
213 scanr f q0 (x:xs)       =  f x q : qs
214                            where qs@(q:_) = scanr f q0 xs 
215
216 -- | 'scanr1' is a variant of 'scanr' that has no starting value argument.
217
218 scanr1                  :: (a -> a -> a) -> [a] -> [a]
219 scanr1 _ []             =  []
220 scanr1 _ [x]            =  [x]
221 scanr1 f (x:xs)         =  f x q : qs
222                            where qs@(q:_) = scanr1 f xs 
223
224 -- | 'iterate' @f x@ returns an infinite list of repeated applications
225 -- of @f@ to @x@:
226 --
227 -- > iterate f x == [x, f x, f (f x), ...]
228
229 iterate :: (a -> a) -> a -> [a]
230 iterate f x =  x : iterate f (f x)
231
232 iterateFB :: (a -> b -> b) -> (a -> a) -> a -> b
233 iterateFB c f x = x `c` iterateFB c f (f x)
234
235
236 {-# RULES
237 "iterate"    [~1] forall f x.   iterate f x = build (\c _n -> iterateFB c f x)
238 "iterateFB"  [1]                iterateFB (:) = iterate
239  #-}
240
241
242 -- | 'repeat' @x@ is an infinite list, with @x@ the value of every element.
243 repeat :: a -> [a]
244 {-# INLINE [0] repeat #-}
245 -- The pragma just gives the rules more chance to fire
246 repeat x = xs where xs = x : xs
247
248 {-# INLINE [0] repeatFB #-}     -- ditto
249 repeatFB :: (a -> b -> b) -> a -> b
250 repeatFB c x = xs where xs = x `c` xs
251
252
253 {-# RULES
254 "repeat"    [~1] forall x. repeat x = build (\c _n -> repeatFB c x)
255 "repeatFB"  [1]  repeatFB (:)       = repeat
256  #-}
257
258 -- | 'replicate' @n x@ is a list of length @n@ with @x@ the value of
259 -- every element.
260 -- It is an instance of the more general 'Data.List.genericReplicate',
261 -- in which @n@ may be of any integral type.
262 {-# INLINE replicate #-}
263 replicate               :: Int -> a -> [a]
264 replicate n x           =  take n (repeat x)
265
266 -- | 'cycle' ties a finite list into a circular one, or equivalently,
267 -- the infinite repetition of the original list.  It is the identity
268 -- on infinite lists.
269
270 cycle                   :: [a] -> [a]
271 cycle []                = error "Prelude.cycle: empty list"
272 cycle xs                = xs' where xs' = xs ++ xs'
273
274 -- | 'takeWhile', applied to a predicate @p@ and a list @xs@, returns the
275 -- longest prefix (possibly empty) of @xs@ of elements that satisfy @p@:
276 --
277 -- > takeWhile (< 3) [1,2,3,4,1,2,3,4] == [1,2]
278 -- > takeWhile (< 9) [1,2,3] == [1,2,3]
279 -- > takeWhile (< 0) [1,2,3] == []
280 --
281
282 takeWhile               :: (a -> Bool) -> [a] -> [a]
283 takeWhile _ []          =  []
284 takeWhile p (x:xs) 
285             | p x       =  x : takeWhile p xs
286             | otherwise =  []
287
288 -- | 'dropWhile' @p xs@ returns the suffix remaining after 'takeWhile' @p xs@:
289 --
290 -- > dropWhile (< 3) [1,2,3,4,5,1,2,3] == [3,4,5,1,2,3]
291 -- > dropWhile (< 9) [1,2,3] == []
292 -- > dropWhile (< 0) [1,2,3] == [1,2,3]
293 --
294
295 dropWhile               :: (a -> Bool) -> [a] -> [a]
296 dropWhile _ []          =  []
297 dropWhile p xs@(x:xs')
298             | p x       =  dropWhile p xs'
299             | otherwise =  xs
300
301 -- | 'take' @n@, applied to a list @xs@, returns the prefix of @xs@
302 -- of length @n@, or @xs@ itself if @n > 'length' xs@:
303 --
304 -- > take 5 "Hello World!" == "Hello"
305 -- > take 3 [1,2,3,4,5] == [1,2,3]
306 -- > take 3 [1,2] == [1,2]
307 -- > take 3 [] == []
308 -- > take (-1) [1,2] == []
309 -- > take 0 [1,2] == []
310 --
311 -- It is an instance of the more general 'Data.List.genericTake',
312 -- in which @n@ may be of any integral type.
313 take                   :: Int -> [a] -> [a]
314
315 -- | 'drop' @n xs@ returns the suffix of @xs@
316 -- after the first @n@ elements, or @[]@ if @n > 'length' xs@:
317 --
318 -- > drop 6 "Hello World!" == "World!"
319 -- > drop 3 [1,2,3,4,5] == [4,5]
320 -- > drop 3 [1,2] == []
321 -- > drop 3 [] == []
322 -- > drop (-1) [1,2] == [1,2]
323 -- > drop 0 [1,2] == [1,2]
324 --
325 -- It is an instance of the more general 'Data.List.genericDrop',
326 -- in which @n@ may be of any integral type.
327 drop                   :: Int -> [a] -> [a]
328
329 -- | 'splitAt' @n xs@ returns a tuple where first element is @xs@ prefix of
330 -- length @n@ and second element is the remainder of the list:
331 --
332 -- > splitAt 6 "Hello World!" == ("Hello ","World!")
333 -- > splitAt 3 [1,2,3,4,5] == ([1,2,3],[4,5])
334 -- > splitAt 1 [1,2,3] == ([1],[2,3])
335 -- > splitAt 3 [1,2,3] == ([1,2,3],[])
336 -- > splitAt 4 [1,2,3] == ([1,2,3],[])
337 -- > splitAt 0 [1,2,3] == ([],[1,2,3])
338 -- > splitAt (-1) [1,2,3] == ([],[1,2,3])
339 --
340 -- It is equivalent to @('take' n xs, 'drop' n xs)@.
341 -- 'splitAt' is an instance of the more general 'Data.List.genericSplitAt',
342 -- in which @n@ may be of any integral type.
343 splitAt                :: Int -> [a] -> ([a],[a])
344
345 #ifdef USE_REPORT_PRELUDE
346 take n _      | n <= 0 =  []
347 take _ []              =  []
348 take n (x:xs)          =  x : take (n-1) xs
349
350 drop n xs     | n <= 0 =  xs
351 drop _ []              =  []
352 drop n (_:xs)          =  drop (n-1) xs
353
354 splitAt n xs           =  (take n xs, drop n xs)
355
356 #else /* hack away */
357 {-# RULES
358 "take"     [~1] forall n xs . take n xs = takeFoldr n xs 
359 "takeList"  [1] forall n xs . foldr (takeFB (:) []) (takeConst []) xs n = takeUInt n xs
360  #-}
361
362 {-# INLINE takeFoldr #-}
363 takeFoldr :: Int -> [a] -> [a]
364 takeFoldr (I# n#) xs
365   = build (\c nil -> if n# <=# 0# then nil else
366                      foldr (takeFB c nil) (takeConst nil) xs n#)
367
368 {-# NOINLINE [0] takeConst #-}
369 -- just a version of const that doesn't get inlined too early, so we
370 -- can spot it in rules.  Also we need a type sig due to the unboxed Int#.
371 takeConst :: a -> Int# -> a
372 takeConst x _ = x
373
374 {-# NOINLINE [0] takeFB #-}
375 takeFB :: (a -> b -> b) -> b -> a -> (Int# -> b) -> Int# -> b
376 takeFB c n x xs m | m <=# 1#  = x `c` n
377                   | otherwise = x `c` xs (m -# 1#)
378
379 {-# INLINE [0] take #-}
380 take (I# n#) xs = takeUInt n# xs
381
382 -- The general code for take, below, checks n <= maxInt
383 -- No need to check for maxInt overflow when specialised
384 -- at type Int or Int# since the Int must be <= maxInt
385
386 takeUInt :: Int# -> [b] -> [b]
387 takeUInt n xs
388   | n >=# 0#  =  take_unsafe_UInt n xs
389   | otherwise =  []
390
391 take_unsafe_UInt :: Int# -> [b] -> [b]
392 take_unsafe_UInt 0#  _  = []
393 take_unsafe_UInt m   ls =
394   case ls of
395     []     -> []
396     (x:xs) -> x : take_unsafe_UInt (m -# 1#) xs
397
398 takeUInt_append :: Int# -> [b] -> [b] -> [b]
399 takeUInt_append n xs rs
400   | n >=# 0#  =  take_unsafe_UInt_append n xs rs
401   | otherwise =  []
402
403 take_unsafe_UInt_append :: Int# -> [b] -> [b] -> [b]
404 take_unsafe_UInt_append 0#  _ rs  = rs
405 take_unsafe_UInt_append m  ls rs  =
406   case ls of
407     []     -> rs
408     (x:xs) -> x : take_unsafe_UInt_append (m -# 1#) xs rs
409
410 drop (I# n#) ls
411   | n# <# 0#    = ls
412   | otherwise   = drop# n# ls
413     where
414         drop# :: Int# -> [a] -> [a]
415         drop# 0# xs      = xs
416         drop# _  xs@[]   = xs
417         drop# m# (_:xs)  = drop# (m# -# 1#) xs
418
419 splitAt (I# n#) ls
420   | n# <# 0#    = ([], ls)
421   | otherwise   = splitAt# n# ls
422     where
423         splitAt# :: Int# -> [a] -> ([a], [a])
424         splitAt# 0# xs     = ([], xs)
425         splitAt# _  xs@[]  = (xs, xs)
426         splitAt# m# (x:xs) = (x:xs', xs'')
427           where
428             (xs', xs'') = splitAt# (m# -# 1#) xs
429
430 #endif /* USE_REPORT_PRELUDE */
431
432 -- | 'span', applied to a predicate @p@ and a list @xs@, returns a tuple where
433 -- first element is longest prefix (possibly empty) of @xs@ of elements that
434 -- satisfy @p@ and second element is the remainder of the list:
435 -- 
436 -- > span (< 3) [1,2,3,4,1,2,3,4] == ([1,2],[3,4,1,2,3,4])
437 -- > span (< 9) [1,2,3] == ([1,2,3],[])
438 -- > span (< 0) [1,2,3] == ([],[1,2,3])
439 -- 
440 -- 'span' @p xs@ is equivalent to @('takeWhile' p xs, 'dropWhile' p xs)@
441
442 span                    :: (a -> Bool) -> [a] -> ([a],[a])
443 span _ xs@[]            =  (xs, xs)
444 span p xs@(x:xs')
445          | p x          =  let (ys,zs) = span p xs' in (x:ys,zs)
446          | otherwise    =  ([],xs)
447
448 -- | 'break', applied to a predicate @p@ and a list @xs@, returns a tuple where
449 -- first element is longest prefix (possibly empty) of @xs@ of elements that
450 -- /do not satisfy/ @p@ and second element is the remainder of the list:
451 -- 
452 -- > break (> 3) [1,2,3,4,1,2,3,4] == ([1,2,3],[4,1,2,3,4])
453 -- > break (< 9) [1,2,3] == ([],[1,2,3])
454 -- > break (> 9) [1,2,3] == ([1,2,3],[])
455 --
456 -- 'break' @p@ is equivalent to @'span' ('not' . p)@.
457
458 break                   :: (a -> Bool) -> [a] -> ([a],[a])
459 #ifdef USE_REPORT_PRELUDE
460 break p                 =  span (not . p)
461 #else
462 -- HBC version (stolen)
463 break _ xs@[]           =  (xs, xs)
464 break p xs@(x:xs')
465            | p x        =  ([],xs)
466            | otherwise  =  let (ys,zs) = break p xs' in (x:ys,zs)
467 #endif
468
469 -- | 'reverse' @xs@ returns the elements of @xs@ in reverse order.
470 -- @xs@ must be finite.
471 reverse                 :: [a] -> [a]
472 #ifdef USE_REPORT_PRELUDE
473 reverse                 =  foldl (flip (:)) []
474 #else
475 reverse l =  rev l []
476   where
477     rev []     a = a
478     rev (x:xs) a = rev xs (x:a)
479 #endif
480
481 -- | 'and' returns the conjunction of a Boolean list.  For the result to be
482 -- 'True', the list must be finite; 'False', however, results from a 'False'
483 -- value at a finite index of a finite or infinite list.
484 and                     :: [Bool] -> Bool
485
486 -- | 'or' returns the disjunction of a Boolean list.  For the result to be
487 -- 'False', the list must be finite; 'True', however, results from a 'True'
488 -- value at a finite index of a finite or infinite list.
489 or                      :: [Bool] -> Bool
490 #ifdef USE_REPORT_PRELUDE
491 and                     =  foldr (&&) True
492 or                      =  foldr (||) False
493 #else
494 and []          =  True
495 and (x:xs)      =  x && and xs
496 or []           =  False
497 or (x:xs)       =  x || or xs
498
499 {-# RULES
500 "and/build"     forall (g::forall b.(Bool->b->b)->b->b) . 
501                 and (build g) = g (&&) True
502 "or/build"      forall (g::forall b.(Bool->b->b)->b->b) . 
503                 or (build g) = g (||) False
504  #-}
505 #endif
506
507 -- | Applied to a predicate and a list, 'any' determines if any element
508 -- of the list satisfies the predicate.  For the result to be
509 -- 'False', the list must be finite; 'True', however, results from a 'True'
510 -- value for the predicate applied to an element at a finite index of a finite or infinite list.
511 any                     :: (a -> Bool) -> [a] -> Bool
512
513 -- | Applied to a predicate and a list, 'all' determines if all elements
514 -- of the list satisfy the predicate. For the result to be
515 -- 'True', the list must be finite; 'False', however, results from a 'False'
516 -- value for the predicate applied to an element at a finite index of a finite or infinite list.
517 all                     :: (a -> Bool) -> [a] -> Bool
518 #ifdef USE_REPORT_PRELUDE
519 any p                   =  or . map p
520 all p                   =  and . map p
521 #else
522 any _ []        = False
523 any p (x:xs)    = p x || any p xs
524
525 all _ []        =  True
526 all p (x:xs)    =  p x && all p xs
527 {-# RULES
528 "any/build"     forall p (g::forall b.(a->b->b)->b->b) . 
529                 any p (build g) = g ((||) . p) False
530 "all/build"     forall p (g::forall b.(a->b->b)->b->b) . 
531                 all p (build g) = g ((&&) . p) True
532  #-}
533 #endif
534
535 -- | 'elem' is the list membership predicate, usually written in infix form,
536 -- e.g., @x \`elem\` xs@.  For the result to be
537 -- 'False', the list must be finite; 'True', however, results from an element equal to @x@ found at a finite index of a finite or infinite list.
538 elem                    :: (Eq a) => a -> [a] -> Bool
539
540 -- | 'notElem' is the negation of 'elem'.
541 notElem                 :: (Eq a) => a -> [a] -> Bool
542 #ifdef USE_REPORT_PRELUDE
543 elem x                  =  any (== x)
544 notElem x               =  all (/= x)
545 #else
546 elem _ []       = False
547 elem x (y:ys)   = x==y || elem x ys
548
549 notElem _ []    =  True
550 notElem x (y:ys)=  x /= y && notElem x ys
551 #endif
552
553 -- | 'lookup' @key assocs@ looks up a key in an association list.
554 lookup                  :: (Eq a) => a -> [(a,b)] -> Maybe b
555 lookup _key []          =  Nothing
556 lookup  key ((x,y):xys)
557     | key == x          =  Just y
558     | otherwise         =  lookup key xys
559
560 -- | Map a function over a list and concatenate the results.
561 concatMap               :: (a -> [b]) -> [a] -> [b]
562 concatMap f             =  foldr ((++) . f) []
563
564 -- | Concatenate a list of lists.
565 concat :: [[a]] -> [a]
566 concat = foldr (++) []
567
568 {-# RULES
569   "concat" forall xs. concat xs = build (\c n -> foldr (\x y -> foldr c y x) n xs)
570 -- We don't bother to turn non-fusible applications of concat back into concat
571  #-}
572
573 \end{code}
574
575
576 \begin{code}
577 -- | List index (subscript) operator, starting from 0.
578 -- It is an instance of the more general 'Data.List.genericIndex',
579 -- which takes an index of any integral type.
580 (!!)                    :: [a] -> Int -> a
581 #ifdef USE_REPORT_PRELUDE
582 xs     !! n | n < 0 =  error "Prelude.!!: negative index"
583 []     !! _         =  error "Prelude.!!: index too large"
584 (x:_)  !! 0         =  x
585 (_:xs) !! n         =  xs !! (n-1)
586 #else
587 -- HBC version (stolen), then unboxified
588 -- The semantics is not quite the same for error conditions
589 -- in the more efficient version.
590 --
591 xs !! (I# n0) | n0 <# 0#   =  error "Prelude.(!!): negative index\n"
592                | otherwise =  sub xs n0
593                          where
594                             sub :: [a] -> Int# -> a
595                             sub []     _ = error "Prelude.(!!): index too large\n"
596                             sub (y:ys) n = if n ==# 0#
597                                            then y
598                                            else sub ys (n -# 1#)
599 #endif
600 \end{code}
601
602
603 %*********************************************************
604 %*                                                      *
605 \subsection{The zip family}
606 %*                                                      *
607 %*********************************************************
608
609 \begin{code}
610 foldr2 :: (a -> b -> c -> c) -> c -> [a] -> [b] -> c
611 foldr2 _k z []    _ys    = z
612 foldr2 _k z _xs   []     = z
613 foldr2 k z (x:xs) (y:ys) = k x y (foldr2 k z xs ys)
614
615 foldr2_left :: (a -> b -> c -> d) -> d -> a -> ([b] -> c) -> [b] -> d
616 foldr2_left _k  z _x _r []     = z
617 foldr2_left  k _z  x  r (y:ys) = k x y (r ys)
618
619 foldr2_right :: (a -> b -> c -> d) -> d -> b -> ([a] -> c) -> [a] -> d
620 foldr2_right _k z  _y _r []     = z
621 foldr2_right  k _z  y  r (x:xs) = k x y (r xs)
622
623 -- foldr2 k z xs ys = foldr (foldr2_left k z)  (\_ -> z) xs ys
624 -- foldr2 k z xs ys = foldr (foldr2_right k z) (\_ -> z) ys xs
625 {-# RULES
626 "foldr2/left"   forall k z ys (g::forall b.(a->b->b)->b->b) . 
627                   foldr2 k z (build g) ys = g (foldr2_left  k z) (\_ -> z) ys
628
629 "foldr2/right"  forall k z xs (g::forall b.(a->b->b)->b->b) . 
630                   foldr2 k z xs (build g) = g (foldr2_right k z) (\_ -> z) xs
631  #-}
632 \end{code}
633
634 The foldr2/right rule isn't exactly right, because it changes
635 the strictness of foldr2 (and thereby zip)
636
637 E.g. main = print (null (zip nonobviousNil (build undefined)))
638           where   nonobviousNil = f 3
639                   f n = if n == 0 then [] else f (n-1)
640
641 I'm going to leave it though.
642
643
644 Zips for larger tuples are in the List module.
645
646 \begin{code}
647 ----------------------------------------------
648 -- | 'zip' takes two lists and returns a list of corresponding pairs.
649 -- If one input list is short, excess elements of the longer list are
650 -- discarded.
651 zip :: [a] -> [b] -> [(a,b)]
652 zip (a:as) (b:bs) = (a,b) : zip as bs
653 zip _      _      = []
654
655 {-# INLINE [0] zipFB #-}
656 zipFB :: ((a, b) -> c -> d) -> a -> b -> c -> d
657 zipFB c = \x y r -> (x,y) `c` r
658
659 {-# RULES
660 "zip"      [~1] forall xs ys. zip xs ys = build (\c n -> foldr2 (zipFB c) n xs ys)
661 "zipList"  [1]  foldr2 (zipFB (:)) []   = zip
662  #-}
663 \end{code}
664
665 \begin{code}
666 ----------------------------------------------
667 -- | 'zip3' takes three lists and returns a list of triples, analogous to
668 -- 'zip'.
669 zip3 :: [a] -> [b] -> [c] -> [(a,b,c)]
670 -- Specification
671 -- zip3 =  zipWith3 (,,)
672 zip3 (a:as) (b:bs) (c:cs) = (a,b,c) : zip3 as bs cs
673 zip3 _      _      _      = []
674 \end{code}
675
676
677 -- The zipWith family generalises the zip family by zipping with the
678 -- function given as the first argument, instead of a tupling function.
679
680 \begin{code}
681 ----------------------------------------------
682 -- | 'zipWith' generalises 'zip' by zipping with the function given
683 -- as the first argument, instead of a tupling function.
684 -- For example, @'zipWith' (+)@ is applied to two lists to produce the
685 -- list of corresponding sums.
686 zipWith :: (a->b->c) -> [a]->[b]->[c]
687 zipWith f (a:as) (b:bs) = f a b : zipWith f as bs
688 zipWith _ _      _      = []
689
690 -- zipWithFB must have arity 2 since it gets two arguments in the "zipWith"
691 -- rule; it might not get inlined otherwise
692 {-# INLINE [0] zipWithFB #-}
693 zipWithFB :: (a -> b -> c) -> (d -> e -> a) -> d -> e -> b -> c
694 zipWithFB c f = \x y r -> (x `f` y) `c` r
695
696 {-# RULES
697 "zipWith"       [~1] forall f xs ys.    zipWith f xs ys = build (\c n -> foldr2 (zipWithFB c f) n xs ys)
698 "zipWithList"   [1]  forall f.  foldr2 (zipWithFB (:) f) [] = zipWith f
699   #-}
700 \end{code}
701
702 \begin{code}
703 -- | The 'zipWith3' function takes a function which combines three
704 -- elements, as well as three lists and returns a list of their point-wise
705 -- combination, analogous to 'zipWith'.
706 zipWith3                :: (a->b->c->d) -> [a]->[b]->[c]->[d]
707 zipWith3 z (a:as) (b:bs) (c:cs)
708                         =  z a b c : zipWith3 z as bs cs
709 zipWith3 _ _ _ _        =  []
710
711 -- | 'unzip' transforms a list of pairs into a list of first components
712 -- and a list of second components.
713 unzip    :: [(a,b)] -> ([a],[b])
714 {-# INLINE unzip #-}
715 unzip    =  foldr (\(a,b) ~(as,bs) -> (a:as,b:bs)) ([],[])
716
717 -- | The 'unzip3' function takes a list of triples and returns three
718 -- lists, analogous to 'unzip'.
719 unzip3   :: [(a,b,c)] -> ([a],[b],[c])
720 {-# INLINE unzip3 #-}
721 unzip3   =  foldr (\(a,b,c) ~(as,bs,cs) -> (a:as,b:bs,c:cs))
722                   ([],[],[])
723 \end{code}
724
725
726 %*********************************************************
727 %*                                                      *
728 \subsection{Error code}
729 %*                                                      *
730 %*********************************************************
731
732 Common up near identical calls to `error' to reduce the number
733 constant strings created when compiled:
734
735 \begin{code}
736 errorEmptyList :: String -> a
737 errorEmptyList fun =
738   error (prel_list_str ++ fun ++ ": empty list")
739
740 prel_list_str :: String
741 prel_list_str = "Prelude."
742 \end{code}