go-ify foldr2
[packages/base.git] / GHC / List.lhs
1 \begin{code}
2 {-# LANGUAGE Trustworthy #-}
3 {-# LANGUAGE CPP, NoImplicitPrelude, MagicHash #-}
4 {-# OPTIONS_HADDOCK hide #-}
5
6 -----------------------------------------------------------------------------
7 -- |
8 -- Module      :  GHC.List
9 -- Copyright   :  (c) The University of Glasgow 1994-2002
10 -- License     :  see libraries/base/LICENSE
11 --
12 -- Maintainer  :  cvs-ghc@haskell.org
13 -- Stability   :  internal
14 -- Portability :  non-portable (GHC Extensions)
15 --
16 -- The List data type and its operations
17 --
18 -----------------------------------------------------------------------------
19
20 module GHC.List (
21    -- [] (..),          -- built-in syntax; can't be used in export list
22
23    map, (++), filter, concat,
24    head, last, tail, init, null, length, (!!),
25    foldl, scanl, scanl1, foldr, foldr1, scanr, scanr1,
26    iterate, repeat, replicate, cycle,
27    take, drop, splitAt, takeWhile, dropWhile, span, break,
28    reverse, and, or,
29    any, all, elem, notElem, lookup,
30    concatMap,
31    zip, zip3, zipWith, zipWith3, unzip, unzip3,
32    errorEmptyList,
33
34 #ifndef USE_REPORT_PRELUDE
35    -- non-standard, but hidden when creating the Prelude
36    -- export list.
37    takeUInt_append
38 #endif
39
40  ) where
41
42 import Data.Maybe
43 import GHC.Base
44
45 infixl 9  !!
46 infix  4 `elem`, `notElem`
47 \end{code}
48
49 %*********************************************************
50 %*                                                      *
51 \subsection{List-manipulation functions}
52 %*                                                      *
53 %*********************************************************
54
55 \begin{code}
56 -- | Extract the first element of a list, which must be non-empty.
57 head                    :: [a] -> a
58 head (x:_)              =  x
59 head []                 =  badHead
60 {-# NOINLINE [1] head #-}
61
62 badHead :: a
63 badHead = errorEmptyList "head"
64
65 -- This rule is useful in cases like
66 --      head [y | (x,y) <- ps, x==t]
67 {-# RULES
68 "head/build"    forall (g::forall b.(a->b->b)->b->b) .
69                 head (build g) = g (\x _ -> x) badHead
70 "head/augment"  forall xs (g::forall b. (a->b->b) -> b -> b) .
71                 head (augment g xs) = g (\x _ -> x) (head xs)
72  #-}
73
74 -- | Extract the elements after the head of a list, which must be non-empty.
75 tail                    :: [a] -> [a]
76 tail (_:xs)             =  xs
77 tail []                 =  errorEmptyList "tail"
78
79 -- | Extract the last element of a list, which must be finite and non-empty.
80 last                    :: [a] -> a
81 #ifdef USE_REPORT_PRELUDE
82 last [x]                =  x
83 last (_:xs)             =  last xs
84 last []                 =  errorEmptyList "last"
85 #else
86 -- eliminate repeated cases
87 last []                 =  errorEmptyList "last"
88 last (x:xs)             =  last' x xs
89   where last' y []     = y
90         last' _ (y:ys) = last' y ys
91 #endif
92
93 -- | Return all the elements of a list except the last one.
94 -- The list must be non-empty.
95 init                    :: [a] -> [a]
96 #ifdef USE_REPORT_PRELUDE
97 init [x]                =  []
98 init (x:xs)             =  x : init xs
99 init []                 =  errorEmptyList "init"
100 #else
101 -- eliminate repeated cases
102 init []                 =  errorEmptyList "init"
103 init (x:xs)             =  init' x xs
104   where init' _ []     = []
105         init' y (z:zs) = y : init' z zs
106 #endif
107
108 -- | Test whether a list is empty.
109 null                    :: [a] -> Bool
110 null []                 =  True
111 null (_:_)              =  False
112
113 -- | /O(n)/. 'length' returns the length of a finite list as an 'Int'.
114 -- It is an instance of the more general 'Data.List.genericLength',
115 -- the result type of which may be any kind of number.
116 {-# NOINLINE [1] length #-}
117 length                  :: [a] -> Int
118 length l                =  lenAcc l 0#
119
120 lenAcc :: [a] -> Int# -> Int
121 lenAcc []     a# = I# a#
122 lenAcc (_:xs) a# = lenAcc xs (a# +# 1#)
123
124 incLen :: a -> (Int# -> Int) -> Int# -> Int
125 incLen _ g x = g (x +# 1#)
126
127 -- These rules make length into a good consumer
128 -- Note that we use a higher-order-style use of foldr, so that
129 -- the accumulating parameter can be evaluated strictly
130 -- See Trac #876 for what goes wrong otherwise
131 {-# RULES
132 "length"     [~1] forall xs. length xs = foldr incLen I# xs 0#
133 "lengthList" [1]  foldr incLen I# = lenAcc
134  #-}
135
136 -- | 'filter', applied to a predicate and a list, returns the list of
137 -- those elements that satisfy the predicate; i.e.,
138 --
139 -- > filter p xs = [ x | x <- xs, p x]
140
141 {-# NOINLINE [1] filter #-}
142 filter :: (a -> Bool) -> [a] -> [a]
143 filter _pred []    = []
144 filter pred (x:xs)
145   | pred x         = x : filter pred xs
146   | otherwise      = filter pred xs
147
148 {-# NOINLINE [0] filterFB #-}
149 filterFB :: (a -> b -> b) -> (a -> Bool) -> a -> b -> b
150 filterFB c p x r | p x       = x `c` r
151                  | otherwise = r
152
153 {-# RULES
154 "filter"     [~1] forall p xs.  filter p xs = build (\c n -> foldr (filterFB c p) n xs)
155 "filterList" [1]  forall p.     foldr (filterFB (:) p) [] = filter p
156 "filterFB"        forall c p q. filterFB (filterFB c p) q = filterFB c (\x -> q x && p x)
157  #-}
158
159 -- Note the filterFB rule, which has p and q the "wrong way round" in the RHS.
160 --     filterFB (filterFB c p) q a b
161 --   = if q a then filterFB c p a b else b
162 --   = if q a then (if p a then c a b else b) else b
163 --   = if q a && p a then c a b else b
164 --   = filterFB c (\x -> q x && p x) a b
165 -- I originally wrote (\x -> p x && q x), which is wrong, and actually
166 -- gave rise to a live bug report.  SLPJ.
167
168
169 -- | 'foldl', applied to a binary operator, a starting value (typically
170 -- the left-identity of the operator), and a list, reduces the list
171 -- using the binary operator, from left to right:
172 --
173 -- > foldl f z [x1, x2, ..., xn] == (...((z `f` x1) `f` x2) `f`...) `f` xn
174 --
175 -- The list must be finite.
176
177 -- We write foldl as a non-recursive thing, so that it
178 -- can be inlined, and then (often) strictness-analysed,
179 -- and hence the classic space leak on foldl (+) 0 xs
180
181 foldl        :: (b -> a -> b) -> b -> [a] -> b
182 foldl f z0 xs0 = lgo z0 xs0
183              where
184                 lgo z []     =  z
185                 lgo z (x:xs) = lgo (f z x) xs
186
187 -- | 'scanl' is similar to 'foldl', but returns a list of successive
188 -- reduced values from the left:
189 --
190 -- > scanl f z [x1, x2, ...] == [z, z `f` x1, (z `f` x1) `f` x2, ...]
191 --
192 -- Note that
193 --
194 -- > last (scanl f z xs) == foldl f z xs.
195
196 scanl                   :: (b -> a -> b) -> b -> [a] -> [b]
197 scanl f q ls            =  q : (case ls of
198                                 []   -> []
199                                 x:xs -> scanl f (f q x) xs)
200
201 -- | 'scanl1' is a variant of 'scanl' that has no starting value argument:
202 --
203 -- > scanl1 f [x1, x2, ...] == [x1, x1 `f` x2, ...]
204
205 scanl1                  :: (a -> a -> a) -> [a] -> [a]
206 scanl1 f (x:xs)         =  scanl f x xs
207 scanl1 _ []             =  []
208
209 -- foldr, foldr1, scanr, and scanr1 are the right-to-left duals of the
210 -- above functions.
211
212 -- | 'foldr1' is a variant of 'foldr' that has no starting value argument,
213 -- and thus must be applied to non-empty lists.
214
215 foldr1                  :: (a -> a -> a) -> [a] -> a
216 foldr1 _ [x]            =  x
217 foldr1 f (x:xs)         =  f x (foldr1 f xs)
218 foldr1 _ []             =  errorEmptyList "foldr1"
219
220 -- | 'scanr' is the right-to-left dual of 'scanl'.
221 -- Note that
222 --
223 -- > head (scanr f z xs) == foldr f z xs.
224
225 scanr                   :: (a -> b -> b) -> b -> [a] -> [b]
226 scanr _ q0 []           =  [q0]
227 scanr f q0 (x:xs)       =  f x q : qs
228                            where qs@(q:_) = scanr f q0 xs
229
230 -- | 'scanr1' is a variant of 'scanr' that has no starting value argument.
231
232 scanr1                  :: (a -> a -> a) -> [a] -> [a]
233 scanr1 _ []             =  []
234 scanr1 _ [x]            =  [x]
235 scanr1 f (x:xs)         =  f x q : qs
236                            where qs@(q:_) = scanr1 f xs
237
238 -- | 'iterate' @f x@ returns an infinite list of repeated applications
239 -- of @f@ to @x@:
240 --
241 -- > iterate f x == [x, f x, f (f x), ...]
242
243 {-# NOINLINE [1] iterate #-}
244 iterate :: (a -> a) -> a -> [a]
245 iterate f x =  x : iterate f (f x)
246
247 {-# NOINLINE [0] iterateFB #-}
248 iterateFB :: (a -> b -> b) -> (a -> a) -> a -> b
249 iterateFB c f x = x `c` iterateFB c f (f x)
250
251 {-# RULES
252 "iterate"    [~1] forall f x.   iterate f x = build (\c _n -> iterateFB c f x)
253 "iterateFB"  [1]                iterateFB (:) = iterate
254  #-}
255
256
257 -- | 'repeat' @x@ is an infinite list, with @x@ the value of every element.
258 repeat :: a -> [a]
259 {-# INLINE [0] repeat #-}
260 -- The pragma just gives the rules more chance to fire
261 repeat x = xs where xs = x : xs
262
263 {-# INLINE [0] repeatFB #-}     -- ditto
264 repeatFB :: (a -> b -> b) -> a -> b
265 repeatFB c x = xs where xs = x `c` xs
266
267
268 {-# RULES
269 "repeat"    [~1] forall x. repeat x = build (\c _n -> repeatFB c x)
270 "repeatFB"  [1]  repeatFB (:)       = repeat
271  #-}
272
273 -- | 'replicate' @n x@ is a list of length @n@ with @x@ the value of
274 -- every element.
275 -- It is an instance of the more general 'Data.List.genericReplicate',
276 -- in which @n@ may be of any integral type.
277 {-# INLINE replicate #-}
278 replicate               :: Int -> a -> [a]
279 replicate n x           =  take n (repeat x)
280
281 -- | 'cycle' ties a finite list into a circular one, or equivalently,
282 -- the infinite repetition of the original list.  It is the identity
283 -- on infinite lists.
284
285 cycle                   :: [a] -> [a]
286 cycle []                = error "Prelude.cycle: empty list"
287 cycle xs                = xs' where xs' = xs ++ xs'
288
289 -- | 'takeWhile', applied to a predicate @p@ and a list @xs@, returns the
290 -- longest prefix (possibly empty) of @xs@ of elements that satisfy @p@:
291 --
292 -- > takeWhile (< 3) [1,2,3,4,1,2,3,4] == [1,2]
293 -- > takeWhile (< 9) [1,2,3] == [1,2,3]
294 -- > takeWhile (< 0) [1,2,3] == []
295 --
296
297 takeWhile               :: (a -> Bool) -> [a] -> [a]
298 takeWhile _ []          =  []
299 takeWhile p (x:xs)
300             | p x       =  x : takeWhile p xs
301             | otherwise =  []
302
303 -- | 'dropWhile' @p xs@ returns the suffix remaining after 'takeWhile' @p xs@:
304 --
305 -- > dropWhile (< 3) [1,2,3,4,5,1,2,3] == [3,4,5,1,2,3]
306 -- > dropWhile (< 9) [1,2,3] == []
307 -- > dropWhile (< 0) [1,2,3] == [1,2,3]
308 --
309
310 dropWhile               :: (a -> Bool) -> [a] -> [a]
311 dropWhile _ []          =  []
312 dropWhile p xs@(x:xs')
313             | p x       =  dropWhile p xs'
314             | otherwise =  xs
315
316 -- | 'take' @n@, applied to a list @xs@, returns the prefix of @xs@
317 -- of length @n@, or @xs@ itself if @n > 'length' xs@:
318 --
319 -- > take 5 "Hello World!" == "Hello"
320 -- > take 3 [1,2,3,4,5] == [1,2,3]
321 -- > take 3 [1,2] == [1,2]
322 -- > take 3 [] == []
323 -- > take (-1) [1,2] == []
324 -- > take 0 [1,2] == []
325 --
326 -- It is an instance of the more general 'Data.List.genericTake',
327 -- in which @n@ may be of any integral type.
328 take                   :: Int -> [a] -> [a]
329
330 -- | 'drop' @n xs@ returns the suffix of @xs@
331 -- after the first @n@ elements, or @[]@ if @n > 'length' xs@:
332 --
333 -- > drop 6 "Hello World!" == "World!"
334 -- > drop 3 [1,2,3,4,5] == [4,5]
335 -- > drop 3 [1,2] == []
336 -- > drop 3 [] == []
337 -- > drop (-1) [1,2] == [1,2]
338 -- > drop 0 [1,2] == [1,2]
339 --
340 -- It is an instance of the more general 'Data.List.genericDrop',
341 -- in which @n@ may be of any integral type.
342 drop                   :: Int -> [a] -> [a]
343
344 -- | 'splitAt' @n xs@ returns a tuple where first element is @xs@ prefix of
345 -- length @n@ and second element is the remainder of the list:
346 --
347 -- > splitAt 6 "Hello World!" == ("Hello ","World!")
348 -- > splitAt 3 [1,2,3,4,5] == ([1,2,3],[4,5])
349 -- > splitAt 1 [1,2,3] == ([1],[2,3])
350 -- > splitAt 3 [1,2,3] == ([1,2,3],[])
351 -- > splitAt 4 [1,2,3] == ([1,2,3],[])
352 -- > splitAt 0 [1,2,3] == ([],[1,2,3])
353 -- > splitAt (-1) [1,2,3] == ([],[1,2,3])
354 --
355 -- It is equivalent to @('take' n xs, 'drop' n xs)@ when @n@ is not @_|_@
356 -- (@splitAt _|_ xs = _|_@).
357 -- 'splitAt' is an instance of the more general 'Data.List.genericSplitAt',
358 -- in which @n@ may be of any integral type.
359 splitAt                :: Int -> [a] -> ([a],[a])
360
361 #ifdef USE_REPORT_PRELUDE
362 take n _      | n <= 0 =  []
363 take _ []              =  []
364 take n (x:xs)          =  x : take (n-1) xs
365
366 drop n xs     | n <= 0 =  xs
367 drop _ []              =  []
368 drop n (_:xs)          =  drop (n-1) xs
369
370 splitAt n xs           =  (take n xs, drop n xs)
371
372 #else /* hack away */
373 {-# RULES
374 "take"     [~1] forall n xs . take n xs = takeFoldr n xs
375 "takeList"  [1] forall n xs . foldr (takeFB (:) []) (takeConst []) xs n = takeUInt n xs
376  #-}
377
378 {-# INLINE takeFoldr #-}
379 takeFoldr :: Int -> [a] -> [a]
380 takeFoldr (I# n#) xs
381   = build (\c nil -> if isTrue# (n# <=# 0#) then nil else
382                      foldr (takeFB c nil) (takeConst nil) xs n#)
383
384 {-# NOINLINE [0] takeConst #-}
385 -- just a version of const that doesn't get inlined too early, so we
386 -- can spot it in rules.  Also we need a type sig due to the unboxed Int#.
387 takeConst :: a -> Int# -> a
388 takeConst x _ = x
389
390 {-# NOINLINE [0] takeFB #-}
391 takeFB :: (a -> b -> b) -> b -> a -> (Int# -> b) -> Int# -> b
392 takeFB c n x xs m | isTrue# (m <=# 1#) = x `c` n
393                   | otherwise          = x `c` xs (m -# 1#)
394
395 {-# INLINE [0] take #-}
396 take (I# n#) xs = takeUInt n# xs
397
398 -- The general code for take, below, checks n <= maxInt
399 -- No need to check for maxInt overflow when specialised
400 -- at type Int or Int# since the Int must be <= maxInt
401
402 takeUInt :: Int# -> [b] -> [b]
403 takeUInt n xs
404   | isTrue# (n >=# 0#) = take_unsafe_UInt n xs
405   | otherwise          = []
406
407 take_unsafe_UInt :: Int# -> [b] -> [b]
408 take_unsafe_UInt 0#  _  = []
409 take_unsafe_UInt m   ls =
410   case ls of
411     []     -> []
412     (x:xs) -> x : take_unsafe_UInt (m -# 1#) xs
413
414 takeUInt_append :: Int# -> [b] -> [b] -> [b]
415 takeUInt_append n xs rs
416   | isTrue# (n >=# 0#) = take_unsafe_UInt_append n xs rs
417   | otherwise          = []
418
419 take_unsafe_UInt_append :: Int# -> [b] -> [b] -> [b]
420 take_unsafe_UInt_append 0#  _ rs  = rs
421 take_unsafe_UInt_append m  ls rs  =
422   case ls of
423     []     -> rs
424     (x:xs) -> x : take_unsafe_UInt_append (m -# 1#) xs rs
425
426 drop (I# n#) ls
427   | isTrue# (n# <# 0#) = ls
428   | otherwise          = drop# n# ls
429     where
430         drop# :: Int# -> [a] -> [a]
431         drop# 0# xs      = xs
432         drop# _  xs@[]   = xs
433         drop# m# (_:xs)  = drop# (m# -# 1#) xs
434
435 splitAt (I# n#) ls
436   | isTrue# (n# <# 0#) = ([], ls)
437   | otherwise          = splitAt# n# ls
438     where
439         splitAt# :: Int# -> [a] -> ([a], [a])
440         splitAt# 0# xs     = ([], xs)
441         splitAt# _  xs@[]  = (xs, xs)
442         splitAt# m# (x:xs) = (x:xs', xs'')
443           where
444             (xs', xs'') = splitAt# (m# -# 1#) xs
445
446 #endif /* USE_REPORT_PRELUDE */
447
448 -- | 'span', applied to a predicate @p@ and a list @xs@, returns a tuple where
449 -- first element is longest prefix (possibly empty) of @xs@ of elements that
450 -- satisfy @p@ and second element is the remainder of the list:
451 --
452 -- > span (< 3) [1,2,3,4,1,2,3,4] == ([1,2],[3,4,1,2,3,4])
453 -- > span (< 9) [1,2,3] == ([1,2,3],[])
454 -- > span (< 0) [1,2,3] == ([],[1,2,3])
455 --
456 -- 'span' @p xs@ is equivalent to @('takeWhile' p xs, 'dropWhile' p xs)@
457
458 span                    :: (a -> Bool) -> [a] -> ([a],[a])
459 span _ xs@[]            =  (xs, xs)
460 span p xs@(x:xs')
461          | p x          =  let (ys,zs) = span p xs' in (x:ys,zs)
462          | otherwise    =  ([],xs)
463
464 -- | 'break', applied to a predicate @p@ and a list @xs@, returns a tuple where
465 -- first element is longest prefix (possibly empty) of @xs@ of elements that
466 -- /do not satisfy/ @p@ and second element is the remainder of the list:
467 --
468 -- > break (> 3) [1,2,3,4,1,2,3,4] == ([1,2,3],[4,1,2,3,4])
469 -- > break (< 9) [1,2,3] == ([],[1,2,3])
470 -- > break (> 9) [1,2,3] == ([1,2,3],[])
471 --
472 -- 'break' @p@ is equivalent to @'span' ('not' . p)@.
473
474 break                   :: (a -> Bool) -> [a] -> ([a],[a])
475 #ifdef USE_REPORT_PRELUDE
476 break p                 =  span (not . p)
477 #else
478 -- HBC version (stolen)
479 break _ xs@[]           =  (xs, xs)
480 break p xs@(x:xs')
481            | p x        =  ([],xs)
482            | otherwise  =  let (ys,zs) = break p xs' in (x:ys,zs)
483 #endif
484
485 -- | 'reverse' @xs@ returns the elements of @xs@ in reverse order.
486 -- @xs@ must be finite.
487 reverse                 :: [a] -> [a]
488 #ifdef USE_REPORT_PRELUDE
489 reverse                 =  foldl (flip (:)) []
490 #else
491 reverse l =  rev l []
492   where
493     rev []     a = a
494     rev (x:xs) a = rev xs (x:a)
495 #endif
496
497 -- | 'and' returns the conjunction of a Boolean list.  For the result to be
498 -- 'True', the list must be finite; 'False', however, results from a 'False'
499 -- value at a finite index of a finite or infinite list.
500 and                     :: [Bool] -> Bool
501
502 -- | 'or' returns the disjunction of a Boolean list.  For the result to be
503 -- 'False', the list must be finite; 'True', however, results from a 'True'
504 -- value at a finite index of a finite or infinite list.
505 or                      :: [Bool] -> Bool
506 #ifdef USE_REPORT_PRELUDE
507 and                     =  foldr (&&) True
508 or                      =  foldr (||) False
509 #else
510 and []          =  True
511 and (x:xs)      =  x && and xs
512 or []           =  False
513 or (x:xs)       =  x || or xs
514
515 {-# NOINLINE [1] and #-}
516 {-# NOINLINE [1] or #-}
517
518 {-# RULES
519 "and/build"     forall (g::forall b.(Bool->b->b)->b->b) .
520                 and (build g) = g (&&) True
521 "or/build"      forall (g::forall b.(Bool->b->b)->b->b) .
522                 or (build g) = g (||) False
523  #-}
524 #endif
525
526 -- | Applied to a predicate and a list, 'any' determines if any element
527 -- of the list satisfies the predicate.  For the result to be
528 -- 'False', the list must be finite; 'True', however, results from a 'True'
529 -- value for the predicate applied to an element at a finite index of a finite or infinite list.
530 any                     :: (a -> Bool) -> [a] -> Bool
531
532 -- | Applied to a predicate and a list, 'all' determines if all elements
533 -- of the list satisfy the predicate. For the result to be
534 -- 'True', the list must be finite; 'False', however, results from a 'False'
535 -- value for the predicate applied to an element at a finite index of a finite or infinite list.
536 all                     :: (a -> Bool) -> [a] -> Bool
537 #ifdef USE_REPORT_PRELUDE
538 any p                   =  or . map p
539 all p                   =  and . map p
540 #else
541 any _ []        = False
542 any p (x:xs)    = p x || any p xs
543
544 all _ []        =  True
545 all p (x:xs)    =  p x && all p xs
546
547 {-# NOINLINE [1] any #-}
548 {-# NOINLINE [1] all #-}
549
550 {-# RULES
551 "any/build"     forall p (g::forall b.(a->b->b)->b->b) .
552                 any p (build g) = g ((||) . p) False
553 "all/build"     forall p (g::forall b.(a->b->b)->b->b) .
554                 all p (build g) = g ((&&) . p) True
555  #-}
556 #endif
557
558 -- | 'elem' is the list membership predicate, usually written in infix form,
559 -- e.g., @x \`elem\` xs@.  For the result to be
560 -- 'False', the list must be finite; 'True', however, results from an element equal to @x@ found at a finite index of a finite or infinite list.
561 elem                    :: (Eq a) => a -> [a] -> Bool
562
563 -- | 'notElem' is the negation of 'elem'.
564 notElem                 :: (Eq a) => a -> [a] -> Bool
565 #ifdef USE_REPORT_PRELUDE
566 elem x                  =  any (== x)
567 notElem x               =  all (/= x)
568 #else
569 elem _ []       = False
570 elem x (y:ys)   = x==y || elem x ys
571
572 notElem _ []    =  True
573 notElem x (y:ys)=  x /= y && notElem x ys
574 #endif
575
576 -- | 'lookup' @key assocs@ looks up a key in an association list.
577 lookup                  :: (Eq a) => a -> [(a,b)] -> Maybe b
578 lookup _key []          =  Nothing
579 lookup  key ((x,y):xys)
580     | key == x          =  Just y
581     | otherwise         =  lookup key xys
582
583 -- | Map a function over a list and concatenate the results.
584 concatMap               :: (a -> [b]) -> [a] -> [b]
585 concatMap f             =  foldr ((++) . f) []
586
587 -- | Concatenate a list of lists.
588 concat :: [[a]] -> [a]
589 concat = foldr (++) []
590
591 {-# NOINLINE [1] concat #-}
592
593 {-# RULES
594   "concat" forall xs. concat xs = build (\c n -> foldr (\x y -> foldr c y x) n xs)
595 -- We don't bother to turn non-fusible applications of concat back into concat
596  #-}
597
598 \end{code}
599
600
601 \begin{code}
602 -- | List index (subscript) operator, starting from 0.
603 -- It is an instance of the more general 'Data.List.genericIndex',
604 -- which takes an index of any integral type.
605 (!!)                    :: [a] -> Int -> a
606 #ifdef USE_REPORT_PRELUDE
607 xs     !! n | n < 0 =  error "Prelude.!!: negative index"
608 []     !! _         =  error "Prelude.!!: index too large"
609 (x:_)  !! 0         =  x
610 (_:xs) !! n         =  xs !! (n-1)
611 #else
612 -- HBC version (stolen), then unboxified
613 -- The semantics is not quite the same for error conditions
614 -- in the more efficient version.
615 --
616 xs !! (I# n0) | isTrue# (n0 <# 0#) =  error "Prelude.(!!): negative index\n"
617               | otherwise          =  sub xs n0
618                          where
619                             sub :: [a] -> Int# -> a
620                             sub []     _ = error "Prelude.(!!): index too large\n"
621                             sub (y:ys) n = if isTrue# (n ==# 0#)
622                                            then y
623                                            else sub ys (n -# 1#)
624 #endif
625 \end{code}
626
627
628 %*********************************************************
629 %*                                                      *
630 \subsection{The zip family}
631 %*                                                      *
632 %*********************************************************
633
634 \begin{code}
635 foldr2 :: (a -> b -> c -> c) -> c -> [a] -> [b] -> c
636 foldr2 k z = go
637   where
638         go []    _ys     = z
639         go _xs   []      = z
640         go (x:xs) (y:ys) = k x y (go xs ys)
641 {-# INLINE [0] foldr2 #-}
642
643 foldr2_left :: (a -> b -> c -> d) -> d -> a -> ([b] -> c) -> [b] -> d
644 foldr2_left _k  z _x _r []     = z
645 foldr2_left  k _z  x  r (y:ys) = k x y (r ys)
646
647 foldr2_right :: (a -> b -> c -> d) -> d -> b -> ([a] -> c) -> [a] -> d
648 foldr2_right _k z  _y _r []     = z
649 foldr2_right  k _z  y  r (x:xs) = k x y (r xs)
650
651 -- foldr2 k z xs ys = foldr (foldr2_left k z)  (\_ -> z) xs ys
652 -- foldr2 k z xs ys = foldr (foldr2_right k z) (\_ -> z) ys xs
653 {-# RULES
654 "foldr2/left"   forall k z ys (g::forall b.(a->b->b)->b->b) .
655                   foldr2 k z (build g) ys = g (foldr2_left  k z) (\_ -> z) ys
656
657 "foldr2/right"  forall k z xs (g::forall b.(a->b->b)->b->b) .
658                   foldr2 k z xs (build g) = g (foldr2_right k z) (\_ -> z) xs
659  #-}
660 \end{code}
661
662 The foldr2/right rule isn't exactly right, because it changes
663 the strictness of foldr2 (and thereby zip)
664
665 E.g. main = print (null (zip nonobviousNil (build undefined)))
666           where   nonobviousNil = f 3
667                   f n = if n == 0 then [] else f (n-1)
668
669 I'm going to leave it though.
670
671
672 Zips for larger tuples are in the List module.
673
674 \begin{code}
675 ----------------------------------------------
676 -- | 'zip' takes two lists and returns a list of corresponding pairs.
677 -- If one input list is short, excess elements of the longer list are
678 -- discarded.
679 {-# NOINLINE [1] zip #-}
680 zip :: [a] -> [b] -> [(a,b)]
681 zip (a:as) (b:bs) = (a,b) : zip as bs
682 zip _      _      = []
683
684 {-# INLINE [0] zipFB #-}
685 zipFB :: ((a, b) -> c -> d) -> a -> b -> c -> d
686 zipFB c = \x y r -> (x,y) `c` r
687
688 {-# RULES
689 "zip"      [~1] forall xs ys. zip xs ys = build (\c n -> foldr2 (zipFB c) n xs ys)
690 "zipList"  [1]  foldr2 (zipFB (:)) []   = zip
691  #-}
692 \end{code}
693
694 \begin{code}
695 ----------------------------------------------
696 -- | 'zip3' takes three lists and returns a list of triples, analogous to
697 -- 'zip'.
698 zip3 :: [a] -> [b] -> [c] -> [(a,b,c)]
699 -- Specification
700 -- zip3 =  zipWith3 (,,)
701 zip3 (a:as) (b:bs) (c:cs) = (a,b,c) : zip3 as bs cs
702 zip3 _      _      _      = []
703 \end{code}
704
705
706 -- The zipWith family generalises the zip family by zipping with the
707 -- function given as the first argument, instead of a tupling function.
708
709 \begin{code}
710 ----------------------------------------------
711 -- | 'zipWith' generalises 'zip' by zipping with the function given
712 -- as the first argument, instead of a tupling function.
713 -- For example, @'zipWith' (+)@ is applied to two lists to produce the
714 -- list of corresponding sums.
715 {-# NOINLINE [1] zipWith #-}
716 zipWith :: (a->b->c) -> [a]->[b]->[c]
717 zipWith f (a:as) (b:bs) = f a b : zipWith f as bs
718 zipWith _ _      _      = []
719
720 -- zipWithFB must have arity 2 since it gets two arguments in the "zipWith"
721 -- rule; it might not get inlined otherwise
722 {-# INLINE [0] zipWithFB #-}
723 zipWithFB :: (a -> b -> c) -> (d -> e -> a) -> d -> e -> b -> c
724 zipWithFB c f = \x y r -> (x `f` y) `c` r
725
726 {-# RULES
727 "zipWith"       [~1] forall f xs ys.    zipWith f xs ys = build (\c n -> foldr2 (zipWithFB c f) n xs ys)
728 "zipWithList"   [1]  forall f.  foldr2 (zipWithFB (:) f) [] = zipWith f
729   #-}
730 \end{code}
731
732 \begin{code}
733 -- | The 'zipWith3' function takes a function which combines three
734 -- elements, as well as three lists and returns a list of their point-wise
735 -- combination, analogous to 'zipWith'.
736 zipWith3                :: (a->b->c->d) -> [a]->[b]->[c]->[d]
737 zipWith3 z (a:as) (b:bs) (c:cs)
738                         =  z a b c : zipWith3 z as bs cs
739 zipWith3 _ _ _ _        =  []
740
741 -- | 'unzip' transforms a list of pairs into a list of first components
742 -- and a list of second components.
743 unzip    :: [(a,b)] -> ([a],[b])
744 {-# INLINE unzip #-}
745 unzip    =  foldr (\(a,b) ~(as,bs) -> (a:as,b:bs)) ([],[])
746
747 -- | The 'unzip3' function takes a list of triples and returns three
748 -- lists, analogous to 'unzip'.
749 unzip3   :: [(a,b,c)] -> ([a],[b],[c])
750 {-# INLINE unzip3 #-}
751 unzip3   =  foldr (\(a,b,c) ~(as,bs,cs) -> (a:as,b:bs,c:cs))
752                   ([],[],[])
753 \end{code}
754
755
756 %*********************************************************
757 %*                                                      *
758 \subsection{Error code}
759 %*                                                      *
760 %*********************************************************
761
762 Common up near identical calls to `error' to reduce the number
763 constant strings created when compiled:
764
765 \begin{code}
766 errorEmptyList :: String -> a
767 errorEmptyList fun =
768   error (prel_list_str ++ fun ++ ": empty list")
769
770 prel_list_str :: String
771 prel_list_str = "Prelude."
772 \end{code}